qcsrc/menu/item/textslider.qc

   1 // Note:
   2 //   to use this, you FIRST call configureSliderVisuals, then multiple times addValue, then configureTextSlider
   3 #ifndef ITEM_TEXTSLIDER_H
   4         #define ITEM_TEXTSLIDER_H
   5         #include "slider.qc"
   6         CLASS(TextSlider, Slider)
   7                 METHOD(TextSlider, valueToText, string(entity, float));
   8                 METHOD(TextSlider, valueToIdentifier, string(entity, float));
   9                 METHOD(TextSlider, setValueFromIdentifier_allowAnim, void(entity, string, bool));
  10                 METHOD(TextSlider, setValueFromIdentifier_noAnim, void(entity, string));
  11                 METHOD(TextSlider, setValueFromIdentifier, void(entity, string));
  12                 METHOD(TextSlider, getIdentifier, string(entity));
  13                 METHOD(TextSlider, clearValues, void(entity));
  14                 METHOD(TextSlider, addValue, void(entity, string, string));
  15                 METHOD(TextSlider, insertValue, void(entity, float, string, string));
  16                 METHOD(TextSlider, configureTextSliderValues, void(entity, string));
  17                 ATTRIBARRAY(TextSlider, valueStrings, string, 256)
  18                 ATTRIBARRAY(TextSlider, valueIdentifiers, string, 256)
  19                 ATTRIB(TextSlider, nValues, int, 0)
  20         ENDCLASS(TextSlider)
  21 #endif
  22
  23 #ifdef IMPLEMENTATION
  24         string TextSlider_valueToIdentifier(entity me, int val)
  25         {
  26                 if (val >= me.nValues) return "custom";
  27                 if (val < 0) return "custom";
  28                 return me.(valueIdentifiers[val]);
  29         }
  30         string TextSlider_valueToText(entity me, int val)
  31         {
  32                 if (val >= me.nValues) return _("Custom");
  33                 if (val < 0) return _("Custom");
  34                 return me.(valueStrings[val]);
  35         }
  36         void TextSlider_setValueFromIdentifier_allowAnim(entity me, string id, bool allowAnim)
  37         {
  38                 int i;
  39                 for (i = 0; i < me.nValues; ++i)
  40                         if (me.valueToIdentifier(me, i) == id)
  41                         {
  42                                 SUPER(TextSlider).setValue_allowAnim(me, i, allowAnim);
  43                                 return;
  44                         }
  45                 SUPER(TextSlider).setValue_allowAnim(me, -1, allowAnim);
  46         }
  47         void TextSlider_setValueFromIdentifier_noAnim(entity me, string id)
  48         {
  49                 TextSlider_setValueFromIdentifier_allowAnim(me, id, false);
  50         }
  51         void TextSlider_setValueFromIdentifier(entity me, string id)
  52         {
  53                 TextSlider_setValueFromIdentifier_allowAnim(me, id, true);
  54         }
  55         string TextSlider_getIdentifier(entity me)
  56         {
  57                 return me.valueToIdentifier(me, me.value);
  58         }
  59         void TextSlider_clearValues(entity me)
  60         {
  61                 me.nValues = 0;
  62         }
  63         void TextSlider_addValue(entity me, string theString, string theIdentifier)
  64         {
  65                 me.(valueStrings[me.nValues]) = theString;
  66                 me.(valueIdentifiers[me.nValues]) = theIdentifier;
  67                 me.nValues += 1;
  68         }
  69         void TextSlider_insertValue(entity me, int pos, string theString, string theIdentifier)
  70         {
  71                 int i;
  72                 for (i = me.nValues; i > pos; --i)
  73                 {
  74                         me.(valueStrings[i]) = me.(valueStrings[i - 1]);
  75                         me.(valueIdentifiers[i]) = me.(valueIdentifiers[i - 1]);
  76                 }
  77                 me.(valueStrings[pos]) = theString;
  78                 me.(valueIdentifiers[pos]) = theIdentifier;
  79                 me.nValues += 1;
  80         }
  81         void TextSlider_configureTextSliderValues(entity me, string theDefault)
  82         {
  83                 me.configureSliderValues(me, 0, 0, me.nValues - 1, 1, 1, 1);
  84                 me.setValueFromIdentifier_noAnim(me, theDefault);
  85         }
  86 #endif