qcsrc/common/weapons/weapon/arc.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Arc, Weapon)
   3 /* ammotype  */ ATTRIB(Arc, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Arc, impulse, int, 3)
   5 /* flags     */ ATTRIB(Arc, spawnflags, int, WEP_FLAG_NORMAL);
   6 /* rating    */ ATTRIB(Arc, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Arc, wpcolor, vector, '1 1 1');
   8 /* modelname */ ATTRIB(Arc, mdl, string, "arc");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Arc, m_model, Model, MDL_ARC_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Arc, w_crosshair, string, "gfx/crosshairhlac");
  13 /* crosshair */ ATTRIB(Arc, w_crosshair_size, float, 0.7);
  14 /* wepimg    */ ATTRIB(Arc, model2, string, "weaponarc");
  15 /* refname   */ ATTRIB(Arc, netname, string, "arc");
  16 /* wepname   */ ATTRIB(Arc, message, string, _("Arc"));
  17 ENDCLASS(Arc)
  18 REGISTER_WEAPON(ARC, NEW(Arc));
  19
  20 #define ARC_SETTINGS(w_cvar,w_prop) ARC_SETTINGS_LIST(w_cvar, w_prop, ARC, arc)
  21 #define ARC_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, NONE, beam_ammo) \
  23         w_cvar(id, sn, NONE, beam_animtime) \
  24         w_cvar(id, sn, NONE, beam_botaimspeed) \
  25         w_cvar(id, sn, NONE, beam_botaimlifetime) \
  26         w_cvar(id, sn, NONE, beam_damage) \
  27         w_cvar(id, sn, NONE, beam_degreespersegment) \
  28         w_cvar(id, sn, NONE, beam_distancepersegment) \
  29         w_cvar(id, sn, NONE, beam_falloff_halflifedist) \
  30         w_cvar(id, sn, NONE, beam_falloff_maxdist) \
  31         w_cvar(id, sn, NONE, beam_falloff_mindist) \
  32         w_cvar(id, sn, NONE, beam_force) \
  33         w_cvar(id, sn, NONE, beam_healing_amax) \
  34         w_cvar(id, sn, NONE, beam_healing_aps) \
  35         w_cvar(id, sn, NONE, beam_healing_hmax) \
  36         w_cvar(id, sn, NONE, beam_healing_hps) \
  37         w_cvar(id, sn, NONE, beam_maxangle) \
  38         w_cvar(id, sn, NONE, beam_nonplayerdamage) \
  39         w_cvar(id, sn, NONE, beam_range) \
  40         w_cvar(id, sn, NONE, beam_refire) \
  41         w_cvar(id, sn, NONE, beam_returnspeed) \
  42         w_cvar(id, sn, NONE, beam_tightness) \
  43         w_cvar(id, sn, NONE, burst_ammo) \
  44         w_cvar(id, sn, NONE, burst_damage) \
  45         w_cvar(id, sn, NONE, burst_healing_aps) \
  46         w_cvar(id, sn, NONE, burst_healing_hps) \
  47         w_cvar(id, sn, NONE, overheat_max)/* maximum heat before jamming */ \
  48         w_cvar(id, sn, NONE, overheat_min)/* minimum heat to wait for cooldown */ \
  49         w_cvar(id, sn, NONE, beam_heat)   /* heat increase per second (primary) */ \
  50         w_cvar(id, sn, NONE, burst_heat)  /* heat increase per second (secondary) */ \
  51         w_cvar(id, sn, NONE, cooldown)    /* heat decrease per second when resting */ \
  52         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  53         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  54         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  55         w_prop(id, sn, float,  weaponstart, weaponstart) \
  56         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  57         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  58
  59 #ifndef MENUQC
  60 const float ARC_MAX_SEGMENTS = 20;
  61 vector arc_shotorigin[4];
  62 .vector beam_start;
  63 .vector beam_dir;
  64 .vector beam_wantdir;
  65 .int beam_type;
  66
  67 const int ARC_BT_MISS =        0x00;
  68 const int ARC_BT_WALL =        0x01;
  69 const int ARC_BT_HEAL =        0x02;
  70 const int ARC_BT_HIT =         0x03;
  71 const int ARC_BT_BURST_MISS =  0x10;
  72 const int ARC_BT_BURST_WALL =  0x11;
  73 const int ARC_BT_BURST_HEAL =  0x12;
  74 const int ARC_BT_BURST_HIT =   0x13;
  75 const int ARC_BT_BURSTMASK =   0x10;
  76
  77 const int ARC_SF_SETTINGS =    1;
  78 const int ARC_SF_START =       2;
  79 const int ARC_SF_WANTDIR =     4;
  80 const int ARC_SF_BEAMDIR =     8;
  81 const int ARC_SF_BEAMTYPE =    16;
  82 const int ARC_SF_LOCALMASK =   14;
  83 #endif
  84 #ifdef SVQC
  85 ARC_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  86 .entity arc_beam;
  87 .bool arc_BUTTON_ATCK_prev; // for better animation control
  88 .float beam_prev;
  89 .float beam_initialized;
  90 .float beam_bursting;
  91 .float beam_teleporttime;
  92 .float beam_heat; // (beam) amount of heat produced
  93 .float arc_overheat; // (dropped arc/player) time during which it's too hot
  94 .float arc_cooldown; // (dropped arc/player) cooling speed
  95 .float arc_heat_percent; // (player) arc heat in [0,1] (stat)
  96 .float arc_smoke_sound;
  97 #endif
  98 #ifdef CSQC
  99 void Ent_ReadArcBeam(float isnew);
 100
 101 .vector beam_color;
 102 .float beam_alpha;
 103 .float beam_thickness;
 104 .float beam_traileffect;
 105 .float beam_hiteffect;
 106 .float beam_hitlight[4]; // 0: radius, 123: rgb
 107 .float beam_muzzleeffect;
 108 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
 109 .string beam_image;
 110
 111 .entity beam_muzzleentity;
 112
 113 .float beam_degreespersegment;
 114 .float beam_distancepersegment;
 115 .float beam_usevieworigin;
 116 .float beam_initialized;
 117 .float beam_maxangle;
 118 .float beam_range;
 119 .float beam_returnspeed;
 120 .float beam_tightness;
 121 .vector beam_shotorigin;
 122
 123 entity Draw_ArcBeam_callback_entity;
 124 float Draw_ArcBeam_callback_last_thickness;
 125 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
 126 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
 127 #endif
 128 #endif
 129 #ifdef IMPLEMENTATION
 130 #ifdef SVQC
 131 void spawnfunc_weapon_arc(void) { weapon_defaultspawnfunc(WEP_ARC.m_id); }
 132
 133 float W_Arc_Beam_Send(entity to, int sf)
 134 {SELFPARAM();
 135         WriteByte(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
 136
 137         // Truncate information when this beam is displayed to the owner client
 138         // - The owner client has no use for beam start position or directions,
 139         //    it always figures this information out for itself with csqc code.
 140         // - Spectating the owner also truncates this information.
 141         float drawlocal = ((to == self.owner) || ((to.enemy == self.owner) && IS_SPEC(to)));
 142         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
 143
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if(sf & ARC_SF_SETTINGS) // settings information
 147         {
 148                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
 149                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
 150                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
 151                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
 152                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
 153                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
 154
 155                 WriteByte(MSG_ENTITY, drawlocal);
 156         }
 157         if(sf & ARC_SF_START) // starting location
 158         {
 159                 WriteCoord(MSG_ENTITY, self.beam_start.x);
 160                 WriteCoord(MSG_ENTITY, self.beam_start.y);
 161                 WriteCoord(MSG_ENTITY, self.beam_start.z);
 162         }
 163         if(sf & ARC_SF_WANTDIR) // want/aim direction
 164         {
 165                 WriteCoord(MSG_ENTITY, self.beam_wantdir.x);
 166                 WriteCoord(MSG_ENTITY, self.beam_wantdir.y);
 167                 WriteCoord(MSG_ENTITY, self.beam_wantdir.z);
 168         }
 169         if(sf & ARC_SF_BEAMDIR) // beam direction
 170         {
 171                 WriteCoord(MSG_ENTITY, self.beam_dir.x);
 172                 WriteCoord(MSG_ENTITY, self.beam_dir.y);
 173                 WriteCoord(MSG_ENTITY, self.beam_dir.z);
 174         }
 175         if(sf & ARC_SF_BEAMTYPE) // beam type
 176         {
 177                 WriteByte(MSG_ENTITY, self.beam_type);
 178         }
 179
 180         return true;
 181 }
 182
 183 void Reset_ArcBeam(entity player, vector forward)
 184 {
 185         if (!player.arc_beam) {
 186                 return;
 187         }
 188         player.arc_beam.beam_dir = forward;
 189         player.arc_beam.beam_teleporttime = time;
 190 }
 191
 192 float Arc_GetHeat_Percent(entity player)
 193 {
 194         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
 195         {
 196                 player.arc_overheat = 0;
 197                 return 0;
 198         }
 199
 200         if ( player.arc_beam )
 201                 return player.arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
 202
 203         if ( player.arc_overheat > time )
 204         {
 205                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
 206                         * player.arc_cooldown;
 207         }
 208
 209         return 0;
 210 }
 211 void Arc_Player_SetHeat(entity player)
 212 {
 213         player.arc_heat_percent = Arc_GetHeat_Percent(player);
 214         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
 215 }
 216
 217 void W_Arc_Beam_Think(void)
 218 {SELFPARAM();
 219         if(self != self.owner.arc_beam)
 220         {
 221                 remove(self);
 222                 return;
 223         }
 224
 225
 226         float burst = 0;
 227         if( self.owner.BUTTON_ATCK2 || self.beam_bursting)
 228         {
 229                 if(!self.beam_bursting)
 230                         self.beam_bursting = true;
 231                 burst = ARC_BT_BURSTMASK;
 232         }
 233
 234         if(
 235                 !IS_PLAYER(self.owner)
 236                 ||
 237                 (self.owner.WEP_AMMO(ARC) <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 238                 ||
 239                 self.owner.deadflag != DEAD_NO
 240                 ||
 241                 (!self.owner.BUTTON_ATCK && !burst )
 242                 ||
 243                 self.owner.frozen
 244                 ||
 245                 self.owner.vehicle
 246                 ||
 247                 (WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max))
 248         )
 249         {
 250                 if ( WEP_CVAR(arc, cooldown) > 0 )
 251                 {
 252                         float cooldown_speed = 0;
 253                         if ( self.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 254                         {
 255                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 256                         }
 257                         else if ( !burst )
 258                         {
 259                                 cooldown_speed = self.beam_heat / WEP_CVAR(arc, beam_refire);
 260                         }
 261
 262                         if ( cooldown_speed )
 263                         {
 264                                 self.owner.arc_overheat = time + self.beam_heat / cooldown_speed;
 265                                 self.owner.arc_cooldown = cooldown_speed;
 266                         }
 267
 268                         if ( WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max) )
 269                         {
 270                                 Send_Effect_("arc_overheat",
 271                                         self.beam_start, self.beam_wantdir, 1 );
 272                                 sound(self, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 273                         }
 274                 }
 275
 276                 if(self == self.owner.arc_beam) { self.owner.arc_beam = world; }
 277                 setself(self.owner);
 278                 Weapon w = WEP_ARC;
 279                 if(!w.wr_checkammo1(w) && !w.wr_checkammo2(w))
 280                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 281                 {
 282                         // note: this doesn't force the switch
 283                         W_SwitchToOtherWeapon(self);
 284                 }
 285                 setself(this);
 286                 remove(self);
 287                 return;
 288         }
 289
 290         // decrease ammo
 291         float coefficient = frametime;
 292         if(!(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 293         {
 294                 float rootammo;
 295                 if(burst)
 296                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 297                 else
 298                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 299
 300                 if(rootammo)
 301                 {
 302                         coefficient = min(coefficient, self.owner.WEP_AMMO(ARC) / rootammo);
 303                         self.owner.WEP_AMMO(ARC) = max(0, self.owner.WEP_AMMO(ARC) - (rootammo * frametime));
 304                 }
 305         }
 306         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 307         self.beam_heat = min( WEP_CVAR(arc, overheat_max), self.beam_heat + heat_speed*frametime );
 308
 309         makevectors(self.owner.v_angle);
 310
 311         W_SetupShot_Range(
 312                 self.owner,
 313                 true,
 314                 0,
 315                 "",
 316                 0,
 317                 WEP_CVAR(arc, beam_damage) * coefficient,
 318                 WEP_CVAR(arc, beam_range)
 319         );
 320
 321         // After teleport, "lock" the beam until the teleport is confirmed.
 322         if (time < self.beam_teleporttime + ANTILAG_LATENCY(self.owner)) {
 323                 w_shotdir = self.beam_dir;
 324         }
 325
 326         // network information: shot origin and want/aim direction
 327         if(self.beam_start != w_shotorg)
 328         {
 329                 self.SendFlags |= ARC_SF_START;
 330                 self.beam_start = w_shotorg;
 331         }
 332         if(self.beam_wantdir != w_shotdir)
 333         {
 334                 self.SendFlags |= ARC_SF_WANTDIR;
 335                 self.beam_wantdir = w_shotdir;
 336         }
 337
 338         if(!self.beam_initialized)
 339         {
 340                 self.beam_dir = w_shotdir;
 341                 self.beam_initialized = true;
 342         }
 343
 344         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 345         // idea: blend together self.beam_dir with the inverted direction the player is moving in
 346         // might have to make some special accomodation so that it only uses view_right and view_up
 347
 348         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 349
 350         float segments;
 351         if(self.beam_dir != w_shotdir)
 352         {
 353                 // calculate how much we're going to move the end of the beam to the want position
 354                 // WEAPONTODO (server and client):
 355                 // blendfactor never actually becomes 0 in this situation, which is a problem
 356                 // regarding precision... this means that self.beam_dir and w_shotdir approach
 357                 // eachother, however they never actually become the same value with this method.
 358                 // Perhaps we should do some form of rounding/snapping?
 359                 float angle = vlen(w_shotdir - self.beam_dir) * RAD2DEG;
 360                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 361                 {
 362                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 363                         float blendfactor = bound(
 364                                 0,
 365                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 366                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 367                         );
 368                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 369                 }
 370                 else
 371                 {
 372                         // the radius is not too far yet, no worries :D
 373                         float blendfactor = bound(
 374                                 0,
 375                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 376                                 1
 377                         );
 378                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 379                 }
 380
 381                 // network information: beam direction
 382                 self.SendFlags |= ARC_SF_BEAMDIR;
 383
 384                 // calculate how many segments are needed
 385                 float max_allowed_segments;
 386
 387                 if(WEP_CVAR(arc, beam_distancepersegment))
 388                 {
 389                         max_allowed_segments = min(
 390                                 ARC_MAX_SEGMENTS,
 391                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 392                         );
 393                 }
 394                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 395
 396                 if(WEP_CVAR(arc, beam_degreespersegment))
 397                 {
 398                         segments = bound(
 399                                 1,
 400                                 (
 401                                         min(
 402                                                 angle,
 403                                                 WEP_CVAR(arc, beam_maxangle)
 404                                         )
 405                                         /
 406                                         WEP_CVAR(arc, beam_degreespersegment)
 407                                 ),
 408                                 max_allowed_segments
 409                         );
 410                 }
 411                 else { segments = 1; }
 412         }
 413         else { segments = 1; }
 414
 415         vector beam_endpos = (w_shotorg + (self.beam_dir * WEP_CVAR(arc, beam_range)));
 416         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 417
 418         float i;
 419         float new_beam_type = 0;
 420         vector last_origin = w_shotorg;
 421         for(i = 1; i <= segments; ++i)
 422         {
 423                 // WEAPONTODO (client):
 424                 // In order to do nice fading and pointing on the starting segment, we must always
 425                 // have that drawn as a separate triangle... However, that is difficult to do when
 426                 // keeping in mind the above problems and also optimizing the amount of segments
 427                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 428
 429                 vector new_origin = bezier_quadratic_getpoint(
 430                         w_shotorg,
 431                         beam_controlpoint,
 432                         beam_endpos,
 433                         i / segments);
 434                 vector new_dir = normalize(new_origin - last_origin);
 435
 436                 WarpZone_traceline_antilag(
 437                         self.owner,
 438                         last_origin,
 439                         new_origin,
 440                         MOVE_NORMAL,
 441                         self.owner,
 442                         ANTILAG_LATENCY(self.owner)
 443                 );
 444
 445                 // Do all the transforms for warpzones right now, as we already
 446                 // "are" in the post-trace system (if we hit a player, that's
 447                 // always BEHIND the last passed wz).
 448                 last_origin = trace_endpos;
 449                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 450                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 451                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 452                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 453
 454                 float is_player = (
 455                         IS_PLAYER(trace_ent)
 456                         ||
 457                         trace_ent.classname == "body"
 458                         ||
 459                         IS_MONSTER(trace_ent)
 460                 );
 461
 462                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 463                 {
 464                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 465                         // NO. trace_endpos should be just fine. If not,
 466                         // that's an engine bug that needs proper debugging.
 467                         vector hitorigin = trace_endpos;
 468
 469                         float falloff = ExponentialFalloff(
 470                                 WEP_CVAR(arc, beam_falloff_mindist),
 471                                 WEP_CVAR(arc, beam_falloff_maxdist),
 472                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 473                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 474                         );
 475
 476                         if(is_player && SAME_TEAM(self.owner, trace_ent))
 477                         {
 478                                 float roothealth, rootarmor;
 479                                 if(burst)
 480                                 {
 481                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 482                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 483                                 }
 484                                 else
 485                                 {
 486                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 487                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 488                                 }
 489
 490                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 491                                 {
 492                                         trace_ent.health = min(
 493                                                 trace_ent.health + (roothealth * coefficient),
 494                                                 WEP_CVAR(arc, beam_healing_hmax)
 495                                         );
 496                                 }
 497                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 498                                 {
 499                                         trace_ent.armorvalue = min(
 500                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 501                                                 WEP_CVAR(arc, beam_healing_amax)
 502                                         );
 503                                 }
 504
 505                                 // stop rot, set visual effect
 506                                 if(roothealth || rootarmor)
 507                                 {
 508                                         trace_ent.pauserothealth_finished = max(
 509                                                 trace_ent.pauserothealth_finished,
 510                                                 time + autocvar_g_balance_pause_health_rot
 511                                         );
 512                                         trace_ent.pauserotarmor_finished = max(
 513                                                 trace_ent.pauserotarmor_finished,
 514                                                 time + autocvar_g_balance_pause_armor_rot
 515                                         );
 516                                         new_beam_type = ARC_BT_HEAL;
 517                                 }
 518                         }
 519                         else
 520                         {
 521                                 float rootdamage;
 522                                 if(is_player)
 523                                 {
 524                                         if(burst)
 525                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 526                                         else
 527                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 528                                 }
 529                                 else
 530                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 531
 532                                 if(accuracy_isgooddamage(self.owner, trace_ent))
 533                                 {
 534                                         accuracy_add(
 535                                                 self.owner,
 536                                                 WEP_ARC.m_id,
 537                                                 0,
 538                                                 rootdamage * coefficient * falloff
 539                                         );
 540                                 }
 541
 542                                 Damage(
 543                                         trace_ent,
 544                                         self.owner,
 545                                         self.owner,
 546                                         rootdamage * coefficient * falloff,
 547                                         WEP_ARC.m_id,
 548                                         hitorigin,
 549                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 550                                 );
 551
 552                                 new_beam_type = ARC_BT_HIT;
 553                         }
 554                         break;
 555                 }
 556                 else if(trace_fraction != 1)
 557                 {
 558                         // we collided with geometry
 559                         new_beam_type = ARC_BT_WALL;
 560                         break;
 561                 }
 562         }
 563
 564         // te_explosion(trace_endpos);
 565
 566         // if we're bursting, use burst visual effects
 567         new_beam_type |= burst;
 568
 569         // network information: beam type
 570         if(new_beam_type != self.beam_type)
 571         {
 572                 self.SendFlags |= ARC_SF_BEAMTYPE;
 573                 self.beam_type = new_beam_type;
 574         }
 575
 576         self.owner.beam_prev = time;
 577         self.nextthink = time;
 578 }
 579
 580 void W_Arc_Beam(float burst)
 581 {SELFPARAM();
 582
 583         // only play fire sound if 1 sec has passed since player let go the fire button
 584         if(time - self.beam_prev > 1)
 585                 sound(self, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 586
 587         entity beam = self.arc_beam = spawn();
 588         beam.classname = "W_Arc_Beam";
 589         beam.solid = SOLID_NOT;
 590         beam.think = W_Arc_Beam_Think;
 591         beam.owner = self;
 592         beam.movetype = MOVETYPE_NONE;
 593         beam.bot_dodge = true;
 594         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 595         beam.beam_bursting = burst;
 596         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 597
 598         WITH(entity, self, beam, beam.think());
 599 }
 600
 601 void Arc_Smoke()
 602 {SELFPARAM();
 603         makevectors(self.v_angle);
 604         W_SetupShot_Range(self,true,0,"",0,0,0);
 605
 606         vector smoke_origin = w_shotorg + self.velocity*frametime;
 607         if ( self.arc_overheat > time )
 608         {
 609                 if ( random() < self.arc_heat_percent )
 610                         Send_Effect_("arc_smoke", smoke_origin, '0 0 0', 1 );
 611                 if ( self.BUTTON_ATCK || self.BUTTON_ATCK2 )
 612                 {
 613                         Send_Effect_("arc_overheat_fire", smoke_origin, w_shotdir, 1 );
 614                         if ( !self.arc_smoke_sound )
 615                         {
 616                                 self.arc_smoke_sound = 1;
 617                                 sound(self, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 618                         }
 619                 }
 620         }
 621         else if ( self.arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 622                         self.arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 623         {
 624                 if ( random() < (self.arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 625                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 626                         Send_Effect_("arc_smoke", smoke_origin, '0 0 0', 1 );
 627         }
 628
 629         if (  self.arc_smoke_sound && ( self.arc_overheat <= time ||
 630                 !( self.BUTTON_ATCK || self.BUTTON_ATCK2 ) ) || self.switchweapon != WEP_ARC.m_id )
 631         {
 632                 self.arc_smoke_sound = 0;
 633                 sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 634         }
 635 }
 636
 637                 METHOD(Arc, wr_aim, bool(entity thiswep))
 638                 {
 639                         SELFPARAM();
 640                         if(WEP_CVAR(arc, beam_botaimspeed))
 641                         {
 642                                 self.BUTTON_ATCK = bot_aim(
 643                                         WEP_CVAR(arc, beam_botaimspeed),
 644                                         0,
 645                                         WEP_CVAR(arc, beam_botaimlifetime),
 646                                         false
 647                                 );
 648                         }
 649                         else
 650                         {
 651                                 self.BUTTON_ATCK = bot_aim(
 652                                         1000000,
 653                                         0,
 654                                         0.001,
 655                                         false
 656                                 );
 657                         }
 658                         return true;
 659                 }
 660                 METHOD(Arc, wr_think, bool(entity thiswep, bool fire1, bool fire2))
 661                 {
 662                         SELFPARAM();
 663                         Arc_Player_SetHeat(self);
 664                         Arc_Smoke();
 665
 666                         if (time >= self.arc_overheat)
 667                         if (fire1 || fire2 || self.arc_beam.beam_bursting)
 668                         {
 669
 670                                 if(self.arc_BUTTON_ATCK_prev)
 671                                 {
 672                                         #if 0
 673                                         if(self.animstate_startframe == self.anim_shoot.x && self.animstate_numframes == self.anim_shoot.y)
 674                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 675                                         else
 676                                         #endif
 677                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 678                                 }
 679
 680                                 if((!self.arc_beam) || wasfreed(self.arc_beam))
 681                                 {
 682                                         if(weapon_prepareattack(fire2, 0))
 683                                         {
 684                                                 W_Arc_Beam(fire2);
 685
 686                                                 if(!self.arc_BUTTON_ATCK_prev)
 687                                                 {
 688                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 689                                                         self.arc_BUTTON_ATCK_prev = true;
 690                                                 }
 691                                         }
 692                                 }
 693
 694                                 return true;
 695                         }
 696
 697                         if(self.arc_BUTTON_ATCK_prev)
 698                         {
 699                                 sound(self, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 700                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 701                                 ATTACK_FINISHED(self) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor();
 702                         }
 703                         self.arc_BUTTON_ATCK_prev = false;
 704
 705                         #if 0
 706                         if(fire2)
 707                         if(weapon_prepareattack(true, autocvar_g_balance_arc_secondary_refire))
 708                         {
 709                                 W_Arc_Attack2();
 710                                 self.arc_count = autocvar_g_balance_arc_secondary_count;
 711                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 712                                 self.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor();
 713                         }
 714                         #endif
 715
 716                         return true;
 717                 }
 718                 METHOD(Arc, wr_init, bool(entity thiswep))
 719                 {
 720                         if(!arc_shotorigin[0])
 721                         {
 722                                 arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 723                                 arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 724                                 arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 725                                 arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 726                         }
 727                         ARC_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 728                         return true;
 729                 }
 730                 METHOD(Arc, wr_checkammo1, bool(entity thiswep))
 731                 {
 732                         SELFPARAM();
 733                         return ((!WEP_CVAR(arc, beam_ammo)) || (self.WEP_AMMO(ARC) > 0));
 734                 }
 735                 METHOD(Arc, wr_checkammo2, bool(entity thiswep))
 736                 {
 737                         SELFPARAM();
 738                         return WEP_CVAR(arc, overheat_max) > 0 &&
 739                                 ((!WEP_CVAR(arc, burst_ammo)) || (self.WEP_AMMO(ARC) > 0));
 740                 }
 741                 METHOD(Arc, wr_config, bool(entity thiswep))
 742                 {
 743                         ARC_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 744                         return true;
 745                 }
 746                 METHOD(Arc, wr_killmessage, bool(entity thiswep))
 747                 {
 748                         return WEAPON_ARC_MURDER;
 749                 }
 750                 METHOD(Arc, wr_drop, bool(entity thiswep))
 751                 {
 752                         weapon_dropevent_item.arc_overheat = self.arc_overheat;
 753                         weapon_dropevent_item.arc_cooldown = self.arc_cooldown;
 754                         self.arc_overheat = 0;
 755                         self.arc_cooldown = 0;
 756                         return true;
 757                 }
 758                 METHOD(Arc, wr_pickup, bool(entity thiswep))
 759                 {
 760                         if ( !client_hasweapon(self, WEP_ARC.m_id, false, false) &&
 761                                 weapon_dropevent_item.arc_overheat > time )
 762                         {
 763                                 self.arc_overheat = weapon_dropevent_item.arc_overheat;
 764                                 self.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 765                         }
 766                         return true;
 767                 }
 768 #endif
 769 #ifdef CSQC
 770 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 771 {
 772         entity beam = Draw_ArcBeam_callback_entity;
 773         vector transformed_view_org;
 774         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 775
 776         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 777         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 778         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 779
 780         vector hitorigin;
 781
 782         // draw segment
 783         #if 0
 784         if(trace_fraction != 1)
 785         {
 786                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 787                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 788                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 789         }
 790         else
 791         {
 792                 hitorigin = hit;
 793         }
 794         #else
 795         hitorigin = hit;
 796         #endif
 797
 798         // decide upon thickness
 799         float thickness = beam.beam_thickness;
 800
 801         // draw primary beam render
 802         vector top    = hitorigin + (thickdir * thickness);
 803         vector bottom = hitorigin - (thickdir * thickness);
 804
 805         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 806         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 807
 808         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 809         R_PolygonVertex(
 810                 top,
 811                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 812                 beam.beam_color,
 813                 beam.beam_alpha
 814         );
 815         R_PolygonVertex(
 816                 last_top,
 817                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 818                 beam.beam_color,
 819                 beam.beam_alpha
 820         );
 821         R_PolygonVertex(
 822                 last_bottom,
 823                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 824                 beam.beam_color,
 825                 beam.beam_alpha
 826         );
 827         R_PolygonVertex(
 828                 bottom,
 829                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 830                 beam.beam_color,
 831                 beam.beam_alpha
 832         );
 833         R_EndPolygon();
 834
 835         // draw trailing particles
 836         // NOTES:
 837         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 838         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 839         if(beam.beam_traileffect)
 840         {
 841                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 842         }
 843
 844         // set up for the next
 845         Draw_ArcBeam_callback_last_thickness = thickness;
 846         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 847         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 848 }
 849
 850 void Reset_ArcBeam(void)
 851 {
 852         entity e;
 853         for (e = world; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 854                 e.beam_initialized = false;
 855         }
 856         for (e = world; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 857                 e.beam_initialized = false;
 858         }
 859 }
 860
 861 void Draw_ArcBeam(void)
 862 {SELFPARAM();
 863         float dt = time - self.move_time;
 864         self.move_time = time;
 865         if(dt <= 0) { return; }
 866
 867         if(!self.beam_usevieworigin)
 868         {
 869                 InterpolateOrigin_Do();
 870         }
 871
 872         // origin = beam starting origin
 873         // v_angle = wanted/aim direction
 874         // angles = current direction of beam
 875
 876         vector start_pos;
 877         vector wantdir; //= view_forward;
 878         vector beamdir; //= self.beam_dir;
 879
 880         float segments;
 881         if(self.beam_usevieworigin)
 882         {
 883                 // WEAPONTODO:
 884                 // Currently we have to replicate nearly the same method of figuring
 885                 // out the shotdir that the server does... Ideally in the future we
 886                 // should be able to acquire this from a generalized function built
 887                 // into a weapon system for client code.
 888
 889                 // find where we are aiming
 890                 makevectors(warpzone_save_view_angles);
 891                 vector forward = v_forward;
 892                 vector right = v_right;
 893                 vector up = v_up;
 894
 895                 // decide upon start position
 896                 if(self.beam_usevieworigin == 2)
 897                         { start_pos = warpzone_save_view_origin; }
 898                 else
 899                         { start_pos = self.origin; }
 900
 901                 // trace forward with an estimation
 902                 WarpZone_TraceLine(
 903                         start_pos,
 904                         start_pos + forward * self.beam_range,
 905                         MOVE_NOMONSTERS,
 906                         self
 907                 );
 908
 909                 // untransform in case our trace went through a warpzone
 910                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 911
 912                 // un-adjust trueaim if shotend is too close
 913                 if(vlen(end_pos - start_pos) < g_trueaim_minrange)
 914                         end_pos = start_pos + (forward * g_trueaim_minrange);
 915
 916                 // move shot origin to the actual gun muzzle origin
 917                 vector origin_offset =
 918                           right * -self.beam_shotorigin.y
 919                         + up * self.beam_shotorigin.z;
 920
 921                 start_pos = start_pos + origin_offset;
 922
 923                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 924                 traceline(start_pos, start_pos + forward * self.beam_shotorigin.x, MOVE_NORMAL, self);
 925                 start_pos = trace_endpos;
 926
 927                 // calculate the aim direction now
 928                 wantdir = normalize(end_pos - start_pos);
 929
 930                 if(!self.beam_initialized)
 931                 {
 932                         self.beam_dir = wantdir;
 933                         self.beam_initialized = true;
 934                 }
 935
 936                 if(self.beam_dir != wantdir)
 937                 {
 938                         // calculate how much we're going to move the end of the beam to the want position
 939                         // WEAPONTODO (server and client):
 940                         // blendfactor never actually becomes 0 in this situation, which is a problem
 941                         // regarding precision... this means that self.beam_dir and w_shotdir approach
 942                         // eachother, however they never actually become the same value with this method.
 943                         // Perhaps we should do some form of rounding/snapping?
 944                         float angle = vlen(wantdir - self.beam_dir) * RAD2DEG;
 945                         if(angle && (angle > self.beam_maxangle))
 946                         {
 947                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 948                                 float blendfactor = bound(
 949                                         0,
 950                                         (1 - (self.beam_returnspeed * frametime)),
 951                                         min(self.beam_maxangle / angle, 1)
 952                                 );
 953                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 954                         }
 955                         else
 956                         {
 957                                 // the radius is not too far yet, no worries :D
 958                                 float blendfactor = bound(
 959                                         0,
 960                                         (1 - (self.beam_returnspeed * frametime)),
 961                                         1
 962                                 );
 963                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 964                         }
 965
 966                         // calculate how many segments are needed
 967                         float max_allowed_segments;
 968
 969                         if(self.beam_distancepersegment)
 970                         {
 971                                 max_allowed_segments = min(
 972                                         ARC_MAX_SEGMENTS,
 973                                         1 + (vlen(wantdir / self.beam_distancepersegment))
 974                                 );
 975                         }
 976                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 977
 978                         if(self.beam_degreespersegment)
 979                         {
 980                                 segments = bound(
 981                                         1,
 982                                         (
 983                                                 min(
 984                                                         angle,
 985                                                         self.beam_maxangle
 986                                                 )
 987                                                 /
 988                                                 self.beam_degreespersegment
 989                                         ),
 990                                         max_allowed_segments
 991                                 );
 992                         }
 993                         else { segments = 1; }
 994                 }
 995                 else { segments = 1; }
 996
 997                 // set the beam direction which the rest of the code will refer to
 998                 beamdir = self.beam_dir;
 999
1000                 // finally, set self.angles to the proper direction so that muzzle attachment points in proper direction
1001                 self.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1002         }
1003         else
1004         {
1005                 // set the values from the provided info from the networked entity
1006                 start_pos = self.origin;
1007                 wantdir = self.v_angle;
1008                 beamdir = self.angles;
1009
1010                 if(beamdir != wantdir)
1011                 {
1012                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1013
1014                         // calculate how many segments are needed
1015                         float max_allowed_segments;
1016
1017                         if(self.beam_distancepersegment)
1018                         {
1019                                 max_allowed_segments = min(
1020                                         ARC_MAX_SEGMENTS,
1021                                         1 + (vlen(wantdir / self.beam_distancepersegment))
1022                                 );
1023                         }
1024                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1025
1026                         if(self.beam_degreespersegment)
1027                         {
1028                                 segments = bound(
1029                                         1,
1030                                         (
1031                                                 min(
1032                                                         angle,
1033                                                         self.beam_maxangle
1034                                                 )
1035                                                 /
1036                                                 self.beam_degreespersegment
1037                                         ),
1038                                         max_allowed_segments
1039                                 );
1040                         }
1041                         else { segments = 1; }
1042                 }
1043                 else { segments = 1; }
1044         }
1045
1046         setorigin(self, start_pos);
1047         self.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1048
1049         vector beam_endpos = (start_pos + (beamdir * self.beam_range));
1050         vector beam_controlpoint = start_pos + wantdir * (self.beam_range * (1 - self.beam_tightness));
1051
1052         Draw_ArcBeam_callback_entity = self;
1053         Draw_ArcBeam_callback_last_thickness = 0;
1054         Draw_ArcBeam_callback_last_top = start_pos;
1055         Draw_ArcBeam_callback_last_bottom = start_pos;
1056
1057         vector last_origin = start_pos;
1058         vector original_start_pos = start_pos;
1059
1060         float i;
1061         for(i = 1; i <= segments; ++i)
1062         {
1063                 // WEAPONTODO (client):
1064                 // In order to do nice fading and pointing on the starting segment, we must always
1065                 // have that drawn as a separate triangle... However, that is difficult to do when
1066                 // keeping in mind the above problems and also optimizing the amount of segments
1067                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1068
1069                 vector new_origin = bezier_quadratic_getpoint(
1070                         start_pos,
1071                         beam_controlpoint,
1072                         beam_endpos,
1073                         i / segments);
1074
1075                 WarpZone_TraceBox_ThroughZone(
1076                         last_origin,
1077                         '0 0 0',
1078                         '0 0 0',
1079                         new_origin,
1080                         MOVE_NORMAL,
1081                         world,
1082                         world,
1083                         Draw_ArcBeam_callback
1084                 );
1085
1086                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1087                 // system (if we hit a player, that's always BEHIND the last passed wz).
1088                 last_origin = trace_endpos;
1089                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1090                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1091                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1092                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1093                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1094                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1095
1096                 if(trace_fraction < 1) { break; }
1097         }
1098
1099         // visual effects for startpoint and endpoint
1100         if(self.beam_hiteffect)
1101         {
1102                 // FIXME we really should do this on the server so it actually
1103                 // matches gameplay. What this client side stuff is doing is no
1104                 // more than guesswork.
1105                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1106                 pointparticles(
1107                         self.beam_hiteffect,
1108                         last_origin,
1109                         beamdir * -1,
1110                         frametime * 2
1111                 );
1112         }
1113         if(self.beam_hitlight[0])
1114         {
1115                 adddynamiclight(
1116                         last_origin,
1117                         self.beam_hitlight[0],
1118                         vec3(
1119                                 self.beam_hitlight[1],
1120                                 self.beam_hitlight[2],
1121                                 self.beam_hitlight[3]
1122                         )
1123                 );
1124         }
1125         if(self.beam_muzzleeffect)
1126         {
1127                 pointparticles(
1128                         self.beam_muzzleeffect,
1129                         original_start_pos + wantdir * 20,
1130                         wantdir * 1000,
1131                         frametime * 0.1
1132                 );
1133         }
1134         if(self.beam_muzzlelight[0])
1135         {
1136                 adddynamiclight(
1137                         original_start_pos + wantdir * 20,
1138                         self.beam_muzzlelight[0],
1139                         vec3(
1140                                 self.beam_muzzlelight[1],
1141                                 self.beam_muzzlelight[2],
1142                                 self.beam_muzzlelight[3]
1143                         )
1144                 );
1145         }
1146
1147         // cleanup
1148         Draw_ArcBeam_callback_entity = world;
1149         Draw_ArcBeam_callback_last_thickness = 0;
1150         Draw_ArcBeam_callback_last_top = '0 0 0';
1151         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1152 }
1153
1154 void Remove_ArcBeam(void)
1155 {SELFPARAM();
1156         remove(self.beam_muzzleentity);
1157         sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1158 }
1159
1160 void Ent_ReadArcBeam(float isnew)
1161 {SELFPARAM();
1162         int sf = ReadByte();
1163         entity flash;
1164
1165         if(isnew)
1166         {
1167                 // calculate shot origin offset from gun alignment
1168                 int gunalign = autocvar_cl_gunalign;
1169                 if(gunalign != 1 && gunalign != 2 && gunalign != 4)
1170                         gunalign = 3; // default value
1171                 --gunalign;
1172
1173                 self.beam_shotorigin = arc_shotorigin[gunalign];
1174
1175                 // set other main attributes of the beam
1176                 self.draw = Draw_ArcBeam;
1177                 self.entremove = Remove_ArcBeam;
1178                 self.move_time = time;
1179                 loopsound(self, CH_SHOTS_SINGLE, SND(ARC_LOOP), VOL_BASE, ATTEN_NORM);
1180
1181                 flash = spawn();
1182                 flash.owner = self;
1183                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1184                 flash.drawmask = MASK_NORMAL;
1185                 flash.solid = SOLID_NOT;
1186                 flash.avelocity_z = 5000;
1187                 setattachment(flash, self, "");
1188                 setorigin(flash, '0 0 0');
1189
1190                 self.beam_muzzleentity = flash;
1191         }
1192         else
1193         {
1194                 flash = self.beam_muzzleentity;
1195         }
1196
1197         if(sf & ARC_SF_SETTINGS) // settings information
1198         {
1199                 self.beam_degreespersegment = ReadShort();
1200                 self.beam_distancepersegment = ReadShort();
1201                 self.beam_maxangle = ReadShort();
1202                 self.beam_range = ReadCoord();
1203                 self.beam_returnspeed = ReadShort();
1204                 self.beam_tightness = (ReadByte() / 10);
1205
1206                 if(ReadByte())
1207                 {
1208                         if(autocvar_chase_active)
1209                                 { self.beam_usevieworigin = 1; }
1210                         else // use view origin
1211                                 { self.beam_usevieworigin = 2; }
1212                 }
1213                 else
1214                 {
1215                         self.beam_usevieworigin = 0;
1216                 }
1217         }
1218
1219         if(!self.beam_usevieworigin)
1220         {
1221                 // self.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1222                 self.iflags = IFLAG_ORIGIN;
1223
1224                 InterpolateOrigin_Undo();
1225         }
1226
1227         if(sf & ARC_SF_START) // starting location
1228         {
1229                 self.origin_x = ReadCoord();
1230                 self.origin_y = ReadCoord();
1231                 self.origin_z = ReadCoord();
1232         }
1233         else if(self.beam_usevieworigin) // infer the location from player location
1234         {
1235                 if(self.beam_usevieworigin == 2)
1236                 {
1237                         // use view origin
1238                         self.origin = view_origin;
1239                 }
1240                 else
1241                 {
1242                         // use player origin so that third person display still works
1243                         self.origin = getplayerorigin(player_localnum) + ('0 0 1' * getstati(STAT_VIEWHEIGHT));
1244                 }
1245         }
1246
1247         setorigin(self, self.origin);
1248
1249         if(sf & ARC_SF_WANTDIR) // want/aim direction
1250         {
1251                 self.v_angle_x = ReadCoord();
1252                 self.v_angle_y = ReadCoord();
1253                 self.v_angle_z = ReadCoord();
1254         }
1255
1256         if(sf & ARC_SF_BEAMDIR) // beam direction
1257         {
1258                 self.angles_x = ReadCoord();
1259                 self.angles_y = ReadCoord();
1260                 self.angles_z = ReadCoord();
1261         }
1262
1263         if(sf & ARC_SF_BEAMTYPE) // beam type
1264         {
1265                 self.beam_type = ReadByte();
1266                 switch(self.beam_type)
1267                 {
1268                         case ARC_BT_MISS:
1269                         {
1270                                 self.beam_color = '1 1 1';
1271                                 self.beam_alpha = 0.5;
1272                                 self.beam_thickness = 8;
1273                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1274                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1275                                 self.beam_hitlight[0] = 0;
1276                                 self.beam_hitlight[1] = 1;
1277                                 self.beam_hitlight[2] = 1;
1278                                 self.beam_hitlight[3] = 1;
1279                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1280                                 self.beam_muzzlelight[0] = 0;
1281                                 self.beam_muzzlelight[1] = 1;
1282                                 self.beam_muzzlelight[2] = 1;
1283                                 self.beam_muzzlelight[3] = 1;
1284                                 if(self.beam_muzzleeffect >= 0)
1285                                 {
1286                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1287                                         flash.alpha = self.beam_alpha;
1288                                         flash.colormod = self.beam_color;
1289                                         flash.scale = 0.5;
1290                                 }
1291                                 break;
1292                         }
1293                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1294                         {
1295                                 self.beam_color = '1 1 1';
1296                                 self.beam_alpha = 0.5;
1297                                 self.beam_thickness = 8;
1298                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1299                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1300                                 self.beam_hitlight[0] = 0;
1301                                 self.beam_hitlight[1] = 1;
1302                                 self.beam_hitlight[2] = 1;
1303                                 self.beam_hitlight[3] = 1;
1304                                 self.beam_muzzleeffect = -1; // particleeffectnum(EFFECT_GRENADE_MUZZLEFLASH);
1305                                 self.beam_muzzlelight[0] = 0;
1306                                 self.beam_muzzlelight[1] = 1;
1307                                 self.beam_muzzlelight[2] = 1;
1308                                 self.beam_muzzlelight[3] = 1;
1309                                 self.beam_image = "particles/lgbeam";
1310                                 if(self.beam_muzzleeffect >= 0)
1311                                 {
1312                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1313                                         flash.alpha = self.beam_alpha;
1314                                         flash.colormod = self.beam_color;
1315                                         flash.scale = 0.5;
1316                                 }
1317                                 break;
1318                         }
1319                         case ARC_BT_HEAL:
1320                         {
1321                                 self.beam_color = '1 1 1';
1322                                 self.beam_alpha = 0.5;
1323                                 self.beam_thickness = 8;
1324                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL);
1325                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL_IMPACT);
1326                                 self.beam_hitlight[0] = 0;
1327                                 self.beam_hitlight[1] = 1;
1328                                 self.beam_hitlight[2] = 1;
1329                                 self.beam_hitlight[3] = 1;
1330                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1331                                 self.beam_muzzlelight[0] = 0;
1332                                 self.beam_muzzlelight[1] = 1;
1333                                 self.beam_muzzlelight[2] = 1;
1334                                 self.beam_muzzlelight[3] = 1;
1335                                 self.beam_image = "particles/lgbeam";
1336                                 if(self.beam_muzzleeffect >= 0)
1337                                 {
1338                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1339                                         flash.alpha = self.beam_alpha;
1340                                         flash.colormod = self.beam_color;
1341                                         flash.scale = 0.5;
1342                                 }
1343                                 break;
1344                         }
1345                         case ARC_BT_HIT:
1346                         {
1347                                 self.beam_color = '1 1 1';
1348                                 self.beam_alpha = 0.5;
1349                                 self.beam_thickness = 8;
1350                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1351                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1352                                 self.beam_hitlight[0] = 20;
1353                                 self.beam_hitlight[1] = 1;
1354                                 self.beam_hitlight[2] = 0;
1355                                 self.beam_hitlight[3] = 0;
1356                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1357                                 self.beam_muzzlelight[0] = 50;
1358                                 self.beam_muzzlelight[1] = 1;
1359                                 self.beam_muzzlelight[2] = 0;
1360                                 self.beam_muzzlelight[3] = 0;
1361                                 self.beam_image = "particles/lgbeam";
1362                                 if(self.beam_muzzleeffect >= 0)
1363                                 {
1364                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1365                                         flash.alpha = self.beam_alpha;
1366                                         flash.colormod = self.beam_color;
1367                                         flash.scale = 0.5;
1368                                 }
1369                                 break;
1370                         }
1371                         case ARC_BT_BURST_MISS:
1372                         {
1373                                 self.beam_color = '1 1 1';
1374                                 self.beam_alpha = 0.5;
1375                                 self.beam_thickness = 14;
1376                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1377                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1378                                 self.beam_hitlight[0] = 0;
1379                                 self.beam_hitlight[1] = 1;
1380                                 self.beam_hitlight[2] = 1;
1381                                 self.beam_hitlight[3] = 1;
1382                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1383                                 self.beam_muzzlelight[0] = 0;
1384                                 self.beam_muzzlelight[1] = 1;
1385                                 self.beam_muzzlelight[2] = 1;
1386                                 self.beam_muzzlelight[3] = 1;
1387                                 self.beam_image = "particles/lgbeam";
1388                                 if(self.beam_muzzleeffect >= 0)
1389                                 {
1390                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1391                                         flash.alpha = self.beam_alpha;
1392                                         flash.colormod = self.beam_color;
1393                                         flash.scale = 0.5;
1394                                 }
1395                                 break;
1396                         }
1397                         case ARC_BT_BURST_WALL:
1398                         {
1399                                 self.beam_color = '1 1 1';
1400                                 self.beam_alpha = 0.5;
1401                                 self.beam_thickness = 14;
1402                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1403                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1404                                 self.beam_hitlight[0] = 0;
1405                                 self.beam_hitlight[1] = 1;
1406                                 self.beam_hitlight[2] = 1;
1407                                 self.beam_hitlight[3] = 1;
1408                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1409                                 self.beam_muzzlelight[0] = 0;
1410                                 self.beam_muzzlelight[1] = 1;
1411                                 self.beam_muzzlelight[2] = 1;
1412                                 self.beam_muzzlelight[3] = 1;
1413                                 self.beam_image = "particles/lgbeam";
1414                                 if(self.beam_muzzleeffect >= 0)
1415                                 {
1416                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1417                                         flash.alpha = self.beam_alpha;
1418                                         flash.colormod = self.beam_color;
1419                                         flash.scale = 0.5;
1420                                 }
1421                                 break;
1422                         }
1423                         case ARC_BT_BURST_HEAL:
1424                         {
1425                                 self.beam_color = '1 1 1';
1426                                 self.beam_alpha = 0.5;
1427                                 self.beam_thickness = 14;
1428                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL);
1429                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL_IMPACT2);
1430                                 self.beam_hitlight[0] = 0;
1431                                 self.beam_hitlight[1] = 1;
1432                                 self.beam_hitlight[2] = 1;
1433                                 self.beam_hitlight[3] = 1;
1434                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1435                                 self.beam_muzzlelight[0] = 0;
1436                                 self.beam_muzzlelight[1] = 1;
1437                                 self.beam_muzzlelight[2] = 1;
1438                                 self.beam_muzzlelight[3] = 1;
1439                                 self.beam_image = "particles/lgbeam";
1440                                 if(self.beam_muzzleeffect >= 0)
1441                                 {
1442                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1443                                         flash.alpha = self.beam_alpha;
1444                                         flash.colormod = self.beam_color;
1445                                         flash.scale = 0.5;
1446                                 }
1447                                 break;
1448                         }
1449                         case ARC_BT_BURST_HIT:
1450                         {
1451                                 self.beam_color = '1 1 1';
1452                                 self.beam_alpha = 0.5;
1453                                 self.beam_thickness = 14;
1454                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1455                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1456                                 self.beam_hitlight[0] = 0;
1457                                 self.beam_hitlight[1] = 1;
1458                                 self.beam_hitlight[2] = 1;
1459                                 self.beam_hitlight[3] = 1;
1460                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1461                                 self.beam_muzzlelight[0] = 0;
1462                                 self.beam_muzzlelight[1] = 1;
1463                                 self.beam_muzzlelight[2] = 1;
1464                                 self.beam_muzzlelight[3] = 1;
1465                                 self.beam_image = "particles/lgbeam";
1466                                 if(self.beam_muzzleeffect >= 0)
1467                                 {
1468                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1469                                         flash.alpha = self.beam_alpha;
1470                                         flash.colormod = self.beam_color;
1471                                         flash.scale = 0.5;
1472                                 }
1473                                 break;
1474                         }
1475
1476                         // shouldn't be possible, but lets make it colorful if it does :D
1477                         default:
1478                         {
1479                                 self.beam_color = randomvec();
1480                                 self.beam_alpha = 1;
1481                                 self.beam_thickness = 8;
1482                                 self.beam_traileffect = false;
1483                                 self.beam_hiteffect = false;
1484                                 self.beam_hitlight[0] = 0;
1485                                 self.beam_hitlight[1] = 1;
1486                                 self.beam_hitlight[2] = 1;
1487                                 self.beam_hitlight[3] = 1;
1488                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1489                                 self.beam_muzzlelight[0] = 0;
1490                                 self.beam_muzzlelight[1] = 1;
1491                                 self.beam_muzzlelight[2] = 1;
1492                                 self.beam_muzzlelight[3] = 1;
1493                                 self.beam_image = "particles/lgbeam";
1494                                 if(self.beam_muzzleeffect >= 0)
1495                                 {
1496                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1497                                         flash.alpha = self.beam_alpha;
1498                                         flash.colormod = self.beam_color;
1499                                         flash.scale = 0.5;
1500                                 }
1501                                 break;
1502                         }
1503                 }
1504         }
1505
1506         if(!self.beam_usevieworigin)
1507         {
1508                 InterpolateOrigin_Note();
1509         }
1510 }
1511
1512                 METHOD(Arc, wr_impacteffect, bool(entity thiswep))
1513                 {
1514                         // todo
1515                         return true;
1516                 }
1517                 METHOD(Arc, wr_init, bool(entity thiswep))
1518                 {
1519                         return true;
1520                 }
1521                 METHOD(Arc, wr_zoomreticle, bool(entity thiswep))
1522                 {
1523                         // no weapon specific image for this weapon
1524                         return false;
1525                 }
1526 #endif
1527 #endif