qcsrc/common/weapons/w_rifle.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ RIFLE,
   4 /* function */ w_rifle,
   5 /* ammotype */ IT_NAILS,
   6 /* impulse  */ 7,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "campingrifle",
  10 /* netname  */ "rifle",
  11 /* fullname */ _("Rifle")
  12 );
  13
  14 #define RIFLE_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_BOTH, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_BOTH, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_BOTH, bulletconstant) \
  18         WEP_ADD_CVAR(weapon, MO_BOTH, bullethail) \
  19         WEP_ADD_CVAR(weapon, MO_BOTH, burstcost) \
  20         WEP_ADD_CVAR(weapon, MO_BOTH, damage) \
  21         WEP_ADD_CVAR(weapon, MO_BOTH, force) \
  22         WEP_ADD_CVAR(weapon, MO_BOTH, lifetime) \
  23         WEP_ADD_CVAR(weapon, MO_BOTH, refire) \
  24         WEP_ADD_CVAR(weapon, MO_BOTH, shots) \
  25         WEP_ADD_CVAR(weapon, MO_BOTH, speed) \
  26         WEP_ADD_CVAR(weapon, MO_BOTH, spread) \
  27         WEP_ADD_CVAR(weapon, MO_BOTH, tracer) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, bursttime) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, secondary) \
  30         WEP_ADD_CVAR(weapon, MO_SEC,  reload) \
  31         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  32         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  33         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  34         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  35
  36 #ifdef SVQC
  37 RIFLE_SETTINGS(rifle)
  38 .float rifle_accumulator;
  39 #endif
  40 #else
  41 #ifdef SVQC
  42 void spawnfunc_weapon_rifle (void) { weapon_defaultspawnfunc(WEP_RIFLE); }
  43 void spawnfunc_weapon_campingrifle (void) { spawnfunc_weapon_rifle(); }
  44 void spawnfunc_weapon_sniperrifle (void) { spawnfunc_weapon_rifle(); }
  45
  46 void W_Rifle_FireBullet(float pSpread, float pDamage, float pForce, float pSpeed, float pLifetime, float pAmmo, float deathtype, float pBulletConstant, float pTracer, float pShots, string pSound)
  47 {
  48         float i;
  49
  50         W_DecreaseAmmo(ammo_nails, pAmmo, autocvar_g_balance_rifle_reload_ammo);
  51
  52         W_SetupShot (self, autocvar_g_antilag_bullets && pSpeed >= autocvar_g_antilag_bullets, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  53
  54         pointparticles(particleeffectnum("rifle_muzzleflash"), w_shotorg, w_shotdir * 2000, 1);
  55
  56         if(self.BUTTON_ZOOM | self.BUTTON_ZOOMSCRIPT) // if zoomed, shoot from the eye
  57         {
  58                 w_shotdir = v_forward;
  59                 w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
  60         }
  61
  62         for(i = 0; i < pShots; ++i)
  63                 fireBallisticBullet(w_shotorg, w_shotdir, pSpread, pSpeed, pLifetime, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE), 1, pBulletConstant);
  64         endFireBallisticBullet();
  65
  66         if (autocvar_g_casings >= 2)
  67                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  68 }
  69
  70 void W_Rifle_Attack()
  71 {
  72         W_Rifle_FireBullet(WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, speed), WEP_CVAR_PRI(rifle, lifetime), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE, WEP_CVAR_PRI(rifle, bulletconstant), WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), "weapons/campingrifle_fire.wav");
  73 }
  74
  75 void W_Rifle_Attack2()
  76 {
  77         W_Rifle_FireBullet(WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, speed), WEP_CVAR_SEC(rifle, lifetime), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, bulletconstant), WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), "weapons/campingrifle_fire2.wav");
  78 }
  79
  80 .void(void) rifle_bullethail_attackfunc;
  81 .float rifle_bullethail_frame;
  82 .float rifle_bullethail_animtime;
  83 .float rifle_bullethail_refire;
  84 void W_Rifle_BulletHail_Continue()
  85 {
  86         float r, sw, af;
  87
  88         sw = self.switchweapon; // make it not detect weapon changes as reason to abort firing
  89         af = ATTACK_FINISHED(self);
  90         self.switchweapon = self.weapon;
  91         ATTACK_FINISHED(self) = time;
  92         print(ftos(self.ammo_nails), "\n");
  93         r = weapon_prepareattack(self.rifle_bullethail_frame == WFRAME_FIRE2, self.rifle_bullethail_refire);
  94         if(self.switchweapon == self.weapon)
  95                 self.switchweapon = sw;
  96         if(r)
  97         {
  98                 self.rifle_bullethail_attackfunc();
  99                 weapon_thinkf(self.rifle_bullethail_frame, self.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
 100                 print("thinkf set\n");
 101         }
 102         else
 103         {
 104                 ATTACK_FINISHED(self) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
 105                 print("out of ammo... ", ftos(self.weaponentity.state), "\n");
 106         }
 107 }
 108
 109 void W_Rifle_BulletHail(float mode, void(void) AttackFunc, float fr, float animtime, float refire)
 110 {
 111         // if we get here, we have at least one bullet to fire
 112         AttackFunc();
 113         if(mode)
 114         {
 115                 // continue hail
 116                 self.rifle_bullethail_attackfunc = AttackFunc;
 117                 self.rifle_bullethail_frame = fr;
 118                 self.rifle_bullethail_animtime = animtime;
 119                 self.rifle_bullethail_refire = refire;
 120                 weapon_thinkf(fr, animtime, W_Rifle_BulletHail_Continue);
 121         }
 122         else
 123         {
 124                 // just one shot
 125                 weapon_thinkf(fr, animtime, w_ready);
 126         }
 127 }
 128
 129 .float bot_secondary_riflemooth;
 130 float w_rifle(float req)
 131 {
 132         float ammo_amount;
 133
 134         switch(req)
 135         {
 136                 case WR_AIM:
 137                 {
 138                         self.BUTTON_ATCK=FALSE;
 139                         self.BUTTON_ATCK2=FALSE;
 140                         if(vlen(self.origin-self.enemy.origin) > 1000)
 141                                 self.bot_secondary_riflemooth = 0;
 142                         if(self.bot_secondary_riflemooth == 0)
 143                         {
 144                                 if(bot_aim(WEP_CVAR_PRI(rifle, speed), 0, WEP_CVAR_PRI(rifle, lifetime), FALSE))
 145                                 {
 146                                         self.BUTTON_ATCK = TRUE;
 147                                         if(random() < 0.01) self.bot_secondary_riflemooth = 1;
 148                                 }
 149                         }
 150                         else
 151                         {
 152                                 if(bot_aim(WEP_CVAR_SEC(rifle, speed), 0, WEP_CVAR_SEC(rifle, lifetime), FALSE))
 153                                 {
 154                                         self.BUTTON_ATCK2 = TRUE;
 155                                         if(random() < 0.03) self.bot_secondary_riflemooth = 0;
 156                                 }
 157                         }
 158
 159                         return TRUE;
 160                 }
 161                 case WR_THINK:
 162                 {
 163                         if(autocvar_g_balance_rifle_reload_ammo && self.clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) // forced reload
 164                                 WEP_ACTION(self.weapon, WR_RELOAD);
 165                         else
 166                         {
 167                                 self.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), self.rifle_accumulator, time);
 168                                 if (self.BUTTON_ATCK)
 169                                 if (weapon_prepareattack_check(0, WEP_CVAR_PRI(rifle, refire)))
 170                                 if (time >= self.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 171                                 {
 172                                         weapon_prepareattack_do(0, WEP_CVAR_PRI(rifle, refire));
 173                                         W_Rifle_BulletHail(WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 174                                         self.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 175                                 }
 176                                 if (self.BUTTON_ATCK2)
 177                                 {
 178                                         if (WEP_CVAR(rifle, secondary))
 179                                         {
 180                                                 if(WEP_CVAR_SEC(rifle, reload))
 181                                                         WEP_ACTION(self.weapon, WR_RELOAD);
 182                                                 else
 183                                                 {
 184                                                         if (weapon_prepareattack_check(1, WEP_CVAR_SEC(rifle, refire)))
 185                                                         if (time >= self.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 186                                                         {
 187                                                                 weapon_prepareattack_do(1, WEP_CVAR_SEC(rifle, refire));
 188                                                                 W_Rifle_BulletHail(WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 189                                                                 self.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 190                                                         }
 191                                                 }
 192                                         }
 193                                 }
 194                         }
 195
 196                         return TRUE;
 197                 }
 198                 case WR_INIT:
 199                 {
 200                         precache_model ("models/weapons/g_campingrifle.md3");
 201                         precache_model ("models/weapons/v_campingrifle.md3");
 202                         precache_model ("models/weapons/h_campingrifle.iqm");
 203                         precache_sound ("weapons/campingrifle_fire.wav");
 204                         precache_sound ("weapons/campingrifle_fire2.wav");
 205                         WEP_SET_PROPS(RIFLE_SETTINGS(rifle), WEP_RIFLE)
 206                         return TRUE;
 207                 }
 208                 case WR_SETUP:
 209                 {
 210                         self.current_ammo = ammo_nails;
 211                         return TRUE;
 212                 }
 213                 case WR_CHECKAMMO1:
 214                 {
 215                         ammo_amount = self.ammo_nails >= WEP_CVAR_PRI(rifle, ammo);
 216                         ammo_amount += self.(weapon_load[WEP_RIFLE]) >= WEP_CVAR_PRI(rifle, ammo);
 217                         return ammo_amount;
 218                 }
 219                 case WR_CHECKAMMO2:
 220                 {
 221                         ammo_amount = self.ammo_nails >= WEP_CVAR_SEC(rifle, ammo);
 222                         ammo_amount += self.(weapon_load[WEP_RIFLE]) >= WEP_CVAR_SEC(rifle, ammo);
 223                         return ammo_amount;
 224                 }
 225                 case WR_CONFIG:
 226                 {
 227                         WEP_CONFIG_SETTINGS(RIFLE_SETTINGS(rifle))
 228                         return TRUE;
 229                 }
 230                 case WR_RESETPLAYER:
 231                 {
 232                         self.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 233                         return TRUE;
 234                 }
 235                 case WR_RELOAD:
 236                 {
 237                         W_Reload(min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), "weapons/reload.wav");
 238                         return TRUE;
 239                 }
 240                 case WR_SUICIDEMESSAGE:
 241                 {
 242                         return WEAPON_THINKING_WITH_PORTALS;
 243                 }
 244                 case WR_KILLMESSAGE:
 245                 {
 246                         if(w_deathtype & HITTYPE_SECONDARY)
 247                         {
 248                                 if(w_deathtype & HITTYPE_BOUNCE)
 249                                         return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 250                                 else
 251                                         return WEAPON_RIFLE_MURDER_HAIL;
 252                         }
 253                         else
 254                         {
 255                                 if(w_deathtype & HITTYPE_BOUNCE)
 256                                         return WEAPON_RIFLE_MURDER_PIERCING;
 257                                 else
 258                                         return WEAPON_RIFLE_MURDER;
 259                         }
 260                 }
 261         }
 262         return TRUE;
 263 }
 264 #endif
 265 #ifdef CSQC
 266 float w_rifle(float req)
 267 {
 268         switch(req)
 269         {
 270                 case WR_IMPACTEFFECT:
 271                 {
 272                         vector org2;
 273                         org2 = w_org + w_backoff * 2;
 274                         pointparticles(particleeffectnum("machinegun_impact"), org2, w_backoff * 1000, 1);
 275                         if(!w_issilent)
 276                         {
 277                                 if(w_random < 0.2)
 278                                         sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 279                                 else if(w_random < 0.4)
 280                                         sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 281                                 else if(w_random < 0.5)
 282                                         sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 283                         }
 284
 285                         return TRUE;
 286                 }
 287                 case WR_INIT:
 288                 {
 289                         precache_sound("weapons/ric1.wav");
 290                         precache_sound("weapons/ric2.wav");
 291                         precache_sound("weapons/ric3.wav");
 292                         return TRUE;
 293                 }
 294         }
 295
 296         return TRUE;
 297 }
 298 #endif
 299 #endif