qcsrc/common/weapons/w_vaporizer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ VAPORIZER,
   4 /* function  */ W_Vaporizer,
   5 /* ammotype  */ ammo_cells,
   6 /* impulse   */ 7,
   7 /* flags     */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.5 1 1',
  10 /* modelname */ "minstanex",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairminstanex 0.4",
  13 /* wepimg    */ "weaponminstanex",
  14 /* refname   */ "vaporizer",
  15 /* wepname   */ _("Vaporizer")
  16 );
  17
  18 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  19 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, PRI, ammo) \
  21         w_cvar(id, sn, PRI, animtime) \
  22         w_cvar(id, sn, PRI, refire) \
  23         w_cvar(id, sn, SEC, ammo) \
  24         w_cvar(id, sn, SEC, animtime) \
  25         w_cvar(id, sn, SEC, damage) \
  26         w_cvar(id, sn, SEC, delay) \
  27         w_cvar(id, sn, SEC, edgedamage) \
  28         w_cvar(id, sn, SEC, force) \
  29         w_cvar(id, sn, SEC, lifetime) \
  30         w_cvar(id, sn, SEC, radius) \
  31         w_cvar(id, sn, SEC, refire) \
  32         w_cvar(id, sn, SEC, shotangle) \
  33         w_cvar(id, sn, SEC, speed) \
  34         w_cvar(id, sn, SEC, spread) \
  35         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  36         w_prop(id, sn, float,  reloading_time, reload_time) \
  37         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  38         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  39         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  40         w_prop(id, sn, float,  weaponstart, weaponstart) \
  41         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  42
  43 #ifdef SVQC
  44 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  45 .float vaporizer_lasthit;
  46 .float jump_interval;
  47 #endif
  48 #else
  49 #ifdef SVQC
  50 void spawnfunc_weapon_vaporizer (void) { weapon_defaultspawnfunc(WEP_VAPORIZER); }
  51 void spawnfunc_weapon_minstanex () { spawnfunc_weapon_vaporizer(); }
  52
  53 void W_Vaporizer_Attack (void)
  54 {
  55         float flying;
  56         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  57
  58         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  59
  60         yoda = 0;
  61         damage_goodhits = 0;
  62         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_VAPORIZER);
  63
  64         if(yoda && flying)
  65                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  66         if(damage_goodhits && self.vaporizer_lasthit)
  67         {
  68                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  69                 damage_goodhits = 0; // only every second time
  70         }
  71
  72         self.vaporizer_lasthit = damage_goodhits;
  73
  74         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  75
  76         // teamcolor / hit beam effect
  77         vector v;
  78         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  79         switch(self.team)
  80         {
  81                 case NUM_TEAM_1:   // Red
  82                         if(damage_goodhits)
  83                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  84                         else
  85                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  86                         break;
  87                 case NUM_TEAM_2:   // Blue
  88                         if(damage_goodhits)
  89                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  90                         else
  91                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  92                         break;
  93                 case NUM_TEAM_3:   // Yellow
  94                         if(damage_goodhits)
  95                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  96                         else
  97                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  98                         break;
  99                 case NUM_TEAM_4:   // Pink
 100                         if(damage_goodhits)
 101                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
 102                         else
 103                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
 104                         break;
 105                 default:
 106                         if(damage_goodhits)
 107                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
 108                         else
 109                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
 110                         break;
 111         }
 112
 113         W_DecreaseAmmo(((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 114 }
 115
 116 float W_Vaporizer(float req)
 117 {
 118         float ammo_amount;
 119         float vaporizer_ammo;
 120
 121         // now multiple WR_s use this
 122         vaporizer_ammo = ((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 123
 124         switch(req)
 125         {
 126                 case WR_AIM:
 127                 {
 128                         if(self.WEP_AMMO(VAPORIZER) > 0)
 129                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 130                         else
 131                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), FALSE); // WEAPONTODO: replace with proper vaporizer cvars
 132
 133                         return TRUE;
 134                 }
 135                 case WR_THINK:
 136                 {
 137                         // if the laser uses load, we also consider its ammo for reloading
 138                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && self.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) // forced reload
 139                                 WEP_ACTION(self.weapon, WR_RELOAD);
 140                         else if(WEP_CVAR(vaporizer, reload_ammo) && self.clip_load < vaporizer_ammo) // forced reload
 141                                 WEP_ACTION(self.weapon, WR_RELOAD);
 142                         else if (self.BUTTON_ATCK)
 143                         {
 144                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(vaporizer, refire)))
 145                                 {
 146                                         W_Vaporizer_Attack();
 147                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 148                                 }
 149                         }
 150                         else if (self.BUTTON_ATCK2)
 151                         {
 152                                 if (self.jump_interval <= time)
 153                                 if (weapon_prepareattack(1, -1))
 154                                 {
 155                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 156                                         self.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 157
 158                                         // decrease ammo for the laser?
 159                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 160                                                 W_DecreaseAmmo(WEP_CVAR_SEC(vaporizer, ammo));
 161
 162                                         // ugly minstagib hack to reuse the fire mode of the laser
 163                                         float w;
 164                                         w = self.weapon;
 165                                         self.weapon = WEP_BLASTER;
 166                                         W_Blaster_Attack(
 167                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 168                                                 WEP_CVAR_SEC(vaporizer, damage),
 169                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 170                                                 WEP_CVAR_SEC(vaporizer, radius),
 171                                                 WEP_CVAR_SEC(vaporizer, force),
 172                                                 WEP_CVAR_SEC(vaporizer, speed),
 173                                                 WEP_CVAR_SEC(vaporizer, spread),
 174                                                 WEP_CVAR_SEC(vaporizer, delay),
 175                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 176                                         );
 177                                         self.weapon = w;
 178
 179                                         // now do normal refire
 180                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 181                                 }
 182                         }
 183
 184                         return TRUE;
 185                 }
 186                 case WR_INIT:
 187                 {
 188                         precache_model("models/nexflash.md3");
 189                         precache_model("models/weapons/g_minstanex.md3");
 190                         precache_model("models/weapons/v_minstanex.md3");
 191                         precache_model("models/weapons/h_minstanex.iqm");
 192                         precache_sound("weapons/minstanexfire.wav");
 193                         precache_sound("weapons/nexwhoosh1.wav");
 194                         precache_sound("weapons/nexwhoosh2.wav");
 195                         precache_sound("weapons/nexwhoosh3.wav");
 196                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 197                         VAPORIZER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 198                         return TRUE;
 199                 }
 200                 case WR_SETUP:
 201                 {
 202                         self.ammo_field = WEP_AMMO(VAPORIZER);
 203                         self.vaporizer_lasthit = 0;
 204                         return TRUE;
 205                 }
 206                 case WR_CHECKAMMO1:
 207                 {
 208                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= vaporizer_ammo;
 209                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= vaporizer_ammo;
 210                         return ammo_amount;
 211                 }
 212                 case WR_CHECKAMMO2:
 213                 {
 214                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 215                                 return TRUE;
 216                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 217                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= WEP_CVAR_SEC(vaporizer, ammo);
 218                         return ammo_amount;
 219                 }
 220                 case WR_CONFIG:
 221                 {
 222                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 223                         return TRUE;
 224                 }
 225                 case WR_RESETPLAYER:
 226                 {
 227                         self.vaporizer_lasthit = 0;
 228                         return TRUE;
 229                 }
 230                 case WR_RELOAD:
 231                 {
 232                         float used_ammo;
 233                         if(WEP_CVAR_SEC(vaporizer, ammo))
 234                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 235                         else
 236                                 used_ammo = vaporizer_ammo;
 237
 238                         W_Reload(used_ammo, "weapons/reload.wav");
 239                         return TRUE;
 240                 }
 241                 case WR_SUICIDEMESSAGE:
 242                 {
 243                         return WEAPON_THINKING_WITH_PORTALS;
 244                 }
 245                 case WR_KILLMESSAGE:
 246                 {
 247                         return WEAPON_VAPORIZER_MURDER;
 248                 }
 249         }
 250         return TRUE;
 251 }
 252 #endif
 253 #ifdef CSQC
 254 float W_Vaporizer(float req)
 255 {
 256         switch(req)
 257         {
 258                 case WR_IMPACTEFFECT:
 259                 {
 260                         vector org2;
 261                         org2 = w_org + w_backoff * 6;
 262                         pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 263                         if(!w_issilent)
 264                                 sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 265
 266                         return TRUE;
 267                 }
 268                 case WR_INIT:
 269                 {
 270                         precache_sound("weapons/neximpact.wav");
 271                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 272                         {
 273                                 precache_pic("gfx/reticle_nex");
 274                         }
 275                         return TRUE;
 276                 }
 277                 case WR_ZOOMRETICLE:
 278                 {
 279                         if(button_zoom || zoomscript_caught)
 280                         {
 281                                 reticle_image = "gfx/reticle_nex";
 282                                 return TRUE;
 283                         }
 284                         else
 285                         {
 286                                 // no weapon specific image for this weapon
 287                                 return FALSE;
 288                         }
 289                 }
 290         }
 291         return TRUE;
 292 }
 293 #endif
 294 #endif