qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "waypoints.qh"
   7
   8 #include <common/t_items.qh>
   9
  10 #include <common/items/_mod.qh>
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/triggers/trigger/jumppads.qh>
  15
  16 .float speed;
  17
  18 void navigation_dynamicgoal_init(entity this, bool initially_static)
  19 {
  20         this.navigation_dynamicgoal = true;
  21         this.bot_basewaypoint = this.nearestwaypoint;
  22         if(initially_static)
  23                 this.nearestwaypointtimeout = -1;
  24         else
  25                 this.nearestwaypointtimeout = time;
  26 }
  27
  28 void navigation_dynamicgoal_set(entity this)
  29 {
  30         this.nearestwaypointtimeout = time;
  31 }
  32
  33 void navigation_dynamicgoal_unset(entity this)
  34 {
  35         if(this.bot_basewaypoint)
  36                 this.nearestwaypoint = this.bot_basewaypoint;
  37         this.nearestwaypointtimeout = -1;
  38 }
  39
  40 bool navigation_check_submerged_state(entity ent, vector pos)
  41 {
  42         bool submerged;
  43         if(IS_PLAYER(ent))
  44                 submerged = (ent.waterlevel == WATERLEVEL_SUBMERGED);
  45         else if(ent.nav_submerged_state != SUBMERGED_UNDEFINED)
  46                 submerged = (ent.nav_submerged_state == SUBMERGED_YES);
  47         else
  48         {
  49                 submerged = SUBMERGED(pos);
  50                 // NOTE: SUBMERGED check of box waypoint origin may fail even if origin
  51                 //  is actually submerged because often they are inside some solid.
  52                 //  That's why submerged state is saved now that we know current pos is
  53                 //  not stuck in solid (previous tracewalk call to this pos was successfully)
  54                 if(!ent.navigation_dynamicgoal)
  55                         ent.nav_submerged_state = (submerged) ? SUBMERGED_YES : SUBMERGED_NO;
  56         }
  57         return submerged;
  58 }
  59
  60 bool navigation_checkladders(entity e, vector org, vector m1, vector m2, vector end, vector end2, int movemode)
  61 {
  62         IL_EACH(g_ladders, it.classname == "func_ladder",
  63         {
  64                 if(it.bot_pickup)
  65                 if(boxesoverlap(org + m1 + '-1 -1 -1', org + m2 + '1 1 1', it.absmin, it.absmax))
  66                 if(boxesoverlap(end, end2, it.absmin + vec2(m1) + '-1 -1 0', it.absmax + vec2(m2) + '1 1 0'))
  67                 {
  68                         vector top = org;
  69                         top.z = it.absmax.z + (PL_MAX_CONST.z - PL_MIN_CONST.z);
  70                         tracebox(org, m1, m2, top, movemode, e);
  71                         if(trace_fraction == 1)
  72                                 return true;
  73                 }
  74         });
  75         return false;
  76 }
  77
  78 vector resurface_limited(vector org, float lim, vector m1)
  79 {
  80         if (WETFEET(org + eZ * (lim - org.z)))
  81                 org.z = lim;
  82         else
  83         {
  84                 float RES_min_h = org.z;
  85                 float RES_max_h = lim;
  86                 do {
  87                         org.z = 0.5 * (RES_min_h + RES_max_h);
  88                         if(WETFEET(org))
  89                                 RES_min_h = org.z;
  90                         else
  91                                 RES_max_h = org.z;
  92                 } while (RES_max_h - RES_min_h >= 1);
  93                 org.z = RES_min_h;
  94         }
  95         return org;
  96 }
  97 #define RESURFACE_LIMITED(org, lim) org = resurface_limited(org, lim, m1)
  98
  99 #define NAV_WALK 0
 100 #define NAV_SWIM_ONWATER 1
 101 #define NAV_SWIM_UNDERWATER 2
 102
 103 // rough simulation of walking from one point to another to test if a path
 104 // can be traveled, used for waypoint linking and havocbot
 105 // if end_height is > 0 destination is any point in the vertical segment [end, end + end_height * eZ]
 106 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float end_height, float movemode)
 107 {
 108         if(autocvar_bot_debug_tracewalk)
 109         {
 110                 debugresetnodes();
 111                 debugnode(e, start);
 112         }
 113
 114         vector org = start;
 115         vector flatdir = end - start;
 116         flatdir.z = 0;
 117         float flatdist = vlen(flatdir);
 118         flatdir = normalize(flatdir);
 119         float stepdist = 32;
 120         bool ignorehazards = false;
 121         int nav_action;
 122
 123         // Analyze starting point
 124         traceline(start, start, MOVE_NORMAL, e);
 125         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 126                 ignorehazards = true;
 127
 128         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 129         if (trace_startsolid)
 130         {
 131                 // Bad start
 132                 if(autocvar_bot_debug_tracewalk)
 133                         debugnodestatus(start, DEBUG_NODE_FAIL);
 134
 135                 //print("tracewalk: ", vtos(start), " is a bad start\n");
 136                 return false;
 137         }
 138
 139         vector end2 = end;
 140         if(end_height)
 141                 end2.z += end_height;
 142
 143         vector fixed_end = end;
 144         vector move;
 145
 146         if (flatdist > 0 && WETFEET(org))
 147         {
 148                 if (SUBMERGED(org))
 149                         nav_action = NAV_SWIM_UNDERWATER;
 150                 else
 151                 {
 152                         // tracebox down by player's height
 153                         // useful to know if water level is so low that bot can still walk
 154                         tracebox(org, m1, m2, org - eZ * (m2.z - m1.z), movemode, e);
 155                         if (SUBMERGED(trace_endpos))
 156                         {
 157                                 org = trace_endpos;
 158                                 nav_action = NAV_SWIM_UNDERWATER;
 159                         }
 160                         else
 161                                 nav_action = NAV_WALK;
 162                 }
 163         }
 164         else
 165                 nav_action =  NAV_WALK;
 166
 167         // Movement loop
 168         while (true)
 169         {
 170                 if (flatdist <= 0)
 171                 {
 172                         bool success = true;
 173                         if (org.z > end2.z + 1)
 174                         {
 175                                 tracebox(org, m1, m2, end2, movemode, e);
 176                                 org = trace_endpos;
 177                                 if (org.z > end2.z + 1)
 178                                         success = false;
 179                         }
 180                         else if (org.z < end.z - 1)
 181                         {
 182                                 tracebox(org, m1, m2, org - jumpheight_vec, movemode, e);
 183                                 if (SUBMERGED(trace_endpos))
 184                                         RESURFACE_LIMITED(trace_endpos, end.z);
 185                                 else if (trace_endpos.z > org.z - jumpheight_vec.z)
 186                                         tracebox(trace_endpos, m1, m2, trace_endpos + jumpheight_vec, movemode, e);
 187                                 org = trace_endpos;
 188                                 if (org.z < end.z - 1)
 189                                         success = false;
 190                         }
 191
 192                         if (success)
 193                         {
 194                                 // Succeeded
 195                                 if(autocvar_bot_debug_tracewalk)
 196                                 {
 197                                         debugnode(e, org);
 198                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 199                                 }
 200
 201                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 202                                 return true;
 203                         }
 204                 }
 205
 206                 if(autocvar_bot_debug_tracewalk)
 207                         debugnode(e, org);
 208
 209                 if (flatdist <= 0)
 210                         break;
 211
 212                 if(nav_action == NAV_SWIM_UNDERWATER || (nav_action == NAV_SWIM_ONWATER && org.z > end2.z))
 213                 {
 214                         // can't use movement direction here to calculate move because of
 215                         // precision errors especially when direction has a high enough z value
 216                         //water_dir = normalize(water_end - org);
 217                         //move = org + water_dir * stepdist;
 218                         fixed_end.z = bound(end.z, org.z, end2.z);
 219                         if (stepdist > flatdist)
 220                                 stepdist = flatdist;
 221                         if (stepdist == flatdist) {
 222                                 move = fixed_end;
 223                                 flatdist = 0;
 224                         } else {
 225                                 move = org + (fixed_end - org) * (stepdist / flatdist);
 226                                 flatdist = vlen(vec2(fixed_end - move));
 227                         }
 228                 }
 229                 else // horiz. direction
 230                 {
 231                         if (stepdist > flatdist)
 232                                 stepdist = flatdist;
 233                         flatdist -= stepdist;
 234                         move = org + flatdir * stepdist;
 235                 }
 236
 237                 if(nav_action == NAV_SWIM_ONWATER)
 238                 {
 239                         tracebox(org, m1, m2, move, movemode, e); // swim
 240
 241                         // hit something
 242                         if (trace_fraction < 1)
 243                         {
 244                                 // stepswim
 245                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 246
 247                                 if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 248                                 {
 249                                         org = trace_endpos;
 250                                         if(navigation_checkladders(e, org, m1, m2, end, end2, movemode))
 251                                         {
 252                                                 if(autocvar_bot_debug_tracewalk)
 253                                                 {
 254                                                         debugnode(e, org);
 255                                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 256                                                 }
 257
 258                                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 259                                                 return true;
 260                                         }
 261
 262                                         if(autocvar_bot_debug_tracewalk)
 263                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 264
 265                                         return false;
 266                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 267                                 }
 268
 269                                 //succesful stepswim
 270
 271                                 if (flatdist <= 0)
 272                                 {
 273                                         org = trace_endpos;
 274                                         continue;
 275                                 }
 276
 277                                 if (org.z <= move.z) // going horiz.
 278                                 {
 279                                         tracebox(trace_endpos, m1, m2, move, movemode, e);
 280                                         org = trace_endpos;
 281                                         nav_action = NAV_WALK;
 282                                         continue;
 283                                 }
 284                         }
 285
 286                         if (org.z <= move.z) // going horiz.
 287                         {
 288                                 org = trace_endpos;
 289                                 nav_action = NAV_SWIM_ONWATER;
 290                         }
 291                         else // going down
 292                         {
 293                                 org = trace_endpos;
 294                                 if (SUBMERGED(org))
 295                                         nav_action = NAV_SWIM_UNDERWATER;
 296                                 else
 297                                         nav_action = NAV_SWIM_ONWATER;
 298                         }
 299                 }
 300                 else if(nav_action == NAV_SWIM_UNDERWATER)
 301                 {
 302                         if (move.z >= org.z) // swimming upwards or horiz.
 303                         {
 304                                 tracebox(org, m1, m2, move, movemode, e); // swim
 305
 306                                 bool stepswimmed = false;
 307
 308                                 // hit something
 309                                 if (trace_fraction < 1)
 310                                 {
 311                                         // stepswim
 312                                         vector stepswim_move = move + stepheightvec;
 313                                         if (flatdist > 0 && stepswim_move.z > end2.z) // don't allow stepswim to go higher than destination
 314                                                 stepswim_move.z = end2.z;
 315
 316                                         tracebox(org + stepheightvec, m1, m2, stepswim_move, movemode, e);
 317
 318                                         // hit something
 319                                         if (trace_startsolid)
 320                                         {
 321                                                 if(autocvar_bot_debug_tracewalk)
 322                                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 323
 324                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 325                                                 return false;
 326                                         }
 327
 328                                         if (trace_fraction < 1)
 329                                         {
 330                                                 float org_z_prev = org.z;
 331                                                 RESURFACE_LIMITED(org, end2.z);
 332                                                 if(org.z == org_z_prev)
 333                                                 {
 334                                                         if(autocvar_bot_debug_tracewalk)
 335                                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 336
 337                                                         //print("tracewalk: ", vtos(start), " can't reach ", vtos(end), "\n");
 338                                                         return false;
 339                                                 }
 340                                                 if(SUBMERGED(org))
 341                                                         nav_action = NAV_SWIM_UNDERWATER;
 342                                                 else
 343                                                         nav_action = NAV_SWIM_ONWATER;
 344
 345                                                 // we didn't advance horiz. in this step, flatdist decrease should be reverted
 346                                                 // but we can do it properly right now... apply this workaround instead
 347                                                 if (flatdist <= 0)
 348                                                         flatdist = 1;
 349
 350                                                 continue;
 351                                         }
 352
 353                                         //succesful stepswim
 354
 355                                         if (flatdist <= 0)
 356                                         {
 357                                                 org = trace_endpos;
 358                                                 continue;
 359                                         }
 360
 361                                         stepswimmed = true;
 362                                 }
 363
 364                                 if (!WETFEET(trace_endpos))
 365                                 {
 366                                         tracebox(trace_endpos, m1, m2, trace_endpos - eZ * (stepdist + (m2.z - m1.z)), movemode, e);
 367                                         // if stepswimmed we'll land on the obstacle, avoid the SUBMERGED check
 368                                         if (!stepswimmed && SUBMERGED(trace_endpos))
 369                                         {
 370                                                 RESURFACE_LIMITED(trace_endpos, end2.z);
 371                                                 org = trace_endpos;
 372                                                 nav_action = NAV_SWIM_ONWATER;
 373                                                 continue;
 374                                         }
 375
 376                                         // not submerged
 377                                         org = trace_endpos;
 378                                         nav_action = NAV_WALK;
 379                                         continue;
 380                                 }
 381
 382                                 // wetfeet
 383                                 org = trace_endpos;
 384                                 nav_action = NAV_SWIM_UNDERWATER;
 385                                 continue;
 386                         }
 387                         else //if (move.z < org.z) // swimming downwards
 388                         {
 389                                 tracebox(org, m1, m2, move, movemode, e); // swim
 390
 391                                 // hit something
 392                                 if (trace_fraction < 1)
 393                                 {
 394                                         // stepswim
 395                                         tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 396
 397                                         // hit something
 398                                         if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 399                                         {
 400                                                 if(autocvar_bot_debug_tracewalk)
 401                                                         debugnodestatus(move, DEBUG_NODE_FAIL);
 402
 403                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 404                                                 return false;
 405                                         }
 406
 407                                         //succesful stepswim
 408
 409                                         if (flatdist <= 0)
 410                                         {
 411                                                 org = trace_endpos;
 412                                                 continue;
 413                                         }
 414
 415                                         if (trace_endpos.z > org.z && !SUBMERGED(trace_endpos))
 416                                         {
 417                                                 // stepswim caused upwards direction
 418                                                 tracebox(trace_endpos, m1, m2, trace_endpos - stepheightvec, movemode, e);
 419                                                 if (!SUBMERGED(trace_endpos))
 420                                                 {
 421                                                         org = trace_endpos;
 422                                                         nav_action = NAV_WALK;
 423                                                         continue;
 424                                                 }
 425                                         }
 426                                 }
 427
 428                                 org = trace_endpos;
 429                                 nav_action = NAV_SWIM_UNDERWATER;
 430                                 continue;
 431                         }
 432                 }
 433                 else if(nav_action == NAV_WALK)
 434                 {
 435                         // walk
 436                         tracebox(org, m1, m2, move, movemode, e);
 437
 438                         if(autocvar_bot_debug_tracewalk)
 439                                 debugnode(e, trace_endpos);
 440
 441                         // hit something
 442                         if (trace_fraction < 1)
 443                         {
 444                                 // check if we can walk over this obstacle, possibly by jumpstepping
 445                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 446                                 if (trace_fraction < 1 || trace_startsolid)
 447                                 {
 448                                         if (trace_startsolid) // hit ceiling above org
 449                                         {
 450                                                 // reduce stepwalk height
 451                                                 tracebox(org, m1, m2, org + stepheightvec, movemode, e);
 452                                                 tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 453                                         }
 454                                         else //if (trace_fraction < 1)
 455                                         {
 456                                                 tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 457                                                 if (trace_startsolid) // hit ceiling above org
 458                                                 {
 459                                                         // reduce jumpstepwalk height
 460                                                         tracebox(org, m1, m2, org + jumpstepheightvec, movemode, e);
 461                                                         tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 462                                                 }
 463                                         }
 464
 465                                         if (trace_fraction < 1)
 466                                         {
 467                                                 vector v = trace_endpos;
 468                                                 v.z = org.z + jumpheight_vec.z;
 469                                                 if(navigation_checkladders(e, v, m1, m2, end, end2, movemode))
 470                                                 {
 471                                                         if(autocvar_bot_debug_tracewalk)
 472                                                         {
 473                                                                 debugnode(e, v);
 474                                                                 debugnodestatus(v, DEBUG_NODE_SUCCESS);
 475                                                         }
 476
 477                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 478                                                         return true;
 479                                                 }
 480
 481                                                 if(autocvar_bot_debug_tracewalk)
 482                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 483
 484                                                 traceline( org, move, movemode, e);
 485
 486                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 487                                                 {
 488                                                         vector nextmove;
 489                                                         move = trace_endpos;
 490                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 491                                                         {
 492                                                                 nextmove = move + (flatdir * stepdist);
 493                                                                 traceline( move, nextmove, movemode, e);
 494                                                                 move = nextmove;
 495                                                         }
 496                                                         flatdist = vlen(vec2(end - move));
 497                                                 }
 498                                                 else
 499                                                 {
 500                                                         if(autocvar_bot_debug_tracewalk)
 501                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 502
 503                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 504                                                         //te_explosion(trace_endpos);
 505                                                         //print(ftos(e.dphitcontentsmask), "\n");
 506                                                         return false; // failed
 507                                                 }
 508                                         }
 509                                         else
 510                                                 move = trace_endpos;
 511                                 }
 512                                 else
 513                                         move = trace_endpos;
 514                         }
 515                         else
 516                                 move = trace_endpos;
 517
 518                         if (flatdist <= 0)
 519                         {
 520                                 org = move;
 521                                 continue;
 522                         }
 523
 524                         // trace down from stepheight as far as possible and move there,
 525                         // if this starts in solid we try again without the stepup, and
 526                         // if that also fails we assume it is a wall
 527                         // (this is the same logic as the Quake walkmove function used)
 528                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 529
 530                         org = trace_endpos;
 531
 532                         if (!ignorehazards)
 533                         {
 534                                 if (IN_LAVA(org))
 535                                 {
 536                                         if(autocvar_bot_debug_tracewalk)
 537                                         {
 538                                                 debugnode(e, trace_endpos);
 539                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 540                                         }
 541
 542                                         //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 543                                         return false;
 544                                 }
 545                         }
 546
 547                         if(org.z > move.z - 1 || !SUBMERGED(org))
 548                         {
 549                                 nav_action = NAV_WALK;
 550                                 continue;
 551                         }
 552
 553                         // ended up submerged while walking
 554                         if(autocvar_bot_debug_tracewalk)
 555                                 debugnode(e, org);
 556
 557                         RESURFACE_LIMITED(org, move.z);
 558                         nav_action = NAV_SWIM_ONWATER;
 559                         continue;
 560                 }
 561         }
 562
 563         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 564
 565         // moved but didn't arrive at the intended destination
 566         if(autocvar_bot_debug_tracewalk)
 567                 debugnodestatus(org, DEBUG_NODE_FAIL);
 568
 569         return false;
 570 }
 571
 572 /////////////////////////////////////////////////////////////////////////////
 573 // goal stack
 574 /////////////////////////////////////////////////////////////////////////////
 575
 576 // completely empty the goal stack, used when deciding where to go
 577 void navigation_clearroute(entity this)
 578 {
 579         this.goalcurrent_prev = this.goalcurrent;
 580         this.goalcurrent_distance = 10000000;
 581         this.goalcurrent_distance_time = 0;
 582         //print("bot ", etos(this), " clear\n");
 583         this.goalentity = NULL;
 584         this.goalcurrent = NULL;
 585         this.goalstack01 = NULL;
 586         this.goalstack02 = NULL;
 587         this.goalstack03 = NULL;
 588         this.goalstack04 = NULL;
 589         this.goalstack05 = NULL;
 590         this.goalstack06 = NULL;
 591         this.goalstack07 = NULL;
 592         this.goalstack08 = NULL;
 593         this.goalstack09 = NULL;
 594         this.goalstack10 = NULL;
 595         this.goalstack11 = NULL;
 596         this.goalstack12 = NULL;
 597         this.goalstack13 = NULL;
 598         this.goalstack14 = NULL;
 599         this.goalstack15 = NULL;
 600         this.goalstack16 = NULL;
 601         this.goalstack17 = NULL;
 602         this.goalstack18 = NULL;
 603         this.goalstack19 = NULL;
 604         this.goalstack20 = NULL;
 605         this.goalstack21 = NULL;
 606         this.goalstack22 = NULL;
 607         this.goalstack23 = NULL;
 608         this.goalstack24 = NULL;
 609         this.goalstack25 = NULL;
 610         this.goalstack26 = NULL;
 611         this.goalstack27 = NULL;
 612         this.goalstack28 = NULL;
 613         this.goalstack29 = NULL;
 614         this.goalstack30 = NULL;
 615         this.goalstack31 = NULL;
 616 }
 617
 618 // add a new goal at the beginning of the stack
 619 // (in other words: add a new prerequisite before going to the later goals)
 620 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 621 // next-closest WP on the shortest path to the WP
 622 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 623 // steps to the goal, and then recalculate the path.
 624 void navigation_pushroute(entity this, entity e)
 625 {
 626         this.goalcurrent_prev = this.goalcurrent;
 627         this.goalcurrent_distance = 10000000;
 628         this.goalcurrent_distance_time = 0;
 629         //print("bot ", etos(this), " push ", etos(e), "\n");
 630         if(this.goalstack31 == this.goalentity)
 631                 this.goalentity = NULL;
 632         this.goalstack31 = this.goalstack30;
 633         this.goalstack30 = this.goalstack29;
 634         this.goalstack29 = this.goalstack28;
 635         this.goalstack28 = this.goalstack27;
 636         this.goalstack27 = this.goalstack26;
 637         this.goalstack26 = this.goalstack25;
 638         this.goalstack25 = this.goalstack24;
 639         this.goalstack24 = this.goalstack23;
 640         this.goalstack23 = this.goalstack22;
 641         this.goalstack22 = this.goalstack21;
 642         this.goalstack21 = this.goalstack20;
 643         this.goalstack20 = this.goalstack19;
 644         this.goalstack19 = this.goalstack18;
 645         this.goalstack18 = this.goalstack17;
 646         this.goalstack17 = this.goalstack16;
 647         this.goalstack16 = this.goalstack15;
 648         this.goalstack15 = this.goalstack14;
 649         this.goalstack14 = this.goalstack13;
 650         this.goalstack13 = this.goalstack12;
 651         this.goalstack12 = this.goalstack11;
 652         this.goalstack11 = this.goalstack10;
 653         this.goalstack10 = this.goalstack09;
 654         this.goalstack09 = this.goalstack08;
 655         this.goalstack08 = this.goalstack07;
 656         this.goalstack07 = this.goalstack06;
 657         this.goalstack06 = this.goalstack05;
 658         this.goalstack05 = this.goalstack04;
 659         this.goalstack04 = this.goalstack03;
 660         this.goalstack03 = this.goalstack02;
 661         this.goalstack02 = this.goalstack01;
 662         this.goalstack01 = this.goalcurrent;
 663         this.goalcurrent = e;
 664 }
 665
 666 // remove first goal from stack
 667 // (in other words: remove a prerequisite for reaching the later goals)
 668 // (used when a spawnfunc_waypoint is reached)
 669 void navigation_poproute(entity this)
 670 {
 671         this.goalcurrent_prev = this.goalcurrent;
 672         this.goalcurrent_distance = 10000000;
 673         this.goalcurrent_distance_time = 0;
 674         //print("bot ", etos(this), " pop\n");
 675         if(this.goalcurrent == this.goalentity)
 676                 this.goalentity = NULL;
 677         this.goalcurrent = this.goalstack01;
 678         this.goalstack01 = this.goalstack02;
 679         this.goalstack02 = this.goalstack03;
 680         this.goalstack03 = this.goalstack04;
 681         this.goalstack04 = this.goalstack05;
 682         this.goalstack05 = this.goalstack06;
 683         this.goalstack06 = this.goalstack07;
 684         this.goalstack07 = this.goalstack08;
 685         this.goalstack08 = this.goalstack09;
 686         this.goalstack09 = this.goalstack10;
 687         this.goalstack10 = this.goalstack11;
 688         this.goalstack11 = this.goalstack12;
 689         this.goalstack12 = this.goalstack13;
 690         this.goalstack13 = this.goalstack14;
 691         this.goalstack14 = this.goalstack15;
 692         this.goalstack15 = this.goalstack16;
 693         this.goalstack16 = this.goalstack17;
 694         this.goalstack17 = this.goalstack18;
 695         this.goalstack18 = this.goalstack19;
 696         this.goalstack19 = this.goalstack20;
 697         this.goalstack20 = this.goalstack21;
 698         this.goalstack21 = this.goalstack22;
 699         this.goalstack22 = this.goalstack23;
 700         this.goalstack23 = this.goalstack24;
 701         this.goalstack24 = this.goalstack25;
 702         this.goalstack25 = this.goalstack26;
 703         this.goalstack26 = this.goalstack27;
 704         this.goalstack27 = this.goalstack28;
 705         this.goalstack28 = this.goalstack29;
 706         this.goalstack29 = this.goalstack30;
 707         this.goalstack30 = this.goalstack31;
 708         this.goalstack31 = NULL;
 709 }
 710
 711 // walking to wp (walkfromwp == false) v2 and v2_height will be used as
 712 // waypoint destination coordinates instead of v (only useful for box waypoints)
 713 // for normal waypoints v2 == v and v2_height == 0
 714 float navigation_waypoint_will_link(vector v, vector org, entity ent, vector v2, float v2_height, float walkfromwp, float bestdist)
 715 {
 716         if (vdist(v - org, <, bestdist))
 717         {
 718                 traceline(v, org, true, ent);
 719                 if (trace_fraction == 1)
 720                 {
 721                         if (walkfromwp)
 722                         {
 723                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, org, 0, bot_navigation_movemode))
 724                                         return true;
 725                         }
 726                         else
 727                         {
 728                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 729                                         return true;
 730                         }
 731                 }
 732         }
 733         return false;
 734 }
 735
 736 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 737 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 738 {
 739         vector pm1 = ent.origin + ent.mins;
 740         vector pm2 = ent.origin + ent.maxs;
 741
 742         // do two scans, because box test is cheaper
 743         IL_EACH(g_waypoints, it != ent && it != except,
 744         {
 745                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 746                         return it;
 747         });
 748
 749         vector org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 750         org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 751         // TODO possibly make other code have the same support for bboxes
 752         if(ent.tag_entity)
 753                 org = org + ent.tag_entity.origin;
 754         if (navigation_testtracewalk)
 755                 te_plasmaburn(org);
 756
 757         entity best = NULL;
 758         vector v, v2;
 759         float v2_height;
 760
 761         if(!autocvar_g_waypointeditor && !ent.navigation_dynamicgoal)
 762         {
 763                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 764                 IL_EACH(g_waypoints, it != ent,
 765                 {
 766                         if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 767                                 continue;
 768
 769                         SET_TRACEWALK_DESTCOORDS_2(it, org, v, v2, v2_height);
 770                         if(navigation_waypoint_will_link(v, org, ent, v2, v2_height, walkfromwp, 1050))
 771                                 navigation_item_addlink(it, ent);
 772                 });
 773         }
 774
 775         // box check failed, try walk
 776         IL_EACH(g_waypoints, it != ent,
 777         {
 778                 if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 779                         continue;
 780                 SET_TRACEWALK_DESTCOORDS_2(it, org, v, v2, v2_height);
 781                 if(navigation_waypoint_will_link(v, org, ent, v2, v2_height, walkfromwp, bestdist))
 782                 {
 783                         bestdist = vlen(v - org);
 784                         best = it;
 785                 }
 786         });
 787         return best;
 788 }
 789 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 790 {
 791         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 792         if (autocvar_g_waypointeditor_auto)
 793         {
 794                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
 795                 if (wp && !wp2)
 796                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
 797         }
 798         return wp;
 799 }
 800
 801 // finds the waypoints near the bot initiating a navigation query
 802 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
 803 {
 804         vector v;
 805         //navigation_testtracewalk = true;
 806         int c = 0;
 807         float v_height;
 808         IL_EACH(g_waypoints, !it.wpconsidered,
 809         {
 810                 SET_TRACEWALK_DESTCOORDS(it, this.origin, v, v_height);
 811
 812                 vector diff = v - this.origin;
 813                 diff.z = max(0, diff.z);
 814                 if(vdist(diff, <, maxdist))
 815                 {
 816                         it.wpconsidered = true;
 817                         if (tracewalk(this, this.origin, this.mins, this.maxs, v, v_height, bot_navigation_movemode))
 818                         {
 819                                 it.wpnearestpoint = v;
 820                                 it.wpcost = waypoint_gettravelcost(this.origin, v, this, it) + it.dmg;
 821                                 it.wpfire = 1;
 822                                 it.enemy = NULL;
 823                                 c = c + 1;
 824                         }
 825                 }
 826         });
 827         //navigation_testtracewalk = false;
 828         return c;
 829 }
 830
 831 // updates a path link if a spawnfunc_waypoint link is better than the current one
 832 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost, vector p)
 833 {
 834         vector m1, m2;
 835         vector v;
 836         if (wp.wpisbox)
 837         {
 838                 m1 = wp.origin + wp.mins;
 839                 m2 = wp.origin + wp.maxs;
 840                 v.x = bound(m1_x, p.x, m2_x);
 841                 v.y = bound(m1_y, p.y, m2_y);
 842                 v.z = bound(m1_z, p.z, m2_z);
 843         }
 844         else
 845                 v = wp.origin;
 846         if (w.wpflags & WAYPOINTFLAG_TELEPORT)
 847                 cost += w.wp00mincost; // assuming teleport has exactly one destination
 848         else
 849                 cost += waypoint_gettravelcost(p, v, w, wp);
 850         if (wp.wpcost > cost)
 851         {
 852                 wp.wpcost = cost;
 853                 wp.enemy = w;
 854                 wp.wpfire = 1;
 855                 wp.wpnearestpoint = v;
 856         }
 857 }
 858
 859 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 860 void navigation_markroutes(entity this, entity fixed_source_waypoint)
 861 {
 862         float cost, cost2;
 863         vector p;
 864
 865         IL_EACH(g_waypoints, true,
 866         {
 867                 it.wpconsidered = false;
 868                 it.wpnearestpoint = '0 0 0';
 869                 it.wpcost = 10000000;
 870                 it.wpfire = 0;
 871                 it.enemy = NULL;
 872         });
 873
 874         if(fixed_source_waypoint)
 875         {
 876                 fixed_source_waypoint.wpconsidered = true;
 877                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 878                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 879                 fixed_source_waypoint.wpfire = 1;
 880                 fixed_source_waypoint.enemy = NULL;
 881         }
 882         else
 883         {
 884                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 885                 // as this search is expensive we will use lower values if the bot is on the air
 886                 float increment, maxdistance;
 887                 if(IS_ONGROUND(this))
 888                 {
 889                         increment = 750;
 890                         maxdistance = 50000;
 891                 }
 892                 else
 893                 {
 894                         increment = 500;
 895                         maxdistance = 1500;
 896                 }
 897
 898                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
 899         }
 900
 901         bool searching = true;
 902         while (searching)
 903         {
 904                 searching = false;
 905                 IL_EACH(g_waypoints, it.wpfire,
 906                 {
 907                         searching = true;
 908                         it.wpfire = 0;
 909                         cost = it.wpcost;
 910                         p = it.wpnearestpoint;
 911                         entity wp;
 912                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 913                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 914                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 915                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 916                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 917                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 918                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 919                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 920                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 921                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 922                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 923                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 924                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 925                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 926                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 927                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 928                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 929                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 930                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 931                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 932                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 933                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 934                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 935                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 936                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 937                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 938                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 939                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 940                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 941                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 942                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 943                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 944                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 945                 });
 946         }
 947 }
 948
 949 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 950 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 951 {
 952         float cost, cost2;
 953         vector p;
 954         IL_EACH(g_waypoints, true,
 955         {
 956                 it.wpconsidered = false;
 957                 it.wpnearestpoint = '0 0 0';
 958                 it.wpcost = 10000000;
 959                 it.wpfire = 0;
 960                 it.enemy = NULL;
 961         });
 962
 963         if(fixed_source_waypoint)
 964         {
 965                 fixed_source_waypoint.wpconsidered = true;
 966                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 967                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
 968                 fixed_source_waypoint.wpfire = 1;
 969                 fixed_source_waypoint.enemy = NULL;
 970         }
 971         else
 972         {
 973                 error("need to start with a waypoint\n");
 974         }
 975
 976         bool searching = true;
 977         while (searching)
 978         {
 979                 searching = false;
 980                 IL_EACH(g_waypoints, it.wpfire,
 981                 {
 982                         searching = true;
 983                         it.wpfire = 0;
 984                         cost = it.wpcost; // cost to walk from it to home
 985                         p = it.wpnearestpoint;
 986                         entity wp = it;
 987                         IL_EACH(g_waypoints, it != wp,
 988                         {
 989                                 if(!waypoint_islinked(it, wp))
 990                                         continue;
 991                                 cost2 = cost + it.dmg;
 992                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
 993                         });
 994                 });
 995         }
 996 }
 997
 998 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 999 void navigation_routerating(entity this, entity e, float f, float rangebias)
