qcsrc/common/weapons/weapon/porto.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(PortoLaunch, Weapon)
   3 /* ammotype  */ ATTRIB(PortoLaunch, ammo_field, .int, ammo_none)
   4 /* impulse   */ ATTRIB(PortoLaunch, impulse, int, 0)
   5 /* flags     */ ATTRIB(PortoLaunch, spawnflags, int, WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON);
   6 /* rating    */ ATTRIB(PortoLaunch, bot_pickupbasevalue, float, 0);
   7 /* color     */ ATTRIB(PortoLaunch, wpcolor, vector, '0.5 0.5 0.5');
   8 /* modelname */ ATTRIB(PortoLaunch, mdl, string, "porto");
   9 /* model     */ ATTRIB(PortoLaunch, model, string, strzone(W_Model(strcat("g_", this.mdl, ".md3"))));
  10 /* simplemdl */ ATTRIB(PortoLaunch, w_simplemdl, string, "foobar");
  11 /* crosshair */ ATTRIB(PortoLaunch, w_crosshair, string, "gfx/crosshairporto");
  12 /* crosshair */ ATTRIB(PortoLaunch, w_crosshair_size, float, 0.6);
  13 /* wepimg    */ ATTRIB(PortoLaunch, model2, string, "weaponporto");
  14 /* refname   */ ATTRIB(PortoLaunch, netname, string, "porto");
  15 /* wepname   */ ATTRIB(PortoLaunch, message, string, _("Port-O-Launch"));
  16 ENDCLASS(PortoLaunch)
  17 REGISTER_WEAPON(PORTO, NEW(PortoLaunch));
  18
  19 #define PORTO_SETTINGS(w_cvar,w_prop) PORTO_SETTINGS_LIST(w_cvar, w_prop, PORTO, porto)
  20 #define PORTO_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  21         w_cvar(id, sn, BOTH, animtime) \
  22         w_cvar(id, sn, BOTH, lifetime) \
  23         w_cvar(id, sn, BOTH, refire) \
  24         w_cvar(id, sn, BOTH, speed) \
  25         w_cvar(id, sn, NONE, secondary) \
  26         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  27         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  28         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  29         w_prop(id, sn, float,  weaponstart, weaponstart) \
  30         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  31         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  32
  33 #ifdef SVQC
  34 PORTO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  35 .entity porto_current;
  36 .vector porto_v_angle; // holds "held" view angles
  37 .float porto_v_angle_held;
  38 .vector right_vector;
  39 #endif
  40 #endif
  41 #ifdef IMPLEMENTATION
  42 #ifdef SVQC
  43 #include "../../triggers/trigger/jumppads.qh"
  44
  45 void spawnfunc_weapon_porto(void) { weapon_defaultspawnfunc(WEP_PORTO.m_id); }
  46
  47 void W_Porto_Success(void)
  48 {SELFPARAM();
  49         if(self.realowner == world)
  50         {
  51                 objerror("Cannot succeed successfully: no owner\n");
  52                 return;
  53         }
  54
  55         self.realowner.porto_current = world;
  56         remove(self);
  57 }
  58
  59 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  60 void W_Porto_Fail(float failhard)
  61 {SELFPARAM();
  62         if(self.realowner == world)
  63         {
  64                 objerror("Cannot fail successfully: no owner\n");
  65                 return;
  66         }
  67
  68         // no portals here!
  69         if(self.cnt < 0)
  70         {
  71                 Portal_ClearWithID(self.realowner, self.portal_id);
  72         }
  73
  74         self.realowner.porto_current = world;
  75
  76         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET_PORTO))
  77         {
  78                 setsize(self, '-16 -16 0', '16 16 32');
  79                 setorigin(self, self.origin + trace_plane_normal);
  80                 if(move_out_of_solid(self))
  81                 {
  82                         self.flags = FL_ITEM;
  83                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  84                         tracetoss(self, self);
  85                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  86                         {
  87                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO.m_id, 0, self.origin, self.velocity);
  88                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_FAILED);
  89                         }
  90                 }
  91         }
  92         remove(self);
  93 }
  94
  95 void W_Porto_Remove(entity p)
  96 {SELFPARAM();
  97         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  98         {
  99                 WITH(entity, self, p.porto_current, W_Porto_Fail(1));
 100         }
 101 }
 102
 103 void W_Porto_Think(void)
 104 {SELFPARAM();
 105         trace_plane_normal = '0 0 0';
 106         if(self.realowner.playerid != self.playerid)
 107                 remove(self);
 108         else
 109                 W_Porto_Fail(0);
 110 }
 111
 112 void W_Porto_Touch(void)
 113 {SELFPARAM();
 114         vector norm;
 115
 116         // do not use PROJECTILE_TOUCH here
 117         // FIXME but DO handle warpzones!
 118
 119         if(other.classname == "portal")
 120                 return; // handled by the portal
 121
 122         norm = trace_plane_normal;
 123         if(trace_ent.iscreature)
 124         {
 125                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN.z, MOVE_WORLDONLY, self);
 126                 if(trace_fraction >= 1)
 127                         return;
 128                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 129                         return;
 130                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 131                         return;
 132         }
 133
 134         if(self.realowner.playerid != self.playerid)
 135         {
 136                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 137                 remove(self);
 138         }
 139         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 140         {
 141                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTEN_NORM);
 142                 // just reflect
 143                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 144                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 145         }
 146         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 147         {
 148                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 149                 W_Porto_Fail(0);
 150                 if(self.cnt < 0)
 151                         Portal_ClearAll_PortalsOnly(self.realowner);
 152         }
 153         else if(self.cnt == 0)
 154         {
 155                 // in-portal only
 156                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 157                 {
 158                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 159                         trace_plane_normal = norm;
 160                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 161                         W_Porto_Success();
 162                 }
 163                 else
 164                 {
 165                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 166                         trace_plane_normal = norm;
 167                         W_Porto_Fail(0);
 168                 }
 169         }
 170         else if(self.cnt == 1)
 171         {
 172                 // out-portal only
 173                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 174                 {
 175                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 176                         trace_plane_normal = norm;
 177                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 178                         W_Porto_Success();
 179                 }
 180                 else
 181                 {
 182                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 183                         trace_plane_normal = norm;
 184                         W_Porto_Fail(0);
 185                 }
 186         }
 187         else if(self.effects & EF_RED)
 188         {
 189                 self.effects += EF_BLUE - EF_RED;
 190                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 191                 {
 192                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 193                         trace_plane_normal = norm;
 194                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 195                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 196                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 197                         CSQCProjectile(self, true, PROJECTILE_PORTO_BLUE, true); // change type
 198                 }
 199                 else
 200                 {
 201                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 202                         trace_plane_normal = norm;
 203                         Portal_ClearAll_PortalsOnly(self.realowner);
 204                         W_Porto_Fail(0);
 205                 }
 206         }
 207         else
 208         {
 209                 if(self.realowner.portal_in.portal_id == self.portal_id)
 210                 {
 211                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 212                         {
 213                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 214                                 trace_plane_normal = norm;
 215                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 216                                 W_Porto_Success();
 217                         }
 218                         else
 219                         {
 220                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 221                                 Portal_ClearAll_PortalsOnly(self.realowner);
 222                                 W_Porto_Fail(0);
 223                         }
 224                 }
 225                 else
 226                 {
 227                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 228                         Portal_ClearAll_PortalsOnly(self.realowner);
 229                         W_Porto_Fail(0);
 230                 }
 231         }
 232 }
 233
 234 void W_Porto_Attack(float type)
 235 {SELFPARAM();
 236         entity gren;
 237
 238         W_SetupShot(self, false, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 239         // always shoot from the eye
 240         w_shotdir = v_forward;
 241         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 242
 243         //Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 244
 245         gren = spawn();
 246         gren.cnt = type;
 247         gren.owner = gren.realowner = self;
 248         gren.playerid = self.playerid;
 249         gren.classname = "porto";
 250         gren.bot_dodge = true;
 251         gren.bot_dodgerating = 200;
 252         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 253         PROJECTILE_MAKETRIGGER(gren);
 254         gren.effects = EF_RED;
 255         gren.scale = 4;
 256         setorigin(gren, w_shotorg);
 257         setsize(gren, '0 0 0', '0 0 0');
 258
 259         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 260         gren.think = W_Porto_Think;
 261         gren.touch = W_Porto_Touch;
 262
 263         if(self.items & ITEM_Strength.m_itemid)
 264                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 265         else
 266                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 267
 268         gren.angles = vectoangles(gren.velocity);
 269         gren.flags = FL_PROJECTILE;
 270
 271         gren.portal_id = time;
 272         self.porto_current = gren;
 273         gren.playerid = self.playerid;
 274         fixedmakevectors(fixedvectoangles(gren.velocity));
 275         gren.right_vector = v_right;
 276
 277         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 278
 279         if(type > 0)
 280                 CSQCProjectile(gren, true, PROJECTILE_PORTO_BLUE, true);
 281         else
 282                 CSQCProjectile(gren, true, PROJECTILE_PORTO_RED, true);
 283
 284         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 285 }
 286
 287                 METHOD(PortoLaunch, wr_aim, bool(entity thiswep))
 288                 {
 289                         SELFPARAM();
 290                         self.BUTTON_ATCK = false;
 291                         self.BUTTON_ATCK2 = false;
 292                         if(!WEP_CVAR(porto, secondary))
 293                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), false))
 294                                         self.BUTTON_ATCK = true;
 295
 296                         return true;
 297                 }
 298                 METHOD(PortoLaunch, wr_config, bool(entity this))
 299                 {
 300                         PORTO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 301                         return true;
 302                 }
 303                 METHOD(PortoLaunch, wr_think, bool(entity thiswep))
 304                 {
 305                         SELFPARAM();
 306                         if(WEP_CVAR(porto, secondary))
 307                         {
 308                                 if(self.BUTTON_ATCK)
 309                                 if(!self.porto_current)
 310                                 if(!self.porto_forbidden)
 311                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 312                                 {
 313                                         W_Porto_Attack(0);
 314                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 315                                 }
 316
 317                                 if(self.BUTTON_ATCK2)
 318                                 if(!self.porto_current)
 319                                 if(!self.porto_forbidden)
 320                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(porto, refire)))
 321                                 {
 322                                         W_Porto_Attack(1);
 323                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 324                                 }
 325                         }
 326                         else
 327                         {
 328                                 if(self.porto_v_angle_held)
 329                                 {
 330                                         if(!self.BUTTON_ATCK2)
 331                                         {
 332                                                 self.porto_v_angle_held = 0;
 333
 334                                                 ClientData_Touch(self);
 335                                         }
 336                                 }
 337                                 else
 338                                 {
 339                                         if(self.BUTTON_ATCK2)
 340                                         {
 341                                                 self.porto_v_angle = self.v_angle;
 342                                                 self.porto_v_angle_held = 1;
 343
 344                                                 ClientData_Touch(self);
 345                                         }
 346                                 }
 347                                 if(self.porto_v_angle_held)
 348                                         makevectors(self.porto_v_angle); // override the previously set angles
 349
 350                                 if(self.BUTTON_ATCK)
 351                                 if(!self.porto_current)
 352                                 if(!self.porto_forbidden)
 353                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 354                                 {
 355                                         W_Porto_Attack(-1);
 356                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 357                                 }
 358                         }
 359
 360                         return true;
 361                 }
 362                 METHOD(PortoLaunch, wr_checkammo1, bool(entity this))
 363                 {
 364                         // always allow infinite ammo
 365                         return true;
 366                 }
 367                 METHOD(PortoLaunch, wr_checkammo2, bool(entity this))
 368                 {
 369                         // always allow infinite ammo
 370                         return true;
 371                 }
 372                 METHOD(PortoLaunch, wr_init, bool(entity this))
 373                 {
 374                         precache_sound("porto/bounce.wav");
 375                         precache_sound("porto/create.wav");
 376                         precache_sound("porto/expire.wav");
 377                         precache_sound("porto/explode.wav");
 378                         precache_sound("porto/fire.wav");
 379                         precache_sound("porto/unsupported.wav");
 380                         PORTO_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 381                         return true;
 382                 }
 383                 METHOD(PortoLaunch, wr_setup, bool(entity thiswep))
 384                 {
 385                         SELFPARAM();
 386                         self.ammo_field = ammo_none;
 387                         return true;
 388                 }
 389                 METHOD(PortoLaunch, wr_resetplayer, bool(entity thiswep))
 390                 {
 391                         SELFPARAM();
 392                         self.porto_current = world;
 393                         return true;
 394                 }
 395 #endif
 396 #ifdef CSQC
 397                 METHOD(PortoLaunch, wr_impacteffect, bool(entity this)) {
 398                         LOG_WARNING("Since when does Porto send DamageInfo?\n");
 399                         return true;
 400                 }
 401                 METHOD(PortoLaunch, wr_init, bool(entity this)) {
 402                         // nothing to do
 403                         return true;
 404                 }
 405                 METHOD(PortoLaunch, wr_zoomreticle, bool(entity this)) {
 406                         // no weapon specific image for this weapon
 407                         return false;
 408                 }
 409 #endif
 410 #endif