qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  45
  46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  47 void bot_setclientfields(entity this)
  48 {
  49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  51 }
  52
  53 entity bot_spawn()
  54 {
  55         entity bot = spawnclient();
  56         if (bot)
  57         {
  58                 setItemGroupCount();
  59                 currentbots = currentbots + 1;
  60                 bot_setnameandstuff(bot);
  61                 ClientConnect(bot);
  62                 bot_setclientfields(bot);
  63                 PutClientInServer(bot);
  64         }
  65         return bot;
  66 }
  67
  68 void bot_think(entity this)
  69 {
  70         if (this.bot_nextthink > time)
  71                 return;
  72
  73         this.flags &= ~FL_GODMODE;
  74         if(autocvar_bot_god)
  75                 this.flags |= FL_GODMODE;
  76
  77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  78
  79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  80         {
  81                 CS(this).movement = '0 0 0';
  82                 this.bot_nextthink = time + 0.5;
  83                 return;
  84         }
  85
  86         if (this.fixangle)
  87         {
  88                 this.v_angle = this.angles;
  89                 this.v_angle_z = 0;
  90                 this.fixangle = false;
  91         }
  92
  93         this.dmg_take = 0;
  94         this.dmg_save = 0;
  95         this.dmg_inflictor = NULL;
  96
  97         // calculate an aiming latency based on the skill setting
  98         // (simulated network latency + naturally delayed reflexes)
  99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 100         // minimum ping 20+10 random
 101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 102         // skill 10 = ping 0.2 (adrenaline)
 103         // skill 0 = ping 0.7 (slightly drunk)
 104
 105         // clear buttons
 106         PHYS_INPUT_BUTTON_ATCK(this) = false;
 107         PHYS_INPUT_BUTTON_JUMP(this) = false;
 108         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 109         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 110         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 111         PHYS_INPUT_BUTTON_HOOK(this) = false;
 112         PHYS_INPUT_BUTTON_INFO(this) = false;
 113         PHYS_INPUT_BUTTON_DRAG(this) = false;
 114         PHYS_INPUT_BUTTON_CHAT(this) = false;
 115         PHYS_INPUT_BUTTON_USE(this) = false;
 116
 117         if (time < game_starttime)
 118         {
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (this.deadflag == DEAD_DEAD)
 133                 {
 134                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 135                         navigation_goalrating_timeout_force(this);
 136                 }
 137         }
 138         else if(this.aistatus & AI_STATUS_STUCK)
 139                 navigation_unstuck(this);
 140
 141         // now call the current bot AI (havocbot for example)
 142         this.bot_ai(this);
 143 }
 144
 145 void bot_setnameandstuff(entity this)
 146 {
 147         string readfile, s;
 148         float file, tokens, prio;
 149
 150         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 151         string name, prefix, suffix;
 152
 153         if(autocvar_g_campaign)
 154         {
 155                 prefix = "";
 156                 suffix = "";
 157         }
 158         else
 159         {
 160                 prefix = autocvar_bot_prefix;
 161                 suffix = autocvar_bot_suffix;
 162         }
 163
 164         file = fopen(autocvar_bot_config_file, FILE_READ);
 165
 166         if(file < 0)
 167         {
 168                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 169                 readfile = "";
 170         }
 171         else
 172         {
 173                 RandomSelection_Init();
 174                 while((readfile = fgets(file)))
 175                 {
 176                         if(substring(readfile, 0, 2) == "//")
 177                                 continue;
 178                         if(substring(readfile, 0, 1) == "#")
 179                                 continue;
 180                         tokens = tokenizebyseparator(readfile, "\t");
 181                         if(tokens == 0)
 182                                 continue;
 183                         s = argv(0);
 184                         prio = 1;
 185                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 186                                 if(s == it.cleanname)
 187                                 {
 188                                         prio = 0;
 189                                         break;
 190                                 }
 191                         });
 192                         RandomSelection_AddString(readfile, 1, prio);
 193                 }
 194                 readfile = RandomSelection_chosen_string;
 195                 fclose(file);
 196         }
 197
 198         tokens = tokenizebyseparator(readfile, "\t");
 199         if(argv(0) != "") bot_name = argv(0);
 200         else bot_name = "Bot";
 201
 202         if(argv(1) != "") bot_model = argv(1);
 203         else bot_model = "";
 204
 205         if(argv(2) != "") bot_skin = argv(2);
 206         else bot_skin = "0";
 207
 208         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 209         else bot_shirt = ftos(floor(random() * 15));
 210
 211         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 212         else bot_pants = ftos(floor(random() * 15));
 213
 214         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 215                 this.bot_forced_team = 0;
 216         else
 217                 this.bot_forced_team = stof(argv(5));
 218
 219         prio = 6;
 220
 221         #define READSKILL(f, w, r) MACRO_BEGIN \
 222                 if(argv(prio) != "") \
 223                         this.f = stof(argv(prio)) * w; \
 224                 else \
 225                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 226                 prio++; \
 227         MACRO_END
 228         //print(bot_name, ": ping=", argv(9), "\n");
 229
 230         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 231         READSKILL(bot_moveskill, 2, 0); // move skill
 232         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 233
 234         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 235
 236         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 237         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 238         READSKILL(bot_rangepreference, 1, 0); // read skill
 239
 240         READSKILL(bot_aimskill, 2, 0); // aim skill
 241         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 242         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 243
 244         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 245         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 246
 247         if (file >= 0 && argv(prio) != "")
 248                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 249
 250         this.bot_config_loaded = true;
 251
 252         // this is really only a default, TeamBalance_JoinBestTeam is called later
 253         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 254         this.bot_preferredcolors = this.clientcolors;
 255
 256         // pick the name
 257         if (autocvar_bot_usemodelnames)
 258                 name = bot_model;
 259         else
 260                 name = bot_name;
 261
 262         // number bots with identical names
 263         if (name == "")
 264         {
 265                 name = ftos(etof(this));
 266                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 267         }
 268         else
 269         {
 270                 int j = 0;
 271                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 272                         if(it.cleanname == name)
 273                                 ++j;
 274                 });
 275                 if (j)
 276                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 277                 else
 278                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 279         }
 280         this.cleanname = strzone(name);
 281
 282         // pick the model and skin
 283         if(substring(bot_model, -4, 1) != ".")
 284                 bot_model = strcat(bot_model, ".iqm");
 285         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 286         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 287 }
 288
 289 void bot_custom_weapon_priority_setup()
 290 {
 291         float tokens, i, w;
 292
 293         bot_custom_weapon = false;
 294
 295         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 296                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 297                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 298                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 299         )
 300                 return;
 301
 302         // Parse distances
 303         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 304
 305         if (tokens!=2)
 306                 return;
 307
 308         bot_distance_far = stof(argv(0));
 309         bot_distance_close = stof(argv(1));
 310
 311         if(bot_distance_far < bot_distance_close){
 312                 bot_distance_far = stof(argv(1));
 313                 bot_distance_close = stof(argv(0));
 314         }
 315
 316         // Initialize list of weapons
 317         bot_weapons_far[0] = -1;
 318         bot_weapons_mid[0] = -1;
 319         bot_weapons_close[0] = -1;
 320
 321         // Parse far distance weapon priorities
 322         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 323
 324         int c = 0;
 325         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 326                 w = stof(argv(i));
 327                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 328                         bot_weapons_far[c] = w;
 329                         ++c;
 330                 }
 331         }
 332         if(c < Weapons_COUNT)
 333                 bot_weapons_far[c] = -1;
 334
 335         // Parse mid distance weapon priorities
 336         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 337
 338         c = 0;
 339         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 340                 w = stof(argv(i));
 341                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 342                         bot_weapons_mid[c] = w;
 343                         ++c;
 344                 }
 345         }
 346         if(c < Weapons_COUNT)
 347                 bot_weapons_mid[c] = -1;
 348
 349         // Parse close distance weapon priorities
 350         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 351
 352         c = 0;
 353         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 354                 w = stof(argv(i));
 355                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 356                         bot_weapons_close[c] = w;
 357                         ++c;
 358                 }
 359         }
 360         if(c < Weapons_COUNT)
 361                 bot_weapons_close[c] = -1;
 362
 363         bot_custom_weapon = true;
 364 }
 365
 366 void bot_endgame()
 367 {
 368         bot_relinkplayerlist();
 369         entity e = bot_list;
 370         while (e)
 371         {
 372                 setcolor(e, e.bot_preferredcolors);
 373                 e = e.nextbot;
 374         }
 375         // if dynamic waypoints are ever implemented, save them here
 376 }
 377
 378 void bot_relinkplayerlist()
 379 {
 380         player_count = 0;
 381         currentbots = 0;
 382         bot_list = NULL;
 383
 384         entity prevbot = NULL;
 385         FOREACH_CLIENT(true,
 386         {
 387                 ++player_count;
 388
 389                 if(IS_BOT_CLIENT(it))
 390                 {
 391                         if(prevbot)
 392                                 prevbot.nextbot = it;
 393                         else
 394                                 bot_list = it;
 395                         prevbot = it;
 396                         ++currentbots;
 397                 }
 398         });
 399         if(prevbot)
 400                 prevbot.nextbot = NULL;
 401         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 402         bot_strategytoken = bot_list;
 403         bot_strategytoken_taken = true;
 404 }
 405
 406 void bot_clientdisconnect(entity this)
 407 {
 408         if (!IS_BOT_CLIENT(this))
 409                 return;
 410         bot_clearqueue(this);
 411         strfree(this.cleanname);
 412         strfree(this.netname_freeme);
 413         strfree(this.playermodel_freeme);
 414         strfree(this.playerskin_freeme);
 415         if(this.bot_cmd_current)
 416                 delete(this.bot_cmd_current);
 417         if(bot_waypoint_queue_owner == this)
 418                 bot_waypoint_queue_owner = NULL;
 419 }
 420
 421 void bot_clientconnect(entity this)
 422 {
 423         if (!IS_BOT_CLIENT(this)) return;
 424         this.bot_preferredcolors = this.clientcolors;
 425         this.bot_nextthink = time - random();
 426         this.lag_func = bot_lagfunc;
 427         this.isbot = true;
 428         this.createdtime = this.bot_nextthink;
 429
 430         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 431         {
 432                 bot_setnameandstuff(this);
 433                 bot_setclientfields(this);
 434         }
 435
 436         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 437         {
 438                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 439         }
 440         else
 441         {
 442                 this.bot_forced_team = 0;
 443                 TeamBalance_JoinBestTeam(this);
 444         }
 445
 446         havocbot_setupbot(this);
 447 }
 448
 449 void bot_removefromlargestteam()
 450 {
 451         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 452         TeamBalance_GetTeamCounts(balance, NULL);
 453
 454         entity best = NULL;
 455         float besttime = 0;
 456         int bestcount = 0;
 457
 458         int bcount = 0;
 459         FOREACH_CLIENT(it.isbot,
 460         {
 461                 ++bcount;
 462
 463                 if(!best)
 464                 {
 465                         best = it;
 466                         besttime = it.createdtime;
 467                 }
 468
 469                 int thiscount = 0;
 470
 471                 if (Team_IsValidTeam(it.team))
 472                 {
 473                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 474                                 Team_TeamToIndex(it.team));
 475                 }
 476
 477                 if(thiscount > bestcount)
 478                 {
 479                         bestcount = thiscount;
 480                         besttime = it.createdtime;
 481                         best = it;
 482                 }
 483                 else if(thiscount == bestcount && besttime < it.createdtime)
 484                 {
 485                         besttime = it.createdtime;
 486                         best = it;
 487                 }
 488         });
 489         TeamBalance_Destroy(balance);
 490         if(!bcount)
 491                 return; // no bots to remove
 492         currentbots = currentbots - 1;
 493         dropclient(best);
 494 }
 495
 496 void bot_removenewest()
 497 {
 498         if(teamplay)
 499         {
 500                 bot_removefromlargestteam();
 501                 return;
 502         }
 503
 504         float besttime = 0;
 505         entity best = NULL;
 506         int bcount = 0;
 507
 508         FOREACH_CLIENT(it.isbot,
 509         {
 510                 ++bcount;
 511
 512                 if(!best)
 513                 {
 514                         best = it;
 515                         besttime = it.createdtime;
 516                 }
 517
 518                 if(besttime < it.createdtime)
 519                 {
 520                         besttime = it.createdtime;
 521                         best = it;
 522                 }
 523         });
 524
 525         if(!bcount)
 526                 return; // no bots to remove
 527
 528         currentbots = currentbots - 1;
 529         dropclient(best);
 530 }
 531
 532 void autoskill(float factor)
 533 {
 534         float bestbot;
 535         float bestplayer;
 536
 537         bestbot = -1;
 538         bestplayer = -1;
 539         FOREACH_CLIENT(IS_PLAYER(it), {
 540                 if(IS_REAL_CLIENT(it))
 541                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 542                 else
 543                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 544         });
 545
 546         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 547         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 548         if(bestbot < 0 || bestplayer < 0)
 549         {
 550                 LOG_DEBUG("not doing anything");
 551                 // don't return, let it reset all counters below
 552         }
 553         else if(bestbot <= bestplayer * factor - 2)
 554         {
 555                 if(autocvar_skill < 17)
 556                 {
 557                         LOG_DEBUG("2 frags difference, increasing skill");
 558                         cvar_set("skill", ftos(autocvar_skill + 1));
 559                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 560                 }
 561         }
 562         else if(bestbot >= bestplayer * factor + 2)
 563         {
 564                 if(autocvar_skill > 0)
 565                 {
 566                         LOG_DEBUG("2 frags difference, decreasing skill");
 567                         cvar_set("skill", ftos(autocvar_skill - 1));
 568                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 569                 }
 570         }
 571         else
 572         {
 573                 LOG_DEBUG("not doing anything");
 574                 return;
 575                 // don't reset counters, wait for them to accumulate
 576         }
 577
 578         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 579 }
 580
 581 void bot_calculate_stepheightvec()
 582 {
 583         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 584         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 585         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 586         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 587 }
 588
 589 bool bot_fixcount()
 590 {
 591         int activerealplayers = 0;
 592         int realplayers = 0;
 593         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 594                 activerealplayers = M_ARGV(0, int);
 595                 realplayers = M_ARGV(1, int);
 596         } else {
 597                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 598                         if(IS_PLAYER(it))
 599                                 ++activerealplayers;
 600                         ++realplayers;
 601                 });
 602         }
 603
 604         int bots;
 605         // But don't remove bots immediately on level change, as the real players
 606         // usually haven't rejoined yet
 607         bots_would_leave = false;
 608         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 609                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 610         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 611         {
 612                 int minplayers = max(0, floor(autocvar_minplayers));
 613                 if (teamplay)
 614                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 615                 int minbots = max(0, floor(autocvar_bot_number));
 616
 617                 // add bots to reach minplayers if needed
 618                 bots = max(minbots, minplayers - activerealplayers);
 619                 // cap bots to the max players allowed by the server
 620                 int player_limit = GetPlayerLimit();
 621                 if(player_limit)
 622                         bots = min(bots, max(player_limit - activerealplayers, 0));
 623                 bots = min(bots, maxclients - realplayers);
 624
 625                 if(bots > minbots)
 626                         bots_would_leave = true;
 627         }
 628         else
 629         {
 630                 // if there are no players, remove bots
 631                 bots = 0;
 632         }
 633
 634         // only add one bot per frame to avoid utter chaos
 635         if(time > botframe_nextthink)
 636         {
 637                 if (currentbots < bots)
 638                 {
 639                         if (bot_spawn() == NULL)
 640                         {
 641                                 bprint("Can not add bot, server full.\n");
 642                                 return false;
 643                         }
 644                 }
 645                 while (currentbots > bots && bots >= 0)
 646                         bot_removenewest();
 647         }
 648
 649         return true;
 650 }
 651
 652 void bot_remove_from_bot_list(entity this)
 653 {
 654         entity e = bot_list;
 655         entity prev_bot = NULL;
 656         while (e)
 657         {
 658                 if(e == this)
 659                 {
 660                         if(!prev_bot)
 661                                 bot_list = this.nextbot;
 662                         else
 663                                 prev_bot.nextbot = this.nextbot;
 664                         if(bot_strategytoken == this)
 665                         {
 666                                 bot_strategytoken = this.nextbot;
 667                                 bot_strategytoken_taken = true;
 668                         }
 669                         this.nextbot = NULL;
 670                         break;
 671                 }
 672                 prev_bot = e;
 673                 e = e.nextbot;
 674         }
 675 }
 676
 677 void bot_clear(entity this)
 678 {
 679         bot_remove_from_bot_list(this);
 680         if(bot_waypoint_queue_owner == this)
 681                 bot_waypoint_queue_owner = NULL;
 682         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 683 }
 684
 685 void bot_serverframe()
 686 {
 687         if (intermission_running && currentbots > 0)
 688         {
 689                 // after the end of the match all bots stay unless all human players disconnect
 690                 int realplayers = 0;
 691                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 692                 if (!realplayers)
 693                 {
 694                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 695                         currentbots = 0;
 696                 }
 697                 return;
 698         }
 699
 700         if (game_stopped)
 701                 return;
 702
 703         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 704         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 705         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 706         // either intentionally or automatically (sv_spectate 0)
 707         if (time < 2.5)
 708         {
 709                 currentbots = -1;
 710                 return;
 711         }
 712
 713         if (currentbots == -1)
 714         {
 715                 // count bots already in the server from the previous match
 716                 currentbots = 0;
 717                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 718         }
 719
 720         if(autocvar_skill != skill)
 721         {
 722                 float wpcost_update = false;
 723                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 724                         wpcost_update = true;
 725                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 726                         wpcost_update = true;
 727
 728                 skill = autocvar_skill;
 729                 if (wpcost_update)
 730                         waypoint_updatecost_foralllinks();
 731         }
 732
 733         bot_calculate_stepheightvec();
 734         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 735
 736         if(time > autoskill_nextthink)
 737         {
 738                 float a;
 739                 a = autocvar_skill_auto;
 740                 if(a)
 741                         autoskill(a);
 742                 autoskill_nextthink = time + 5;
 743         }
 744
 745         if(time > botframe_nextthink)
 746         {
 747                 if(!bot_fixcount())
 748                         botframe_nextthink = time + 10;
 749         }
 750
 751         if(botframe_spawnedwaypoints)
 752         {
 753                 if(autocvar_waypoint_benchmark)
 754                         localcmd("quit\n");
 755         }
 756
 757         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 758         if (botframe_spawnedwaypoints)
 759         {
 760                 if(botframe_cachedwaypointlinks)
 761                 {
 762                         if(!botframe_loadedforcedlinks)
 763                                 waypoint_load_hardwiredlinks();
 764                 }
 765                 else
 766                 {
 767                         // TODO: Make this check cleaner
 768                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 769                         {
 770                                 waypoint_save_links();
 771                                 break;
 772                         });
 773                 }
 774         }
 775         else
 776         {
 777                 botframe_spawnedwaypoints = true;
 778                 waypoint_loadall();
 779                 waypoint_load_links();
 780         }
 781
 782         if (bot_list)
 783         {
 784                 // cycle the goal token from one bot to the next each frame
 785                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 786                 //  frame, which causes choppy framerates)
 787                 if (bot_strategytoken_taken)
 788                 {
 789                         // give goal token to the first bot without goals; if all bots don't have
 790                         // any goal (or are dead/frozen) simply give it to the next one
 791                         bot_strategytoken_taken = false;
 792                         entity bot_strategytoken_save = bot_strategytoken;
 793                         while (true)
 794                         {
 795                                 if (bot_strategytoken)
 796                                         bot_strategytoken = bot_strategytoken.nextbot;
 797                                 if (!bot_strategytoken)
 798                                         bot_strategytoken = bot_list;
 799
 800                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 801                                         && !bot_strategytoken.goalcurrent)
 802                                         break;
 803
 804                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 805                                         break;
 806                                 if (bot_strategytoken == bot_strategytoken_save)
 807                                         bot_strategytoken_save = NULL; // looped through all the bots
 808                         }
 809                 }
 810
 811                 if (botframe_nextdangertime < time)
 812                 {
 813                         float interval;
 814                         interval = autocvar_bot_ai_dangerdetectioninterval;
 815                         if (botframe_nextdangertime < time - interval * 1.5)
 816                                 botframe_nextdangertime = time;
 817                         botframe_nextdangertime = botframe_nextdangertime + interval;
 818                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 819                 }
 820         }
 821
 822         if (autocvar_g_waypointeditor)
 823                 botframe_showwaypointlinks();
 824
 825         if (autocvar_g_waypointeditor_auto)
 826                 botframe_autowaypoints();
 827
 828         if(time > bot_cvar_nextthink)
 829         {
 830                 if(currentbots>0)
 831                         bot_custom_weapon_priority_setup();
 832                 bot_cvar_nextthink = time + 5;
 833         }
 834 }