qcsrc/common/weapons/weapon/blaster.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ BLASTER,
   4 /* function  */ W_Blaster,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 1,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ 0,
   9 /* color     */ '1 0.5 0.5',
  10 /* modelname */ "laser",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairlaser 0.5",
  13 /* wepimg    */ "weaponlaser",
  14 /* refname   */ "blaster",
  15 /* wepname   */ _("Blaster")
  16 );
  17
  18 #define BLASTER_SETTINGS(w_cvar,w_prop) BLASTER_SETTINGS_LIST(w_cvar, w_prop, BLASTER, blaster)
  19 #define BLASTER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, animtime) \
  21         w_cvar(id, sn, BOTH, damage) \
  22         w_cvar(id, sn, BOTH, delay) \
  23         w_cvar(id, sn, BOTH, edgedamage) \
  24         w_cvar(id, sn, BOTH, force) \
  25         w_cvar(id, sn, BOTH, force_zscale) \
  26         w_cvar(id, sn, BOTH, lifetime) \
  27         w_cvar(id, sn, BOTH, radius) \
  28         w_cvar(id, sn, BOTH, refire) \
  29         w_cvar(id, sn, BOTH, shotangle) \
  30         w_cvar(id, sn, BOTH, speed) \
  31         w_cvar(id, sn, BOTH, spread) \
  32         w_cvar(id, sn, NONE, secondary) \
  33         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  34         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  35         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  36         w_prop(id, sn, float,  weaponstart, weaponstart) \
  37         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  38         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  39
  40 #ifdef SVQC
  41 BLASTER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  42 .float blaster_damage;
  43 .float blaster_edgedamage;
  44 .float blaster_radius;
  45 .float blaster_force;
  46 .float blaster_lifetime;
  47 #endif
  48 #endif
  49 #ifdef IMPLEMENTATION
  50 #ifdef SVQC
  51 void spawnfunc_weapon_blaster(void) { weapon_defaultspawnfunc(WEP_BLASTER.m_id); }
  52 void spawnfunc_weapon_laser(void) { spawnfunc_weapon_blaster(); }
  53
  54 void W_Blaster_Touch(void)
  55 {SELFPARAM();
  56         PROJECTILE_TOUCH;
  57
  58         self.event_damage = func_null;
  59
  60         RadiusDamage(
  61                 self,
  62                 self.realowner,
  63                 self.blaster_damage,
  64                 self.blaster_edgedamage,
  65                 self.blaster_radius,
  66                 world,
  67                 world,
  68                 self.blaster_force,
  69                 self.projectiledeathtype,
  70                 other
  71         );
  72
  73         remove(self);
  74 }
  75
  76 void W_Blaster_Think(void)
  77 {SELFPARAM();
  78         self.movetype = MOVETYPE_FLY;
  79         self.think = SUB_Remove;
  80         self.nextthink = time + self.blaster_lifetime;
  81         CSQCProjectile(self, true, PROJECTILE_BLASTER, true);
  82 }
  83
  84 void W_Blaster_Attack(
  85         float atk_deathtype,
  86         float atk_shotangle,
  87         float atk_damage,
  88         float atk_edgedamage,
  89         float atk_radius,
  90         float atk_force,
  91         float atk_speed,
  92         float atk_spread,
  93         float atk_delay,
  94         float atk_lifetime)
  95 {SELFPARAM();
  96         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  97
  98         W_SetupShot_Dir(self, s_forward, false, 3, W_Sound("lasergun_fire"), CH_WEAPON_B, atk_damage);
  99         Send_Effect(EFFECT_BLASTER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 100
 101         entity missile = spawn();
 102         missile.owner = missile.realowner = self;
 103         missile.classname = "blasterbolt";
 104         missile.bot_dodge = true;
 105         missile.bot_dodgerating = atk_damage;
 106         PROJECTILE_MAKETRIGGER(missile);
 107
 108         missile.blaster_damage = atk_damage;
 109         missile.blaster_edgedamage = atk_edgedamage;
 110         missile.blaster_radius = atk_radius;
 111         missile.blaster_force = atk_force;
 112         missile.blaster_lifetime = atk_lifetime;
 113
 114         setorigin(missile, w_shotorg);
 115         setsize(missile, '0 0 0', '0 0 0');
 116
 117         W_SetupProjVelocity_Explicit(
 118                 missile,
 119                 w_shotdir,
 120                 v_up,
 121                 atk_speed,
 122                 0,
 123                 0,
 124                 atk_spread,
 125                 false
 126         );
 127
 128         missile.angles = vectoangles(missile.velocity);
 129
 130         //missile.glow_color = 250; // 244, 250
 131         //missile.glow_size = 120;
 132
 133         missile.touch = W_Blaster_Touch;
 134         missile.flags = FL_PROJECTILE;
 135         missile.missile_flags = MIF_SPLASH;
 136         missile.projectiledeathtype = atk_deathtype;
 137         missile.think = W_Blaster_Think;
 138         missile.nextthink = time + atk_delay;
 139
 140         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 141
 142         if(time >= missile.nextthink)
 143         {
 144                 SELFCALL(missile, missile.think());
 145                 SELFCALL_DONE();
 146         }
 147 }
 148 bool W_Blaster(int request)
 149 {SELFPARAM();
 150         switch(request)
 151         {
 152                 case WR_AIM:
 153                 {
 154                         if(WEP_CVAR(blaster, secondary))
 155                         {
 156                                 if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
 157                                         { self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), false); }
 158                                 else
 159                                         { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), false); }
 160                         }
 161                         else
 162                                 { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), false); }
 163
 164                         return true;
 165                 }
 166
 167                 case WR_THINK:
 168                 {
 169                         if(self.BUTTON_ATCK)
 170                         {
 171                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(blaster, refire)))
 172                                 {
 173                                         W_Blaster_Attack(
 174                                                 WEP_BLASTER.m_id,
 175                                                 WEP_CVAR_PRI(blaster, shotangle),
 176                                                 WEP_CVAR_PRI(blaster, damage),
 177                                                 WEP_CVAR_PRI(blaster, edgedamage),
 178                                                 WEP_CVAR_PRI(blaster, radius),
 179                                                 WEP_CVAR_PRI(blaster, force),
 180                                                 WEP_CVAR_PRI(blaster, speed),
 181                                                 WEP_CVAR_PRI(blaster, spread),
 182                                                 WEP_CVAR_PRI(blaster, delay),
 183                                                 WEP_CVAR_PRI(blaster, lifetime)
 184                                         );
 185                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 186                                 }
 187                         }
 188                         else if(self.BUTTON_ATCK2)
 189                         {
 190                                 switch(WEP_CVAR(blaster, secondary))
 191                                 {
 192                                         case 0: // switch to last used weapon
 193                                         {
 194                                                 if(self.switchweapon == WEP_BLASTER.m_id) // don't do this if already switching
 195                                                         W_LastWeapon();
 196                                                 break;
 197                                         }
 198
 199                                         case 1: // normal projectile secondary
 200                                         {
 201                                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(blaster, refire)))
 202                                                 {
 203                                                         W_Blaster_Attack(
 204                                                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 205                                                                 WEP_CVAR_SEC(blaster, shotangle),
 206                                                                 WEP_CVAR_SEC(blaster, damage),
 207                                                                 WEP_CVAR_SEC(blaster, edgedamage),
 208                                                                 WEP_CVAR_SEC(blaster, radius),
 209                                                                 WEP_CVAR_SEC(blaster, force),
 210                                                                 WEP_CVAR_SEC(blaster, speed),
 211                                                                 WEP_CVAR_SEC(blaster, spread),
 212                                                                 WEP_CVAR_SEC(blaster, delay),
 213                                                                 WEP_CVAR_SEC(blaster, lifetime)
 214                                                         );
 215                                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 216                                                 }
 217
 218                                                 break;
 219                                         }
 220                                 }
 221                         }
 222                         return true;
 223                 }
 224
 225                 case WR_INIT:
 226                 {
 227                         precache_model(W_Model("g_laser.md3"));
 228                         precache_model(W_Model("v_laser.md3"));
 229                         precache_model(W_Model("h_laser.iqm"));
 230                         precache_sound(W_Sound("lasergun_fire"));
 231                         BLASTER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 232                         return true;
 233                 }
 234
 235                 case WR_SETUP:
 236                 {
 237                         self.ammo_field = ammo_none;
 238                         return true;
 239                 }
 240
 241                 case WR_CHECKAMMO1:
 242                 case WR_CHECKAMMO2:
 243                 {
 244                         return true; // laser has infinite ammo
 245                 }
 246
 247                 case WR_CONFIG:
 248                 {
 249                         BLASTER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 250                         return true;
 251                 }
 252
 253                 case WR_SUICIDEMESSAGE:
 254                 {
 255                         return WEAPON_BLASTER_SUICIDE;
 256                 }
 257
 258                 case WR_KILLMESSAGE:
 259                 {
 260                         return WEAPON_BLASTER_MURDER;
 261                 }
 262         }
 263         return false;
 264 }
 265 #endif
 266 #ifdef CSQC
 267 bool W_Blaster(int request)
 268 {SELFPARAM();
 269         switch(request)
 270         {
 271                 case WR_IMPACTEFFECT:
 272                 {
 273                         vector org2;
 274                         org2 = w_org + w_backoff * 6;
 275                         pointparticles(particleeffectnum(EFFECT_BLASTER_IMPACT), org2, w_backoff * 1000, 1);
 276                         if(!w_issilent) { sound(self, CH_SHOTS, W_Sound("laserimpact"), VOL_BASE, ATTN_NORM); }
 277                         return true;
 278                 }
 279
 280                 case WR_INIT:
 281                 {
 282                         precache_sound(W_Sound("laserimpact"));
 283                         return true;
 284                 }
 285                 case WR_ZOOMRETICLE:
 286                 {
 287                         // no weapon specific image for this weapon
 288                         return false;
 289                 }
 290         }
 291         return false;
 292 }
 293 #endif
 294 #endif