qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "../cvars.qh"
   4
   5 #include "../aim.qh"
   6 #include "../bot.qh"
   7 #include "../navigation.qh"
   8 #include "../scripting.qh"
   9 #include "../waypoints.qh"
  10
  11 #include <common/constants.qh>
  12 #include <common/impulses/all.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15 #include <common/state.qh>
  16 #include <common/items/_mod.qh>
  17 #include <common/wepent.qh>
  18
  19 #include <common/triggers/teleporters.qh>
  20 #include <common/triggers/trigger/jumppads.qh>
  21
  22 #include <lib/warpzone/common.qh>
  23
  24 .float speed;
  25
  26 void havocbot_ai(entity this)
  27 {
  28         if(this.draggedby)
  29                 return;
  30
  31         if(bot_execute_commands(this))
  32                 return;
  33
  34         if (bot_strategytoken == this)
  35         if (!bot_strategytoken_taken)
  36         {
  37                 if(this.havocbot_blockhead)
  38                 {
  39                         this.havocbot_blockhead = false;
  40                 }
  41                 else
  42                 {
  43                         if (!this.jumppadcount && !STAT(FROZEN, this))
  44                                 this.havocbot_role(this); // little too far down the rabbit hole
  45                 }
  46
  47                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  48                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  49                 if(!this.goalcurrent)
  50                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  51                 {
  52                         // Look for the closest waypoint out of water
  53                         entity newgoal = NULL;
  54                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  55                         {
  56                                 if(it.origin.z < this.origin.z)
  57                                         continue;
  58
  59                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  60                                         continue;
  61
  62                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  63                                         continue;
  64
  65                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  66
  67                                 if(trace_fraction < 1)
  68                                         continue;
  69
  70                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  71                                         newgoal = it;
  72                         });
  73
  74                         if(newgoal)
  75                         {
  76                         //      te_wizspike(newgoal.origin);
  77                                 navigation_pushroute(this, newgoal);
  78                         }
  79                 }
  80
  81                 // token has been used this frame
  82                 bot_strategytoken_taken = true;
  83         }
  84
  85         if(IS_DEAD(this) || STAT(FROZEN, this))
  86                 return;
  87
  88         havocbot_chooseenemy(this);
  89
  90         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  91         {
  92                 .entity weaponentity = weaponentities[slot];
  93                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  94                 if(this.(weaponentity).bot_chooseweapontime < time)
  95                 {
  96                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  97                         havocbot_chooseweapon(this, weaponentity);
  98                 }
  99         }
 100         havocbot_aim(this);
 101         lag_update(this);
 102         if (this.bot_aimtarg)
 103         {
 104                 this.aistatus |= AI_STATUS_ATTACKING;
 105                 this.aistatus &= ~AI_STATUS_ROAMING;
 106
 107                 if(this.weapons)
 108                 {
 109                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 110                         {
 111                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 112                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 113                         }
 114                         else
 115                         {
 116                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 117                                 {
 118                                         .entity weaponentity = weaponentities[slot];
 119                                         Weapon w = this.(weaponentity).m_weapon;
 120                                         if(w == WEP_Null && slot != 0)
 121                                                 continue;
 122                                         w.wr_aim(w, this, weaponentity);
 123                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 124                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 125                                 }
 126                         }
 127                 }
 128                 else
 129                 {
 130                         if(IS_PLAYER(this.bot_aimtarg))
 131                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 132                 }
 133         }
 134         else if (this.goalcurrent)
 135         {
 136                 this.aistatus |= AI_STATUS_ROAMING;
 137                 this.aistatus &= ~AI_STATUS_ATTACKING;
 138
 139                 vector v, now, next;
 140                 float aimdistance,skillblend,distanceblend,blend;
 141
 142                 if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 143                         v = this.goalcurrent.origin;
 144                 else
 145                         SET_DESTCOORDS(this.goalcurrent, this.origin, v);
 146                 next = now = v - (this.origin + this.view_ofs);
 147                 aimdistance = vlen(now);
 148
 149                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 150                 if(
 151                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 152                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 153                 )
 154                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 155
 156                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 157                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 158                 blend = skillblend * (1-distanceblend);
 159                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 160                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 161                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 162                 v = now + blend * (next - now);
 163                 //dprint(etos(this), " ");
 164                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 165                 //v = now * (distanceblend) + next * (1-distanceblend);
 166                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 167                         v.z = 0;
 168                 //dprint("walk at:", vtos(v), "\n");
 169                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 170                 bot_aimdir(this, v, -1);
 171         }
 172         havocbot_movetogoal(this);
 173
 174         // if the bot is not attacking, consider reloading weapons
 175         if (!(this.aistatus & AI_STATUS_ATTACKING))
 176         {
 177                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 178                 {
 179                         .entity weaponentity = weaponentities[slot];
 180
 181                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 182                                 continue;
 183
 184                         // we are currently holding a weapon that's not fully loaded, reload it
 185                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 186                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 187                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 188
 189                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 190                         // the code above executes next frame, starting the reloading then
 191                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 192                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 193                         {
 194                                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 195                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 196                                         {
 197                                                 this.(weaponentity).m_switchweapon = it;
 198                                                 break;
 199                                         }
 200                                 ));
 201                         }
 202                 }
 203         }
 204 }
 205
 206 void havocbot_keyboard_movement(entity this, vector destorg)
 207 {
 208         vector keyboard;
 209
 210         if (time > this.havocbot_keyboardtime)
 211         {
 212                 float sk = skill + this.bot_moveskill;
 213                 this.havocbot_keyboardtime =
 214                         max(
 215                                 this.havocbot_keyboardtime
 216                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 217                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 218                         , time);
 219                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 220
 221                 float trigger = autocvar_bot_ai_keyboard_threshold;
 222                 float trigger1 = -trigger;
 223
 224                 // categorize forward movement
 225                 // at skill < 1.5 only forward
 226                 // at skill < 2.5 only individual directions
 227                 // at skill < 4.5 only individual directions, and forward diagonals
 228                 // at skill >= 4.5, all cases allowed
 229                 if (keyboard.x > trigger)
 230                 {
 231                         keyboard.x = 1;
 232                         if (sk < 2.5)
 233                                 keyboard.y = 0;
 234                 }
 235                 else if (keyboard.x < trigger1 && sk > 1.5)
 236                 {
 237                         keyboard.x = -1;
 238                         if (sk < 4.5)
 239                                 keyboard.y = 0;
 240                 }
 241                 else
 242                 {
 243                         keyboard.x = 0;
 244                         if (sk < 1.5)
 245                                 keyboard.y = 0;
 246                 }
 247                 if (sk < 4.5)
 248                         keyboard.z = 0;
 249
 250                 if (keyboard.y > trigger)
 251                         keyboard.y = 1;
 252                 else if (keyboard.y < trigger1)
 253                         keyboard.y = -1;
 254                 else
 255                         keyboard.y = 0;
 256
 257                 if (keyboard.z > trigger)
 258                         keyboard.z = 1;
 259                 else if (keyboard.z < trigger1)
 260                         keyboard.z = -1;
 261                 else
 262                         keyboard.z = 0;
 263
 264                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 265                 if (this.havocbot_ducktime > time)
 266                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 267         }
 268
 269         keyboard = this.havocbot_keyboard;
 270         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 271         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 272         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 273 }
 274
 275 void havocbot_bunnyhop(entity this, vector dir)
 276 {
 277         float bunnyhopdistance;
 278         vector deviation;
 279         float maxspeed;
 280         vector gco, gno;
 281
 282         // Don't jump when attacking
 283         if(this.aistatus & AI_STATUS_ATTACKING)
 284                 return;
 285
 286         if(IS_PLAYER(this.goalcurrent))
 287                 return;
 288
 289         maxspeed = autocvar_sv_maxspeed;
 290
 291         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 292                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 293         {
 294                 this.aistatus &= ~AI_STATUS_RUNNING;
 295                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 296                 this.bot_canruntogoal = 0;
 297                 this.bot_timelastseengoal = 0;
 298                 return;
 299         }
 300
 301         if(this.waterlevel > WATERLEVEL_WETFEET)
 302         {
 303                 this.aistatus &= ~AI_STATUS_RUNNING;
 304                 return;
 305         }
 306
 307         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 308         {
 309                 this.bot_canruntogoal = 0;
 310                 this.bot_timelastseengoal = 0;
 311         }
 312
 313         SET_DESTCOORDS(this.goalcurrent, this.origin, gco);
 314         bunnyhopdistance = vlen(this.origin - gco);
 315
 316         // Run only to visible goals
 317         if(IS_ONGROUND(this))
 318         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 319         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 320         {
 321                         this.bot_lastseengoal = this.goalcurrent;
 322
 323                         // seen it before
 324                         if(this.bot_timelastseengoal)
 325                         {
 326                                 // for a period of time
 327                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 328                                 {
 329                                         float checkdistance;
 330                                         checkdistance = true;
 331
 332                                         // don't run if it is too close
 333                                         if(this.bot_canruntogoal==0)
 334                                         {
 335                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 336                                                         this.bot_canruntogoal = 1;
 337                                                 else
 338                                                         this.bot_canruntogoal = -1;
 339                                         }
 340
 341                                         if(this.bot_canruntogoal != 1)
 342                                                 return;
 343
 344                                         if(this.aistatus & AI_STATUS_ROAMING)
 345                                         if(this.goalcurrent.classname=="waypoint")
 346                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 347                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 348                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 349                                         {
 350                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 351                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 352                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 353                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 354
 355                                                 if(fabs(deviation.y) < 20)
 356                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 357                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 358                                                 {
 359                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 360                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 361                                                         {
 362                                                                 checkdistance = false;
 363                                                         }
 364                                                 }
 365                                         }
 366
 367                                         if(checkdistance)
 368                                         {
 369                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 370                                                 // increase stop distance in case the goal is on a slope or a lower platform
 371                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 372                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 373                                         }
 374                                         else
 375                                         {
 376                                                 this.aistatus |= AI_STATUS_RUNNING;
 377                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 378                                         }
 379                                 }
 380                         }
 381                         else
 382                         {
 383                                 this.bot_timelastseengoal = time;
 384                         }
 385         }
 386         else
 387         {
 388                 this.bot_timelastseengoal = 0;
 389         }
 390
 391 #if 0
 392         // Release jump button
 393         if(!cvar("sv_pogostick"))
 394         if((IS_ONGROUND(this)) == 0)
 395         {
 396                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 397                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 398
 399                 // Strafe
 400                 if(this.aistatus & AI_STATUS_RUNNING)
 401                 if(vlen(this.velocity)>maxspeed)
 402                 {
 403                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 404                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 405                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 406
 407                         if(fabs(deviation.y)>10)
 408                                 CS(this).movement_x = 0;
 409
 410                         if(deviation.y>10)
 411                                 CS(this).movement_y = maxspeed * -1;
 412                         else if(deviation.y<10)
 413                                 CS(this).movement_y = maxspeed;
 414
 415                 }
 416         }
 417 #endif
 418 }
 419
 420 // return true when bot isn't getting closer to the current goal
 421 bool havocbot_checkgoaldistance(entity this, vector gco)
 422 {
 423         float curr_dist = vlen(this.origin - gco);
 424         if(curr_dist > this.goalcurrent_distance)
 425         {
 426                 if(!this.goalcurrent_distance_time)
 427                         this.goalcurrent_distance_time = time;
 428                 else if (time - this.goalcurrent_distance_time > 0.5)
 429                         return true;
 430         }
 431         else
 432         {
 433                 // reduce it a little bit so it works even with very small approaches to the goal
 434                 this.goalcurrent_distance = max(20, curr_dist - 15);
 435                 this.goalcurrent_distance_time = 0;
 436         }
 437         return false;
 438 }
 439
 440 void havocbot_movetogoal(entity this)
 441 {
 442         vector destorg;
 443         vector diff;
 444         vector dir;
 445         vector flatdir;
 446         vector evadeobstacle;
 447         vector evadelava;
 448         float maxspeed;
 449         vector gco;
 450         //float dist;
 451         vector dodge;
 452         //if (this.goalentity)
 453         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 454         CS(this).movement = '0 0 0';
 455         maxspeed = autocvar_sv_maxspeed;
 456
 457         // Jetpack navigation
 458         if(this.goalcurrent)
 459         if(this.navigation_jetpack_goal)
 460         if(this.goalcurrent==this.navigation_jetpack_goal)
 461         if(this.ammo_fuel)
 462         {
 463                 if(autocvar_bot_debug_goalstack)
 464                 {
 465                         debuggoalstack(this);
 466                         te_wizspike(this.navigation_jetpack_point);
 467                 }
 468
 469                 // Take off
 470                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 471                 {
 472                         // Brake almost completely so it can get a good direction
 473                         if(vdist(this.velocity, >, 10))
 474                                 return;
 475                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 476                 }
 477
 478                 makevectors(this.v_angle.y * '0 1 0');
 479                 dir = normalize(this.navigation_jetpack_point - this.origin);
 480
 481                 // Landing
 482                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 483                 {
 484                         // Calculate brake distance in xy
 485                         float db, v, d;
 486                         vector dxy;
 487
 488                         dxy = this.origin - ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 489                         d = vlen(dxy);
 490                         v = vlen(this.velocity -  this.velocity.z * '0 0 1');
 491                         db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 492                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 493                         if(d < db || d < 500)
 494                         {
 495                                 // Brake
 496                                 if(fabs(this.velocity.x)>maxspeed*0.3)
 497                                 {
 498                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 499                                         return;
 500                                 }
 501                                 // Switch to normal mode
 502                                 this.navigation_jetpack_goal = NULL;
 503                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 504                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 505                                 return;
 506                         }
 507                 }
 508                 else if(checkpvs(this.origin,this.goalcurrent))
 509                 {
 510                         // If I can see the goal switch to landing code
 511                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 512                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 513                         return;
 514                 }
 515
 516                 // Flying
 517                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 518                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 519                 {
 520                         CS(this).movement_x = dir * v_forward * maxspeed;
 521                         CS(this).movement_y = dir * v_right * maxspeed;
 522                 }
 523                 return;
 524         }
 525
 526         // Handling of jump pads
 527         if(this.jumppadcount)
 528         {
 529                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 530                 {
 531                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 532                         navigation_poptouchedgoals(this);
 533                         return;
 534                 }
 535                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 536                 {
 537                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 538                         // but with some randomness so it can try out different paths
 539                         if(!this.goalcurrent)
 540                         {
 541                                 entity newgoal = NULL;
 542                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 543                                 {
 544                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 545                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 546                                                 continue;
 547
 548                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 549
 550                                         if(trace_fraction < 1)
 551                                                 continue;
 552
 553                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 554                                                 newgoal = it;
 555                                 });
 556
 557                                 if(newgoal)
 558                                 {
 559                                         this.ignoregoal = this.goalcurrent;
 560                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 561                                         navigation_clearroute(this);
 562                                         navigation_routetogoal(this, newgoal, this.origin);
 563                                         if(autocvar_bot_debug_goalstack)
 564                                                 debuggoalstack(this);
 565                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 566                                 }
 567                         }
 568                         else
 569                         {
 570                                 gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 571                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 572                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 573                                 else if(havocbot_checkgoaldistance(this, gco))
 574                                 {
 575                                         navigation_clearroute(this);
 576                                         this.bot_strategytime = 0;
 577                                 }
 578                                 else
 579                                         return;
 580                         }
 581                 }
 582                 else
 583                 {
 584                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 585                         {
 586                                 vector velxy = this.velocity; velxy_z = 0;
 587                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 588                                 {
 589                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 590                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 591                                 }
 592                                 return;
 593                         }
 594
 595                         // Don't chase players while using a jump pad
 596                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 597                                 return;
 598                 }
 599         }
 600         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 601                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 602
 603         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 604         if(skill>6)
 605         if (!(IS_ONGROUND(this)))
 606         {
 607                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 608                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 609                 if(this.items & IT_JETPACK)
 610                 {
 611                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 612                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 613                         {
 614                                 if(this.velocity.z<0)
 615                                 {
 616                                         PHYS_INPUT_BUTTON_HOOK(this) = true;
 617                                 }
 618                         }
 619                         else
 620                                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 621
 622                         // If there is no goal try to move forward
 623
 624                         if(this.goalcurrent==NULL)
 625                                 dir = v_forward;
 626                         else
 627                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 628
 629                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 630                         float xyspeed = xyvelocity * dir;
 631
 632                         if(xyspeed < (maxspeed / 2))
 633                         {
 634                                 makevectors(this.v_angle.y * '0 1 0');
 635                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 636                                 if(trace_fraction==1)
 637                                 {
 638                                         CS(this).movement_x = dir * v_forward * maxspeed;
 639                                         CS(this).movement_y = dir * v_right * maxspeed;
 640                                         if (skill < 10)
 641                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 642                                 }
 643                         }
 644
 645                         this.havocbot_blockhead = true;
 646
 647                         return;
 648                 }
 649                 else if(this.health > WEP_CVAR(devastator, damage) * 0.5 * ((this.strength_finished < time) ? autocvar_g_balance_powerup_strength_selfdamage : 1))
 650                 {
 651                         if(this.velocity.z < 0)
 652                         {
 653                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 654                                 {
 655                                         .entity weaponentity = weaponentities[slot];
 656
 657                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 658                                                 continue;
 659
 660                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 661                                         {
 662                                                 CS(this).movement_x = maxspeed;
 663
 664                                                 if(this.rocketjumptime)
 665                                                 {
 666                                                         if(time > this.rocketjumptime)
 667                                                         {
 668                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 669                                                                 this.rocketjumptime = 0;
 670                                                         }
 671                                                         return;
 672                                                 }
 673
 674                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 675                                                 this.v_angle_x = 90;
 676                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 677                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 678                                                 return;
 679                                         }
 680                                 }
 681                         }
 682                 }
 683                 else
 684                 {
 685                         // If there is no goal try to move forward
 686                         if(this.goalcurrent==NULL)
 687                                 CS(this).movement_x = maxspeed;
 688                 }
 689         }
 690
 691         // If we are under water with no goals, swim up
 692         if(this.waterlevel)
 693         if(this.goalcurrent==NULL)
 694         {
 695                 dir = '0 0 0';
 696                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 697                         dir.z = 1;
 698                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 699                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 700                 else
 701                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 702                 makevectors(this.v_angle.y * '0 1 0');
 703                 CS(this).movement_x = dir * v_forward * maxspeed;
 704                 CS(this).movement_y = dir * v_right * maxspeed;
 705                 CS(this).movement_z = dir * v_up * maxspeed;
 706         }
 707
 708         // if there is nowhere to go, exit
 709         if (this.goalcurrent == NULL)
 710                 return;
 711
 712
 713         bool locked_goal = false;
 714         if(this.goalentity && wasfreed(this.goalentity))
 715         {
 716                 navigation_clearroute(this);
 717                 this.bot_strategytime = 0;
 718                 return;
 719         }
 720         else if(this.goalentity.bot_pickup)
 721         {
 722                 if(this.goalentity.bot_pickup_respawning)
 723                 {
 724                         if(this.goalentity.solid) // item respawned
 725                                 this.goalentity.bot_pickup_respawning = false;
 726                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 727                         {
 728                                 this.goalentity.bot_pickup_respawning = false;
 729                                 navigation_clearroute(this);
 730                                 this.bot_strategytime = 0;
 731                                 return;
 732                         }
 733                         else if(this.goalentity == this.goalcurrent)
 734                                 locked_goal = true; // wait for item to respawn
 735                 }
 736                 else if(!this.goalentity.solid)
 737                 {
 738                         navigation_clearroute(this);
 739                         this.bot_strategytime = 0;
 740                         return;
 741                 }
 742         }
 743         if(!locked_goal)
 744                 navigation_poptouchedgoals(this);
 745
 746         // if ran out of goals try to use an alternative goal or get a new strategy asap
 747         if(this.goalcurrent == NULL)
 748         {
 749                 this.bot_strategytime = 0;
 750                 return;
 751         }
 752
 753
 754         if(autocvar_bot_debug_goalstack)
 755                 debuggoalstack(this);
 756
 757         bool bunnyhop_forbidden = false;;
 758         SET_DESTCOORDS(this.goalcurrent, this.origin, destorg);
 759
 760         // in case bot ends up inside the teleport waypoint without touching
 761         // the teleport itself, head to the teleport origin
 762         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.absmin, this.absmax))
 763         {
 764                 bunnyhop_forbidden = true;
 765                 destorg = this.goalcurrent.origin;
 766                 if(destorg.z > this.origin.z)
 767                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 768         }
 769
 770         diff = destorg - this.origin;
 771         //dist = vlen(diff);
 772         dir = normalize(diff);
 773         flatdir = diff;flatdir.z = 0;
 774         flatdir = normalize(flatdir);
 775         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 776
 777         //if (this.bot_dodgevector_time < time)
 778         {
 779                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 780                 //this.bot_dodgevector_jumpbutton = 1;
 781                 evadeobstacle = '0 0 0';
 782                 evadelava = '0 0 0';
 783
 784                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 785                 makevectors(this.v_angle.y * '0 1 0');
 786                 if (this.waterlevel)
 787                 {
 788                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 789                         {
 790                                 if(!this.goalcurrent)
 791                                         this.aistatus |= AI_STATUS_OUT_WATER;
 792                                 else if(gco.z > this.origin.z)
 793                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 794                         }
 795                         else
 796                         {
 797                                 dir = flatdir;
 798                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 799                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 800                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 801                                 else
 802                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 803                         }
 804                 }
 805                 else
 806                 {
 807                         float s;
 808                         vector offset;
 809                         if(this.aistatus & AI_STATUS_OUT_WATER)
 810                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 811
 812                         // jump if going toward an obstacle that doesn't look like stairs we
 813                         // can walk up directly
 814                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 815                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 816                         if (trace_fraction < 1)
 817                         if (trace_plane_normal.z < 0.7)
 818                         {
 819                                 s = trace_fraction;
 820                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 821                                 if (trace_fraction < s + 0.01)
 822                                 if (trace_plane_normal.z < 0.7)
 823                                 {
 824                                         s = trace_fraction;
 825                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 826                                         if (trace_fraction > s)
 827                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 828                                 }
 829                         }
 830
 831                         // if bot for some reason doesn't get close to the current goal find another one
 832                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent) && !(this.goalcurrent.bot_pickup_respawning && this.goalcurrent_distance < 50))
 833                         if(havocbot_checkgoaldistance(this, gco))
 834                         {
 835                                 navigation_clearroute(this);
 836                                 this.bot_strategytime = 0;
 837                                 return;
 838                         }
 839
 840                         // Check for water/slime/lava and dangerous edges
 841                         // (only when the bot is on the ground or jumping intentionally)
 842
 843                         vector dst_ahead = this.origin + this.view_ofs + offset;
 844                         vector dst_down = dst_ahead - '0 0 3000';
 845                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 846
 847                         bool unreachable = false;
 848                         s = CONTENT_SOLID;
 849                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 850                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 851                         {
 852                                 // Look downwards
 853                                 traceline(dst_ahead , dst_down, true, NULL);
 854                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 855                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 856                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 857                                 {
 858                                         s = pointcontents(trace_endpos + '0 0 1');
 859                                         if (s != CONTENT_SOLID)
 860                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 861                                                 evadelava = normalize(this.velocity) * -1;
 862                                         else if (s == CONTENT_SKY)
 863                                                 evadeobstacle = normalize(this.velocity) * -1;
 864                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 865                                         {
 866                                                 // the traceline check isn't enough but is good as optimization,
 867                                                 // when not true (most of the time) this tracebox call is avoided
 868                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 869                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 870                                                 {
 871                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 872                                                         {
 873                                                                 // the goal is probably on an upper platform, assume bot can't get there
 874                                                                 unreachable = true;
 875                                                         }
 876                                                         else
 877                                                                 evadelava = normalize(this.velocity) * -1;
 878                                                 }
 879                                         }
 880                                 }
 881                         }
 882
 883                         dir = flatdir;
 884                         evadeobstacle.z = 0;
 885                         evadelava.z = 0;
 886                         makevectors(this.v_angle.y * '0 1 0');
 887
 888                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 889                         {
 890                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 891                                 if(IS_PLAYER(this.goalcurrent))
 892                                         unreachable = true;
 893                         }
 894                         if(unreachable)
 895                         {
 896                                 navigation_clearroute(this);
 897                                 this.bot_strategytime = 0;
 898                         }
 899                 }
 900
 901                 dodge = havocbot_dodge(this);
 902                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 903                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 904                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 905                 if(IS_PLAYER(trace_ent))
 906                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 907
 908                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 909         //      this.bot_dodgevector = dir;
 910         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 911         }
 912
 913         if(time < this.ladder_time)
 914         {
 915                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 916                 {
 917                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 918                                 dir.z = 1;
 919                 }
 920                 else
 921                 {
 922                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 923                                 dir.z = -1;
 924                 }
 925         }
 926
 927         //dir = this.bot_dodgevector;
 928         //if (this.bot_dodgevector_jumpbutton)
 929         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 930         CS(this).movement_x = dir * v_forward * maxspeed;
 931         CS(this).movement_y = dir * v_right * maxspeed;
 932         CS(this).movement_z = dir * v_up * maxspeed;
 933
 934         // Emulate keyboard interface
 935         if (skill < 10)
 936                 havocbot_keyboard_movement(this, destorg);
 937
 938         // Bunnyhop!
 939         //if(this.aistatus & AI_STATUS_ROAMING)
 940         if(!bunnyhop_forbidden && this.goalcurrent)
 941         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 942                 havocbot_bunnyhop(this, dir);
 943
 944         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 945         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 946         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 947 }
 948
 949 entity havocbot_gettarget(entity this, bool secondary)
 950 {
 951         entity best = NULL;
 952         vector eye = CENTER_OR_VIEWOFS(this);
 953         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 954         {
 955                 vector v = CENTER_OR_VIEWOFS(it);
 956                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 957                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 958                 if(bot_shouldattack(this, it))
 959                 {
 960                         traceline(eye, v, true, this);
 961                         if (trace_ent == it || trace_fraction >= 1)
 962                                 best = it;
 963                 }
 964         });
 965
 966         return best;
 967 }
 968
 969 void havocbot_chooseenemy(entity this)
 970 {
 971         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 972         {
 973                 this.enemy = NULL;
 974                 return;
 975         }
 976         if (this.enemy)
 977         {
 978                 if (!bot_shouldattack(this, this.enemy))
 979                 {
 980                         // enemy died or something, find a new target
 981                         this.enemy = NULL;
 982                         this.havocbot_chooseenemy_finished = time;
 983                 }
 984                 else if (this.havocbot_stickenemy)
 985                 {
 986                         // tracking last chosen enemy
 987                         // if enemy is visible
 988                         // and not really really far away
 989                         // and we're not severely injured
 990                         // then keep tracking for a half second into the future
 991                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
 992                         if (trace_ent == this.enemy || trace_fraction == 1)
 993                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
 994                         if (this.health > 30)
 995                         {
 996                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 997                                 this.havocbot_chooseenemy_finished = time + 0.5;
 998                                 return;
 999                         }
1000                         // enemy isn't visible, or is far away, or we're injured severely
1001                         // so stop preferring this enemy
1002                         // (it will still take a half second until a new one is chosen)
1003                         this.havocbot_stickenemy = 0;
1004                 }
1005         }
1006         if (time < this.havocbot_chooseenemy_finished)
1007                 return;
1008         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1009         vector eye = this.origin + this.view_ofs;
1010         entity best = NULL;
1011         float bestrating = 100000000;
1012
1013         // Backup hit flags
1014         int hf = this.dphitcontentsmask;
1015
1016         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1017
1018         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1019
1020         bool scan_transparent = false;
1021         bool scan_secondary_targets = false;
1022         bool have_secondary_targets = false;
1023         while(true)
1024         {
1025                 scan_secondary_targets = false;
1026 LABEL(scan_targets)
1027                 IL_EACH(g_bot_targets, it.bot_attack,
1028                 {
1029                         if(!scan_secondary_targets)
1030                         {
1031                                 if(it.classname == "misc_breakablemodel")
1032                                 {
1033                                         have_secondary_targets = true;
1034                                         continue;
1035                                 }
1036                         }
1037                         else if(it.classname != "misc_breakablemodel")
1038                                 continue;
1039
1040                         vector v = (it.absmin + it.absmax) * 0.5;
1041                         float rating = vlen2(v - eye);
1042                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1043                         if (bestrating > rating)
1044                         if (bot_shouldattack(this, it))
1045                         {
1046                                 traceline(eye, v, true, this);
1047                                 if (trace_ent == it || trace_fraction >= 1)
1048                                 {
1049                                         best = it;
1050                                         bestrating = rating;
1051                                 }
1052                         }
1053                 });
1054
1055                 if(!best && have_secondary_targets && !scan_secondary_targets)
1056                 {
1057                         scan_secondary_targets = true;
1058                         // restart the loop
1059                         bestrating = 100000000;
1060                         goto scan_targets;
1061                 }
1062
1063                 // I want to do a second scan if no enemy was found or I don't have weapons
1064                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1065                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1066                         break;
1067                 if(scan_transparent)
1068                         break;
1069
1070                 // Set flags to see through transparent objects
1071                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1072
1073                 scan_transparent = true;
1074         }
1075
1076         // Restore hit flags
1077         this.dphitcontentsmask = hf;
1078
1079         this.enemy = best;
1080         this.havocbot_stickenemy = true;
1081         if(best && best.classname == "misc_breakablemodel")
1082                 this.havocbot_stickenemy = false;
1083 }
1084
1085 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1086 {
1087         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1088         // so skip this for them, or they'll never get to reload their weapons at all.
1089         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1090         if(skill < 5)
1091                 return false;
1092
1093         // if this weapon is scheduled for reloading, don't switch to it during combat
1094         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1095         {
1096                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1097                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1098                                 return true; // other weapon available
1099                 ));
1100         }
1101
1102         return false;
1103 }
1104
1105 void havocbot_chooseweapon(entity this, .entity weaponentity)
1106 {
1107         int i;
1108
1109         // ;)
1110         if(g_weaponarena_weapons == WEPSET(TUBA))
1111         {
1112                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1113                 return;
1114         }
1115
1116         // TODO: clean this up by moving it to weapon code
1117         if(this.enemy==NULL)
1118         {
1119                 // If no weapon was chosen get the first available weapon
1120                 if(this.(weaponentity).m_weapon==WEP_Null)
1121                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1122                         if(client_hasweapon(this, it, weaponentity, true, false))
1123                         {
1124                                 this.(weaponentity).m_switchweapon = it;
1125                                 return;
1126                         }
1127                 ));
1128                 return;
1129         }
1130
1131         // Do not change weapon during the next second after a combo
1132         float f = time - this.lastcombotime;
1133         if(f < 1)
1134                 return;
1135
1136         float w;
1137         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1138
1139         // Should it do a weapon combo?
1140         float af, ct, combo_time, combo;
1141
1142         af = ATTACK_FINISHED(this, 0);
1143         ct = autocvar_bot_ai_weapon_combo_threshold;
1144
1145         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1146         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1147         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1148
1149         combo = false;
1150
1151         if(autocvar_bot_ai_weapon_combo)
1152         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1153         if(af > combo_time)
1154         {
1155                 combo = true;
1156                 this.lastcombotime = time;
1157         }
1158
1159         distance *= (2 ** this.bot_rangepreference);
1160
1161         // Custom weapon list based on distance to the enemy
1162         if(bot_custom_weapon){
1163
1164                 // Choose weapons for far distance
1165                 if ( distance > bot_distance_far ) {
1166                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1167                                 w = bot_weapons_far[i];
1168                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1169                                 {
1170                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1171                                                 continue;
1172                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1173                                         return;
1174                                 }
1175                         }
1176                 }
1177
1178                 // Choose weapons for mid distance
1179                 if ( distance > bot_distance_close) {
1180                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1181                                 w = bot_weapons_mid[i];
1182                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1183                                 {
1184                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1185                                                 continue;
1186                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1187                                         return;
1188                                 }
1189                         }
1190                 }
1191
1192                 // Choose weapons for close distance
1193                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1194                         w = bot_weapons_close[i];
1195                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1196                         {
1197                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1198                                         continue;
1199                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1200                                 return;
1201                         }
1202                 }
1203         }
1204 }
1205
1206 void havocbot_aim(entity this)
1207 {
1208         if (time < this.nextaim)
1209                 return;
1210         this.nextaim = time + 0.1;
1211         vector myvel = this.velocity;
1212         if (!this.waterlevel)
1213                 myvel.z = 0;
1214         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1215         else if (this.enemy)
1216         {
1217                 vector enemyvel = this.enemy.velocity;
1218                 if (!this.enemy.waterlevel)
1219                         enemyvel.z = 0;
1220                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1221         }
1222         else
1223                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1224 }
1225
1226 bool havocbot_moveto_refresh_route(entity this)
1227 {
1228         // Refresh path to goal if necessary
1229         entity wp;
1230         wp = this.havocbot_personal_waypoint;
1231         navigation_goalrating_start(this);
1232         navigation_routerating(this, wp, 10000, 10000);
1233         navigation_goalrating_end(this);
1234         return (this.goalentity != NULL);
1235 }
1236
1237 float havocbot_moveto(entity this, vector pos)
1238 {
1239         entity wp;
1240
1241         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1242         {
1243                 // Step 4: Move to waypoint
1244                 if(this.havocbot_personal_waypoint==NULL)
1245                 {
1246                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1247                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1248                         return CMD_STATUS_ERROR;
1249                 }
1250
1251                 if (!bot_strategytoken_taken)
1252                 if(this.havocbot_personal_waypoint_searchtime<time)
1253                 {
1254                         bot_strategytoken_taken = true;
1255                         if(havocbot_moveto_refresh_route(this))
1256                         {
1257                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1258                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1259                                 this.havocbot_personal_waypoint_failcounter = 0;
1260                         }
1261                         else
1262                         {
1263                                 this.havocbot_personal_waypoint_failcounter += 1;
1264                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1265                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1266                                 {
1267                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1268                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1269                                         delete(this.havocbot_personal_waypoint);
1270                                         return CMD_STATUS_ERROR;
1271                                 }
1272                                 else
1273                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1274                         }
1275                 }
1276
1277                 if(autocvar_bot_debug_goalstack)
1278                         debuggoalstack(this);
1279
1280                 // Heading
1281                 vector dir;
1282                 SET_DESTCOORDS(this.goalcurrent, this.origin, dir);
1283                 dir = dir - (this.origin + this.view_ofs);
1284                 dir.z = 0;
1285                 bot_aimdir(this, dir, -1);
1286
1287                 // Go!
1288                 havocbot_movetogoal(this);
1289
1290                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1291                 {
1292                         // Step 5: Waypoint reached
1293                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1294                         delete(this.havocbot_personal_waypoint);
1295                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1296                         return CMD_STATUS_FINISHED;
1297                 }
1298
1299                 return CMD_STATUS_EXECUTING;
1300         }
1301
1302         // Step 2: Linking waypoint
1303         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1304         {
1305                 // Wait until it is linked
1306                 if(!this.havocbot_personal_waypoint.wplinked)
1307                 {
1308                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1309                         return CMD_STATUS_EXECUTING;
1310                 }
1311
1312                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1313                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1314                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1315
1316                 // Step 3: Route to waypoint
1317                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1318
1319                 return CMD_STATUS_EXECUTING;
1320         }
1321
1322         // Step 1: Spawning waypoint
1323         wp = waypoint_spawnpersonal(this, pos);
1324         if(wp==NULL)
1325         {
1326                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1327                 return CMD_STATUS_ERROR;
1328         }
1329
1330         this.havocbot_personal_waypoint = wp;
1331         this.havocbot_personal_waypoint_failcounter = 0;
1332         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1333
1334         // if pos is inside a teleport, then let's mark it as teleport waypoint
1335         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1336         {
1337                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1338                 this.lastteleporttime = 0;
1339         });
1340
1341 /*
1342         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1343                 print("routing to a teleporter\n");
1344         else
1345                 print("routing to a non-teleporter\n");
1346 */
1347
1348         return CMD_STATUS_EXECUTING;
1349 }
1350
1351 float havocbot_resetgoal(entity this)
1352 {
1353         navigation_clearroute(this);
1354         return CMD_STATUS_FINISHED;
1355 }
1356
1357 void havocbot_setupbot(entity this)
1358 {
1359         this.bot_ai = havocbot_ai;
1360         this.cmd_moveto = havocbot_moveto;
1361         this.cmd_resetgoal = havocbot_resetgoal;
1362
1363         havocbot_chooserole(this);
1364 }
1365
1366 vector havocbot_dodge(entity this)
1367 {
1368         // LordHavoc: disabled because this is too expensive
1369         return '0 0 0';
1370 #if 0
1371         entity head;
1372         vector dodge, v, n;
1373         float danger, bestdanger, vl, d;
1374         dodge = '0 0 0';
1375         bestdanger = -20;
1376         // check for dangerous objects near bot or approaching bot
1377         head = findchainfloat(bot_dodge, true);
1378         while(head)
1379         {
1380                 if (head.owner != this)
1381                 {
1382                         vl = vlen(head.velocity);
1383                         if (vl > autocvar_sv_maxspeed * 0.3)
1384                         {
1385                                 n = normalize(head.velocity);
1386                                 v = this.origin - head.origin;
1387                                 d = v * n;
1388                                 if (d > (0 - head.bot_dodgerating))
1389                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1390                                 {
1391                                         // calculate direction and distance from the flight path, by removing the forward axis
1392                                         v = v - (n * (v * n));
1393                                         danger = head.bot_dodgerating - vlen(v);
1394                                         if (bestdanger < danger)
1395                                         {
1396                                                 bestdanger = danger;
1397                                                 // dodge to the side of the object
1398                                                 dodge = normalize(v);
1399                                         }
1400                                 }
1401                         }
1402                         else
1403                         {
1404                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1405                                 if (bestdanger < danger)
1406                                 {
1407                                         bestdanger = danger;
1408                                         dodge = normalize(this.origin - head.origin);
1409                                 }
1410                         }
1411                 }
1412                 head = head.chain;
1413         }
1414         return dodge;
1415 #endif
1416 }