qcsrc/common/weapons/weapon/rifle.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Rifle, Weapon)
   3 /* ammotype  */ ATTRIB(Rifle, ammo_field, .int, ammo_nails)
   4 /* impulse   */ ATTRIB(Rifle, impulse, int, 7)
   5 /* flags     */ ATTRIB(Rifle, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Rifle, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(Rifle, wpcolor, vector, '0.5 1 0');
   8 /* modelname */ ATTRIB(Rifle, mdl, string, "campingrifle");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Rifle, m_model, Model, MDL_RIFLE_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Rifle, w_crosshair, string, "gfx/crosshairrifle");
  13 /* crosshair */ ATTRIB(Rifle, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Rifle, model2, string, "weaponrifle");
  15 /* refname   */ ATTRIB(Rifle, netname, string, "rifle");
  16 /* wepname   */ ATTRIB(Rifle, m_name, string, _("Rifle"));
  17 ENDCLASS(Rifle)
  18 REGISTER_WEAPON(RIFLE, NEW(Rifle));
  19
  20 #define RIFLE_SETTINGS(w_cvar,w_prop) RIFLE_SETTINGS_LIST(w_cvar, w_prop, RIFLE, rifle)
  21 #define RIFLE_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, BOTH, ammo) \
  23         w_cvar(id, sn, BOTH, animtime) \
  24         w_cvar(id, sn, BOTH, bullethail) \
  25         w_cvar(id, sn, BOTH, burstcost) \
  26         w_cvar(id, sn, BOTH, damage) \
  27         w_cvar(id, sn, BOTH, force) \
  28         w_cvar(id, sn, BOTH, refire) \
  29         w_cvar(id, sn, BOTH, shots) \
  30         w_cvar(id, sn, BOTH, solidpenetration) \
  31         w_cvar(id, sn, BOTH, spread) \
  32         w_cvar(id, sn, BOTH, tracer) \
  33         w_cvar(id, sn, NONE, bursttime) \
  34         w_cvar(id, sn, NONE, secondary) \
  35         w_cvar(id, sn, SEC,  reload) \
  36         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  37         w_prop(id, sn, float,  reloading_time, reload_time) \
  38         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  39         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  40         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  41         w_prop(id, sn, float,  weaponstart, weaponstart) \
  42         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  43         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  44
  45 #ifdef SVQC
  46 RIFLE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  47 .float rifle_accumulator;
  48 #endif
  49 #endif
  50 #ifdef IMPLEMENTATION
  51 #ifdef SVQC
  52 spawnfunc(weapon_rifle) { weapon_defaultspawnfunc(this, WEP_RIFLE); }
  53 spawnfunc(weapon_campingrifle) { spawnfunc_weapon_rifle(this); }
  54 spawnfunc(weapon_sniperrifle) { spawnfunc_weapon_rifle(this); }
  55
  56 void W_Rifle_FireBullet(Weapon thiswep, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, string pSound)
  57 {SELFPARAM();
  58         float i;
  59
  60         W_DecreaseAmmo(thiswep, self, pAmmo);
  61
  62         W_SetupShot(self, true, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  63
  64         Send_Effect(EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000, 1);
  65
  66         if(self.BUTTON_ZOOM | self.BUTTON_ZOOMSCRIPT) // if zoomed, shoot from the eye
  67         {
  68                 w_shotdir = v_forward;
  69                 w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
  70         }
  71
  72         for(i = 0; i < pShots; ++i)
  73                 fireBullet(w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
  74
  75         if(autocvar_g_casings >= 2)
  76                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  77 }
  78
  79 void W_Rifle_Attack()
  80 {
  81         W_Rifle_FireBullet(WEP_RIFLE, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND(CAMPINGRIFLE_FIRE));
  82 }
  83
  84 void W_Rifle_Attack2()
  85 {
  86         W_Rifle_FireBullet(WEP_RIFLE, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND(CAMPINGRIFLE_FIRE2));
  87 }
  88
  89 .void() rifle_bullethail_attackfunc;
  90 .WFRAME rifle_bullethail_frame;
  91 .float rifle_bullethail_animtime;
  92 .float rifle_bullethail_refire;
  93 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  94 {
  95         float r, sw, af;
  96
  97         sw = actor.switchweapon; // make it not detect weapon changes as reason to abort firing
  98         int slot = weaponslot(weaponentity);
  99         af = ATTACK_FINISHED(actor, slot);
 100         actor.switchweapon = actor.weapon;
 101         ATTACK_FINISHED(actor, slot) = time;
 102         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
 103         if(actor.switchweapon == actor.weapon)
 104                 actor.switchweapon = sw;
 105         if(r)
 106         {
 107                 actor.rifle_bullethail_attackfunc();
 108                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
 109         }
 110         else
 111         {
 112                 ATTACK_FINISHED(actor, slot) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
 113         }
 114 }
 115
 116 void W_Rifle_BulletHail(.entity weaponentity, float mode, void() AttackFunc, WFRAME fr, float animtime, float refire)
 117 {SELFPARAM();
 118         // if we get here, we have at least one bullet to fire
 119         AttackFunc();
 120         if(mode)
 121         {
 122                 // continue hail
 123                 self.rifle_bullethail_attackfunc = AttackFunc;
 124                 self.rifle_bullethail_frame = fr;
 125                 self.rifle_bullethail_animtime = animtime;
 126                 self.rifle_bullethail_refire = refire;
 127                 weapon_thinkf(self, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
 128         }
 129         else
 130         {
 131                 // just one shot
 132                 weapon_thinkf(self, weaponentity, fr, animtime, w_ready);
 133         }
 134 }
 135
 136 .float bot_secondary_riflemooth;
 137
 138                 METHOD(Rifle, wr_aim, void(entity thiswep))
 139                 {
 140                         self.BUTTON_ATCK=false;
 141                         self.BUTTON_ATCK2=false;
 142                         if(vlen(self.origin-self.enemy.origin) > 1000)
 143                                 self.bot_secondary_riflemooth = 0;
 144                         if(self.bot_secondary_riflemooth == 0)
 145                         {
 146                                 if(bot_aim(1000000, 0, 0.001, false))
 147                                 {
 148                                         self.BUTTON_ATCK = true;
 149                                         if(random() < 0.01) self.bot_secondary_riflemooth = 1;
 150                                 }
 151                         }
 152                         else
 153                         {
 154                                 if(bot_aim(1000000, 0, 0.001, false))
 155                                 {
 156                                         self.BUTTON_ATCK2 = true;
 157                                         if(random() < 0.03) self.bot_secondary_riflemooth = 0;
 158                                 }
 159                         }
 160                 }
 161                 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 162                 {
 163                         if(autocvar_g_balance_rifle_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
 164                                 thiswep.wr_reload(thiswep);
 165                         } else
 166                         {
 167                                 actor.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.rifle_accumulator, time);
 168                                 if(fire & 1)
 169                                 if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
 170                                 if(time >= actor.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 171                                 {
 172                                         weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
 173                                         W_Rifle_BulletHail(weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 174                                         actor.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 175                                 }
 176                                 if(fire & 2)
 177                                 {
 178                                         if(WEP_CVAR(rifle, secondary))
 179                                         {
 180                                                 if(WEP_CVAR_SEC(rifle, reload)) {
 181                                                         thiswep.wr_reload(thiswep);
 182                                                 } else
 183                                                 {
 184                                                         if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
 185                                                         if(time >= actor.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 186                                                         {
 187                                                                 weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
 188                                                                 W_Rifle_BulletHail(weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 189                                                                 actor.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 190                                                         }
 191                                                 }
 192                                         }
 193                                 }
 194                         }
 195                 }
 196                 METHOD(Rifle, wr_init, void(entity thiswep))
 197                 {
 198                         RIFLE_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 199                 }
 200                 METHOD(Rifle, wr_checkammo1, bool(entity thiswep))
 201                 {
 202                         float ammo_amount = self.WEP_AMMO(RIFLE) >= WEP_CVAR_PRI(rifle, ammo);
 203                         ammo_amount += self.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
 204                         return ammo_amount;
 205                 }
 206                 METHOD(Rifle, wr_checkammo2, bool(entity thiswep))
 207                 {
 208                         float ammo_amount = self.WEP_AMMO(RIFLE) >= WEP_CVAR_SEC(rifle, ammo);
 209                         ammo_amount += self.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
 210                         return ammo_amount;
 211                 }
 212                 METHOD(Rifle, wr_config, void(entity thiswep))
 213                 {
 214                         RIFLE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 215                 }
 216                 METHOD(Rifle, wr_resetplayer, void(entity thiswep))
 217                 {
 218                         self.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 219                 }
 220                 METHOD(Rifle, wr_reload, void(entity thiswep))
 221                 {
 222                         W_Reload(self, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND(RELOAD));
 223                 }
 224                 METHOD(Rifle, wr_suicidemessage, int(entity thiswep))
 225                 {
 226                         return WEAPON_THINKING_WITH_PORTALS;
 227                 }
 228                 METHOD(Rifle, wr_killmessage, int(entity thiswep))
 229                 {
 230                         if(w_deathtype & HITTYPE_SECONDARY)
 231                         {
 232                                 if(w_deathtype & HITTYPE_BOUNCE)
 233                                         return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 234                                 else
 235                                         return WEAPON_RIFLE_MURDER_HAIL;
 236                         }
 237                         else
 238                         {
 239                                 if(w_deathtype & HITTYPE_BOUNCE)
 240                                         return WEAPON_RIFLE_MURDER_PIERCING;
 241                                 else
 242                                         return WEAPON_RIFLE_MURDER;
 243                         }
 244                 }
 245
 246 #endif
 247 #ifdef CSQC
 248
 249                 METHOD(Rifle, wr_impacteffect, void(entity thiswep))
 250                 {
 251                         vector org2;
 252                         org2 = w_org + w_backoff * 2;
 253                         pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
 254                         if(!w_issilent)
 255                         {
 256                                 sound(self, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 257                         }
 258                 }
 259                 METHOD(Rifle, wr_init, void(entity thiswep))
 260                 {
 261                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 262                         {
 263                                 precache_pic("gfx/reticle_nex");
 264                         }
 265                 }
 266                 METHOD(Rifle, wr_zoomreticle, bool(entity thiswep))
 267                 {
 268                         if(button_zoom || zoomscript_caught)
 269                         {
 270                                 reticle_image = "gfx/reticle_nex";
 271                                 return true;
 272                         }
 273                         else
 274                         {
 275                                 // no weapon specific image for this weapon
 276                                 return false;
 277                         }
 278                 }
 279
 280 #endif
 281 #endif