qcsrc/common/vehicles/unit/racer.qc

   1 #ifndef VEHICLE_RACER
   2 #define VEHICLE_RACER
   3
   4 #ifndef MENUQC
   5 int v_racer(int);
   6 #endif
   7 REGISTER_VEHICLE_SIMPLE(
   8 /* VEH_##id   */ RACER,
   9 /* spawnflags */ VHF_DMGSHAKE | VHF_DMGROLL,
  10 /* mins,maxs  */ '-120 -120 -40' * 0.5, '120 120 40' * 0.5,
  11 /* model          */ "models/vehicles/wakizashi.dpm",
  12 /* head_model */ "null",
  13 /* hud_model  */ "models/vehicles/wakizashi_cockpit.dpm",
  14 /* tags           */ "", "", "tag_viewport",
  15 /* netname        */ "racer",
  16 /* fullname   */ _("Racer")
  17 ) {
  18     this.m_icon = "vehicle_racer";
  19 #ifndef MENUQC
  20     this.vehicle_func = v_racer;
  21 #endif
  22 }
  23
  24 #include "../../weapons/all.qh"
  25
  26 CLASS(RacerAttack, PortoLaunch)
  27 /* flags     */ ATTRIB(RacerAttack, spawnflags, int, WEP_TYPE_OTHER);
  28 /* impulse   */ ATTRIB(RacerAttack, impulse, int, 3);
  29 /* refname   */ ATTRIB(RacerAttack, netname, string, "racercannon");
  30 /* wepname   */ ATTRIB(RacerAttack, message, string, _("Racer cannon"));
  31 ENDCLASS(RacerAttack)
  32 REGISTER_WEAPON(RACER, NEW(RacerAttack));
  33
  34 #endif
  35
  36 #ifdef IMPLEMENTATION
  37 #ifdef SVQC
  38 #include "../../effects/effects.qh"
  39 #include "../../triggers/trigger/impulse.qh"
  40
  41 void racer_fire_cannon(string tagname);
  42 METHOD(RacerAttack, wr_think, bool(entity thiswep)) {
  43         SELFPARAM();
  44         if (self.BUTTON_ATCK)
  45         if (weapon_prepareattack(0, 0)) {
  46                 W_SetupShot_Dir(self, v_forward, false, 0, W_Sound("lasergun_fire"), CH_WEAPON_B, 0);
  47                 racer_fire_cannon("tag_fire1");
  48                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(machinegun, sustained_refire), w_ready);
  49         }
  50         return true;
  51 }
  52
  53 bool autocvar_g_vehicle_racer;
  54
  55 float autocvar_g_vehicle_racer_speed_afterburn;
  56 float autocvar_g_vehicle_racer_afterburn_cost;
  57
  58 float autocvar_g_vehicle_racer_waterburn_cost;
  59 float autocvar_g_vehicle_racer_waterburn_speed;
  60
  61 float autocvar_g_vehicle_racer_water_speed_forward;
  62 float autocvar_g_vehicle_racer_water_speed_strafe;
  63
  64 float autocvar_g_vehicle_racer_pitchlimit = 30;
  65
  66 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  67 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  68
  69 float autocvar_g_vehicle_racer_anglestabilizer;
  70 float autocvar_g_vehicle_racer_downforce;
  71
  72 float autocvar_g_vehicle_racer_speed_forward;
  73 float autocvar_g_vehicle_racer_speed_strafe;
  74 float autocvar_g_vehicle_racer_springlength;
  75 float autocvar_g_vehicle_racer_upforcedamper;
  76 float autocvar_g_vehicle_racer_friction;
  77
  78 float autocvar_g_vehicle_racer_water_time = 5;
  79
  80 float autocvar_g_vehicle_racer_hovertype;
  81 float autocvar_g_vehicle_racer_hoverpower;
  82
  83 float autocvar_g_vehicle_racer_turnroll;
  84 float autocvar_g_vehicle_racer_turnspeed;
  85 float autocvar_g_vehicle_racer_pitchspeed;
  86
  87 float autocvar_g_vehicle_racer_energy;
  88 float autocvar_g_vehicle_racer_energy_regen;
  89 float autocvar_g_vehicle_racer_energy_regen_pause;
  90
  91 float autocvar_g_vehicle_racer_health;
  92 float autocvar_g_vehicle_racer_health_regen;
  93 float autocvar_g_vehicle_racer_health_regen_pause;
  94
  95 float autocvar_g_vehicle_racer_shield;
  96 float autocvar_g_vehicle_racer_shield_regen;
  97 float autocvar_g_vehicle_racer_shield_regen_pause;
  98
  99 float autocvar_g_vehicle_racer_cannon_cost;
 100 float autocvar_g_vehicle_racer_cannon_damage;
 101 float autocvar_g_vehicle_racer_cannon_radius;
 102 float autocvar_g_vehicle_racer_cannon_refire;
 103 float autocvar_g_vehicle_racer_cannon_speed;
 104 float autocvar_g_vehicle_racer_cannon_spread;
 105 float autocvar_g_vehicle_racer_cannon_force;
 106
 107 float autocvar_g_vehicle_racer_rocket_accel;
 108 float autocvar_g_vehicle_racer_rocket_damage;
 109 float autocvar_g_vehicle_racer_rocket_radius;
 110 float autocvar_g_vehicle_racer_rocket_force;
 111 float autocvar_g_vehicle_racer_rocket_refire;
 112 float autocvar_g_vehicle_racer_rocket_speed;
 113 float autocvar_g_vehicle_racer_rocket_turnrate;
 114
 115 float autocvar_g_vehicle_racer_rocket_locktarget;
 116 float autocvar_g_vehicle_racer_rocket_locking_time;
 117 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
 118 float autocvar_g_vehicle_racer_rocket_locked_time;
 119 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
 120 float autocvar_g_vehicle_racer_rocket_climbspeed;
 121
 122 float autocvar_g_vehicle_racer_respawntime;
 123
 124 float autocvar_g_vehicle_racer_blowup_radius;
 125 float autocvar_g_vehicle_racer_blowup_coredamage;
 126 float autocvar_g_vehicle_racer_blowup_edgedamage;
 127 float autocvar_g_vehicle_racer_blowup_forceintensity;
 128
 129 float autocvar_g_vehicle_racer_bouncefactor;
 130 float autocvar_g_vehicle_racer_bouncestop;
 131 vector autocvar_g_vehicle_racer_bouncepain;
 132
 133 .float racer_watertime;
 134
 135 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
 136
 137 void racer_align4point(float _delta)
 138 {SELFPARAM();
 139         vector push_vector;
 140         float fl_push, fr_push, bl_push, br_push;
 141
 142         push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 143         fr_push   = force_fromtag_normpower;
 144         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 145
 146         push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 147         fl_push   = force_fromtag_normpower;
 148         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 149
 150         push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 151         br_push   = force_fromtag_normpower;
 152         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 153
 154         push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 155         bl_push   = force_fromtag_normpower;
 156         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 157
 158         self.velocity += push_vector * _delta;
 159
 160         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 161
 162         int cont = pointcontents(self.origin - '0 0 64');
 163         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 164         {
 165                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 166
 167                 if(self.owner.BUTTON_CROUCH && time < self.air_finished)
 168                         self.velocity_z += 30;
 169                 else
 170                         self.velocity_z += 200;
 171         }
 172
 173
 174         // Anti ocilation
 175         if(self.velocity_z > 0)
 176                 self.velocity_z *= 1 - uforce * _delta;
 177
 178         push_vector_x =  (fl_push - bl_push);
 179         push_vector_x += (fr_push - br_push);
 180         push_vector_x *= 360;
 181
 182         push_vector_z = (fr_push - fl_push);
 183         push_vector_z += (br_push - bl_push);
 184         push_vector_z *= 360;
 185
 186         // Apply angle diffrance
 187         self.angles_z += push_vector_z * _delta;
 188         self.angles_x += push_vector_x * _delta;
 189
 190         // Apply stabilizer
 191         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 192         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 193 }
 194
 195 void racer_fire_cannon(string tagname)
 196 {SELFPARAM();
 197         vector v;
 198         entity bolt;
 199
 200         v = gettaginfo(self, gettagindex(self, tagname));
 201         bolt = vehicles_projectile(EFFECT_RACER_MUZZLEFLASH.eent_eff_name, SND(LASERGUN_FIRE),
 202                                                    v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 203                                                    autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 204                                                    DEATH_VH_WAKI_GUN, PROJECTILE_WAKICANNON, 0, true, true, self.owner);
 205
 206         // Fix z-aim (for chase mode)
 207         v = normalize(trace_endpos - bolt.origin);
 208         v_forward_z = v_z * 0.5;
 209         bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 210 }
 211
 212 void racer_rocket_groundhugger()
 213 {SELFPARAM();
 214         vector olddir, newdir;
 215         float oldvel, newvel;
 216
 217         self.nextthink  = time;
 218
 219         if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 220         {
 221                 self.use();
 222                 return;
 223         }
 224
 225         if(!self.realowner.vehicle)
 226         {
 227                 UpdateCSQCProjectile(self);
 228                 return;
 229         }
 230
 231         olddir = normalize(self.velocity);
 232         oldvel = vlen(self.velocity);
 233         newvel = oldvel + self.lip;
 234
 235         tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 236         if(trace_fraction <= 0.5)
 237         {
 238                 // Hitting somethign soon, just speed ahead
 239                 self.velocity = olddir * newvel;
 240                 UpdateCSQCProjectile(self);
 241                 return;
 242         }
 243
 244         traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 245         if(trace_fraction != 1.0)
 246         {
 247                 newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 248                 self.velocity = normalize(olddir + newdir) * newvel;
 249         }
 250         else
 251         {
 252                 self.velocity = olddir * newvel;
 253                 self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 254         }
 255
 256         int cont = pointcontents(self.origin - '0 0 32');
 257         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 258                 self.velocity_z += 200;
 259
 260         UpdateCSQCProjectile(self);
 261         return;
 262 }
 263
 264 void racer_rocket_tracker()
 265 {SELFPARAM();
 266         vector olddir, newdir;
 267         float oldvel, newvel;
 268
 269         self.nextthink  = time;
 270
 271         if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 272         {
 273                 self.use();
 274                 return;
 275         }
 276
 277         if(!self.realowner.vehicle)
 278         {
 279                 UpdateCSQCProjectile(self);
 280                 return;
 281         }
 282
 283         olddir = normalize(self.velocity);
 284         oldvel = vlen(self.velocity);
 285         newvel = oldvel + self.lip;
 286         makevectors(vectoangles(olddir));
 287
 288         float time_to_impact = min(vlen(self.enemy.origin - self.origin) / vlen(self.velocity), 1);
 289         vector predicted_origin = self.enemy.origin + self.enemy.velocity * time_to_impact;
 290
 291         traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 292         newdir = normalize(predicted_origin - self.origin);
 293
 294         //vector
 295         float height_diff = predicted_origin_z - self.origin_z;
 296
 297         if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 298         {
 299                 //bprint("Target lost!\n");
 300                 //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 301                 self.think = racer_rocket_groundhugger;
 302                 return;
 303         }
 304
 305         if(trace_fraction != 1.0 && trace_ent != self.enemy)
 306                 newdir_z += 16 * sys_frametime;
 307
 308         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 309         self.velocity_z -= 800 * sys_frametime;
 310         self.velocity_z += max(height_diff, autocvar_g_vehicle_racer_rocket_climbspeed) * sys_frametime ;
 311
 312         UpdateCSQCProjectile(self);
 313         return;
 314 }
 315
 316 void racer_fire_rocket(string tagname, entity trg)
 317 {SELFPARAM();
 318         vector v = gettaginfo(self, gettagindex(self, tagname));
 319         entity rocket = vehicles_projectile(EFFECT_RACER_ROCKETLAUNCH.eent_eff_name, SND(ROCKET_FIRE),
 320                                                    v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 321                                                    autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 322                                                    DEATH_VH_WAKI_ROCKET, PROJECTILE_WAKIROCKET, 20, false, false, self.owner);
 323
 324         rocket.lip                        = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 325         rocket.wait                      = autocvar_g_vehicle_racer_rocket_turnrate;
 326         rocket.nextthink                = time;
 327         rocket.enemy                    = trg;
 328         rocket.cnt                        = time + 15;
 329
 330         if(trg)
 331                 rocket.think                    = racer_rocket_tracker;
 332         else
 333                 rocket.think                    = racer_rocket_groundhugger;
 334 }
 335
 336 float racer_frame()
 337 {SELFPARAM();
 338         entity player, racer;
 339         vector df;
 340         float ftmp;
 341
 342         if(intermission_running)
 343         {
 344                 self.vehicle.velocity = '0 0 0';
 345                 self.vehicle.avelocity = '0 0 0';
 346                 return 1;
 347         }
 348
 349         player  = self;
 350         racer   = self.vehicle;
 351         setself(racer);
 352
 353         vehicles_painframe();
 354
 355         if(pointcontents(racer.origin) != CONTENT_WATER)
 356                 racer.air_finished = time + autocvar_g_vehicle_racer_water_time;
 357
 358         if(racer.deadflag != DEAD_NO)
 359         {
 360                 setself(player);
 361                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 362                 return 1;
 363         }
 364
 365         racer_align4point(PHYS_INPUT_TIMELENGTH);
 366
 367         player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 368
 369         crosshair_trace(player);
 370
 371         racer.angles_x *= -1;
 372
 373         // Yaw
 374         ftmp = autocvar_g_vehicle_racer_turnspeed * PHYS_INPUT_TIMELENGTH;
 375         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 376         racer.angles_y = anglemods(racer.angles_y + ftmp);
 377
 378         // Roll
 379         racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * PHYS_INPUT_TIMELENGTH;
 380
 381         // Pitch
 382         ftmp = autocvar_g_vehicle_racer_pitchspeed  * PHYS_INPUT_TIMELENGTH;
 383         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 384         racer.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(racer.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 385
 386         makevectors(racer.angles);
 387         racer.angles_x *= -1;
 388
 389         //ftmp = racer.velocity_z;
 390         df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 391         //racer.velocity_z = ftmp;
 392
 393         int cont = pointcontents(racer.origin);
 394         if(vlen(player.movement) != 0)
 395         {
 396                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 397                 {
 398                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 399                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 400                 }
 401                 else
 402                 {
 403                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 404                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 405                 }
 406
 407 #ifdef SVQC
 408                 if(self.sound_nexttime < time || self.sounds != 1)
 409                 {
 410                         self.sounds = 1;
 411                         self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 412                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 413                 }
 414 #endif
 415         }
 416 #ifdef SVQC
 417         else
 418         {
 419                 if(self.sound_nexttime < time || self.sounds != 0)
 420                 {
 421                         self.sounds = 0;
 422                         self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 423                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 424                 }
 425         }
 426 #endif
 427
 428         // Afterburn
 429         if (PHYS_INPUT_BUTTON_JUMP(player) && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH))
 430         {
 431 #ifdef SVQC
 432                 if(time - racer.wait > 0.2)
 433                         pointparticles(particleeffectnum(EFFECT_RACER_BOOSTER), self.origin - v_forward * 32, v_forward  * vlen(self.velocity), 1);
 434 #endif
 435
 436                 racer.wait = time;
 437
 438                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 439                 {
 440                         racer.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * PHYS_INPUT_TIMELENGTH;
 441                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 442                 }
 443                 else
 444                 {
 445                         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH;
 446                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 447                 }
 448
 449 #ifdef SVQC
 450                 if(racer.invincible_finished < time)
 451                 {
 452                         traceline(racer.origin, racer.origin - '0 0 256', MOVE_NORMAL, self);
 453                         if(trace_fraction != 1.0)
 454                                 pointparticles(particleeffectnum(EFFECT_SMOKE_SMALL), trace_endpos, '0 0 0', 1);
 455
 456                         racer.invincible_finished = time + 0.1 + (random() * 0.1);
 457                 }
 458
 459                 if(racer.strength_finished < time)
 460                 {
 461                         racer.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 462                         sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 463                 }
 464 #endif
 465         }
 466         else
 467         {
 468                 racer.strength_finished = 0;
 469                 sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 470         }
 471
 472         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 473                 racer.racer_watertime = time;
 474
 475         float dforce = autocvar_g_vehicle_racer_downforce;
 476         if(time - racer.racer_watertime <= 3)
 477                 dforce = autocvar_g_vehicle_racer_water_downforce;
 478
 479         df -= v_up * (vlen(racer.velocity) * dforce);
 480         player.movement = racer.velocity += df * PHYS_INPUT_TIMELENGTH;
 481
 482 #ifdef SVQC
 483         if(!forbidWeaponUse(player))
 484         if(player.BUTTON_ATCK)
 485         if(time > racer.attack_finished_single)
 486         if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 487         {
 488                 racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 489                 racer.wait = time;
 490
 491                 crosshair_trace(player);
 492                 if(racer.cnt)
 493                 {
 494                         racer_fire_cannon("tag_fire1");
 495                         racer.cnt = 0;
 496                 }
 497                 else
 498                 {
 499                         racer_fire_cannon("tag_fire2");
 500                         racer.cnt = 1;
 501                 }
 502                 racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 503         }
 504
 505         if(autocvar_g_vehicle_racer_rocket_locktarget)
 506         {
 507                 vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 508                                                  (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 509                                                  autocvar_g_vehicle_racer_rocket_locked_time);
 510
 511                 if(self.lock_target)
 512                 {
 513                         if(racer.lock_strength == 1)
 514                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 515                         else if(self.lock_strength > 0.5)
 516                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 517                         else if(self.lock_strength < 0.5)
 518                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 519                 }
 520         }
 521
 522         if(!forbidWeaponUse(player))
 523         if(time > racer.delay)
 524         if(player.BUTTON_ATCK2)
 525         {
 526                 racer.misc_bulletcounter += 1;
 527                 racer.delay = time + 0.3;
 528
 529                 if(racer.misc_bulletcounter == 1)
 530                 {
 531                         racer_fire_rocket("tag_rocket_r", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 532                         player.vehicle_ammo2 = 50;
 533                 }
 534                 else if(racer.misc_bulletcounter == 2)
 535                 {
 536                         racer_fire_rocket("tag_rocket_l", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 537                         racer.lock_strength  = 0;
 538                         racer.lock_target       = world;
 539                         racer.misc_bulletcounter = 0;
 540                         racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 541                         racer.lip = time;
 542                         player.vehicle_ammo2 = 0;
 543                 }
 544         }
 545         else if(racer.misc_bulletcounter == 0)
 546                 player.vehicle_ammo2 = 100;
 547
 548         player.vehicle_reload2 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 549
 550         if(racer.vehicle_flags  & VHF_SHIELDREGEN)
 551                 vehicles_regen(racer.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime, true);
 552
 553         if(racer.vehicle_flags  & VHF_HEALTHREGEN)
 554                 vehicles_regen(racer.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime, false);
 555
 556         if(racer.vehicle_flags  & VHF_ENERGYREGEN)
 557                 vehicles_regen(racer.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime, false);
 558
 559
 560         VEHICLE_UPDATE_PLAYER(player, health, racer);
 561         VEHICLE_UPDATE_PLAYER(player, energy, racer);
 562
 563         if(racer.vehicle_flags & VHF_HASSHIELD)
 564                 VEHICLE_UPDATE_PLAYER(player, shield, racer);
 565
 566         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 567 #endif
 568
 569         setorigin(player,racer.origin + '0 0 32');
 570         player.velocity = racer.velocity;
 571
 572         setself(player);
 573         return 1;
 574 }
 575
 576 void racer_think()
 577 {SELFPARAM();
 578         self.nextthink = time;
 579
 580         float pushdeltatime = time - self.lastpushtime;
 581         if (pushdeltatime > 0.15) pushdeltatime = 0;
 582         self.lastpushtime = time;
 583         if(!pushdeltatime) return;
 584
 585         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, self);
 586
 587         vector df = self.velocity * -autocvar_g_vehicle_racer_friction;
 588         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 589
 590         float forced = autocvar_g_vehicle_racer_upforcedamper;
 591
 592         int cont = pointcontents(self.origin - '0 0 64');
 593         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 594         {
 595                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 596                 self.velocity_z += 200;
 597         }
 598
 599         self.velocity += df * pushdeltatime;
 600         if(self.velocity_z > 0)
 601                 self.velocity_z *= 1 - forced * pushdeltatime;
 602
 603         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 604         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 605
 606         CSQCMODEL_AUTOUPDATE(self);
 607 }
 608
 609 void racer_exit(float eject)
 610 {SELFPARAM();
 611         vector spot;
 612
 613         self.think        = racer_think;
 614         self.nextthink  = time;
 615         self.movetype   = MOVETYPE_BOUNCE;
 616         sound (self.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 617
 618         if(!self.owner)
 619                 return;
 620
 621         makevectors(self.angles);
 622         if(eject)
 623         {
 624                 spot = self.origin + v_forward * 100 + '0 0 64';
 625                 spot = vehicles_findgoodexit(spot);
 626                 setorigin(self.owner , spot);
 627                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 628                 self.owner.oldvelocity = self.owner.velocity;
 629         }
 630         else
 631         {
 632                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 633                 {
 634                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 635                         self.owner.velocity_z += 200;
 636                         spot = self.origin + v_forward * 32 + '0 0 32';
 637                         spot = vehicles_findgoodexit(spot);
 638                 }
 639                 else
 640                 {
 641                         self.owner.velocity = self.velocity * 0.5;
 642                         self.owner.velocity_z += 10;
 643                         spot = self.origin - v_forward * 200 + '0 0 32';
 644                         spot = vehicles_findgoodexit(spot);
 645                 }
 646                 self.owner.oldvelocity = self.owner.velocity;
 647                 setorigin(self.owner , spot);
 648         }
 649         antilag_clear(self.owner);
 650         self.owner = world;
 651 }
 652
 653 void racer_blowup()
 654 {SELFPARAM();
 655         self.deadflag   = DEAD_DEAD;
 656         self.vehicle_exit(VHEF_NORMAL);
 657
 658         RadiusDamage (self, self.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 659                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 660                                         autocvar_g_vehicle_racer_blowup_radius, world, world,
 661                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 662                                         DEATH_VH_WAKI_DEATH, world);
 663
 664         self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 665         self.think        = vehicles_spawn;
 666         self.movetype   = MOVETYPE_NONE;
 667         self.effects    = EF_NODRAW;
 668
 669         self.colormod  = '0 0 0';
 670         self.avelocity = '0 0 0';
 671         self.velocity  = '0 0 0';
 672
 673         setorigin(self, self.pos1);
 674 }
 675
 676 void racer_blowup_think()
 677 {SELFPARAM();
 678         self.nextthink = time;
 679
 680         if(time >= self.delay)
 681                 racer_blowup();
 682
 683         CSQCMODEL_AUTOUPDATE(self);
 684 }
 685
 686 void racer_deadtouch()
 687 {SELFPARAM();
 688         self.avelocity_x *= 0.7;
 689         self.cnt -= 1;
 690         if(self.cnt <= 0)
 691                 racer_blowup();
 692 }
 693
 694 void spawnfunc_vehicle_racer()
 695 {SELFPARAM();
 696         if(!autocvar_g_vehicle_racer) { remove(self); return; }
 697         if(!vehicle_initialize(VEH_RACER, false)) { remove(self); return; }
 698 }
 699
 700 #endif // SVQC
 701
 702 #ifdef CSQC
 703 #if 0
 704 void racer_draw()
 705 {SELFPARAM();
 706         float pushdeltatime = time - self.lastpushtime;
 707         if (pushdeltatime > 0.15) pushdeltatime = 0;
 708         self.lastpushtime = time;
 709         if(!pushdeltatime) return;
 710
 711         tracebox(self.move_origin, self.mins, self.maxs, self.move_origin - ('0 0 1' * getstatf(STAT_VEH_RACER_SPRINGLENGTH)), MOVE_NOMONSTERS, self);
 712
 713         vector df = self.move_velocity * -getstatf(STAT_VEH_RACER_FRICTION);
 714         df_z += (1 - trace_fraction) * getstatf(STAT_VEH_RACER_HOVERPOWER) + sin(time * 2) * (getstatf(STAT_VEH_RACER_SPRINGLENGTH) * 2);
 715
 716         float forced = getstatf(STAT_VEH_RACER_UPFORCEDAMPER);
 717
 718         int cont = pointcontents(self.move_origin - '0 0 64');
 719         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 720         {
 721                 forced = getstatf(STAT_VEH_RACER_WATER_UPFORCEDAMPER);
 722                 self.move_velocity_z += 200;
 723         }
 724
 725         self.move_velocity += df * pushdeltatime;
 726         if(self.move_velocity_z > 0)
 727                 self.move_velocity_z *= 1 - forced * pushdeltatime;
 728
 729         self.move_angles_x *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 730         self.move_angles_z *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 731
 732         Movetype_Physics_MatchServer(false);
 733 }
 734 #endif
 735 #endif
 736
 737 bool v_racer(int req)
 738 {SELFPARAM();
 739         switch(req)
 740         {
 741                 case VR_IMPACT:
 742                 {
 743                 #ifdef SVQC
 744                         if(autocvar_g_vehicle_racer_bouncepain)
 745                                 vehicles_impact(autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 746                 #endif
 747                         return true;
 748                 }
 749
 750                 case VR_ENTER:
 751                 {
 752                 #ifdef SVQC
 753                         self.movetype = MOVETYPE_BOUNCE;
 754                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 755                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 756
 757                         if(self.owner.flagcarried)
 758                            setorigin(self.owner.flagcarried, '-190 0 96');
 759                 #elif defined(CSQC)
 760
 761                         self.move_movetype = MOVETYPE_BOUNCE;
 762                 #endif
 763
 764                         return true;
 765                 }
 766
 767                 case VR_SPAWN:
 768                 {
 769                 #ifdef SVQC
 770                         if(self.scale != 0.5)
 771                         {
 772                                 if(autocvar_g_vehicle_racer_hovertype != 0)
 773                                         racer_force_from_tag = vehicles_force_fromtag_maglev;
 774                                 else
 775                                         racer_force_from_tag = vehicles_force_fromtag_hover;
 776
 777                                 // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 778                                 self.scale = 0.5;
 779                                 setattachment(self.vehicle_hudmodel, self, "");
 780                                 setattachment(self.vehicle_viewport, self, "tag_viewport");
 781
 782                                 self.mass                          = 900;
 783                         }
 784
 785                         self.think                = racer_think;
 786                         self.nextthink    = time;
 787                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 788                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 789
 790                         self.movetype     = MOVETYPE_TOSS;
 791                         self.solid                = SOLID_SLIDEBOX;
 792                         self.delay                = time;
 793                         self.scale                = 0.5;
 794
 795                         self.PlayerPhysplug = racer_frame;
 796
 797                         self.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 798                         self.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 799                         self.damageforcescale = 0.5;
 800                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 801                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 802                 #endif
 803                         return true;
 804                 }
 805
 806                 case VR_DEATH:
 807                 {
 808                 #ifdef SVQC
 809                         self.SendEntity         = func_null; // stop networking this racer (for now)
 810                         self.health                     = 0;
 811                         self.event_damage       = func_null;
 812                         self.solid                      = SOLID_CORPSE;
 813                         self.takedamage         = DAMAGE_NO;
 814                         self.deadflag           = DEAD_DYING;
 815                         self.movetype           = MOVETYPE_BOUNCE;
 816                         self.wait                       = time;
 817                         self.delay                      = 2 + time + random() * 3;
 818                         self.cnt                        = 1 + random() * 2;
 819                         self.touch                      = racer_deadtouch;
 820
 821                         Send_Effect(EFFECT_EXPLOSION_MEDIUM, self.origin, '0 0 0', 1);
 822
 823                         if(random() < 0.5)
 824                                 self.avelocity_z = 32;
 825                         else
 826                                 self.avelocity_z = -32;
 827
 828                         self.avelocity_x = -vlen(self.velocity) * 0.2;
 829                         self.velocity += '0 0 700';
 830                         self.colormod = '-0.5 -0.5 -0.5';
 831
 832                         self.think = racer_blowup_think;
 833                         self.nextthink = time;
 834                 #endif
 835                         return true;
 836                 }
 837
 838 #ifdef CSQC
 839                 case VR_HUD:
 840                 {
 841                         Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 842                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 843                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color,
 844                                                          vCROSS_GUIDE);
 845                         return true;
 846                 }
 847 #endif
 848                 case VR_SETUP:
 849                 {
 850                 #ifdef SVQC
 851                         self.vehicle_exit = racer_exit;
 852                 #endif
 853
 854                 #ifdef SVQC
 855                         // we have no need to network energy
 856                         if(autocvar_g_vehicle_racer_energy)
 857                         if(autocvar_g_vehicle_racer_energy_regen)
 858                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 859
 860                         if(autocvar_g_vehicle_racer_shield)
 861                                 self.vehicle_flags |= VHF_HASSHIELD;
 862
 863                         if(autocvar_g_vehicle_racer_shield_regen)
 864                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 865
 866                         if(autocvar_g_vehicle_racer_health_regen)
 867                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 868
 869                         self.respawntime = autocvar_g_vehicle_racer_respawntime;
 870                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 871                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 872                         self.max_health = self.vehicle_health;
 873                 #endif
 874
 875                 #ifdef CSQC
 876                         AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 877                 #endif
 878                         return true;
 879                 }
 880
 881                 case VR_PRECACHE:
 882                 {
 883                         return true;
 884                 }
 885         }
 886
 887         return true;
 888 }
 889
 890 #endif // REGISTER_VEHICLE