qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "../cvars.qh"
   4
   5 #include "../aim.qh"
   6 #include "../bot.qh"
   7 #include "../navigation.qh"
   8 #include "../scripting.qh"
   9 #include "../waypoints.qh"
  10
  11 #include <common/constants.qh>
  12 #include <common/impulses/all.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15 #include <common/state.qh>
  16 #include <common/items/_mod.qh>
  17 #include <common/wepent.qh>
  18
  19 #include <common/triggers/teleporters.qh>
  20 #include <common/triggers/trigger/jumppads.qh>
  21
  22 #include <lib/warpzone/common.qh>
  23
  24 .float speed;
  25
  26 void havocbot_ai(entity this)
  27 {
  28         if(this.draggedby)
  29                 return;
  30
  31         if(bot_execute_commands(this))
  32                 return;
  33
  34         if (bot_strategytoken == this)
  35         if (!bot_strategytoken_taken)
  36         {
  37                 if(this.havocbot_blockhead)
  38                 {
  39                         this.havocbot_blockhead = false;
  40                 }
  41                 else
  42                 {
  43                         if (!this.jumppadcount)
  44                                 this.havocbot_role(this); // little too far down the rabbit hole
  45                 }
  46
  47                 // TODO: tracewalk() should take care of this job (better path finding under water)
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this))
  87                 return;
  88
  89         havocbot_chooseenemy(this);
  90
  91         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  92         {
  93                 .entity weaponentity = weaponentities[slot];
  94                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  95                 if(this.(weaponentity).bot_chooseweapontime < time)
  96                 {
  97                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  98                         havocbot_chooseweapon(this, weaponentity);
  99                 }
 100         }
 101         havocbot_aim(this);
 102         lag_update(this);
 103         if (this.bot_aimtarg)
 104         {
 105                 this.aistatus |= AI_STATUS_ATTACKING;
 106                 this.aistatus &= ~AI_STATUS_ROAMING;
 107
 108                 if(this.weapons)
 109                 {
 110                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 111                         {
 112                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 113                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 114                         }
 115                         else
 116                         {
 117                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 118                                 {
 119                                         .entity weaponentity = weaponentities[slot];
 120                                         Weapon w = this.(weaponentity).m_weapon;
 121                                         if(w == WEP_Null && slot != 0)
 122                                                 continue;
 123                                         w.wr_aim(w, this, weaponentity);
 124                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 125                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 126                                 }
 127                         }
 128                 }
 129                 else
 130                 {
 131                         if(IS_PLAYER(this.bot_aimtarg))
 132                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 133                 }
 134         }
 135         else if (this.goalcurrent)
 136         {
 137                 this.aistatus |= AI_STATUS_ROAMING;
 138                 this.aistatus &= ~AI_STATUS_ATTACKING;
 139
 140                 vector now,v,next;//,heading;
 141                 float aimdistance,skillblend,distanceblend,blend;
 142                 next = now = ( (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5) - (this.origin + this.view_ofs);
 143                 aimdistance = vlen(now);
 144                 //heading = this.velocity;
 145                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 146                 if(
 147                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 148                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 149                 )
 150                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 151
 152                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 153                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 154                 blend = skillblend * (1-distanceblend);
 155                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 156                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 157                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 158                 v = now + blend * (next - now);
 159                 //dprint(etos(this), " ");
 160                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 161                 //v = now * (distanceblend) + next * (1-distanceblend);
 162                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 163                         v.z = 0;
 164                 //dprint("walk at:", vtos(v), "\n");
 165                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 166                 bot_aimdir(this, v, -1);
 167         }
 168         havocbot_movetogoal(this);
 169
 170         // if the bot is not attacking, consider reloading weapons
 171         if (!(this.aistatus & AI_STATUS_ATTACKING))
 172         {
 173                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 174                 {
 175                         .entity weaponentity = weaponentities[slot];
 176
 177                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 178                                 continue;
 179
 180                         // we are currently holding a weapon that's not fully loaded, reload it
 181                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 182                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 183                                 this.impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 184
 185                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 186                         // the code above executes next frame, starting the reloading then
 187                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 188                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 189                         {
 190                                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 191                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 192                                         {
 193                                                 this.(weaponentity).m_switchweapon = it;
 194                                                 break;
 195                                         }
 196                                 ));
 197                         }
 198                 }
 199         }
 200 }
 201
 202 void havocbot_keyboard_movement(entity this, vector destorg)
 203 {
 204         vector keyboard;
 205         float blend, maxspeed;
 206         float sk;
 207
 208         sk = skill + this.bot_moveskill;
 209
 210         maxspeed = autocvar_sv_maxspeed;
 211
 212         if (time < this.havocbot_keyboardtime)
 213                 return;
 214
 215         this.havocbot_keyboardtime =
 216                 max(
 217                         this.havocbot_keyboardtime
 218                                 + 0.05/max(1, sk+this.havocbot_keyboardskill)
 219                                 + random()*0.025/max(0.00025, skill+this.havocbot_keyboardskill)
 220                 , time);
 221         keyboard = this.movement * (1.0 / maxspeed);
 222
 223         float trigger, trigger1;
 224         blend = bound(0,sk*0.1,1);
 225         trigger = autocvar_bot_ai_keyboard_threshold;
 226         trigger1 = 0 - trigger;
 227
 228         // categorize forward movement
 229         // at skill < 1.5 only forward
 230         // at skill < 2.5 only individual directions
 231         // at skill < 4.5 only individual directions, and forward diagonals
 232         // at skill >= 4.5, all cases allowed
 233         if (keyboard.x > trigger)
 234         {
 235                 keyboard.x = 1;
 236                 if (sk < 2.5)
 237                         keyboard.y = 0;
 238         }
 239         else if (keyboard.x < trigger1 && sk > 1.5)
 240         {
 241                 keyboard.x = -1;
 242                 if (sk < 4.5)
 243                         keyboard.y = 0;
 244         }
 245         else
 246         {
 247                 keyboard.x = 0;
 248                 if (sk < 1.5)
 249                         keyboard.y = 0;
 250         }
 251         if (sk < 4.5)
 252                 keyboard.z = 0;
 253
 254         if (keyboard.y > trigger)
 255                 keyboard.y = 1;
 256         else if (keyboard.y < trigger1)
 257                 keyboard.y = -1;
 258         else
 259                 keyboard.y = 0;
 260
 261         if (keyboard.z > trigger)
 262                 keyboard.z = 1;
 263         else if (keyboard.z < trigger1)
 264                 keyboard.z = -1;
 265         else
 266                 keyboard.z = 0;
 267
 268         this.havocbot_keyboard = keyboard * maxspeed;
 269         if (this.havocbot_ducktime>time) PHYS_INPUT_BUTTON_CROUCH(this) = true;
 270
 271         keyboard = this.havocbot_keyboard;
 272         blend = bound(0,vlen(destorg-this.origin)/autocvar_bot_ai_keyboard_distance,1); // When getting close move with 360 degree
 273         //dprint("movement ", vtos(this.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 274         this.movement = this.movement + (keyboard - this.movement) * blend;
 275 }
 276
 277 void havocbot_bunnyhop(entity this, vector dir)
 278 {
 279         float bunnyhopdistance;
 280         vector deviation;
 281         float maxspeed;
 282         vector gco, gno;
 283
 284         // Don't jump when attacking
 285         if(this.aistatus & AI_STATUS_ATTACKING)
 286                 return;
 287
 288         if(IS_PLAYER(this.goalcurrent))
 289                 return;
 290
 291         maxspeed = autocvar_sv_maxspeed;
 292
 293         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 294                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 295         {
 296                 this.aistatus &= ~AI_STATUS_RUNNING;
 297                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 298                 this.bot_canruntogoal = 0;
 299                 this.bot_timelastseengoal = 0;
 300                 return;
 301         }
 302
 303         if(this.waterlevel > WATERLEVEL_WETFEET)
 304         {
 305                 this.aistatus &= ~AI_STATUS_RUNNING;
 306                 return;
 307         }
 308
 309         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 310         {
 311                 this.bot_canruntogoal = 0;
 312                 this.bot_timelastseengoal = 0;
 313         }
 314
 315         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 316         bunnyhopdistance = vlen(this.origin - gco);
 317
 318         // Run only to visible goals
 319         if(IS_ONGROUND(this))
 320         if(vlen(this.velocity - eZ * this.velocity.z) >= autocvar_sv_maxspeed) // if -really- running
 321         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 322         {
 323                         this.bot_lastseengoal = this.goalcurrent;
 324
 325                         // seen it before
 326                         if(this.bot_timelastseengoal)
 327                         {
 328                                 // for a period of time
 329                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 330                                 {
 331                                         float checkdistance;
 332                                         checkdistance = true;
 333
 334                                         // don't run if it is too close
 335                                         if(this.bot_canruntogoal==0)
 336                                         {
 337                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 338                                                         this.bot_canruntogoal = 1;
 339                                                 else
 340                                                         this.bot_canruntogoal = -1;
 341                                         }
 342
 343                                         if(this.bot_canruntogoal != 1)
 344                                                 return;
 345
 346                                         if(this.aistatus & AI_STATUS_ROAMING)
 347                                         if(this.goalcurrent.classname=="waypoint")
 348                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 349                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 350                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 351                                         {
 352                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 353                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 354                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 355                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 356
 357                                                 if(fabs(deviation.y) < 20)
 358                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 359                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 360                                                 {
 361                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 362                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 363                                                         {
 364                                                                 checkdistance = false;
 365                                                         }
 366                                                 }
 367                                         }
 368
 369                                         if(checkdistance)
 370                                         {
 371                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 372                                                 // increase stop distance in case the goal is on a slope or a lower platform
 373                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 374                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 375                                         }
 376                                         else
 377                                         {
 378                                                 this.aistatus |= AI_STATUS_RUNNING;
 379                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 380                                         }
 381                                 }
 382                         }
 383                         else
 384                         {
 385                                 this.bot_timelastseengoal = time;
 386                         }
 387         }
 388         else
 389         {
 390                 this.bot_timelastseengoal = 0;
 391         }
 392
 393 #if 0
 394         // Release jump button
 395         if(!cvar("sv_pogostick"))
 396         if((IS_ONGROUND(this)) == 0)
 397         {
 398                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 399                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 400
 401                 // Strafe
 402                 if(this.aistatus & AI_STATUS_RUNNING)
 403                 if(vlen(this.velocity)>maxspeed)
 404                 {
 405                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 406                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 407                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 408
 409                         if(fabs(deviation.y)>10)
 410                                 this.movement_x = 0;
 411
 412                         if(deviation.y>10)
 413                                 this.movement_y = maxspeed * -1;
 414                         else if(deviation.y<10)
 415                                 this.movement_y = maxspeed;
 416
 417                 }
 418         }
 419 #endif
 420 }
 421
 422 .entity goalcurrent_prev;
 423 .float goalcurrent_distance;
 424 .float goalcurrent_distance_time;
 425 void havocbot_movetogoal(entity this)
 426 {
 427         vector destorg;
 428         vector diff;
 429         vector dir;
 430         vector flatdir;
 431         vector m1;
 432         vector m2;
 433         vector evadeobstacle;
 434         vector evadelava;
 435         float maxspeed;
 436         vector gco;
 437         //float dist;
 438         vector dodge;
 439         //if (this.goalentity)
 440         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 441         this.movement = '0 0 0';
 442         maxspeed = autocvar_sv_maxspeed;
 443
 444         // Jetpack navigation
 445         if(this.goalcurrent)
 446         if(this.navigation_jetpack_goal)
 447         if(this.goalcurrent==this.navigation_jetpack_goal)
 448         if(this.ammo_fuel)
 449         {
 450                 if(autocvar_bot_debug_goalstack)
 451                 {
 452                         debuggoalstack(this);
 453                         te_wizspike(this.navigation_jetpack_point);
 454                 }
 455
 456                 // Take off
 457                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 458                 {
 459                         // Brake almost completely so it can get a good direction
 460                         if(vdist(this.velocity, >, 10))
 461                                 return;
 462                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 463                 }
 464
 465                 makevectors(this.v_angle.y * '0 1 0');
 466                 dir = normalize(this.navigation_jetpack_point - this.origin);
 467
 468                 // Landing
 469                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 470                 {
 471                         // Calculate brake distance in xy
 472                         float db, v, d;
 473                         vector dxy;
 474
 475                         dxy = this.origin - ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 476                         d = vlen(dxy);
 477                         v = vlen(this.velocity -  this.velocity.z * '0 0 1');
 478                         db = (pow(v,2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 479                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 480                         if(d < db || d < 500)
 481                         {
 482                                 // Brake
 483                                 if(fabs(this.velocity.x)>maxspeed*0.3)
 484                                 {
 485                                         this.movement_x = dir * v_forward * -maxspeed;
 486                                         return;
 487                                 }
 488                                 // Switch to normal mode
 489                                 this.navigation_jetpack_goal = NULL;
 490                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 491                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 492                                 return;
 493                         }
 494                 }
 495                 else if(checkpvs(this.origin,this.goalcurrent))
 496                 {
 497                         // If I can see the goal switch to landing code
 498                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 499                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 500                         return;
 501                 }
 502
 503                 // Flying
 504                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 505                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 506                 {
 507                         this.movement_x = dir * v_forward * maxspeed;
 508                         this.movement_y = dir * v_right * maxspeed;
 509                 }
 510                 return;
 511         }
 512
 513         // Handling of jump pads
 514         if(this.jumppadcount)
 515         {
 516                 // If got stuck on the jump pad try to reach the farthest visible waypoint
 517                 // but with some randomness so it can try out different paths
 518                 if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 519                 {
 520                         if(fabs(this.velocity.z)<50)
 521                         {
 522                                 entity newgoal = NULL;
 523                                 if (vdist(this.origin - this.goalcurrent.origin, <, 150))
 524                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 525                                 else IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 526                                 {
 527                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 528
 529                                         if(trace_fraction < 1)
 530                                                 continue;
 531
 532                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 533                                                 newgoal = it;
 534                                 });
 535
 536                                 if(newgoal)
 537                                 {
 538                                         this.ignoregoal = this.goalcurrent;
 539                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 540                                         navigation_clearroute(this);
 541                                         navigation_routetogoal(this, newgoal, this.origin);
 542                                         if(autocvar_bot_debug_goalstack)
 543                                                 debuggoalstack(this);
 544                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 545                                 }
 546                         }
 547                         else
 548                                 return;
 549                 }
 550                 else
 551                 {
 552                         if(time - this.lastteleporttime > 0.3 && this.velocity.z > 0)
 553                         {
 554                                 vector velxy = this.velocity; velxy_z = 0;
 555                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 556                                 {
 557                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 558                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 559                                 }
 560                                 return;
 561                         }
 562
 563                         // Don't chase players while using a jump pad
 564                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 565                                 return;
 566                 }
 567         }
 568         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 569                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 570
 571         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 572         if(skill>6)
 573         if (!(IS_ONGROUND(this)))
 574         {
 575                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 576                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 577                 if(this.items & IT_JETPACK)
 578                 {
 579                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 580                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 581                         {
 582                                 if(this.velocity.z<0)
 583                                 {
 584                                         PHYS_INPUT_BUTTON_HOOK(this) = true;
 585                                 }
 586                         }
 587                         else
 588                                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 589
 590                         // If there is no goal try to move forward
 591
 592                         if(this.goalcurrent==NULL)
 593                                 dir = v_forward;
 594                         else
 595                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 596
 597                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 598                         float xyspeed = xyvelocity * dir;
 599
 600                         if(xyspeed < (maxspeed / 2))
 601                         {
 602                                 makevectors(this.v_angle.y * '0 1 0');
 603                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 604                                 if(trace_fraction==1)
 605                                 {
 606                                         this.movement_x = dir * v_forward * maxspeed;
 607                                         this.movement_y = dir * v_right * maxspeed;
 608                                         if (skill < 10)
 609                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 610                                 }
 611                         }
 612
 613                         this.havocbot_blockhead = true;
 614
 615                         return;
 616                 }
 617                 else if(this.health>WEP_CVAR(devastator, damage)*0.5)
 618                 {
 619                         if(this.velocity.z < 0)
 620                         {
 621                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 622                                 {
 623                                         .entity weaponentity = weaponentities[slot];
 624
 625                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 626                                                 continue;
 627
 628                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 629                                         {
 630                                                 this.movement_x = maxspeed;
 631
 632                                                 if(this.rocketjumptime)
 633                                                 {
 634                                                         if(time > this.rocketjumptime)
 635                                                         {
 636                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 637                                                                 this.rocketjumptime = 0;
 638                                                         }
 639                                                         return;
 640                                                 }
 641
 642                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 643                                                 this.v_angle_x = 90;
 644                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 645                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 646                                                 return;
 647                                         }
 648                                 }
 649                         }
 650                 }
 651                 else
 652                 {
 653                         // If there is no goal try to move forward
 654                         if(this.goalcurrent==NULL)
 655                                 this.movement_x = maxspeed;
 656                 }
 657         }
 658
 659         // If we are under water with no goals, swim up
 660         if(this.waterlevel)
 661         if(this.goalcurrent==NULL)
 662         {
 663                 dir = '0 0 0';
 664                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 665                         dir.z = 1;
 666                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 667                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 668                 else
 669                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 670                 makevectors(this.v_angle.y * '0 1 0');
 671                 this.movement_x = dir * v_forward * maxspeed;
 672                 this.movement_y = dir * v_right * maxspeed;
 673                 this.movement_z = dir * v_up * maxspeed;
 674         }
 675
 676         // if there is nowhere to go, exit
 677         if (this.goalcurrent == NULL)
 678                 return;
 679
 680
 681         bool locked_goal = false;
 682         if(this.goalentity && wasfreed(this.goalentity))
 683         {
 684                 navigation_clearroute(this);
 685                 this.bot_strategytime = 0;
 686                 return;
 687         }
 688         else if(this.goalentity.bot_pickup)
 689         {
 690                 if(this.goalentity.bot_pickup_respawning)
 691                 {
 692                         if(this.goalentity.solid) // item respawned
 693                                 this.goalentity.bot_pickup_respawning = false;
 694                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 695                         {
 696                                 this.goalentity.bot_pickup_respawning = false;
 697                                 navigation_clearroute(this);
 698                                 this.bot_strategytime = 0;
 699                                 return;
 700                         }
 701                         else if(this.goalentity == this.goalcurrent)
 702                                 locked_goal = true; // wait for item to respawn
 703                 }
 704                 else if(!this.goalentity.solid)
 705                 {
 706                         navigation_clearroute(this);
 707                         this.bot_strategytime = 0;
 708                         return;
 709                 }
 710         }
 711         if(!locked_goal)
 712                 navigation_poptouchedgoals(this);
 713
 714         // if ran out of goals try to use an alternative goal or get a new strategy asap
 715         if(this.goalcurrent == NULL)
 716         {
 717                 this.bot_strategytime = 0;
 718                 return;
 719         }
 720
 721
 722         if(autocvar_bot_debug_goalstack)
 723                 debuggoalstack(this);
 724
 725         m1 = this.goalcurrent.origin + this.goalcurrent.mins;
 726         m2 = this.goalcurrent.origin + this.goalcurrent.maxs;
 727         destorg = this.origin;
 728         destorg.x = bound(m1_x, destorg.x, m2_x);
 729         destorg.y = bound(m1_y, destorg.y, m2_y);
 730         destorg.z = bound(m1_z, destorg.z, m2_z);
 731         diff = destorg - this.origin;
 732         //dist = vlen(diff);
 733         dir = normalize(diff);
 734         flatdir = diff;flatdir.z = 0;
 735         flatdir = normalize(flatdir);
 736         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 737
 738         //if (this.bot_dodgevector_time < time)
 739         {
 740         //      this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 741         //      this.bot_dodgevector_jumpbutton = 1;
 742                 evadeobstacle = '0 0 0';
 743                 evadelava = '0 0 0';
 744
 745                 makevectors(this.v_angle.y * '0 1 0');
 746                 if (this.waterlevel)
 747                 {
 748                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 749                         {
 750                         //      flatdir_z = 1;
 751                                 this.aistatus |= AI_STATUS_OUT_WATER;
 752                         }
 753                         else
 754                         {
 755                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 756                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 757                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 758                                 else
 759                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 760                         }
 761                         dir = normalize(flatdir);
 762                 }
 763                 else
 764                 {
 765                         float s;
 766                         vector offset;
 767                         if(this.aistatus & AI_STATUS_OUT_WATER)
 768                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 769
 770                         // jump if going toward an obstacle that doesn't look like stairs we
 771                         // can walk up directly
 772                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 773                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 774                         if (trace_fraction < 1)
 775                         if (trace_plane_normal.z < 0.7)
 776                         {
 777                                 s = trace_fraction;
 778                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 779                                 if (trace_fraction < s + 0.01)
 780                                 if (trace_plane_normal.z < 0.7)
 781                                 {
 782                                         s = trace_fraction;
 783                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 784                                         if (trace_fraction > s)
 785                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 786                                 }
 787                         }
 788
 789                         // if bot for some reason doesn't get close to the current goal find another one
 790                         float curr_dist = vlen(this.origin - this.goalcurrent.origin);
 791                         if(!IS_PLAYER(this.goalcurrent))
 792                         {
 793                                 if(this.goalcurrent != this.goalcurrent_prev)
 794                                 {
 795                                         this.goalcurrent_prev = this.goalcurrent;
 796                                         this.goalcurrent_distance = curr_dist;
 797                                         this.goalcurrent_distance_time = 0;
 798                                 }
 799                                 else if(curr_dist > this.goalcurrent_distance)
 800                                 {
 801                                         if(!this.goalcurrent_distance_time)
 802                                                 this.goalcurrent_distance_time = time;
 803                                         else if (time - this.goalcurrent_distance_time > 0.5)
 804                                         {
 805                                                 this.goalcurrent_prev = NULL;
 806                                                 navigation_clearroute(this);
 807                                                 this.bot_strategytime = 0;
 808                                                 return;
 809                                         }
 810                                 }
 811                                 else
 812                                 {
 813                                         // reduce it a little bit so it works even with very small approaches to the goal
 814                                         this.goalcurrent_distance = max(20, curr_dist - 15);
 815                                         this.goalcurrent_distance_time = 0;
 816                                 }
 817                         }
 818
 819                         // Check for water/slime/lava and dangerous edges
 820                         // (only when the bot is on the ground or jumping intentionally)
 821                         this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 822
 823                         vector dst_ahead = this.origin + this.view_ofs + offset;
 824                         vector dst_down = dst_ahead - '0 0 3000';
 825                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 826
 827                         bool unreachable = false;
 828                         s = CONTENT_SOLID;
 829                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 830                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 831                         {
 832                                 // Look downwards
 833                                 traceline(dst_ahead , dst_down, true, NULL);
 834                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 835                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 836                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 837                                 {
 838                                         s = pointcontents(trace_endpos + '0 0 1');
 839                                         if (s != CONTENT_SOLID)
 840                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 841                                                 evadelava = normalize(this.velocity) * -1;
 842                                         else if (s == CONTENT_SKY)
 843                                                 evadeobstacle = normalize(this.velocity) * -1;
 844                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 845                                         {
 846                                                 // the traceline check isn't enough but is good as optimization,
 847                                                 // when not true (most of the time) this tracebox call is avoided
 848                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 849                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 850                                                 {
 851                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 852                                                         {
 853                                                                 // the goal is probably on an upper platform, assume bot can't get there
 854                                                                 unreachable = true;
 855                                                         }
 856                                                         else
 857                                                                 evadelava = normalize(this.velocity) * -1;
 858                                                 }
 859                                         }
 860                                 }
 861                         }
 862
 863                         dir = flatdir;
 864                         evadeobstacle.z = 0;
 865                         evadelava.z = 0;
 866                         makevectors(this.v_angle.y * '0 1 0');
 867
 868                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 869                         {
 870                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 871                                 if(IS_PLAYER(this.goalcurrent))
 872                                         unreachable = true;
 873                         }
 874                         if(unreachable)
 875                         {
 876                                 navigation_clearroute(this);
 877                                 this.bot_strategytime = 0;
 878                         }
 879                 }
 880
 881                 dodge = havocbot_dodge(this);
 882                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 883                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 884                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 885                 if(IS_PLAYER(trace_ent))
 886                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 887
 888                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 889         //      this.bot_dodgevector = dir;
 890         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 891         }
 892
 893         if(time < this.ladder_time)
 894         {
 895                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 896                 {
 897                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 898                                 dir.z = 1;
 899                 }
 900                 else
 901                 {
 902                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 903                                 dir.z = -1;
 904                 }
 905         }
 906
 907         //dir = this.bot_dodgevector;
 908         //if (this.bot_dodgevector_jumpbutton)
 909         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 910         this.movement_x = dir * v_forward * maxspeed;
 911         this.movement_y = dir * v_right * maxspeed;
 912         this.movement_z = dir * v_up * maxspeed;
 913
 914         // Emulate keyboard interface
 915         if (skill < 10)
 916                 havocbot_keyboard_movement(this, destorg);
 917
 918         // Bunnyhop!
 919 //      if(this.aistatus & AI_STATUS_ROAMING)
 920         if(this.goalcurrent)
 921         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 922                 havocbot_bunnyhop(this, dir);
 923
 924         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 925         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 926         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 927 }
 928
 929 entity havocbot_gettarget(entity this, bool secondary)
 930 {
 931         entity best = NULL;
 932         vector eye = CENTER_OR_VIEWOFS(this);
 933         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 934         {
 935                 vector v = CENTER_OR_VIEWOFS(it);
 936                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 937                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 938                 if(bot_shouldattack(this, it))
 939                 {
 940                         traceline(eye, v, true, this);
 941                         if (trace_ent == it || trace_fraction >= 1)
 942                                 best = it;
 943                 }
 944         });
 945
 946         return best;
 947 }
 948
 949 void havocbot_chooseenemy(entity this)
 950 {
 951         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 952         {
 953                 this.enemy = NULL;
 954                 return;
 955         }
 956         if (this.enemy)
 957         {
 958                 if (!bot_shouldattack(this, this.enemy))
 959                 {
 960                         // enemy died or something, find a new target
 961                         this.enemy = NULL;
 962                         this.havocbot_chooseenemy_finished = time;
 963                 }
 964                 else if (this.havocbot_stickenemy)
 965                 {
 966                         // tracking last chosen enemy
 967                         // if enemy is visible
 968                         // and not really really far away
 969                         // and we're not severely injured
 970                         // then keep tracking for a half second into the future
 971                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
 972                         if (trace_ent == this.enemy || trace_fraction == 1)
 973                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
 974                         if (this.health > 30)
 975                         {
 976                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 977                                 this.havocbot_chooseenemy_finished = time + 0.5;
 978                                 return;
 979                         }
 980                         // enemy isn't visible, or is far away, or we're injured severely
 981                         // so stop preferring this enemy
 982                         // (it will still take a half second until a new one is chosen)
 983                         this.havocbot_stickenemy = 0;
 984                 }
 985         }
 986         if (time < this.havocbot_chooseenemy_finished)
 987                 return;
 988         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 989         vector eye = this.origin + this.view_ofs;
 990         entity best = NULL;
 991         float bestrating = 100000000;
 992
 993         // Backup hit flags
 994         int hf = this.dphitcontentsmask;
 995
 996         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
 997
 998         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 999
1000         bool scan_transparent = false;
1001         bool scan_secondary_targets = false;
1002         bool have_secondary_targets = false;
1003         while(true)
1004         {
1005                 scan_secondary_targets = false;
1006 LABEL(scan_targets)
1007                 IL_EACH(g_bot_targets, it.bot_attack,
1008                 {
1009                         if(!scan_secondary_targets)
1010                         {
1011                                 if(it.classname == "misc_breakablemodel")
1012                                 {
1013                                         have_secondary_targets = true;
1014                                         continue;
1015                                 }
1016                         }
1017                         else if(it.classname != "misc_breakablemodel")
1018                                 continue;
1019
1020                         vector v = (it.absmin + it.absmax) * 0.5;
1021                         float rating = vlen2(v - eye);
1022                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1023                         if (bestrating > rating)
1024                         if (bot_shouldattack(this, it))
1025                         {
1026                                 traceline(eye, v, true, this);
1027                                 if (trace_ent == it || trace_fraction >= 1)
1028                                 {
1029                                         best = it;
1030                                         bestrating = rating;
1031                                 }
1032                         }
1033                 });
1034
1035                 if(!best && have_secondary_targets && !scan_secondary_targets)
1036                 {
1037                         scan_secondary_targets = true;
1038                         // restart the loop
1039                         bestrating = 100000000;
1040                         goto scan_targets;
1041                 }
1042
1043                 // I want to do a second scan if no enemy was found or I don't have weapons
1044                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1045                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1046                         break;
1047                 if(scan_transparent)
1048                         break;
1049
1050                 // Set flags to see through transparent objects
1051                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1052
1053                 scan_transparent = true;
1054         }
1055
1056         // Restore hit flags
1057         this.dphitcontentsmask = hf;
1058
1059         this.enemy = best;
1060         this.havocbot_stickenemy = true;
1061         if(best && best.classname == "misc_breakablemodel")
1062                 this.havocbot_stickenemy = false;
1063 }
1064
1065 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1066 {
1067         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1068         // so skip this for them, or they'll never get to reload their weapons at all.
1069         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1070         if(skill < 5)
1071                 return false;
1072
1073         // if this weapon is scheduled for reloading, don't switch to it during combat
1074         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1075         {
1076                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1077                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1078                                 return true; // other weapon available
1079                 ));
1080         }
1081
1082         return false;
1083 }
1084
1085 void havocbot_chooseweapon(entity this, .entity weaponentity)
1086 {
1087         int i;
1088
1089         // ;)
1090         if(g_weaponarena_weapons == WEPSET(TUBA))
1091         {
1092                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1093                 return;
1094         }
1095
1096         // TODO: clean this up by moving it to weapon code
1097         if(this.enemy==NULL)
1098         {
1099                 // If no weapon was chosen get the first available weapon
1100                 if(this.(weaponentity).m_weapon==WEP_Null)
1101                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1102                         if(client_hasweapon(this, it, weaponentity, true, false))
1103                         {
1104                                 this.(weaponentity).m_switchweapon = it;
1105                                 return;
1106                         }
1107                 ));
1108                 return;
1109         }
1110
1111         // Do not change weapon during the next second after a combo
1112         float f = time - this.lastcombotime;
1113         if(f < 1)
1114                 return;
1115
1116         float w;
1117         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1118
1119         // Should it do a weapon combo?
1120         float af, ct, combo_time, combo;
1121
1122         af = ATTACK_FINISHED(this, 0);
1123         ct = autocvar_bot_ai_weapon_combo_threshold;
1124
1125         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1126         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1127         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1128
1129         combo = false;
1130
1131         if(autocvar_bot_ai_weapon_combo)
1132         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1133         if(af > combo_time)
1134         {
1135                 combo = true;
1136                 this.lastcombotime = time;
1137         }
1138
1139         distance *= pow(2, this.bot_rangepreference);
1140
1141         // Custom weapon list based on distance to the enemy
1142         if(bot_custom_weapon){
1143
1144                 // Choose weapons for far distance
1145                 if ( distance > bot_distance_far ) {
1146                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1147                                 w = bot_weapons_far[i];
1148                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1149                                 {
1150                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1151                                                 continue;
1152                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1153                                         return;
1154                                 }
1155                         }
1156                 }
1157
1158                 // Choose weapons for mid distance
1159                 if ( distance > bot_distance_close) {
1160                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1161                                 w = bot_weapons_mid[i];
1162                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1163                                 {
1164                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1165                                                 continue;
1166                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1167                                         return;
1168                                 }
1169                         }
1170                 }
1171
1172                 // Choose weapons for close distance
1173                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1174                         w = bot_weapons_close[i];
1175                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1176                         {
1177                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1178                                         continue;
1179                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1180                                 return;
1181                         }
1182                 }
1183         }
1184 }
1185
1186 void havocbot_aim(entity this)
1187 {
1188         vector myvel, enemyvel;
1189 //      if(this.flags & FL_INWATER)
1190 //              return;
1191         if (time < this.nextaim)
1192                 return;
1193         this.nextaim = time + 0.1;
1194         myvel = this.velocity;
1195         if (!this.waterlevel)
1196                 myvel.z = 0;
1197         if (this.enemy)
1198         {
1199                 enemyvel = this.enemy.velocity;
1200                 if (!this.enemy.waterlevel)
1201                         enemyvel.z = 0;
1202                 lag_additem(this, time + this.ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1203         }
1204         else
1205                 lag_additem(this, time + this.ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1206 }
1207
1208 bool havocbot_moveto_refresh_route(entity this)
1209 {
1210         // Refresh path to goal if necessary
1211         entity wp;
1212         wp = this.havocbot_personal_waypoint;
1213         navigation_goalrating_start(this);
1214         navigation_routerating(this, wp, 10000, 10000);
1215         navigation_goalrating_end(this);
1216         return this.navigation_hasgoals;
1217 }
1218
1219 float havocbot_moveto(entity this, vector pos)
1220 {
1221         entity wp;
1222
1223         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1224         {
1225                 // Step 4: Move to waypoint
1226                 if(this.havocbot_personal_waypoint==NULL)
1227                 {
1228                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1229                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1230                         return CMD_STATUS_ERROR;
1231                 }
1232
1233                 if (!bot_strategytoken_taken)
1234                 if(this.havocbot_personal_waypoint_searchtime<time)
1235                 {
1236                         bot_strategytoken_taken = true;
1237                         if(havocbot_moveto_refresh_route(this))
1238                         {
1239                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1240                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1241                                 this.havocbot_personal_waypoint_failcounter = 0;
1242                         }
1243                         else
1244                         {
1245                                 this.havocbot_personal_waypoint_failcounter += 1;
1246                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1247                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1248                                 {
1249                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1250                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1251                                         delete(this.havocbot_personal_waypoint);
1252                                         return CMD_STATUS_ERROR;
1253                                 }
1254                                 else
1255                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1256                         }
1257                 }
1258
1259                 if(autocvar_bot_debug_goalstack)
1260                         debuggoalstack(this);
1261
1262                 // Heading
1263                 vector dir = ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - (this.origin + this.view_ofs);
1264                 dir.z = 0;
1265                 bot_aimdir(this, dir, -1);
1266
1267                 // Go!
1268                 havocbot_movetogoal(this);
1269
1270                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1271                 {
1272                         // Step 5: Waypoint reached
1273                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1274                         delete(this.havocbot_personal_waypoint);
1275                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1276                         return CMD_STATUS_FINISHED;
1277                 }
1278
1279                 return CMD_STATUS_EXECUTING;
1280         }
1281
1282         // Step 2: Linking waypoint
1283         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1284         {
1285                 // Wait until it is linked
1286                 if(!this.havocbot_personal_waypoint.wplinked)
1287                 {
1288                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1289                         return CMD_STATUS_EXECUTING;
1290                 }
1291
1292                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1293                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1294                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1295
1296                 // Step 3: Route to waypoint
1297                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1298
1299                 return CMD_STATUS_EXECUTING;
1300         }
1301
1302         // Step 1: Spawning waypoint
1303         wp = waypoint_spawnpersonal(this, pos);
1304         if(wp==NULL)
1305         {
1306                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1307                 return CMD_STATUS_ERROR;
1308         }
1309
1310         this.havocbot_personal_waypoint = wp;
1311         this.havocbot_personal_waypoint_failcounter = 0;
1312         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1313
1314         // if pos is inside a teleport, then let's mark it as teleport waypoint
1315         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1316         {
1317                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1318                 this.lastteleporttime = 0;
1319         });
1320
1321 /*
1322         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1323                 print("routing to a teleporter\n");
1324         else
1325                 print("routing to a non-teleporter\n");
1326 */
1327
1328         return CMD_STATUS_EXECUTING;
1329 }
1330
1331 float havocbot_resetgoal(entity this)
1332 {
1333         navigation_clearroute(this);
1334         return CMD_STATUS_FINISHED;
1335 }
1336
1337 void havocbot_setupbot(entity this)
1338 {
1339         this.bot_ai = havocbot_ai;
1340         this.cmd_moveto = havocbot_moveto;
1341         this.cmd_resetgoal = havocbot_resetgoal;
1342
1343         havocbot_chooserole(this);
1344 }
1345
1346 vector havocbot_dodge(entity this)
1347 {
1348         // LordHavoc: disabled because this is too expensive
1349         return '0 0 0';
1350 #if 0
1351         entity head;
1352         vector dodge, v, n;
1353         float danger, bestdanger, vl, d;
1354         dodge = '0 0 0';
1355         bestdanger = -20;
1356         // check for dangerous objects near bot or approaching bot
1357         head = findchainfloat(bot_dodge, true);
1358         while(head)
1359         {
1360                 if (head.owner != this)
1361                 {
1362                         vl = vlen(head.velocity);
1363                         if (vl > autocvar_sv_maxspeed * 0.3)
1364                         {
1365                                 n = normalize(head.velocity);
1366                                 v = this.origin - head.origin;
1367                                 d = v * n;
1368                                 if (d > (0 - head.bot_dodgerating))
1369                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1370                                 {
1371                                         // calculate direction and distance from the flight path, by removing the forward axis
1372                                         v = v - (n * (v * n));
1373                                         danger = head.bot_dodgerating - vlen(v);
1374                                         if (bestdanger < danger)
1375                                         {
1376                                                 bestdanger = danger;
1377                                                 // dodge to the side of the object
1378                                                 dodge = normalize(v);
1379                                         }
1380                                 }
1381                         }
1382                         else
1383                         {
1384                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1385                                 if (bestdanger < danger)
1386                                 {
1387                                         bestdanger = danger;
1388                                         dodge = normalize(this.origin - head.origin);
1389                                 }
1390                         }
1391                 }
1392                 head = head.chain;
1393         }
1394         return dodge;
1395 #endif
1396 }