qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ MINE_LAYER,
   4 /* function */ w_minelayer,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 4,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "minelayer",
  10 /* netname  */ "minelayer",
  11 /* fullname */ _("Mine Layer")
  12 );
  13
  14 #define MINELAYER_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_NONE, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_NONE, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_NONE, damage) \
  18         WEP_ADD_CVAR(weapon, MO_NONE, damageforcescale) \
  19         WEP_ADD_CVAR(weapon, MO_NONE, detonatedelay) \
  20         WEP_ADD_CVAR(weapon, MO_NONE, edgedamage) \
  21         WEP_ADD_CVAR(weapon, MO_NONE, force) \
  22         WEP_ADD_CVAR(weapon, MO_NONE, health) \
  23         WEP_ADD_CVAR(weapon, MO_NONE, lifetime) \
  24         WEP_ADD_CVAR(weapon, MO_NONE, lifetime_countdown) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, limit) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, protection) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, proximityradius) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, radius) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, refire) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, remote_damage) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, remote_edgedamage) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, remote_force) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, remote_radius) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, speed) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, time) \
  36         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  37         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  38         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  39         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  40
  41 #ifdef SVQC
  42 MINELAYER_SETTINGS(minelayer)
  43 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  44
  45 void W_Mine_Think (void);
  46 .float minelayer_detonate, mine_explodeanyway;
  47 .float mine_time;
  48 .vector mine_orientation;
  49 #endif
  50 #else
  51 #ifdef SVQC
  52
  53 void W_Mine_Stick (entity to)
  54 {
  55         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  56
  57         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  58
  59         entity newmine;
  60         newmine = spawn();
  61         newmine.classname = self.classname;
  62
  63         newmine.bot_dodge = self.bot_dodge;
  64         newmine.bot_dodgerating = self.bot_dodgerating;
  65
  66         newmine.owner = self.owner;
  67         newmine.realowner = self.realowner;
  68         setsize(newmine, '-4 -4 -4', '4 4 4');
  69         setorigin(newmine, self.origin);
  70         setmodel(newmine, "models/mine.md3");
  71         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  72
  73         newmine.mine_orientation = -trace_plane_normal;
  74
  75         newmine.takedamage = self.takedamage;
  76         newmine.damageforcescale = self.damageforcescale;
  77         newmine.health = self.health;
  78         newmine.event_damage = self.event_damage;
  79         newmine.spawnshieldtime = self.spawnshieldtime;
  80         newmine.damagedbycontents = TRUE;
  81
  82         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  83         newmine.projectiledeathtype = self.projectiledeathtype;
  84
  85         newmine.mine_time = self.mine_time;
  86
  87         newmine.touch = func_null;
  88         newmine.think = W_Mine_Think;
  89         newmine.nextthink = time;
  90         newmine.cnt = self.cnt;
  91         newmine.flags = self.flags;
  92
  93         remove(self);
  94         self = newmine;
  95
  96         if(to)
  97                 SetMovetypeFollow(self, to);
  98 }
  99
 100 void W_Mine_Explode ()
 101 {
 102         if(other.takedamage == DAMAGE_AIM)
 103                 if(IS_PLAYER(other))
 104                         if(IsDifferentTeam(self.realowner, other))
 105                                 if(other.deadflag == DEAD_NO)
 106                                         if(IsFlying(other))
 107                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 108
 109         self.event_damage = func_null;
 110         self.takedamage = DAMAGE_NO;
 111
 112         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 113
 114         if (self.realowner.weapon == WEP_MINE_LAYER)
 115         {
 116                 entity oldself;
 117                 oldself = self;
 118                 self = self.realowner;
 119                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 120                 {
 121                         self.cnt = WEP_MINE_LAYER;
 122                         ATTACK_FINISHED(self) = time;
 123                         self.switchweapon = w_getbestweapon(self);
 124                 }
 125                 self = oldself;
 126         }
 127         self.realowner.minelayer_mines -= 1;
 128         remove (self);
 129 }
 130
 131 void W_Mine_DoRemoteExplode ()
 132 {
 133         self.event_damage = func_null;
 134         self.takedamage = DAMAGE_NO;
 135
 136         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 137                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 138
 139         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 140
 141         if (self.realowner.weapon == WEP_MINE_LAYER)
 142         {
 143                 entity oldself;
 144                 oldself = self;
 145                 self = self.realowner;
 146                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 147                 {
 148                         self.cnt = WEP_MINE_LAYER;
 149                         ATTACK_FINISHED(self) = time;
 150                         self.switchweapon = w_getbestweapon(self);
 151                 }
 152                 self = oldself;
 153         }
 154         self.realowner.minelayer_mines -= 1;
 155         remove (self);
 156 }
 157
 158 void W_Mine_RemoteExplode ()
 159 {
 160         if(self.realowner.deadflag == DEAD_NO)
 161                 if((self.spawnshieldtime >= 0)
 162                         ? (time >= self.spawnshieldtime) // timer
 163                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 164                 )
 165                 {
 166                         W_Mine_DoRemoteExplode();
 167                 }
 168 }
 169
 170 void W_Mine_ProximityExplode ()
 171 {
 172         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 173         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 174         {
 175                 entity head;
 176                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 177                 while(head)
 178                 {
 179                         if(head == self.realowner || !IsDifferentTeam(head, self.realowner))
 180                                 return;
 181                         head = head.chain;
 182                 }
 183         }
 184
 185         self.mine_time = 0;
 186         W_Mine_Explode();
 187 }
 188
 189 float W_Mine_Count(entity e)
 190 {
 191         float minecount = 0;
 192         entity mine;
 193         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 194                 minecount += 1;
 195
 196         return minecount;
 197 }
 198
 199 void W_Mine_Think (void)
 200 {
 201         entity head;
 202
 203         self.nextthink = time;
 204
 205         if(self.movetype == MOVETYPE_FOLLOW)
 206         {
 207                 if(LostMovetypeFollow(self))
 208                 {
 209                         UnsetMovetypeFollow(self);
 210                         self.movetype = MOVETYPE_NONE;
 211                 }
 212         }
 213
 214         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 215         // TODO: replace this mine_trigger.wav sound with a real countdown
 216         if ((time > self.cnt) && (!self.mine_time))
 217         {
 218                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 219                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 220                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 221                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 222         }
 223
 224         // a player's mines shall explode if he disconnects or dies
 225         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 226         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 227         {
 228                 other = world;
 229                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 230                 W_Mine_Explode();
 231                 return;
 232         }
 233
 234         // set the mine for detonation when a foe gets close enough
 235         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 236         while(head)
 237         {
 238                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 239                 if(head != self.realowner && IsDifferentTeam(head, self.realowner)) // don't trigger for team mates
 240                 if(!self.mine_time)
 241                 {
 242                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 243                         self.mine_time = time + WEP_CVAR(minelayer, time);
 244                 }
 245                 head = head.chain;
 246         }
 247
 248         // explode if it's time to
 249         if(self.mine_time && time >= self.mine_time)
 250         {
 251                 W_Mine_ProximityExplode();
 252                 return;
 253         }
 254
 255         // remote detonation
 256         if (self.realowner.weapon == WEP_MINE_LAYER)
 257         if (self.realowner.deadflag == DEAD_NO)
 258         if (self.minelayer_detonate)
 259                 W_Mine_RemoteExplode();
 260 }
 261
 262 void W_Mine_Touch (void)
 263 {
 264         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 265                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 266
 267         if(WarpZone_Projectile_Touch())
 268         {
 269                 if(wasfreed(self))
 270                         self.realowner.minelayer_mines -= 1;
 271                 return;
 272         }
 273
 274         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 275         {
 276                 // hit a player
 277                 // don't stick
 278         }
 279         else
 280         {
 281                 W_Mine_Stick(other);
 282         }
 283 }
 284
 285 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 286 {
 287         if (self.health <= 0)
 288                 return;
 289
 290         float is_from_enemy = (inflictor.realowner != self.realowner);
 291
 292         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 293                 return; // g_projectiles_damage says to halt
 294
 295         self.health = self.health - damage;
 296         self.angles = vectoangles(self.velocity);
 297
 298         if (self.health <= 0)
 299                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 300 }
 301
 302 void W_Mine_Attack (void)
 303 {
 304         entity mine;
 305         entity flash;
 306
 307         // scan how many mines we placed, and return if we reached our limit
 308         if(WEP_CVAR(minelayer, limit))
 309         {
 310                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 311                 {
 312                         // the refire delay keeps this message from being spammed
 313                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 314                         play2(self, "weapons/unavailable.wav");
 315                         return;
 316                 }
 317         }
 318
 319         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(minelayer, ammo), autocvar_g_balance_minelayer_reload_ammo);
 320
 321         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 322         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 323
 324         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 325         mine.owner = mine.realowner = self;
 326         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 327                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 328         else
 329                 mine.spawnshieldtime = -1;
 330         mine.classname = "mine";
 331         mine.bot_dodge = TRUE;
 332         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 333
 334         mine.takedamage = DAMAGE_YES;
 335         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 336         mine.health = WEP_CVAR(minelayer, health);
 337         mine.event_damage = W_Mine_Damage;
 338         mine.damagedbycontents = TRUE;
 339
 340         mine.movetype = MOVETYPE_TOSS;
 341         PROJECTILE_MAKETRIGGER(mine);
 342         mine.projectiledeathtype = WEP_MINE_LAYER;
 343         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 344
 345         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 346         W_SetupProjectileVelocity(mine, WEP_CVAR(minelayer, speed), 0);
 347         mine.angles = vectoangles (mine.velocity);
 348
 349         mine.touch = W_Mine_Touch;
 350         mine.think = W_Mine_Think;
 351         mine.nextthink = time;
 352         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 353         mine.flags = FL_PROJECTILE;
 354         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 355
 356         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 357
 358         // muzzle flash for 1st person view
 359         flash = spawn ();
 360         setmodel (flash, "models/flash.md3"); // precision set below
 361         SUB_SetFade (flash, time, 0.1);
 362         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 363         W_AttachToShotorg(flash, '5 0 0');
 364
 365         // common properties
 366
 367         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 368
 369         self.minelayer_mines = W_Mine_Count(self);
 370 }
 371
 372 float W_PlacedMines(float detonate)
 373 {
 374         entity mine;
 375         float minfound = 0;
 376
 377         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 378         {
 379                 if(detonate)
 380                 {
 381                         if(!mine.minelayer_detonate)
 382                         {
 383                                 mine.minelayer_detonate = TRUE;
 384                                 minfound = 1;
 385                         }
 386                 }
 387                 else
 388                         minfound = 1;
 389         }
 390         return minfound;
 391 }
 392
 393 float w_minelayer(float req)
 394 {
 395         entity mine;
 396         float ammo_amount;
 397         switch(req)
 398         {
 399                 case WR_AIM:
 400                 {
 401                         // aim and decide to fire if appropriate
 402                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 403                                 self.BUTTON_ATCK = FALSE;
 404                         else
 405                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 406                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 407                         {
 408                                 // decide whether to detonate mines
 409                                 entity targetlist, targ;
 410                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 411                                 float selfdamage, teamdamage, enemydamage;
 412                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 413                                 coredamage = WEP_CVAR(minelayer, damage);
 414                                 edgeradius = WEP_CVAR(minelayer, radius);
 415                                 recipricoledgeradius = 1 / edgeradius;
 416                                 selfdamage = 0;
 417                                 teamdamage = 0;
 418                                 enemydamage = 0;
 419                                 targetlist = findchainfloat(bot_attack, TRUE);
 420                                 mine = find(world, classname, "mine");
 421                                 while (mine)
 422                                 {
 423                                         if (mine.realowner != self)
 424                                         {
 425                                                 mine = find(mine, classname, "mine");
 426                                                 continue;
 427                                         }
 428                                         targ = targetlist;
 429                                         while (targ)
 430                                         {
 431                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 432                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 433                                                 // count potential damage according to type of target
 434                                                 if (targ == self)
 435                                                         selfdamage = selfdamage + d;
 436                                                 else if (targ.team == self.team && teamplay)
 437                                                         teamdamage = teamdamage + d;
 438                                                 else if (bot_shouldattack(targ))
 439                                                         enemydamage = enemydamage + d;
 440                                                 targ = targ.chain;
 441                                         }
 442                                         mine = find(mine, classname, "mine");
 443                                 }
 444                                 float desirabledamage;
 445                                 desirabledamage = enemydamage;
 446                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 447                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 448                                 if (teamplay && self.team)
 449                                         desirabledamage = desirabledamage - teamdamage;
 450
 451                                 mine = find(world, classname, "mine");
 452                                 while (mine)
 453                                 {
 454                                         if (mine.realowner != self)
 455                                         {
 456                                                 mine = find(mine, classname, "mine");
 457                                                 continue;
 458                                         }
 459                                         makevectors(mine.v_angle);
 460                                         targ = targetlist;
 461                                         if (skill > 9) // normal players only do this for the target they are tracking
 462                                         {
 463                                                 targ = targetlist;
 464                                                 while (targ)
 465                                                 {
 466                                                         if (
 467                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 468                                                                 && desirabledamage > 0.1*coredamage
 469                                                         )self.BUTTON_ATCK2 = TRUE;
 470                                                         targ = targ.chain;
 471                                                 }
 472                                         }else{
 473                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 474                                                 //As the distance gets larger, a correct detonation gets near imposible
 475                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 476                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 477                                                         if(IS_PLAYER(self.enemy))
 478                                                                 if(desirabledamage >= 0.1*coredamage)
 479                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 480                                                                                 self.BUTTON_ATCK2 = TRUE;
 481                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 482                                         }
 483
 484                                         mine = find(mine, classname, "mine");
 485                                 }
 486                                 // if we would be doing at X percent of the core damage, detonate it
 487                                 // but don't fire a new shot at the same time!
 488                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 489                                         self.BUTTON_ATCK2 = TRUE;
 490                                 if ((skill > 6.5) && (selfdamage > self.health))
 491                                         self.BUTTON_ATCK2 = FALSE;
 492                                 //if(self.BUTTON_ATCK2 == TRUE)
 493                                 //      dprint(ftos(desirabledamage),"\n");
 494                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 495                         }
 496
 497                         return TRUE;
 498                 }
 499                 case WR_THINK:
 500                 {
 501                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 502                         {
 503                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 504                                 if not (W_PlacedMines(FALSE) && self.ammo_rockets < WEP_CVAR(minelayer, ammo))
 505                                         WEP_ACTION(self.weapon, WR_RELOAD);
 506                         }
 507                         else if (self.BUTTON_ATCK)
 508                         {
 509                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 510                                 {
 511                                         W_Mine_Attack();
 512                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 513                                 }
 514                         }
 515
 516                         if (self.BUTTON_ATCK2)
 517                         {
 518                                 if(W_PlacedMines(TRUE))
 519                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 520                         }
 521
 522                         return TRUE;
 523                 }
 524                 case WR_INIT:
 525                 {
 526                         precache_model ("models/flash.md3");
 527                         precache_model ("models/mine.md3");
 528                         precache_model ("models/weapons/g_minelayer.md3");
 529                         precache_model ("models/weapons/v_minelayer.md3");
 530                         precache_model ("models/weapons/h_minelayer.iqm");
 531                         precache_sound ("weapons/mine_det.wav");
 532                         precache_sound ("weapons/mine_fire.wav");
 533                         precache_sound ("weapons/mine_stick.wav");
 534                         precache_sound ("weapons/mine_trigger.wav");
 535                         #define WEP_ADD_CVAR(weapon,mode,name) /*nothing*/
 536                         #define WEP_ADD_PROP(weapon,prop,name) WEP_SET_PROP(WEP_MINE_LAYER,weapon,prop,name)
 537                         MINELAYER_SETTINGS(minelayer)
 538                         #undef WEP_ADD_CVAR
 539                         #undef WEP_ADD_PROP
 540                         return TRUE;
 541                 }
 542                 case WR_SETUP:
 543                 {
 544                         weapon_setup(WEP_MINE_LAYER);
 545                         self.current_ammo = ammo_rockets;
 546                         return TRUE;
 547                 }
 548                 case WR_CHECKAMMO1:
 549                 {
 550                         // don't switch while placing a mine
 551                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 552                         {
 553                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(minelayer, ammo);
 554                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 555                                 return ammo_amount;
 556                         }
 557                         return TRUE;
 558                 }
 559                 case WR_CHECKAMMO2:
 560                 {
 561                         if (W_PlacedMines(FALSE))
 562                                 return TRUE;
 563                         else
 564                                 return FALSE;
 565                 }
 566                 case WR_RESETPLAYER:
 567                 {
 568                         self.minelayer_mines = 0;
 569                         return TRUE;
 570                 }
 571                 case WR_RELOAD:
 572                 {
 573                         W_Reload(WEP_CVAR(minelayer, ammo), autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 574                         return TRUE;
 575                 }
 576                 case WR_SUICIDEMESSAGE:
 577                 {
 578                         return WEAPON_MINELAYER_SUICIDE;
 579                 }
 580                 case WR_KILLMESSAGE:
 581                 {
 582                         return WEAPON_MINELAYER_MURDER;
 583                 }
 584         }
 585         return TRUE;
 586 }
 587 #endif
 588 #ifdef CSQC
 589 float w_minelayer(float req)
 590 {
 591         switch(req)
 592         {
 593                 case WR_IMPACTEFFECT:
 594                 {
 595                         vector org2;
 596                         org2 = w_org + w_backoff * 12;
 597                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 598                         if(!w_issilent)
 599                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 600
 601                         return TRUE;
 602                 }
 603                 case WR_INIT:
 604                 {
 605                         precache_sound("weapons/mine_exp.wav");
 606                         return TRUE;
 607                 }
 608         }
 609         return TRUE;
 610 }
 611 #endif
 612 #endif