qcsrc/common/weapons/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ ELECTRO,
   4 /* function  */ w_electro,
   5 /* ammotype  */ IT_CELLS,
   6 /* impulse   */ 5,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* model     */ "electro",
  10 /* shortname */ "electro",
  11 /* fullname  */ _("Electro")
  12 );
  13
  14 #ifdef SVQC
  15 void ElectroInit();
  16 vector electro_shotorigin[4];
  17 #endif
  18 #else
  19 #ifdef SVQC
  20 .float electro_count;
  21 .float electro_secondarytime;
  22
  23 void W_Plasma_Explode_Combo (void);
  24
  25 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  26 {
  27         entity e;
  28         e = WarpZone_FindRadius(org, rad, TRUE);
  29         while (e)
  30         {
  31                 if (e.classname == "plasma")
  32                 {
  33                         // change owner to whoever caused the combo explosion
  34                         e.realowner = own;
  35                         e.takedamage = DAMAGE_NO;
  36                         e.classname = "plasma_chain";
  37                         e.think = W_Plasma_Explode_Combo;
  38                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
  39                 }
  40                 e = e.chain;
  41         }
  42 }
  43
  44 void W_Plasma_Explode (void)
  45 {
  46         if(other.takedamage == DAMAGE_AIM)
  47                 if(IS_PLAYER(other))
  48                         if(IsDifferentTeam(self.realowner, other))
  49                                 if(other.deadflag == DEAD_NO)
  50                                         if(IsFlying(other))
  51                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
  52
  53         self.event_damage = func_null;
  54         self.takedamage = DAMAGE_NO;
  55         if (self.movetype == MOVETYPE_BOUNCE)
  56         {
  57                 RadiusDamage (self, self.realowner, autocvar_g_balance_electro_secondary_damage, autocvar_g_balance_electro_secondary_edgedamage, autocvar_g_balance_electro_secondary_radius, world, world, autocvar_g_balance_electro_secondary_force, self.projectiledeathtype, other);
  58         }
  59         else
  60         {
  61                 W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_primary_comboradius, self.realowner);
  62                 RadiusDamage (self, self.realowner, autocvar_g_balance_electro_primary_damage, autocvar_g_balance_electro_primary_edgedamage, autocvar_g_balance_electro_primary_radius, world, world, autocvar_g_balance_electro_primary_force, self.projectiledeathtype, other);
  63         }
  64
  65         remove (self);
  66 }
  67
  68 void W_Plasma_Explode_Combo (void)
  69 {
  70         W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_combo_comboradius, self.realowner);
  71
  72         self.event_damage = func_null;
  73         RadiusDamage (self, self.realowner, autocvar_g_balance_electro_combo_damage, autocvar_g_balance_electro_combo_edgedamage, autocvar_g_balance_electro_combo_radius, world, world, autocvar_g_balance_electro_combo_force, WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  74
  75         remove (self);
  76 }
  77
  78 void W_Plasma_Touch (void)
  79 {
  80         //self.velocity = self.velocity  * 0.1;
  81
  82         PROJECTILE_TOUCH;
  83         if (other.takedamage == DAMAGE_AIM) {
  84                 W_Plasma_Explode ();
  85         } else {
  86                 //UpdateCSQCProjectile(self);
  87                 spamsound (self, CH_SHOTS, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  88                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  89         }
  90 }
  91
  92 void W_Plasma_TouchExplode (void)
  93 {
  94         PROJECTILE_TOUCH;
  95         W_Plasma_Explode ();
  96 }
  97
  98 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  99 {
 100         if(self.health <= 0)
 101                 return;
 102
 103         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
 104         float is_combo = (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim");
 105
 106         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_combo ? 1 : -1)))
 107                 return; // g_projectiles_damage says to halt
 108
 109         self.health = self.health - damage;
 110         if (self.health <= 0)
 111         {
 112                 self.takedamage = DAMAGE_NO;
 113                 self.nextthink = time;
 114                 if (is_combo)
 115                 {
 116                         // change owner to whoever caused the combo explosion
 117                         self.realowner = inflictor.realowner;
 118                         self.classname = "plasma_chain";
 119                         self.think = W_Plasma_Explode_Combo;
 120                         self.nextthink = time + min(autocvar_g_balance_electro_combo_radius, vlen(self.origin - inflictor.origin)) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
 121                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
 122                 }
 123                 else
 124                 {
 125                         self.use = W_Plasma_Explode;
 126                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 127                 }
 128         }
 129 }
 130
 131 void W_Electro_Attack()
 132 {
 133         entity proj;
 134
 135         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_reload_ammo);
 136
 137         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CH_WEAPON_A, autocvar_g_balance_electro_primary_damage);
 138
 139         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 140
 141         proj = spawn ();
 142         proj.classname = "plasma_prim";
 143         proj.owner = proj.realowner = self;
 144         proj.bot_dodge = TRUE;
 145         proj.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 146         proj.use = W_Plasma_Explode;
 147         proj.think = adaptor_think2use_hittype_splash;
 148         proj.nextthink = time + autocvar_g_balance_electro_primary_lifetime;
 149         PROJECTILE_MAKETRIGGER(proj);
 150         proj.projectiledeathtype = WEP_ELECTRO;
 151         setorigin(proj, w_shotorg);
 152
 153         proj.movetype = MOVETYPE_FLY;
 154         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 155         proj.angles = vectoangles(proj.velocity);
 156         proj.touch = W_Plasma_TouchExplode;
 157         setsize(proj, '0 0 -3', '0 0 -3');
 158         proj.flags = FL_PROJECTILE;
 159         proj.missile_flags = MIF_SPLASH;
 160
 161         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 162
 163         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 164 }
 165
 166 void W_Electro_Attack2()
 167 {
 168         entity proj;
 169
 170         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_electro_secondary_ammo, autocvar_g_balance_electro_reload_ammo);
 171
 172         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, autocvar_g_balance_electro_secondary_damage);
 173
 174         w_shotdir = v_forward; // no TrueAim for grenades please
 175
 176         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 177
 178         proj = spawn ();
 179         proj.classname = "plasma";
 180         proj.owner = proj.realowner = self;
 181         proj.use = W_Plasma_Explode;
 182         proj.think = adaptor_think2use_hittype_splash;
 183         proj.bot_dodge = TRUE;
 184         proj.bot_dodgerating = autocvar_g_balance_electro_secondary_damage;
 185         proj.nextthink = time + autocvar_g_balance_electro_secondary_lifetime;
 186         PROJECTILE_MAKETRIGGER(proj);
 187         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 188         setorigin(proj, w_shotorg);
 189
 190         //proj.glow_size = 50;
 191         //proj.glow_color = 45;
 192         proj.movetype = MOVETYPE_BOUNCE;
 193         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 194         proj.touch = W_Plasma_Touch;
 195         setsize(proj, '0 0 -4', '0 0 -4');
 196         proj.takedamage = DAMAGE_YES;
 197         proj.damageforcescale = autocvar_g_balance_electro_secondary_damageforcescale;
 198         proj.health = autocvar_g_balance_electro_secondary_health;
 199         proj.event_damage = W_Plasma_Damage;
 200         proj.flags = FL_PROJECTILE;
 201         proj.damagedbycontents = (autocvar_g_balance_electro_secondary_damagedbycontents);
 202
 203         proj.bouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 204         proj.bouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 205         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 206
 207 #if 0
 208         entity p2;
 209         p2 = spawn();
 210         copyentity(proj, p2);
 211         setmodel(p2, "models/ebomb.mdl");
 212         setsize(p2, proj.mins, proj.maxs);
 213 #endif
 214
 215         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 216
 217         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 218 }
 219
 220 .vector hook_start, hook_end;
 221 float lgbeam_send(entity to, float sf)
 222 {
 223         WriteByte(MSG_ENTITY, ENT_CLIENT_ELECTRO_BEAM);
 224         sf = sf & 0x7F;
 225         if(sound_allowed(MSG_BROADCAST, self.realowner))
 226                 sf |= 0x80;
 227         WriteByte(MSG_ENTITY, sf);
 228         if(sf & 1)
 229         {
 230                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 231                 WriteCoord(MSG_ENTITY, autocvar_g_balance_electro_primary_range);
 232         }
 233         if(sf & 2)
 234         {
 235                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 236                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 237                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 238         }
 239         if(sf & 4)
 240         {
 241                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 242                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 243                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 244         }
 245         return TRUE;
 246 }
 247 .entity lgbeam;
 248 .float prevlgfire;
 249 float lgbeam_checkammo()
 250 {
 251         if(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO)
 252                 return TRUE;
 253         else if(autocvar_g_balance_electro_reload_ammo)
 254                 return self.realowner.clip_load > 0;
 255         else
 256                 return self.realowner.ammo_cells > 0;
 257 }
 258
 259 entity lgbeam_owner_ent;
 260 void lgbeam_think()
 261 {
 262         entity owner_player;
 263         owner_player = self.realowner;
 264
 265         owner_player.prevlgfire = time;
 266         if (self != owner_player.lgbeam)
 267         {
 268                 remove(self);
 269                 return;
 270         }
 271
 272         if (owner_player.weaponentity.state != WS_INUSE || !lgbeam_checkammo() || owner_player.deadflag != DEAD_NO || !owner_player.BUTTON_ATCK || owner_player.freezetag_frozen)
 273         {
 274                 if(self == owner_player.lgbeam)
 275                         owner_player.lgbeam = world;
 276                 remove(self);
 277                 return;
 278         }
 279
 280         self.nextthink = time;
 281
 282         makevectors(owner_player.v_angle);
 283
 284         float dt, f;
 285         dt = frametime;
 286
 287         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 288         if not(owner_player.items & IT_UNLIMITED_WEAPON_AMMO)
 289         {
 290                 if(autocvar_g_balance_electro_primary_ammo)
 291                 {
 292                         if(autocvar_g_balance_electro_reload_ammo)
 293                         {
 294                                 dt = min(dt, owner_player.clip_load / autocvar_g_balance_electro_primary_ammo);
 295                                 owner_player.clip_load = max(0, owner_player.clip_load - autocvar_g_balance_electro_primary_ammo * frametime);
 296                                 owner_player.(weapon_load[WEP_ELECTRO]) = owner_player.clip_load;
 297                         }
 298                         else
 299                         {
 300                                 dt = min(dt, owner_player.ammo_cells / autocvar_g_balance_electro_primary_ammo);
 301                                 owner_player.ammo_cells = max(0, owner_player.ammo_cells - autocvar_g_balance_electro_primary_ammo * frametime);
 302                         }
 303                 }
 304         }
 305
 306         W_SetupShot_Range(owner_player, TRUE, 0, "", 0, autocvar_g_balance_electro_primary_damage * dt, autocvar_g_balance_electro_primary_range);
 307         if(!lgbeam_owner_ent)
 308         {
 309                 lgbeam_owner_ent = spawn();
 310                 lgbeam_owner_ent.classname = "lgbeam_owner_ent";
 311         }
 312         WarpZone_traceline_antilag(lgbeam_owner_ent, w_shotorg, w_shotend, MOVE_NORMAL, lgbeam_owner_ent, ANTILAG_LATENCY(owner_player));
 313
 314         // apply the damage
 315         if(trace_ent)
 316         {
 317                 vector force;
 318                 force = w_shotdir * autocvar_g_balance_electro_primary_force + '0 0 1' * autocvar_g_balance_electro_primary_force_up;
 319
 320                 f = ExponentialFalloff(autocvar_g_balance_electro_primary_falloff_mindist, autocvar_g_balance_electro_primary_falloff_maxdist, autocvar_g_balance_electro_primary_falloff_halflifedist, vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - w_shotorg));
 321
 322                 if(accuracy_isgooddamage(owner_player, trace_ent))
 323                         accuracy_add(owner_player, WEP_ELECTRO, 0, autocvar_g_balance_electro_primary_damage * dt * f);
 324                 Damage (trace_ent, owner_player, owner_player, autocvar_g_balance_electro_primary_damage * dt * f, WEP_ELECTRO, trace_endpos, force * dt);
 325         }
 326         W_Plasma_TriggerCombo(trace_endpos, autocvar_g_balance_electro_primary_comboradius, owner_player);
 327
 328         // draw effect
 329         if(w_shotorg != self.hook_start)
 330         {
 331                 self.SendFlags |= 2;
 332                 self.hook_start = w_shotorg;
 333         }
 334         if(w_shotend != self.hook_end)
 335         {
 336                 self.SendFlags |= 4;
 337                 self.hook_end = w_shotend;
 338         }
 339 }
 340
 341 // experimental lightning gun
 342 void W_Electro_Attack3 (void)
 343 {
 344         // only play fire sound if 0.5 sec has passed since player let go the fire button
 345         if(time - self.prevlgfire > 0.5)
 346                 sound (self, CH_WEAPON_A, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 347
 348         entity beam, oldself;
 349
 350         self.lgbeam = beam = spawn();
 351         beam.classname = "lgbeam";
 352         beam.solid = SOLID_NOT;
 353         beam.think = lgbeam_think;
 354         beam.owner = beam.realowner = self;
 355         beam.movetype = MOVETYPE_NONE;
 356         beam.shot_spread = 0;
 357         beam.bot_dodge = TRUE;
 358         beam.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 359         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
 360
 361         oldself = self;
 362         self = beam;
 363         self.think();
 364         self = oldself;
 365 }
 366
 367 void ElectroInit()
 368 {
 369         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 370         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 371         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 372         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 373         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 374 }
 375
 376 void spawnfunc_weapon_electro (void)
 377 {
 378         weapon_defaultspawnfunc(WEP_ELECTRO);
 379 }
 380
 381 void w_electro_checkattack()
 382 {
 383         if(self.electro_count > 1)
 384         if(self.BUTTON_ATCK2)
 385         if(weapon_prepareattack(1, -1))
 386         {
 387                 W_Electro_Attack2();
 388                 self.electro_count -= 1;
 389                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 390                 return;
 391         }
 392
 393         w_ready();
 394 }
 395
 396 .float bot_secondary_electromooth;
 397 .float BUTTON_ATCK_prev;
 398 float w_electro(float req)
 399 {
 400         float ammo_amount;
 401         if (req == WR_AIM)
 402         {
 403                 self.BUTTON_ATCK=FALSE;
 404                 self.BUTTON_ATCK2=FALSE;
 405                 if(vlen(self.origin-self.enemy.origin) > 1000)
 406                         self.bot_secondary_electromooth = 0;
 407                 if(self.bot_secondary_electromooth == 0)
 408                 {
 409                         float shoot;
 410
 411                         if(autocvar_g_balance_electro_primary_speed)
 412                                 shoot = bot_aim(autocvar_g_balance_electro_primary_speed, 0, autocvar_g_balance_electro_primary_lifetime, FALSE);
 413                         else
 414                                 shoot = bot_aim(1000000, 0, 0.001, FALSE);
 415
 416                         if(shoot)
 417                         {
 418                                 self.BUTTON_ATCK = TRUE;
 419                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 420                         }
 421                 }
 422                 else
 423                 {
 424                         if(bot_aim(autocvar_g_balance_electro_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_electro_secondary_lifetime, TRUE))
 425                         {
 426                                 self.BUTTON_ATCK2 = TRUE;
 427                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 428                         }
 429                 }
 430         }
 431         else if (req == WR_THINK)
 432         {
 433                 if(autocvar_g_balance_electro_reload_ammo) // forced reload
 434                 {
 435                         ammo_amount = 0;
 436                         if(autocvar_g_balance_electro_lightning)
 437                         {
 438                                 if(self.clip_load > 0)
 439                                         ammo_amount = 1;
 440                         }
 441                         else if(self.clip_load >= autocvar_g_balance_electro_primary_ammo)
 442                                 ammo_amount = 1;
 443                         if(self.clip_load >= autocvar_g_balance_electro_secondary_ammo)
 444                                 ammo_amount += 1;
 445
 446                         if(!ammo_amount)
 447                         {
 448                                 weapon_action(self.weapon, WR_RELOAD);
 449                                 return FALSE;
 450                         }
 451                 }
 452                 if (self.BUTTON_ATCK)
 453                 {
 454                         if(autocvar_g_balance_electro_lightning)
 455                                 if(self.BUTTON_ATCK_prev)
 456                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 457
 458                         if (weapon_prepareattack(0, (autocvar_g_balance_electro_lightning ? 0 : autocvar_g_balance_electro_primary_refire)))
 459                         {
 460                                 if(autocvar_g_balance_electro_lightning)
 461                                 {
 462                                         if ((!self.lgbeam) || wasfreed(self.lgbeam))
 463                                         {
 464                                                 W_Electro_Attack3();
 465                                         }
 466                                         if(!self.BUTTON_ATCK_prev)
 467                                         {
 468                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 469                                                 self.BUTTON_ATCK_prev = 1;
 470                                         }
 471                                 }
 472                                 else
 473                                 {
 474                                         W_Electro_Attack();
 475                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 476                                 }
 477                         }
 478                 } else {
 479                         if(autocvar_g_balance_electro_lightning)
 480                         {
 481                                 if (self.BUTTON_ATCK_prev != 0)
 482                                 {
 483                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 484                                         ATTACK_FINISHED(self) = time + autocvar_g_balance_electro_primary_refire * W_WeaponRateFactor();
 485                                 }
 486                                 self.BUTTON_ATCK_prev = 0;
 487                         }
 488
 489                         if (self.BUTTON_ATCK2)
 490                         {
 491                                 if (time >= self.electro_secondarytime)
 492                                 if (weapon_prepareattack(1, autocvar_g_balance_electro_secondary_refire))
 493                                 {
 494                                         W_Electro_Attack2();
 495                                         self.electro_count = autocvar_g_balance_electro_secondary_count;
 496                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 497                                         self.electro_secondarytime = time + autocvar_g_balance_electro_secondary_refire2 * W_WeaponRateFactor();
 498                                 }
 499                         }
 500                 }
 501         }
 502         else if (req == WR_PRECACHE)
 503         {
 504                 precache_model ("models/weapons/g_electro.md3");
 505                 precache_model ("models/weapons/v_electro.md3");
 506                 precache_model ("models/weapons/h_electro.iqm");
 507                 precache_sound ("weapons/electro_bounce.wav");
 508                 precache_sound ("weapons/electro_fire.wav");
 509                 precache_sound ("weapons/electro_fire2.wav");
 510                 precache_sound ("weapons/electro_impact.wav");
 511                 precache_sound ("weapons/electro_impact_combo.wav");
 512                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 513                 if(autocvar_g_balance_electro_lightning)
 514                 {
 515                         precache_sound ("weapons/lgbeam_fire.wav");
 516                 }
 517         }
 518         else if (req == WR_SETUP)
 519         {
 520                 weapon_setup(WEP_ELECTRO);
 521                 self.current_ammo = ammo_cells;
 522         }
 523         else if (req == WR_CHECKAMMO1)
 524         {
 525                 if(autocvar_g_balance_electro_lightning)
 526                 {
 527                         if(!autocvar_g_balance_electro_primary_ammo)
 528                                 ammo_amount = 1;
 529                         else
 530                                 ammo_amount = self.ammo_cells > 0;
 531                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) > 0;
 532                 }
 533                 else
 534                 {
 535                         ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_primary_ammo;
 536                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_primary_ammo;
 537                 }
 538                 return ammo_amount;
 539         }
 540         else if (req == WR_CHECKAMMO2)
 541         {
 542                 if(autocvar_g_balance_electro_combo_safeammocheck) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 543                 {
 544                         ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo + autocvar_g_balance_electro_primary_ammo;
 545                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_secondary_ammo + autocvar_g_balance_electro_primary_ammo;
 546                 }
 547                 else
 548                 {
 549                         ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo;
 550                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_secondary_ammo;
 551                 }
 552                 return ammo_amount;
 553         }
 554         else if (req == WR_RESETPLAYER)
 555         {
 556                 self.electro_secondarytime = time;
 557         }
 558         else if (req == WR_RELOAD)
 559         {
 560                 W_Reload(min(autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_secondary_ammo), autocvar_g_balance_electro_reload_ammo, autocvar_g_balance_electro_reload_time, "weapons/reload.wav");
 561         }
 562         else if (req == WR_SUICIDEMESSAGE)
 563         {
 564                 if(w_deathtype & HITTYPE_SECONDARY)
 565                         return WEAPON_ELECTRO_SUICIDE_ORBS;
 566                 else
 567                         return WEAPON_ELECTRO_SUICIDE_BOLT;
 568         }
 569         else if (req == WR_KILLMESSAGE)
 570         {
 571                 if(w_deathtype & HITTYPE_SECONDARY)
 572                 {
 573                         return WEAPON_ELECTRO_MURDER_ORBS;
 574                 }
 575                 else
 576                 {
 577                         if(w_deathtype & HITTYPE_BOUNCE)
 578                                 return WEAPON_ELECTRO_MURDER_COMBO;
 579                         else
 580                                 return WEAPON_ELECTRO_MURDER_BOLT;
 581                 }
 582         }
 583         return TRUE;
 584 }
 585 #endif
 586 #ifdef CSQC
 587 float w_electro(float req)
 588 {
 589         if(req == WR_IMPACTEFFECT)
 590         {
 591                 vector org2;
 592                 org2 = w_org + w_backoff * 6;
 593                 if(w_deathtype & HITTYPE_SECONDARY)
 594                 {
 595                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 596                         if(!w_issilent)
 597                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 598                 }
 599                 else
 600                 {
 601                         if(w_deathtype & HITTYPE_BOUNCE)
 602                         {
 603                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 604                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 605                                 if(!w_issilent)
 606                                         sound(self, CH_SHOTS, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 607                         }
 608                         else
 609                         {
 610                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 611                                 if(!w_issilent)
 612                                         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 613                         }
 614                 }
 615         }
 616         else if(req == WR_PRECACHE)
 617         {
 618                 precache_sound("weapons/electro_impact.wav");
 619                 precache_sound("weapons/electro_impact_combo.wav");
 620         }
 621         return TRUE;
 622 }
 623 #endif
 624 #endif