1000 {
1001         if (!e)
1002                 return;
1003
1004         if(e.blacklisted)
1005                 return;
1006
1007         rangebias = waypoint_getlinearcost(rangebias);
1008         f = waypoint_getlinearcost(f);
1009
1010         if (IS_PLAYER(e))
1011         {
1012                 bool rate_wps = false;
1013                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
1014                         rate_wps = true;
1015
1016                 if(!IS_ONGROUND(e))
1017                 {
1018                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
1019                         int t = pointcontents(trace_endpos + '0 0 1');
1020                         if(t != CONTENT_SOLID )
1021                         {
1022                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
1023                                         rate_wps = true;
1024                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
1025                                         return;
1026                         }
1027                 }
1028
1029                 if(rate_wps)
1030                 {
1031                         entity theEnemy = e;
1032                         entity best_wp = NULL;
1033                         float best_dist = 10000;
1034                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
1035                                 && vdist(it.origin - this.origin, >, 100)
1036                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1037                         {
1038                                 float dist = vlen(it.origin - theEnemy.origin);
1039                                 if (dist < best_dist)
1040                                 {
1041                                         best_wp = it;
1042                                         best_dist = dist;
1043                                 }
1044                         });
1045                         if (!best_wp)
1046                                 return;
1047                         e = best_wp;
1048                 }
1049         }
1050
1051         vector goal_org = (e.absmin + e.absmax) * 0.5;
1052
1053         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
1054
1055         // Evaluate path using jetpack
1056         if(g_jetpack)
1057         if(this.items & IT_JETPACK)
1058         if(autocvar_bot_ai_navigation_jetpack)
1059         if(vdist(this.origin - goal_org, >, autocvar_bot_ai_navigation_jetpack_mindistance))
1060         {
1061                 vector pointa, pointb;
1062
1063                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
1064
1065                 // Point A
1066                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
1067                 pointa = trace_endpos - '0 0 1';
1068
1069                 // Point B
1070                 traceline(goal_org, goal_org + '0 0 65535', MOVE_NORMAL, e);
1071                 pointb = trace_endpos - '0 0 1';
1072
1073                 // Can I see these two points from the sky?
1074                 traceline(pointa, pointb, MOVE_NORMAL, this);
1075
1076                 if(trace_fraction==1)
1077                 {
1078                         LOG_DEBUG("jetpack ai: can bridge these two points");
1079
1080                         // Lower the altitude of these points as much as possible
1081                         float zdistance, xydistance, cost, t, fuel;
1082                         vector down, npa, npb;
1083
1084                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
1085
1086                         do{
1087                                 npa = pointa + down;
1088                                 npb = pointb + down;
1089
1090                                 if(npa.z<=this.absmax.z)
1091                                         break;
1092
1093                                 if(npb.z<=e.absmax.z)
1094                                         break;
1095
1096                                 traceline(npa, npb, MOVE_NORMAL, this);
1097                                 if(trace_fraction==1)
1098                                 {
1099                                         pointa = npa;
1100                                         pointb = npb;
1101                                 }
1102                         }
1103                         while(trace_fraction == 1);
1104
1105
1106                         // Rough estimation of fuel consumption
1107                         // (ignores acceleration and current xyz velocity)
1108                         xydistance = vlen(pointa - pointb);
1109                         zdistance = fabs(pointa.z - this.origin.z);
1110
1111                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
1112                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
1113                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
1114
1115                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
1116
1117                         // enough fuel ?
1118                         if(this.ammo_fuel>fuel)
1119                         {
1120                                 // Estimate cost
1121                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
1122                                 //  - between air and ground speeds)
1123
1124                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
1125                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
1126                                 cost *= 1.5;
1127
1128                                 // Compare against other goals
1129                                 f = f * rangebias / (rangebias + cost);
1130
1131                                 if (navigation_bestrating < f)
1132                                 {
1133                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1134                                         navigation_bestrating = f;
1135                                         navigation_bestgoal = e;
1136                                         this.navigation_jetpack_goal = e;
1137                                         this.navigation_jetpack_point = pointb;
1138                                 }
1139                                 return;
1140                         }
1141                 }
1142         }
1143
1144         entity nwp;
1145         //te_wizspike(e.origin);
1146         //bprint(etos(e));
1147         //bprint("\n");
1148         // update the cached spawnfunc_waypoint link on a dynamic item entity
1149         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1150         {
1151                 nwp = e;
1152         }
1153         else
1154         {
1155                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1156                         e.nearestwaypoint = NULL;
1157
1158                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
1159                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1160                 {
1161                         nwp = navigation_findnearestwaypoint(e, true);
1162                         if(nwp)
1163                         {
1164                                 e.nearestwaypoint = nwp;
1165
1166                                 vector m1 = nwp.absmin, m2 = nwp.absmax;
1167                                 m1.x = nwp.origin.x; m1.y = nwp.origin.y;
1168                                 m2.x = nwp.origin.x; m2.y = nwp.origin.y;
1169                                 vector ve = (e.absmin - e.absmax) * 0.5;
1170                                 ve.x = bound(m1.x, ve.x, m2.x);
1171                                 ve.y = bound(m1.y, ve.y, m2.y);
1172                                 ve.z = bound(m1.z, ve.z, m2.z);
1173
1174                                 m1 = e.absmin; m2 = e.absmax;
1175                                 m1.x = e.origin.x; m1.y = e.origin.y;
1176                                 m2.x = e.origin.x; m2.y = e.origin.y;
1177                                 vector vnwp = nwp.origin;
1178                                 vnwp.x = bound(m1.x, vnwp.x, m2.x);
1179                                 vnwp.y = bound(m1.y, vnwp.y, m2.y);
1180                                 vnwp.z = bound(m1.z, vnwp.z, m2.z);
1181                                 e.nearestwaypoint_dist = vlen(ve - vnwp);
1182                         }
1183                         else
1184                         {
1185                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
1186
1187                                 if(!e.navigation_dynamicgoal)
1188                                         e.blacklisted = true;
1189
1190                                 if(e.blacklisted)
1191                                 {
1192                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
1193                                         return;
1194                                 }
1195                         }
1196
1197                         if(e.navigation_dynamicgoal)
1198                                 e.nearestwaypointtimeout = time + 2;
1199                         else if(autocvar_g_waypointeditor)
1200                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
1201                 }
1202                 nwp = e.nearestwaypoint;
1203         }
1204
1205         LOG_DEBUG("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")");
1206         if (nwp)
1207         if (nwp.wpcost < 10000000)
1208         {
1209                 //te_wizspike(nwp.wpnearestpoint);
1210                 float cost = nwp.wpcost + waypoint_gettravelcost(nwp.wpnearestpoint, goal_org, nwp, e);
1211                 LOG_DEBUG(e.classname, " ", ftos(f), "/(1+", ftos(cost), "/", ftos(rangebias), ") = ");
1212                 f = f * rangebias / (rangebias + cost);
1213                 LOG_DEBUG("considering ", e.classname, " (with rating ", ftos(f), ")");
1214                 if (navigation_bestrating < f)
1215                 {
1216                         LOG_DEBUG("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1217                         navigation_bestrating = f;
1218                         navigation_bestgoal = e;
1219                 }
1220         }
1221 }
1222
1223 // adds an item to the the goal stack with the path to a given item
1224 bool navigation_routetogoal(entity this, entity e, vector startposition)
1225 {
1226         // if there is no goal, just exit
1227         if (!e)
1228                 return false;
1229
1230         if(e.wpflags & WAYPOINTFLAG_TELEPORT)
1231         {
1232                 // force teleport destination as route destination
1233                 e.wp00.enemy = e;
1234                 e = e.wp00;
1235         }
1236
1237         this.goalentity = e;
1238
1239         // put the entity on the goal stack
1240         //print("routetogoal ", etos(e), "\n");
1241         navigation_pushroute(this, e);
1242
1243         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1244         {
1245                 this.wp_goal_prev1 = this.wp_goal_prev0;
1246                 this.wp_goal_prev0 = e;
1247         }
1248
1249         if(g_jetpack)
1250         if(e==this.navigation_jetpack_goal)
1251                 return true;
1252
1253         // if it can reach the goal there is nothing more to do
1254         vector dest = (e.absmin + e.absmax) * 0.5;
1255         dest.z = e.absmin.z;
1256         float dest_height = e.absmax.z - e.absmin.z;
1257         if (tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1258                 return true;
1259
1260         entity nearest_wp = NULL;
1261         // see if there are waypoints describing a path to the item
1262         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
1263         {
1264                 e = e.nearestwaypoint;
1265                 nearest_wp = e;
1266         }
1267         else
1268                 e = e.enemy; // we already have added it, so...
1269
1270         if(e == NULL)
1271                 return false;
1272
1273         if(nearest_wp && nearest_wp.enemy)
1274         {
1275                 // often path can be optimized by not adding the nearest waypoint
1276                 if (this.goalentity.nearestwaypoint_dist < 8)
1277                         e = nearest_wp.enemy;
1278                 else
1279                 {
1280                         if (this.goalentity.navigation_dynamicgoal)
1281                         {
1282                                 vector dest = (this.goalentity.absmin + this.goalentity.absmax) * 0.5;
1283                                 dest.z = this.goalentity.absmin.z;
1284                                 float dest_height = this.goalentity.absmax.z - this.goalentity.absmin.z;
1285                                 if(tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1286                                         e = nearest_wp.enemy;
1287                         }
1288                         else if(navigation_item_islinked(nearest_wp.enemy, this.goalentity))
1289                                 e = nearest_wp.enemy;
1290                 }
1291         }
1292
1293         for (;;)
1294         {
1295                 // add the spawnfunc_waypoint to the path
1296                 navigation_pushroute(this, e);
1297                 e = e.enemy;
1298
1299                 if(e==NULL)
1300                         break;
1301         }
1302
1303         return false;
1304 }
1305
1306 // removes any currently touching waypoints from the goal stack
1307 // (this is how bots detect if they reached a goal)
1308 void navigation_poptouchedgoals(entity this)
1309 {
1310         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1311         {
1312                 // make sure jumppad is really hit, don't rely on distance based checks
1313                 // as they may report a touch even if it didn't really happen
1314                 if(this.lastteleporttime > 0
1315                         && time - this.lastteleporttime < ((this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL) ? 2 : 0.15))
1316                 {
1317                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1318                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1319                         {
1320                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1321                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1322                         }
1323                         navigation_poproute(this);
1324                 }
1325                 else
1326                         return;
1327         }
1328
1329         // If for some reason the bot is closer to the next goal, pop the current one
1330         if(this.goalstack01 && !wasfreed(this.goalstack01))
1331         if(vlen2(this.goalcurrent.origin - this.origin) > vlen2(this.goalstack01.origin - this.origin))
1332         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
1333         {
1334                 vector dest = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1335                 dest.z = this.goalstack01.absmin.z;
1336                 float dest_height = this.goalstack01.absmax.z - this.goalstack01.absmin.z;
1337                 if(tracewalk(this, this.origin, this.mins, this.maxs, dest, dest_height, bot_navigation_movemode))
1338                 {
1339                         LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1340                         navigation_poproute(this);
1341                         // TODO this may also be a nice idea to do "early" (e.g. by
1342                         // manipulating the vlen() comparisons) to shorten paths in
1343                         // general - this would make bots walk more "on rails" than
1344                         // "zigzagging" which they currently do with sufficiently
1345                         // random-like waypoints, and thus can make a nice bot
1346                         // personality property
1347                 }
1348         }
1349
1350         // Loose goal touching check when running
1351         if(this.aistatus & AI_STATUS_RUNNING)
1352         if(this.goalcurrent.classname=="waypoint")
1353         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
1354         {
1355                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1356                 {
1357                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1358                         if(trace_fraction==1)
1359                         {
1360                                 // Detect personal waypoints
1361                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1362                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1363                                 {
1364                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1365                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1366                                 }
1367
1368                                 navigation_poproute(this);
1369                         }
1370                 }
1371         }
1372
1373         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1374         {
1375                 vector gc_min = this.goalcurrent.absmin;
1376                 vector gc_max = this.goalcurrent.absmax;
1377                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1378                 {
1379                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1380                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1381                 }
1382                 if(!boxesoverlap(this.absmin, this.absmax, gc_min, gc_max))
1383                         break;
1384
1385                 // Detect personal waypoints
1386                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1387                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1388                 {
1389                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1390                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1391                 }
1392
1393                 navigation_poproute(this);
1394         }
1395 }
1396
1397 // begin a goal selection session (queries spawnfunc_waypoint network)
1398 void navigation_goalrating_start(entity this)
1399 {
1400         if(this.aistatus & AI_STATUS_STUCK)
1401                 return;
1402
1403         this.navigation_jetpack_goal = NULL;
1404         navigation_bestrating = -1;
1405         navigation_clearroute(this);
1406         navigation_bestgoal = NULL;
1407         navigation_markroutes(this, NULL);
1408 }
1409
1410 // ends a goal selection session (updates goal stack to the best goal)
1411 void navigation_goalrating_end(entity this)
1412 {
1413         if(this.aistatus & AI_STATUS_STUCK)
1414                 return;
1415
1416         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1417         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1418
1419         // If the bot got stuck then try to reach the farthest waypoint
1420         if (!this.goalentity && autocvar_bot_wander_enable)
1421         {
1422                 if (!(this.aistatus & AI_STATUS_STUCK))
1423                 {
1424                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1425                         this.aistatus |= AI_STATUS_STUCK;
1426                 }
1427         }
1428 }
1429
1430 void botframe_updatedangerousobjects(float maxupdate)
1431 {
1432         vector m1, m2, v, o;
1433         float c, d, danger;
1434         c = 0;
1435         entity wp_cur;
1436         IL_EACH(g_waypoints, true,
1437         {
1438                 danger = 0;
1439                 m1 = it.absmin;
1440                 m2 = it.absmax;
1441                 wp_cur = it;
1442                 IL_EACH(g_bot_dodge, it.bot_dodge,
1443                 {
1444                         v = it.origin;
1445                         v.x = bound(m1_x, v.x, m2_x);
1446                         v.y = bound(m1_y, v.y, m2_y);
1447                         v.z = bound(m1_z, v.z, m2_z);
1448                         o = (it.absmin + it.absmax) * 0.5;
1449                         d = waypoint_getlinearcost(it.bot_dodgerating) - waypoint_gettravelcost(o, v, it, wp_cur);
1450                         if (d > 0)
1451                         {
1452                                 traceline(o, v, true, NULL);
1453                                 if (trace_fraction == 1)
1454                                         danger = danger + d;
1455                         }
1456                 });
1457                 it.dmg = danger;
1458                 c = c + 1;
1459                 if (c >= maxupdate)
1460                         break;
1461         });
1462 }
1463
1464 void navigation_unstuck(entity this)
1465 {
1466         float search_radius = 1000;
1467
1468         if (!autocvar_bot_wander_enable)
1469                 return;
1470
1471         if (!bot_waypoint_queue_owner)
1472         {
1473                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1474                 bot_waypoint_queue_owner = this;
1475                 bot_waypoint_queue_bestgoal = NULL;
1476                 bot_waypoint_queue_bestgoalrating = 0;
1477         }
1478
1479         if(bot_waypoint_queue_owner!=this)
1480                 return;
1481
1482         if (bot_waypoint_queue_goal)
1483         {
1484                 // evaluate the next goal on the queue
1485                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1486                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1487                 vector dest = (bot_waypoint_queue_goal.absmin + bot_waypoint_queue_goal.absmax) * 0.5;
1488                 dest.z = bot_waypoint_queue_goal.absmin.z;
1489                 float dest_height = bot_waypoint_queue_goal.absmax.z - bot_waypoint_queue_goal.absmin.z;
1490                 if(tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1491                 {
1492                         if( d > bot_waypoint_queue_bestgoalrating)
1493                         {
1494                                 bot_waypoint_queue_bestgoalrating = d;
1495                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1496                         }
1497                 }
1498                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1499
1500                 if (!bot_waypoint_queue_goal)
1501                 {
1502                         if (bot_waypoint_queue_bestgoal)
1503                         {
1504                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1505                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1506                                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1507                                 this.aistatus &= ~AI_STATUS_STUCK;
1508                         }
1509                         else
1510                         {
1511                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1512                         }
1513
1514                         bot_waypoint_queue_owner = NULL;
1515                 }
1516         }
1517         else
1518         {
1519                 if(bot_strategytoken!=this)
1520                         return;
1521
1522                 // build a new queue
1523                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1524
1525                 entity first = NULL;
1526
1527                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1528                 {
1529                         if(bot_waypoint_queue_goal)
1530                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1531                         else
1532                                 first = it;
1533
1534                         bot_waypoint_queue_goal = it;
1535                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1536                 });
1537
1538                 if (first)
1539                         bot_waypoint_queue_goal = first;
1540                 else
1541                 {
1542                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1543                         bot_waypoint_queue_owner = NULL;
1544                 }
1545         }
1546 }
1547
1548 // Support for debugging tracewalk visually
1549
1550 void debugresetnodes()
1551 {
1552         debuglastnode = '0 0 0';
1553 }
1554
1555 void debugnode(entity this, vector node)
1556 {
1557         if (!IS_PLAYER(this))
1558                 return;
1559
1560         if(debuglastnode=='0 0 0')
1561         {
1562                 debuglastnode = node;
1563                 return;
1564         }
1565
1566         te_lightning2(NULL, node, debuglastnode);
1567         debuglastnode = node;
1568 }
1569
1570 void debugnodestatus(vector position, float status)
1571 {
1572         vector c;
1573
1574         switch (status)
1575         {
1576                 case DEBUG_NODE_SUCCESS:
1577                         c = '0 15 0';
1578                         break;
1579                 case DEBUG_NODE_WARNING:
1580                         c = '15 15 0';
1581                         break;
1582                 case DEBUG_NODE_FAIL:
1583                         c = '15 0 0';
1584                         break;
1585                 default:
1586                         c = '15 15 15';
1587         }
1588
1589         te_customflash(position, 40,  2, c);
1590 }
1591
1592 // Support for debugging the goal stack visually
1593
1594 .float goalcounter;
1595 .vector lastposition;
1596
1597 // Debug the goal stack visually
1598 void debuggoalstack(entity this)
1599 {
1600         entity goal;
1601         vector org, go;
1602
1603         if(this.goalcounter==0)goal=this.goalcurrent;
1604         else if(this.goalcounter==1)goal=this.goalstack01;
1605         else if(this.goalcounter==2)goal=this.goalstack02;
1606         else if(this.goalcounter==3)goal=this.goalstack03;
1607         else if(this.goalcounter==4)goal=this.goalstack04;
1608         else if(this.goalcounter==5)goal=this.goalstack05;
1609         else if(this.goalcounter==6)goal=this.goalstack06;
1610         else if(this.goalcounter==7)goal=this.goalstack07;
1611         else if(this.goalcounter==8)goal=this.goalstack08;
1612         else if(this.goalcounter==9)goal=this.goalstack09;
1613         else if(this.goalcounter==10)goal=this.goalstack10;
1614         else if(this.goalcounter==11)goal=this.goalstack11;
1615         else if(this.goalcounter==12)goal=this.goalstack12;
1616         else if(this.goalcounter==13)goal=this.goalstack13;
1617         else if(this.goalcounter==14)goal=this.goalstack14;
1618         else if(this.goalcounter==15)goal=this.goalstack15;
1619         else if(this.goalcounter==16)goal=this.goalstack16;
1620         else if(this.goalcounter==17)goal=this.goalstack17;
1621         else if(this.goalcounter==18)goal=this.goalstack18;
1622         else if(this.goalcounter==19)goal=this.goalstack19;
1623         else if(this.goalcounter==20)goal=this.goalstack20;
1624         else if(this.goalcounter==21)goal=this.goalstack21;
1625         else if(this.goalcounter==22)goal=this.goalstack22;
1626         else if(this.goalcounter==23)goal=this.goalstack23;
1627         else if(this.goalcounter==24)goal=this.goalstack24;
1628         else if(this.goalcounter==25)goal=this.goalstack25;
1629         else if(this.goalcounter==26)goal=this.goalstack26;
1630         else if(this.goalcounter==27)goal=this.goalstack27;
1631         else if(this.goalcounter==28)goal=this.goalstack28;
1632         else if(this.goalcounter==29)goal=this.goalstack29;
1633         else if(this.goalcounter==30)goal=this.goalstack30;
1634         else if(this.goalcounter==31)goal=this.goalstack31;
1635         else goal=NULL;
1636
1637         if(goal==NULL)
1638         {
1639                 this.goalcounter = 0;
1640                 this.lastposition='0 0 0';
1641                 return;
1642         }
1643
1644         if(this.lastposition=='0 0 0')
1645                 org = this.origin;
1646         else
1647                 org = this.lastposition;
1648
1649
1650         go = ( goal.absmin + goal.absmax ) * 0.5;
1651         te_lightning2(NULL, org, go);
1652         this.lastposition = go;
1653
1654         this.goalcounter++;
1655 }