qcsrc/common/weapons/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ ELECTRO,
   4 /* function  */ w_electro,
   5 /* ammotype  */ IT_CELLS,
   6 /* impulse   */ 5,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* model     */ "electro",
  10 /* shortname */ "electro",
  11 /* fullname  */ _("Electro")
  12 );
  13
  14 #ifdef SVQC
  15 void ElectroInit();
  16 vector electro_shotorigin[4];
  17 #endif
  18 #else
  19 #ifdef SVQC
  20 void spawnfunc_weapon_electro() { weapon_defaultspawnfunc(WEP_ELECTRO); }
  21
  22 .float electro_count;
  23 .float electro_secondarytime;
  24
  25 void W_Plasma_Explode_Combo (void);
  26
  27 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  28 {
  29         entity e;
  30         e = WarpZone_FindRadius(org, rad, TRUE);
  31         while (e)
  32         {
  33                 if (e.classname == "plasma")
  34                 {
  35                         // change owner to whoever caused the combo explosion
  36                         e.realowner = own;
  37                         e.takedamage = DAMAGE_NO;
  38                         e.classname = "plasma_chain";
  39                         e.think = W_Plasma_Explode_Combo;
  40                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
  41                 }
  42                 e = e.chain;
  43         }
  44 }
  45
  46 void W_Plasma_Explode (void)
  47 {
  48         if(other.takedamage == DAMAGE_AIM)
  49                 if(IS_PLAYER(other))
  50                         if(IsDifferentTeam(self.realowner, other))
  51                                 if(other.deadflag == DEAD_NO)
  52                                         if(IsFlying(other))
  53                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
  54
  55         self.event_damage = func_null;
  56         self.takedamage = DAMAGE_NO;
  57         if (self.movetype == MOVETYPE_BOUNCE)
  58         {
  59                 RadiusDamage (self, self.realowner, autocvar_g_balance_electro_secondary_damage, autocvar_g_balance_electro_secondary_edgedamage, autocvar_g_balance_electro_secondary_radius, world, world, autocvar_g_balance_electro_secondary_force, self.projectiledeathtype, other);
  60         }
  61         else
  62         {
  63                 W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_primary_comboradius, self.realowner);
  64                 RadiusDamage (self, self.realowner, autocvar_g_balance_electro_primary_damage, autocvar_g_balance_electro_primary_edgedamage, autocvar_g_balance_electro_primary_radius, world, world, autocvar_g_balance_electro_primary_force, self.projectiledeathtype, other);
  65         }
  66
  67         remove (self);
  68 }
  69
  70 void W_Plasma_Explode_Combo (void)
  71 {
  72         W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_combo_comboradius, self.realowner);
  73
  74         self.event_damage = func_null;
  75         RadiusDamage (self, self.realowner, autocvar_g_balance_electro_combo_damage, autocvar_g_balance_electro_combo_edgedamage, autocvar_g_balance_electro_combo_radius, world, world, autocvar_g_balance_electro_combo_force, WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  76
  77         remove (self);
  78 }
  79
  80 void W_Plasma_Touch (void)
  81 {
  82         //self.velocity = self.velocity  * 0.1;
  83
  84         PROJECTILE_TOUCH;
  85         if (other.takedamage == DAMAGE_AIM) {
  86                 W_Plasma_Explode ();
  87         } else {
  88                 //UpdateCSQCProjectile(self);
  89                 spamsound (self, CH_SHOTS, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  90                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  91         }
  92 }
  93
  94 void W_Plasma_TouchExplode (void)
  95 {
  96         PROJECTILE_TOUCH;
  97         W_Plasma_Explode ();
  98 }
  99
 100 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 101 {
 102         if(self.health <= 0)
 103                 return;
 104
 105         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
 106         float is_combo = (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim");
 107
 108         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_combo ? 1 : -1)))
 109                 return; // g_projectiles_damage says to halt
 110
 111         self.health = self.health - damage;
 112         if (self.health <= 0)
 113         {
 114                 self.takedamage = DAMAGE_NO;
 115                 self.nextthink = time;
 116                 if (is_combo)
 117                 {
 118                         // change owner to whoever caused the combo explosion
 119                         self.realowner = inflictor.realowner;
 120                         self.classname = "plasma_chain";
 121                         self.think = W_Plasma_Explode_Combo;
 122                         self.nextthink = time + min(autocvar_g_balance_electro_combo_radius, vlen(self.origin - inflictor.origin)) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
 123                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
 124                 }
 125                 else
 126                 {
 127                         self.use = W_Plasma_Explode;
 128                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 129                 }
 130         }
 131 }
 132
 133 void W_Electro_Attack()
 134 {
 135         entity proj;
 136
 137         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_reload_ammo);
 138
 139         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CH_WEAPON_A, autocvar_g_balance_electro_primary_damage);
 140
 141         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 142
 143         proj = spawn ();
 144         proj.classname = "plasma_prim";
 145         proj.owner = proj.realowner = self;
 146         proj.bot_dodge = TRUE;
 147         proj.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 148         proj.use = W_Plasma_Explode;
 149         proj.think = adaptor_think2use_hittype_splash;
 150         proj.nextthink = time + autocvar_g_balance_electro_primary_lifetime;
 151         PROJECTILE_MAKETRIGGER(proj);
 152         proj.projectiledeathtype = WEP_ELECTRO;
 153         setorigin(proj, w_shotorg);
 154
 155         proj.movetype = MOVETYPE_FLY;
 156         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 157         proj.angles = vectoangles(proj.velocity);
 158         proj.touch = W_Plasma_TouchExplode;
 159         setsize(proj, '0 0 -3', '0 0 -3');
 160         proj.flags = FL_PROJECTILE;
 161         proj.missile_flags = MIF_SPLASH;
 162
 163         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 164
 165         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 166 }
 167
 168 void W_Electro_Attack2()
 169 {
 170         entity proj;
 171
 172         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_electro_secondary_ammo, autocvar_g_balance_electro_reload_ammo);
 173
 174         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, autocvar_g_balance_electro_secondary_damage);
 175
 176         w_shotdir = v_forward; // no TrueAim for grenades please
 177
 178         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 179
 180         proj = spawn ();
 181         proj.classname = "plasma";
 182         proj.owner = proj.realowner = self;
 183         proj.use = W_Plasma_Explode;
 184         proj.think = adaptor_think2use_hittype_splash;
 185         proj.bot_dodge = TRUE;
 186         proj.bot_dodgerating = autocvar_g_balance_electro_secondary_damage;
 187         proj.nextthink = time + autocvar_g_balance_electro_secondary_lifetime;
 188         PROJECTILE_MAKETRIGGER(proj);
 189         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 190         setorigin(proj, w_shotorg);
 191
 192         //proj.glow_size = 50;
 193         //proj.glow_color = 45;
 194         proj.movetype = MOVETYPE_BOUNCE;
 195         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 196         proj.touch = W_Plasma_Touch;
 197         setsize(proj, '0 0 -4', '0 0 -4');
 198         proj.takedamage = DAMAGE_YES;
 199         proj.damageforcescale = autocvar_g_balance_electro_secondary_damageforcescale;
 200         proj.health = autocvar_g_balance_electro_secondary_health;
 201         proj.event_damage = W_Plasma_Damage;
 202         proj.flags = FL_PROJECTILE;
 203         proj.damagedbycontents = (autocvar_g_balance_electro_secondary_damagedbycontents);
 204
 205         proj.bouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 206         proj.bouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 207         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 208
 209 #if 0
 210         entity p2;
 211         p2 = spawn();
 212         copyentity(proj, p2);
 213         setmodel(p2, "models/ebomb.mdl");
 214         setsize(p2, proj.mins, proj.maxs);
 215 #endif
 216
 217         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 218
 219         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 220 }
 221
 222 .vector hook_start, hook_end;
 223 float lgbeam_send(entity to, float sf)
 224 {
 225         WriteByte(MSG_ENTITY, ENT_CLIENT_ELECTRO_BEAM);
 226         sf = sf & 0x7F;
 227         if(sound_allowed(MSG_BROADCAST, self.realowner))
 228                 sf |= 0x80;
 229         WriteByte(MSG_ENTITY, sf);
 230         if(sf & 1)
 231         {
 232                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 233                 WriteCoord(MSG_ENTITY, autocvar_g_balance_electro_primary_range);
 234         }
 235         if(sf & 2)
 236         {
 237                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 238                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 239                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 240         }
 241         if(sf & 4)
 242         {
 243                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 244                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 245                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 246         }
 247         return TRUE;
 248 }
 249 .entity lgbeam;
 250 .float prevlgfire;
 251 float lgbeam_checkammo()
 252 {
 253         if(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO)
 254                 return TRUE;
 255         else if(autocvar_g_balance_electro_reload_ammo)
 256                 return self.realowner.clip_load > 0;
 257         else
 258                 return self.realowner.ammo_cells > 0;
 259 }
 260
 261 entity lgbeam_owner_ent;
 262 void lgbeam_think()
 263 {
 264         entity owner_player;
 265         owner_player = self.realowner;
 266
 267         owner_player.prevlgfire = time;
 268         if (self != owner_player.lgbeam)
 269         {
 270                 remove(self);
 271                 return;
 272         }
 273
 274         if (owner_player.weaponentity.state != WS_INUSE || !lgbeam_checkammo() || owner_player.deadflag != DEAD_NO || !owner_player.BUTTON_ATCK || owner_player.freezetag_frozen)
 275         {
 276                 if(self == owner_player.lgbeam)
 277                         owner_player.lgbeam = world;
 278                 remove(self);
 279                 return;
 280         }
 281
 282         self.nextthink = time;
 283
 284         makevectors(owner_player.v_angle);
 285
 286         float dt, f;
 287         dt = frametime;
 288
 289         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 290         if not(owner_player.items & IT_UNLIMITED_WEAPON_AMMO)
 291         {
 292                 if(autocvar_g_balance_electro_primary_ammo)
 293                 {
 294                         if(autocvar_g_balance_electro_reload_ammo)
 295                         {
 296                                 dt = min(dt, owner_player.clip_load / autocvar_g_balance_electro_primary_ammo);
 297                                 owner_player.clip_load = max(0, owner_player.clip_load - autocvar_g_balance_electro_primary_ammo * frametime);
 298                                 owner_player.(weapon_load[WEP_ELECTRO]) = owner_player.clip_load;
 299                         }
 300                         else
 301                         {
 302                                 dt = min(dt, owner_player.ammo_cells / autocvar_g_balance_electro_primary_ammo);
 303                                 owner_player.ammo_cells = max(0, owner_player.ammo_cells - autocvar_g_balance_electro_primary_ammo * frametime);
 304                         }
 305                 }
 306         }
 307
 308         W_SetupShot_Range(owner_player, TRUE, 0, "", 0, autocvar_g_balance_electro_primary_damage * dt, autocvar_g_balance_electro_primary_range);
 309         if(!lgbeam_owner_ent)
 310         {
 311                 lgbeam_owner_ent = spawn();
 312                 lgbeam_owner_ent.classname = "lgbeam_owner_ent";
 313         }
 314         WarpZone_traceline_antilag(lgbeam_owner_ent, w_shotorg, w_shotend, MOVE_NORMAL, lgbeam_owner_ent, ANTILAG_LATENCY(owner_player));
 315
 316         // apply the damage
 317         if(trace_ent)
 318         {
 319                 vector force;
 320                 force = w_shotdir * autocvar_g_balance_electro_primary_force + '0 0 1' * autocvar_g_balance_electro_primary_force_up;
 321
 322                 f = ExponentialFalloff(autocvar_g_balance_electro_primary_falloff_mindist, autocvar_g_balance_electro_primary_falloff_maxdist, autocvar_g_balance_electro_primary_falloff_halflifedist, vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - w_shotorg));
 323
 324                 if(accuracy_isgooddamage(owner_player, trace_ent))
 325                         accuracy_add(owner_player, WEP_ELECTRO, 0, autocvar_g_balance_electro_primary_damage * dt * f);
 326                 Damage (trace_ent, owner_player, owner_player, autocvar_g_balance_electro_primary_damage * dt * f, WEP_ELECTRO, trace_endpos, force * dt);
 327         }
 328         W_Plasma_TriggerCombo(trace_endpos, autocvar_g_balance_electro_primary_comboradius, owner_player);
 329
 330         // draw effect
 331         if(w_shotorg != self.hook_start)
 332         {
 333                 self.SendFlags |= 2;
 334                 self.hook_start = w_shotorg;
 335         }
 336         if(w_shotend != self.hook_end)
 337         {
 338                 self.SendFlags |= 4;
 339                 self.hook_end = w_shotend;
 340         }
 341 }
 342
 343 // experimental lightning gun
 344 void W_Electro_Attack3 (void)
 345 {
 346         // only play fire sound if 0.5 sec has passed since player let go the fire button
 347         if(time - self.prevlgfire > 0.5)
 348                 sound (self, CH_WEAPON_A, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 349
 350         entity beam, oldself;
 351
 352         self.lgbeam = beam = spawn();
 353         beam.classname = "lgbeam";
 354         beam.solid = SOLID_NOT;
 355         beam.think = lgbeam_think;
 356         beam.owner = beam.realowner = self;
 357         beam.movetype = MOVETYPE_NONE;
 358         beam.shot_spread = 0;
 359         beam.bot_dodge = TRUE;
 360         beam.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 361         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
 362
 363         oldself = self;
 364         self = beam;
 365         self.think();
 366         self = oldself;
 367 }
 368
 369 void ElectroInit()
 370 {
 371         WEP_ACTION(WEP_ELECTRO, WR_INIT);
 372         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 373         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 374         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 375         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 376 }
 377
 378 void w_electro_checkattack()
 379 {
 380         if(self.electro_count > 1)
 381         if(self.BUTTON_ATCK2)
 382         if(weapon_prepareattack(1, -1))
 383         {
 384                 W_Electro_Attack2();
 385                 self.electro_count -= 1;
 386                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 387                 return;
 388         }
 389
 390         w_ready();
 391 }
 392
 393 .float bot_secondary_electromooth;
 394 .float BUTTON_ATCK_prev;
 395 float w_electro(float req)
 396 {
 397         float ammo_amount;
 398         switch(req)
 399         {
 400                 case WR_AIM:
 401                 {
 402                         self.BUTTON_ATCK=FALSE;
 403                         self.BUTTON_ATCK2=FALSE;
 404                         if(vlen(self.origin-self.enemy.origin) > 1000)
 405                                 self.bot_secondary_electromooth = 0;
 406                         if(self.bot_secondary_electromooth == 0)
 407                         {
 408                                 float shoot;
 409
 410                                 if(autocvar_g_balance_electro_primary_speed)
 411                                         shoot = bot_aim(autocvar_g_balance_electro_primary_speed, 0, autocvar_g_balance_electro_primary_lifetime, FALSE);
 412                                 else
 413                                         shoot = bot_aim(1000000, 0, 0.001, FALSE);
 414
 415                                 if(shoot)
 416                                 {
 417                                         self.BUTTON_ATCK = TRUE;
 418                                         if(random() < 0.01) self.bot_secondary_electromooth = 1;
 419                                 }
 420                         }
 421                         else
 422                         {
 423                                 if(bot_aim(autocvar_g_balance_electro_secondary_speed, autocvar_g_balance_mortar_secondary_speed_up, autocvar_g_balance_electro_secondary_lifetime, TRUE)) // WHAT THE ACTUAL FUUUUUUUUUCK?!?!? WEAPONTODO
 424                                 {
 425                                         self.BUTTON_ATCK2 = TRUE;
 426                                         if(random() < 0.03) self.bot_secondary_electromooth = 0;
 427                                 }
 428                         }
 429
 430                         return TRUE;
 431                 }
 432                 case WR_THINK:
 433                 {
 434                         if(autocvar_g_balance_electro_reload_ammo) // forced reload
 435                         {
 436                                 ammo_amount = 0;
 437                                 if(autocvar_g_balance_electro_lightning)
 438                                 {
 439                                         if(self.clip_load > 0)
 440                                                 ammo_amount = 1;
 441                                 }
 442                                 else if(self.clip_load >= autocvar_g_balance_electro_primary_ammo)
 443                                         ammo_amount = 1;
 444                                 if(self.clip_load >= autocvar_g_balance_electro_secondary_ammo)
 445                                         ammo_amount += 1;
 446
 447                                 if(!ammo_amount)
 448                                 {
 449                                         WEP_ACTION(self.weapon, WR_RELOAD);
 450                                         return FALSE;
 451                                 }
 452
 453                                 return TRUE;
 454                         }
 455                         if (self.BUTTON_ATCK)
 456                         {
 457                                 if(autocvar_g_balance_electro_lightning)
 458                                         if(self.BUTTON_ATCK_prev)
 459                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 460
 461                                 if (weapon_prepareattack(0, (autocvar_g_balance_electro_lightning ? 0 : autocvar_g_balance_electro_primary_refire)))
 462                                 {
 463                                         if(autocvar_g_balance_electro_lightning)
 464                                         {
 465                                                 if ((!self.lgbeam) || wasfreed(self.lgbeam))
 466                                                 {
 467                                                         W_Electro_Attack3();
 468                                                 }
 469                                                 if(!self.BUTTON_ATCK_prev)
 470                                                 {
 471                                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 472                                                         self.BUTTON_ATCK_prev = 1;
 473                                                 }
 474                                         }
 475                                         else
 476                                         {
 477                                                 W_Electro_Attack();
 478                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 479                                         }
 480                                 }
 481                         } else {
 482                                 if(autocvar_g_balance_electro_lightning)
 483                                 {
 484                                         if (self.BUTTON_ATCK_prev != 0)
 485                                         {
 486                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 487                                                 ATTACK_FINISHED(self) = time + autocvar_g_balance_electro_primary_refire * W_WeaponRateFactor();
 488                                         }
 489                                         self.BUTTON_ATCK_prev = 0;
 490                                 }
 491
 492                                 if (self.BUTTON_ATCK2)
 493                                 {
 494                                         if (time >= self.electro_secondarytime)
 495                                         if (weapon_prepareattack(1, autocvar_g_balance_electro_secondary_refire))
 496                                         {
 497                                                 W_Electro_Attack2();
 498                                                 self.electro_count = autocvar_g_balance_electro_secondary_count;
 499                                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 500                                                 self.electro_secondarytime = time + autocvar_g_balance_electro_secondary_refire2 * W_WeaponRateFactor();
 501                                         }
 502                                 }
 503                         }
 504
 505                         return TRUE;
 506                 }
 507                 case WR_INIT:
 508                 {
 509                         precache_model ("models/weapons/g_electro.md3");
 510                         precache_model ("models/weapons/v_electro.md3");
 511                         precache_model ("models/weapons/h_electro.iqm");
 512                         precache_sound ("weapons/electro_bounce.wav");
 513                         precache_sound ("weapons/electro_fire.wav");
 514                         precache_sound ("weapons/electro_fire2.wav");
 515                         precache_sound ("weapons/electro_impact.wav");
 516                         precache_sound ("weapons/electro_impact_combo.wav");
 517
 518                         if(autocvar_g_balance_electro_lightning)
 519                                 precache_sound ("weapons/lgbeam_fire.wav");
 520
 521                         return TRUE;
 522                 }
 523                 case WR_SETUP:
 524                 {
 525                         weapon_setup(WEP_ELECTRO);
 526                         self.current_ammo = ammo_cells;
 527                         return TRUE;
 528                 }
 529                 case WR_CHECKAMMO1:
 530                 {
 531                         if(autocvar_g_balance_electro_lightning)
 532                         {
 533                                 if(!autocvar_g_balance_electro_primary_ammo)
 534                                         ammo_amount = 1;
 535                                 else
 536                                         ammo_amount = self.ammo_cells > 0;
 537                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) > 0;
 538                         }
 539                         else
 540                         {
 541                                 ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_primary_ammo;
 542                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_primary_ammo;
 543                         }
 544                         return ammo_amount;
 545                 }
 546                 case WR_CHECKAMMO2:
 547                 {
 548                         if(autocvar_g_balance_electro_combo_safeammocheck) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 549                         {
 550                                 ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo + autocvar_g_balance_electro_primary_ammo;
 551                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_secondary_ammo + autocvar_g_balance_electro_primary_ammo;
 552                         }
 553                         else
 554                         {
 555                                 ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo;
 556                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_secondary_ammo;
 557                         }
 558                         return ammo_amount;
 559                 }
 560                 case WR_RESETPLAYER:
 561                 {
 562                         self.electro_secondarytime = time;
 563                         return TRUE;
 564                 }
 565                 case WR_RELOAD:
 566                 {
 567                         W_Reload(min(autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_secondary_ammo), autocvar_g_balance_electro_reload_ammo, autocvar_g_balance_electro_reload_time, "weapons/reload.wav");
 568                         return TRUE;
 569                 }
 570                 case WR_SUICIDEMESSAGE:
 571                 {
 572                         if(w_deathtype & HITTYPE_SECONDARY)
 573                                 return WEAPON_ELECTRO_SUICIDE_ORBS;
 574                         else
 575                                 return WEAPON_ELECTRO_SUICIDE_BOLT;
 576                 }
 577                 case WR_KILLMESSAGE:
 578                 {
 579                         if(w_deathtype & HITTYPE_SECONDARY)
 580                         {
 581                                 return WEAPON_ELECTRO_MURDER_ORBS;
 582                         }
 583                         else
 584                         {
 585                                 if(w_deathtype & HITTYPE_BOUNCE)
 586                                         return WEAPON_ELECTRO_MURDER_COMBO;
 587                                 else
 588                                         return WEAPON_ELECTRO_MURDER_BOLT;
 589                         }
 590                 }
 591         }
 592         return TRUE;
 593 }
 594 #endif
 595 #ifdef CSQC
 596 float w_electro(float req)
 597 {
 598         switch(req)
 599         {
 600                 case WR_IMPACTEFFECT:
 601                 {
 602                         vector org2;
 603                         org2 = w_org + w_backoff * 6;
 604                         if(w_deathtype & HITTYPE_SECONDARY)
 605                         {
 606                                 pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 607                                 if(!w_issilent)
 608                                         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 609                         }
 610                         else
 611                         {
 612                                 if(w_deathtype & HITTYPE_BOUNCE)
 613                                 {
 614                                         // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 615                                         pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 616                                         if(!w_issilent)
 617                                                 sound(self, CH_SHOTS, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 618                                 }
 619                                 else
 620                                 {
 621                                         pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 622                                         if(!w_issilent)
 623                                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 624                                 }
 625                         }
 626
 627                         return TRUE;
 628                 }
 629                 case WR_INIT:
 630                 {
 631                         precache_sound("weapons/electro_impact.wav");
 632                         precache_sound("weapons/electro_impact_combo.wav");
 633                         return TRUE;
 634                 }
 635         }
 636         return TRUE;
 637 }
 638 #endif
 639 #endif