qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  45 void bot_setclientfields(entity this)
  46 {
  47         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  48         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  49 }
  50
  51 entity bot_spawn()
  52 {
  53         entity bot = spawnclient();
  54         if (bot)
  55         {
  56                 setItemGroupCount();
  57                 currentbots = currentbots + 1;
  58                 bot_setnameandstuff(bot);
  59                 ClientConnect(bot);
  60                 bot_setclientfields(bot);
  61                 PutClientInServer(bot);
  62         }
  63         return bot;
  64 }
  65
  66 void bot_think(entity this)
  67 {
  68         if (this.bot_nextthink > time)
  69                 return;
  70
  71         this.flags &= ~FL_GODMODE;
  72         if(autocvar_bot_god)
  73                 this.flags |= FL_GODMODE;
  74
  75         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  76
  77         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  78         {
  79                 CS(this).movement = '0 0 0';
  80                 this.bot_nextthink = time + 0.5;
  81                 return;
  82         }
  83
  84         if (this.fixangle)
  85         {
  86                 this.v_angle = this.angles;
  87                 this.v_angle_z = 0;
  88                 this.fixangle = false;
  89         }
  90
  91         this.dmg_take = 0;
  92         this.dmg_save = 0;
  93         this.dmg_inflictor = NULL;
  94
  95         // calculate an aiming latency based on the skill setting
  96         // (simulated network latency + naturally delayed reflexes)
  97         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  98         // minimum ping 20+10 random
  99         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 100         // skill 10 = ping 0.2 (adrenaline)
 101         // skill 0 = ping 0.7 (slightly drunk)
 102
 103         // clear buttons
 104         PHYS_INPUT_BUTTON_ATCK(this) = false;
 105         PHYS_INPUT_BUTTON_JUMP(this) = false;
 106         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 107         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 108         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 109         PHYS_INPUT_BUTTON_HOOK(this) = false;
 110         PHYS_INPUT_BUTTON_INFO(this) = false;
 111         PHYS_INPUT_BUTTON_DRAG(this) = false;
 112         PHYS_INPUT_BUTTON_CHAT(this) = false;
 113         PHYS_INPUT_BUTTON_USE(this) = false;
 114
 115         if (time < game_starttime)
 116         {
 117                 // block the bot during the countdown to game start
 118                 CS(this).movement = '0 0 0';
 119                 this.bot_nextthink = game_starttime;
 120                 return;
 121         }
 122
 123         // if dead, just wait until we can respawn
 124         if (IS_DEAD(this))
 125         {
 126                 CS(this).movement = '0 0 0';
 127                 if (this.deadflag == DEAD_DEAD)
 128                 {
 129                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 130                         navigation_goalrating_timeout_force(this);
 131                 }
 132         }
 133         else if(this.aistatus & AI_STATUS_STUCK)
 134                 navigation_unstuck(this);
 135
 136         // now call the current bot AI (havocbot for example)
 137         this.bot_ai(this);
 138 }
 139
 140 void bot_setnameandstuff(entity this)
 141 {
 142         string readfile, s;
 143         float file, tokens, prio;
 144
 145         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 146         string name, prefix, suffix;
 147
 148         if(autocvar_g_campaign)
 149         {
 150                 prefix = "";
 151                 suffix = "";
 152         }
 153         else
 154         {
 155                 prefix = autocvar_bot_prefix;
 156                 suffix = autocvar_bot_suffix;
 157         }
 158
 159         file = fopen(autocvar_bot_config_file, FILE_READ);
 160
 161         if(file < 0)
 162         {
 163                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 164                 readfile = "";
 165         }
 166         else
 167         {
 168                 RandomSelection_Init();
 169                 while((readfile = fgets(file)))
 170                 {
 171                         if(substring(readfile, 0, 2) == "//")
 172                                 continue;
 173                         if(substring(readfile, 0, 1) == "#")
 174                                 continue;
 175                         tokens = tokenizebyseparator(readfile, "\t");
 176                         if(tokens == 0)
 177                                 continue;
 178                         s = argv(0);
 179                         prio = 1;
 180                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 181                                 if(s == it.cleanname)
 182                                 {
 183                                         prio = 0;
 184                                         break;
 185                                 }
 186                         });
 187                         RandomSelection_AddString(readfile, 1, prio);
 188                 }
 189                 readfile = RandomSelection_chosen_string;
 190                 fclose(file);
 191         }
 192
 193         tokens = tokenizebyseparator(readfile, "\t");
 194         if(argv(0) != "") bot_name = argv(0);
 195         else bot_name = "Bot";
 196
 197         if(argv(1) != "") bot_model = argv(1);
 198         else bot_model = "";
 199
 200         if(argv(2) != "") bot_skin = argv(2);
 201         else bot_skin = "0";
 202
 203         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 204         else bot_shirt = ftos(floor(random() * 15));
 205
 206         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 207         else bot_pants = ftos(floor(random() * 15));
 208
 209         this.bot_forced_team = stof(argv(5));
 210
 211         prio = 6;
 212
 213         #define READSKILL(f, w, r) MACRO_BEGIN { \
 214                 if(argv(prio) != "") \
 215                         this.f = stof(argv(prio)) * w; \
 216                 else \
 217                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 218                 prio++; \
 219         } MACRO_END
 220         //print(bot_name, ": ping=", argv(9), "\n");
 221
 222         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 223         READSKILL(bot_moveskill, 2, 0); // move skill
 224         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 225
 226         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 227
 228         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 229         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 230         READSKILL(bot_rangepreference, 1, 0); // read skill
 231
 232         READSKILL(bot_aimskill, 2, 0); // aim skill
 233         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 234         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 235
 236         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 237         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 238
 239         this.bot_config_loaded = true;
 240
 241         // this is really only a default, TeamBalance_JoinBestTeam is called later
 242         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 243         this.bot_preferredcolors = this.clientcolors;
 244
 245         // pick the name
 246         if (autocvar_bot_usemodelnames)
 247                 name = bot_model;
 248         else
 249                 name = bot_name;
 250
 251         // number bots with identical names
 252         if (name == "")
 253         {
 254                 name = ftos(etof(this));
 255                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 256         }
 257         else
 258         {
 259                 int j = 0;
 260                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 261                         if(it.cleanname == name)
 262                                 ++j;
 263                 });
 264                 if (j)
 265                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 266                 else
 267                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 268         }
 269         this.cleanname = strzone(name);
 270
 271         // pick the model and skin
 272         if(substring(bot_model, -4, 1) != ".")
 273                 bot_model = strcat(bot_model, ".iqm");
 274         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 275         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 276 }
 277
 278 void bot_custom_weapon_priority_setup()
 279 {
 280         float tokens, i, w;
 281
 282         bot_custom_weapon = false;
 283
 284         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 285                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 286                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 287                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 288         )
 289                 return;
 290
 291         // Parse distances
 292         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 293
 294         if (tokens!=2)
 295                 return;
 296
 297         bot_distance_far = stof(argv(0));
 298         bot_distance_close = stof(argv(1));
 299
 300         if(bot_distance_far < bot_distance_close){
 301                 bot_distance_far = stof(argv(1));
 302                 bot_distance_close = stof(argv(0));
 303         }
 304
 305         // Initialize list of weapons
 306         bot_weapons_far[0] = -1;
 307         bot_weapons_mid[0] = -1;
 308         bot_weapons_close[0] = -1;
 309
 310         // Parse far distance weapon priorities
 311         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 312
 313         int c = 0;
 314         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 315                 w = stof(argv(i));
 316                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 317                         bot_weapons_far[c] = w;
 318                         ++c;
 319                 }
 320         }
 321         if(c < Weapons_COUNT)
 322                 bot_weapons_far[c] = -1;
 323
 324         // Parse mid distance weapon priorities
 325         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 326
 327         c = 0;
 328         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 329                 w = stof(argv(i));
 330                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 331                         bot_weapons_mid[c] = w;
 332                         ++c;
 333                 }
 334         }
 335         if(c < Weapons_COUNT)
 336                 bot_weapons_mid[c] = -1;
 337
 338         // Parse close distance weapon priorities
 339         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 340
 341         c = 0;
 342         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 343                 w = stof(argv(i));
 344                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 345                         bot_weapons_close[c] = w;
 346                         ++c;
 347                 }
 348         }
 349         if(c < Weapons_COUNT)
 350                 bot_weapons_close[c] = -1;
 351
 352         bot_custom_weapon = true;
 353 }
 354
 355 void bot_endgame()
 356 {
 357         bot_relinkplayerlist();
 358         entity e = bot_list;
 359         while (e)
 360         {
 361                 setcolor(e, e.bot_preferredcolors);
 362                 e = e.nextbot;
 363         }
 364         // if dynamic waypoints are ever implemented, save them here
 365 }
 366
 367 void bot_relinkplayerlist()
 368 {
 369         player_count = 0;
 370         currentbots = 0;
 371         bot_list = NULL;
 372
 373         entity prevbot = NULL;
 374         FOREACH_CLIENT(true,
 375         {
 376                 ++player_count;
 377
 378                 if(IS_BOT_CLIENT(it))
 379                 {
 380                         if(prevbot)
 381                                 prevbot.nextbot = it;
 382                         else
 383                                 bot_list = it;
 384                         prevbot = it;
 385                         ++currentbots;
 386                 }
 387         });
 388         if(prevbot)
 389                 prevbot.nextbot = NULL;
 390         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 391         bot_strategytoken = bot_list;
 392         bot_strategytoken_taken = true;
 393 }
 394
 395 void bot_clientdisconnect(entity this)
 396 {
 397         if (!IS_BOT_CLIENT(this))
 398                 return;
 399         bot_clearqueue(this);
 400         strfree(this.cleanname);
 401         strfree(this.netname_freeme);
 402         strfree(this.playermodel_freeme);
 403         strfree(this.playerskin_freeme);
 404         if(this.bot_cmd_current)
 405                 delete(this.bot_cmd_current);
 406         if(bot_waypoint_queue_owner == this)
 407                 bot_waypoint_queue_owner = NULL;
 408 }
 409
 410 void bot_clientconnect(entity this)
 411 {
 412         if (!IS_BOT_CLIENT(this)) return;
 413         this.bot_preferredcolors = this.clientcolors;
 414         this.bot_nextthink = time - random();
 415         this.lag_func = bot_lagfunc;
 416         this.isbot = true;
 417         this.createdtime = this.bot_nextthink;
 418
 419         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 420         {
 421                 bot_setnameandstuff(this);
 422                 bot_setclientfields(this);
 423         }
 424
 425         if(this.bot_forced_team==1)
 426                 this.team = NUM_TEAM_1;
 427         else if(this.bot_forced_team==2)
 428                 this.team = NUM_TEAM_2;
 429         else if(this.bot_forced_team==3)
 430                 this.team = NUM_TEAM_3;
 431         else if(this.bot_forced_team==4)
 432                 this.team = NUM_TEAM_4;
 433         else
 434                 TeamBalance_JoinBestTeam(this);
 435
 436         havocbot_setupbot(this);
 437 }
 438
 439 void bot_removefromlargestteam()
 440 {
 441         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 442         TeamBalance_GetTeamCounts(balance, NULL);
 443
 444         entity best = NULL;
 445         float besttime = 0;
 446         int bestcount = 0;
 447
 448         int bcount = 0;
 449         FOREACH_CLIENT(it.isbot,
 450         {
 451                 ++bcount;
 452
 453                 if(!best)
 454                 {
 455                         best = it;
 456                         besttime = it.createdtime;
 457                 }
 458
 459                 int thiscount = 0;
 460
 461                 if (Team_IsValidTeam(it.team))
 462                 {
 463                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 464                                 Team_TeamToIndex(it.team));
 465                 }
 466
 467                 if(thiscount > bestcount)
 468                 {
 469                         bestcount = thiscount;
 470                         besttime = it.createdtime;
 471                         best = it;
 472                 }
 473                 else if(thiscount == bestcount && besttime < it.createdtime)
 474                 {
 475                         besttime = it.createdtime;
 476                         best = it;
 477                 }
 478         });
 479         TeamBalance_Destroy(balance);
 480         if(!bcount)
 481                 return; // no bots to remove
 482         currentbots = currentbots - 1;
 483         dropclient(best);
 484 }
 485
 486 void bot_removenewest()
 487 {
 488         if(teamplay)
 489         {
 490                 bot_removefromlargestteam();
 491                 return;
 492         }
 493
 494         float besttime = 0;
 495         entity best = NULL;
 496         int bcount = 0;
 497
 498         FOREACH_CLIENT(it.isbot,
 499         {
 500                 ++bcount;
 501
 502                 if(!best)
 503                 {
 504                         best = it;
 505                         besttime = it.createdtime;
 506                 }
 507
 508                 if(besttime < it.createdtime)
 509                 {
 510                         besttime = it.createdtime;
 511                         best = it;
 512                 }
 513         });
 514
 515         if(!bcount)
 516                 return; // no bots to remove
 517
 518         currentbots = currentbots - 1;
 519         dropclient(best);
 520 }
 521
 522 void autoskill(float factor)
 523 {
 524         float bestbot;
 525         float bestplayer;
 526
 527         bestbot = -1;
 528         bestplayer = -1;
 529         FOREACH_CLIENT(IS_PLAYER(it), {
 530                 if(IS_REAL_CLIENT(it))
 531                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 532                 else
 533                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 534         });
 535
 536         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 537         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 538         if(bestbot < 0 || bestplayer < 0)
 539         {
 540                 LOG_DEBUG("not doing anything");
 541                 // don't return, let it reset all counters below
 542         }
 543         else if(bestbot <= bestplayer * factor - 2)
 544         {
 545                 if(autocvar_skill < 17)
 546                 {
 547                         LOG_DEBUG("2 frags difference, increasing skill");
 548                         cvar_set("skill", ftos(autocvar_skill + 1));
 549                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 550                 }
 551         }
 552         else if(bestbot >= bestplayer * factor + 2)
 553         {
 554                 if(autocvar_skill > 0)
 555                 {
 556                         LOG_DEBUG("2 frags difference, decreasing skill");
 557                         cvar_set("skill", ftos(autocvar_skill - 1));
 558                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 559                 }
 560         }
 561         else
 562         {
 563                 LOG_DEBUG("not doing anything");
 564                 return;
 565                 // don't reset counters, wait for them to accumulate
 566         }
 567
 568         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 569 }
 570
 571 void bot_calculate_stepheightvec()
 572 {
 573         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 574         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 575         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 576 }
 577
 578 float bot_fixcount()
 579 {
 580         int activerealplayers = 0;
 581         int realplayers = 0;
 582         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 583                 activerealplayers = M_ARGV(0, int);
 584                 realplayers = M_ARGV(1, int);
 585         } else {
 586                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 587                         if(IS_PLAYER(it))
 588                                 ++activerealplayers;
 589                         ++realplayers;
 590                 });
 591         }
 592
 593         int bots;
 594         // add/remove bots if needed to make sure there are at least
 595         // minplayers+bot_number, or remove all bots if no one is playing
 596         // But don't remove bots immediately on level change, as the real players
 597         // usually haven't rejoined yet
 598         bots_would_leave = false;
 599         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 600                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 601         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 602         {
 603                 float realminplayers, minplayers;
 604                 realminplayers = autocvar_minplayers;
 605                 minplayers = max(0, floor(realminplayers));
 606
 607                 float realminbots, minbots;
 608                 realminbots = autocvar_bot_number;
 609                 minbots = max(0, floor(realminbots));
 610
 611                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 612                 if(bots > minbots)
 613                         bots_would_leave = true;
 614         }
 615         else
 616         {
 617                 // if there are no players, remove bots
 618                 bots = 0;
 619         }
 620
 621         // only add one bot per frame to avoid utter chaos
 622         if(time > botframe_nextthink)
 623         {
 624                 if (currentbots < bots)
 625                 {
 626                         if (bot_spawn() == NULL)
 627                         {
 628                                 bprint("Can not add bot, server full.\n");
 629                                 return false;
 630                         }
 631                 }
 632                 while (currentbots > bots)
 633                         bot_removenewest();
 634         }
 635
 636         return true;
 637 }
 638
 639 void bot_remove_from_bot_list(entity this)
 640 {
 641         entity e = bot_list;
 642         entity prev_bot = NULL;
 643         while (e)
 644         {
 645                 if(e == this)
 646                 {
 647                         if(!prev_bot)
 648                                 bot_list = this.nextbot;
 649                         else
 650                                 prev_bot.nextbot = this.nextbot;
 651                         if(bot_strategytoken == this)
 652                         {
 653                                 bot_strategytoken = this.nextbot;
 654                                 bot_strategytoken_taken = true;
 655                         }
 656                         this.nextbot = NULL;
 657                         break;
 658                 }
 659                 prev_bot = e;
 660                 e = e.nextbot;
 661         }
 662 }
 663
 664 void bot_clear(entity this)
 665 {
 666         bot_remove_from_bot_list(this);
 667         if(bot_waypoint_queue_owner == this)
 668                 bot_waypoint_queue_owner = NULL;
 669         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 670 }
 671
 672 void bot_serverframe()
 673 {
 674         if (intermission_running && currentbots > 0)
 675         {
 676                 // after the end of the match all bots stay unless all human players disconnect
 677                 int realplayers = 0;
 678                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 679                 if (!realplayers)
 680                 {
 681                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 682                         currentbots = 0;
 683                 }
 684                 return;
 685         }
 686
 687         if (game_stopped)
 688                 return;
 689
 690         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 691         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 692         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 693         // either intentionally or automatically (sv_spectate 0)
 694         if (time < 2.5)
 695         {
 696                 currentbots = -1;
 697                 return;
 698         }
 699
 700         if (currentbots == -1)
 701         {
 702                 // count bots already in the server from the previous match
 703                 currentbots = 0;
 704                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 705         }
 706
 707         if(autocvar_skill != skill)
 708         {
 709                 float wpcost_update = false;
 710                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 711                         wpcost_update = true;
 712                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 713                         wpcost_update = true;
 714
 715                 skill = autocvar_skill;
 716                 if (wpcost_update)
 717                         waypoint_updatecost_foralllinks();
 718         }
 719
 720         bot_calculate_stepheightvec();
 721         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 722
 723         if(time > autoskill_nextthink)
 724         {
 725                 float a;
 726                 a = autocvar_skill_auto;
 727                 if(a)
 728                         autoskill(a);
 729                 autoskill_nextthink = time + 5;
 730         }
 731
 732         if(time > botframe_nextthink)
 733         {
 734                 if(!bot_fixcount())
 735                         botframe_nextthink = time + 10;
 736         }
 737
 738         if(botframe_spawnedwaypoints)
 739         {
 740                 if(autocvar_waypoint_benchmark)
 741                         localcmd("quit\n");
 742         }
 743
 744         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 745         if (botframe_spawnedwaypoints)
 746         {
 747                 if(botframe_cachedwaypointlinks)
 748                 {
 749                         if(!botframe_loadedforcedlinks)
 750                                 waypoint_load_links_hardwired();
 751                 }
 752                 else
 753                 {
 754                         // TODO: Make this check cleaner
 755                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 756                         {
 757                                 waypoint_save_links();
 758                                 break;
 759                         });
 760                 }
 761         }
 762         else
 763         {
 764                 botframe_spawnedwaypoints = true;
 765                 waypoint_loadall();
 766                 waypoint_load_links();
 767         }
 768
 769         if (bot_list)
 770         {
 771                 // cycle the goal token from one bot to the next each frame
 772                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 773                 //  frame, which causes choppy framerates)
 774                 if (bot_strategytoken_taken)
 775                 {
 776                         // give goal token to the first bot without goals; if all bots don't have
 777                         // any goal (or are dead/frozen) simply give it to the next one
 778                         bot_strategytoken_taken = false;
 779                         entity bot_strategytoken_save = bot_strategytoken;
 780                         while (true)
 781                         {
 782                                 if (bot_strategytoken)
 783                                         bot_strategytoken = bot_strategytoken.nextbot;
 784                                 if (!bot_strategytoken)
 785                                         bot_strategytoken = bot_list;
 786
 787                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 788                                         && !bot_strategytoken.goalcurrent)
 789                                         break;
 790
 791                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 792                                         break;
 793                                 if (bot_strategytoken == bot_strategytoken_save)
 794                                         bot_strategytoken_save = NULL; // looped through all the bots
 795                         }
 796                 }
 797
 798                 if (botframe_nextdangertime < time)
 799                 {
 800                         float interval;
 801                         interval = autocvar_bot_ai_dangerdetectioninterval;
 802                         if (botframe_nextdangertime < time - interval * 1.5)
 803                                 botframe_nextdangertime = time;
 804                         botframe_nextdangertime = botframe_nextdangertime + interval;
 805                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 806                 }
 807         }
 808
 809         if (autocvar_g_waypointeditor)
 810                 botframe_showwaypointlinks();
 811
 812         if (autocvar_g_waypointeditor_auto)
 813                 botframe_autowaypoints();
 814
 815         if(time > bot_cvar_nextthink)
 816         {
 817                 if(currentbots>0)
 818                         bot_custom_weapon_priority_setup();
 819                 bot_cvar_nextthink = time + 5;
 820         }
 821 }