qcsrc/common/weapons/w_vaporizer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ VAPORIZER,
   4 /* function */ W_Vaporizer,
   5 /* ammotype */ ammo_cells,
   6 /* impulse  */ 7,
   7 /* flags    */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* color        */ '0.5 1 1',
  10 /* model    */ "minstanex",
  11 /* crosshair */ "gfx/crosshairminstanex 0.4",
  12 /* netname  */ "minstanex",
  13 /* fullname */ _("Vaporizer")
  14 );
  15
  16 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  17 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  18         w_cvar(id, sn, PRI, ammo) \
  19         w_cvar(id, sn, PRI, animtime) \
  20         w_cvar(id, sn, PRI, refire) \
  21         w_cvar(id, sn, SEC, ammo) \
  22         w_cvar(id, sn, SEC, animtime) \
  23         w_cvar(id, sn, SEC, damage) \
  24         w_cvar(id, sn, SEC, delay) \
  25         w_cvar(id, sn, SEC, edgedamage) \
  26         w_cvar(id, sn, SEC, force) \
  27         w_cvar(id, sn, SEC, lifetime) \
  28         w_cvar(id, sn, SEC, radius) \
  29         w_cvar(id, sn, SEC, refire) \
  30         w_cvar(id, sn, SEC, shotangle) \
  31         w_cvar(id, sn, SEC, speed) \
  32         w_cvar(id, sn, SEC, spread) \
  33         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  34         w_prop(id, sn, float,  reloading_time, reload_time) \
  35         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  36         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  37         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  38         w_prop(id, sn, float,  weaponstart, weaponstart) \
  39         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  40
  41 #ifdef SVQC
  42 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  43 .float vaporizer_lasthit;
  44 .float jump_interval;
  45 #endif
  46 #else
  47 #ifdef SVQC
  48 void spawnfunc_weapon_vaporizer (void) { weapon_defaultspawnfunc(WEP_VAPORIZER); }
  49 void spawnfunc_weapon_minstanex () { spawnfunc_weapon_vaporizer(); }
  50
  51 void W_Vaporizer_Attack (void)
  52 {
  53         float flying;
  54         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  55
  56         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  57
  58         yoda = 0;
  59         damage_goodhits = 0;
  60         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_VAPORIZER);
  61
  62         if(yoda && flying)
  63                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  64         if(damage_goodhits && self.vaporizer_lasthit)
  65         {
  66                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  67                 damage_goodhits = 0; // only every second time
  68         }
  69
  70         self.vaporizer_lasthit = damage_goodhits;
  71
  72         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  73
  74         // teamcolor / hit beam effect
  75         vector v;
  76         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  77         switch(self.team)
  78         {
  79                 case NUM_TEAM_1:   // Red
  80                         if(damage_goodhits)
  81                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  82                         else
  83                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  84                         break;
  85                 case NUM_TEAM_2:   // Blue
  86                         if(damage_goodhits)
  87                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  88                         else
  89                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  90                         break;
  91                 case NUM_TEAM_3:   // Yellow
  92                         if(damage_goodhits)
  93                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  94                         else
  95                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  96                         break;
  97                 case NUM_TEAM_4:   // Pink
  98                         if(damage_goodhits)
  99                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
 100                         else
 101                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
 102                         break;
 103                 default:
 104                         if(damage_goodhits)
 105                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
 106                         else
 107                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
 108                         break;
 109         }
 110
 111         W_DecreaseAmmo(((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 112 }
 113
 114 float W_Vaporizer(float req)
 115 {
 116         float ammo_amount;
 117         float vaporizer_ammo;
 118
 119         // now multiple WR_s use this
 120         vaporizer_ammo = ((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 121
 122         switch(req)
 123         {
 124                 case WR_AIM:
 125                 {
 126                         if(self.WEP_AMMO(VAPORIZER) > 0)
 127                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 128                         else
 129                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), FALSE); // WEAPONTODO: replace with proper vaporizer cvars
 130
 131                         return TRUE;
 132                 }
 133                 case WR_THINK:
 134                 {
 135                         // if the laser uses load, we also consider its ammo for reloading
 136                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && self.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) // forced reload
 137                                 WEP_ACTION(self.weapon, WR_RELOAD);
 138                         else if(WEP_CVAR(vaporizer, reload_ammo) && self.clip_load < vaporizer_ammo) // forced reload
 139                                 WEP_ACTION(self.weapon, WR_RELOAD);
 140                         else if (self.BUTTON_ATCK)
 141                         {
 142                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(vaporizer, refire)))
 143                                 {
 144                                         W_Vaporizer_Attack();
 145                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 146                                 }
 147                         }
 148                         else if (self.BUTTON_ATCK2)
 149                         {
 150                                 if (self.jump_interval <= time)
 151                                 if (weapon_prepareattack(1, -1))
 152                                 {
 153                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 154                                         self.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 155
 156                                         // decrease ammo for the laser?
 157                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 158                                                 W_DecreaseAmmo(WEP_CVAR_SEC(vaporizer, ammo));
 159
 160                                         // ugly minstagib hack to reuse the fire mode of the laser
 161                                         float w;
 162                                         w = self.weapon;
 163                                         self.weapon = WEP_BLASTER;
 164                                         W_Blaster_Attack(
 165                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 166                                                 WEP_CVAR_SEC(vaporizer, damage),
 167                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 168                                                 WEP_CVAR_SEC(vaporizer, radius),
 169                                                 WEP_CVAR_SEC(vaporizer, force),
 170                                                 WEP_CVAR_SEC(vaporizer, speed),
 171                                                 WEP_CVAR_SEC(vaporizer, spread),
 172                                                 WEP_CVAR_SEC(vaporizer, delay),
 173                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 174                                         );
 175                                         self.weapon = w;
 176
 177                                         // now do normal refire
 178                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 179                                 }
 180                         }
 181
 182                         return TRUE;
 183                 }
 184                 case WR_INIT:
 185                 {
 186                         precache_model("models/nexflash.md3");
 187                         precache_model("models/weapons/g_minstanex.md3");
 188                         precache_model("models/weapons/v_minstanex.md3");
 189                         precache_model("models/weapons/h_minstanex.iqm");
 190                         precache_sound("weapons/minstanexfire.wav");
 191                         precache_sound("weapons/nexwhoosh1.wav");
 192                         precache_sound("weapons/nexwhoosh2.wav");
 193                         precache_sound("weapons/nexwhoosh3.wav");
 194                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 195                         VAPORIZER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 196                         return TRUE;
 197                 }
 198                 case WR_SETUP:
 199                 {
 200                         self.ammo_field = WEP_AMMO(VAPORIZER);
 201                         self.vaporizer_lasthit = 0;
 202                         return TRUE;
 203                 }
 204                 case WR_CHECKAMMO1:
 205                 {
 206                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= vaporizer_ammo;
 207                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= vaporizer_ammo;
 208                         return ammo_amount;
 209                 }
 210                 case WR_CHECKAMMO2:
 211                 {
 212                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 213                                 return TRUE;
 214                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 215                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= WEP_CVAR_SEC(vaporizer, ammo);
 216                         return ammo_amount;
 217                 }
 218                 case WR_CONFIG:
 219                 {
 220                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 221                         return TRUE;
 222                 }
 223                 case WR_RESETPLAYER:
 224                 {
 225                         self.vaporizer_lasthit = 0;
 226                         return TRUE;
 227                 }
 228                 case WR_RELOAD:
 229                 {
 230                         float used_ammo;
 231                         if(WEP_CVAR_SEC(vaporizer, ammo))
 232                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 233                         else
 234                                 used_ammo = vaporizer_ammo;
 235
 236                         W_Reload(used_ammo, "weapons/reload.wav");
 237                         return TRUE;
 238                 }
 239                 case WR_SUICIDEMESSAGE:
 240                 {
 241                         return WEAPON_THINKING_WITH_PORTALS;
 242                 }
 243                 case WR_KILLMESSAGE:
 244                 {
 245                         return WEAPON_VAPORIZER_MURDER;
 246                 }
 247         }
 248         return TRUE;
 249 }
 250 #endif
 251 #ifdef CSQC
 252 float W_Vaporizer(float req)
 253 {
 254         switch(req)
 255         {
 256                 case WR_IMPACTEFFECT:
 257                 {
 258                         vector org2;
 259                         org2 = w_org + w_backoff * 6;
 260                         pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 261                         if(!w_issilent)
 262                                 sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 263
 264                         return TRUE;
 265                 }
 266                 case WR_INIT:
 267                 {
 268                         precache_sound("weapons/neximpact.wav");
 269                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 270                         {
 271                                 precache_pic("gfx/reticle_nex");
 272                         }
 273                         return TRUE;
 274                 }
 275                 case WR_ZOOMRETICLE:
 276                 {
 277                         if(button_zoom || zoomscript_caught)
 278                         {
 279                                 reticle_image = "gfx/reticle_nex";
 280                                 return TRUE;
 281                         }
 282                         else
 283                         {
 284                                 // no weapon specific image for this weapon
 285                                 return FALSE;
 286                         }
 287                 }
 288         }
 289         return TRUE;
 290 }
 291 #endif
 292 #endif