qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SEEKER,
   4 /* function */ w_seeker,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 8,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "seeker",
  10 /* netname  */ "seeker",
  11 /* fullname */ _("T.A.G. Seeker")
  12 );
  13
  14 #define SEEKER_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_SEEKER, seeker, MO_NONE, type) \
  16         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_ammo) \
  17         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_animtime) \
  18         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_damage) \
  19         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_edgedamage) \
  20         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_force) \
  21         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_lifetime) \
  22         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_lifetime_rand) \
  23         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_radius) \
  24         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_refire) \
  25         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed) \
  26         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed_up) \
  27         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed_z) \
  28         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_spread) \
  29         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_accel) \
  30         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_ammo) \
  31         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_animtime) \
  32         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_count) \
  33         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_damage) \
  34         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_damageforcescale) \
  35         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_decel) \
  36         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_delay) \
  37         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_edgedamage) \
  38         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_force) \
  39         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_health) \
  40         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_lifetime) \
  41         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy) \
  42         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy_delay) \
  43         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy_maxrange) \
  44         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_radius) \
  45         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_refire) \
  46         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart) \
  47         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_mindist) \
  48         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_trace_max) \
  49         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_trace_min) \
  50         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed) \
  51         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_max) \
  52         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_up) \
  53         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_z) \
  54         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_spread) \
  55         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_turnrate) \
  56         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_ammo) \
  57         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_animtime) \
  58         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_damageforcescale) \
  59         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_health) \
  60         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_lifetime) \
  61         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_refire) \
  62         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_speed) \
  63         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_spread) \
  64         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_tracker_lifetime) \
  65         w_prop(WEP_SEEKER, seeker, float,  reloading_ammo, reload_ammo) \
  66         w_prop(WEP_SEEKER, seeker, float,  reloading_time, reload_time) \
  67         w_prop(WEP_SEEKER, seeker, float,  switchdelay_raise, switchdelay_raise) \
  68         w_prop(WEP_SEEKER, seeker, float,  switchdelay_drop, switchdelay_drop) \
  69         w_prop(WEP_SEEKER, seeker, string, weaponreplace, weaponreplace) \
  70         w_prop(WEP_SEEKER, seeker, float,  weaponstart, weaponstart) \
  71         w_prop(WEP_SEEKER, seeker, float,  weaponstartoverride, weaponstartoverride)
  72
  73 #ifdef SVQC
  74 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  75 .entity tag_target, wps_tag_tracker;
  76 .float tag_time;
  77 #endif
  78 #else
  79 #ifdef SVQC
  80 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  81
  82 // ============================
  83 // Begin: Missile functions, these are general functions to be manipulated by other code
  84 // ============================
  85 void Seeker_Missile_Explode ()
  86 {
  87         self.event_damage = func_null;
  88         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  89
  90         remove (self);
  91 }
  92
  93 void Seeker_Missile_Touch()
  94 {
  95         PROJECTILE_TOUCH;
  96
  97         Seeker_Missile_Explode();
  98 }
  99
 100 void Seeker_Missile_Think()
 101 {
 102         entity e;
 103         vector desireddir, olddir, newdir, eorg;
 104         float turnrate;
 105         float dist;
 106         float spd;
 107
 108         if (time > self.cnt)
 109         {
 110                 self.projectiledeathtype |= HITTYPE_SPLASH;
 111                 Seeker_Missile_Explode();
 112         }
 113
 114         spd = vlen(self.velocity);
 115         spd = bound(
 116                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 117                 WEP_CVAR(seeker, missile_speed_max),
 118                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 119         );
 120
 121         if (self.enemy != world)
 122                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 123                         self.enemy = world;
 124
 125         if (self.enemy != world)
 126         {
 127                 e               = self.enemy;
 128                 eorg            = 0.5 * (e.absmin + e.absmax);
 129                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 130                 desireddir      = normalize(eorg - self.origin);
 131                 olddir          = normalize(self.velocity); // get my current direction
 132                 dist            = vlen(eorg - self.origin);
 133
 134                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 135                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 136                 {
 137                         // Is it a better idea (shorter distance) to trace to the target itself?
 138                         if ( vlen(self.origin + olddir * self.wait) < dist)
 139                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 140                         else
 141                                 traceline(self.origin, eorg, FALSE, self);
 142
 143                         // Setup adaptive tracelength
 144                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 145
 146                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 147                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 148                 }
 149
 150                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 151                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 152         }
 153         else
 154                 dist = 0;
 155
 156         // Proxy
 157         if (WEP_CVAR(seeker, missile_proxy))
 158         {
 159                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 160                 {
 161                         if (self.autoswitch == 0)
 162                         {
 163                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 164                         }
 165                         else
 166                         {
 167                                 if (self.autoswitch <= time)
 168                                 {
 169                                         Seeker_Missile_Explode();
 170                                         self.autoswitch = 0;
 171                                 }
 172                         }
 173                 }
 174                 else
 175                 {
 176                         if (self.autoswitch != 0)
 177                                 self.autoswitch = 0;
 178                 }
 179         }
 180         ///////////////
 181
 182         if (self.enemy.deadflag != DEAD_NO)
 183         {
 184                 self.enemy = world;
 185                 self.cnt = time + 1 + (random() * 4);
 186                 self.nextthink = self.cnt;
 187                 return;
 188         }
 189
 190         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 191         self.nextthink = time;// + 0.05; // csqc projectiles
 192         UpdateCSQCProjectile(self);
 193 }
 194
 195
 196
 197 void Seeker_Missile_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 198 {
 199         if (self.health <= 0)
 200                 return;
 201
 202         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 203                 return; // g_projectiles_damage says to halt
 204
 205         if (self.realowner == attacker)
 206                 self.health = self.health - (damage * 0.25);
 207         else
 208                 self.health = self.health - damage;
 209
 210         if (self.health <= 0)
 211                 W_PrepareExplosionByDamage(attacker, Seeker_Missile_Explode);
 212 }
 213
 214 /*
 215 void Seeker_Missile_Animate()
 216 {
 217         self.frame = self.frame +1;
 218         self.nextthink = time + 0.05;
 219
 220         if (self.enemy != world)
 221                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 222                         self.enemy = world;
 223
 224         if(self.frame == 5)
 225         {
 226                 self.think           = Seeker_Missile_Think;
 227                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 228
 229                 if (autocvar_g_balance_seeker_missile_proxy)
 230                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 231                 else
 232                         self.movetype    = MOVETYPE_FLYMISSILE;
 233         }
 234
 235         UpdateCSQCProjectile(self);
 236 }
 237 */
 238
 239 void Seeker_Fire_Missile(vector f_diff, entity m_target)
 240 {
 241         entity missile;
 242
 243         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, missile_ammo), autocvar_g_balance_seeker_reload_ammo);
 244
 245         makevectors(self.v_angle);
 246         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 247         w_shotorg += f_diff;
 248         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 249
 250         //self.detornator         = FALSE;
 251
 252         missile                 = spawn();
 253         missile.owner           = missile.realowner = self;
 254         missile.classname       = "seeker_missile";
 255         missile.bot_dodge       = TRUE;
 256         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 257
 258         missile.think           = Seeker_Missile_Think;
 259         missile.touch           = Seeker_Missile_Touch;
 260         missile.event_damage    = Seeker_Missile_Damage;
 261         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 262         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 263         missile.enemy           = m_target;
 264         missile.solid           = SOLID_BBOX;
 265         missile.scale           = 2;
 266         missile.takedamage      = DAMAGE_YES;
 267         missile.health          = WEP_CVAR(seeker, missile_health);
 268         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 269         missile.damagedbycontents = TRUE;
 270         //missile.think           = Seeker_Missile_Animate; // csqc projectiles.
 271
 272         if (missile.enemy != world)
 273                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 274         else
 275                 missile.projectiledeathtype = WEP_SEEKER;
 276
 277
 278         setorigin (missile, w_shotorg);
 279         setsize (missile, '-4 -4 -4', '4 4 4');
 280         missile.movetype    = MOVETYPE_FLYMISSILE;
 281         missile.flags       = FL_PROJECTILE;
 282         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 283
 284         WEP_SETUPPROJVELOCITY_UP_NONE(missile, seeker, missile_);
 285
 286         missile.angles = vectoangles (missile.velocity);
 287
 288         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 289
 290         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 291 }
 292
 293 // ============================
 294 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 295 // ============================
 296 void Seeker_Flac_Explode ()
 297 {
 298         self.event_damage = func_null;
 299
 300         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 301
 302         remove (self);
 303 }
 304
 305 void Seeker_Flac_Touch()
 306 {
 307         PROJECTILE_TOUCH;
 308
 309         Seeker_Flac_Explode();
 310 }
 311
 312 void Seeker_Fire_Flac()
 313 {
 314         entity missile;
 315         vector f_diff;
 316         float c;
 317
 318         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, flac_ammo), autocvar_g_balance_seeker_reload_ammo);
 319
 320         c = mod(self.bulletcounter, 4);
 321         switch(c)
 322         {
 323                 case 0:
 324                         f_diff = '-1.25 -3.75 0';
 325                         break;
 326                 case 1:
 327                         f_diff = '+1.25 -3.75 0';
 328                         break;
 329                 case 2:
 330                         f_diff = '-1.25 +3.75 0';
 331                         break;
 332                 case 3:
 333                 default:
 334                         f_diff = '+1.25 +3.75 0';
 335                         break;
 336         }
 337         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 338         w_shotorg += f_diff;
 339
 340         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 341
 342         missile                                 = spawn ();
 343         missile.owner                   = missile.realowner = self;
 344         missile.classname               = "missile";
 345         missile.bot_dodge               = TRUE;
 346         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 347         missile.touch                   = Seeker_Flac_Explode;
 348         missile.use                     = Seeker_Flac_Explode;
 349         missile.think                   = adaptor_think2use_hittype_splash;
 350         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 351         missile.solid                   = SOLID_BBOX;
 352         missile.movetype                = MOVETYPE_FLY;
 353         missile.projectiledeathtype = WEP_SEEKER;
 354         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 355         missile.flags                           = FL_PROJECTILE;
 356         missile.missile_flags       = MIF_SPLASH;
 357
 358         // csqc projectiles
 359         //missile.angles                                = vectoangles (missile.velocity);
 360         //missile.scale = 0.4; // BUG: the model is too big
 361
 362         setorigin (missile, w_shotorg);
 363         setsize (missile, '-2 -2 -2', '2 2 2');
 364
 365         WEP_SETUPPROJVELOCITY_UP_NONE(missile, seeker, flac_);
 366         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 367
 368         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 369 }
 370
 371 // ============================
 372 // Begin: Tag and rocket controllers
 373 // ============================
 374 entity Seeker_Tagged_Info(entity isowner, entity istarget)
 375 {
 376         entity tag;
 377         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 378                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 379                         return tag;
 380
 381         return world;
 382 }
 383
 384 void Seeker_Attack()
 385 {
 386         entity tracker, closest_target;
 387
 388         closest_target = world;
 389         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 390         {
 391                 if (closest_target)
 392                 {
 393                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 394                                 closest_target = tracker.tag_target;
 395                 }
 396                 else
 397                         closest_target = tracker.tag_target;
 398         }
 399
 400         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 401         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 402                 closest_target = world;
 403
 404         Seeker_Fire_Missile('0 0 0', closest_target);
 405 }
 406
 407 void Seeker_Vollycontroller_Think() // TODO: Merge this with Seeker_Attack
 408 {
 409         float c;
 410         entity oldself,oldenemy;
 411         self.cnt = self.cnt - 1;
 412
 413         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.ammo_rockets < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 414         {
 415                 remove(self);
 416                 return;
 417         }
 418
 419         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 420
 421         oldself = self;
 422         self = self.realowner;
 423
 424         oldenemy = self.enemy;
 425         self.enemy = oldself.enemy;
 426
 427         c = mod(self.cnt, 4);
 428         switch(c)
 429         {
 430                 case 0:
 431                         Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 432                         break;
 433                 case 1:
 434                         Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 435                         break;
 436                 case 2:
 437                         Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 438                         break;
 439                 case 3:
 440                 default:
 441                         Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 442                         break;
 443         }
 444
 445         self.enemy = oldenemy;
 446         self = oldself;
 447 }
 448
 449 void Seeker_Tracker_Think()
 450 {
 451         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 452         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 453         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 454         {
 455                 if (self)
 456                 {
 457                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 458                         remove(self);
 459                 }
 460                 return;
 461         }
 462
 463         // Update the think method information
 464         self.nextthink = time;
 465 }
 466
 467 // ============================
 468 // Begin: Tag projectile
 469 // ============================
 470 void Seeker_Tag_Explode ()
 471 {
 472         //if(other==self.realowner)
 473         //    return;
 474         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 475
 476         remove (self);
 477 }
 478
 479 void Seeker_Tag_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 480 {
 481         if (self.health <= 0)
 482                 return;
 483         self.health = self.health - damage;
 484         if (self.health <= 0)
 485                 Seeker_Tag_Explode();
 486 }
 487
 488 void Seeker_Tag_Touch()
 489 {
 490         vector dir;
 491         vector org2;
 492         entity e;
 493
 494         PROJECTILE_TOUCH;
 495
 496         dir     = normalize (self.realowner.origin - self.origin);
 497         org2    = findbetterlocation (self.origin, 8);
 498
 499         te_knightspike(org2);
 500
 501         self.event_damage = func_null;
 502         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 503
 504         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 505         {
 506                 // check to see if this person is already tagged by me
 507                 entity tag = Seeker_Tagged_Info(self.realowner, other);
 508
 509                 if (tag != world)
 510                 {
 511                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 512                                 WaypointSprite_Kill(other.wps_tag_tracker);
 513
 514                         tag.tag_time = time;
 515                 }
 516                 else
 517                 {
 518                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 519                         e             = spawn();
 520                         e.cnt         = WEP_CVAR(seeker, missile_count);
 521                         e.classname   = "tag_tracker";
 522                         e.owner       = self.owner;
 523                         e.realowner   = self.realowner;
 524
 525                         if(WEP_CVAR(seeker, type) == 1)
 526                         {
 527                                 e.tag_target  = other;
 528                                 e.tag_time    = time;
 529                                 e.think       = Seeker_Tracker_Think;
 530                         }
 531                         else
 532                         {
 533                                 e.enemy     = other;
 534                                 e.think     = Seeker_Vollycontroller_Think;
 535                         }
 536
 537                         e.nextthink   = time;
 538                 }
 539
 540                 if(WEP_CVAR(seeker, type) == 1)
 541                 {
 542                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 543                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 544                 }
 545         }
 546
 547         remove(self);
 548         return;
 549 }
 550
 551 void Seeker_Fire_Tag()
 552 {
 553         entity missile;
 554         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, tag_ammo), autocvar_g_balance_seeker_reload_ammo);
 555
 556         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 557
 558         missile                 = spawn();
 559         missile.owner           = missile.realowner = self;
 560         missile.classname       = "seeker_tag";
 561         missile.bot_dodge       = TRUE;
 562         missile.bot_dodgerating = 50;
 563         missile.touch           = Seeker_Tag_Touch;
 564         missile.think           = SUB_Remove;
 565         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 566         missile.movetype        = MOVETYPE_FLY;
 567         missile.solid           = SOLID_BBOX;
 568
 569         missile.takedamage       = DAMAGE_YES;
 570         missile.event_damage     = Seeker_Tag_Damage;
 571         missile.health           = WEP_CVAR(seeker, tag_health);
 572         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 573
 574         setorigin (missile, w_shotorg);
 575         setsize (missile, '-2 -2 -2', '2 2 2');
 576
 577         missile.flags       = FL_PROJECTILE;
 578         //missile.missile_flags = MIF_..?;
 579
 580         missile.movetype    = MOVETYPE_FLY;
 581         WEP_SETUPPROJVELOCITY_NONE(missile, seeker, tag_);
 582         missile.angles = vectoangles (missile.velocity);
 583
 584         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 585
 586         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 587 }
 588
 589 // ============================
 590 // Begin: Genereal weapon functions
 591 // ============================
 592
 593 float w_seeker(float req)
 594 {
 595         float ammo_amount;
 596
 597         switch(req)
 598         {
 599                 case WR_AIM:
 600                 {
 601                         if (WEP_CVAR(seeker, type) == 1)
 602                                 if (Seeker_Tagged_Info(self, self.enemy) != world)
 603                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 604                                 else
 605                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 606                         else
 607                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 608                         return TRUE;
 609                 }
 610                 case WR_THINK:
 611                 {
 612                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 613                                 WEP_ACTION(self.weapon, WR_RELOAD);
 614
 615                         else if (self.BUTTON_ATCK)
 616                         {
 617                                 if (WEP_CVAR(seeker, type) == 1)
 618                                 {
 619                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 620                                         {
 621                                                 Seeker_Attack();
 622                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 623                                         }
 624                                 }
 625                                 else
 626                                 {
 627                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 628                                         {
 629                                                 Seeker_Fire_Tag();
 630                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 631                                         }
 632                                 }
 633                         }
 634
 635                         else if (self.BUTTON_ATCK2)
 636                         {
 637                                 if (WEP_CVAR(seeker, type) == 1)
 638                                 {
 639                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 640                                         {
 641                                                 Seeker_Fire_Tag();
 642                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 643                                         }
 644                                 }
 645                                 else
 646                                 {
 647                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 648                                         {
 649                                                 Seeker_Fire_Flac();
 650                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 651                                         }
 652                                 }
 653                         }
 654
 655                         return TRUE;
 656                 }
 657                 case WR_INIT:
 658                 {
 659                         precache_model ("models/weapons/g_seeker.md3");
 660                         precache_model ("models/weapons/v_seeker.md3");
 661                         precache_model ("models/weapons/h_seeker.iqm");
 662                         precache_sound ("weapons/tag_fire.wav");
 663                         precache_sound ("weapons/flac_fire.wav");
 664                         precache_sound ("weapons/seeker_fire.wav");
 665                         SEEKER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 666                         return TRUE;
 667                 }
 668                 case WR_SETUP:
 669                 {
 670                         self.current_ammo = ammo_rockets;
 671                         return TRUE;
 672                 }
 673                 case WR_CHECKAMMO1:
 674                 {
 675                         if (WEP_CVAR(seeker, type) == 1)
 676                         {
 677                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, missile_ammo);
 678                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 679                         }
 680                         else
 681                         {
 682                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 683                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 684                         }
 685                         return ammo_amount;
 686                 }
 687                 case WR_CHECKAMMO2:
 688                 {
 689                         if (WEP_CVAR(seeker, type) == 1)
 690                         {
 691                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 692                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 693                         }
 694                         else
 695                         {
 696                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, flac_ammo);
 697                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 698                         }
 699                         return ammo_amount;
 700                 }
 701                 case WR_CONFIG:
 702                 {
 703                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 704                         return TRUE;
 705                 }
 706                 case WR_RELOAD:
 707                 {
 708                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 709                         return TRUE;
 710                 }
 711                 case WR_SUICIDEMESSAGE:
 712                 {
 713                         return WEAPON_SEEKER_SUICIDE;
 714                 }
 715                 case WR_KILLMESSAGE:
 716                 {
 717                         if(w_deathtype & HITTYPE_SECONDARY)
 718                                 return WEAPON_SEEKER_MURDER_TAG;
 719                         else
 720                                 return WEAPON_SEEKER_MURDER_SPRAY;
 721                 }
 722         }
 723         return TRUE;
 724 }
 725 #endif
 726 #ifdef CSQC
 727 float w_seeker(float req)
 728 {
 729         switch(req)
 730         {
 731                 case WR_IMPACTEFFECT:
 732                 {
 733                         vector org2;
 734                         org2 = w_org + w_backoff * 6;
 735                         if(w_deathtype & HITTYPE_BOUNCE)
 736                         {
 737                                 if(w_deathtype & HITTYPE_SECONDARY)
 738                                 {
 739                                         if(!w_issilent)
 740                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 741                                 }
 742                                 else
 743                                 {
 744                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 745                                         if(!w_issilent)
 746                                         {
 747                                                 if (w_random<0.15)
 748                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 749                                                 else if (w_random<0.7)
 750                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 751                                                 else
 752                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 753                                         }
 754                                 }
 755                         }
 756                         else
 757                         {
 758                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 759                                 if(!w_issilent)
 760                                 {
 761                                         if (w_random<0.15)
 762                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 763                                         else if (w_random<0.7)
 764                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 765                                         else
 766                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 767                                 }
 768                         }
 769                         return TRUE;
 770                 }
 771                 case WR_INIT:
 772                 {
 773                         precache_sound("weapons/seekerexp1.wav");
 774                         precache_sound("weapons/seekerexp2.wav");
 775                         precache_sound("weapons/seekerexp3.wav");
 776                         precache_sound("weapons/tagexp1.wav");
 777                         precache_sound("weapons/tagexp2.wav");
 778                         precache_sound("weapons/tagexp3.wav");
 779                         precache_sound("weapons/tag_impact.wav");
 780                         return TRUE;
 781                 }
 782         }
 783
 784         return TRUE;
 785 }
 786 #endif
 787 #endif