qcsrc/common/util.qc

   1 string wordwrap_buffer;
   2
   3 void wordwrap_buffer_put(string s)
   4 {
   5         wordwrap_buffer = strcat(wordwrap_buffer, s);
   6 }
   7
   8 string wordwrap(string s, float l)
   9 {
  10         string r;
  11         wordwrap_buffer = "";
  12         wordwrap_cb(s, l, wordwrap_buffer_put);
  13         r = wordwrap_buffer;
  14         wordwrap_buffer = "";
  15         return r;
  16 }
  17
  18 #ifndef MENUQC
  19 #ifndef CSQC
  20 void wordwrap_buffer_sprint(string s)
  21 {
  22         wordwrap_buffer = strcat(wordwrap_buffer, s);
  23         if(s == "\n")
  24         {
  25                 sprint(self, wordwrap_buffer);
  26                 wordwrap_buffer = "";
  27         }
  28 }
  29
  30 void wordwrap_sprint(string s, float l)
  31 {
  32         wordwrap_buffer = "";
  33         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  34         if(wordwrap_buffer != "")
  35                 sprint(self, strcat(wordwrap_buffer, "\n"));
  36         wordwrap_buffer = "";
  37         return;
  38 }
  39 #endif
  40 #endif
  41
  42 #ifndef SVQC
  43 string draw_UseSkinFor(string pic)
  44 {
  45         if(substring(pic, 0, 1) == "/")
  46                 return substring(pic, 1, strlen(pic)-1);
  47         else
  48                 return strcat(draw_currentSkin, "/", pic);
  49 }
  50 #endif
  51
  52 string unescape(string in)
  53 {
  54         float i, len;
  55         string str, s;
  56
  57         // but it doesn't seem to be necessary in my tests at least
  58         in = strzone(in);
  59
  60         len = strlen(in);
  61         str = "";
  62         for(i = 0; i < len; ++i)
  63         {
  64                 s = substring(in, i, 1);
  65                 if(s == "\\")
  66                 {
  67                         s = substring(in, i+1, 1);
  68                         if(s == "n")
  69                                 str = strcat(str, "\n");
  70                         else if(s == "\\")
  71                                 str = strcat(str, "\\");
  72                         else
  73                                 str = strcat(str, substring(in, i, 2));
  74                         ++i;
  75                 } else
  76                         str = strcat(str, s);
  77         }
  78
  79         strunzone(in);
  80         return str;
  81 }
  82
  83 void wordwrap_cb(string s, float l, void(string) callback)
  84 {
  85         string c;
  86         float lleft, i, j, wlen;
  87
  88         s = strzone(s);
  89         lleft = l;
  90         for (i = 0;i < strlen(s);++i)
  91         {
  92                 if (substring(s, i, 2) == "\\n")
  93                 {
  94                         callback("\n");
  95                         lleft = l;
  96                         ++i;
  97                 }
  98                 else if (substring(s, i, 1) == "\n")
  99                 {
 100                         callback("\n");
 101                         lleft = l;
 102                 }
 103                 else if (substring(s, i, 1) == " ")
 104                 {
 105                         if (lleft > 0)
 106                         {
 107                                 callback(" ");
 108                                 lleft = lleft - 1;
 109                         }
 110                 }
 111                 else
 112                 {
 113                         for (j = i+1;j < strlen(s);++j)
 114                                 //    ^^ this skips over the first character of a word, which
 115                                 //       is ALWAYS part of the word
 116                                 //       this is safe since if i+1 == strlen(s), i will become
 117                                 //       strlen(s)-1 at the end of this block and the function
 118                                 //       will terminate. A space can't be the first character we
 119                                 //       read here, and neither can a \n be the start, since these
 120                                 //       two cases have been handled above.
 121                         {
 122                                 c = substring(s, j, 1);
 123                                 if (c == " ")
 124                                         break;
 125                                 if (c == "\\")
 126                                         break;
 127                                 if (c == "\n")
 128                                         break;
 129                                 // we need to keep this tempstring alive even if substring is
 130                                 // called repeatedly, so call strcat even though we're not
 131                                 // doing anything
 132                                 callback("");
 133                         }
 134                         wlen = j - i;
 135                         if (lleft < wlen)
 136                         {
 137                                 callback("\n");
 138                                 lleft = l;
 139                         }
 140                         callback(substring(s, i, wlen));
 141                         lleft = lleft - wlen;
 142                         i = j - 1;
 143                 }
 144         }
 145         strunzone(s);
 146 }
 147
 148 float dist_point_line(vector p, vector l0, vector ldir)
 149 {
 150         ldir = normalize(ldir);
 151
 152         // remove the component in line direction
 153         p = p - (p * ldir) * ldir;
 154
 155         // vlen of the remaining vector
 156         return vlen(p);
 157 }
 158
 159 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 160 {
 161         entity e;
 162         e = start;
 163         funcPre(pass, e);
 164         while(e.downleft)
 165         {
 166                 e = e.downleft;
 167                 funcPre(pass, e);
 168         }
 169         funcPost(pass, e);
 170         while(e != start)
 171         {
 172                 if(e.right)
 173                 {
 174                         e = e.right;
 175                         funcPre(pass, e);
 176                         while(e.downleft)
 177                         {
 178                                 e = e.downleft;
 179                                 funcPre(pass, e);
 180                         }
 181                 }
 182                 else
 183                         e = e.up;
 184                 funcPost(pass, e);
 185         }
 186 }
 187
 188 float median(float a, float b, float c)
 189 {
 190         if(a < c)
 191                 return bound(a, b, c);
 192         return bound(c, b, a);
 193 }
 194
 195 // converts a number to a string with the indicated number of decimals
 196 // works for up to 10 decimals!
 197 string ftos_decimals(float number, float decimals)
 198 {
 199         // inhibit stupid negative zero
 200         if(number == 0)
 201                 number = 0;
 202         // we have sprintf...
 203         return sprintf("%.*f", decimals, number);
 204 }
 205
 206 float time;
 207 vector colormapPaletteColor(float c, float isPants)
 208 {
 209         switch(c)
 210         {
 211                 case  0: return '1.000000 1.000000 1.000000';
 212                 case  1: return '1.000000 0.333333 0.000000';
 213                 case  2: return '0.000000 1.000000 0.501961';
 214                 case  3: return '0.000000 1.000000 0.000000';
 215                 case  4: return '1.000000 0.000000 0.000000';
 216                 case  5: return '0.000000 0.666667 1.000000';
 217                 case  6: return '0.000000 1.000000 1.000000';
 218                 case  7: return '0.501961 1.000000 0.000000';
 219                 case  8: return '0.501961 0.000000 1.000000';
 220                 case  9: return '1.000000 0.000000 1.000000';
 221                 case 10: return '1.000000 0.000000 0.501961';
 222                 case 11: return '0.000000 0.000000 1.000000';
 223                 case 12: return '1.000000 1.000000 0.000000';
 224                 case 13: return '0.000000 0.333333 1.000000';
 225                 case 14: return '1.000000 0.666667 0.000000';
 226                 case 15:
 227                         if(isPants)
 228                                 return
 229                                           '1 0 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 0.0000000000))
 230                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 2.0943951024))
 231                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 2.7182818285 + 4.1887902048));
 232                         else
 233                                 return
 234                                           '1 0 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 5.2359877560))
 235                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 3.1415926536))
 236                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 3.1415926536 + 1.0471975512));
 237                 default: return '0.000 0.000 0.000';
 238         }
 239 }
 240
 241 // unzone the string, and return it as tempstring. Safe to be called on string_null
 242 string fstrunzone(string s)
 243 {
 244         string sc;
 245         if not(s)
 246                 return s;
 247         sc = strcat(s, "");
 248         strunzone(s);
 249         return sc;
 250 }
 251
 252 float fexists(string f)
 253 {
 254     float fh;
 255     fh = fopen(f, FILE_READ);
 256     if (fh < 0)
 257         return FALSE;
 258     fclose(fh);
 259     return TRUE;
 260 }
 261
 262 // Databases (hash tables)
 263 #define DB_BUCKETS 8192
 264 void db_save(float db, string pFilename)
 265 {
 266         float fh, i, n;
 267         fh = fopen(pFilename, FILE_WRITE);
 268         if(fh < 0)
 269         {
 270                 print(strcat("^1Can't write DB to ", pFilename));
 271                 return;
 272         }
 273         n = buf_getsize(db);
 274         fputs(fh, strcat(ftos(DB_BUCKETS), "\n"));
 275         for(i = 0; i < n; ++i)
 276                 fputs(fh, strcat(bufstr_get(db, i), "\n"));
 277         fclose(fh);
 278 }
 279
 280 float db_create()
 281 {
 282         return buf_create();
 283 }
 284
 285 float db_load(string pFilename)
 286 {
 287         float db, fh, i, j, n;
 288         string l;
 289         db = buf_create();
 290         if(db < 0)
 291                 return -1;
 292         fh = fopen(pFilename, FILE_READ);
 293         if(fh < 0)
 294                 return db;
 295         l = fgets(fh);
 296         if(stof(l) == DB_BUCKETS)
 297         {
 298                 i = 0;
 299                 while((l = fgets(fh)))
 300                 {
 301                         if(l != "")
 302                                 bufstr_set(db, i, l);
 303                         ++i;
 304                 }
 305         }
 306         else
 307         {
 308                 // different count of buckets, or a dump?
 309                 // need to reorganize the database then (SLOW)
 310                 //
 311                 // note: we also parse the first line (l) in case the DB file is
 312                 // missing the bucket count
 313                 do
 314                 {
 315                         n = tokenizebyseparator(l, "\\");
 316                         for(j = 2; j < n; j += 2)
 317                                 db_put(db, argv(j-1), uri_unescape(argv(j)));
 318                 }
 319                 while((l = fgets(fh)));
 320         }
 321         fclose(fh);
 322         return db;
 323 }
 324
 325 void db_dump(float db, string pFilename)
 326 {
 327         float fh, i, j, n, m;
 328         fh = fopen(pFilename, FILE_WRITE);
 329         if(fh < 0)
 330                 error(strcat("Can't dump DB to ", pFilename));
 331         n = buf_getsize(db);
 332         fputs(fh, "0\n");
 333         for(i = 0; i < n; ++i)
 334         {
 335                 m = tokenizebyseparator(bufstr_get(db, i), "\\");
 336                 for(j = 2; j < m; j += 2)
 337                         fputs(fh, strcat("\\", argv(j-1), "\\", argv(j), "\n"));
 338         }
 339         fclose(fh);
 340 }
 341
 342 void db_close(float db)
 343 {
 344         buf_del(db);
 345 }
 346
 347 string db_get(float db, string pKey)
 348 {
 349         float h;
 350         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 351         return uri_unescape(infoget(bufstr_get(db, h), pKey));
 352 }
 353
 354 void db_put(float db, string pKey, string pValue)
 355 {
 356         float h;
 357         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 358         bufstr_set(db, h, infoadd(bufstr_get(db, h), pKey, uri_escape(pValue)));
 359 }
 360
 361 void db_test()
 362 {
 363         float db, i;
 364         print("LOAD...\n");
 365         db = db_load("foo.db");
 366         print("LOADED. FILL...\n");
 367         for(i = 0; i < DB_BUCKETS; ++i)
 368                 db_put(db, ftos(random()), "X");
 369         print("FILLED. SAVE...\n");
 370         db_save(db, "foo.db");
 371         print("SAVED. CLOSE...\n");
 372         db_close(db);
 373         print("CLOSED.\n");
 374 }
 375
 376 // Multiline text file buffers
 377 float buf_load(string pFilename)
 378 {
 379         float buf, fh, i;
 380         string l;
 381         buf = buf_create();
 382         if(buf < 0)
 383                 return -1;
 384         fh = fopen(pFilename, FILE_READ);
 385         if(fh < 0)
 386         {
 387                 buf_del(buf);
 388                 return -1;
 389         }
 390         i = 0;
 391         while((l = fgets(fh)))
 392         {
 393                 bufstr_set(buf, i, l);
 394                 ++i;
 395         }
 396         fclose(fh);
 397         return buf;
 398 }
 399
 400 void buf_save(float buf, string pFilename)
 401 {
 402         float fh, i, n;
 403         fh = fopen(pFilename, FILE_WRITE);
 404         if(fh < 0)
 405                 error(strcat("Can't write buf to ", pFilename));
 406         n = buf_getsize(buf);
 407         for(i = 0; i < n; ++i)
 408                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 409         fclose(fh);
 410 }
 411
 412 string mmsss(float tenths)
 413 {
 414         float minutes;
 415         string s;
 416         tenths = floor(tenths + 0.5);
 417         minutes = floor(tenths / 600);
 418         tenths -= minutes * 600;
 419         s = ftos(1000 + tenths);
 420         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 421 }
 422
 423 string mmssss(float hundredths)
 424 {
 425         float minutes;
 426         string s;
 427         hundredths = floor(hundredths + 0.5);
 428         minutes = floor(hundredths / 6000);
 429         hundredths -= minutes * 6000;
 430         s = ftos(10000 + hundredths);
 431         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
 432 }
 433
 434 string ScoreString(float pFlags, float pValue)
 435 {
 436         string valstr;
 437         float l;
 438
 439         pValue = floor(pValue + 0.5); // round
 440
 441         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 442                 valstr = "";
 443         else if(pFlags & SFL_RANK)
 444         {
 445                 valstr = ftos(pValue);
 446                 l = strlen(valstr);
 447                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 448                         valstr = strcat(valstr, "th");
 449                 else if(substring(valstr, l - 1, 1) == "1")
 450                         valstr = strcat(valstr, "st");
 451                 else if(substring(valstr, l - 1, 1) == "2")
 452                         valstr = strcat(valstr, "nd");
 453                 else if(substring(valstr, l - 1, 1) == "3")
 454                         valstr = strcat(valstr, "rd");
 455                 else
 456                         valstr = strcat(valstr, "th");
 457         }
 458         else if(pFlags & SFL_TIME)
 459                 valstr = TIME_ENCODED_TOSTRING(pValue);
 460         else
 461                 valstr = ftos(pValue);
 462
 463         return valstr;
 464 }
 465
 466 vector cross(vector a, vector b)
 467 {
 468         return
 469                 '1 0 0' * (a_y * b_z - a_z * b_y)
 470         +       '0 1 0' * (a_z * b_x - a_x * b_z)
 471         +       '0 0 1' * (a_x * b_y - a_y * b_x);
 472 }
 473
 474 // compressed vector format:
 475 // like MD3, just even shorter
 476 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 477 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 478 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 479 //     length = 2^(length_encoded/8) / 8
 480 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 481 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 482 // the special value 0 indicates the zero vector
 483
 484 float lengthLogTable[128];
 485
 486 float invertLengthLog(float x)
 487 {
 488         float l, r, m, lerr, rerr;
 489
 490         if(x >= lengthLogTable[127])
 491                 return 127;
 492         if(x <= lengthLogTable[0])
 493                 return 0;
 494
 495         l = 0;
 496         r = 127;
 497
 498         while(r - l > 1)
 499         {
 500                 m = floor((l + r) / 2);
 501                 if(lengthLogTable[m] < x)
 502                         l = m;
 503                 else
 504                         r = m;
 505         }
 506
 507         // now: r is >=, l is <
 508         lerr = (x - lengthLogTable[l]);
 509         rerr = (lengthLogTable[r] - x);
 510         if(lerr < rerr)
 511                 return l;
 512         return r;
 513 }
 514
 515 vector decompressShortVector(float data)
 516 {
 517         vector out;
 518         float p, y, len;
 519         if(data == 0)
 520                 return '0 0 0';
 521         p   = (data & 0xF000) / 0x1000;
 522         y   = (data & 0x0F80) / 0x80;
 523         len = (data & 0x007F);
 524
 525         //print("\ndecompress: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 526
 527         if(p == 0)
 528         {
 529                 out_x = 0;
 530                 out_y = 0;
 531                 if(y == 31)
 532                         out_z = -1;
 533                 else
 534                         out_z = +1;
 535         }
 536         else
 537         {
 538                 y   = .19634954084936207740 * y;
 539                 p = .19634954084936207740 * p - 1.57079632679489661922;
 540                 out_x = cos(y) *  cos(p);
 541                 out_y = sin(y) *  cos(p);
 542                 out_z =          -sin(p);
 543         }
 544
 545         //print("decompressed: ", vtos(out), "\n");
 546
 547         return out * lengthLogTable[len];
 548 }
 549
 550 float compressShortVector(vector vec)
 551 {
 552         vector ang;
 553         float p, y, len;
 554         if(vlen(vec) == 0)
 555                 return 0;
 556         //print("compress: ", vtos(vec), "\n");
 557         ang = vectoangles(vec);
 558         ang_x = -ang_x;
 559         if(ang_x < -90)
 560                 ang_x += 360;
 561         if(ang_x < -90 && ang_x > +90)
 562                 error("BOGUS vectoangles");
 563         //print("angles: ", vtos(ang), "\n");
 564
 565         p = floor(0.5 + (ang_x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 566         if(p == 0)
 567         {
 568                 if(vec_z < 0)
 569                         y = 31;
 570                 else
 571                         y = 30;
 572         }
 573         else
 574                 y = floor(0.5 + ang_y * 32 / 360)          & 31; // 0..360 to 0..32
 575         len = invertLengthLog(vlen(vec));
 576
 577         //print("compressed: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 578
 579         return (p * 0x1000) + (y * 0x80) + len;
 580 }
 581
 582 void compressShortVector_init()
 583 {
 584         float l, f, i;
 585         l = 1;
 586         f = pow(2, 1/8);
 587         for(i = 0; i < 128; ++i)
 588         {
 589                 lengthLogTable[i] = l;
 590                 l *= f;
 591         }
 592
 593         if(cvar("developer"))
 594         {
 595                 print("Verifying vector compression table...\n");
 596                 for(i = 0x0F00; i < 0xFFFF; ++i)
 597                         if(i != compressShortVector(decompressShortVector(i)))
 598                         {
 599                                 print("BROKEN vector compression: ", ftos(i));
 600                                 print(" -> ", vtos(decompressShortVector(i)));
 601                                 print(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 602                                 print("\n");
 603                                 error("b0rk");
 604                         }
 605                 print("Done.\n");
 606         }
 607 }
 608
 609 #ifndef MENUQC
 610 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 611 {
 612         traceline(v0, v0 + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 613         traceline(v0, v0 + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 614         traceline(v0, v0 + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 615         traceline(v0 + dvx, v0 + dvx + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 616         traceline(v0 + dvx, v0 + dvx + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 617         traceline(v0 + dvy, v0 + dvy + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 618         traceline(v0 + dvy, v0 + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 619         traceline(v0 + dvz, v0 + dvz + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 620         traceline(v0 + dvz, v0 + dvz + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 621         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 622         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 623         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 624         return 1;
 625 }
 626 #endif
 627
 628 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 629 {
 630         string neworder;
 631         float i, n, w;
 632
 633         n = tokenize_console(order);
 634         neworder = "";
 635         for(i = 0; i < n; ++i)
 636         {
 637                 w = stof(argv(i));
 638                 if(w == floor(w))
 639                 {
 640                         if(w >= from && w <= to)
 641                                 neworder = strcat(neworder, ftos(w), " ");
 642                         else
 643                         {
 644                                 w -= subtract;
 645                                 if(w >= from && w <= to)
 646                                         neworder = strcat(neworder, ftos(w), " ");
 647                         }
 648                 }
 649         }
 650
 651         if(complete)
 652         {
 653                 n = tokenize_console(neworder);
 654                 for(w = to; w >= from; --w)
 655                 {
 656                         for(i = 0; i < n; ++i)
 657                                 if(stof(argv(i)) == w)
 658                                         break;
 659                         if(i == n) // not found
 660                                 neworder = strcat(neworder, ftos(w), " ");
 661                 }
 662         }
 663
 664         return substring(neworder, 0, strlen(neworder) - 1);
 665 }
 666
 667 string mapPriorityList(string order, string(string) mapfunc)
 668 {
 669         string neworder;
 670         float i, n;
 671
 672         n = tokenize_console(order);
 673         neworder = "";
 674         for(i = 0; i < n; ++i)
 675                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
 676
 677         return substring(neworder, 0, strlen(neworder) - 1);
 678 }
 679
 680 string swapInPriorityList(string order, float i, float j)
 681 {
 682         string s;
 683         float w, n;
 684
 685         n = tokenize_console(order);
 686
 687         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 688         {
 689                 s = "";
 690                 for(w = 0; w < n; ++w)
 691                 {
 692                         if(w == i)
 693                                 s = strcat(s, argv(j), " ");
 694                         else if(w == j)
 695                                 s = strcat(s, argv(i), " ");
 696                         else
 697                                 s = strcat(s, argv(w), " ");
 698                 }
 699                 return substring(s, 0, strlen(s) - 1);
 700         }
 701
 702         return order;
 703 }
 704
 705 float cvar_value_issafe(string s)
 706 {
 707         if(strstrofs(s, "\"", 0) >= 0)
 708                 return 0;
 709         if(strstrofs(s, "\\", 0) >= 0)
 710                 return 0;
 711         if(strstrofs(s, ";", 0) >= 0)
 712                 return 0;
 713         if(strstrofs(s, "$", 0) >= 0)
 714                 return 0;
 715         if(strstrofs(s, "\r", 0) >= 0)
 716                 return 0;
 717         if(strstrofs(s, "\n", 0) >= 0)
 718                 return 0;
 719         return 1;
 720 }
 721
 722 #ifndef MENUQC
 723 void get_mi_min_max(float mode)
 724 {
 725         vector mi, ma;
 726
 727         if(mi_shortname)
 728                 strunzone(mi_shortname);
 729         mi_shortname = mapname;
 730         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 731                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 732         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 733                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 734         mi_shortname = strzone(mi_shortname);
 735
 736 #ifdef CSQC
 737         mi = world.mins;
 738         ma = world.maxs;
 739 #else
 740         mi = world.absmin;
 741         ma = world.absmax;
 742 #endif
 743
 744         mi_min = mi;
 745         mi_max = ma;
 746         MapInfo_Get_ByName(mi_shortname, 0, 0);
 747         if(MapInfo_Map_mins_x < MapInfo_Map_maxs_x)
 748         {
 749                 mi_min = MapInfo_Map_mins;
 750                 mi_max = MapInfo_Map_maxs;
 751         }
 752         else
 753         {
 754                 // not specified
 755                 if(mode)
 756                 {
 757                         // be clever
 758                         tracebox('1 0 0' * mi_x,
 759                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 760                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 761                                          '1 0 0' * ma_x,
 762                                          MOVE_WORLDONLY,
 763                                          world);
 764                         if(!trace_startsolid)
 765                                 mi_min_x = trace_endpos_x;
 766
 767                         tracebox('0 1 0' * mi_y,
 768                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 769                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 770                                          '0 1 0' * ma_y,
 771                                          MOVE_WORLDONLY,
 772                                          world);
 773                         if(!trace_startsolid)
 774                                 mi_min_y = trace_endpos_y;
 775
 776                         tracebox('0 0 1' * mi_z,
 777                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 778                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 779                                          '0 0 1' * ma_z,
 780                                          MOVE_WORLDONLY,
 781                                          world);
 782                         if(!trace_startsolid)
 783                                 mi_min_z = trace_endpos_z;
 784
 785                         tracebox('1 0 0' * ma_x,
 786                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 787                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 788                                          '1 0 0' * mi_x,
 789                                          MOVE_WORLDONLY,
 790                                          world);
 791                         if(!trace_startsolid)
 792                                 mi_max_x = trace_endpos_x;
 793
 794                         tracebox('0 1 0' * ma_y,
 795                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 796                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 797                                          '0 1 0' * mi_y,
 798                                          MOVE_WORLDONLY,
 799                                          world);
 800                         if(!trace_startsolid)
 801                                 mi_max_y = trace_endpos_y;
 802
 803                         tracebox('0 0 1' * ma_z,
 804                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 805                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 806                                          '0 0 1' * mi_z,
 807                                          MOVE_WORLDONLY,
 808                                          world);
 809                         if(!trace_startsolid)
 810                                 mi_max_z = trace_endpos_z;
 811                 }
 812         }
 813 }
 814
 815 void get_mi_min_max_texcoords(float mode)
 816 {
 817         vector extend;
 818
 819         get_mi_min_max(mode);
 820
 821         mi_picmin = mi_min;
 822         mi_picmax = mi_max;
 823
 824         // extend mi_picmax to get a square aspect ratio
 825         // center the map in that area
 826         extend = mi_picmax - mi_picmin;
 827         if(extend_y > extend_x)
 828         {
 829                 mi_picmin_x -= (extend_y - extend_x) * 0.5;
 830                 mi_picmax_x += (extend_y - extend_x) * 0.5;
 831         }
 832         else
 833         {
 834                 mi_picmin_y -= (extend_x - extend_y) * 0.5;
 835                 mi_picmax_y += (extend_x - extend_y) * 0.5;
 836         }
 837
 838         // add another some percent
 839         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 840         mi_picmin -= extend;
 841         mi_picmax += extend;
 842
 843         // calculate the texcoords
 844         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 845         // first the two corners of the origin
 846         mi_pictexcoord0_x = (mi_min_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 847         mi_pictexcoord0_y = (mi_min_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 848         mi_pictexcoord2_x = (mi_max_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 849         mi_pictexcoord2_y = (mi_max_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 850         // then the other corners
 851         mi_pictexcoord1_x = mi_pictexcoord0_x;
 852         mi_pictexcoord1_y = mi_pictexcoord2_y;
 853         mi_pictexcoord3_x = mi_pictexcoord2_x;
 854         mi_pictexcoord3_y = mi_pictexcoord0_y;
 855 }
 856 #endif
 857
 858 float cvar_settemp(string tmp_cvar, string tmp_value)
 859 {
 860         float created_saved_value;
 861         entity e;
 862
 863         if not(tmp_cvar || tmp_value)
 864         {
 865                 dprint("Error: Invalid usage of cvar_settemp(string, string); !\n");
 866                 return FALSE;
 867         }
 868
 869         if(!cvar_type(tmp_cvar))
 870         {
 871                 print(sprintf("Error: cvar %s doesn't exist!\n", tmp_cvar));
 872                 return FALSE;
 873         }
 874
 875         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
 876                 if(e.netname == tmp_cvar)
 877                         goto saved; // skip creation
 878
 879         // creating a new entity to keep track of this cvar
 880         e = spawn();
 881         e.classname = "saved_cvar_value";
 882         e.netname = strzone(tmp_cvar);
 883         e.message = strzone(cvar_string(tmp_cvar));
 884         created_saved_value = TRUE;
 885
 886         // an entity for this cvar already exists
 887         :saved
 888
 889         // update the cvar to the value given
 890         cvar_set(tmp_cvar, tmp_value);
 891
 892         return created_saved_value;
 893 }
 894
 895 float cvar_settemp_restore()
 896 {
 897         float i;
 898         entity e;
 899         while((e = find(e, classname, "saved_cvar_value")))
 900         {
 901                 if(cvar_type(e.netname))
 902                 {
 903                         cvar_set(e.netname, e.message);
 904                         remove(e);
 905                         ++i;
 906                 }
 907                 else
 908                         print(sprintf("Error: cvar %s doesn't exist anymore! It can still be restored once it's manually recreated.\n", e.netname));
 909         }
 910
 911         return i;
 912 }
 913
 914 float almost_equals(float a, float b)
 915 {
 916         float eps;
 917         eps = (max(a, -a) + max(b, -b)) * 0.001;
 918         if(a - b < eps && b - a < eps)
 919                 return TRUE;
 920         return FALSE;
 921 }
 922
 923 float almost_in_bounds(float a, float b, float c)
 924 {
 925         float eps;
 926         eps = (max(a, -a) + max(c, -c)) * 0.001;
 927         if(a > c)
 928                 eps = -eps;
 929         return b == median(a - eps, b, c + eps);
 930 }
 931
 932 float power2of(float e)
 933 {
 934         return pow(2, e);
 935 }
 936 float log2of(float x)
 937 {
 938         // NOTE: generated code
 939         if(x > 2048)
 940                 if(x > 131072)
 941                         if(x > 1048576)
 942                                 if(x > 4194304)
 943                                         return 23;
 944                                 else
 945                                         if(x > 2097152)
 946                                                 return 22;
 947                                         else
 948                                                 return 21;
 949                         else
 950                                 if(x > 524288)
 951                                         return 20;
 952                                 else
 953                                         if(x > 262144)
 954                                                 return 19;
 955                                         else
 956                                                 return 18;
 957                 else
 958                         if(x > 16384)
 959                                 if(x > 65536)
 960                                         return 17;
 961                                 else
 962                                         if(x > 32768)
 963                                                 return 16;
 964                                         else
 965                                                 return 15;
 966                         else
 967                                 if(x > 8192)
 968                                         return 14;
 969                                 else
 970                                         if(x > 4096)
 971                                                 return 13;
 972                                         else
 973                                                 return 12;
 974         else
 975                 if(x > 32)
 976                         if(x > 256)
 977                                 if(x > 1024)
 978                                         return 11;
 979                                 else
 980                                         if(x > 512)
 981                                                 return 10;
 982                                         else
 983                                                 return 9;
 984                         else
 985                                 if(x > 128)
 986                                         return 8;
 987                                 else
 988                                         if(x > 64)
 989                                                 return 7;
 990                                         else
 991                                                 return 6;
 992                 else
 993                         if(x > 4)
 994                                 if(x > 16)
 995                                         return 5;
 996                                 else
 997                                         if(x > 8)
 998                                                 return 4;
 999                                         else
1000                                                 return 3;
1001                         else
1002                                 if(x > 2)
1003                                         return 2;
1004                                 else
1005                                         if(x > 1)
1006                                                 return 1;
1007                                         else
1008                                                 return 0;
1009 }
1010
1011 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
1012 {
1013         if(mi == ma)
1014                 return 0;
1015         else if(ma == rgb_x)
1016         {
1017                 if(rgb_y >= rgb_z)
1018                         return (rgb_y - rgb_z) / (ma - mi);
1019                 else
1020                         return (rgb_y - rgb_z) / (ma - mi) + 6;
1021         }
1022         else if(ma == rgb_y)
1023                 return (rgb_z - rgb_x) / (ma - mi) + 2;
1024         else // if(ma == rgb_z)
1025                 return (rgb_x - rgb_y) / (ma - mi) + 4;
1026 }
1027
1028 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
1029 {
1030         vector rgb;
1031
1032         hue -= 6 * floor(hue / 6);
1033
1034         //else if(ma == rgb_x)
1035         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1036         if(hue <= 1)
1037         {
1038                 rgb_x = ma;
1039                 rgb_y = hue * (ma - mi) + mi;
1040                 rgb_z = mi;
1041         }
1042         //else if(ma == rgb_y)
1043         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
1044         else if(hue <= 2)
1045         {
1046                 rgb_x = (2 - hue) * (ma - mi) + mi;
1047                 rgb_y = ma;
1048                 rgb_z = mi;
1049         }
1050         else if(hue <= 3)
1051         {
1052                 rgb_x = mi;
1053                 rgb_y = ma;
1054                 rgb_z = (hue - 2) * (ma - mi) + mi;
1055         }
1056         //else // if(ma == rgb_z)
1057         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
1058         else if(hue <= 4)
1059         {
1060                 rgb_x = mi;
1061                 rgb_y = (4 - hue) * (ma - mi) + mi;
1062                 rgb_z = ma;
1063         }
1064         else if(hue <= 5)
1065         {
1066                 rgb_x = (hue - 4) * (ma - mi) + mi;
1067                 rgb_y = mi;
1068                 rgb_z = ma;
1069         }
1070         //else if(ma == rgb_x)
1071         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1072         else // if(hue <= 6)
1073         {
1074                 rgb_x = ma;
1075                 rgb_y = mi;
1076                 rgb_z = (6 - hue) * (ma - mi) + mi;
1077         }
1078
1079         return rgb;
1080 }
1081
1082 vector rgb_to_hsv(vector rgb)
1083 {
1084         float mi, ma;
1085         vector hsv;
1086
1087         mi = min(rgb_x, rgb_y, rgb_z);
1088         ma = max(rgb_x, rgb_y, rgb_z);
1089
1090         hsv_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1091         hsv_z = ma;
1092
1093         if(ma == 0)
1094                 hsv_y = 0;
1095         else
1096                 hsv_y = 1 - mi/ma;
1097
1098         return hsv;
1099 }
1100
1101 vector hsv_to_rgb(vector hsv)
1102 {
1103         return hue_mi_ma_to_rgb(hsv_x, hsv_z * (1 - hsv_y), hsv_z);
1104 }
1105
1106 vector rgb_to_hsl(vector rgb)
1107 {
1108         float mi, ma;
1109         vector hsl;
1110
1111         mi = min(rgb_x, rgb_y, rgb_z);
1112         ma = max(rgb_x, rgb_y, rgb_z);
1113
1114         hsl_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1115
1116         hsl_z = 0.5 * (mi + ma);
1117         if(mi == ma)
1118                 hsl_y = 0;
1119         else if(hsl_z <= 0.5)
1120                 hsl_y = (ma - mi) / (2*hsl_z);
1121         else // if(hsl_z > 0.5)
1122                 hsl_y = (ma - mi) / (2 - 2*hsl_z);
1123
1124         return hsl;
1125 }
1126
1127 vector hsl_to_rgb(vector hsl)
1128 {
1129         float mi, ma, maminusmi;
1130
1131         if(hsl_z <= 0.5)
1132                 maminusmi = hsl_y * 2 * hsl_z;
1133         else
1134                 maminusmi = hsl_y * (2 - 2 * hsl_z);
1135
1136         // hsl_z     = 0.5 * mi + 0.5 * ma
1137         // maminusmi =     - mi +       ma
1138         mi = hsl_z - 0.5 * maminusmi;
1139         ma = hsl_z + 0.5 * maminusmi;
1140
1141         return hue_mi_ma_to_rgb(hsl_x, mi, ma);
1142 }
1143
1144 string rgb_to_hexcolor(vector rgb)
1145 {
1146         return
1147                 strcat(
1148                         "^x",
1149                         DEC_TO_HEXDIGIT(floor(rgb_x * 15 + 0.5)),
1150                         DEC_TO_HEXDIGIT(floor(rgb_y * 15 + 0.5)),
1151                         DEC_TO_HEXDIGIT(floor(rgb_z * 15 + 0.5))
1152                 );
1153 }
1154
1155 // requires that m2>m1 in all coordinates, and that m4>m3
1156 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;}
1157
1158 // requires the same, but is a stronger condition
1159 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;}
1160
1161 #ifndef MENUQC
1162 #endif
1163
1164 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
1165 {
1166         // STOP.
1167         // The following function is SLOW.
1168         // For your safety and for the protection of those around you...
1169         // DO NOT CALL THIS AT HOME.
1170         // No really, don't.
1171         if(w(theText, theSize) <= maxWidth)
1172                 return strlen(theText); // yeah!
1173
1174         // binary search for right place to cut string
1175         float ch;
1176         float left, right, middle; // this always works
1177         left = 0;
1178         right = strlen(theText); // this always fails
1179         do
1180         {
1181                 middle = floor((left + right) / 2);
1182                 if(w(substring(theText, 0, middle), theSize) <= maxWidth)
1183                         left = middle;
1184                 else
1185                         right = middle;
1186         }
1187         while(left < right - 1);
1188
1189         if(w("^7", theSize) == 0) // detect color codes support in the width function
1190         {
1191                 // NOTE: when color codes are involved, this binary search is,
1192                 // mathematically, BROKEN. However, it is obviously guaranteed to
1193                 // terminate, as the range still halves each time - but nevertheless, it is
1194                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1195                 // range, and "right" is outside).
1196
1197                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1198                 // and decrease left on the basis of the chars detected of the truncated tag
1199                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1200                 // (sometimes too much but with a correct result)
1201                 // it fixes also ^[0-9]
1202                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1203                         left-=1;
1204
1205                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1206                         left-=2;
1207                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1208                         {
1209                                 ch = str2chr(theText, left-1);
1210                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1211                                         left-=3;
1212                         }
1213                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1214                         {
1215                                 ch = str2chr(theText, left-2);
1216                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1217                                 {
1218                                         ch = str2chr(theText, left-1);
1219                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1220                                                 left-=4;
1221                                 }
1222                         }
1223         }
1224
1225         return left;
1226 }
1227
1228 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
1229 {
1230         // STOP.
1231         // The following function is SLOW.
1232         // For your safety and for the protection of those around you...
1233         // DO NOT CALL THIS AT HOME.
1234         // No really, don't.
1235         if(w(theText) <= maxWidth)
1236                 return strlen(theText); // yeah!
1237
1238         // binary search for right place to cut string
1239         float ch;
1240         float left, right, middle; // this always works
1241         left = 0;
1242         right = strlen(theText); // this always fails
1243         do
1244         {
1245                 middle = floor((left + right) / 2);
1246                 if(w(substring(theText, 0, middle)) <= maxWidth)
1247                         left = middle;
1248                 else
1249                         right = middle;
1250         }
1251         while(left < right - 1);
1252
1253         if(w("^7") == 0) // detect color codes support in the width function
1254         {
1255                 // NOTE: when color codes are involved, this binary search is,
1256                 // mathematically, BROKEN. However, it is obviously guaranteed to
1257                 // terminate, as the range still halves each time - but nevertheless, it is
1258                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1259                 // range, and "right" is outside).
1260
1261                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1262                 // and decrease left on the basis of the chars detected of the truncated tag
1263                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1264                 // (sometimes too much but with a correct result)
1265                 // it fixes also ^[0-9]
1266                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1267                         left-=1;
1268
1269                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1270                         left-=2;
1271                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1272                         {
1273                                 ch = str2chr(theText, left-1);
1274                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1275                                         left-=3;
1276                         }
1277                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1278                         {
1279                                 ch = str2chr(theText, left-2);
1280                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1281                                 {
1282                                         ch = str2chr(theText, left-1);
1283                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1284                                                 left-=4;
1285                                 }
1286                         }
1287         }
1288
1289         return left;
1290 }
1291
1292 string find_last_color_code(string s)
1293 {
1294         float start, len, i, carets;
1295         start = strstrofs(s, "^", 0);
1296         if (start == -1) // no caret found
1297                 return "";
1298         len = strlen(s)-1;
1299         for(i = len; i >= start; --i)
1300         {
1301                 if(substring(s, i, 1) != "^")
1302                         continue;
1303
1304                 carets = 1;
1305                 while (i-carets >= start && substring(s, i-carets, 1) == "^")
1306                         ++carets;
1307
1308                 // check if carets aren't all escaped
1309                 if (carets == 1 || mod(carets, 2) == 1) // first check is just an optimization
1310                 {
1311                         if(i+1 <= len)
1312                         if(strstrofs("0123456789", substring(s, i+1, 1), 0) >= 0)
1313                                 return substring(s, i, 2);
1314
1315                         if(i+4 <= len)
1316                         if(substring(s, i+1, 1) == "x")
1317                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+2, 1), 0) >= 0)
1318                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+3, 1), 0) >= 0)
1319                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+4, 1), 0) >= 0)
1320                                 return substring(s, i, 5);
1321                 }
1322                 i -= carets; // this also skips one char before the carets
1323         }
1324
1325         return "";
1326 }
1327
1328 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1329 {
1330         float cantake;
1331         float take;
1332         string s;
1333
1334         s = getWrappedLine_remaining;
1335
1336         if(w <= 0)
1337         {
1338                 getWrappedLine_remaining = string_null;
1339                 return s; // the line has no size ANYWAY, nothing would be displayed.
1340         }
1341
1342         cantake = textLengthUpToWidth(s, w, theFontSize, tw);
1343         if(cantake > 0 && cantake < strlen(s))
1344         {
1345                 take = cantake - 1;
1346                 while(take > 0 && substring(s, take, 1) != " ")
1347                         --take;
1348                 if(take == 0)
1349                 {
1350                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1351                         if(getWrappedLine_remaining == "")
1352                                 getWrappedLine_remaining = string_null;
1353                         else if (tw("^7", theFontSize) == 0)
1354                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1355                         return substring(s, 0, cantake);
1356                 }
1357                 else
1358                 {
1359                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1360                         if(getWrappedLine_remaining == "")
1361                                 getWrappedLine_remaining = string_null;
1362                         else if (tw("^7", theFontSize) == 0)
1363                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1364                         return substring(s, 0, take);
1365                 }
1366         }
1367         else
1368         {
1369                 getWrappedLine_remaining = string_null;
1370                 return s;
1371         }
1372 }
1373
1374 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
1375 {
1376         float cantake;
1377         float take;
1378         string s;
1379
1380         s = getWrappedLine_remaining;
1381
1382         if(w <= 0)
1383         {
1384                 getWrappedLine_remaining = string_null;
1385                 return s; // the line has no size ANYWAY, nothing would be displayed.
1386         }
1387
1388         cantake = textLengthUpToLength(s, w, tw);
1389         if(cantake > 0 && cantake < strlen(s))
1390         {
1391                 take = cantake - 1;
1392                 while(take > 0 && substring(s, take, 1) != " ")
1393                         --take;
1394                 if(take == 0)
1395                 {
1396                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1397                         if(getWrappedLine_remaining == "")
1398                                 getWrappedLine_remaining = string_null;
1399                         else if (tw("^7") == 0)
1400                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1401                         return substring(s, 0, cantake);
1402                 }
1403                 else
1404                 {
1405                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1406                         if(getWrappedLine_remaining == "")
1407                                 getWrappedLine_remaining = string_null;
1408                         else if (tw("^7") == 0)
1409                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1410                         return substring(s, 0, take);
1411                 }
1412         }
1413         else
1414         {
1415                 getWrappedLine_remaining = string_null;
1416                 return s;
1417         }
1418 }
1419
1420 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1421 {
1422         if(tw(theText, theFontSize) <= maxWidth)
1423                 return theText;
1424         else
1425                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
1426 }
1427
1428 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
1429 {
1430         if(tw(theText) <= maxWidth)
1431                 return theText;
1432         else
1433                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
1434 }
1435
1436 float isGametypeInFilter(float gt, float tp, float ts, string pattern)
1437 {
1438         string subpattern, subpattern2, subpattern3, subpattern4;
1439         subpattern = strcat(",", MapInfo_Type_ToString(gt), ",");
1440         if(tp)
1441                 subpattern2 = ",teams,";
1442         else
1443                 subpattern2 = ",noteams,";
1444         if(ts)
1445                 subpattern3 = ",teamspawns,";
1446         else
1447                 subpattern3 = ",noteamspawns,";
1448         if(gt == MAPINFO_TYPE_RACE || gt == MAPINFO_TYPE_CTS)
1449                 subpattern4 = ",race,";
1450         else
1451                 subpattern4 = string_null;
1452
1453         if(substring(pattern, 0, 1) == "-")
1454         {
1455                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1456                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1457                         return 0;
1458                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1459                         return 0;
1460                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
1461                         return 0;
1462                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
1463                         return 0;
1464         }
1465         else
1466         {
1467                 if(substring(pattern, 0, 1) == "+")
1468                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1469                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1470                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1471                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
1472                 if((!subpattern4) || strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
1473                         return 0;
1474         }
1475         return 1;
1476 }
1477
1478 void shuffle(float n, swapfunc_t swap, entity pass)
1479 {
1480         float i, j;
1481         for(i = 1; i < n; ++i)
1482         {
1483                 // swap i-th item at a random position from 0 to i
1484                 // proof for even distribution:
1485                 //   n = 1: obvious
1486                 //   n -> n+1:
1487                 //     item n+1 gets at any position with chance 1/(n+1)
1488                 //     all others will get their 1/n chance reduced by factor n/(n+1)
1489                 //     to be on place n+1, their chance will be 1/(n+1)
1490                 //     1/n * n/(n+1) = 1/(n+1)
1491                 //     q.e.d.
1492                 j = floor(random() * (i + 1));
1493                 if(j != i)
1494                         swap(j, i, pass);
1495         }
1496 }
1497
1498 string substring_range(string s, float b, float e)
1499 {
1500         return substring(s, b, e - b);
1501 }
1502
1503 string swapwords(string str, float i, float j)
1504 {
1505         float n;
1506         string s1, s2, s3, s4, s5;
1507         float si, ei, sj, ej, s0, en;
1508         n = tokenizebyseparator(str, " "); // must match g_maplist processing in ShuffleMaplist and "shuffle"
1509         si = argv_start_index(i);
1510         sj = argv_start_index(j);
1511         ei = argv_end_index(i);
1512         ej = argv_end_index(j);
1513         s0 = argv_start_index(0);
1514         en = argv_end_index(n-1);
1515         s1 = substring_range(str, s0, si);
1516         s2 = substring_range(str, si, ei);
1517         s3 = substring_range(str, ei, sj);
1518         s4 = substring_range(str, sj, ej);
1519         s5 = substring_range(str, ej, en);
1520         return strcat(s1, s4, s3, s2, s5);
1521 }
1522
1523 string _shufflewords_str;
1524 void _shufflewords_swapfunc(float i, float j, entity pass)
1525 {
1526         _shufflewords_str = swapwords(_shufflewords_str, i, j);
1527 }
1528 string shufflewords(string str)
1529 {
1530         float n;
1531         _shufflewords_str = str;
1532         n = tokenizebyseparator(str, " ");
1533         shuffle(n, _shufflewords_swapfunc, world);
1534         str = _shufflewords_str;
1535         _shufflewords_str = string_null;
1536         return str;
1537 }
1538
1539 vector solve_quadratic(float a, float b, float c) // ax^2 + bx + c = 0
1540 {
1541         vector v;
1542         float D;
1543         v = '0 0 0';
1544         if(a == 0)
1545         {
1546                 if(b != 0)
1547                 {
1548                         v_x = v_y = -c / b;
1549                         v_z = 1;
1550                 }
1551                 else
1552                 {
1553                         if(c == 0)
1554                         {
1555                                 // actually, every number solves the equation!
1556                                 v_z = 1;
1557                         }
1558                 }
1559         }
1560         else
1561         {
1562                 D = b*b - 4*a*c;
1563                 if(D >= 0)
1564                 {
1565                         D = sqrt(D);
1566                         if(a > 0) // put the smaller solution first
1567                         {
1568                                 v_x = ((-b)-D) / (2*a);
1569                                 v_y = ((-b)+D) / (2*a);
1570                         }
1571                         else
1572                         {
1573                                 v_x = (-b+D) / (2*a);
1574                                 v_y = (-b-D) / (2*a);
1575                         }
1576                         v_z = 1;
1577                 }
1578                 else
1579                 {
1580                         // complex solutions!
1581                         D = sqrt(-D);
1582                         v_x = -b / (2*a);
1583                         if(a > 0)
1584                                 v_y =  D / (2*a);
1585                         else
1586                                 v_y = -D / (2*a);
1587                         v_z = 0;
1588                 }
1589         }
1590         return v;
1591 }
1592
1593 void check_unacceptable_compiler_bugs()
1594 {
1595         if(cvar("_allow_unacceptable_compiler_bugs"))
1596                 return;
1597         tokenize_console("foo bar");
1598         if(strcat(argv(0), substring("foo bar", 4, 7 - argv_start_index(1))) == "barbar")
1599                 error("fteqcc bug introduced with revision 3178 detected. Please upgrade fteqcc to a later revision, downgrade fteqcc to revision 3177, or pester Spike until he fixes it. You can set _allow_unacceptable_compiler_bugs 1 to skip this check, but expect stuff to be horribly broken then.");
1600
1601         string s = "";
1602         if not(s)
1603                 error("The empty string counts as false. We do not want that!");
1604 }
1605
1606 float compressShotOrigin(vector v)
1607 {
1608         float x, y, z;
1609         x = rint(v_x * 2);
1610         y = rint(v_y * 4) + 128;
1611         z = rint(v_z * 4) + 128;
1612         if(x > 255 || x < 0)
1613         {
1614                 print("shot origin ", vtos(v), " x out of bounds\n");
1615                 x = bound(0, x, 255);
1616         }
1617         if(y > 255 || y < 0)
1618         {
1619                 print("shot origin ", vtos(v), " y out of bounds\n");
1620                 y = bound(0, y, 255);
1621         }
1622         if(z > 255 || z < 0)
1623         {
1624                 print("shot origin ", vtos(v), " z out of bounds\n");
1625                 z = bound(0, z, 255);
1626         }
1627         return x * 0x10000 + y * 0x100 + z;
1628 }
1629 vector decompressShotOrigin(float f)
1630 {
1631         vector v;
1632         v_x = ((f & 0xFF0000) / 0x10000) / 2;
1633         v_y = ((f & 0xFF00) / 0x100 - 128) / 4;
1634         v_z = ((f & 0xFF) - 128) / 4;
1635         return v;
1636 }
1637
1638 void heapsort(float n, swapfunc_t swap, comparefunc_t cmp, entity pass)
1639 {
1640         float start, end, root, child;
1641
1642         // heapify
1643         start = floor((n - 2) / 2);
1644         while(start >= 0)
1645         {
1646                 // siftdown(start, count-1);
1647                 root = start;
1648                 while(root * 2 + 1 <= n-1)
1649                 {
1650                         child = root * 2 + 1;
1651                         if(child < n-1)
1652                                 if(cmp(child, child+1, pass) < 0)
1653                                         ++child;
1654                         if(cmp(root, child, pass) < 0)
1655                         {
1656                                 swap(root, child, pass);
1657                                 root = child;
1658                         }
1659                         else
1660                                 break;
1661                 }
1662                 // end of siftdown
1663                 --start;
1664         }
1665
1666         // extract
1667         end = n - 1;
1668         while(end > 0)
1669         {
1670                 swap(0, end, pass);
1671                 --end;
1672                 // siftdown(0, end);
1673                 root = 0;
1674                 while(root * 2 + 1 <= end)
1675                 {
1676                         child = root * 2 + 1;
1677                         if(child < end && cmp(child, child+1, pass) < 0)
1678                                 ++child;
1679                         if(cmp(root, child, pass) < 0)
1680                         {
1681                                 swap(root, child, pass);
1682                                 root = child;
1683                         }
1684                         else
1685                                 break;
1686                 }
1687                 // end of siftdown
1688         }
1689 }
1690
1691 void RandomSelection_Init()
1692 {
1693         RandomSelection_totalweight = 0;
1694         RandomSelection_chosen_ent = world;
1695         RandomSelection_chosen_float = 0;
1696         RandomSelection_chosen_string = string_null;
1697         RandomSelection_best_priority = -1;
1698 }
1699 void RandomSelection_Add(entity e, float f, string s, float weight, float priority)
1700 {
1701         if(priority > RandomSelection_best_priority)
1702         {
1703                 RandomSelection_best_priority = priority;
1704                 RandomSelection_chosen_ent = e;
1705                 RandomSelection_chosen_float = f;
1706                 RandomSelection_chosen_string = s;
1707                 RandomSelection_totalweight = weight;
1708         }
1709         else if(priority == RandomSelection_best_priority)
1710         {
1711                 RandomSelection_totalweight += weight;
1712                 if(random() * RandomSelection_totalweight <= weight)
1713                 {
1714                         RandomSelection_chosen_ent = e;
1715                         RandomSelection_chosen_float = f;
1716                         RandomSelection_chosen_string = s;
1717                 }
1718         }
1719 }
1720
1721 vector healtharmor_maxdamage(float h, float a, float armorblock)
1722 {
1723         // NOTE: we'll always choose the SMALLER value...
1724         float healthdamage, armordamage, armorideal;
1725         vector v;
1726         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1727         armordamage = a + (h - 1); // damage we can take if we could use more armor
1728         armorideal = healthdamage * armorblock;
1729         v_y = armorideal;
1730         if(armordamage < healthdamage)
1731         {
1732                 v_x = armordamage;
1733                 v_z = 1;
1734         }
1735         else
1736         {
1737                 v_x = healthdamage;
1738                 v_z = 0;
1739         }
1740         return v;
1741 }
1742
1743 vector healtharmor_applydamage(float a, float armorblock, float damage)
1744 {
1745         vector v;
1746         v_y = bound(0, damage * armorblock, a); // save
1747         v_x = bound(0, damage - v_y, damage); // take
1748         v_z = 0;
1749         return v;
1750 }
1751
1752 string getcurrentmod()
1753 {
1754         float n;
1755         string m;
1756         m = cvar_string("fs_gamedir");
1757         n = tokenize_console(m);
1758         if(n == 0)
1759                 return "data";
1760         else
1761                 return argv(n - 1);
1762 }
1763
1764 #ifndef MENUQC
1765 #ifdef CSQC
1766 float ReadInt24_t()
1767 {
1768         float v;
1769         v = ReadShort() * 256; // note: this is signed
1770         v += ReadByte(); // note: this is unsigned
1771         return v;
1772 }
1773 #else
1774 void WriteInt24_t(float dst, float val)
1775 {
1776         float v;
1777         WriteShort(dst, (v = floor(val / 256)));
1778         WriteByte(dst, val - v * 256); // 0..255
1779 }
1780 #endif
1781 #endif
1782
1783 float float2range11(float f)
1784 {
1785         // continuous function mapping all reals into -1..1
1786         return f / (fabs(f) + 1);
1787 }
1788
1789 float float2range01(float f)
1790 {
1791         // continuous function mapping all reals into 0..1
1792         return 0.5 + 0.5 * float2range11(f);
1793 }
1794
1795 // from the GNU Scientific Library
1796 float gsl_ran_gaussian_lastvalue;
1797 float gsl_ran_gaussian_lastvalue_set;
1798 float gsl_ran_gaussian(float sigma)
1799 {
1800         float a, b;
1801         if(gsl_ran_gaussian_lastvalue_set)
1802         {
1803                 gsl_ran_gaussian_lastvalue_set = 0;
1804                 return sigma * gsl_ran_gaussian_lastvalue;
1805         }
1806         else
1807         {
1808                 a = random() * 2 * M_PI;
1809                 b = sqrt(-2 * log(random()));
1810                 gsl_ran_gaussian_lastvalue = cos(a) * b;
1811                 gsl_ran_gaussian_lastvalue_set = 1;
1812                 return sigma * sin(a) * b;
1813         }
1814 }
1815
1816 string car(string s)
1817 {
1818         float o;
1819         o = strstrofs(s, " ", 0);
1820         if(o < 0)
1821                 return s;
1822         return substring(s, 0, o);
1823 }
1824 string cdr(string s)
1825 {
1826         float o;
1827         o = strstrofs(s, " ", 0);
1828         if(o < 0)
1829                 return string_null;
1830         return substring(s, o + 1, strlen(s) - (o + 1));
1831 }
1832 float matchacl(string acl, string str)
1833 {
1834         string t, s;
1835         float r, d;
1836         r = 0;
1837         while(acl)
1838         {
1839                 t = car(acl); acl = cdr(acl);
1840                 d = 1;
1841                 if(substring(t, 0, 1) == "-")
1842                 {
1843                         d = -1;
1844                         t = substring(t, 1, strlen(t) - 1);
1845                 }
1846                 else if(substring(t, 0, 1) == "+")
1847                         t = substring(t, 1, strlen(t) - 1);
1848                 if(substring(t, -1, 1) == "*")
1849                 {
1850                         t = substring(t, 0, strlen(t) - 1);
1851                         s = substring(s, 0, strlen(t));
1852                 }
1853                 else
1854                         s = str;
1855
1856                 if(s == t)
1857                 {
1858                         r = d;
1859                 }
1860         }
1861         return r;
1862 }
1863 float startsWith(string haystack, string needle)
1864 {
1865         return substring(haystack, 0, strlen(needle)) == needle;
1866 }
1867 float startsWithNocase(string haystack, string needle)
1868 {
1869         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
1870 }
1871
1872 string get_model_datafilename(string m, float sk, string fil)
1873 {
1874         if(m)
1875                 m = strcat(m, "_");
1876         else
1877                 m = "models/player/*_";
1878         if(sk >= 0)
1879                 m = strcat(m, ftos(sk));
1880         else
1881                 m = strcat(m, "*");
1882         return strcat(m, ".", fil);
1883 }
1884
1885 float get_model_parameters(string m, float sk)
1886 {
1887         string fn, s, c;
1888         float fh;
1889
1890         get_model_parameters_modelname = string_null;
1891         get_model_parameters_modelskin = -1;
1892         get_model_parameters_name = string_null;
1893         get_model_parameters_species = -1;
1894         get_model_parameters_sex = string_null;
1895         get_model_parameters_weight = -1;
1896         get_model_parameters_age = -1;
1897         get_model_parameters_desc = string_null;
1898
1899         if not(m)
1900                 return 1;
1901         if(sk < 0)
1902         {
1903                 if(substring(m, -4, -1) != ".txt")
1904                         return 0;
1905                 if(substring(m, -6, 1) != "_")
1906                         return 0;
1907                 sk = stof(substring(m, -5, 1));
1908                 m = substring(m, 0, -7);
1909         }
1910
1911         fn = get_model_datafilename(m, sk, "txt");
1912         fh = fopen(fn, FILE_READ);
1913         if(fh < 0)
1914         {
1915                 sk = 0;
1916                 fn = get_model_datafilename(m, sk, "txt");
1917                 fh = fopen(fn, FILE_READ);
1918                 if(fh < 0)
1919                         return 0;
1920         }
1921
1922         get_model_parameters_modelname = m;
1923         get_model_parameters_modelskin = sk;
1924         while((s = fgets(fh)))
1925         {
1926                 if(s == "")
1927                         break; // next lines will be description
1928                 c = car(s);
1929                 s = cdr(s);
1930                 if(c == "name")
1931                         get_model_parameters_name = s;
1932                 if(c == "species")
1933                         switch(s)
1934                         {
1935                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1936                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1937                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1938                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1939                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1940                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1941                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1942                         }
1943                 if(c == "sex")
1944                         get_model_parameters_sex = s;
1945                 if(c == "weight")
1946                         get_model_parameters_weight = stof(s);
1947                 if(c == "age")
1948                         get_model_parameters_age = stof(s);
1949         }
1950
1951         while((s = fgets(fh)))
1952         {
1953                 if(get_model_parameters_desc)
1954                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1955                 if(s != "")
1956                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1957         }
1958
1959         fclose(fh);
1960
1961         return 1;
1962 }
1963
1964 vector vec2(vector v)
1965 {
1966         v_z = 0;
1967         return v;
1968 }
1969
1970 #ifndef MENUQC
1971 vector NearestPointOnBox(entity box, vector org)
1972 {
1973         vector m1, m2, nearest;
1974
1975         m1 = box.mins + box.origin;
1976         m2 = box.maxs + box.origin;
1977
1978         nearest_x = bound(m1_x, org_x, m2_x);
1979         nearest_y = bound(m1_y, org_y, m2_y);
1980         nearest_z = bound(m1_z, org_z, m2_z);
1981
1982         return nearest;
1983 }
1984 #endif
1985
1986 float vercmp_recursive(string v1, string v2)
1987 {
1988         float dot1, dot2;
1989         string s1, s2;
1990         float r;
1991
1992         dot1 = strstrofs(v1, ".", 0);
1993         dot2 = strstrofs(v2, ".", 0);
1994         if(dot1 == -1)
1995                 s1 = v1;
1996         else
1997                 s1 = substring(v1, 0, dot1);
1998         if(dot2 == -1)
1999                 s2 = v2;
2000         else
2001                 s2 = substring(v2, 0, dot2);
2002
2003         r = stof(s1) - stof(s2);
2004         if(r != 0)
2005                 return r;
2006
2007         r = strcasecmp(s1, s2);
2008         if(r != 0)
2009                 return r;
2010
2011         if(dot1 == -1)
2012                 if(dot2 == -1)
2013                         return 0;
2014                 else
2015                         return -1;
2016         else
2017                 if(dot2 == -1)
2018                         return 1;
2019                 else
2020                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2021 }
2022
2023 float vercmp(string v1, string v2)
2024 {
2025         if(strcasecmp(v1, v2) == 0) // early out check
2026                 return 0;
2027
2028         // "git" beats all
2029         if(v1 == "git")
2030                 return 1;
2031         if(v2 == "git")
2032                 return -1;
2033
2034         return vercmp_recursive(v1, v2);
2035 }
2036
2037 float u8_strsize(string s)
2038 {
2039         float l, i, c;
2040         l = 0;
2041         for(i = 0; ; ++i)
2042         {
2043                 c = str2chr(s, i);
2044                 if(c <= 0)
2045                         break;
2046                 ++l;
2047                 if(c >= 0x80)
2048                         ++l;
2049                 if(c >= 0x800)
2050                         ++l;
2051                 if(c >= 0x10000)
2052                         ++l;
2053         }
2054         return l;
2055 }
2056
2057 // translation helpers
2058 string language_filename(string s)
2059 {
2060         string fn;
2061         float fh;
2062         fn = prvm_language;
2063         if(fn == "" || fn == "dump")
2064                 return s;
2065         fn = strcat(s, ".", fn);
2066         if((fh = fopen(fn, FILE_READ)) >= 0)
2067         {
2068                 fclose(fh);
2069                 return fn;
2070         }
2071         return s;
2072 }
2073 string CTX(string s)
2074 {
2075         float p = strstrofs(s, "^", 0);
2076         if(p < 0)
2077                 return s;
2078         return substring(s, p+1, -1);
2079 }
2080
2081 // x-encoding (encoding as zero length invisible string)
2082 const string XENCODE_2  = "xX";
2083 const string XENCODE_22 = "0123456789abcdefABCDEF";
2084 string xencode(float f)
2085 {
2086         float a, b, c, d;
2087         d = mod(f, 22); f = floor(f / 22);
2088         c = mod(f, 22); f = floor(f / 22);
2089         b = mod(f, 22); f = floor(f / 22);
2090         a = mod(f,  2); // f = floor(f /  2);
2091         return strcat(
2092                 "^",
2093                 substring(XENCODE_2,  a, 1),
2094                 substring(XENCODE_22, b, 1),
2095                 substring(XENCODE_22, c, 1),
2096                 substring(XENCODE_22, d, 1)
2097         );
2098 }
2099 float xdecode(string s)
2100 {
2101         float a, b, c, d;
2102         if(substring(s, 0, 1) != "^")
2103                 return -1;
2104         if(strlen(s) < 5)
2105                 return -1;
2106         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
2107         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
2108         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
2109         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
2110         if(a < 0 || b < 0 || c < 0 || d < 0)
2111                 return -1;
2112         return ((a * 22 + b) * 22 + c) * 22 + d;
2113 }
2114
2115 float lowestbit(float f)
2116 {
2117         f &~= f * 2;
2118         f &~= f * 4;
2119         f &~= f * 16;
2120         f &~= f * 256;
2121         f &~= f * 65536;
2122         return f;
2123 }
2124
2125 /*
2126 string strlimitedlen(string input, string truncation, float strip_colors, float limit)
2127 {
2128         if(strlen((strip_colors ? strdecolorize(input) : input)) <= limit)
2129                 return input;
2130         else
2131                 return strcat(substring(input, 0, (strlen(input) - strlen(truncation))), truncation);
2132 }*/
2133
2134 // escape the string to make it safe for consoles
2135 string MakeConsoleSafe(string input)
2136 {
2137         input = strreplace("\n", "", input);
2138         input = strreplace("\\", "\\\\", input);
2139         input = strreplace("$", "$$", input);
2140         input = strreplace("\"", "\\\"", input);
2141         return input;
2142 }
2143
2144 #ifndef MENUQC
2145 // get true/false value of a string with multiple different inputs
2146 float InterpretBoolean(string input)
2147 {
2148         switch(strtolower(input))
2149         {
2150                 case "yes":
2151                 case "true":
2152                 case "on":
2153                         return TRUE;
2154
2155                 case "no":
2156                 case "false":
2157                 case "off":
2158                         return FALSE;
2159
2160                 default: return stof(input);
2161         }
2162 }
2163 #endif
2164
2165 #ifdef CSQC
2166 entity ReadCSQCEntity()
2167 {
2168         float f;
2169         f = ReadShort();
2170         if(f == 0)
2171                 return world;
2172         return findfloat(world, entnum, f);
2173 }
2174 #endif
2175
2176 float shutdown_running;
2177 #ifdef SVQC
2178 void SV_Shutdown()
2179 #endif
2180 #ifdef CSQC
2181 void CSQC_Shutdown()
2182 #endif
2183 #ifdef MENUQC
2184 void m_shutdown()
2185 #endif
2186 {
2187         if(shutdown_running)
2188         {
2189                 print("Recursive shutdown detected! Only restoring cvars...\n");
2190         }
2191         else
2192         {
2193                 shutdown_running = 1;
2194                 Shutdown();
2195         }
2196         cvar_settemp_restore(); // this must be done LAST, but in any case
2197 }
2198
2199 #define APPROXPASTTIME_ACCURACY_REQUIREMENT 0.05
2200 #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
2201 #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
2202 // this will use the value:
2203 //   128
2204 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
2205 // accuracy at x is 1/derivative, i.e.
2206 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
2207 #ifdef SVQC
2208 void WriteApproxPastTime(float dst, float t)
2209 {
2210         float dt = time - t;
2211
2212         // warning: this is approximate; do not resend when you don't have to!
2213         // be careful with sendflags here!
2214         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
2215
2216         // map to range...
2217         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
2218
2219         // round...
2220         dt = rint(bound(0, dt, 255));
2221
2222         WriteByte(dst, dt);
2223 }
2224 #endif
2225 #ifdef CSQC
2226 float ReadApproxPastTime()
2227 {
2228         float dt = ReadByte();
2229
2230         // map from range...PPROXPASTTIME_MAX / 256
2231         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
2232
2233         return servertime - dt;
2234 }
2235 #endif
2236
2237 #ifndef MENUQC
2238 .float skeleton_bones_index;
2239 void Skeleton_SetBones(entity e)
2240 {
2241         // set skeleton_bones to the total number of bones on the model
2242         if(e.skeleton_bones_index == e.modelindex)
2243                 return; // same model, nothing to update
2244
2245         float skelindex;
2246         skelindex = skel_create(e.modelindex);
2247         e.skeleton_bones = skel_get_numbones(skelindex);
2248         skel_delete(skelindex);
2249         e.skeleton_bones_index = e.modelindex;
2250 }
2251 #endif
2252
2253 string to_execute_next_frame;
2254 void execute_next_frame()
2255 {
2256         if(to_execute_next_frame)
2257         {
2258                 localcmd("\n", to_execute_next_frame, "\n");
2259                 strunzone(to_execute_next_frame);
2260                 to_execute_next_frame = string_null;
2261         }
2262 }
2263 void queue_to_execute_next_frame(string s)
2264 {
2265         if(to_execute_next_frame)
2266         {
2267                 s = strcat(s, "\n", to_execute_next_frame);
2268                 strunzone(to_execute_next_frame);
2269         }
2270         to_execute_next_frame = strzone(s);
2271 }