qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 0',
  10 /* modelname */ "rl",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairrocketlauncher 0.5875",
  13 /* wepimg    */ "weaponrocketlauncher",
  14 /* refname   */ "devastator",
  15 /* wepname   */ _("Devastator")
  16 );
  17
  18 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  19 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, ammo) \
  21         w_cvar(id, sn, NONE, animtime) \
  22         w_cvar(id, sn, NONE, damage) \
  23         w_cvar(id, sn, NONE, damageforcescale) \
  24         w_cvar(id, sn, NONE, detonatedelay) \
  25         w_cvar(id, sn, NONE, edgedamage) \
  26         w_cvar(id, sn, NONE, force) \
  27         w_cvar(id, sn, NONE, guidedelay) \
  28         w_cvar(id, sn, NONE, guidegoal) \
  29         w_cvar(id, sn, NONE, guiderate) \
  30         w_cvar(id, sn, NONE, guideratedelay) \
  31         w_cvar(id, sn, NONE, guidestop) \
  32         w_cvar(id, sn, NONE, health) \
  33         w_cvar(id, sn, NONE, lifetime) \
  34         w_cvar(id, sn, NONE, radius) \
  35         w_cvar(id, sn, NONE, refire) \
  36         w_cvar(id, sn, NONE, remote_damage) \
  37         w_cvar(id, sn, NONE, remote_edgedamage) \
  38         w_cvar(id, sn, NONE, remote_force) \
  39         w_cvar(id, sn, NONE, remote_radius) \
  40         w_cvar(id, sn, NONE, speed) \
  41         w_cvar(id, sn, NONE, speedaccel) \
  42         w_cvar(id, sn, NONE, speedstart) \
  43         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  44         w_prop(id, sn, float,  reloading_time, reload_time) \
  45         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  46         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  47         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  48         w_prop(id, sn, float,  weaponstart, weaponstart) \
  49         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  50
  51 #ifdef SVQC
  52 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  53 .float rl_release;
  54 .float rl_detonate_later;
  55 #endif
  56 #else
  57 #ifdef SVQC
  58 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  59 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  60
  61 void W_Devastator_Unregister()
  62 {
  63         if(self.realowner && self.realowner.lastrocket == self)
  64         {
  65                 self.realowner.lastrocket = world;
  66                 // self.realowner.rl_release = 1;
  67         }
  68 }
  69
  70 void W_Devastator_Explode()
  71 {
  72         W_Devastator_Unregister();
  73
  74         if(other.takedamage == DAMAGE_AIM)
  75                 if(IS_PLAYER(other))
  76                         if(DIFF_TEAM(self.realowner, other))
  77                                 if(other.deadflag == DEAD_NO)
  78                                         if(IsFlying(other))
  79                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  80
  81         self.event_damage = func_null;
  82         self.takedamage = DAMAGE_NO;
  83
  84         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  85
  86         if (self.realowner.weapon == WEP_DEVASTATOR)
  87         {
  88                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
  89                 {
  90                         self.realowner.cnt = WEP_DEVASTATOR;
  91                         ATTACK_FINISHED(self.realowner) = time;
  92                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  93                 }
  94         }
  95         remove (self);
  96 }
  97
  98 void W_Devastator_DoRemoteExplode()
  99 {
 100         W_Devastator_Unregister();
 101
 102         self.event_damage = func_null;
 103         self.takedamage = DAMAGE_NO;
 104
 105         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 106
 107         if (self.realowner.weapon == WEP_DEVASTATOR)
 108         {
 109                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 110                 {
 111                         self.realowner.cnt = WEP_DEVASTATOR;
 112                         ATTACK_FINISHED(self.realowner) = time;
 113                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 114                 }
 115         }
 116         remove (self);
 117 }
 118
 119 void W_Devastator_RemoteExplode()
 120 {
 121         if(self.realowner.deadflag == DEAD_NO)
 122         if(self.realowner.lastrocket)
 123         {
 124                 if((self.spawnshieldtime >= 0)
 125                         ? (time >= self.spawnshieldtime) // timer
 126                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 127                 )
 128                 {
 129                         W_Devastator_DoRemoteExplode();
 130                 }
 131         }
 132 }
 133
 134 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 135 {
 136         if(thisdir * goaldir > maxturn_cos)
 137                 return goaldir;
 138         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 139                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 140         float f, m2;
 141         vector v;
 142         // solve:
 143         //   g = normalize(thisdir + goaldir * X)
 144         //   thisdir * g = maxturn
 145         //
 146         //   gg = thisdir + goaldir * X
 147         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 148         //
 149         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 150         f = thisdir * goaldir;
 151         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 152         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 153         m2 = maxturn_cos * maxturn_cos;
 154         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 155         return normalize(thisdir + goaldir * v_y); // the larger solution!
 156 }
 157 // assume thisdir == -goaldir:
 158 //   f == -1
 159 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 160 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 161 //   x^2 - 2 * x + 1 = 0
 162 //   (x - 1)^2 = 0
 163 //   x = 1
 164 //   normalize(thisdir + goaldir)
 165 //   normalize(0)
 166
 167 void W_Devastator_Think (void)
 168 {
 169         vector desireddir, olddir, newdir, desiredorigin, goal;
 170 #if 0
 171         float cosminang, cosmaxang, cosang;
 172 #endif
 173         float velspeed, f;
 174         self.nextthink = time;
 175         if (time > self.cnt)
 176         {
 177                 other = world;
 178                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 179                 W_Devastator_Explode ();
 180                 return;
 181         }
 182
 183         // accelerate
 184         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 185         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 186         if (velspeed > 0)
 187                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 188
 189         // laser guided, or remote detonation
 190         if (self.realowner.weapon == WEP_DEVASTATOR)
 191         {
 192                 if(self == self.realowner.lastrocket)
 193                 if(!self.realowner.rl_release)
 194                 if(!self.BUTTON_ATCK2)
 195                 if(WEP_CVAR(devastator, guiderate))
 196                 if(time > self.pushltime)
 197                 if(self.realowner.deadflag == DEAD_NO)
 198                 {
 199                         f = WEP_CVAR(devastator, guideratedelay);
 200                         if(f)
 201                                 f = bound(0, (time - self.pushltime) / f, 1);
 202                         else
 203                                 f = 1;
 204
 205                         velspeed = vlen(self.velocity);
 206
 207                         makevectors(self.realowner.v_angle);
 208                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 209                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 210                         olddir = normalize(self.velocity);
 211
 212                         // now it gets tricky... we want to move like some curve to approximate the target direction
 213                         // but we are limiting the rate at which we can turn!
 214                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 215                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 216
 217                         self.velocity = newdir * velspeed;
 218                         self.angles = vectoangles(self.velocity);
 219
 220                         if(!self.count)
 221                         {
 222                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 223                                 // TODO add a better sound here
 224                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 225                                 self.count = 1;
 226                         }
 227                 }
 228
 229                 if(self.rl_detonate_later)
 230                         W_Devastator_RemoteExplode();
 231         }
 232
 233         if(self.csqcprojectile_clientanimate == 0)
 234                 UpdateCSQCProjectile(self);
 235 }
 236
 237 void W_Devastator_Touch (void)
 238 {
 239         if(WarpZone_Projectile_Touch())
 240         {
 241                 if(wasfreed(self))
 242                         W_Devastator_Unregister();
 243                 return;
 244         }
 245         W_Devastator_Unregister();
 246         W_Devastator_Explode ();
 247 }
 248
 249 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 250 {
 251         if (self.health <= 0)
 252                 return;
 253
 254         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 255                 return; // g_projectiles_damage says to halt
 256
 257         self.health = self.health - damage;
 258         self.angles = vectoangles(self.velocity);
 259
 260         if (self.health <= 0)
 261                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 262 }
 263
 264 void W_Devastator_Attack (void)
 265 {
 266         entity missile;
 267         entity flash;
 268
 269         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 270
 271         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 272         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 273
 274         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 275         missile.owner = missile.realowner = self;
 276         self.lastrocket = missile;
 277         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 278                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 279         else
 280                 missile.spawnshieldtime = -1;
 281         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 282         missile.classname = "rocket";
 283         missile.bot_dodge = TRUE;
 284         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 285
 286         missile.takedamage = DAMAGE_YES;
 287         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 288         missile.health = WEP_CVAR(devastator, health);
 289         missile.event_damage = W_Devastator_Damage;
 290         missile.damagedbycontents = TRUE;
 291
 292         missile.movetype = MOVETYPE_FLY;
 293         PROJECTILE_MAKETRIGGER(missile);
 294         missile.projectiledeathtype = WEP_DEVASTATOR;
 295         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 296
 297         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 298         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 299         missile.angles = vectoangles (missile.velocity);
 300
 301         missile.touch = W_Devastator_Touch;
 302         missile.think = W_Devastator_Think;
 303         missile.nextthink = time;
 304         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 305         missile.flags = FL_PROJECTILE;
 306         missile.missile_flags = MIF_SPLASH;
 307
 308         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 309
 310         // muzzle flash for 1st person view
 311         flash = spawn ();
 312         setmodel (flash, "models/flash.md3"); // precision set below
 313         SUB_SetFade (flash, time, 0.1);
 314         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 315         W_AttachToShotorg(flash, '5 0 0');
 316
 317         // common properties
 318         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 319 }
 320
 321 float W_Devastator(float req)
 322 {
 323         entity rock;
 324         float rockfound;
 325         float ammo_amount;
 326         switch(req)
 327         {
 328                 #if 0
 329                 case WR_AIM:
 330                 {
 331                         // aim and decide to fire if appropriate
 332                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 333                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 334                         {
 335                                 // decide whether to detonate rockets
 336                                 entity missile, targetlist, targ;
 337                                 targetlist = findchainfloat(bot_attack, TRUE);
 338                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 339                                 {
 340                                         targ = targetlist;
 341                                         while(targ)
 342                                         {
 343                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 344                                                 {
 345                                                         self.BUTTON_ATCK2 = TRUE;
 346                                                         break;
 347                                                 }
 348                                                 targ = targ.chain;
 349                                         }
 350                                 }
 351
 352                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 353                         }
 354
 355                         return TRUE;
 356                 }
 357                 #else
 358                 case WR_AIM:
 359                 {
 360                         // aim and decide to fire if appropriate
 361                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 362                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 363                         {
 364                                 // decide whether to detonate rockets
 365                                 entity missile, targetlist, targ;
 366                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 367                                 float selfdamage, teamdamage, enemydamage;
 368                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 369                                 coredamage = WEP_CVAR(devastator, damage);
 370                                 edgeradius = WEP_CVAR(devastator, radius);
 371                                 recipricoledgeradius = 1 / edgeradius;
 372                                 selfdamage = 0;
 373                                 teamdamage = 0;
 374                                 enemydamage = 0;
 375                                 targetlist = findchainfloat(bot_attack, TRUE);
 376                                 missile = find(world, classname, "rocket");
 377                                 while (missile)
 378                                 {
 379                                         if (missile.realowner != self)
 380                                         {
 381                                                 missile = find(missile, classname, "rocket");
 382                                                 continue;
 383                                         }
 384                                         targ = targetlist;
 385                                         while (targ)
 386                                         {
 387                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 388                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 389                                                 // count potential damage according to type of target
 390                                                 if (targ == self)
 391                                                         selfdamage = selfdamage + d;
 392                                                 else if (targ.team == self.team && teamplay)
 393                                                         teamdamage = teamdamage + d;
 394                                                 else if (bot_shouldattack(targ))
 395                                                         enemydamage = enemydamage + d;
 396                                                 targ = targ.chain;
 397                                         }
 398                                         missile = find(missile, classname, "rocket");
 399                                 }
 400                                 float desirabledamage;
 401                                 desirabledamage = enemydamage;
 402                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 403                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 404                                 if (teamplay && self.team)
 405                                         desirabledamage = desirabledamage - teamdamage;
 406
 407                                 missile = find(world, classname, "rocket");
 408                                 while (missile)
 409                                 {
 410                                         if (missile.realowner != self)
 411                                         {
 412                                                 missile = find(missile, classname, "rocket");
 413                                                 continue;
 414                                         }
 415                                         makevectors(missile.v_angle);
 416                                         targ = targetlist;
 417                                         if (skill > 9) // normal players only do this for the target they are tracking
 418                                         {
 419                                                 targ = targetlist;
 420                                                 while (targ)
 421                                                 {
 422                                                         if (
 423                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 424                                                                 && desirabledamage > 0.1*coredamage
 425                                                         )self.BUTTON_ATCK2 = TRUE;
 426                                                         targ = targ.chain;
 427                                                 }
 428                                         }else{
 429                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 430                                                 //As the distance gets larger, a correct detonation gets near imposible
 431                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 432                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 433                                                         if(IS_PLAYER(self.enemy))
 434                                                                 if(desirabledamage >= 0.1*coredamage)
 435                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 436                                                                                 self.BUTTON_ATCK2 = TRUE;
 437                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 438                                         }
 439
 440                                         missile = find(missile, classname, "rocket");
 441                                 }
 442                                 // if we would be doing at X percent of the core damage, detonate it
 443                                 // but don't fire a new shot at the same time!
 444                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 445                                         self.BUTTON_ATCK2 = TRUE;
 446                                 if ((skill > 6.5) && (selfdamage > self.health))
 447                                         self.BUTTON_ATCK2 = FALSE;
 448                                 //if(self.BUTTON_ATCK2 == TRUE)
 449                                 //      dprint(ftos(desirabledamage),"\n");
 450                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 451                         }
 452
 453                         return TRUE;
 454                 }
 455                 #endif
 456                 case WR_THINK:
 457                 {
 458                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 459                                 WEP_ACTION(self.weapon, WR_RELOAD);
 460                         else
 461                         {
 462                                 if(self.BUTTON_ATCK)
 463                                 {
 464                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 465                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 466                                         {
 467                                                 W_Devastator_Attack();
 468                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 469                                                 self.rl_release = 0;
 470                                         }
 471                                 }
 472                                 else
 473                                         self.rl_release = 1;
 474
 475                                 if(self.BUTTON_ATCK2)
 476                                 {
 477                                         rockfound = 0;
 478                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 479                                         {
 480                                                 if(!rock.rl_detonate_later)
 481                                                 {
 482                                                         rock.rl_detonate_later = TRUE;
 483                                                         rockfound = 1;
 484                                                 }
 485                                         }
 486                                         if(rockfound)
 487                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 488                                 }
 489                         }
 490
 491                         return TRUE;
 492                 }
 493                 case WR_INIT:
 494                 {
 495                         if(autocvar_sv_precacheweapons)
 496                         {
 497                                 precache_model("models/flash.md3");
 498                                 precache_model("models/weapons/g_rl.md3");
 499                                 precache_model("models/weapons/v_rl.md3");
 500                                 precache_model("models/weapons/h_rl.iqm");
 501                                 precache_sound("weapons/rocket_det.wav");
 502                                 precache_sound("weapons/rocket_fire.wav");
 503                                 precache_sound("weapons/rocket_mode.wav");
 504                         }
 505                         DEVASTATOR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 506                         return TRUE;
 507                 }
 508                 case WR_SETUP:
 509                 {
 510                         self.rl_release = 1;
 511                         return TRUE;
 512                 }
 513                 case WR_CHECKAMMO1:
 514                 {
 515                         #if 0
 516                         // don't switch while guiding a missile
 517                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 518                         {
 519                                 ammo_amount = FALSE;
 520                                 if(WEP_CVAR(devastator, reload_ammo))
 521                                 {
 522                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 523                                                 ammo_amount = TRUE;
 524                                 }
 525                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 526                                         ammo_amount = TRUE;
 527                                 return !ammo_amount;
 528                         }
 529                         #endif
 530                         #if 0
 531                         if(self.rl_release == 0)
 532                         {
 533                                 printf("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo));
 534                                 return TRUE;
 535                         }
 536                         else
 537                         {
 538                                 ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 539                                 ammo_amount += self.(weapon_load[WEP_DEVASTATOR]) >= WEP_CVAR(devastator, ammo);
 540                                 printf("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 541                                 return ammo_amount;
 542                         }
 543                         #else
 544                         ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 545                         ammo_amount += self.(weapon_load[WEP_DEVASTATOR]) >= WEP_CVAR(devastator, ammo);
 546                         return ammo_amount;
 547                         #endif
 548                 }
 549                 case WR_CHECKAMMO2:
 550                 {
 551                         return FALSE;
 552                 }
 553                 case WR_CONFIG:
 554                 {
 555                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 556                         return TRUE;
 557                 }
 558                 case WR_RESETPLAYER:
 559                 {
 560                         self.rl_release = 0;
 561                         return TRUE;
 562                 }
 563                 case WR_RELOAD:
 564                 {
 565                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 566                         return TRUE;
 567                 }
 568                 case WR_SUICIDEMESSAGE:
 569                 {
 570                         return WEAPON_DEVASTATOR_SUICIDE;
 571                 }
 572                 case WR_KILLMESSAGE:
 573                 {
 574                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 575                                 return WEAPON_DEVASTATOR_MURDER_SPLASH;
 576                         else
 577                                 return WEAPON_DEVASTATOR_MURDER_DIRECT;
 578                 }
 579         }
 580         return FALSE;
 581 }
 582 #endif
 583 #ifdef CSQC
 584 float W_Devastator(float req)
 585 {
 586         switch(req)
 587         {
 588                 case WR_IMPACTEFFECT:
 589                 {
 590                         vector org2;
 591                         org2 = w_org + w_backoff * 12;
 592                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 593                         if(!w_issilent)
 594                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 595
 596                         return TRUE;
 597                 }
 598                 case WR_INIT:
 599                 {
 600                         precache_sound("weapons/rocket_impact.wav");
 601                         return TRUE;
 602                 }
 603                 case WR_ZOOMRETICLE:
 604                 {
 605                         // no weapon specific image for this weapon
 606                         return FALSE;
 607                 }
 608         }
 609         return FALSE;
 610 }
 611 #endif
 612 #endif