qcsrc/common/weapons/w_minstanex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ MINSTANEX,
   4 /* function */ w_minstanex,
   5 /* ammotype */ IT_CELLS,
   6 /* impulse  */ 7,
   7 /* flags    */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "minstanex",
  10 /* netname  */ "minstanex",
  11 /* fullname */ _("MinstaNex")
  12 );
  13
  14 #define MINSTANEX_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_MINSTANEX, minstanex, MO_PRI, ammo) \
  16         w_cvar(WEP_MINSTANEX, minstanex, MO_PRI, animtime) \
  17         w_cvar(WEP_MINSTANEX, minstanex, MO_PRI, refire) \
  18         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, ammo) \
  19         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, animtime) \
  20         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, damage) \
  21         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, delay) \
  22         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, edgedamage) \
  23         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, force) \
  24         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, lifetime) \
  25         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, radius) \
  26         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, refire) \
  27         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, shotangle) \
  28         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, speed) \
  29         w_cvar(WEP_MINSTANEX, minstanex, MO_SEC, spread) \
  30         w_prop(WEP_MINSTANEX, minstanex, float,  reloading_ammo, reload_ammo) \
  31         w_prop(WEP_MINSTANEX, minstanex, float,  reloading_time, reload_time) \
  32         w_prop(WEP_MINSTANEX, minstanex, float,  switchdelay_raise, switchdelay_raise) \
  33         w_prop(WEP_MINSTANEX, minstanex, float,  switchdelay_drop, switchdelay_drop) \
  34         w_prop(WEP_MINSTANEX, minstanex, string, weaponreplace, weaponreplace) \
  35         w_prop(WEP_MINSTANEX, minstanex, float,  weaponstart, weaponstart)
  36
  37 #ifdef SVQC
  38 MINSTANEX_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  39 .float minstanex_lasthit;
  40 .float jump_interval;
  41 #endif
  42 #else
  43 #ifdef SVQC
  44 void spawnfunc_weapon_minstanex (void) { weapon_defaultspawnfunc(WEP_MINSTANEX); }
  45
  46 void W_MinstaNex_Attack (void)
  47 {
  48         float flying;
  49         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  50
  51         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  52
  53         yoda = 0;
  54         damage_goodhits = 0;
  55         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_MINSTANEX);
  56
  57         if(yoda && flying)
  58                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  59         if(damage_goodhits && self.minstanex_lasthit)
  60         {
  61                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  62                 damage_goodhits = 0; // only every second time
  63         }
  64
  65         self.minstanex_lasthit = damage_goodhits;
  66
  67         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  68
  69         // teamcolor / hit beam effect
  70         vector v;
  71         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  72         switch(self.team)
  73         {
  74                 case NUM_TEAM_1:   // Red
  75                         if(damage_goodhits)
  76                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  77                         else
  78                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  79                         break;
  80                 case NUM_TEAM_2:   // Blue
  81                         if(damage_goodhits)
  82                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  83                         else
  84                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  85                         break;
  86                 case NUM_TEAM_3:   // Yellow
  87                         if(damage_goodhits)
  88                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  89                         else
  90                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  91                         break;
  92                 case NUM_TEAM_4:   // Pink
  93                         if(damage_goodhits)
  94                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
  95                         else
  96                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
  97                         break;
  98                 default:
  99                         if(damage_goodhits)
 100                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
 101                         else
 102                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
 103                         break;
 104         }
 105
 106         W_DecreaseAmmo(ammo_cells, ((g_minstagib) ? 1 : WEP_CVAR_PRI(minstanex, ammo)), WEP_CVAR(minstanex, reload_ammo));
 107 }
 108
 109 float w_minstanex(float req)
 110 {
 111         float ammo_amount;
 112         float minstanex_ammo;
 113
 114         // now multiple WR_s use this
 115         minstanex_ammo = ((g_minstagib) ? 1 : WEP_CVAR_PRI(minstanex, ammo));
 116
 117         switch(req)
 118         {
 119                 case WR_AIM:
 120                 {
 121                         if(self.ammo_cells > 0)
 122                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 123                         else
 124                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(minstanex, speed), 0, WEP_CVAR_SEC(minstanex, lifetime), FALSE); // WEAPONTODO: replace with proper minstanex cvars
 125
 126                         return TRUE;
 127                 }
 128                 case WR_THINK:
 129                 {
 130                         // if the laser uses load, we also consider its ammo for reloading
 131                         if(WEP_CVAR(minstanex, reload_ammo) && WEP_CVAR_SEC(minstanex, ammo) && self.clip_load < min(minstanex_ammo, WEP_CVAR_SEC(minstanex, ammo))) // forced reload
 132                                 WEP_ACTION(self.weapon, WR_RELOAD);
 133                         else if(WEP_CVAR(minstanex, reload_ammo) && self.clip_load < minstanex_ammo) // forced reload
 134                                 WEP_ACTION(self.weapon, WR_RELOAD);
 135                         else if (self.BUTTON_ATCK)
 136                         {
 137                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(minstanex, refire)))
 138                                 {
 139                                         W_MinstaNex_Attack();
 140                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(minstanex, animtime), w_ready);
 141                                 }
 142                         }
 143                         else if (self.BUTTON_ATCK2)
 144                         {
 145                                 if (self.jump_interval <= time)
 146                                 if (weapon_prepareattack(1, -1))
 147                                 {
 148                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 149                                         self.jump_interval = time + WEP_CVAR_SEC(minstanex, refire) * W_WeaponRateFactor();
 150
 151                                         // decrease ammo for the laser?
 152                                         if(WEP_CVAR_SEC(minstanex, ammo))
 153                                                 W_DecreaseAmmo(ammo_cells, WEP_CVAR_SEC(minstanex, ammo), WEP_CVAR(minstanex, reload_ammo));
 154
 155                                         // ugly minstagib hack to reuse the fire mode of the laser
 156                                         float w;
 157                                         w = self.weapon;
 158                                         self.weapon = WEP_BLASTER;
 159                                         W_Blaster_Attack(
 160                                                 WEP_CVAR_SEC(minstanex, shotangle),
 161                                                 WEP_CVAR_SEC(minstanex, damage),
 162                                                 WEP_CVAR_SEC(minstanex, edgedamage),
 163                                                 WEP_CVAR_SEC(minstanex, radius),
 164                                                 WEP_CVAR_SEC(minstanex, force),
 165                                                 WEP_CVAR_SEC(minstanex, speed),
 166                                                 WEP_CVAR_SEC(minstanex, spread),
 167                                                 WEP_CVAR_SEC(minstanex, delay),
 168                                                 WEP_CVAR_SEC(minstanex, lifetime)
 169                                         );
 170                                         self.weapon = w;
 171
 172                                         // now do normal refire
 173                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(minstanex, animtime), w_ready);
 174                                 }
 175                         }
 176
 177                         return TRUE;
 178                 }
 179                 case WR_INIT:
 180                 {
 181                         precache_model("models/nexflash.md3");
 182                         precache_model("models/weapons/g_minstanex.md3");
 183                         precache_model("models/weapons/v_minstanex.md3");
 184                         precache_model("models/weapons/h_minstanex.iqm");
 185                         precache_sound("weapons/minstanexfire.wav");
 186                         precache_sound("weapons/nexwhoosh1.wav");
 187                         precache_sound("weapons/nexwhoosh2.wav");
 188                         precache_sound("weapons/nexwhoosh3.wav");
 189                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 190                         MINSTANEX_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 191                         return TRUE;
 192                 }
 193                 case WR_SETUP:
 194                 {
 195                         self.current_ammo = ammo_cells;
 196                         self.minstanex_lasthit = 0;
 197                         return TRUE;
 198                 }
 199                 case WR_CHECKAMMO1:
 200                 {
 201                         ammo_amount = self.ammo_cells >= minstanex_ammo;
 202                         ammo_amount += self.(weapon_load[WEP_MINSTANEX]) >= minstanex_ammo;
 203                         return ammo_amount;
 204                 }
 205                 case WR_CHECKAMMO2:
 206                 {
 207                         if(!WEP_CVAR_SEC(minstanex, ammo))
 208                                 return TRUE;
 209                         ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(minstanex, ammo);
 210                         ammo_amount += self.(weapon_load[WEP_MINSTANEX]) >= WEP_CVAR_SEC(minstanex, ammo);
 211                         return ammo_amount;
 212                 }
 213                 case WR_CONFIG:
 214                 {
 215                         MINSTANEX_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 216                         return TRUE;
 217                 }
 218                 case WR_RESETPLAYER:
 219                 {
 220                         self.minstanex_lasthit = 0;
 221                         return TRUE;
 222                 }
 223                 case WR_RELOAD:
 224                 {
 225                         float used_ammo;
 226                         if(WEP_CVAR_SEC(minstanex, ammo))
 227                                 used_ammo = min(minstanex_ammo, WEP_CVAR_SEC(minstanex, ammo));
 228                         else
 229                                 used_ammo = minstanex_ammo;
 230
 231                         W_Reload(used_ammo, "weapons/reload.wav");
 232                         return TRUE;
 233                 }
 234                 case WR_SUICIDEMESSAGE:
 235                 {
 236                         return WEAPON_THINKING_WITH_PORTALS;
 237                 }
 238                 case WR_KILLMESSAGE:
 239                 {
 240                         return WEAPON_MINSTANEX_MURDER;
 241                 }
 242         }
 243         return TRUE;
 244 }
 245 #endif
 246 #ifdef CSQC
 247 float w_minstanex(float req)
 248 {
 249         switch(req)
 250         {
 251                 case WR_IMPACTEFFECT:
 252                 {
 253                         vector org2;
 254                         org2 = w_org + w_backoff * 6;
 255                         pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 256                         if(!w_issilent)
 257                                 sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 258
 259                         return TRUE;
 260                 }
 261                 case WR_INIT:
 262                 {
 263                         precache_sound("weapons/neximpact.wav");
 264                         return TRUE;
 265                 }
 266         }
 267         return TRUE;
 268 }
 269 #endif
 270 #endif