qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "../menu.qh"
   3 #include "../oo/base.qh"
   4 #include "../../common/campaign_common.qh"
   5 #include "../../common/constants.qh"
   6 #include "../../common/mapinfo.qh"
   7 #include "../../common/util.qh"
   8 #include "../../common/command/generic.qh"
   9
  10 float GL_CheckExtension(string ext)
  11 {
  12         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
  13 }
  14
  15 float GL_Have_TextureCompression()
  16 {
  17         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  18 }
  19
  20 string getZonedTooltip(string theTooltip, string theCvar)
  21 {
  22         if(theTooltip == "")
  23         {
  24                 if(theCvar != "" && prvm_language == "en")
  25                 {
  26                         string t = cvar_description(theCvar);
  27                         if(t != "" && t != "custom cvar")
  28                                 return strzone(t);
  29                 }
  30         }
  31         else if(theTooltip != "-")
  32                 return strzone(theTooltip);
  33
  34         return string_null;
  35 }
  36
  37 .entity parent, firstChild, nextSibling;
  38 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  39 {
  40         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  41 }
  42
  43 .string cvarName;
  44 void SUB_Null_ee(entity e1, entity e2)
  45 {
  46 }
  47
  48 .void(entity) saveCvars;
  49 void saveCvarsOf(entity ignore, entity e)
  50 {
  51         if(e.saveCvars)
  52                 e.saveCvars(e);
  53 }
  54
  55 .void(entity) loadCvars;
  56 void loadCvarsOf(entity ignore, entity e)
  57 {
  58         if(e.loadCvars)
  59                 e.loadCvars(e);
  60 }
  61 void saveAllCvars(entity root)
  62 {
  63         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  64 }
  65 void loadAllCvars(entity root)
  66 {
  67         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  68 }
  69
  70 .string cvarNames_Multi;
  71 .void(entity me) saveCvars_Multi;
  72 string getCvarsMulti(entity me)
  73 {
  74         if (me.cvarNames_Multi)
  75                 return me.cvarNames_Multi;
  76         return string_null;
  77 }
  78 void saveCvarsMulti(entity me)
  79 {
  80         float n, i;
  81         string s;
  82
  83         me.saveCvars_Multi(me);
  84         s = cvar_string(me.cvarName);
  85
  86         n = tokenize_console(me.cvarNames_Multi);
  87         for(i = 0; i < n; ++i)
  88         {
  89                 if(substring(argv(i), 0, 1) == "!")
  90                         cvar_set(substring(argv(i), 1, strlen(argv(i))), ((s == "0") ? "1" : "0"));
  91                 else
  92                         cvar_set(argv(i), s);
  93
  94                 CheckSendCvars(me, argv(i));
  95         }
  96 }
  97 void makeMulti(entity e, string otherCvars)
  98 {
  99         e.cvarNames_Multi = otherCvars;
 100         e.saveCvars_Multi = e.saveCvars;
 101         e.saveCvars = saveCvarsMulti;
 102 }
 103
 104 .void(entity me) saveCvars_Callback;
 105 .entity saveCvars_Callback_ent;
 106 .void(entity me, entity cb) saveCvars_Callback_func;
 107 void saveCvarsCallback(entity me)
 108 {
 109         me.saveCvars_Callback(me);
 110         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 111 }
 112 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 113 {
 114         e.saveCvars_Callback = e.saveCvars;
 115         e.saveCvars = saveCvarsCallback;
 116         e.saveCvars_Callback_ent = cbent;
 117         e.saveCvars_Callback_func = cbfunc;
 118 }
 119
 120 .void(entity) draw_setDependent;
 121 .string cvar_setDependent;
 122 .float cvarMin_setDependent;
 123 .float cvarMax_setDependent;
 124 .string cvar2_setDependent;
 125 .float cvar2Min_setDependent;
 126 .float cvar2Max_setDependent;
 127 .string cvar3_setDependent;
 128 .float cvar3Min_setDependent;
 129 .float cvar3Max_setDependent;
 130 .float op_setDependent;
 131 .string cvarString_setDependent;
 132 .string cvarValue_setDependent;
 133 .float(entity) func_setDependent;
 134 .bool disabled;
 135 void setDependent_Check(entity e)
 136 {
 137         float f;
 138         string s;
 139         if(e.func_setDependent)
 140         {
 141                 e.disabled = !(e.func_setDependent(e));
 142         }
 143         else if(e.cvarString_setDependent)
 144         {
 145                 s = cvar_string(e.cvarString_setDependent);
 146                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 147         }
 148         else
 149         {
 150                 if(e.cvar_setDependent)
 151                 {
 152                         f = cvar(e.cvar_setDependent);
 153                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 154                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 155                         else
 156                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 157                 }
 158                 if(e.cvar2_setDependent)
 159                 {
 160                         f = cvar(e.cvar2_setDependent);
 161                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 162                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 163                         else
 164                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 165                 }
 166                 if(e.cvar3_setDependent)
 167                 {
 168                         f = cvar(e.cvar3_setDependent);
 169                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 170                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 171                         else
 172                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 173                 }
 174         }
 175 }
 176 void setDependent_Draw(entity e)
 177 {
 178         setDependent_Check(e);
 179         e.draw_setDependent(e);
 180 }
 181 .void(entity) draw;
 182 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 183 {
 184         e.draw_setDependent = e.draw;
 185         e.cvar_setDependent = theCvarName;
 186         e.cvarMin_setDependent = theCvarMin;
 187         e.cvarMax_setDependent = theCvarMax;
 188         e.cvar2_setDependent = string_null;
 189         e.cvar3_setDependent = string_null;
 190         e.func_setDependent = func_null;
 191         e.draw = setDependent_Draw;
 192         setDependent_Check(e);
 193 }
 194 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 195 {
 196         e.draw_setDependent = e.draw;
 197         e.cvarString_setDependent = theCvarName;
 198         e.cvarValue_setDependent = theCvarValue;
 199         e.cvar_setDependent = string_null;
 200         e.cvar2_setDependent = string_null;
 201         e.cvar3_setDependent = string_null;
 202         e.func_setDependent = func_null;
 203         e.draw = setDependent_Draw;
 204         setDependent_Check(e);
 205 }
 206 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 207 {
 208         e.draw_setDependent = e.draw;
 209         e.cvar_setDependent = theCvarName;
 210         e.cvarMin_setDependent = theCvarMin;
 211         e.cvarMax_setDependent = theCvarMax;
 212         e.cvar2_setDependent = theCvar2Name;
 213         e.cvar2Min_setDependent = theCvar2Min;
 214         e.cvar2Max_setDependent = theCvar2Max;
 215         e.cvar3_setDependent = string_null;
 216         e.op_setDependent = 0;
 217         e.func_setDependent = func_null;
 218         e.draw = setDependent_Draw;
 219         setDependent_Check(e);
 220 }
 221 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 222 {
 223         e.draw_setDependent = e.draw;
 224         e.cvar_setDependent = theCvarName;
 225         e.cvarMin_setDependent = theCvarMin;
 226         e.cvarMax_setDependent = theCvarMax;
 227         e.cvar2_setDependent = theCvar2Name;
 228         e.cvar2Min_setDependent = theCvar2Min;
 229         e.cvar2Max_setDependent = theCvar2Max;
 230         e.cvar3_setDependent = string_null;
 231         e.op_setDependent = 1;
 232         e.func_setDependent = func_null;
 233         e.draw = setDependent_Draw;
 234         setDependent_Check(e);
 235 }
 236 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 237 {
 238         e.draw_setDependent = e.draw;
 239         e.cvar_setDependent = theCvarName;
 240         e.cvarMin_setDependent = theCvarMin;
 241         e.cvarMax_setDependent = theCvarMax;
 242         e.cvar2_setDependent = theCvar2Name;
 243         e.cvar2Min_setDependent = theCvar2Min;
 244         e.cvar2Max_setDependent = theCvar2Max;
 245         e.cvar3_setDependent = theCvar3Name;
 246         e.cvar3Min_setDependent = theCvar3Min;
 247         e.cvar3Max_setDependent = theCvar3Max;
 248         e.op_setDependent = 0;
 249         e.func_setDependent = func_null;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253 void setDependentWeird(entity e, float(entity) func)
 254 {
 255         e.draw_setDependent = e.draw;
 256         e.func_setDependent = func;
 257         e.draw = setDependent_Draw;
 258         setDependent_Check(e);
 259 }
 260
 261 // URI SYSTEM ////////////////////////////////////////////////////////
 262
 263 float _Nex_ExtResponseSystem_Queried;
 264 string _Nex_ExtResponseSystem_UpdateTo;
 265 string _Nex_ExtResponseSystem_UpdateToURL;
 266 string _Nex_ExtResponseSystem_Packs;
 267 float _Nex_ExtResponseSystem_PacksStep;
 268
 269 void URI_Get_Callback(float id, float status, string data)
 270 {
 271         if(url_URI_Get_Callback(id, status, data))
 272         {
 273                 // handled
 274         }
 275         else if (id == URI_GET_DISCARD)
 276         {
 277                 // discard
 278         }
 279         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 280         {
 281                 // sv_cmd curl
 282                 Curl_URI_Get_Callback(id, status, data);
 283         }
 284         else if (id == URI_GET_UPDATENOTIFICATION)
 285         {
 286                 UpdateNotification_URI_Get_Callback(id, status, data);
 287         }
 288         else
 289         {
 290                 LOG_INFOF("Received HTTP request data for an invalid id %d.\n", id);
 291         }
 292 }
 293
 294 void DisableServerBackwardsCompatibility()
 295 {
 296         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 297 }
 298
 299 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 300 {
 301         float n;
 302
 303         if(_Nex_ExtResponseSystem_UpdateTo)
 304         {
 305                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before\n");
 306                 return;
 307         }
 308         if(status != 0)
 309         {
 310                 LOG_TRACEF("error receiving update notification: status is %d\n", status);
 311                 return;
 312         }
 313         if(substring(data, 0, 1) == "<")
 314         {
 315                 LOG_TRACE("error: received HTML instead of an update notification\n");
 316                 return;
 317         }
 318         if(strstrofs(data, "\r", 0) != -1)
 319         {
 320                 LOG_TRACE("error: received carriage returns from update notification server\n");
 321                 return;
 322         }
 323
 324         if(data == "")
 325                 n = 0;
 326         else
 327                 n = tokenizebyseparator(data, "\n");
 328
 329         float i;
 330         string s;
 331
 332         string un_version = "";
 333         string un_download = "";
 334         string un_url = "";
 335         string un_bannedservers = "";
 336         string un_emergency_pk3s = "";
 337         string un_promoted = "";
 338         string un_recommended = "";
 339         string un_compatexpire = "";
 340
 341         for(i = 0; i < n; ++i)
 342         {
 343                 s = substring(argv(i), 2, -1);
 344                 if(s == "") { continue; } // ignore empty lines
 345
 346                 switch(substring(argv(i), 0, 1))
 347                 {
 348                         case "V":
 349                         {
 350                                 un_version = s;
 351                                 break;
 352                         }
 353                         case "C":
 354                         {
 355                                 un_compatexpire = s;
 356                                 break;
 357                         }
 358                         case "D":
 359                         {
 360                                 un_download = s;
 361                                 break;
 362                         }
 363                         case "U":
 364                         {
 365                                 un_url = s;
 366                                 break;
 367                         }
 368                         case "B":
 369                         {
 370                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 371                                 break;
 372                         }
 373                         case "E":
 374                         {
 375                                 if(cvar("menu_updatecheck_getpacks"))
 376                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 377                                 break;
 378                         }
 379                         case "P":
 380                         {
 381                                 APPEND_TO_STRING(un_promoted, " ", s);
 382                                 break;
 383                         }
 384                         case "R":
 385                         {
 386                                 APPEND_TO_STRING(un_recommended, " ", s);
 387                                 break;
 388                         }
 389                 }
 390         }
 391
 392         if(un_version != "")
 393         {
 394                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 395                 {
 396                         // update needed
 397                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 398                         if(un_download) { LOG_INFOF(_("Update can be downloaded at:\n%s\n"), un_download); }
 399                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 400                         DisableServerBackwardsCompatibility();
 401                 }
 402                 else if(cvar_string("g_xonoticversion") == un_version)
 403                 {
 404                         if(un_compatexpire != "")
 405                         {
 406                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 407                                 if (strcmp(curdate, un_compatexpire) >= 0)
 408                                         DisableServerBackwardsCompatibility();
 409                         }
 410                 }
 411         }
 412
 413         if(un_emergency_pk3s != "")
 414         {
 415                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 416                 _Nex_ExtResponseSystem_PacksStep = 1;
 417         }
 418
 419         if(un_promoted != "")
 420         {
 421                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 422                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 423         }
 424
 425         if(un_recommended != "")
 426         {
 427                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 428                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 429         }
 430 }
 431
 432 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 433
 434 void updateCheck()
 435 {
 436         if(cvar("menu_updatecheck"))
 437         {
 438                 if(!_Nex_ExtResponseSystem_Queried)
 439                 {
 440                         _Nex_ExtResponseSystem_Queried = 1;
 441                         float startcnt;
 442                         string uri;
 443
 444                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 445
 446                         // for privacy, munge the start count a little
 447                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 448                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 449                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 450                 }
 451         }
 452
 453         if(_Nex_ExtResponseSystem_PacksStep > 0)
 454         {
 455                 float n, i;
 456                 float allgood;
 457                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 458                 allgood = true;
 459                 for(i = 0; i+1 < n; i += 2)
 460                 {
 461                         if(fexists(argv(i+1)))
 462                                 continue;
 463                         allgood = false;
 464                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 465                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 466                 }
 467                 if(allgood)
 468                 {
 469                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 470                         {
 471                                 if(!Menu_Active)
 472                                         cvar_set("_menu_initialized", "0");
 473                                         // HACK: cause m_hide call on next start
 474                                 localcmd("\nmenu_restart\n");
 475                         }
 476                         _Nex_ExtResponseSystem_PacksStep = 0;
 477                 }
 478                 else
 479                         _Nex_ExtResponseSystem_PacksStep = 2;
 480         }
 481
 482 }
 483
 484 float preMenuInit()
 485 {
 486         vector sz;
 487         vector boxA, boxB;
 488
 489         updateCheck();
 490
 491         MapInfo_Cache_Create();
 492         MapInfo_Enumerate();
 493         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 494         {
 495                 draw_reset_cropped();
 496
 497                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 498                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 499
 500                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 501                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 502                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 503
 504                 boxA += sz * 0.1;
 505                 boxB -= sz * 0.1;
 506                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 507
 508                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 509                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 510
 511                 return false;
 512         }
 513         return true;
 514 }
 515
 516 string campaign_name_previous;
 517 float campaign_won_previous;
 518 #ifdef WATERMARK
 519 string autocvar_menu_watermark = WATERMARK;
 520 #else
 521 string autocvar_menu_watermark = "";
 522 #endif
 523 void postMenuDraw()
 524 {
 525         if(autocvar_menu_watermark != "")
 526         {
 527                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 528         }
 529 }
 530 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 531 .entity winnerDialog;
 532 void preMenuDraw()
 533 {
 534         vector fs, sz = '0 0 0', line, mid;
 535
 536         updateCheck();
 537
 538         if(_Nex_ExtResponseSystem_UpdateTo != "")
 539         {
 540                 // TODO rather turn this into a dialog
 541                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 542                 line = eY * fs.y;
 543                 string l1, l2;
 544                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 545                 l2 = "http://www.xonotic.org/";
 546                 if(_Nex_ExtResponseSystem_UpdateToURL)
 547                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 548
 549                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 550                                 draw_TextWidth(l1, 0, fs),
 551                                 draw_TextWidth(l2, 0, fs)
 552                         );
 553                 sz_y = 3 * fs.y;
 554
 555                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 556                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 557                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 558
 559                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 560                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 561                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 562         }
 563         if (!campaign_name_previous)
 564                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 565         if(campaign_name == campaign_name_previous)
 566         {
 567                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 568                 {
 569                         if(!campaign_won_previous)
 570                         {
 571                                 m_display();
 572                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 573                         }
 574                         campaign_won_previous = 1;
 575                 }
 576                 else
 577                         campaign_won_previous = 0;
 578         }
 579         else
 580         {
 581                 strunzone(campaign_name_previous);
 582                 campaign_name_previous = strzone(campaign_name);
 583                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 584         }
 585 }
 586
 587 string resolvemod(string m)
 588 {
 589         if(m == "=")
 590                 return getcurrentmod();
 591         else
 592                 return m;
 593 }
 594
 595 float updateCompression()
 596 {
 597         float have_dds, have_jpg, have_tga;
 598         float can_dds;
 599         have_dds = (fexists("dds/particles/particlefont.dds"));
 600         have_jpg = (fexists("particles/particlefont.jpg"));
 601         have_tga = (fexists("particles/particlefont.tga"));
 602         can_dds = GL_Have_TextureCompression();
 603         if(have_dds && (have_jpg || have_tga))
 604         {
 605                 // both? Let's only use good quality precompressed files
 606                 // but ONLY if we actually support it!
 607                 if(can_dds)
 608                 {
 609                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 610                         cvar_set("gl_texturecompression", "0");
 611                         return 1;
 612
 613                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 614                         //return 2;
 615                 }
 616                 else
 617                 {
 618                         cvar_set("gl_texturecompression", "0");
 619                         cvar_set("r_texture_dds_load", "0");
 620                         return 0;
 621                 }
 622         }
 623         else if(have_dds)
 624         {
 625                 // DDS only? We probably always want texture compression
 626                 cvar_set("gl_texturecompression", "1");
 627                 cvar_set("r_texture_dds_load", "1");
 628                 if(!can_dds)
 629                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 630                 return 0;
 631         }
 632         else
 633         {
 634                 // TGA only? Allow runtime compression
 635                 if(can_dds)
 636                 {
 637                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 638                         return 2;
 639                 }
 640                 else
 641                 {
 642                         cvar_set("gl_texturecompression", "0");
 643                         cvar_set("r_texture_dds_load", "0");
 644                         return 0;
 645                 }
 646         }
 647 }
 648
 649 // note: include only those that should be in the menu!
 650 #define GAMETYPES \
 651         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 652         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 653         GAMETYPE(MAPINFO_TYPE_CTF) \
 654         GAMETYPE(MAPINFO_TYPE_CA) \
 655         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 656         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 657         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 658         GAMETYPE(MAPINFO_TYPE_LMS) \
 659         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 660         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 661         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 662         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 663         if (cvar("developer")) GAMETYPE(MAPINFO_TYPE_RACE) \
 664         GAMETYPE(MAPINFO_TYPE_CTS) \
 665         //GAMETYPE(MAPINFO_TYPE_INVASION) \
 666         /* nothing */
 667
 668 int GameType_GetID(int cnt)
 669 {
 670         int i = 0;
 671
 672         #define GAMETYPE(id) { if (i++ == cnt) return id; }
 673         GAMETYPES
 674         #undef GAMETYPE
 675
 676         unused_float = i;
 677
 678         return 0;
 679 }
 680
 681 int GameType_GetCount()
 682 {
 683         int i = 0;
 684
 685         #define GAMETYPE(id) ++i;
 686         GAMETYPES
 687         #undef GAMETYPE
 688
 689         return i;
 690 }
 691
 692 string GameType_GetName(int cnt)
 693 {
 694         int i = GameType_GetID(cnt);
 695
 696         if(i)
 697                 return MapInfo_Type_ToText(i);
 698
 699         return "";
 700 }
 701
 702 string GameType_GetIcon(int cnt)
 703 {
 704         int i = GameType_GetID(cnt);
 705
 706         if(i)
 707                 return strcat("gametype_", MapInfo_Type_ToString(i));
 708
 709         return "";
 710 }
 711
 712 .void(entity) TR;
 713 .void(entity, float, float, entity) TD;
 714 .void(entity, float) TDempty;
 715 entity makeXonoticTextLabel(float theAlign, string theText);
 716 entity makeXonoticTextSlider(string);
 717 .void(entity, string, string) addValue;
 718 .void(entity) configureXonoticTextSliderValues;
 719 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 720 entity makeXonoticCheckBoxString(string, string, string, string);
 721 entity makeXonoticCheckBox(float, string, string);
 722 .bool sendCvars;
 723
 724 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 725 {
 726         float i;
 727         entity e;
 728
 729         me.TR(me);
 730                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 731                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 732                                 e.addValue(e, _("Default"), "");
 733                                 e.addValue(e, _("Disable"), "0");
 734                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 735                                 e.configureXonoticTextSliderValues(e);
 736         me.TR(me);
 737                 me.TDempty(me, 0.2);
 738                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 739                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 740                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 741         me.TR(me);
 742                 me.TDempty(me, 0.2);
 743                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 744         me.TR(me);
 745                 me.TDempty(me, 0.2);
 746                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 747                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 748                                 e.addValue(e, _("Default"), "");
 749                                 e.addValue(e, _("Disable"), "0");
 750                                 for(i = 1; i <= 10; ++i)
 751                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 752                                 e.configureXonoticTextSliderValues(e);
 753         me.TR(me);
 754                 me.TDempty(me, 0.2);
 755                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 756                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 757                                 e.addValue(e, _("Default"), "");
 758                                 for(i = 1; i <= 10; ++i)
 759                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 760                                 e.configureXonoticTextSliderValues(e);
 761         me.TR(me);
 762                 me.TDempty(me, 0.2);
 763                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 764                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 765                                 e.addValue(e, _("Default"), "");
 766                                 e.addValue(e, _("Disable"), "0");
 767                                 for(i = 1; i <= 10; ++i)
 768                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 769                                 e.configureXonoticTextSliderValues(e);
 770         me.TR(me);
 771                 me.TDempty(me, 0.4);
 772                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 773         me.TR(me);
 774                 me.TDempty(me, 0.2);
 775                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 776                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 777                                 e.addValue(e, _("Default"), "");
 778                                 for(i = 0; i <= 10; ++i)
 779                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 780                                 e.configureXonoticTextSliderValues(e);
 781 }
 782
 783 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 784 {
 785         if(startAlpha < targetAlpha)
 786                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 787         else
 788                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 789         return currentAlpha;
 790 }
 791
 792 void CheckSendCvars(entity me, string cvarnamestring)
 793 {
 794         if(me.sendCvars)
 795         {
 796                 LOG_INFOF("Sending cvar: %s -> %s\n", cvarnamestring, cvar_string(cvarnamestring));
 797                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 798                 {
 799                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 800                 }
 801         }
 802 }