qcsrc/common/weapons/weapon/shotgun.qc

   1 #include "shotgun.qh"
   2
   3 #ifdef SVQC
   4 spawnfunc(weapon_shotgun) { weapon_defaultspawnfunc(this, WEP_SHOTGUN); }
   5
   6 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force)
   7 {
   8         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
   9
  10         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets);
  11         for(int sc = 0;sc < bullets;sc = sc + 1)
  12                 fireBullet(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, force, WEP_SHOTGUN.m_id, 0);
  13
  14         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, ammocount);
  15
  16         // casing code
  17         if(autocvar_g_casings >= 1)
  18         {
  19                 makevectors(actor.v_angle); // for some reason, this is lost
  20                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  21                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
  22         }
  23
  24         // muzzle flash for 1st person view
  25         entity flash = spawn();
  26         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
  27         setthink(flash, SUB_Remove);
  28         flash.nextthink = time + 0.06;
  29         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  30         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
  31 }
  32
  33 .float swing_prev;
  34 .entity swing_alreadyhit;
  35 void W_Shotgun_Melee_Think(entity this)
  36 {
  37         // declarations
  38         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  39         entity target_victim;
  40         vector targpos;
  41
  42         if(!this.cnt) // set start time of melee
  43         {
  44                 this.cnt = time;
  45                 W_PlayStrengthSound(this.realowner);
  46         }
  47
  48         makevectors(this.realowner.v_angle); // update values for v_* vectors
  49
  50         // calculate swing percentage based on time
  51         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
  52         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
  53         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
  54
  55         // check to see if we can still continue, otherwise give up now
  56         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
  57         {
  58                 delete(this);
  59                 return;
  60         }
  61
  62         // if okay, perform the traces needed for this frame
  63         for(i=this.swing_prev; i < f; ++i)
  64         {
  65                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
  66
  67                 targpos = (this.realowner.origin + this.realowner.view_ofs
  68                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
  69                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
  70                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
  71
  72                 WarpZone_traceline_antilag(this, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
  73
  74                 // draw lightning beams for debugging
  75                 //te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
  76                 //te_customflash(targpos, 40,  2, '1 1 1');
  77
  78                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
  79
  80                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
  81                         && (trace_ent.takedamage == DAMAGE_AIM)
  82                         && (trace_ent != this.swing_alreadyhit)
  83                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
  84                 {
  85                         target_victim = trace_ent; // so it persists through other calls
  86
  87                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
  88                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
  89                         else
  90                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
  91
  92                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
  93
  94                         Damage(target_victim, this.realowner, this.realowner,
  95                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY,
  96                                 this.realowner.origin + this.realowner.view_ofs,
  97                                 v_forward * WEP_CVAR_SEC(shotgun, force));
  98
  99                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN.m_id, 0, swing_damage); }
 100
 101                         // draw large red flash for debugging
 102                         //te_customflash(targpos, 200, 2, '15 0 0');
 103
 104                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 105                         {
 106                                 this.swing_alreadyhit = target_victim;
 107                                 continue; // move along to next trace
 108                         }
 109                         else
 110                         {
 111                                 delete(this);
 112                                 return;
 113                         }
 114                 }
 115         }
 116
 117         if(time >= this.cnt + meleetime)
 118         {
 119                 // melee is finished
 120                 delete(this);
 121                 return;
 122         }
 123         else
 124         {
 125                 // set up next frame
 126                 this.swing_prev = i;
 127                 this.nextthink = time;
 128         }
 129 }
 130
 131 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 132 {
 133         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
 134         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 135
 136         entity meleetemp = new_pure(meleetemp);
 137         meleetemp.realowner = actor;
 138         setthink(meleetemp, W_Shotgun_Melee_Think);
 139         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
 140         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range));
 141 }
 142
 143 // alternate secondary weapon frames
 144 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 145 {
 146         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 147         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 148         {
 149                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 150                 w_ready(thiswep, actor, weaponentity, fire);
 151                 return;
 152         }
 153
 154         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
 155         W_Shotgun_Attack(WEP_SHOTGUN, actor, weaponentity, true,
 156                 WEP_CVAR_PRI(shotgun, ammo),
 157                 WEP_CVAR_PRI(shotgun, damage),
 158                 WEP_CVAR_PRI(shotgun, bullets),
 159                 WEP_CVAR_PRI(shotgun, spread),
 160                 WEP_CVAR_PRI(shotgun, solidpenetration),
 161                 WEP_CVAR_PRI(shotgun, force)); // actually is secondary, but we trick the last shot into playing full reload sound
 162         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
 163 }
 164 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 165 {
 166         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 167         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 168         {
 169                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 170                 w_ready(thiswep, actor, weaponentity, fire);
 171                 return;
 172         }
 173
 174         W_Shotgun_Attack(WEP_SHOTGUN, actor, weaponentity, false,
 175                 WEP_CVAR_PRI(shotgun, ammo),
 176                 WEP_CVAR_PRI(shotgun, damage),
 177                 WEP_CVAR_PRI(shotgun, bullets),
 178                 WEP_CVAR_PRI(shotgun, spread),
 179                 WEP_CVAR_PRI(shotgun, solidpenetration),
 180                 WEP_CVAR_PRI(shotgun, force));
 181         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
 182 }
 183
 184 .float shotgun_primarytime;
 185
 186 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 187 {
 188     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
 189         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 190     else
 191         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 192 }
 193
 194 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 195 {
 196     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
 197     {
 198         // don't force reload an empty shotgun if its melee attack is active
 199         if(WEP_CVAR(shotgun, secondary) < 2) {
 200             thiswep.wr_reload(thiswep, actor, weaponentity);
 201         }
 202     }
 203     else
 204     {
 205         if(fire & 1)
 206         {
 207             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 208             {
 209                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
 210                 {
 211                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 212                                                 WEP_CVAR_PRI(shotgun, ammo),
 213                                                 WEP_CVAR_PRI(shotgun, damage),
 214                                                 WEP_CVAR_PRI(shotgun, bullets),
 215                                                 WEP_CVAR_PRI(shotgun, spread),
 216                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 217                                                 WEP_CVAR_PRI(shotgun, force));
 218                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
 219                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 220                 }
 221             }
 222         }
 223         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
 224         {
 225             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 226             {
 227                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
 228                 {
 229                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 230                                                 WEP_CVAR_PRI(shotgun, ammo),
 231                                                 WEP_CVAR_PRI(shotgun, damage),
 232                                                 WEP_CVAR_PRI(shotgun, bullets),
 233                                                 WEP_CVAR_PRI(shotgun, spread),
 234                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 235                                                 WEP_CVAR_PRI(shotgun, force));
 236                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
 237                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
 238                 }
 239             }
 240         }
 241     }
 242     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 243     if(WEP_CVAR(shotgun, secondary) == 1)
 244     if(((fire & 1) && GetResourceAmount(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_WEAPON_AMMO)) || (fire & 2))
 245     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
 246     {
 247         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 248         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 249     }
 250 }
 251 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 252 {
 253     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 254     ammo_amount += actor.(weaponentity).(weapon_load[WEP_SHOTGUN.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 255     return ammo_amount;
 256 }
 257 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 258 {
 259     if(IS_BOT_CLIENT(actor))
 260     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
 261         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
 262     switch(WEP_CVAR(shotgun, secondary))
 263     {
 264         case 1: return true; // melee does not use ammo
 265         case 2: // secondary triple shot
 266         {
 267             float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 268             ammo_amount += actor.(weaponentity).(weapon_load[WEP_SHOTGUN.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 269             return ammo_amount;
 270         }
 271         default: return false; // secondary unavailable
 272     }
 273 }
 274 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 275 {
 276     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
 277 }
 278 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
 279 {
 280     return WEAPON_THINKING_WITH_PORTALS;
 281 }
 282 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
 283 {
 284     if(w_deathtype & HITTYPE_SECONDARY)
 285         return WEAPON_SHOTGUN_MURDER_SLAP;
 286     else
 287         return WEAPON_SHOTGUN_MURDER;
 288 }
 289
 290 #endif
 291 #ifdef CSQC
 292 .float prevric;
 293
 294 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
 295 {
 296     vector org2 = w_org + w_backoff * 2;
 297     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 298     if(!w_issilent && time - actor.prevric > 0.25)
 299     {
 300         if(w_random < 0.05)
 301             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 302         actor.prevric = time;
 303     }
 304 }
 305
 306 #endif