qcsrc/common/vehicles/unit/spiderbot.qc

   1 #ifdef REGISTER_VEHICLE
   2 REGISTER_VEHICLE(
   3 /* VEH_##id   */ SPIDERBOT,
   4 /* function   */ v_spiderbot,
   5 /* spawnflags */ VHF_DMGSHAKE,
   6 /* mins,maxs  */ '-75 -75 10', '75 75 125',
   7 /* model          */ "models/vehicles/spiderbot.dpm",
   8 /* head_model */ "models/vehicles/spiderbot_top.dpm",
   9 /* hud_model  */ "models/vehicles/spiderbot_cockpit.dpm",
  10 /* tags           */ "tag_head", "tag_hud", "",
  11 /* netname        */ "spiderbot",
  12 /* fullname   */ _("Spiderbot")
  13 );
  14 #else
  15
  16 #ifdef SVQC
  17 float autocvar_g_vehicle_spiderbot;
  18
  19 float autocvar_g_vehicle_spiderbot_respawntime;
  20
  21 float autocvar_g_vehicle_spiderbot_speed_stop;
  22 float autocvar_g_vehicle_spiderbot_speed_strafe;
  23 float autocvar_g_vehicle_spiderbot_speed_walk;
  24 float autocvar_g_vehicle_spiderbot_turnspeed;
  25 float autocvar_g_vehicle_spiderbot_turnspeed_strafe;
  26 float autocvar_g_vehicle_spiderbot_movement_inertia;
  27
  28 float autocvar_g_vehicle_spiderbot_springlength;
  29 float autocvar_g_vehicle_spiderbot_springup;
  30 float autocvar_g_vehicle_spiderbot_springblend;
  31 float autocvar_g_vehicle_spiderbot_tiltlimit;
  32
  33 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  34 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  35 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  36 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  37
  38 float autocvar_g_vehicle_spiderbot_health;
  39 float autocvar_g_vehicle_spiderbot_health_regen;
  40 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  41
  42 float autocvar_g_vehicle_spiderbot_shield;
  43 float autocvar_g_vehicle_spiderbot_shield_regen;
  44 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  45
  46 float autocvar_g_vehicle_spiderbot_minigun_damage;
  47 float autocvar_g_vehicle_spiderbot_minigun_refire;
  48 float autocvar_g_vehicle_spiderbot_minigun_spread;
  49 float autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
  50 float autocvar_g_vehicle_spiderbot_minigun_ammo_max;
  51 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen;
  52 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause;
  53 float autocvar_g_vehicle_spiderbot_minigun_force;
  54 float autocvar_g_vehicle_spiderbot_minigun_speed;
  55 float autocvar_g_vehicle_spiderbot_minigun_bulletconstant;
  56
  57 float autocvar_g_vehicle_spiderbot_rocket_damage;
  58 float autocvar_g_vehicle_spiderbot_rocket_force;
  59 float autocvar_g_vehicle_spiderbot_rocket_radius;
  60 float autocvar_g_vehicle_spiderbot_rocket_speed;
  61 float autocvar_g_vehicle_spiderbot_rocket_spread;
  62 float autocvar_g_vehicle_spiderbot_rocket_refire;
  63 float autocvar_g_vehicle_spiderbot_rocket_refire2;
  64 float autocvar_g_vehicle_spiderbot_rocket_reload;
  65 float autocvar_g_vehicle_spiderbot_rocket_health;
  66 float autocvar_g_vehicle_spiderbot_rocket_noise;
  67 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  68 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  69
  70 #define SBRM_FIRST 0
  71 #define SBRM_VOLLY 0
  72 #define SBRM_GUIDE 1
  73 #define SBRM_ARTILLERY 2
  74 #define SBRM_LAST 2
  75
  76 vector autocvar_g_vehicle_spiderbot_bouncepain;
  77
  78 void spiderbot_rocket_artillery()
  79 {
  80         self.nextthink = time;
  81         UpdateCSQCProjectile(self);
  82 }
  83
  84 void spiderbot_rocket_unguided()
  85 {
  86         vector newdir, olddir;
  87
  88         self.nextthink  = time;
  89
  90         olddir = normalize(self.velocity);
  91         newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  92         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  93
  94         UpdateCSQCProjectile(self);
  95
  96         if (self.owner.deadflag != DEAD_NO || self.cnt < time || vlen(self.pos1 - self.origin) < 16)
  97                 self.use();
  98 }
  99
 100 void spiderbot_rocket_guided()
 101 {
 102         vector newdir, olddir;
 103
 104         self.nextthink  = time;
 105
 106         if(!self.realowner.vehicle)
 107                 self.think = spiderbot_rocket_unguided;
 108
 109         crosshair_trace(self.realowner);
 110         olddir = normalize(self.velocity);
 111         newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
 112         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
 113
 114         UpdateCSQCProjectile(self);
 115
 116         if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 117                 self.use();
 118 }
 119
 120 void spiderbot_guide_release()
 121 {
 122         entity rkt;
 123         rkt = findchainentity(realowner, self.owner);
 124         if(!rkt)
 125                 return;
 126
 127         crosshair_trace(self.owner);
 128         while(rkt)
 129         {
 130                 if(rkt.think == spiderbot_rocket_guided)
 131                 {
 132                         rkt.pos1 = trace_endpos;
 133                         rkt.think = spiderbot_rocket_unguided;
 134                 }
 135                 rkt = rkt.chain;
 136         }
 137 }
 138
 139 float spiberbot_calcartillery_flighttime;
 140 vector spiberbot_calcartillery(vector org, vector tgt, float ht)
 141 {
 142         float grav, sdist, zdist, vs, vz, jumpheight;
 143         vector sdir;
 144
 145         grav  = autocvar_sv_gravity;
 146         zdist = tgt_z - org_z;
 147         sdist = vlen(tgt - org - zdist * '0 0 1');
 148         sdir  = normalize(tgt - org - zdist * '0 0 1');
 149
 150         // how high do we need to go?
 151         jumpheight = fabs(ht);
 152         if(zdist > 0)
 153                 jumpheight = jumpheight + zdist;
 154
 155         // push so high...
 156         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
 157
 158         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
 159         if(ht < 0)
 160                 if(zdist < 0)
 161                         vz = -vz;
 162
 163         vector solution;
 164         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
 165         // ALWAYS solvable because jumpheight >= zdist
 166         if(!solution_z)
 167                 solution_y = solution_x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
 168         if(zdist == 0)
 169                 solution_x = solution_y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
 170
 171         if(zdist < 0)
 172         {
 173                 // down-jump
 174                 if(ht < 0)
 175                 {
 176                         // almost straight line type
 177                         // jump apex is before the jump
 178                         // we must take the larger one
 179                         spiberbot_calcartillery_flighttime = solution_y;
 180                 }
 181                 else
 182                 {
 183                         // regular jump
 184                         // jump apex is during the jump
 185                         // we must take the larger one too
 186                         spiberbot_calcartillery_flighttime = solution_y;
 187                 }
 188         }
 189         else
 190         {
 191                 // up-jump
 192                 if(ht < 0)
 193                 {
 194                         // almost straight line type
 195                         // jump apex is after the jump
 196                         // we must take the smaller one
 197                         spiberbot_calcartillery_flighttime = solution_x;
 198                 }
 199                 else
 200                 {
 201                         // regular jump
 202                         // jump apex is during the jump
 203                         // we must take the larger one
 204                         spiberbot_calcartillery_flighttime = solution_y;
 205                 }
 206         }
 207         vs = sdist / spiberbot_calcartillery_flighttime;
 208
 209         // finally calculate the velocity
 210         return sdir * vs + '0 0 1' * vz;
 211 }
 212
 213 void spiderbot_rocket_do()
 214 {
 215         vector v;
 216         entity rocket = world;
 217
 218         if (self.wait != -10)
 219         {
 220                 if (self.owner.BUTTON_ATCK2 && self.vehicle_weapon2mode == SBRM_GUIDE)
 221                 {
 222                         if (self.wait == 1)
 223                         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 224                         {
 225                                 if(self.gun2.cnt < time && self.tur_head.frame == 9)
 226                                         self.tur_head.frame = 1;
 227
 228                                 return;
 229                         }
 230                         self.wait = 1;
 231                 }
 232                 else
 233                 {
 234                         if(self.wait)
 235                                 spiderbot_guide_release();
 236
 237                         self.wait = 0;
 238                 }
 239         }
 240
 241         if(self.gun2.cnt > time)
 242                 return;
 243
 244         if (self.tur_head.frame >= 9)
 245         {
 246                 self.tur_head.frame = 1;
 247                 self.wait = 0;
 248         }
 249
 250         if(self.wait != -10)
 251         if(!self.owner.BUTTON_ATCK2)
 252                 return;
 253
 254         v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 255
 256         switch(self.vehicle_weapon2mode)
 257         {
 258                 case SBRM_VOLLY:
 259                         rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 260                                                                    v, normalize(randomvec() * autocvar_g_vehicle_spiderbot_rocket_spread + v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 261                                                                    autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 262                                                                    DEATH_VH_SPID_ROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, TRUE, self.owner);
 263                         crosshair_trace(self.owner);
 264                         float _dist = (random() * autocvar_g_vehicle_spiderbot_rocket_radius) + vlen(v - trace_endpos);
 265                         _dist -= (random() * autocvar_g_vehicle_spiderbot_rocket_radius) ;
 266                         rocket.nextthink  = time + (_dist / autocvar_g_vehicle_spiderbot_rocket_speed);
 267                         rocket.think     = vehicles_projectile_explode;
 268
 269                         if(self.owner.BUTTON_ATCK2 && self.tur_head.frame == 1)
 270                                 self.wait = -10;
 271                         break;
 272                 case SBRM_GUIDE:
 273                         rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 274                                                                    v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 275                                                                    autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 276                                                                    DEATH_VH_SPID_ROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, FALSE, self.owner);
 277                         crosshair_trace(self.owner);
 278                         rocket.pos1        = trace_endpos;
 279                         rocket.nextthink  = time;
 280                         rocket.think      = spiderbot_rocket_guided;
 281
 282
 283                 break;
 284                 case SBRM_ARTILLERY:
 285                         rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 286                                                                    v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 287                                                                    autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 288                                                                    DEATH_VH_SPID_ROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, TRUE, self.owner);
 289
 290                         crosshair_trace(self.owner);
 291
 292                         rocket.pos1        = trace_endpos + randomvec() * (0.75 * autocvar_g_vehicle_spiderbot_rocket_radius);
 293                         rocket.pos1_z      = trace_endpos_z;
 294
 295                         traceline(v, v + '0 0 1' * MAX_SHOT_DISTANCE, MOVE_WORLDONLY, self);
 296                         float h1 = 0.75 * vlen(v - trace_endpos);
 297
 298                         //v = trace_endpos;
 299                         traceline(v , rocket.pos1 + '0 0 1' * MAX_SHOT_DISTANCE, MOVE_WORLDONLY, self);
 300                         float h2 = 0.75 * vlen(rocket.pos1 - v);
 301
 302                         rocket.velocity  = spiberbot_calcartillery(v, rocket.pos1, ((h1 < h2) ? h1 : h2));
 303                         rocket.movetype  = MOVETYPE_TOSS;
 304                         rocket.gravity   = 1;
 305                         //rocket.think   = spiderbot_rocket_artillery;
 306                 break;
 307         }
 308         rocket.classname  = "spiderbot_rocket";
 309
 310         rocket.cnt = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 311
 312         self.tur_head.frame += 1;
 313         if (self.tur_head.frame == 9)
 314                 self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 315         else
 316                 self.attack_finished_single = ((self.vehicle_weapon2mode ==  SBRM_VOLLY) ? autocvar_g_vehicle_spiderbot_rocket_refire2 : autocvar_g_vehicle_spiderbot_rocket_refire);
 317
 318         self.gun2.cnt = time + self.attack_finished_single;
 319 }
 320
 321 float spiderbot_frame()
 322 {
 323         vector ad, vf;
 324         entity player, spider;
 325         float ftmp;
 326
 327         if(intermission_running)
 328                 return 1;
 329
 330         player = self;
 331         spider = self.vehicle;
 332         self   = spider;
 333
 334         vehicles_painframe();
 335
 336         player.BUTTON_ZOOM        = 0;
 337         player.BUTTON_CROUCH    = 0;
 338         player.switchweapon      = 0;
 339
 340
 341 #if 1 // 0 to enable per-gun impact aux crosshairs
 342         // Avarage gun impact point's -> aux cross
 343         ad = gettaginfo(spider.tur_head, gettagindex(spider.tur_head, "tag_hardpoint01"));
 344         vf = v_forward;
 345         ad += gettaginfo(spider.tur_head, gettagindex(spider.tur_head, "tag_hardpoint02"));
 346         vf += v_forward;
 347         ad = ad * 0.5;
 348         v_forward = vf * 0.5;
 349         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 350         UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 351 #else
 352         ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 353         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 354         UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 355         vf = ad;
 356         ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 357         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 358         UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 359         ad = 0.5 * (ad + vf);
 360 #endif
 361
 362         crosshair_trace(player);
 363         ad = vectoangles(normalize(trace_endpos - ad));
 364         ad = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(spider.angles), AnglesTransform_FromAngles(ad))) - spider.tur_head.angles;
 365         ad = AnglesTransform_Normalize(ad, TRUE);
 366         //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 367
 368         // Rotate head
 369         ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 370         ad_y = bound(-ftmp, ad_y, ftmp);
 371         spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 372
 373         // Pitch head
 374         ad_x = bound(ftmp * -1, ad_x, ftmp);
 375         spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 376
 377
 378         //fixedmakevectors(spider.angles);
 379         makevectors(spider.angles + '-2 0 0' * spider.angles_x);
 380
 381         movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend, autocvar_g_vehicle_spiderbot_tiltlimit);
 382
 383         if(spider.flags & FL_ONGROUND)
 384         {
 385                 if(spider.frame == 4 && self.tur_head.wait != 0)
 386                 {
 387                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_land.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 388                         spider.frame = 5;
 389                 }
 390
 391                 if(player.BUTTON_JUMP && self.tur_head.wait < time)
 392                 {
 393                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_jump.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 394                         //dprint("spiderbot_jump:", ftos(soundlength("vehicles/spiderbot_jump.wav")), "\n");
 395                         self.delay = 0;
 396
 397                         self.tur_head.wait = time + 2;
 398                         player.BUTTON_JUMP = 0;
 399                         spider.velocity   = v_forward * 700 + v_up * 600;
 400                         spider.frame = 4;
 401                 }
 402                 else
 403                 {
 404                         if(vlen(player.movement) == 0)
 405                         {
 406                                 if(self.sound_nexttime < time || self.delay != 3)
 407                                 {
 408                                         self.delay = 3;
 409                                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_idle.wav");
 410                                         //dprint("spiderbot_idle:", ftos(soundlength("vehicles/spiderbot_idle.wav")), "\n");
 411                                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_idle.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 412                                 }
 413                                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 414                                 spider.frame = 5;
 415                         }
 416                         else
 417                         {
 418                                 // Turn Body
 419                                 if(player.movement_x == 0 && player.movement_y != 0)
 420                                         ftmp = autocvar_g_vehicle_spiderbot_turnspeed_strafe * sys_frametime;
 421                                 else
 422                                         ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 423
 424                                 ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 425                                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 426                                 spider.tur_head.angles_y -= ftmp;
 427
 428                                 if(player.movement_x != 0)
 429                                 {
 430                                         if(player.movement_x > 0)
 431                                         {
 432                                                 player.movement_x = 1;
 433                                                 spider.frame = 0;
 434                                         }
 435                                         else if(player.movement_x < 0)
 436                                         {
 437                                                 player.movement_x = -1;
 438                                                 spider.frame = 1;
 439                                         }
 440                                         player.movement_y = 0;
 441                                         movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 442
 443                                         if(self.sound_nexttime < time || self.delay != 1)
 444                                         {
 445                                                 self.delay = 1;
 446                                                 self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_walk.wav");
 447                                                 sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_walk.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 448                                                 //dprint("spiderbot_walk:", ftos(soundlength("vehicles/spiderbot_walk.wav")), "\n");
 449                                         }
 450                                 }
 451                                 else if(player.movement_y != 0)
 452                                 {
 453                                         if(player.movement_y < 0)
 454                                         {
 455                                                 player.movement_y = -1;
 456                                                 spider.frame = 2;
 457                                         }
 458                                         else if(player.movement_y > 0)
 459                                         {
 460                                                 player.movement_y = 1;
 461                                                 spider.frame = 3;
 462                                         }
 463                                         movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 464                                         if(self.sound_nexttime < time || self.delay != 2)
 465                                         {
 466                                                 self.delay = 2;
 467                                                 self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_strafe.wav");
 468                                                 sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_strafe.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 469                                                 //dprint("spiderbot_strafe:", ftos(soundlength("vehicles/spiderbot_strafe.wav")), "\n");
 470                                         }
 471                                 }
 472                         }
 473                 }
 474         }
 475
 476         self.angles_x = bound(-autocvar_g_vehicle_spiderbot_tiltlimit, self.angles_x, autocvar_g_vehicle_spiderbot_tiltlimit);
 477         self.angles_z = bound(-autocvar_g_vehicle_spiderbot_tiltlimit, self.angles_z, autocvar_g_vehicle_spiderbot_tiltlimit);
 478
 479         if(player.BUTTON_ATCK)
 480         {
 481                 spider.cnt = time;
 482                 if(spider.vehicle_ammo1 >= autocvar_g_vehicle_spiderbot_minigun_ammo_cost && spider.tur_head.attack_finished_single <= time)
 483                 {
 484                         entity gun;
 485                         vector v;
 486                         spider.misc_bulletcounter += 1;
 487
 488                         self = player;
 489
 490                         mod(spider.misc_bulletcounter, 2) ? gun = spider.gun1 : gun = spider.gun2;
 491                         v = gettaginfo(gun, gettagindex(gun, "barrels"));
 492                         v_forward = normalize(v_forward);
 493                         v += v_forward * 50;
 494
 495 //void fireBallisticBullet(vector start, vector dir, float spread, float pSpeed, float lifetime, float damage, float force, float dtype, float tracereffects, float gravityfactor, float bulletconstant)
 496
 497                         fireBallisticBullet(v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_speed,
 498                                                                 5, autocvar_g_vehicle_spiderbot_minigun_damage, autocvar_g_vehicle_spiderbot_minigun_force, DEATH_VH_SPID_MINIGUN, 0, autocvar_g_vehicle_spiderbot_minigun_bulletconstant);
 499
 500                         endFireBallisticBullet();
 501
 502 //                      fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 503 //                              autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_VH_SPID_MINIGUN, 0);
 504
 505                         sound (gun, CH_WEAPON_A, "weapons/uzi_fire.wav", VOL_BASE, ATTEN_NORM);
 506                         //trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 507                         pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 508
 509                         self = spider;
 510
 511                         spider.vehicle_ammo1 -= autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
 512                         spider.tur_head.attack_finished_single = time + autocvar_g_vehicle_spiderbot_minigun_refire;
 513                         player.vehicle_ammo1 = (spider.vehicle_ammo1 / autocvar_g_vehicle_spiderbot_minigun_ammo_max) * 100;
 514                         spider.gun1.angles_z += 45;
 515                         spider.gun2.angles_z -= 45;
 516                         if(spider.gun1.angles_z >= 360)
 517                         {
 518                                 spider.gun1.angles_z = 0;
 519                                 spider.gun2.angles_z = 0;
 520                         }
 521                 }
 522         }
 523         else
 524                 vehicles_regen(spider.cnt, vehicle_ammo1, autocvar_g_vehicle_spiderbot_minigun_ammo_max,
 525                                                                                    autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause,
 526                                                                                    autocvar_g_vehicle_spiderbot_minigun_ammo_regen, frametime, FALSE);
 527
 528
 529         spiderbot_rocket_do();
 530
 531         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 532                 vehicles_regen(spider.dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime, TRUE);
 533
 534         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 535                 vehicles_regen(spider.dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime, FALSE);
 536
 537         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 538         player.vehicle_ammo2 = spider.tur_head.frame;
 539
 540         if(spider.gun2.cnt <= time)
 541                 player.vehicle_reload2 = 100;
 542         else
 543                 player.vehicle_reload2 = 100 - ((spider.gun2.cnt - time) / spider.attack_finished_single) * 100;
 544
 545         setorigin(player, spider.origin + '0 0 1' * spider.maxs_z);
 546         player.velocity = spider.velocity;
 547
 548         VEHICLE_UPDATE_PLAYER(player, health, spiderbot);
 549
 550         if(self.vehicle_flags & VHF_HASSHIELD)
 551                 VEHICLE_UPDATE_PLAYER(player, shield, spiderbot);
 552
 553         self = player;
 554         return 1;
 555 }
 556
 557 void spiderbot_exit(float eject)
 558 {
 559         entity e;
 560         vector spot;
 561
 562         e = findchain(classname,"spiderbot_rocket");
 563         while(e)
 564         {
 565                 if(e.owner == self.owner)
 566                 {
 567                         e.realowner = self.owner;
 568                         e.owner = world;
 569                 }
 570                 e = e.chain;
 571         }
 572
 573         self.think = vehicles_think;
 574         self.nextthink = time;
 575         self.frame = 5;
 576         self.movetype = MOVETYPE_WALK;
 577
 578         if(!self.owner)
 579                 return;
 580
 581         makevectors(self.angles);
 582         if(eject)
 583         {
 584                 spot = self.origin + v_forward * 100 + '0 0 64';
 585                 spot = vehicles_findgoodexit(spot);
 586                 setorigin(self.owner , spot);
 587                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 588                 self.owner.oldvelocity = self.owner.velocity;
 589         }
 590         else
 591         {
 592                 if(vlen(self.velocity) > autocvar_g_vehicle_spiderbot_speed_strafe)
 593                 {
 594                         self.owner.velocity = normalize(self.velocity) * vlen(self.velocity);
 595                         self.owner.velocity_z += 200;
 596                         spot = self.origin + v_forward * 128 + '0 0 64';
 597                         spot = vehicles_findgoodexit(spot);
 598                 }
 599                 else
 600                 {
 601                         self.owner.velocity = self.velocity * 0.5;
 602                         self.owner.velocity_z += 10;
 603                         spot = self.origin + v_forward * 256 + '0 0 64';
 604                         spot = vehicles_findgoodexit(spot);
 605                 }
 606                 self.owner.oldvelocity = self.owner.velocity;
 607                 setorigin(self.owner , spot);
 608         }
 609
 610         antilag_clear(self.owner);
 611         self.owner = world;
 612 }
 613
 614 void spiderbot_headfade()
 615 {
 616         self.think = spiderbot_headfade;
 617         self.nextthink = self.fade_time;
 618         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 619
 620         if(self.cnt < time || self.alpha < 0.1)
 621         {
 622                 if(self.alpha > 0.1)
 623                 {
 624                         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 625                         pointparticles(particleeffectnum("explosion_big"), self.origin + '0 0 100', '0 0 0', 1);
 626                 }
 627                 remove(self);
 628         }
 629 }
 630
 631 void spiderbot_blowup()
 632 {
 633         if(self.cnt > time)
 634         {
 635                 if(random() < 0.1)
 636                 {
 637                         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 638                         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 639                 }
 640                 self.nextthink = time + 0.1;
 641                 return;
 642         }
 643
 644         entity h, g1, g2, b;
 645         b = spawn();
 646         h = spawn();
 647         g1 = spawn();
 648         g2 = spawn();
 649
 650         setmodel(b, "models/vehicles/spiderbot.dpm");
 651         setmodel(h, "models/vehicles/spiderbot_top.dpm");
 652         setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 653         setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 654
 655         setorigin(b, self.origin);
 656         b.frame = 11;
 657         b.angles = self.angles;
 658         setsize(b, self.mins, self.maxs);
 659
 660         setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 661         h.movetype = MOVETYPE_BOUNCE;
 662         h.solid = SOLID_BBOX;
 663         h.velocity = v_up * (500 + random() * 500) + randomvec() * 128;
 664         h.modelflags = MF_ROCKET;
 665         h.effects = EF_FLAME | EF_LOWPRECISION;
 666         h.avelocity = randomvec() * 360;
 667
 668         h.alpha = 1;
 669         h.cnt = time + (3.5 * random());
 670         h.fade_rate = 1 / min(self.respawntime, 10);
 671         h.fade_time = time;
 672         h.think = spiderbot_headfade;
 673         h.nextthink = time;
 674
 675         setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 676         g1.movetype = MOVETYPE_TOSS;
 677         g1.solid = SOLID_CORPSE;
 678         g1.velocity = v_forward * 700 + (randomvec() * 32);
 679         g1.avelocity = randomvec() * 180;
 680
 681         setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 682         g2.movetype = MOVETYPE_TOSS;
 683         g2.solid = SOLID_CORPSE;
 684         g2.velocity = v_forward * 700 + (randomvec() * 32);
 685         g2.avelocity = randomvec() * 180;
 686
 687         h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 688
 689         SUB_SetFade(b,  time + 5, min(self.respawntime, 1));
 690         //SUB_SetFade(h,  time, min(self.respawntime, 10));
 691         SUB_SetFade(g1, time, min(self.respawntime, 10));
 692         SUB_SetFade(g2, time, min(self.respawntime, 10));
 693
 694         RadiusDamage (self, self.enemy, 250, 15, 250, world, 250, DEATH_VH_SPID_DEATH, world);
 695
 696         self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 697         self.movetype = MOVETYPE_NONE;
 698         self.deadflag = DEAD_DEAD;
 699         self.solid = SOLID_NOT;
 700         self.tur_head.effects &= ~EF_FLAME;
 701         self.vehicle_hudmodel.viewmodelforclient = self;
 702 }
 703
 704 float spiderbot_impulse(float _imp)
 705 {
 706         switch(_imp)
 707         {
 708                 case 10:
 709                 case 15:
 710                 case 18:
 711                         self.vehicle.vehicle_weapon2mode += 1;
 712                         if(self.vehicle.vehicle_weapon2mode > SBRM_LAST)
 713                                 self.vehicle.vehicle_weapon2mode = SBRM_FIRST;
 714
 715                         //centerprint(self, strcat("Rocket mode is ", ftos(self.vehicle.vehicle_weapon2mode)));
 716                         CSQCVehicleSetup(self, 0);
 717                         return TRUE;
 718                 case 12:
 719                 case 16:
 720                 case 19:
 721                         self.vehicle.vehicle_weapon2mode -= 1;
 722                         if(self.vehicle.vehicle_weapon2mode < SBRM_FIRST)
 723                                 self.vehicle.vehicle_weapon2mode = SBRM_LAST;
 724
 725                         //centerprint(self, strcat("Rocket mode is ", ftos(self.vehicle.vehicle_weapon2mode)));
 726                         CSQCVehicleSetup(self, 0);
 727                         return TRUE;
 728
 729                 /*
 730                 case 17: // toss gun, could be used to exit?
 731                         break;
 732                 case 20: // Manual minigun reload?
 733                         break;
 734                 */
 735         }
 736         return FALSE;
 737 }
 738
 739 void spawnfunc_vehicle_spiderbot()
 740 {
 741         if(!autocvar_g_vehicle_spiderbot) { remove(self); return; }
 742         if(!vehicle_initialize(VEH_SPIDERBOT, FALSE)) { remove(self); return; }
 743 }
 744
 745 float v_spiderbot(float req)
 746 {
 747         switch(req)
 748         {
 749                 case VR_IMPACT:
 750                 {
 751                         if(autocvar_g_vehicle_spiderbot_bouncepain)
 752                                 vehicles_impact(autocvar_g_vehicle_spiderbot_bouncepain_x, autocvar_g_vehicle_spiderbot_bouncepain_y, autocvar_g_vehicle_spiderbot_bouncepain_z);
 753
 754                         return TRUE;
 755                 }
 756                 case VR_ENTER:
 757                 {
 758                         self.vehicle_weapon2mode = SBRM_GUIDE;
 759                         self.movetype = MOVETYPE_WALK;
 760                         CSQCVehicleSetup(self.owner, 0);
 761                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health) * 100;
 762                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield) * 100;
 763
 764                         if(self.owner.flagcarried)
 765                         {
 766                                 setattachment(self.owner.flagcarried, self.tur_head, "");
 767                                 setorigin(self.owner.flagcarried, '-20 0 120');
 768                         }
 769
 770                         return TRUE;
 771                 }
 772                 case VR_THINK:
 773                 {
 774                         if(self.flags & FL_ONGROUND)
 775                                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 776
 777                         return TRUE;
 778                 }
 779                 case VR_DEATH:
 780                 {
 781                         self.health                             = 0;
 782                         self.event_damage               = func_null;
 783                         self.takedamage                 = DAMAGE_NO;
 784                         self.touch                              = func_null;
 785                         self.cnt                                = 3.4 + time + random() * 2;
 786                         self.think                              = spiderbot_blowup;
 787                         self.nextthink                  = time;
 788                         self.deadflag                   = DEAD_DYING;
 789                         self.frame                              = 5;
 790                         self.tur_head.effects  |= EF_FLAME;
 791                         self.colormod                   = self.tur_head.colormod = '-1 -1 -1';
 792                         self.frame                              = 10;
 793                         self.movetype                   = MOVETYPE_TOSS;
 794
 795                         return TRUE;
 796                 }
 797                 case VR_SPAWN:
 798                 {
 799                         if(!self.gun1)
 800                         {
 801                                 self.vehicles_impulse = spiderbot_impulse;
 802                                 self.gun1 = spawn();
 803                                 self.gun2 = spawn();
 804                                 setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 805                                 setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 806                                 setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 807                                 setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 808                                 self.gravity = 2;
 809                                 self.mass = 5000;
 810                         }
 811
 812                         self.frame = 5;
 813                         self.tur_head.frame = 1;
 814                         self.movetype = MOVETYPE_WALK;
 815                         self.solid = SOLID_SLIDEBOX;
 816                         self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 817                         self.tur_head.angles = '0 0 0';
 818                         self.vehicle_exit = spiderbot_exit;
 819
 820                         setorigin(self, self.pos1 + '0 0 128');
 821                         self.angles = self.pos2;
 822                         self.damageforcescale = 0.03;
 823                         self.vehicle_health = autocvar_g_vehicle_spiderbot_health;
 824                         self.vehicle_shield = autocvar_g_vehicle_spiderbot_shield;
 825
 826                         self.PlayerPhysplug = spiderbot_frame;
 827
 828                         return TRUE;
 829                 }
 830                 case VR_SETUP:
 831                 {
 832                         if(autocvar_g_vehicle_spiderbot_shield)
 833                                 self.vehicle_flags |= VHF_HASSHIELD;
 834
 835                         if(autocvar_g_vehicle_spiderbot_shield_regen)
 836                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 837
 838                         if(autocvar_g_vehicle_spiderbot_health_regen)
 839                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 840
 841                         self.respawntime = autocvar_g_vehicle_spiderbot_respawntime;
 842                         self.vehicle_health = autocvar_g_vehicle_spiderbot_health;
 843                         self.vehicle_shield = autocvar_g_vehicle_spiderbot_shield;
 844                         self.max_health = self.vehicle_health;
 845
 846                         return TRUE;
 847                 }
 848                 case VR_PRECACHE:
 849                 {
 850                         precache_model ("models/vhshield.md3");
 851                         precache_model ("models/vehicles/spiderbot.dpm");
 852                         precache_model ("models/vehicles/spiderbot_top.dpm");
 853                         precache_model ("models/vehicles/spiderbot_barrels.dpm");
 854                         precache_model ("models/vehicles/spiderbot_cockpit.dpm");
 855                         precache_model ( "models/uziflash.md3");
 856
 857                         precache_sound ("weapons/uzi_fire.wav" );
 858                         precache_sound ("weapons/rocket_impact.wav");
 859
 860                         precache_sound ("vehicles/spiderbot_die.wav");
 861                         precache_sound ("vehicles/spiderbot_idle.wav");
 862                         precache_sound ("vehicles/spiderbot_jump.wav");
 863                         precache_sound ("vehicles/spiderbot_strafe.wav");
 864                         precache_sound ("vehicles/spiderbot_walk.wav");
 865                         precache_sound ("vehicles/spiderbot_land.wav");
 866                         return TRUE;
 867                 }
 868         }
 869
 870         return TRUE;
 871 }
 872
 873 #endif // SVQC
 874 #ifdef CSQC
 875
 876 #define spider_ico  "gfx/vehicles/sbot.tga"
 877 #define spider_rkt  "gfx/vehicles/sbot_rpods.tga"
 878 #define spider_mgun "gfx/vehicles/sbot_mguns.tga"
 879 string spider_xhair; // = "gfx/vehicles/axh-special1.tga";
 880
 881 #define SBRM_FIRST 1
 882 #define SBRM_VOLLY 1
 883 #define SBRM_GUIDE 2
 884 #define SBRM_ARTILLERY 3
 885 #define SBRM_LAST 3
 886
 887 float v_spiderbot(float req)
 888 {
 889         switch(req)
 890         {
 891                 case VR_HUD:
 892                 {
 893                         if(autocvar_r_letterbox)
 894                                 return TRUE;
 895
 896                         vector picsize, hudloc = '0 0 0', pic2size, picloc;
 897                         float i;
 898
 899                         // Fetch health & ammo stats
 900                         HUD_GETVEHICLESTATS
 901
 902                         picsize = draw_getimagesize(hud_bg) * autocvar_cl_vehicles_hudscale;
 903                         hudloc_y = vid_conheight - picsize_y;
 904                         hudloc_x = vid_conwidth * 0.5 - picsize_x * 0.5;
 905
 906                         drawpic(hudloc, hud_bg, picsize, '1 1 1', autocvar_cl_vehicles_hudalpha, DRAWFLAG_NORMAL);
 907
 908                         ammo1   *= 0.01;
 909                         shield  *= 0.01;
 910                         vh_health  *= 0.01;
 911                         reload2 *= 0.01;
 912
 913                         pic2size = draw_getimagesize(spider_ico) * (autocvar_cl_vehicles_hudscale * 0.8);
 914                         picloc = picsize * 0.5 - pic2size * 0.5;
 915                         if(vh_health < 0.25)
 916                                 drawpic(hudloc + picloc, spider_ico, pic2size,  '1 0 0' + '0 1 1' * sin(time * 8),  1, DRAWFLAG_NORMAL);
 917                         else
 918                                 drawpic(hudloc + picloc, spider_ico, pic2size,  '1 1 1' * vh_health  + '1 0 0' * (1 - vh_health),  1, DRAWFLAG_NORMAL);
 919                         drawpic(hudloc + picloc, spider_rkt, pic2size,  '1 1 1' * reload2 + '1 0 0' * (1 - reload2), 1, DRAWFLAG_NORMAL);
 920                         drawpic(hudloc + picloc, spider_mgun, pic2size, '1 1 1' * ammo1   + '1 0 0' * (1 - ammo1),   1, DRAWFLAG_NORMAL);
 921                         drawpic(hudloc + picloc, hud_sh, pic2size,  '1 1 1', shield, DRAWFLAG_NORMAL);
 922
 923                 // Health bar
 924                         picsize = draw_getimagesize(hud_hp_bar) * autocvar_cl_vehicles_hudscale;
 925                         picloc = '69 69 0' * autocvar_cl_vehicles_hudscale;
 926                         drawsetcliparea(hudloc_x + picloc_x + (picsize_x * (1 - vh_health)), 0, vid_conwidth, vid_conheight);
 927                         drawpic(hudloc + picloc, hud_hp_bar, picsize, '1 1 1', 1 , DRAWFLAG_NORMAL);
 928                         drawresetcliparea();
 929                 // ..  and icon
 930                         picsize = draw_getimagesize(hud_hp_ico) * autocvar_cl_vehicles_hudscale;
 931                         picloc = '37 65 0' * autocvar_cl_vehicles_hudscale;
 932                         if(vh_health < 0.25)
 933                         {
 934                                 if(alarm1time < time)
 935                                 {
 936                                         alarm1time = time + 2;
 937                                         sound(self, CH_PAIN_SINGLE, "vehicles/alarm.wav", VOL_BASEVOICE, ATTEN_NONE);
 938                                 }
 939                                 drawpic(hudloc + picloc, hud_hp_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
 940                         }
 941                         else
 942                         {
 943                                 drawpic(hudloc + picloc, hud_hp_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 944                                 if(alarm1time)
 945                                 {
 946                                         sound(self, CH_PAIN_SINGLE, "misc/null.wav", VOL_BASEVOICE, ATTEN_NONE);
 947                                         alarm1time = 0;
 948                                 }
 949                         }
 950                 // Shield bar
 951                         picsize = draw_getimagesize(hud_sh_bar) * autocvar_cl_vehicles_hudscale;
 952                         picloc = '69 140 0' * autocvar_cl_vehicles_hudscale;
 953                         drawsetcliparea(hudloc_x + picloc_x + (picsize_x * (1 - shield)), 0, vid_conwidth, vid_conheight);
 954                         drawpic(hudloc + picloc, hud_sh_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 955                         drawresetcliparea();
 956                 // ..  and icon
 957                         picloc = '40 136 0' * autocvar_cl_vehicles_hudscale;
 958                         picsize = draw_getimagesize(hud_sh_ico) * autocvar_cl_vehicles_hudscale;
 959                         if(shield < 0.25)
 960                         {
 961                                 if(alarm2time < time)
 962                                 {
 963                                         alarm2time = time + 1;
 964                                         sound(self, CH_TRIGGER_SINGLE, "vehicles/alarm_shield.wav", VOL_BASEVOICE, ATTEN_NONE);
 965                                 }
 966                                 drawpic(hudloc + picloc, hud_sh_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
 967                         }
 968                         else
 969                         {
 970                                 drawpic(hudloc + picloc, hud_sh_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 971                                 if(alarm2time)
 972                                 {
 973                                         sound(self, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_BASEVOICE, ATTEN_NONE);
 974                                         alarm2time = 0;
 975                                 }
 976                         }
 977
 978                 // Minigun bar
 979                         picsize = draw_getimagesize(hud_ammo1_bar) * autocvar_cl_vehicles_hudscale;
 980                         picloc = '450 69 0' * autocvar_cl_vehicles_hudscale;
 981                         drawsetcliparea(hudloc_x + picloc_x, picloc_y, picsize_x * ammo1, vid_conheight);
 982                         drawpic(hudloc + picloc, hud_ammo1_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 983                         drawresetcliparea();
 984                 // ..  and icon
 985                         picsize = draw_getimagesize(hud_ammo1_ico) * autocvar_cl_vehicles_hudscale;
 986                         picloc = '664 60 0' * autocvar_cl_vehicles_hudscale;
 987                         if(ammo1 < 0.2)
 988                                 drawpic(hudloc + picloc, hud_ammo1_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
 989                         else
 990                                 drawpic(hudloc + picloc, hud_ammo1_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 991
 992                 // Rocket ammo bar
 993                         picsize = draw_getimagesize(hud_ammo2_bar) * autocvar_cl_vehicles_hudscale;
 994                         ammo1 = picsize_x / 8;
 995                         picloc = '450 140 0' * autocvar_cl_vehicles_hudscale;
 996                         drawsetcliparea(hudloc_x + picloc_x, hudloc_y + picloc_y, picsize_x * reload2, vid_conheight);
 997                         drawpic(hudloc + picloc, hud_ammo2_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 998                         drawresetcliparea();
 999
1000                 // ..  and icons
1001                         pic2size = 0.35 * draw_getimagesize(hud_ammo2_ico) * autocvar_cl_vehicles_hudscale;
1002                         picloc_x -= pic2size_x;
1003                         picloc_y += pic2size_y * 2.25;
1004                         if(ammo2 == 9)
1005                         {
1006                                 for(i = 1; i < 9; ++i)
1007                                 {
1008                                         picloc_x += ammo1;
1009                                         drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, ((8 * reload2 <= i) ? '0 0 0' : '1 1 1'), 0.75, DRAWFLAG_NORMAL);
1010                                 }
1011                         }
1012                         else
1013                         {
1014                                 for(i = 1; i < 9; ++i)
1015                                 {
1016                                         picloc_x += ammo1;
1017                                         drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, ((i >= ammo2) ? '1 1 1' : '0 0 0'), 0.75, DRAWFLAG_NORMAL);
1018                                 }
1019                         }
1020                         pic2size = draw_getimagesize(hud_ammo2_ico) * autocvar_cl_vehicles_hudscale;
1021                         picloc = '664 130 0' * autocvar_cl_vehicles_hudscale;
1022                         if(ammo2 == 9)
1023                                 drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
1024                         else
1025                                 drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, '1 1 1', 1, DRAWFLAG_NORMAL);
1026
1027                         if (scoreboard_showscores)
1028                                 HUD_DrawScoreboard();
1029                         else
1030                         {
1031                                 switch(weapon2mode)
1032                                 {
1033                                         case SBRM_VOLLY:
1034                                                 spider_xhair = "gfx/vehicles/axh-bracket.tga";
1035                                                 break;
1036                                         case SBRM_GUIDE:
1037                                                 spider_xhair = "gfx/vehicles/axh-cross.tga";
1038                                                 break;
1039                                         case SBRM_ARTILLERY:
1040                                                 spider_xhair = "gfx/vehicles/axh-tag.tga";
1041                                                 break;
1042                                         default:
1043                                                 spider_xhair= "gfx/vehicles/axh-tag.tga";
1044                                 }
1045
1046                                 picsize = draw_getimagesize(spider_xhair);
1047                                 picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1048                                 picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1049
1050                                 drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), spider_xhair, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_ADDITIVE);
1051                         }
1052
1053                         return TRUE;
1054                 }
1055                 case VR_SETUP:
1056                 {
1057                         // Minigun1
1058                         AuxiliaryXhair[0].axh_image   = "gfx/vehicles/axh-ring.tga";
1059                         AuxiliaryXhair[0].axh_scale   = 0.25;
1060                         // Minigun2
1061                         AuxiliaryXhair[1].axh_image   = "gfx/vehicles/axh-ring.tga";
1062                         AuxiliaryXhair[1].axh_scale   = 0.25;
1063                         // Rocket
1064                         AuxiliaryXhair[2].axh_image   = "gfx/vehicles/axh-special1.tga";
1065                         AuxiliaryXhair[2].axh_scale   = 0.5;
1066
1067                         return TRUE;
1068                 }
1069                 case VR_PRECACHE:
1070                 {
1071                         precache_model ("models/vhshield.md3");
1072                         precache_model ("models/vehicles/spiderbot.dpm");
1073                         precache_model ("models/vehicles/spiderbot_top.dpm");
1074                         precache_model ("models/vehicles/spiderbot_barrels.dpm");
1075                         precache_model ("models/vehicles/spiderbot_cockpit.dpm");
1076                         return TRUE;
1077                 }
1078         }
1079
1080         return TRUE;
1081 }
1082
1083 #endif // CSQC
1084 #endif // REGISTER_VEHICLE