qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "../menu.qh"
   3 #include "../oo/base.qh"
   4 #include "../../common/campaign_common.qh"
   5 #include "../../common/constants.qh"
   6 #include "../../common/mapinfo.qh"
   7 #include "../../common/util.qh"
   8 #include "../../common/command/generic.qh"
   9
  10 float GL_CheckExtension(string ext)
  11 {
  12         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
  13 }
  14
  15 float GL_Have_TextureCompression()
  16 {
  17         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  18 }
  19
  20 .entity parent, firstChild, nextSibling;
  21 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  22 {
  23         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  24 }
  25
  26 .string cvarName;
  27 void SUB_Null_ee(entity e1, entity e2)
  28 {
  29 }
  30
  31 .void(entity) saveCvars;
  32 void saveCvarsOf(entity ignore, entity e)
  33 {
  34         if(e.saveCvars)
  35                 e.saveCvars(e);
  36 }
  37
  38 .void(entity) loadCvars;
  39 void loadCvarsOf(entity ignore, entity e)
  40 {
  41         if(e.loadCvars)
  42                 e.loadCvars(e);
  43 }
  44 void saveAllCvars(entity root)
  45 {
  46         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  47 }
  48 void loadAllCvars(entity root)
  49 {
  50         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  51 }
  52
  53 .string cvarNames_Multi;
  54 .void(entity me) saveCvars_Multi;
  55 string getCvarsMulti(entity me)
  56 {
  57         if (me.cvarNames_Multi)
  58                 return me.cvarNames_Multi;
  59         return string_null;
  60 }
  61 void saveCvarsMulti(entity me)
  62 {
  63         float n, i;
  64         string s;
  65
  66         me.saveCvars_Multi(me);
  67         s = cvar_string(me.cvarName);
  68
  69         n = tokenize_console(me.cvarNames_Multi);
  70         for(i = 0; i < n; ++i)
  71         {
  72                 if(substring(argv(i), 0, 1) == "!")
  73                         cvar_set(substring(argv(i), 1, strlen(argv(i))), ((s == "0") ? "1" : "0"));
  74                 else
  75                         cvar_set(argv(i), s);
  76
  77                 CheckSendCvars(me, argv(i));
  78         }
  79 }
  80 void makeMulti(entity e, string otherCvars)
  81 {
  82         e.cvarNames_Multi = otherCvars;
  83         e.saveCvars_Multi = e.saveCvars;
  84         e.saveCvars = saveCvarsMulti;
  85 }
  86
  87 .void(entity me) saveCvars_Callback;
  88 .entity saveCvars_Callback_ent;
  89 .void(entity me, entity cb) saveCvars_Callback_func;
  90 void saveCvarsCallback(entity me)
  91 {
  92         me.saveCvars_Callback(me);
  93         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
  94 }
  95 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
  96 {
  97         e.saveCvars_Callback = e.saveCvars;
  98         e.saveCvars = saveCvarsCallback;
  99         e.saveCvars_Callback_ent = cbent;
 100         e.saveCvars_Callback_func = cbfunc;
 101 }
 102
 103 .void(entity) draw_setDependent;
 104 .string cvar_setDependent;
 105 .float cvarMin_setDependent;
 106 .float cvarMax_setDependent;
 107 .string cvar2_setDependent;
 108 .float cvar2Min_setDependent;
 109 .float cvar2Max_setDependent;
 110 .string cvar3_setDependent;
 111 .float cvar3Min_setDependent;
 112 .float cvar3Max_setDependent;
 113 .float op_setDependent;
 114 .string cvarString_setDependent;
 115 .string cvarValue_setDependent;
 116 .float(entity) func_setDependent;
 117 .bool disabled;
 118 void setDependent_Check(entity e)
 119 {
 120         float f;
 121         string s;
 122         if(e.func_setDependent)
 123         {
 124                 e.disabled = !(e.func_setDependent(e));
 125         }
 126         else if(e.cvarString_setDependent)
 127         {
 128                 s = cvar_string(e.cvarString_setDependent);
 129                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 130         }
 131         else
 132         {
 133                 if(e.cvar_setDependent)
 134                 {
 135                         f = cvar(e.cvar_setDependent);
 136                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 137                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 138                         else
 139                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 140                 }
 141                 if(e.cvar2_setDependent)
 142                 {
 143                         f = cvar(e.cvar2_setDependent);
 144                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 145                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 146                         else
 147                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 148                 }
 149                 if(e.cvar3_setDependent)
 150                 {
 151                         f = cvar(e.cvar3_setDependent);
 152                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 153                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 154                         else
 155                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 156                 }
 157         }
 158 }
 159 void setDependent_Draw(entity e)
 160 {
 161         setDependent_Check(e);
 162         e.draw_setDependent(e);
 163 }
 164 .void(entity) draw;
 165 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 166 {
 167         e.draw_setDependent = e.draw;
 168         e.cvar_setDependent = theCvarName;
 169         e.cvarMin_setDependent = theCvarMin;
 170         e.cvarMax_setDependent = theCvarMax;
 171         e.cvar2_setDependent = string_null;
 172         e.cvar3_setDependent = string_null;
 173         e.func_setDependent = func_null;
 174         e.draw = setDependent_Draw;
 175         setDependent_Check(e);
 176 }
 177 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 178 {
 179         e.draw_setDependent = e.draw;
 180         e.cvarString_setDependent = theCvarName;
 181         e.cvarValue_setDependent = theCvarValue;
 182         e.cvar_setDependent = string_null;
 183         e.cvar2_setDependent = string_null;
 184         e.cvar3_setDependent = string_null;
 185         e.func_setDependent = func_null;
 186         e.draw = setDependent_Draw;
 187         setDependent_Check(e);
 188 }
 189 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 190 {
 191         e.draw_setDependent = e.draw;
 192         e.cvar_setDependent = theCvarName;
 193         e.cvarMin_setDependent = theCvarMin;
 194         e.cvarMax_setDependent = theCvarMax;
 195         e.cvar2_setDependent = theCvar2Name;
 196         e.cvar2Min_setDependent = theCvar2Min;
 197         e.cvar2Max_setDependent = theCvar2Max;
 198         e.cvar3_setDependent = string_null;
 199         e.op_setDependent = 0;
 200         e.func_setDependent = func_null;
 201         e.draw = setDependent_Draw;
 202         setDependent_Check(e);
 203 }
 204 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 205 {
 206         e.draw_setDependent = e.draw;
 207         e.cvar_setDependent = theCvarName;
 208         e.cvarMin_setDependent = theCvarMin;
 209         e.cvarMax_setDependent = theCvarMax;
 210         e.cvar2_setDependent = theCvar2Name;
 211         e.cvar2Min_setDependent = theCvar2Min;
 212         e.cvar2Max_setDependent = theCvar2Max;
 213         e.cvar3_setDependent = string_null;
 214         e.op_setDependent = 1;
 215         e.func_setDependent = func_null;
 216         e.draw = setDependent_Draw;
 217         setDependent_Check(e);
 218 }
 219 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 220 {
 221         e.draw_setDependent = e.draw;
 222         e.cvar_setDependent = theCvarName;
 223         e.cvarMin_setDependent = theCvarMin;
 224         e.cvarMax_setDependent = theCvarMax;
 225         e.cvar2_setDependent = theCvar2Name;
 226         e.cvar2Min_setDependent = theCvar2Min;
 227         e.cvar2Max_setDependent = theCvar2Max;
 228         e.cvar3_setDependent = theCvar3Name;
 229         e.cvar3Min_setDependent = theCvar3Min;
 230         e.cvar3Max_setDependent = theCvar3Max;
 231         e.op_setDependent = 0;
 232         e.func_setDependent = func_null;
 233         e.draw = setDependent_Draw;
 234         setDependent_Check(e);
 235 }
 236 void setDependentWeird(entity e, float(entity) func)
 237 {
 238         e.draw_setDependent = e.draw;
 239         e.func_setDependent = func;
 240         e.draw = setDependent_Draw;
 241         setDependent_Check(e);
 242 }
 243
 244 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 245 {
 246         if(theTooltip == "") // no tooltip, use cvar description then
 247         {
 248                 if(theCvar != "" && prvm_language == "en")
 249                 {
 250                         string t = cvar_description(theCvar);
 251                         if(t != "" && t != "custom cvar")
 252                                 theTooltip = t;
 253                 }
 254         }
 255         else if(theTooltip == "-") // no cvar description as tooltip
 256         {
 257                 theTooltip = string_null;
 258         }
 259
 260         if(e.tooltip)
 261                 strunzone(e.tooltip);
 262         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 263 }
 264
 265 void clearTooltip(entity e)
 266 {
 267         setZonedTooltip(e, string_null, string_null);
 268 }
 269
 270 // URI SYSTEM ////////////////////////////////////////////////////////
 271
 272 float _Nex_ExtResponseSystem_Queried;
 273 string _Nex_ExtResponseSystem_UpdateTo;
 274 string _Nex_ExtResponseSystem_UpdateToURL;
 275 string _Nex_ExtResponseSystem_Packs;
 276 float _Nex_ExtResponseSystem_PacksStep;
 277
 278 void URI_Get_Callback(float id, float status, string data)
 279 {
 280         if(url_URI_Get_Callback(id, status, data))
 281         {
 282                 // handled
 283         }
 284         else if (id == URI_GET_DISCARD)
 285         {
 286                 // discard
 287         }
 288         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 289         {
 290                 // sv_cmd curl
 291                 Curl_URI_Get_Callback(id, status, data);
 292         }
 293         else if (id == URI_GET_UPDATENOTIFICATION)
 294         {
 295                 UpdateNotification_URI_Get_Callback(id, status, data);
 296         }
 297         else
 298         {
 299                 LOG_INFOF("Received HTTP request data for an invalid id %d.\n", id);
 300         }
 301 }
 302
 303 void DisableServerBackwardsCompatibility()
 304 {
 305         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 306 }
 307
 308 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 309 {
 310         float n;
 311
 312         if(_Nex_ExtResponseSystem_UpdateTo)
 313         {
 314                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before\n");
 315                 return;
 316         }
 317         if(status != 0)
 318         {
 319                 LOG_TRACEF("error receiving update notification: status is %d\n", status);
 320                 return;
 321         }
 322         if(substring(data, 0, 1) == "<")
 323         {
 324                 LOG_TRACE("error: received HTML instead of an update notification\n");
 325                 return;
 326         }
 327         if(strstrofs(data, "\r", 0) != -1)
 328         {
 329                 LOG_TRACE("error: received carriage returns from update notification server\n");
 330                 return;
 331         }
 332
 333         if(data == "")
 334                 n = 0;
 335         else
 336                 n = tokenizebyseparator(data, "\n");
 337
 338         float i;
 339         string s;
 340
 341         string un_version = "";
 342         string un_download = "";
 343         string un_url = "";
 344         string un_bannedservers = "";
 345         string un_emergency_pk3s = "";
 346         string un_promoted = "";
 347         string un_recommended = "";
 348         string un_compatexpire = "";
 349
 350         for(i = 0; i < n; ++i)
 351         {
 352                 s = substring(argv(i), 2, -1);
 353                 if(s == "") { continue; } // ignore empty lines
 354
 355                 switch(substring(argv(i), 0, 1))
 356                 {
 357                         case "V":
 358                         {
 359                                 un_version = s;
 360                                 break;
 361                         }
 362                         case "C":
 363                         {
 364                                 un_compatexpire = s;
 365                                 break;
 366                         }
 367                         case "D":
 368                         {
 369                                 un_download = s;
 370                                 break;
 371                         }
 372                         case "U":
 373                         {
 374                                 un_url = s;
 375                                 break;
 376                         }
 377                         case "B":
 378                         {
 379                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 380                                 break;
 381                         }
 382                         case "E":
 383                         {
 384                                 if(cvar("menu_updatecheck_getpacks"))
 385                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 386                                 break;
 387                         }
 388                         case "P":
 389                         {
 390                                 APPEND_TO_STRING(un_promoted, " ", s);
 391                                 break;
 392                         }
 393                         case "R":
 394                         {
 395                                 APPEND_TO_STRING(un_recommended, " ", s);
 396                                 break;
 397                         }
 398                 }
 399         }
 400
 401         if(un_version != "")
 402         {
 403                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 404                 {
 405                         // update needed
 406                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 407                         if(un_download) { LOG_INFOF(_("Update can be downloaded at:\n%s\n"), un_download); }
 408                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 409                         DisableServerBackwardsCompatibility();
 410                 }
 411                 else if(cvar_string("g_xonoticversion") == un_version)
 412                 {
 413                         if(un_compatexpire != "")
 414                         {
 415                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 416                                 if (strcmp(curdate, un_compatexpire) >= 0)
 417                                         DisableServerBackwardsCompatibility();
 418                         }
 419                 }
 420         }
 421
 422         if(un_emergency_pk3s != "")
 423         {
 424                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 425                 _Nex_ExtResponseSystem_PacksStep = 1;
 426         }
 427
 428         if(un_promoted != "")
 429         {
 430                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 431                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 432         }
 433
 434         if(un_recommended != "")
 435         {
 436                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 437                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 438         }
 439 }
 440
 441 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 442
 443 void updateCheck()
 444 {
 445         if(cvar("menu_updatecheck"))
 446         {
 447                 if(!_Nex_ExtResponseSystem_Queried)
 448                 {
 449                         _Nex_ExtResponseSystem_Queried = 1;
 450                         float startcnt;
 451                         string uri;
 452
 453                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 454
 455                         // for privacy, munge the start count a little
 456                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 457                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 458                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 459                 }
 460         }
 461
 462         if(_Nex_ExtResponseSystem_PacksStep > 0)
 463         {
 464                 float n, i;
 465                 float allgood;
 466                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 467                 allgood = true;
 468                 for(i = 0; i+1 < n; i += 2)
 469                 {
 470                         if(fexists(argv(i+1)))
 471                                 continue;
 472                         allgood = false;
 473                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 474                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 475                 }
 476                 if(allgood)
 477                 {
 478                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 479                         {
 480                                 if(!Menu_Active)
 481                                         cvar_set("_menu_initialized", "0");
 482                                         // HACK: cause m_hide call on next start
 483                                 localcmd("\nmenu_restart\n");
 484                         }
 485                         _Nex_ExtResponseSystem_PacksStep = 0;
 486                 }
 487                 else
 488                         _Nex_ExtResponseSystem_PacksStep = 2;
 489         }
 490
 491 }
 492
 493 float preMenuInit()
 494 {
 495         vector sz;
 496         vector boxA, boxB;
 497
 498         updateCheck();
 499
 500         MapInfo_Cache_Create();
 501         MapInfo_Enumerate();
 502         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 503         {
 504                 draw_reset_cropped();
 505
 506                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 507                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 508
 509                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 510                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 511                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 512
 513                 boxA += sz * 0.1;
 514                 boxB -= sz * 0.1;
 515                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 516
 517                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 518                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 519
 520                 return false;
 521         }
 522         return true;
 523 }
 524
 525 string campaign_name_previous;
 526 float campaign_won_previous;
 527 #ifdef WATERMARK
 528 string autocvar_menu_watermark = WATERMARK;
 529 #else
 530 string autocvar_menu_watermark = "";
 531 #endif
 532 void postMenuDraw()
 533 {
 534         if(autocvar_menu_watermark != "")
 535         {
 536                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 537         }
 538 }
 539 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 540 .entity winnerDialog;
 541 void preMenuDraw()
 542 {
 543         vector fs, sz = '0 0 0', line, mid;
 544
 545         updateCheck();
 546
 547         if(_Nex_ExtResponseSystem_UpdateTo != "")
 548         {
 549                 // TODO rather turn this into a dialog
 550                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 551                 line = eY * fs.y;
 552                 string l1, l2;
 553                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 554                 l2 = "http://www.xonotic.org/";
 555                 if(_Nex_ExtResponseSystem_UpdateToURL)
 556                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 557
 558                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 559                                 draw_TextWidth(l1, 0, fs),
 560                                 draw_TextWidth(l2, 0, fs)
 561                         );
 562                 sz_y = 3 * fs.y;
 563
 564                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 565                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 566                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 567
 568                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 569                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 570                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 571         }
 572         if (!campaign_name_previous)
 573                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 574         if(campaign_name == campaign_name_previous)
 575         {
 576                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 577                 {
 578                         if(!campaign_won_previous)
 579                         {
 580                                 m_display();
 581                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 582                         }
 583                         campaign_won_previous = 1;
 584                 }
 585                 else
 586                         campaign_won_previous = 0;
 587         }
 588         else
 589         {
 590                 strunzone(campaign_name_previous);
 591                 campaign_name_previous = strzone(campaign_name);
 592                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 593         }
 594 }
 595
 596 string resolvemod(string m)
 597 {
 598         if(m == "=")
 599                 return getcurrentmod();
 600         else
 601                 return m;
 602 }
 603
 604 float updateCompression()
 605 {
 606         float have_dds, have_jpg, have_tga;
 607         float can_dds;
 608         have_dds = (fexists("dds/particles/particlefont.dds"));
 609         have_jpg = (fexists("particles/particlefont.jpg"));
 610         have_tga = (fexists("particles/particlefont.tga"));
 611         can_dds = GL_Have_TextureCompression();
 612         if(have_dds && (have_jpg || have_tga))
 613         {
 614                 // both? Let's only use good quality precompressed files
 615                 // but ONLY if we actually support it!
 616                 if(can_dds)
 617                 {
 618                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 619                         cvar_set("gl_texturecompression", "0");
 620                         return 1;
 621
 622                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 623                         //return 2;
 624                 }
 625                 else
 626                 {
 627                         cvar_set("gl_texturecompression", "0");
 628                         cvar_set("r_texture_dds_load", "0");
 629                         return 0;
 630                 }
 631         }
 632         else if(have_dds)
 633         {
 634                 // DDS only? We probably always want texture compression
 635                 cvar_set("gl_texturecompression", "1");
 636                 cvar_set("r_texture_dds_load", "1");
 637                 if(!can_dds)
 638                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 639                 return 0;
 640         }
 641         else
 642         {
 643                 // TGA only? Allow runtime compression
 644                 if(can_dds)
 645                 {
 646                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 647                         return 2;
 648                 }
 649                 else
 650                 {
 651                         cvar_set("gl_texturecompression", "0");
 652                         cvar_set("r_texture_dds_load", "0");
 653                         return 0;
 654                 }
 655         }
 656 }
 657
 658 // note: include only those that should be in the menu!
 659 #define GAMETYPES \
 660         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 661         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 662         GAMETYPE(MAPINFO_TYPE_CTF) \
 663         GAMETYPE(MAPINFO_TYPE_CA) \
 664         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 665         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 666         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 667         GAMETYPE(MAPINFO_TYPE_LMS) \
 668         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 669         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 670         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 671         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 672         if (cvar("developer")) GAMETYPE(MAPINFO_TYPE_RACE) \
 673         GAMETYPE(MAPINFO_TYPE_CTS) \
 674         //GAMETYPE(MAPINFO_TYPE_INVASION) \
 675         /* nothing */
 676
 677 int GameType_GetID(int cnt)
 678 {
 679         int i = 0;
 680
 681         #define GAMETYPE(id) { if (i++ == cnt) return id; }
 682         GAMETYPES
 683         #undef GAMETYPE
 684
 685         unused_float = i;
 686
 687         return 0;
 688 }
 689
 690 int GameType_GetCount()
 691 {
 692         int i = 0;
 693
 694         #define GAMETYPE(id) ++i;
 695         GAMETYPES
 696         #undef GAMETYPE
 697
 698         return i;
 699 }
 700
 701 string GameType_GetName(int cnt)
 702 {
 703         int i = GameType_GetID(cnt);
 704
 705         if(i)
 706                 return MapInfo_Type_ToText(i);
 707
 708         return "";
 709 }
 710
 711 string GameType_GetIcon(int cnt)
 712 {
 713         int i = GameType_GetID(cnt);
 714
 715         if(i)
 716                 return strcat("gametype_", MapInfo_Type_ToString(i));
 717
 718         return "";
 719 }
 720
 721 .void(entity) TR;
 722 .void(entity, float, float, entity) TD;
 723 .void(entity, float) TDempty;
 724 entity makeXonoticTextLabel(float theAlign, string theText);
 725 entity makeXonoticTextSlider(string);
 726 .void(entity, string, string) addValue;
 727 .void(entity) configureXonoticTextSliderValues;
 728 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 729 entity makeXonoticCheckBoxString(string, string, string, string);
 730 entity makeXonoticCheckBox(float, string, string);
 731 .bool sendCvars;
 732
 733 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 734 {
 735         float i;
 736         entity e;
 737
 738         me.TR(me);
 739                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 740                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 741                                 e.addValue(e, _("Default"), "");
 742                                 e.addValue(e, _("Disable"), "0");
 743                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 744                                 e.configureXonoticTextSliderValues(e);
 745         me.TR(me);
 746                 me.TDempty(me, 0.2);
 747                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 748                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 749                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 750         me.TR(me);
 751                 me.TDempty(me, 0.2);
 752                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 753         me.TR(me);
 754                 me.TDempty(me, 0.2);
 755                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 756                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 757                                 e.addValue(e, _("Default"), "");
 758                                 e.addValue(e, _("Disable"), "0");
 759                                 for(i = 1; i <= 10; ++i)
 760                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 761                                 e.configureXonoticTextSliderValues(e);
 762         me.TR(me);
 763                 me.TDempty(me, 0.2);
 764                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 765                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 766                                 e.addValue(e, _("Default"), "");
 767                                 for(i = 1; i <= 10; ++i)
 768                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 769                                 e.configureXonoticTextSliderValues(e);
 770         me.TR(me);
 771                 me.TDempty(me, 0.2);
 772                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 773                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 774                                 e.addValue(e, _("Default"), "");
 775                                 e.addValue(e, _("Disable"), "0");
 776                                 for(i = 1; i <= 10; ++i)
 777                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 778                                 e.configureXonoticTextSliderValues(e);
 779         me.TR(me);
 780                 me.TDempty(me, 0.4);
 781                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 782         me.TR(me);
 783                 me.TDempty(me, 0.2);
 784                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 785                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 786                                 e.addValue(e, _("Default"), "");
 787                                 for(i = 0; i <= 10; ++i)
 788                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 789                                 e.configureXonoticTextSliderValues(e);
 790 }
 791
 792 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 793 {
 794         if(startAlpha < targetAlpha)
 795                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 796         else
 797                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 798         return currentAlpha;
 799 }
 800
 801 void CheckSendCvars(entity me, string cvarnamestring)
 802 {
 803         if(me.sendCvars)
 804         {
 805                 LOG_INFOF("Sending cvar: %s -> %s\n", cvarnamestring, cvar_string(cvarnamestring));
 806                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 807                 {
 808                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 809                 }
 810         }
 811 }