qcsrc/lib/stats.qh

   1 #ifndef LIB_STATS_H
   2 #define LIB_STATS_H
   3
   4 // TODO: rename to 'netvars'
   5
   6 #include "registry.qh"
   7 #include "sort.qh"
   8
   9 .int m_id;
  10 typedef vector vectori;
  11
  12 #define REGISTER_STAT(...) EVAL_REGISTER_STAT(OVERLOAD(REGISTER_STAT, __VA_ARGS__))
  13 #define EVAL_REGISTER_STAT(...) __VA_ARGS__
  14 #if defined(CSQC)
  15         /** Get all stats and store them as globals, access with `STAT(ID)` */
  16         void stats_get() {}
  17         #define STAT(...) EVAL_STAT(OVERLOAD(STAT, __VA_ARGS__))
  18         #define EVAL_STAT(...) __VA_ARGS__
  19     #define STAT_1(id) STAT_2(id, NULL)
  20         #define STAT_2(id, cl) (0, _STAT(id))
  21
  22         #define getstat_int(id) getstati(id, 0, 24)
  23         #define getstat_bool(id) boolean(getstati(id))
  24         #define getstat_float(id) getstatf(id)
  25         #define getstat_vector(id) vec3(getstat_float(id + 0), getstat_float(id + 1), getstat_float(id + 2))
  26         #define getstat_vectori(id) vec3(getstat_int(id + 0), getstat_int(id + 1), getstat_int(id + 2))
  27
  28         #define _STAT(id) g_stat_##id
  29         #define REGISTER_STAT_2(id, T) \
  30                 T _STAT(id); \
  31                 T CAT(_STAT(id), _prev); \
  32                 REGISTER(Stats, STAT_##id, m_id, new_pure(stat)) \
  33                 { \
  34                         if (#T == "vector" || #T == "vectori") { \
  35                                 REGISTRY_RESERVE(Stats, m_id, STAT_##id, y); \
  36                                 REGISTRY_RESERVE(Stats, m_id, STAT_##id, z); \
  37                         } \
  38                 } \
  39                 [[accumulate]] void stats_get() \
  40                 { \
  41                         T it = getstat_##T(STAT_##id.m_id); \
  42                         if (it != CAT(_STAT(id), _prev)) \
  43                                 CAT(_STAT(id), _prev) = _STAT(id) = it; \
  44                 }
  45         #define REGISTER_STAT_3(x, T, expr) REGISTER_STAT_2(x, T)
  46 #elif defined(SVQC)
  47         /** Add all registered stats, access with `STAT(ID, player)` or `.type stat = _STAT(ID); player.stat` */
  48         void stats_add() {}
  49         #define STAT(id, cl) (cl)._STAT(id)
  50
  51         #define addstat_int(id, fld) addstat(id, AS_INT, fld)
  52         #define addstat_bool(id, fld) addstat(id, AS_INT, fld)
  53         #define addstat_float(id, fld) addstat(id, AS_FLOAT, fld)
  54         #define addstat_vector(id, fld) MACRO_BEGIN { \
  55                 addstat_float(id + 0, fld##_x); \
  56                 addstat_float(id + 1, fld##_y); \
  57                 addstat_float(id + 2, fld##_z); \
  58         } MACRO_END
  59         #define addstat_vectori(id, fld) MACRO_BEGIN { \
  60                 addstat_int(id + 0, fld##_x); \
  61                 addstat_int(id + 1, fld##_y); \
  62                 addstat_int(id + 2, fld##_z); \
  63         } MACRO_END
  64         const int AS_STRING = 1;
  65         const int AS_INT = 2;
  66         const int AS_FLOAT = 8;
  67
  68         .int __stat_null;
  69         /** Prevent engine stats being sent */
  70         STATIC_INIT(stats_clear)
  71         {
  72                 int r = 32;
  73                 for (int i = 0, n = 256 - r; i < n; ++i) {
  74                         addstat(r + i, AS_INT, __stat_null);
  75                 }
  76         }
  77
  78         #define _STAT(id) stat_##id
  79         #define REGISTER_STAT_2(id, T) \
  80                 .T _STAT(id); \
  81                 REGISTER(Stats, STAT_##id, m_id, new_pure(stat)) \
  82                 { \
  83                         if (#T == "vector" || #T == "vectori") { \
  84                                 REGISTRY_RESERVE(Stats, m_id, STAT_##id, y); \
  85                                 REGISTRY_RESERVE(Stats, m_id, STAT_##id, z); \
  86                         } \
  87                 } \
  88                 [[accumulate]] void stats_add() \
  89                 { \
  90                         .T fld = _STAT(id); \
  91                         addstat_##T(STAT_##id.m_id, fld); \
  92                 }
  93         void GlobalStats_update(entity this) {}
  94     #define REGISTER_STAT_3(id, T, expr) \
  95         REGISTER_STAT_2(id, T); \
  96         [[accumulate]] void GlobalStats_update(entity this) { STAT(id, this) = (expr); } \
  97         STATIC_INIT(worldstat_##id) { entity this = world; STAT(id, this) = (expr); }
  98 #else
  99         #define REGISTER_STAT_2(id, type)
 100     #define REGISTER_STAT_3(id, T, expr)
 101 #endif
 102
 103 const int STATS_ENGINE_RESERVE = 32;
 104
 105 REGISTRY(Stats, 256 - STATS_ENGINE_RESERVE)
 106 REGISTER_REGISTRY(Stats)
 107 REGISTRY_SORT(Stats)
 108 REGISTRY_CHECK(Stats)
 109 STATIC_INIT(RegisterStats_renumber)
 110 {
 111         FOREACH(Stats, true, LAMBDA(it.m_id = STATS_ENGINE_RESERVE + i));
 112 }
 113 #ifdef SVQC
 114 STATIC_INIT(stats_add) { stats_add(); }
 115 #endif
 116
 117 #endif