qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "../cvars.qh"
   4
   5 #include "../aim.qh"
   6 #include "../bot.qh"
   7 #include "../navigation.qh"
   8 #include "../scripting.qh"
   9 #include "../waypoints.qh"
  10
  11 #include <common/constants.qh>
  12 #include <common/impulses/all.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15 #include <common/state.qh>
  16 #include <common/items/_mod.qh>
  17 #include <common/wepent.qh>
  18
  19 #include <common/triggers/teleporters.qh>
  20 #include <common/triggers/trigger/jumppads.qh>
  21
  22 #include <lib/warpzone/common.qh>
  23
  24 .float speed;
  25
  26 void havocbot_ai(entity this)
  27 {
  28         if(this.draggedby)
  29                 return;
  30
  31         if(bot_execute_commands(this))
  32                 return;
  33
  34         if (bot_strategytoken == this)
  35         if (!bot_strategytoken_taken)
  36         {
  37                 if(this.havocbot_blockhead)
  38                 {
  39                         this.havocbot_blockhead = false;
  40                 }
  41                 else
  42                 {
  43                         if (!this.jumppadcount)
  44                                 this.havocbot_role(this); // little too far down the rabbit hole
  45                 }
  46
  47                 // TODO: tracewalk() should take care of this job (better path finding under water)
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this))
  87                 return;
  88
  89         havocbot_chooseenemy(this);
  90
  91         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  92         {
  93                 .entity weaponentity = weaponentities[slot];
  94                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  95                 if(this.(weaponentity).bot_chooseweapontime < time)
  96                 {
  97                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  98                         havocbot_chooseweapon(this, weaponentity);
  99                 }
 100         }
 101         havocbot_aim(this);
 102         lag_update(this);
 103         if (this.bot_aimtarg)
 104         {
 105                 this.aistatus |= AI_STATUS_ATTACKING;
 106                 this.aistatus &= ~AI_STATUS_ROAMING;
 107
 108                 if(this.weapons)
 109                 {
 110                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 111                         {
 112                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 113                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 114                         }
 115                         else
 116                         {
 117                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 118                                 {
 119                                         .entity weaponentity = weaponentities[slot];
 120                                         Weapon w = this.(weaponentity).m_weapon;
 121                                         if(w == WEP_Null && slot != 0)
 122                                                 continue;
 123                                         w.wr_aim(w, this, weaponentity);
 124                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 125                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 126                                 }
 127                         }
 128                 }
 129                 else
 130                 {
 131                         if(IS_PLAYER(this.bot_aimtarg))
 132                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 133                 }
 134         }
 135         else if (this.goalcurrent)
 136         {
 137                 this.aistatus |= AI_STATUS_ROAMING;
 138                 this.aistatus &= ~AI_STATUS_ATTACKING;
 139
 140                 vector now,v,next;//,heading;
 141                 float aimdistance,skillblend,distanceblend,blend;
 142                 next = now = ( (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5) - (this.origin + this.view_ofs);
 143                 aimdistance = vlen(now);
 144                 //heading = this.velocity;
 145                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 146                 if(
 147                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 148                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 149                 )
 150                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 151
 152                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 153                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 154                 blend = skillblend * (1-distanceblend);
 155                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 156                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 157                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 158                 v = now + blend * (next - now);
 159                 //dprint(etos(this), " ");
 160                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 161                 //v = now * (distanceblend) + next * (1-distanceblend);
 162                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 163                         v.z = 0;
 164                 //dprint("walk at:", vtos(v), "\n");
 165                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 166                 bot_aimdir(this, v, -1);
 167         }
 168         havocbot_movetogoal(this);
 169
 170         // if the bot is not attacking, consider reloading weapons
 171         if (!(this.aistatus & AI_STATUS_ATTACKING))
 172         {
 173                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 174                 {
 175                         .entity weaponentity = weaponentities[slot];
 176
 177                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 178                                 continue;
 179
 180                         // we are currently holding a weapon that's not fully loaded, reload it
 181                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 182                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 183                                 this.impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 184
 185                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 186                         // the code above executes next frame, starting the reloading then
 187                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 188                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 189                         {
 190                                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 191                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 192                                         {
 193                                                 this.(weaponentity).m_switchweapon = it;
 194                                                 break;
 195                                         }
 196                                 ));
 197                         }
 198                 }
 199         }
 200 }
 201
 202 void havocbot_keyboard_movement(entity this, vector destorg)
 203 {
 204         vector keyboard;
 205         float blend, maxspeed;
 206         float sk;
 207
 208         sk = skill + this.bot_moveskill;
 209
 210         maxspeed = autocvar_sv_maxspeed;
 211
 212         if (time < this.havocbot_keyboardtime)
 213                 return;
 214
 215         this.havocbot_keyboardtime =
 216                 max(
 217                         this.havocbot_keyboardtime
 218                                 + 0.05/max(1, sk+this.havocbot_keyboardskill)
 219                                 + random()*0.025/max(0.00025, skill+this.havocbot_keyboardskill)
 220                 , time);
 221         keyboard = this.movement * (1.0 / maxspeed);
 222
 223         float trigger, trigger1;
 224         blend = bound(0,sk*0.1,1);
 225         trigger = autocvar_bot_ai_keyboard_threshold;
 226         trigger1 = 0 - trigger;
 227
 228         // categorize forward movement
 229         // at skill < 1.5 only forward
 230         // at skill < 2.5 only individual directions
 231         // at skill < 4.5 only individual directions, and forward diagonals
 232         // at skill >= 4.5, all cases allowed
 233         if (keyboard.x > trigger)
 234         {
 235                 keyboard.x = 1;
 236                 if (sk < 2.5)
 237                         keyboard.y = 0;
 238         }
 239         else if (keyboard.x < trigger1 && sk > 1.5)
 240         {
 241                 keyboard.x = -1;
 242                 if (sk < 4.5)
 243                         keyboard.y = 0;
 244         }
 245         else
 246         {
 247                 keyboard.x = 0;
 248                 if (sk < 1.5)
 249                         keyboard.y = 0;
 250         }
 251         if (sk < 4.5)
 252                 keyboard.z = 0;
 253
 254         if (keyboard.y > trigger)
 255                 keyboard.y = 1;
 256         else if (keyboard.y < trigger1)
 257                 keyboard.y = -1;
 258         else
 259                 keyboard.y = 0;
 260
 261         if (keyboard.z > trigger)
 262                 keyboard.z = 1;
 263         else if (keyboard.z < trigger1)
 264                 keyboard.z = -1;
 265         else
 266                 keyboard.z = 0;
 267
 268         this.havocbot_keyboard = keyboard * maxspeed;
 269         if (this.havocbot_ducktime>time) PHYS_INPUT_BUTTON_CROUCH(this) = true;
 270
 271         keyboard = this.havocbot_keyboard;
 272         blend = bound(0,vlen(destorg-this.origin)/autocvar_bot_ai_keyboard_distance,1); // When getting close move with 360 degree
 273         //dprint("movement ", vtos(this.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 274         this.movement = this.movement + (keyboard - this.movement) * blend;
 275 }
 276
 277 void havocbot_bunnyhop(entity this, vector dir)
 278 {
 279         float bunnyhopdistance;
 280         vector deviation;
 281         float maxspeed;
 282         vector gco, gno;
 283
 284         // Don't jump when attacking
 285         if(this.aistatus & AI_STATUS_ATTACKING)
 286                 return;
 287
 288         if(IS_PLAYER(this.goalcurrent))
 289                 return;
 290
 291         maxspeed = autocvar_sv_maxspeed;
 292
 293         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 294                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 295         {
 296                 this.aistatus &= ~AI_STATUS_RUNNING;
 297                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 298                 this.bot_canruntogoal = 0;
 299                 this.bot_timelastseengoal = 0;
 300                 return;
 301         }
 302
 303         if(this.waterlevel > WATERLEVEL_WETFEET)
 304         {
 305                 this.aistatus &= ~AI_STATUS_RUNNING;
 306                 return;
 307         }
 308
 309         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 310         {
 311                 this.bot_canruntogoal = 0;
 312                 this.bot_timelastseengoal = 0;
 313         }
 314
 315         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 316         bunnyhopdistance = vlen(this.origin - gco);
 317
 318         // Run only to visible goals
 319         if(IS_ONGROUND(this))
 320         if(vlen(this.velocity - eZ * this.velocity.z) >= autocvar_sv_maxspeed) // if -really- running
 321         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 322         {
 323                         this.bot_lastseengoal = this.goalcurrent;
 324
 325                         // seen it before
 326                         if(this.bot_timelastseengoal)
 327                         {
 328                                 // for a period of time
 329                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 330                                 {
 331                                         float checkdistance;
 332                                         checkdistance = true;
 333
 334                                         // don't run if it is too close
 335                                         if(this.bot_canruntogoal==0)
 336                                         {
 337                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 338                                                         this.bot_canruntogoal = 1;
 339                                                 else
 340                                                         this.bot_canruntogoal = -1;
 341                                         }
 342
 343                                         if(this.bot_canruntogoal != 1)
 344                                                 return;
 345
 346                                         if(this.aistatus & AI_STATUS_ROAMING)
 347                                         if(this.goalcurrent.classname=="waypoint")
 348                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 349                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 350                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 351                                         {
 352                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 353                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 354                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 355                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 356
 357                                                 if(fabs(deviation.y) < 20)
 358                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 359                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 360                                                 {
 361                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 362                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 363                                                         {
 364                                                                 checkdistance = false;
 365                                                         }
 366                                                 }
 367                                         }
 368
 369                                         if(checkdistance)
 370                                         {
 371                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 372                                                 // increase stop distance in case the goal is on a slope or a lower platform
 373                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 374                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 375                                         }
 376                                         else
 377                                         {
 378                                                 this.aistatus |= AI_STATUS_RUNNING;
 379                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 380                                         }
 381                                 }
 382                         }
 383                         else
 384                         {
 385                                 this.bot_timelastseengoal = time;
 386                         }
 387         }
 388         else
 389         {
 390                 this.bot_timelastseengoal = 0;
 391         }
 392
 393 #if 0
 394         // Release jump button
 395         if(!cvar("sv_pogostick"))
 396         if((IS_ONGROUND(this)) == 0)
 397         {
 398                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 399                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 400
 401                 // Strafe
 402                 if(this.aistatus & AI_STATUS_RUNNING)
 403                 if(vlen(this.velocity)>maxspeed)
 404                 {
 405                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 406                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 407                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 408
 409                         if(fabs(deviation.y)>10)
 410                                 this.movement_x = 0;
 411
 412                         if(deviation.y>10)
 413                                 this.movement_y = maxspeed * -1;
 414                         else if(deviation.y<10)
 415                                 this.movement_y = maxspeed;
 416
 417                 }
 418         }
 419 #endif
 420 }
 421
 422 void havocbot_movetogoal(entity this)
 423 {
 424         vector destorg;
 425         vector diff;
 426         vector dir;
 427         vector flatdir;
 428         vector m1;
 429         vector m2;
 430         vector evadeobstacle;
 431         vector evadelava;
 432         float maxspeed;
 433         vector gco;
 434         //float dist;
 435         vector dodge;
 436         //if (this.goalentity)
 437         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 438         this.movement = '0 0 0';
 439         maxspeed = autocvar_sv_maxspeed;
 440
 441         // Jetpack navigation
 442         if(this.goalcurrent)
 443         if(this.navigation_jetpack_goal)
 444         if(this.goalcurrent==this.navigation_jetpack_goal)
 445         if(this.ammo_fuel)
 446         {
 447                 if(autocvar_bot_debug_goalstack)
 448                 {
 449                         debuggoalstack(this);
 450                         te_wizspike(this.navigation_jetpack_point);
 451                 }
 452
 453                 // Take off
 454                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 455                 {
 456                         // Brake almost completely so it can get a good direction
 457                         if(vdist(this.velocity, >, 10))
 458                                 return;
 459                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 460                 }
 461
 462                 makevectors(this.v_angle.y * '0 1 0');
 463                 dir = normalize(this.navigation_jetpack_point - this.origin);
 464
 465                 // Landing
 466                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 467                 {
 468                         // Calculate brake distance in xy
 469                         float db, v, d;
 470                         vector dxy;
 471
 472                         dxy = this.origin - ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 473                         d = vlen(dxy);
 474                         v = vlen(this.velocity -  this.velocity.z * '0 0 1');
 475                         db = (pow(v,2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 476                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 477                         if(d < db || d < 500)
 478                         {
 479                                 // Brake
 480                                 if(fabs(this.velocity.x)>maxspeed*0.3)
 481                                 {
 482                                         this.movement_x = dir * v_forward * -maxspeed;
 483                                         return;
 484                                 }
 485                                 // Switch to normal mode
 486                                 this.navigation_jetpack_goal = NULL;
 487                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 488                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 489                                 return;
 490                         }
 491                 }
 492                 else if(checkpvs(this.origin,this.goalcurrent))
 493                 {
 494                         // If I can see the goal switch to landing code
 495                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 496                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 497                         return;
 498                 }
 499
 500                 // Flying
 501                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 502                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 503                 {
 504                         this.movement_x = dir * v_forward * maxspeed;
 505                         this.movement_y = dir * v_right * maxspeed;
 506                 }
 507                 return;
 508         }
 509
 510         // Handling of jump pads
 511         if(this.jumppadcount)
 512         {
 513                 // If got stuck on the jump pad try to reach the farthest visible waypoint
 514                 // but with some randomness so it can try out different paths
 515                 if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 516                 {
 517                         if(fabs(this.velocity.z)<50)
 518                         {
 519                                 entity newgoal = NULL;
 520                                 if (vdist(this.origin - this.goalcurrent.origin, <, 150))
 521                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 522                                 else IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 523                                 {
 524                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 525
 526                                         if(trace_fraction < 1)
 527                                                 continue;
 528
 529                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 530                                                 newgoal = it;
 531                                 });
 532
 533                                 if(newgoal)
 534                                 {
 535                                         this.ignoregoal = this.goalcurrent;
 536                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 537                                         navigation_clearroute(this);
 538                                         navigation_routetogoal(this, newgoal, this.origin);
 539                                         if(autocvar_bot_debug_goalstack)
 540                                                 debuggoalstack(this);
 541                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 542                                 }
 543                         }
 544                         else
 545                                 return;
 546                 }
 547                 else
 548                 {
 549                         if(time - this.lastteleporttime > 0.3 && this.velocity.z > 0)
 550                         {
 551                                 vector velxy = this.velocity; velxy_z = 0;
 552                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 553                                 {
 554                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 555                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 556                                 }
 557                                 return;
 558                         }
 559
 560                         // Don't chase players while using a jump pad
 561                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 562                                 return;
 563                 }
 564         }
 565         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 566                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 567
 568         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 569         if(skill>6)
 570         if (!(IS_ONGROUND(this)))
 571         {
 572                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 573                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 574                 if(this.items & IT_JETPACK)
 575                 {
 576                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 577                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 578                         {
 579                                 if(this.velocity.z<0)
 580                                 {
 581                                         PHYS_INPUT_BUTTON_HOOK(this) = true;
 582                                 }
 583                         }
 584                         else
 585                                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 586
 587                         // If there is no goal try to move forward
 588
 589                         if(this.goalcurrent==NULL)
 590                                 dir = v_forward;
 591                         else
 592                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 593
 594                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 595                         float xyspeed = xyvelocity * dir;
 596
 597                         if(xyspeed < (maxspeed / 2))
 598                         {
 599                                 makevectors(this.v_angle.y * '0 1 0');
 600                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 601                                 if(trace_fraction==1)
 602                                 {
 603                                         this.movement_x = dir * v_forward * maxspeed;
 604                                         this.movement_y = dir * v_right * maxspeed;
 605                                         if (skill < 10)
 606                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 607                                 }
 608                         }
 609
 610                         this.havocbot_blockhead = true;
 611
 612                         return;
 613                 }
 614                 else if(this.health>WEP_CVAR(devastator, damage)*0.5)
 615                 {
 616                         if(this.velocity.z < 0)
 617                         {
 618                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 619                                 {
 620                                         .entity weaponentity = weaponentities[slot];
 621
 622                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 623                                                 continue;
 624
 625                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 626                                         {
 627                                                 this.movement_x = maxspeed;
 628
 629                                                 if(this.rocketjumptime)
 630                                                 {
 631                                                         if(time > this.rocketjumptime)
 632                                                         {
 633                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 634                                                                 this.rocketjumptime = 0;
 635                                                         }
 636                                                         return;
 637                                                 }
 638
 639                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 640                                                 this.v_angle_x = 90;
 641                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 642                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 643                                                 return;
 644                                         }
 645                                 }
 646                         }
 647                 }
 648                 else
 649                 {
 650                         // If there is no goal try to move forward
 651                         if(this.goalcurrent==NULL)
 652                                 this.movement_x = maxspeed;
 653                 }
 654         }
 655
 656         // If we are under water with no goals, swim up
 657         if(this.waterlevel)
 658         if(this.goalcurrent==NULL)
 659         {
 660                 dir = '0 0 0';
 661                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 662                         dir.z = 1;
 663                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 664                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 665                 else
 666                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 667                 makevectors(this.v_angle.y * '0 1 0');
 668                 this.movement_x = dir * v_forward * maxspeed;
 669                 this.movement_y = dir * v_right * maxspeed;
 670                 this.movement_z = dir * v_up * maxspeed;
 671         }
 672
 673         // if there is nowhere to go, exit
 674         if (this.goalcurrent == NULL)
 675                 return;
 676
 677
 678         bool locked_goal = false;
 679         if(this.goalentity && wasfreed(this.goalentity))
 680         {
 681                 navigation_clearroute(this);
 682                 this.bot_strategytime = 0;
 683                 return;
 684         }
 685         else if(this.goalentity.bot_pickup)
 686         {
 687                 if(this.goalentity.bot_pickup_respawning)
 688                 {
 689                         if(this.goalentity.solid) // item respawned
 690                                 this.goalentity.bot_pickup_respawning = false;
 691                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 692                         {
 693                                 this.goalentity.bot_pickup_respawning = false;
 694                                 navigation_clearroute(this);
 695                                 this.bot_strategytime = 0;
 696                                 return;
 697                         }
 698                         else if(this.goalentity == this.goalcurrent)
 699                                 locked_goal = true; // wait for item to respawn
 700                 }
 701                 else if(!this.goalentity.solid)
 702                 {
 703                         navigation_clearroute(this);
 704                         this.bot_strategytime = 0;
 705                         return;
 706                 }
 707         }
 708         if(!locked_goal)
 709                 navigation_poptouchedgoals(this);
 710
 711         // if ran out of goals try to use an alternative goal or get a new strategy asap
 712         if(this.goalcurrent == NULL)
 713         {
 714                 this.bot_strategytime = 0;
 715                 return;
 716         }
 717
 718
 719         if(autocvar_bot_debug_goalstack)
 720                 debuggoalstack(this);
 721
 722         m1 = this.goalcurrent.origin + this.goalcurrent.mins;
 723         m2 = this.goalcurrent.origin + this.goalcurrent.maxs;
 724         destorg = this.origin;
 725         destorg.x = bound(m1_x, destorg.x, m2_x);
 726         destorg.y = bound(m1_y, destorg.y, m2_y);
 727         destorg.z = bound(m1_z, destorg.z, m2_z);
 728         diff = destorg - this.origin;
 729         //dist = vlen(diff);
 730         dir = normalize(diff);
 731         flatdir = diff;flatdir.z = 0;
 732         flatdir = normalize(flatdir);
 733         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 734
 735         //if (this.bot_dodgevector_time < time)
 736         {
 737         //      this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 738         //      this.bot_dodgevector_jumpbutton = 1;
 739                 evadeobstacle = '0 0 0';
 740                 evadelava = '0 0 0';
 741
 742                 makevectors(this.v_angle.y * '0 1 0');
 743                 if (this.waterlevel)
 744                 {
 745                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 746                         {
 747                         //      flatdir_z = 1;
 748                                 this.aistatus |= AI_STATUS_OUT_WATER;
 749                         }
 750                         else
 751                         {
 752                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 753                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 754                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 755                                 else
 756                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 757                         }
 758                         dir = normalize(flatdir);
 759                 }
 760                 else
 761                 {
 762                         float s;
 763                         vector offset;
 764                         if(this.aistatus & AI_STATUS_OUT_WATER)
 765                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 766
 767                         // jump if going toward an obstacle that doesn't look like stairs we
 768                         // can walk up directly
 769                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 770                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 771                         if (trace_fraction < 1)
 772                         if (trace_plane_normal.z < 0.7)
 773                         {
 774                                 s = trace_fraction;
 775                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 776                                 if (trace_fraction < s + 0.01)
 777                                 if (trace_plane_normal.z < 0.7)
 778                                 {
 779                                         s = trace_fraction;
 780                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 781                                         if (trace_fraction > s)
 782                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 783                                 }
 784                         }
 785
 786                         // avoiding dangers and obstacles
 787                         offset = (vdist(this.velocity - eZ * this.velocity.z, >, 32) ? this.velocity * 0.5 : v_forward * 32);
 788                         vector dst_ahead = this.origin + offset;
 789                         vector dst_down = dst_ahead - '0 0 3000';
 790
 791                         // Check head-banging against walls
 792                         traceline(this.origin, dst_ahead, true, NULL);
 793                         if(vdist(this.origin - trace_endpos, <, 25) && !(this.aistatus & AI_STATUS_OUT_WATER))
 794                         {
 795                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 796                                 if(!this.facingwalltime)
 797                                         this.facingwalltime = time + 0.2;
 798                                 else if(time > this.facingwalltime)
 799                                 {
 800                                         navigation_clearroute(this);
 801                                         this.bot_strategytime = 0;
 802                                         return;
 803                                 }
 804                         }
 805                         else
 806                                 this.facingwalltime = 0;
 807
 808                         // Check for water/slime/lava and dangerous edges
 809                         // (only when the bot is on the ground or jumping intentionally)
 810                         this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 811
 812                         dst_ahead = this.origin + this.view_ofs + offset;
 813                         dst_down = dst_ahead - '0 0 3000';
 814
 815                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 816
 817                         bool unreachable = false;
 818                         s = CONTENT_SOLID;
 819                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 820                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 821                         {
 822                                 // Look downwards
 823                                 traceline(dst_ahead , dst_down, true, NULL);
 824                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 825                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 826                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 827                                 {
 828                                         s = pointcontents(trace_endpos + '0 0 1');
 829                                         if (s != CONTENT_SOLID)
 830                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 831                                                 evadelava = normalize(this.velocity) * -1;
 832                                         else if (s == CONTENT_SKY)
 833                                                 evadeobstacle = normalize(this.velocity) * -1;
 834                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 835                                         {
 836                                                 // the traceline check isn't enough but is good as optimization,
 837                                                 // when not true (most of the time) this tracebox call is avoided
 838                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 839                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 840                                                 {
 841                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 842                                                         {
 843                                                                 // the goal is probably on an upper platform, assume bot can't get there
 844                                                                 unreachable = true;
 845                                                         }
 846                                                         else
 847                                                                 evadelava = normalize(this.velocity) * -1;
 848                                                 }
 849                                         }
 850                                 }
 851                         }
 852
 853                         dir = flatdir;
 854                         evadeobstacle.z = 0;
 855                         evadelava.z = 0;
 856                         makevectors(this.v_angle.y * '0 1 0');
 857
 858                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 859                         {
 860                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 861                                 if(IS_PLAYER(this.goalcurrent))
 862                                         unreachable = true;
 863                         }
 864                         if(unreachable)
 865                         {
 866                                 navigation_clearroute(this);
 867                                 this.bot_strategytime = 0;
 868                         }
 869                 }
 870
 871                 dodge = havocbot_dodge(this);
 872                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 873                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 874                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 875                 if(IS_PLAYER(trace_ent))
 876                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 877
 878                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 879         //      this.bot_dodgevector = dir;
 880         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 881         }
 882
 883         if(time < this.ladder_time)
 884         {
 885                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 886                 {
 887                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 888                                 dir.z = 1;
 889                 }
 890                 else
 891                 {
 892                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 893                                 dir.z = -1;
 894                 }
 895         }
 896
 897         //dir = this.bot_dodgevector;
 898         //if (this.bot_dodgevector_jumpbutton)
 899         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 900         this.movement_x = dir * v_forward * maxspeed;
 901         this.movement_y = dir * v_right * maxspeed;
 902         this.movement_z = dir * v_up * maxspeed;
 903
 904         // Emulate keyboard interface
 905         if (skill < 10)
 906                 havocbot_keyboard_movement(this, destorg);
 907
 908         // Bunnyhop!
 909 //      if(this.aistatus & AI_STATUS_ROAMING)
 910         if(this.goalcurrent)
 911         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 912                 havocbot_bunnyhop(this, dir);
 913
 914         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 915         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 916         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 917 }
 918
 919 entity havocbot_gettarget(entity this, bool secondary)
 920 {
 921         entity best = NULL;
 922         vector eye = CENTER_OR_VIEWOFS(this);
 923         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 924         {
 925                 vector v = CENTER_OR_VIEWOFS(it);
 926                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 927                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 928                 if(bot_shouldattack(this, it))
 929                 {
 930                         traceline(eye, v, true, this);
 931                         if (trace_ent == it || trace_fraction >= 1)
 932                                 best = it;
 933                 }
 934         });
 935
 936         return best;
 937 }
 938
 939 void havocbot_chooseenemy(entity this)
 940 {
 941         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 942         {
 943                 this.enemy = NULL;
 944                 return;
 945         }
 946         if (this.enemy)
 947         {
 948                 if (!bot_shouldattack(this, this.enemy))
 949                 {
 950                         // enemy died or something, find a new target
 951                         this.enemy = NULL;
 952                         this.havocbot_chooseenemy_finished = time;
 953                 }
 954                 else if (this.havocbot_stickenemy)
 955                 {
 956                         // tracking last chosen enemy
 957                         // if enemy is visible
 958                         // and not really really far away
 959                         // and we're not severely injured
 960                         // then keep tracking for a half second into the future
 961                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
 962                         if (trace_ent == this.enemy || trace_fraction == 1)
 963                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
 964                         if (this.health > 30)
 965                         {
 966                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 967                                 this.havocbot_chooseenemy_finished = time + 0.5;
 968                                 return;
 969                         }
 970                         // enemy isn't visible, or is far away, or we're injured severely
 971                         // so stop preferring this enemy
 972                         // (it will still take a half second until a new one is chosen)
 973                         this.havocbot_stickenemy = 0;
 974                 }
 975         }
 976         if (time < this.havocbot_chooseenemy_finished)
 977                 return;
 978         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 979         vector eye = this.origin + this.view_ofs;
 980         entity best = NULL;
 981         float bestrating = 100000000;
 982
 983         // Backup hit flags
 984         int hf = this.dphitcontentsmask;
 985
 986         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
 987
 988         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 989
 990         bool scan_transparent = false;
 991         bool scan_secondary_targets = false;
 992         bool have_secondary_targets = false;
 993         while(true)
 994         {
 995                 scan_secondary_targets = false;
 996 LABEL(scan_targets)
 997                 IL_EACH(g_bot_targets, it.bot_attack,
 998                 {
 999                         if(!scan_secondary_targets)
1000                         {
1001                                 if(it.classname == "misc_breakablemodel")
1002                                 {
1003                                         have_secondary_targets = true;
1004                                         continue;
1005                                 }
1006                         }
1007                         else if(it.classname != "misc_breakablemodel")
1008                                 continue;
1009
1010                         vector v = (it.absmin + it.absmax) * 0.5;
1011                         float rating = vlen2(v - eye);
1012                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1013                         if (bestrating > rating)
1014                         if (bot_shouldattack(this, it))
1015                         {
1016                                 traceline(eye, v, true, this);
1017                                 if (trace_ent == it || trace_fraction >= 1)
1018                                 {
1019                                         best = it;
1020                                         bestrating = rating;
1021                                 }
1022                         }
1023                 });
1024
1025                 if(!best && have_secondary_targets && !scan_secondary_targets)
1026                 {
1027                         scan_secondary_targets = true;
1028                         // restart the loop
1029                         bestrating = 100000000;
1030                         goto scan_targets;
1031                 }
1032
1033                 // I want to do a second scan if no enemy was found or I don't have weapons
1034                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1035                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1036                         break;
1037                 if(scan_transparent)
1038                         break;
1039
1040                 // Set flags to see through transparent objects
1041                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1042
1043                 scan_transparent = true;
1044         }
1045
1046         // Restore hit flags
1047         this.dphitcontentsmask = hf;
1048
1049         this.enemy = best;
1050         this.havocbot_stickenemy = true;
1051         if(best && best.classname == "misc_breakablemodel")
1052                 this.havocbot_stickenemy = false;
1053 }
1054
1055 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1056 {
1057         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1058         // so skip this for them, or they'll never get to reload their weapons at all.
1059         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1060         if(skill < 5)
1061                 return false;
1062
1063         // if this weapon is scheduled for reloading, don't switch to it during combat
1064         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1065         {
1066                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1067                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1068                                 return true; // other weapon available
1069                 ));
1070         }
1071
1072         return false;
1073 }
1074
1075 void havocbot_chooseweapon(entity this, .entity weaponentity)
1076 {
1077         int i;
1078
1079         // ;)
1080         if(g_weaponarena_weapons == WEPSET(TUBA))
1081         {
1082                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1083                 return;
1084         }
1085
1086         // TODO: clean this up by moving it to weapon code
1087         if(this.enemy==NULL)
1088         {
1089                 // If no weapon was chosen get the first available weapon
1090                 if(this.(weaponentity).m_weapon==WEP_Null)
1091                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1092                         if(client_hasweapon(this, it, weaponentity, true, false))
1093                         {
1094                                 this.(weaponentity).m_switchweapon = it;
1095                                 return;
1096                         }
1097                 ));
1098                 return;
1099         }
1100
1101         // Do not change weapon during the next second after a combo
1102         float f = time - this.lastcombotime;
1103         if(f < 1)
1104                 return;
1105
1106         float w;
1107         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1108
1109         // Should it do a weapon combo?
1110         float af, ct, combo_time, combo;
1111
1112         af = ATTACK_FINISHED(this, 0);
1113         ct = autocvar_bot_ai_weapon_combo_threshold;
1114
1115         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1116         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1117         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1118
1119         combo = false;
1120
1121         if(autocvar_bot_ai_weapon_combo)
1122         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1123         if(af > combo_time)
1124         {
1125                 combo = true;
1126                 this.lastcombotime = time;
1127         }
1128
1129         distance *= pow(2, this.bot_rangepreference);
1130
1131         // Custom weapon list based on distance to the enemy
1132         if(bot_custom_weapon){
1133
1134                 // Choose weapons for far distance
1135                 if ( distance > bot_distance_far ) {
1136                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1137                                 w = bot_weapons_far[i];
1138                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1139                                 {
1140                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1141                                                 continue;
1142                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1143                                         return;
1144                                 }
1145                         }
1146                 }
1147
1148                 // Choose weapons for mid distance
1149                 if ( distance > bot_distance_close) {
1150                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1151                                 w = bot_weapons_mid[i];
1152                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1153                                 {
1154                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1155                                                 continue;
1156                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1157                                         return;
1158                                 }
1159                         }
1160                 }
1161
1162                 // Choose weapons for close distance
1163                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1164                         w = bot_weapons_close[i];
1165                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1166                         {
1167                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1168                                         continue;
1169                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1170                                 return;
1171                         }
1172                 }
1173         }
1174 }
1175
1176 void havocbot_aim(entity this)
1177 {
1178         vector myvel, enemyvel;
1179 //      if(this.flags & FL_INWATER)
1180 //              return;
1181         if (time < this.nextaim)
1182                 return;
1183         this.nextaim = time + 0.1;
1184         myvel = this.velocity;
1185         if (!this.waterlevel)
1186                 myvel.z = 0;
1187         if (this.enemy)
1188         {
1189                 enemyvel = this.enemy.velocity;
1190                 if (!this.enemy.waterlevel)
1191                         enemyvel.z = 0;
1192                 lag_additem(this, time + this.ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1193         }
1194         else
1195                 lag_additem(this, time + this.ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1196 }
1197
1198 bool havocbot_moveto_refresh_route(entity this)
1199 {
1200         // Refresh path to goal if necessary
1201         entity wp;
1202         wp = this.havocbot_personal_waypoint;
1203         navigation_goalrating_start(this);
1204         navigation_routerating(this, wp, 10000, 10000);
1205         navigation_goalrating_end(this);
1206         return this.navigation_hasgoals;
1207 }
1208
1209 float havocbot_moveto(entity this, vector pos)
1210 {
1211         entity wp;
1212
1213         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1214         {
1215                 // Step 4: Move to waypoint
1216                 if(this.havocbot_personal_waypoint==NULL)
1217                 {
1218                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1219                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1220                         return CMD_STATUS_ERROR;
1221                 }
1222
1223                 if (!bot_strategytoken_taken)
1224                 if(this.havocbot_personal_waypoint_searchtime<time)
1225                 {
1226                         bot_strategytoken_taken = true;
1227                         if(havocbot_moveto_refresh_route(this))
1228                         {
1229                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1230                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1231                                 this.havocbot_personal_waypoint_failcounter = 0;
1232                         }
1233                         else
1234                         {
1235                                 this.havocbot_personal_waypoint_failcounter += 1;
1236                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1237                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1238                                 {
1239                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1240                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1241                                         delete(this.havocbot_personal_waypoint);
1242                                         return CMD_STATUS_ERROR;
1243                                 }
1244                                 else
1245                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1246                         }
1247                 }
1248
1249                 if(autocvar_bot_debug_goalstack)
1250                         debuggoalstack(this);
1251
1252                 // Heading
1253                 vector dir = ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - (this.origin + this.view_ofs);
1254                 dir.z = 0;
1255                 bot_aimdir(this, dir, -1);
1256
1257                 // Go!
1258                 havocbot_movetogoal(this);
1259
1260                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1261                 {
1262                         // Step 5: Waypoint reached
1263                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1264                         delete(this.havocbot_personal_waypoint);
1265                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1266                         return CMD_STATUS_FINISHED;
1267                 }
1268
1269                 return CMD_STATUS_EXECUTING;
1270         }
1271
1272         // Step 2: Linking waypoint
1273         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1274         {
1275                 // Wait until it is linked
1276                 if(!this.havocbot_personal_waypoint.wplinked)
1277                 {
1278                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1279                         return CMD_STATUS_EXECUTING;
1280                 }
1281
1282                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1283                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1284                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1285
1286                 // Step 3: Route to waypoint
1287                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1288
1289                 return CMD_STATUS_EXECUTING;
1290         }
1291
1292         // Step 1: Spawning waypoint
1293         wp = waypoint_spawnpersonal(this, pos);
1294         if(wp==NULL)
1295         {
1296                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1297                 return CMD_STATUS_ERROR;
1298         }
1299
1300         this.havocbot_personal_waypoint = wp;
1301         this.havocbot_personal_waypoint_failcounter = 0;
1302         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1303
1304         // if pos is inside a teleport, then let's mark it as teleport waypoint
1305         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1306         {
1307                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1308                 this.lastteleporttime = 0;
1309         });
1310
1311 /*
1312         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1313                 print("routing to a teleporter\n");
1314         else
1315                 print("routing to a non-teleporter\n");
1316 */
1317
1318         return CMD_STATUS_EXECUTING;
1319 }
1320
1321 float havocbot_resetgoal(entity this)
1322 {
1323         navigation_clearroute(this);
1324         return CMD_STATUS_FINISHED;
1325 }
1326
1327 void havocbot_setupbot(entity this)
1328 {
1329         this.bot_ai = havocbot_ai;
1330         this.cmd_moveto = havocbot_moveto;
1331         this.cmd_resetgoal = havocbot_resetgoal;
1332
1333         havocbot_chooserole(this);
1334 }
1335
1336 vector havocbot_dodge(entity this)
1337 {
1338         // LordHavoc: disabled because this is too expensive
1339         return '0 0 0';
1340 #if 0
1341         entity head;
1342         vector dodge, v, n;
1343         float danger, bestdanger, vl, d;
1344         dodge = '0 0 0';
1345         bestdanger = -20;
1346         // check for dangerous objects near bot or approaching bot
1347         head = findchainfloat(bot_dodge, true);
1348         while(head)
1349         {
1350                 if (head.owner != this)
1351                 {
1352                         vl = vlen(head.velocity);
1353                         if (vl > autocvar_sv_maxspeed * 0.3)
1354                         {
1355                                 n = normalize(head.velocity);
1356                                 v = this.origin - head.origin;
1357                                 d = v * n;
1358                                 if (d > (0 - head.bot_dodgerating))
1359                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1360                                 {
1361                                         // calculate direction and distance from the flight path, by removing the forward axis
1362                                         v = v - (n * (v * n));
1363                                         danger = head.bot_dodgerating - vlen(v);
1364                                         if (bestdanger < danger)
1365                                         {
1366                                                 bestdanger = danger;
1367                                                 // dodge to the side of the object
1368                                                 dodge = normalize(v);
1369                                         }
1370                                 }
1371                         }
1372                         else
1373                         {
1374                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1375                                 if (bestdanger < danger)
1376                                 {
1377                                         bestdanger = danger;
1378                                         dodge = normalize(this.origin - head.origin);
1379                                 }
1380                         }
1381                 }
1382                 head = head.chain;
1383         }
1384         return dodge;
1385 #endif
1386 }