qcsrc/common/weapons/w_rifle.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ RIFLE,
   4 /* function */ w_rifle,
   5 /* ammotype */ IT_NAILS,
   6 /* impulse  */ 7,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "campingrifle",
  10 /* netname  */ "rifle",
  11 /* fullname */ _("Rifle")
  12 );
  13
  14 #define RIFLE_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_BOTH, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_BOTH, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_BOTH, bulletconstant) \
  18         WEP_ADD_CVAR(weapon, MO_BOTH, bullethail) \
  19         WEP_ADD_CVAR(weapon, MO_BOTH, burstcost) \
  20         WEP_ADD_CVAR(weapon, MO_BOTH, damage) \
  21         WEP_ADD_CVAR(weapon, MO_BOTH, force) \
  22         WEP_ADD_CVAR(weapon, MO_BOTH, lifetime) \
  23         WEP_ADD_CVAR(weapon, MO_BOTH, refire) \
  24         WEP_ADD_CVAR(weapon, MO_BOTH, shots) \
  25         WEP_ADD_CVAR(weapon, MO_BOTH, speed) \
  26         WEP_ADD_CVAR(weapon, MO_BOTH, spread) \
  27         WEP_ADD_CVAR(weapon, MO_BOTH, tracer) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, bursttime) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, secondary) \
  30         WEP_ADD_CVAR(weapon, MO_SEC,  reload) \
  31         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  32         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  33         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  34         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  35
  36 #ifdef SVQC
  37 RIFLE_SETTINGS(rifle)
  38 void spawnfunc_weapon_rifle (void) { weapon_defaultspawnfunc(WEP_RIFLE); }
  39
  40 // compatibility aliases
  41 void spawnfunc_weapon_campingrifle (void) { spawnfunc_weapon_rifle(); }
  42 void spawnfunc_weapon_sniperrifle (void) { spawnfunc_weapon_rifle(); }
  43
  44 .float rifle_accumulator;
  45 #endif
  46 #else
  47 #ifdef SVQC
  48
  49 void W_Rifle_FireBullet(float pSpread, float pDamage, float pForce, float pSpeed, float pLifetime, float pAmmo, float deathtype, float pBulletConstant, float pTracer, float pShots, string pSound)
  50 {
  51         float i;
  52
  53         W_DecreaseAmmo(ammo_nails, pAmmo, autocvar_g_balance_rifle_reload_ammo);
  54
  55         W_SetupShot (self, autocvar_g_antilag_bullets && pSpeed >= autocvar_g_antilag_bullets, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  56
  57         pointparticles(particleeffectnum("rifle_muzzleflash"), w_shotorg, w_shotdir * 2000, 1);
  58
  59         if(self.BUTTON_ZOOM | self.BUTTON_ZOOMSCRIPT) // if zoomed, shoot from the eye
  60         {
  61                 w_shotdir = v_forward;
  62                 w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
  63         }
  64
  65         for(i = 0; i < pShots; ++i)
  66                 fireBallisticBullet(w_shotorg, w_shotdir, pSpread, pSpeed, pLifetime, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE), 1, pBulletConstant);
  67         endFireBallisticBullet();
  68
  69         if (autocvar_g_casings >= 2)
  70                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  71 }
  72
  73 void W_Rifle_Attack()
  74 {
  75         W_Rifle_FireBullet(WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, speed), WEP_CVAR_PRI(rifle, lifetime), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE, WEP_CVAR_PRI(rifle, bulletconstant), WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), "weapons/campingrifle_fire.wav");
  76 }
  77
  78 void W_Rifle_Attack2()
  79 {
  80         W_Rifle_FireBullet(WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, speed), WEP_CVAR_SEC(rifle, lifetime), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, bulletconstant), WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), "weapons/campingrifle_fire2.wav");
  81 }
  82
  83 .void(void) rifle_bullethail_attackfunc;
  84 .float rifle_bullethail_frame;
  85 .float rifle_bullethail_animtime;
  86 .float rifle_bullethail_refire;
  87 void W_Rifle_BulletHail_Continue()
  88 {
  89         float r, sw, af;
  90
  91         sw = self.switchweapon; // make it not detect weapon changes as reason to abort firing
  92         af = ATTACK_FINISHED(self);
  93         self.switchweapon = self.weapon;
  94         ATTACK_FINISHED(self) = time;
  95         print(ftos(self.ammo_nails), "\n");
  96         r = weapon_prepareattack(self.rifle_bullethail_frame == WFRAME_FIRE2, self.rifle_bullethail_refire);
  97         if(self.switchweapon == self.weapon)
  98                 self.switchweapon = sw;
  99         if(r)
 100         {
 101                 self.rifle_bullethail_attackfunc();
 102                 weapon_thinkf(self.rifle_bullethail_frame, self.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
 103                 print("thinkf set\n");
 104         }
 105         else
 106         {
 107                 ATTACK_FINISHED(self) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
 108                 print("out of ammo... ", ftos(self.weaponentity.state), "\n");
 109         }
 110 }
 111
 112 void W_Rifle_BulletHail(float mode, void(void) AttackFunc, float fr, float animtime, float refire)
 113 {
 114         // if we get here, we have at least one bullet to fire
 115         AttackFunc();
 116         if(mode)
 117         {
 118                 // continue hail
 119                 self.rifle_bullethail_attackfunc = AttackFunc;
 120                 self.rifle_bullethail_frame = fr;
 121                 self.rifle_bullethail_animtime = animtime;
 122                 self.rifle_bullethail_refire = refire;
 123                 weapon_thinkf(fr, animtime, W_Rifle_BulletHail_Continue);
 124         }
 125         else
 126         {
 127                 // just one shot
 128                 weapon_thinkf(fr, animtime, w_ready);
 129         }
 130 }
 131
 132 .float bot_secondary_riflemooth;
 133 float w_rifle(float req)
 134 {
 135         float ammo_amount;
 136
 137         switch(req)
 138         {
 139                 case WR_AIM:
 140                 {
 141                         self.BUTTON_ATCK=FALSE;
 142                         self.BUTTON_ATCK2=FALSE;
 143                         if(vlen(self.origin-self.enemy.origin) > 1000)
 144                                 self.bot_secondary_riflemooth = 0;
 145                         if(self.bot_secondary_riflemooth == 0)
 146                         {
 147                                 if(bot_aim(WEP_CVAR_PRI(rifle, speed), 0, WEP_CVAR_PRI(rifle, lifetime), FALSE))
 148                                 {
 149                                         self.BUTTON_ATCK = TRUE;
 150                                         if(random() < 0.01) self.bot_secondary_riflemooth = 1;
 151                                 }
 152                         }
 153                         else
 154                         {
 155                                 if(bot_aim(WEP_CVAR_SEC(rifle, speed), 0, WEP_CVAR_SEC(rifle, lifetime), FALSE))
 156                                 {
 157                                         self.BUTTON_ATCK2 = TRUE;
 158                                         if(random() < 0.03) self.bot_secondary_riflemooth = 0;
 159                                 }
 160                         }
 161
 162                         return TRUE;
 163                 }
 164                 case WR_THINK:
 165                 {
 166                         if(autocvar_g_balance_rifle_reload_ammo && self.clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) // forced reload
 167                                 WEP_ACTION(self.weapon, WR_RELOAD);
 168                         else
 169                         {
 170                                 self.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), self.rifle_accumulator, time);
 171                                 if (self.BUTTON_ATCK)
 172                                 if (weapon_prepareattack_check(0, WEP_CVAR_PRI(rifle, refire)))
 173                                 if (time >= self.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 174                                 {
 175                                         weapon_prepareattack_do(0, WEP_CVAR_PRI(rifle, refire));
 176                                         W_Rifle_BulletHail(WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 177                                         self.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 178                                 }
 179                                 if (self.BUTTON_ATCK2)
 180                                 {
 181                                         if (WEP_CVAR(rifle, secondary))
 182                                         {
 183                                                 if(WEP_CVAR_SEC(rifle, reload))
 184                                                         WEP_ACTION(self.weapon, WR_RELOAD);
 185                                                 else
 186                                                 {
 187                                                         if (weapon_prepareattack_check(1, WEP_CVAR_SEC(rifle, refire)))
 188                                                         if (time >= self.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 189                                                         {
 190                                                                 weapon_prepareattack_do(1, WEP_CVAR_SEC(rifle, refire));
 191                                                                 W_Rifle_BulletHail(WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 192                                                                 self.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 193                                                         }
 194                                                 }
 195                                         }
 196                                 }
 197                         }
 198
 199                         return TRUE;
 200                 }
 201                 case WR_INIT:
 202                 {
 203                         precache_model ("models/weapons/g_campingrifle.md3");
 204                         precache_model ("models/weapons/v_campingrifle.md3");
 205                         precache_model ("models/weapons/h_campingrifle.iqm");
 206                         precache_sound ("weapons/campingrifle_fire.wav");
 207                         precache_sound ("weapons/campingrifle_fire2.wav");
 208                         #define WEP_ADD_CVAR(weapon,mode,name) /*nothing*/
 209                         #define WEP_ADD_PROP(weapon,prop,name) WEP_SET_PROP(WEP_RIFLE,weapon,prop,name)
 210                         RIFLE_SETTINGS(rifle)
 211                         #undef WEP_ADD_CVAR
 212                         #undef WEP_ADD_PROP
 213                         return TRUE;
 214                 }
 215                 case WR_SETUP:
 216                 {
 217                         weapon_setup(WEP_RIFLE);
 218                         self.current_ammo = ammo_nails;
 219                         return TRUE;
 220                 }
 221                 case WR_CHECKAMMO1:
 222                 {
 223                         ammo_amount = self.ammo_nails >= WEP_CVAR_PRI(rifle, ammo);
 224                         ammo_amount += self.(weapon_load[WEP_RIFLE]) >= WEP_CVAR_PRI(rifle, ammo);
 225                         return ammo_amount;
 226                 }
 227                 case WR_CHECKAMMO2:
 228                 {
 229                         ammo_amount = self.ammo_nails >= WEP_CVAR_SEC(rifle, ammo);
 230                         ammo_amount += self.(weapon_load[WEP_RIFLE]) >= WEP_CVAR_SEC(rifle, ammo);
 231                         return ammo_amount;
 232                 }
 233                 case WR_CONFIG:
 234                 {
 235                         WEP_CONFIG_SETTINGS(RIFLE_SETTINGS(rifle))
 236                         return TRUE;
 237                 }
 238                 case WR_RESETPLAYER:
 239                 {
 240                         self.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 241                         return TRUE;
 242                 }
 243                 case WR_RELOAD:
 244                 {
 245                         W_Reload(min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), autocvar_g_balance_rifle_reload_ammo, autocvar_g_balance_rifle_reload_time, "weapons/reload.wav");
 246                         return TRUE;
 247                 }
 248                 case WR_SUICIDEMESSAGE:
 249                 {
 250                         return WEAPON_THINKING_WITH_PORTALS;
 251                 }
 252                 case WR_KILLMESSAGE:
 253                 {
 254                         if(w_deathtype & HITTYPE_SECONDARY)
 255                         {
 256                                 if(w_deathtype & HITTYPE_BOUNCE)
 257                                         return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 258                                 else
 259                                         return WEAPON_RIFLE_MURDER_HAIL;
 260                         }
 261                         else
 262                         {
 263                                 if(w_deathtype & HITTYPE_BOUNCE)
 264                                         return WEAPON_RIFLE_MURDER_PIERCING;
 265                                 else
 266                                         return WEAPON_RIFLE_MURDER;
 267                         }
 268                 }
 269         }
 270         return TRUE;
 271 }
 272 #endif
 273 #ifdef CSQC
 274 float w_rifle(float req)
 275 {
 276         switch(req)
 277         {
 278                 case WR_IMPACTEFFECT:
 279                 {
 280                         vector org2;
 281                         org2 = w_org + w_backoff * 2;
 282                         pointparticles(particleeffectnum("machinegun_impact"), org2, w_backoff * 1000, 1);
 283                         if(!w_issilent)
 284                         {
 285                                 if(w_random < 0.2)
 286                                         sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 287                                 else if(w_random < 0.4)
 288                                         sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 289                                 else if(w_random < 0.5)
 290                                         sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 291                         }
 292
 293                         return TRUE;
 294                 }
 295                 case WR_INIT:
 296                 {
 297                         precache_sound("weapons/ric1.wav");
 298                         precache_sound("weapons/ric2.wav");
 299                         precache_sound("weapons/ric3.wav");
 300                         return TRUE;
 301                 }
 302         }
 303
 304         return TRUE;
 305 }
 306 #endif
 307 #endif