qcsrc/common/weapons/weapon/porto.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(PortoLaunch, Weapon)
   3 /* ammotype  */ ATTRIB(PortoLaunch, ammo_field, .int, ammo_none)
   4 /* impulse   */ ATTRIB(PortoLaunch, impulse, int, 0)
   5 /* flags     */ ATTRIB(PortoLaunch, spawnflags, int, WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON);
   6 /* rating    */ ATTRIB(PortoLaunch, bot_pickupbasevalue, float, 0);
   7 /* color     */ ATTRIB(PortoLaunch, wpcolor, vector, '0.5 0.5 0.5');
   8 /* modelname */ ATTRIB(PortoLaunch, mdl, string, "porto");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(PortoLaunch, m_model, Model, MDL_PORTO_ITEM);
  11 #endif
  12 /* simplemdl */ ATTRIB(PortoLaunch, w_simplemdl, string, "foobar");
  13 /* crosshair */ ATTRIB(PortoLaunch, w_crosshair, string, "gfx/crosshairporto");
  14 /* crosshair */ ATTRIB(PortoLaunch, w_crosshair_size, float, 0.6);
  15 /* wepimg    */ ATTRIB(PortoLaunch, model2, string, "weaponporto");
  16 /* refname   */ ATTRIB(PortoLaunch, netname, string, "porto");
  17 /* wepname   */ ATTRIB(PortoLaunch, message, string, _("Port-O-Launch"));
  18 ENDCLASS(PortoLaunch)
  19 REGISTER_WEAPON(PORTO, NEW(PortoLaunch));
  20
  21 #define PORTO_SETTINGS(w_cvar,w_prop) PORTO_SETTINGS_LIST(w_cvar, w_prop, PORTO, porto)
  22 #define PORTO_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  23         w_cvar(id, sn, BOTH, animtime) \
  24         w_cvar(id, sn, BOTH, lifetime) \
  25         w_cvar(id, sn, BOTH, refire) \
  26         w_cvar(id, sn, BOTH, speed) \
  27         w_cvar(id, sn, NONE, secondary) \
  28         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  29         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  30         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  31         w_prop(id, sn, float,  weaponstart, weaponstart) \
  32         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  33         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  34
  35 #ifdef SVQC
  36 PORTO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  37 .entity porto_current;
  38 .vector porto_v_angle; // holds "held" view angles
  39 .float porto_v_angle_held;
  40 .vector right_vector;
  41 #endif
  42 #endif
  43 #ifdef IMPLEMENTATION
  44 #ifdef SVQC
  45 #include "../../triggers/trigger/jumppads.qh"
  46
  47 void spawnfunc_weapon_porto(void) { weapon_defaultspawnfunc(WEP_PORTO.m_id); }
  48
  49 void W_Porto_Success(void)
  50 {SELFPARAM();
  51         if(self.realowner == world)
  52         {
  53                 objerror("Cannot succeed successfully: no owner\n");
  54                 return;
  55         }
  56
  57         self.realowner.porto_current = world;
  58         remove(self);
  59 }
  60
  61 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  62 void W_Porto_Fail(float failhard)
  63 {SELFPARAM();
  64         if(self.realowner == world)
  65         {
  66                 objerror("Cannot fail successfully: no owner\n");
  67                 return;
  68         }
  69
  70         // no portals here!
  71         if(self.cnt < 0)
  72         {
  73                 Portal_ClearWithID(self.realowner, self.portal_id);
  74         }
  75
  76         self.realowner.porto_current = world;
  77
  78         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET_PORTO))
  79         {
  80                 setsize(self, '-16 -16 0', '16 16 32');
  81                 setorigin(self, self.origin + trace_plane_normal);
  82                 if(move_out_of_solid(self))
  83                 {
  84                         self.flags = FL_ITEM;
  85                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  86                         tracetoss(self, self);
  87                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  88                         {
  89                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO.m_id, 0, self.origin, self.velocity);
  90                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_FAILED);
  91                         }
  92                 }
  93         }
  94         remove(self);
  95 }
  96
  97 void W_Porto_Remove(entity p)
  98 {SELFPARAM();
  99         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
 100         {
 101                 WITH(entity, self, p.porto_current, W_Porto_Fail(1));
 102         }
 103 }
 104
 105 void W_Porto_Think(void)
 106 {SELFPARAM();
 107         trace_plane_normal = '0 0 0';
 108         if(self.realowner.playerid != self.playerid)
 109                 remove(self);
 110         else
 111                 W_Porto_Fail(0);
 112 }
 113
 114 void W_Porto_Touch(void)
 115 {SELFPARAM();
 116         vector norm;
 117
 118         // do not use PROJECTILE_TOUCH here
 119         // FIXME but DO handle warpzones!
 120
 121         if(other.classname == "portal")
 122                 return; // handled by the portal
 123
 124         norm = trace_plane_normal;
 125         if(trace_ent.iscreature)
 126         {
 127                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN.z, MOVE_WORLDONLY, self);
 128                 if(trace_fraction >= 1)
 129                         return;
 130                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 131                         return;
 132                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 133                         return;
 134         }
 135
 136         if(self.realowner.playerid != self.playerid)
 137         {
 138                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 139                 remove(self);
 140         }
 141         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 142         {
 143                 spamsound(self, CH_SHOTS, SND(PORTO_BOUNCE), VOL_BASE, ATTEN_NORM);
 144                 // just reflect
 145                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 146                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 147         }
 148         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 149         {
 150                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 151                 W_Porto_Fail(0);
 152                 if(self.cnt < 0)
 153                         Portal_ClearAll_PortalsOnly(self.realowner);
 154         }
 155         else if(self.cnt == 0)
 156         {
 157                 // in-portal only
 158                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 159                 {
 160                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 161                         trace_plane_normal = norm;
 162                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 163                         W_Porto_Success();
 164                 }
 165                 else
 166                 {
 167                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 168                         trace_plane_normal = norm;
 169                         W_Porto_Fail(0);
 170                 }
 171         }
 172         else if(self.cnt == 1)
 173         {
 174                 // out-portal only
 175                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 176                 {
 177                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 178                         trace_plane_normal = norm;
 179                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 180                         W_Porto_Success();
 181                 }
 182                 else
 183                 {
 184                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 185                         trace_plane_normal = norm;
 186                         W_Porto_Fail(0);
 187                 }
 188         }
 189         else if(self.effects & EF_RED)
 190         {
 191                 self.effects += EF_BLUE - EF_RED;
 192                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 193                 {
 194                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 195                         trace_plane_normal = norm;
 196                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 197                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 198                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 199                         CSQCProjectile(self, true, PROJECTILE_PORTO_BLUE, true); // change type
 200                 }
 201                 else
 202                 {
 203                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 204                         trace_plane_normal = norm;
 205                         Portal_ClearAll_PortalsOnly(self.realowner);
 206                         W_Porto_Fail(0);
 207                 }
 208         }
 209         else
 210         {
 211                 if(self.realowner.portal_in.portal_id == self.portal_id)
 212                 {
 213                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 214                         {
 215                                 sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 216                                 trace_plane_normal = norm;
 217                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 218                                 W_Porto_Success();
 219                         }
 220                         else
 221                         {
 222                                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 223                                 Portal_ClearAll_PortalsOnly(self.realowner);
 224                                 W_Porto_Fail(0);
 225                         }
 226                 }
 227                 else
 228                 {
 229                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 230                         Portal_ClearAll_PortalsOnly(self.realowner);
 231                         W_Porto_Fail(0);
 232                 }
 233         }
 234 }
 235
 236 void W_Porto_Attack(float type)
 237 {SELFPARAM();
 238         entity gren;
 239
 240         W_SetupShot(self, false, 4, SND(PORTO_FIRE), CH_WEAPON_A, 0);
 241         // always shoot from the eye
 242         w_shotdir = v_forward;
 243         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 244
 245         //Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 246
 247         gren = spawn();
 248         gren.cnt = type;
 249         gren.owner = gren.realowner = self;
 250         gren.playerid = self.playerid;
 251         gren.classname = "porto";
 252         gren.bot_dodge = true;
 253         gren.bot_dodgerating = 200;
 254         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 255         PROJECTILE_MAKETRIGGER(gren);
 256         gren.effects = EF_RED;
 257         gren.scale = 4;
 258         setorigin(gren, w_shotorg);
 259         setsize(gren, '0 0 0', '0 0 0');
 260
 261         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 262         gren.think = W_Porto_Think;
 263         gren.touch = W_Porto_Touch;
 264
 265         if(self.items & ITEM_Strength.m_itemid)
 266                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 267         else
 268                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 269
 270         gren.angles = vectoangles(gren.velocity);
 271         gren.flags = FL_PROJECTILE;
 272
 273         gren.portal_id = time;
 274         self.porto_current = gren;
 275         gren.playerid = self.playerid;
 276         fixedmakevectors(fixedvectoangles(gren.velocity));
 277         gren.right_vector = v_right;
 278
 279         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 280
 281         if(type > 0)
 282                 CSQCProjectile(gren, true, PROJECTILE_PORTO_BLUE, true);
 283         else
 284                 CSQCProjectile(gren, true, PROJECTILE_PORTO_RED, true);
 285
 286         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 287 }
 288
 289                 METHOD(PortoLaunch, wr_aim, bool(entity thiswep))
 290                 {
 291                         SELFPARAM();
 292                         self.BUTTON_ATCK = false;
 293                         self.BUTTON_ATCK2 = false;
 294                         if(!WEP_CVAR(porto, secondary))
 295                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), false))
 296                                         self.BUTTON_ATCK = true;
 297
 298                         return true;
 299                 }
 300                 METHOD(PortoLaunch, wr_config, bool(entity this))
 301                 {
 302                         PORTO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 303                         return true;
 304                 }
 305                 METHOD(PortoLaunch, wr_think, bool(entity thiswep))
 306                 {
 307                         SELFPARAM();
 308                         if(WEP_CVAR(porto, secondary))
 309                         {
 310                                 if(self.BUTTON_ATCK)
 311                                 if(!self.porto_current)
 312                                 if(!self.porto_forbidden)
 313                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 314                                 {
 315                                         W_Porto_Attack(0);
 316                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 317                                 }
 318
 319                                 if(self.BUTTON_ATCK2)
 320                                 if(!self.porto_current)
 321                                 if(!self.porto_forbidden)
 322                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(porto, refire)))
 323                                 {
 324                                         W_Porto_Attack(1);
 325                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 326                                 }
 327                         }
 328                         else
 329                         {
 330                                 if(self.porto_v_angle_held)
 331                                 {
 332                                         if(!self.BUTTON_ATCK2)
 333                                         {
 334                                                 self.porto_v_angle_held = 0;
 335
 336                                                 ClientData_Touch(self);
 337                                         }
 338                                 }
 339                                 else
 340                                 {
 341                                         if(self.BUTTON_ATCK2)
 342                                         {
 343                                                 self.porto_v_angle = self.v_angle;
 344                                                 self.porto_v_angle_held = 1;
 345
 346                                                 ClientData_Touch(self);
 347                                         }
 348                                 }
 349                                 if(self.porto_v_angle_held)
 350                                         makevectors(self.porto_v_angle); // override the previously set angles
 351
 352                                 if(self.BUTTON_ATCK)
 353                                 if(!self.porto_current)
 354                                 if(!self.porto_forbidden)
 355                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 356                                 {
 357                                         W_Porto_Attack(-1);
 358                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 359                                 }
 360                         }
 361
 362                         return true;
 363                 }
 364                 METHOD(PortoLaunch, wr_checkammo1, bool(entity this))
 365                 {
 366                         // always allow infinite ammo
 367                         return true;
 368                 }
 369                 METHOD(PortoLaunch, wr_checkammo2, bool(entity this))
 370                 {
 371                         // always allow infinite ammo
 372                         return true;
 373                 }
 374                 METHOD(PortoLaunch, wr_init, bool(entity this))
 375                 {
 376                         PORTO_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 377                         return true;
 378                 }
 379                 METHOD(PortoLaunch, wr_setup, bool(entity thiswep))
 380                 {
 381                         SELFPARAM();
 382                         self.ammo_field = ammo_none;
 383                         return true;
 384                 }
 385                 METHOD(PortoLaunch, wr_resetplayer, bool(entity thiswep))
 386                 {
 387                         SELFPARAM();
 388                         self.porto_current = world;
 389                         return true;
 390                 }
 391 #endif
 392 #ifdef CSQC
 393                 METHOD(PortoLaunch, wr_impacteffect, bool(entity this)) {
 394                         LOG_WARNING("Since when does Porto send DamageInfo?\n");
 395                         return true;
 396                 }
 397                 METHOD(PortoLaunch, wr_init, bool(entity this)) {
 398                         // nothing to do
 399                         return true;
 400                 }
 401                 METHOD(PortoLaunch, wr_zoomreticle, bool(entity this)) {
 402                         // no weapon specific image for this weapon
 403                         return false;
 404                 }
 405 #endif
 406 #endif