qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ DEVASTATOR,
   4 /* function */ W_Devastator,
   5 /* ammotype */ ammo_rockets,
   6 /* impulse  */ 9,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* color        */ '1 1 0',
  10 /* model    */ "rl",
  11 /* netname  */ "devastator",
  12 /* fullname */ _("Devastator")
  13 );
  14
  15 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  16 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  17         w_cvar(id, sn, NONE, ammo) \
  18         w_cvar(id, sn, NONE, animtime) \
  19         w_cvar(id, sn, NONE, damage) \
  20         w_cvar(id, sn, NONE, damageforcescale) \
  21         w_cvar(id, sn, NONE, detonatedelay) \
  22         w_cvar(id, sn, NONE, edgedamage) \
  23         w_cvar(id, sn, NONE, force) \
  24         w_cvar(id, sn, NONE, guidedelay) \
  25         w_cvar(id, sn, NONE, guidegoal) \
  26         w_cvar(id, sn, NONE, guiderate) \
  27         w_cvar(id, sn, NONE, guideratedelay) \
  28         w_cvar(id, sn, NONE, guidestop) \
  29         w_cvar(id, sn, NONE, health) \
  30         w_cvar(id, sn, NONE, lifetime) \
  31         w_cvar(id, sn, NONE, radius) \
  32         w_cvar(id, sn, NONE, refire) \
  33         w_cvar(id, sn, NONE, remote_damage) \
  34         w_cvar(id, sn, NONE, remote_edgedamage) \
  35         w_cvar(id, sn, NONE, remote_force) \
  36         w_cvar(id, sn, NONE, remote_radius) \
  37         w_cvar(id, sn, NONE, speed) \
  38         w_cvar(id, sn, NONE, speedaccel) \
  39         w_cvar(id, sn, NONE, speedstart) \
  40         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  41         w_prop(id, sn, float,  reloading_time, reload_time) \
  42         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  43         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  44         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  45         w_prop(id, sn, float,  weaponstart, weaponstart) \
  46         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  47
  48 #ifdef SVQC
  49 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  50 .float rl_release;
  51 .float rl_detonate_later;
  52 #endif
  53 #else
  54 #ifdef SVQC
  55 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  56 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  57
  58 void W_Devastator_Unregister()
  59 {
  60         if(self.realowner && self.realowner.lastrocket == self)
  61         {
  62                 self.realowner.lastrocket = world;
  63                 // self.realowner.rl_release = 1;
  64         }
  65 }
  66
  67 void W_Devastator_Explode()
  68 {
  69         W_Devastator_Unregister();
  70
  71         if(other.takedamage == DAMAGE_AIM)
  72                 if(IS_PLAYER(other))
  73                         if(DIFF_TEAM(self.realowner, other))
  74                                 if(other.deadflag == DEAD_NO)
  75                                         if(IsFlying(other))
  76                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  77
  78         self.event_damage = func_null;
  79         self.takedamage = DAMAGE_NO;
  80
  81         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  82
  83         if (self.realowner.weapon == WEP_DEVASTATOR)
  84         {
  85                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
  86                 {
  87                         self.realowner.cnt = WEP_DEVASTATOR;
  88                         ATTACK_FINISHED(self.realowner) = time;
  89                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  90                 }
  91         }
  92         remove (self);
  93 }
  94
  95 void W_Devastator_DoRemoteExplode()
  96 {
  97         W_Devastator_Unregister();
  98
  99         self.event_damage = func_null;
 100         self.takedamage = DAMAGE_NO;
 101
 102         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 103
 104         if (self.realowner.weapon == WEP_DEVASTATOR)
 105         {
 106                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 107                 {
 108                         self.realowner.cnt = WEP_DEVASTATOR;
 109                         ATTACK_FINISHED(self.realowner) = time;
 110                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 111                 }
 112         }
 113         remove (self);
 114 }
 115
 116 void W_Devastator_RemoteExplode()
 117 {
 118         if(self.realowner.deadflag == DEAD_NO)
 119         if(self.realowner.lastrocket)
 120         {
 121                 if((self.spawnshieldtime >= 0)
 122                         ? (time >= self.spawnshieldtime) // timer
 123                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 124                 )
 125                 {
 126                         W_Devastator_DoRemoteExplode();
 127                 }
 128         }
 129 }
 130
 131 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 132 {
 133         if(thisdir * goaldir > maxturn_cos)
 134                 return goaldir;
 135         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 136                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 137         float f, m2;
 138         vector v;
 139         // solve:
 140         //   g = normalize(thisdir + goaldir * X)
 141         //   thisdir * g = maxturn
 142         //
 143         //   gg = thisdir + goaldir * X
 144         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 145         //
 146         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 147         f = thisdir * goaldir;
 148         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 149         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 150         m2 = maxturn_cos * maxturn_cos;
 151         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 152         return normalize(thisdir + goaldir * v_y); // the larger solution!
 153 }
 154 // assume thisdir == -goaldir:
 155 //   f == -1
 156 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 157 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 158 //   x^2 - 2 * x + 1 = 0
 159 //   (x - 1)^2 = 0
 160 //   x = 1
 161 //   normalize(thisdir + goaldir)
 162 //   normalize(0)
 163
 164 void W_Devastator_Think (void)
 165 {
 166         vector desireddir, olddir, newdir, desiredorigin, goal;
 167 #if 0
 168         float cosminang, cosmaxang, cosang;
 169 #endif
 170         float velspeed, f;
 171         self.nextthink = time;
 172         if (time > self.cnt)
 173         {
 174                 other = world;
 175                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 176                 W_Devastator_Explode ();
 177                 return;
 178         }
 179
 180         // accelerate
 181         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 182         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 183         if (velspeed > 0)
 184                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 185
 186         // laser guided, or remote detonation
 187         if (self.realowner.weapon == WEP_DEVASTATOR)
 188         {
 189                 if(self == self.realowner.lastrocket)
 190                 if(!self.realowner.rl_release)
 191                 if(!self.BUTTON_ATCK2)
 192                 if(WEP_CVAR(devastator, guiderate))
 193                 if(time > self.pushltime)
 194                 if(self.realowner.deadflag == DEAD_NO)
 195                 {
 196                         f = WEP_CVAR(devastator, guideratedelay);
 197                         if(f)
 198                                 f = bound(0, (time - self.pushltime) / f, 1);
 199                         else
 200                                 f = 1;
 201
 202                         velspeed = vlen(self.velocity);
 203
 204                         makevectors(self.realowner.v_angle);
 205                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 206                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 207                         olddir = normalize(self.velocity);
 208
 209                         // now it gets tricky... we want to move like some curve to approximate the target direction
 210                         // but we are limiting the rate at which we can turn!
 211                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 212                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 213
 214                         self.velocity = newdir * velspeed;
 215                         self.angles = vectoangles(self.velocity);
 216
 217                         if(!self.count)
 218                         {
 219                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 220                                 // TODO add a better sound here
 221                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 222                                 self.count = 1;
 223                         }
 224                 }
 225
 226                 if(self.rl_detonate_later)
 227                         W_Devastator_RemoteExplode();
 228         }
 229
 230         if(self.csqcprojectile_clientanimate == 0)
 231                 UpdateCSQCProjectile(self);
 232 }
 233
 234 void W_Devastator_Touch (void)
 235 {
 236         if(WarpZone_Projectile_Touch())
 237         {
 238                 if(wasfreed(self))
 239                         W_Devastator_Unregister();
 240                 return;
 241         }
 242         W_Devastator_Unregister();
 243         W_Devastator_Explode ();
 244 }
 245
 246 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 247 {
 248         if (self.health <= 0)
 249                 return;
 250
 251         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 252                 return; // g_projectiles_damage says to halt
 253
 254         self.health = self.health - damage;
 255         self.angles = vectoangles(self.velocity);
 256
 257         if (self.health <= 0)
 258                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 259 }
 260
 261 void W_Devastator_Attack (void)
 262 {
 263         entity missile;
 264         entity flash;
 265
 266         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 267
 268         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 269         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 270
 271         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 272         missile.owner = missile.realowner = self;
 273         self.lastrocket = missile;
 274         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 275                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 276         else
 277                 missile.spawnshieldtime = -1;
 278         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 279         missile.classname = "rocket";
 280         missile.bot_dodge = TRUE;
 281         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 282
 283         missile.takedamage = DAMAGE_YES;
 284         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 285         missile.health = WEP_CVAR(devastator, health);
 286         missile.event_damage = W_Devastator_Damage;
 287         missile.damagedbycontents = TRUE;
 288
 289         missile.movetype = MOVETYPE_FLY;
 290         PROJECTILE_MAKETRIGGER(missile);
 291         missile.projectiledeathtype = WEP_DEVASTATOR;
 292         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 293
 294         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 295         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 296         missile.angles = vectoangles (missile.velocity);
 297
 298         missile.touch = W_Devastator_Touch;
 299         missile.think = W_Devastator_Think;
 300         missile.nextthink = time;
 301         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 302         missile.flags = FL_PROJECTILE;
 303         missile.missile_flags = MIF_SPLASH;
 304
 305         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 306
 307         // muzzle flash for 1st person view
 308         flash = spawn ();
 309         setmodel (flash, "models/flash.md3"); // precision set below
 310         SUB_SetFade (flash, time, 0.1);
 311         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 312         W_AttachToShotorg(flash, '5 0 0');
 313
 314         // common properties
 315         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 316 }
 317
 318 float W_Devastator(float req)
 319 {
 320         entity rock;
 321         float rockfound;
 322         float ammo_amount;
 323         switch(req)
 324         {
 325                 case WR_AIM: // WEAPONTODO: rewrite this, it's WAY too complicated for what it should be
 326                 {
 327                         // aim and decide to fire if appropriate
 328                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 329                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 330                         {
 331                                 // decide whether to detonate rockets
 332                                 entity missile, targetlist, targ;
 333                                 targetlist = findchainfloat(bot_attack, TRUE);
 334                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 335                                 {
 336                                         targ = targetlist;
 337                                         while(targ)
 338                                         {
 339                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 340                                                 {
 341                                                         self.BUTTON_ATCK2 = TRUE;
 342                                                         break;
 343                                                 }
 344                                                 targ = targ.chain;
 345                                         }
 346                                 }
 347
 348                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 349                         }
 350
 351                         return TRUE;
 352                 }
 353                 case WR_THINK:
 354                 {
 355                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 356                                 WEP_ACTION(self.weapon, WR_RELOAD);
 357                         else
 358                         {
 359                                 if(self.BUTTON_ATCK)
 360                                 {
 361                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 362                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 363                                         {
 364                                                 W_Devastator_Attack();
 365                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 366                                                 self.rl_release = 0;
 367                                         }
 368                                 }
 369                                 else
 370                                         self.rl_release = 1;
 371
 372                                 if(self.BUTTON_ATCK2)
 373                                 {
 374                                         rockfound = 0;
 375                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 376                                         {
 377                                                 if(!rock.rl_detonate_later)
 378                                                 {
 379                                                         rock.rl_detonate_later = TRUE;
 380                                                         rockfound = 1;
 381                                                 }
 382                                         }
 383                                         if(rockfound)
 384                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 385                                 }
 386                         }
 387
 388                         return TRUE;
 389                 }
 390                 case WR_INIT:
 391                 {
 392                         if(autocvar_sv_precacheweapons)
 393                         {
 394                                 precache_model("models/flash.md3");
 395                                 precache_model("models/weapons/g_rl.md3");
 396                                 precache_model("models/weapons/v_rl.md3");
 397                                 precache_model("models/weapons/h_rl.iqm");
 398                                 precache_sound("weapons/rocket_det.wav");
 399                                 precache_sound("weapons/rocket_fire.wav");
 400                                 precache_sound("weapons/rocket_mode.wav");
 401                         }
 402                         DEVASTATOR_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 403                         return TRUE;
 404                 }
 405                 case WR_SETUP:
 406                 {
 407                         self.rl_release = 1;
 408                         return TRUE;
 409                 }
 410                 case WR_CHECKAMMO1:
 411                 {
 412                         // don't switch while guiding a missile
 413                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 414                         {
 415                                 ammo_amount = FALSE;
 416                                 if(WEP_CVAR(devastator, reload_ammo))
 417                                 {
 418                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 419                                                 ammo_amount = TRUE;
 420                                 }
 421                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 422                                         ammo_amount = TRUE;
 423                                 return !ammo_amount;
 424                         }
 425
 426                         return TRUE;
 427                 }
 428                 case WR_CHECKAMMO2:
 429                 {
 430                         return FALSE;
 431                 }
 432                 case WR_CONFIG:
 433                 {
 434                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 435                         return TRUE;
 436                 }
 437                 case WR_RESETPLAYER:
 438                 {
 439                         self.rl_release = 0;
 440                         return TRUE;
 441                 }
 442                 case WR_RELOAD:
 443                 {
 444                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 445                         return TRUE;
 446                 }
 447                 case WR_SUICIDEMESSAGE:
 448                 {
 449                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 450                 }
 451                 case WR_KILLMESSAGE:
 452                 {
 453                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 454                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 455                         else
 456                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 457                 }
 458         }
 459         return TRUE;
 460 }
 461 #endif
 462 #ifdef CSQC
 463 float W_Devastator(float req)
 464 {
 465         switch(req)
 466         {
 467                 case WR_IMPACTEFFECT:
 468                 {
 469                         vector org2;
 470                         org2 = w_org + w_backoff * 12;
 471                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 472                         if(!w_issilent)
 473                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 474
 475                         return TRUE;
 476                 }
 477                 case WR_INIT:
 478                 {
 479                         precache_sound("weapons/rocket_impact.wav");
 480                         return TRUE;
 481                 }
 482                 case WR_ZOOMRETICLE:
 483                 {
 484                         // no weapon specific image for this weapon
 485                         return FALSE;
 486                 }
 487         }
 488         return TRUE;
 489 }
 490 #endif
 491 #endif