qcsrc/common/weapons/weapon/vortex.qc

   1 #include "vortex.qh"
   2
   3 //REGISTER_STAT(WEP_CVAR_vortex_charge, bool, WEP_CVAR(vortex, charge))
   4 //REGISTER_STAT(WEP_CVAR_vortex_charge_animlimit, float, WEP_CVAR(vortex, charge_animlimit))
   5
   6 #if defined(GAMEQC)
   7 float autocvar_g_weapon_charge_colormod_red_full;
   8 float autocvar_g_weapon_charge_colormod_red_half;
   9 float autocvar_g_weapon_charge_colormod_green_full;
  10 float autocvar_g_weapon_charge_colormod_blue_full;
  11 float autocvar_g_weapon_charge_colormod_blue_half;
  12 float autocvar_g_weapon_charge_colormod_green_half;
  13 float autocvar_g_weapon_charge_colormod_hdrmultiplier;
  14
  15 METHOD(Vortex, wr_glow, vector(Vortex this, entity actor, entity wepent))
  16 {
  17         if (!WEP_CVAR(vortex, charge)) return '0 0 0';
  18         float charge = wepent.vortex_charge;
  19         float animlimit = WEP_CVAR(vortex, charge_animlimit);
  20         float f = autocvar_g_weapon_charge_colormod_hdrmultiplier * min(1, charge / animlimit);
  21         vector g;
  22         g.x = f * autocvar_g_weapon_charge_colormod_red_half;
  23         g.y = f * autocvar_g_weapon_charge_colormod_green_half;
  24         g.z = f * autocvar_g_weapon_charge_colormod_blue_half;
  25         if (charge > animlimit)
  26         {
  27                 f = autocvar_g_weapon_charge_colormod_hdrmultiplier * (charge - animlimit) / (1 - animlimit);
  28                 g.x += f * autocvar_g_weapon_charge_colormod_red_full;
  29                 g.y += f * autocvar_g_weapon_charge_colormod_green_full;
  30                 g.z += f * autocvar_g_weapon_charge_colormod_blue_full;
  31         }
  32         return g;
  33 }
  34 #endif
  35
  36 REGISTER_NET_TEMP(TE_CSQC_VORTEXBEAMPARTICLE)
  37
  38 #if defined(SVQC)
  39 void SendCSQCVortexBeamParticle(float charge) {
  40         vector v;
  41         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  42         WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
  43         WriteVector(MSG_BROADCAST, w_shotorg);
  44         WriteVector(MSG_BROADCAST, v);
  45         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  46 }
  47 #elif defined(CSQC)
  48 NET_HANDLE(TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
  49 {
  50         float charge;
  51     vector shotorg = ReadVector();
  52     vector endpos = ReadVector();
  53         charge = ReadByte() / 255.0;
  54
  55         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
  56
  57         //draw either the old v2.3 beam or the new beam
  58         charge = sqrt(charge); // divide evenly among trail spacing and alpha
  59         particles_alphamin = particles_alphamax = particles_fade = charge;
  60
  61         if(!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
  62         {
  63                 if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
  64                         WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  65                 else
  66                         WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  67         }
  68         return true;
  69 }
  70 #endif
  71
  72 #ifdef SVQC
  73
  74 REGISTER_MUTATOR(vortex_charge, true);
  75
  76 MUTATOR_HOOKFUNCTION(vortex_charge, GetPressedKeys)
  77 {
  78     entity player = M_ARGV(0, entity);
  79
  80         // WEAPONTODO
  81     if(!WEP_CVAR(vortex, charge) || !WEP_CVAR(vortex, charge_velocity_rate))
  82         return;
  83
  84     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  85     {
  86         .entity weaponentity = weaponentities[slot];
  87
  88         if (player.(weaponentity).m_weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && vdist(vec2(player.velocity), >, WEP_CVAR(vortex, charge_minspeed)))
  89         {
  90             float xyspeed = vlen(vec2(player.velocity));
  91                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
  92                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
  93                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
  94                 // add the extra charge
  95                 player.(weaponentity).vortex_charge = min(1, player.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
  96         }
  97     }
  98 }
  99
 100 void W_Vortex_Attack(Weapon thiswep, entity actor, .entity weaponentity, float issecondary)
 101 {
 102         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
 103
 104         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
 105         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
 106         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
 107         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
 108         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
 109         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
 110         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
 111
 112     float dtype = thiswep.m_id;
 113     if(WEP_CVAR_BOTH(vortex, !issecondary, armorpierce))
 114         dtype |= HITTYPE_ARMORPIERCE;
 115
 116         float flying;
 117         flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 118
 119         if(WEP_CVAR(vortex, charge))
 120         {
 121                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * actor.(weaponentity).vortex_charge;
 122                 actor.(weaponentity).vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
 123                 // O RLY? -- divVerent
 124                 // YA RLY -- FruitieX
 125         }
 126         else
 127                 charge = 1;
 128         mydmg *= charge;
 129         myforce *= charge;
 130
 131         W_SetupShot(actor, weaponentity, true, 5, SND_NEXFIRE, CH_WEAPON_A, mydmg, dtype);
 132         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
 133         {
 134                 sound(actor, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
 135         }
 136
 137         yoda = 0;
 138         damage_goodhits = 0;
 139         FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, dtype);
 140
 141         if(yoda && flying)
 142                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 143         if(damage_goodhits && actor.vortex_lasthit)
 144         {
 145                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 146                 damage_goodhits = 0; // only every second time
 147         }
 148
 149         actor.vortex_lasthit = damage_goodhits;
 150
 151         //beam and muzzle flash done on client
 152         SendCSQCVortexBeamParticle(charge);
 153
 154         W_DecreaseAmmo(thiswep, actor, myammo, weaponentity);
 155 }
 156
 157 .float vortex_chargepool_pauseregen_finished;
 158
 159 METHOD(Vortex, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 160 {
 161     if(bot_aim(actor, weaponentity, 1000000, 0, 1, false))
 162         PHYS_INPUT_BUTTON_ATCK(actor) = true;
 163     else
 164     {
 165         if(WEP_CVAR(vortex, charge))
 166             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 167     }
 168 }
 169 METHOD(Vortex, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 170 {
 171     if(WEP_CVAR(vortex, charge) && actor.(weaponentity).vortex_charge < WEP_CVAR(vortex, charge_limit))
 172         actor.(weaponentity).vortex_charge = min(1, actor.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_rate) * frametime / W_TICSPERFRAME);
 173
 174     if(WEP_CVAR_SEC(vortex, chargepool))
 175         if(actor.(weaponentity).vortex_chargepool_ammo < 1)
 176         {
 177             if(actor.vortex_chargepool_pauseregen_finished < time)
 178                 actor.(weaponentity).vortex_chargepool_ammo = min(1, actor.(weaponentity).vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
 179             actor.pauseregen_finished = max(actor.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
 180         }
 181
 182     if(autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
 183         thiswep.wr_reload(thiswep, actor, weaponentity);
 184     } else
 185     {
 186         if(fire & 1)
 187         {
 188             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vortex, refire)))
 189             {
 190                 W_Vortex_Attack(thiswep, actor, weaponentity, 0);
 191                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
 192             }
 193         }
 194         if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) : (fire & 2))
 195         {
 196             if(WEP_CVAR(vortex, charge))
 197             {
 198                 actor.(weaponentity).vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
 199                 float dt = frametime / W_TICSPERFRAME;
 200
 201                 if(actor.(weaponentity).vortex_charge < 1)
 202                 {
 203                     if(WEP_CVAR_SEC(vortex, chargepool))
 204                     {
 205                         if(WEP_CVAR_SEC(vortex, ammo))
 206                         {
 207                             // always deplete if secondary is held
 208                             actor.(weaponentity).vortex_chargepool_ammo = max(0, actor.(weaponentity).vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
 209
 210                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 211                             actor.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
 212                             dt = min(dt, actor.(weaponentity).vortex_chargepool_ammo);
 213                             dt = max(0, dt);
 214
 215                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 216                         }
 217                     }
 218
 219                     else if(WEP_CVAR_SEC(vortex, ammo))
 220                     {
 221                         if(fire & 2) // only eat ammo when the button is pressed
 222                         {
 223                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 224                             if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 225                             {
 226                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 227                                 if(autocvar_g_balance_vortex_reload_ammo)
 228                                 {
 229                                     dt = min(dt, (actor.(weaponentity).clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 230                                     dt = max(0, dt);
 231                                     if(dt > 0)
 232                                     {
 233                                         actor.(weaponentity).clip_load = max(WEP_CVAR_SEC(vortex, ammo), actor.(weaponentity).clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
 234                                     }
 235                                     actor.(weaponentity).(weapon_load[thiswep.m_id]) = actor.(weaponentity).clip_load;
 236                                 }
 237                                 else
 238                                 {
 239                                     dt = min(dt, (GetResource(actor, thiswep.ammo_type) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 240                                     dt = max(0, dt);
 241                                     if(dt > 0)
 242                                     {
 243                                         SetResource(actor, thiswep.ammo_type, max(WEP_CVAR_SEC(vortex, ammo), GetResource(actor, thiswep.ammo_type) - WEP_CVAR_SEC(vortex, ammo) * dt));
 244                                     }
 245                                 }
 246                             }
 247                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 248                         }
 249                     }
 250
 251                     else
 252                     {
 253                         dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 254                         actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 255                     }
 256                 }
 257             }
 258             else if(WEP_CVAR(vortex, secondary))
 259             {
 260                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(vortex, refire)))
 261                 {
 262                     W_Vortex_Attack(thiswep, actor, weaponentity, 1);
 263                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
 264                 }
 265             }
 266         }
 267     }
 268 }
 269 METHOD(Vortex, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 270 {
 271     actor.vortex_lasthit = 0;
 272 }
 273 METHOD(Vortex, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 274 {
 275     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(vortex, ammo);
 276     ammo_amount += (autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
 277     return ammo_amount;
 278 }
 279 METHOD(Vortex, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 280 {
 281     if(WEP_CVAR(vortex, secondary))
 282     {
 283         // don't allow charging if we don't have enough ammo
 284         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(vortex, ammo);
 285         ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
 286         return ammo_amount;
 287     }
 288     else
 289     {
 290         return false; // zoom is not a fire mode
 291     }
 292 }
 293 METHOD(Vortex, wr_resetplayer, void(entity thiswep, entity actor))
 294 {
 295     if (WEP_CVAR(vortex, charge)) {
 296         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 297         {
 298             .entity weaponentity = weaponentities[slot];
 299             actor.(weaponentity).vortex_charge = WEP_CVAR(vortex, charge_start);
 300
 301             if (WEP_CVAR_SEC(vortex, chargepool))
 302                 actor.(weaponentity).vortex_chargepool_ammo = 1;
 303         }
 304     }
 305     actor.vortex_lasthit = 0;
 306 }
 307 METHOD(Vortex, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 308 {
 309     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND_RELOAD);
 310 }
 311 METHOD(Vortex, wr_suicidemessage, Notification(entity thiswep))
 312 {
 313     return WEAPON_THINKING_WITH_PORTALS;
 314 }
 315 METHOD(Vortex, wr_killmessage, Notification(entity thiswep))
 316 {
 317     return WEAPON_VORTEX_MURDER;
 318 }
 319 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 320 {
 321     return PHYS_INPUT_BUTTON_ATCK2(actor) && !WEP_CVAR(vortex, secondary);
 322 }
 323
 324 #endif
 325 #ifdef CSQC
 326
 327 METHOD(Vortex, wr_impacteffect, void(entity thiswep, entity actor))
 328 {
 329     entity this = actor;
 330     vector org2 = w_org + w_backoff * 6;
 331     pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 332     if(!w_issilent)
 333         sound(this, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
 334 }
 335 METHOD(Vortex, wr_init, void(entity thiswep))
 336 {
 337     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 338     {
 339         precache_pic("gfx/reticle_nex");
 340     }
 341 }
 342 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 343 {
 344     if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
 345     {
 346         return true;
 347     }
 348     else
 349     {
 350         // no weapon specific image for this weapon
 351         return false;
 352     }
 353 }
 354 METHOD(Vortex, wr_zoomdir, bool(entity thiswep))
 355 {
 356     return button_attack2 && !WEP_CVAR(vortex, secondary);
 357 }
 358
 359 #endif