qcsrc/menu/xonotic/gametypelist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticGametypeList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticGametypeList, configureXonoticGametypeList, void(entity))
   4         ATTRIB(XonoticGametypeList, rowsPerItem, float, 1)
   5         METHOD(XonoticGametypeList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticGametypeList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticGametypeList, setSelected, void(entity, float))
   8         METHOD(XonoticGametypeList, loadCvars, void(entity))
   9         METHOD(XonoticGametypeList, saveCvars, void(entity))
  10
  11         ATTRIB(XonoticGametypeList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticGametypeList, realUpperMargin, float, 0)
  13         ATTRIB(XonoticGametypeList, columnNameOrigin, float, 0)
  14         ATTRIB(XonoticGametypeList, columnNameSize, float, 0)
  15 ENDCLASS(XonoticGametypeList)
  16 entity makeXonoticGametypeList();
  17 #endif
  18
  19 #ifdef IMPLEMENTATION
  20
  21 #define GAMETYPES \
  22         GAMETYPE(MAPINFO_TYPE_DEATHMATCH, "Deathmatch") \
  23         GAMETYPE(MAPINFO_TYPE_LMS, "LMS") \
  24         GAMETYPE(MAPINFO_TYPE_ARENA, "Arena") \
  25         GAMETYPE(MAPINFO_TYPE_RUNEMATCH, "Runematch") \
  26         GAMETYPE(MAPINFO_TYPE_RACE, "Race") \
  27         GAMETYPE(MAPINFO_TYPE_CTS, "Race CTS") \
  28         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH, "TDM") \
  29         GAMETYPE(MAPINFO_TYPE_CTF, "CTF") \
  30         GAMETYPE(MAPINFO_TYPE_CA, "Clan Arena") \
  31         GAMETYPE(MAPINFO_TYPE_DOMINATION, "Domination") \
  32         GAMETYPE(MAPINFO_TYPE_KEYHUNT, "Key Hunt") \
  33         GAMETYPE(MAPINFO_TYPE_ASSAULT, "Assault") \
  34         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT, "Onslaught") \
  35         GAMETYPE(MAPINFO_TYPE_NEXBALL, "Nexball") \
  36         GAMETYPE(MAPINFO_TYPE_FREEZETAG, "Freeze Tag") \
  37         GAMETYPE(MAPINFO_TYPE_KEEPAWAY, "Keepaway") \
  38         /* nothing */
  39
  40 float GameType_GetID(float cnt)
  41 {
  42         float i;
  43         i = 0;
  44 #define GAMETYPE(id,name) if(i++ == cnt) return id;
  45         GAMETYPES
  46 #undef GAMETYPE
  47         return 0;
  48 }
  49 string GameType_GetName(float cnt)
  50 {
  51         float i;
  52         i = 0;
  53 #define GAMETYPE(id,name) if(i++ == cnt) return name;
  54         GAMETYPES
  55 #undef GAMETYPE
  56         return "@!#%'n Tuba Throwing";
  57 }
  58 float GameType_GetCount()
  59 {
  60         float i;
  61         i = 0;
  62 #define GAMETYPE(id,name) ++i;
  63         GAMETYPES
  64 #undef GAMETYPE
  65         return i;
  66 }
  67
  68 entity makeXonoticGametypeList(void)
  69 {
  70         entity me;
  71         me = spawnXonoticGametypeList();
  72         me.configureXonoticGametypeList(me);
  73         return me;
  74 }
  75 void XonoticGametypeList_configureXonoticGametypeList(entity me)
  76 {
  77         me.loadCvars(me);
  78         me.configureXonoticListBox(me);
  79 }
  80 void XonoticGametypeList_setSelected(entity me, float i)
  81 {
  82         SUPER(XonoticGametypeList).setSelected(me, i);
  83         me.saveCvars(me);
  84 }
  85
  86 void XonoticGametypeList_loadCvars(entity me)
  87 {
  88         if not(me.cvarName)
  89                 return;
  90
  91         float t;
  92         t = MapInfo_CurrentGametype();
  93         float i;
  94         for(i = 0; i < GameType_GetCount(); ++i)
  95                 if(t == GameType_GetID(i))
  96                         break;
  97         if(i >= GameType_GetCount())
  98                 i = 0;
  99         me.setSelected(me, i);
 100         // do we need this: me.parent.gameTypeChangeNotify(me.parent); // to make sure
 101 }
 102 void XonoticGametypeList_saveCvars(entity me)
 103 {
 104         float t;
 105         t = GameType_GetID(me.selectedItem);
 106         if(t == MapInfo_CurrentGametype())
 107                 return;
 108         MapInfo_SwitchGameType(t);
 109         me.parent.gameTypeChangeNotify(me.parent);
 110 }
 111 void XonoticGametypeList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 112 {
 113         string s;
 114         if(isSelected)
 115                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 116         s = GameType_GetName(i);
 117         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 118 }
 119 void XonoticGametypeList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 120 {
 121         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 122         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
 123         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
 124         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 125         me.columnNameOrigin = 0;
 126         me.columnNameSize = 1;
 127 }
 128 #endif