qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 bool waypoint_has_hardwiredlinks(entity wp)
 264 {
 265         if (!wp)
 266                 return false;
 267         return (wp.wphw00 != NULL);
 268 }
 269
 270 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 271 {
 272         if (!(wp_from && wp_to))
 273                 return false;
 274
 275         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 276         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 277         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 278         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 279         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 280         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 281         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 282         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 283
 284         return false;
 285 }
 286
 287 void waypoint_setupmodel(entity wp);
 288 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 289 {
 290         if (!(wp_from && wp_to))
 291                 return;
 292
 293         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 294         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 295         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 296         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 297         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 298         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 299         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 300         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 301
 302         return;
 303 }
 304
 305 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 306 {
 307         if (!(wp_from && wp_to))
 308                 return;
 309
 310         int removed = -1;
 311         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 312         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 313         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 314         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 315         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 316         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 317         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 318         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 319
 320         if (removed >= 0)
 321         {
 322                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 323                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 324                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 325                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 326                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 327                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 328                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 329                 if (removed <= 7) wp_from.wphw07 = NULL;
 330                 if (!wp_from.wphw00)
 331                         waypoint_setupmodel(wp_from);
 332         }
 333
 334         return;
 335 }
 336
 337 void waypoint_setupmodel(entity wp)
 338 {
 339         if (autocvar_g_waypointeditor)
 340         {
 341                 // TODO: add some sort of visible box in edit mode for box waypoints
 342                 vector m1 = wp.mins;
 343                 vector m2 = wp.maxs;
 344                 setmodel(wp, MDL_WAYPOINT);
 345                 setsize(wp, m1, m2);
 346                 wp.effects = EF_LOWPRECISION;
 347                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 348                         wp.colormod = '1 0 0'; // red
 349                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 350                         wp.colormod = '1 1 0'; // yellow
 351                 else if (wp.wpflags & WAYPOINTFLAG_SUPPORT)
 352                         wp.colormod = '0 1 0'; // green
 353                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 354                         wp.colormod = '1 0.5 0'; // orange
 355                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 356                         wp.colormod = '0 1 1'; // cyan
 357                 else if (waypoint_has_hardwiredlinks(wp))
 358                         wp.colormod = '0.5 0 1'; // purple
 359                 else
 360                         wp.colormod = '1 1 1';
 361         }
 362         else
 363                 wp.model = "";
 364 }
 365
 366 string waypoint_get_type_name(entity wp)
 367 {
 368         if (wp.wpflags & WAYPOINTFLAG_ITEM) return "^1Item waypoint";
 369         else if (wp.wpflags & WAYPOINTFLAG_CROUCH) return "^5Crouch waypoint";
 370         else if (wp.wpflags & WAYPOINTFLAG_JUMP) return "^xf80Jump waypoint";
 371         else if (wp.wpflags & WAYPOINTFLAG_SUPPORT) return "^2Support waypoint";
 372         else if (waypoint_has_hardwiredlinks(wp)) return "^x80fHardwired waypoint";
 373         else if (wp.wpflags & WAYPOINTFLAG_LADDER) return "^3Ladder waypoint";
 374         else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 375         {
 376                 if (!wp.wpisbox) return "^3Warpzone waypoint";
 377                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP) return "^3Custom jumppad waypoint";
 378                 else
 379                 {
 380                         IL_EACH(g_jumppads, boxesoverlap(wp.absmin, wp.absmax, it.absmin, it.absmax),
 381                                 { return "^3Jumppad waypoint"; });
 382                         return "^3Teleport waypoint";
 383                 }
 384         }
 385
 386         return "^7Waypoint";
 387 }
 388
 389 entity waypoint_get(vector m1, vector m2)
 390 {
 391         if (m1 == m2)
 392         {
 393                 m1 -= '8 8 8';
 394                 m2 += '8 8 8';
 395         }
 396         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 397
 398         return NULL;
 399 }
 400
 401 .float createdtime;
 402 entity waypoint_spawn(vector m1, vector m2, float f)
 403 {
 404         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 405         {
 406                 entity wp_found = waypoint_get(m1, m2);
 407                 if (wp_found)
 408                         return wp_found;
 409         }
 410         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 411         // otherwise links loaded from file would be applied only to the first destination
 412         // waypoint since link format doesn't specify waypoint entities but just positions
 413         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 414         {
 415                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 416                 {
 417                         return it;
 418                 });
 419         }
 420
 421         entity w = new(waypoint);
 422         IL_PUSH(g_waypoints, w);
 423         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 424         w.wpflags = f;
 425         w.solid = SOLID_TRIGGER;
 426         w.createdtime = time;
 427         setorigin(w, (m1 + m2) * 0.5);
 428         setsize(w, m1 - w.origin, m2 - w.origin);
 429         if (w.size)
 430                 w.wpisbox = true;
 431
 432         if(!w.wpisbox)
 433         {
 434                 if (f & WAYPOINTFLAG_CROUCH)
 435                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 436                 else
 437                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 438                 if(!move_out_of_solid(w))
 439                 {
 440                         if(!(f & WAYPOINTFLAG_GENERATED))
 441                         {
 442                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 443                                 delete(w);
 444                                 return NULL;
 445                         }
 446                         else
 447                         {
 448                                 if(autocvar_developer)
 449                                 {
 450                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 451                                         backtrace("Waypoint stuck");
 452                                 }
 453                         }
 454                 }
 455                 setsize(w, '0 0 0', '0 0 0');
 456         }
 457
 458         waypoint_clearlinks(w);
 459         //waypoint_schedulerelink(w);
 460
 461         waypoint_setupmodel(w);
 462
 463         return w;
 464 }
 465
 466 float trigger_push_get_push_time(entity this, vector endpos);
 467 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 468 {
 469         entity jp = NULL;
 470         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 471         {
 472                 jp = it;
 473                 break;
 474         });
 475         if (!jp)
 476                 return;
 477
 478         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 479         wp_from.wp00 = wp_to;
 480         wp_from.wp00mincost = cost;
 481         jp.nearestwaypoint = wp_from;
 482         jp.nearestwaypointtimeout = -1;
 483 }
 484
 485 bool start_wp_is_spawned;
 486 vector start_wp_origin;
 487 bool start_wp_is_hardwired;
 488 bool start_wp_is_support;
 489
 490 void waypoint_clear_start_wp_globals(entity pl, bool warn)
 491 {
 492         start_wp_is_spawned = false;
 493         start_wp_origin = '0 0 0';
 494         pl.wp_locked = NULL;
 495         start_wp_is_hardwired = false;
 496         start_wp_is_support = false;
 497         if (warn)
 498                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 499 }
 500
 501 void waypoint_start_hardwiredlink(entity pl)
 502 {
 503         entity wp = pl.nearestwaypoint;
 504         if ((!start_wp_is_spawned || start_wp_is_hardwired) && wp && !(wp.wpflags & WAYPOINTFLAG_NORELINK))
 505         {
 506                 start_wp_is_hardwired = true;
 507                 start_wp_is_spawned = true;
 508                 start_wp_origin = wp.origin;
 509                 pl.wp_locked = wp;
 510                 LOG_INFOF("^x80fNearest waypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 511         }
 512         else
 513                 start_wp_is_hardwired = false;
 514 }
 515
 516 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp, bool is_support_wp)
 517 {
 518         if (WAYPOINT_VERSION < waypoint_version_loaded)
 519         {
 520                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 521                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 522                 return;
 523         }
 524
 525         entity e = NULL, jp = NULL;
 526         vector org = pl.origin;
 527         if (at_crosshair)
 528         {
 529                 crosshair_trace(pl);
 530                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 531                 if (!(start_wp_is_hardwired || start_wp_is_support))
 532                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 533                         {
 534                                 jp = it;
 535                                 break;
 536                         });
 537         }
 538         if (jp || is_jump_wp || is_support_wp)
 539         {
 540                 if (start_wp_is_spawned)
 541                         start_wp_is_spawned = false;
 542                 LOG_INFO("^xf80Spawning start waypoint...\n");
 543         }
 544         int ctf_flags = havocbot_symmetry_origin_order;
 545         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 546                    || (autocvar_g_waypointeditor_symmetrical < 0));
 547         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 548                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 549         if (sym && ctf_flags < 2)
 550                 ctf_flags = 2;
 551         int wp_num = ctf_flags;
 552
 553         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp && !is_support_wp)
 554         {
 555                 // snap waypoint to item's origin if close enough
 556                 IL_EACH(g_items, true,
 557                 {
 558                         vector item_org = (it.absmin + it.absmax) * 0.5;
 559                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 560                         if (vlen(item_org - org) < 20)
 561                         {
 562                                 org = item_org;
 563                                 break;
 564                         }
 565                 });
 566         }
 567
 568         vector start_org = '0 0 0';
 569         if (start_wp_is_spawned)
 570         {
 571                 if (!start_wp_is_hardwired)
 572                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 573                 start_org = start_wp_origin;
 574         }
 575
 576         // save org as it can be modified spawning symmetrycal waypoints
 577         vector initial_origin = '0 0 0';
 578         bool initial_origin_is_set = false;
 579
 580         LABEL(add_wp);
 581
 582         if (jp)
 583         {
 584                 e = NULL;
 585                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 586                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 587                 {
 588                         e = it; break;
 589                 });
 590                 if (!e)
 591                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 592                 if (!pl.wp_locked)
 593                         pl.wp_locked = e;
 594         }
 595         else if (is_jump_wp || is_support_wp)
 596         {
 597                 int type_flag = (is_jump_wp) ? WAYPOINTFLAG_JUMP : WAYPOINTFLAG_SUPPORT;
 598
 599                 entity wp_found = waypoint_get(org, org);
 600                 if (wp_found && !(wp_found.wpflags & type_flag))
 601                 {
 602                         LOG_INFOF("Error: can't spawn a %s waypoint over an existent waypoint of a different type\n", (is_jump_wp) ? "Jump" : "Support");
 603                         return;
 604                 }
 605                 e = waypoint_spawn(org, org, type_flag | WAYPOINTFLAG_NORELINK);
 606                 if (!pl.wp_locked)
 607                         pl.wp_locked = e;
 608         }
 609         else
 610                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 611         if(!e)
 612         {
 613                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 614                 if (start_wp_is_spawned)
 615                         waypoint_clear_start_wp_globals(pl, true);
 616                 return;
 617         }
 618
 619         if (!initial_origin_is_set)
 620         {
 621                 initial_origin = e.origin;
 622                 initial_origin_is_set = true;
 623         }
 624
 625         entity start_wp = NULL;
 626         if (start_wp_is_spawned)
 627         {
 628                 IL_EACH(g_waypoints, (start_wp_is_hardwired || it.wpflags & WAYPOINTFLAG_NORELINK)
 629                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 630                 {
 631                         start_wp = it; break;
 632                 });
 633                 if(!start_wp)
 634                 {
 635                         // should not happen
 636                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 637                         waypoint_clear_start_wp_globals(pl, true);
 638                         return;
 639                 }
 640                 if (start_wp_is_hardwired)
 641                 {
 642                         if (waypoint_is_hardwiredlink(start_wp, e))
 643                         {
 644                                 waypoint_unmark_hardwiredlink(start_wp, e);
 645                                 waypoint_removelink(start_wp, e);
 646                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 647                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 648                         }
 649                         else
 650                         {
 651                                 if (e.createdtime == time)
 652                                 {
 653                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 654                                         waypoint_remove(e);
 655                                         waypoint_clear_start_wp_globals(pl, true);
 656                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp, is_support_wp);
 657                                         return;
 658                                 }
 659                                 if (start_wp == e)
 660                                 {
 661                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 662                                         waypoint_clear_start_wp_globals(pl, true);
 663                                         return;
 664                                 }
 665                                 if (waypoint_islinked(start_wp, e))
 666                                 {
 667                                         LOG_INFO("Error: waypoints are already linked.\n");
 668                                         waypoint_clear_start_wp_globals(pl, true);
 669                                         return;
 670                                 }
 671                                 waypoint_addlink(start_wp, e);
 672                                 waypoint_mark_hardwiredlink(start_wp, e);
 673                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 674                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 675                         }
 676                 }
 677                 else
 678                 {
 679                         if (start_wp_is_support)
 680                         {
 681                                 if (e.SUPPORT_WP)
 682                                 {
 683                                         LOG_INFOF("Waypoint %v has already a support waypoint, delete it first.\n", e.origin);
 684                                         waypoint_clear_start_wp_globals(pl, true);
 685                                         return;
 686                                 }
 687                                 // clear all links to e
 688                                 IL_EACH(g_waypoints, it != e,
 689                                 {
 690                                         if (waypoint_islinked(it, e) && !waypoint_is_hardwiredlink(it, e))
 691                                                 waypoint_removelink(it, e);
 692                                 });
 693                         }
 694                         waypoint_addlink(start_wp, e);
 695                 }
 696         }
 697
 698         if (!(jp || is_jump_wp || is_support_wp || start_wp_is_hardwired))
 699                 waypoint_schedulerelink(e);
 700
 701         string wp_type_str = waypoint_get_type_name(e);
 702
 703         bprint(strcat(wp_type_str, "^7 spawned at ", vtos(e.origin), "\n"));
 704
 705         if (start_wp_is_spawned)
 706         {
 707                 pl.wp_locked = NULL;
 708                 if (!start_wp_is_hardwired)
 709                         waypoint_schedulerelink(start_wp);
 710                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 711                 {
 712                         if (start_wp.wp00_original == start_wp.wp00)
 713                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 714                         else
 715                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 716                 }
 717         }
 718
 719         if (sym)
 720         {
 721                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 722                 if (jp)
 723                 {
 724                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 725                         {
 726                                 jp = it; break;
 727                         });
 728                 }
 729                 if (start_wp_is_spawned)
 730                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 731                 if (vdist(org - pl.origin, >, 32))
 732                 {
 733                         if(wp_num > 2)
 734                                 wp_num--;
 735                         else
 736                                 sym = false;
 737                         goto add_wp;
 738                 }
 739         }
 740         if (jp || is_jump_wp || is_support_wp)
 741         {
 742                 if (!start_wp_is_spawned)
 743                 {
 744                         // we've just created a custom jumppad waypoint
 745                         // the next one created by the user will be the destination waypoint
 746                         start_wp_is_spawned = true;
 747                         start_wp_origin = initial_origin;
 748                         if (is_support_wp)
 749                                 start_wp_is_support = true;
 750                 }
 751         }
 752         else if (start_wp_is_spawned)
 753         {
 754                 waypoint_clear_start_wp_globals(pl, false);
 755         }
 756 }
 757
 758 void waypoint_remove(entity wp)
 759 {
 760         IL_EACH(g_waypoints, it != wp,
 761         {
 762                 if (it.SUPPORT_WP == wp)
 763                 {
 764                         it.SUPPORT_WP = NULL;
 765                         waypoint_schedulerelink(it); // restore incoming links
 766                 }
 767                 if (waypoint_islinked(it, wp))
 768                 {
 769                         if (waypoint_is_hardwiredlink(it, wp))
 770                                 waypoint_unmark_hardwiredlink(it, wp);
 771                         waypoint_removelink(it, wp);
 772                 }
 773         });
 774         delete(wp);
 775 }
 776
 777 void waypoint_remove_fromeditor(entity pl)
 778 {
 779         if (WAYPOINT_VERSION < waypoint_version_loaded)
 780         {
 781                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 782                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 783                 return;
 784         }
 785
 786         entity e = navigation_findnearestwaypoint(pl, false);
 787
 788         int ctf_flags = havocbot_symmetry_origin_order;
 789         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 790                    || (autocvar_g_waypointeditor_symmetrical < 0));
 791         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 792                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 793         if (sym && ctf_flags < 2)
 794                 ctf_flags = 2;
 795         int wp_num = ctf_flags;
 796
 797         LABEL(remove_wp);
 798         if (!e) return;
 799
 800         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 801         {
 802                 if (start_wp_is_spawned)
 803                         waypoint_clear_start_wp_globals(pl, true);
 804                 return;
 805         }
 806
 807         if (waypoint_has_hardwiredlinks(e))
 808         {
 809                 LOG_INFO("Can't remove a waypoint with hardwired links, remove them with \"wpeditor hardwire\" first\n");
 810                 return;
 811         }
 812
 813         entity wp_sym = NULL;
 814         if (sym)
 815         {
 816                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 817                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 818                         if(vdist(org - it.origin, <, 3))
 819                         {
 820                                 wp_sym = it;
 821                                 break;
 822                         }
 823                 });
 824         }
 825
 826         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 827         waypoint_remove(e);
 828
 829         if (sym && wp_sym)
 830         {
 831                 e = wp_sym;
 832                 if(wp_num > 2)
 833                         wp_num--;
 834                 else
 835                         sym = false;
 836                 goto remove_wp;
 837         }
 838
 839         if (start_wp_is_spawned)
 840                 waypoint_clear_start_wp_globals(pl, true);
 841 }
 842
 843 void waypoint_removelink(entity from, entity to)
 844 {
 845         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))))
 846                 return;
 847
 848         entity fromwp31_prev = from.wp31;
 849
 850         switch (waypoint_getlinknum(from, to))
 851         {
 852                 // fallthrough all the way
 853                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 854                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 855                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 856                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 857                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 858                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 859                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 860                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 861                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 862                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 863                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 864                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 865                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 866                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 867                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 868                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 869                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 870                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 871                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 872                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 873                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 874                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 875                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 876                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 877                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 878                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 879                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 880                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 881                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 882                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 883                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 884                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 885         }
 886
 887         if (fromwp31_prev && !from.wp31)
 888                 waypoint_schedulerelink(from);
 889 }
 890
 891 int waypoint_getlinknum(entity from, entity to)
 892 {
 893         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 894         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 895         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 896         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 897         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 898         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 899         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 900         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 901         return -1;
 902 }
 903
 904 bool waypoint_islinked(entity from, entity to)
 905 {
 906         return (waypoint_getlinknum(from, to) >= 0);
 907 }
 908
 909 void waypoint_updatecost_foralllinks()
 910 {
 911         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 912         {
 913                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 914                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 915                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 916                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 917                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 918                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 919                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 920                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 921                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 922                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 923                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 924                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 925                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 926                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 927                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 928                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 929                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 930                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 931                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 932                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 933                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 934                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 935                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 936                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 937                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 938                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 939                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 940                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 941                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 942                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 943                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 944                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 945         });
 946 }
 947
 948 float waypoint_getlinearcost(float dist)
 949 {
 950         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 951                 return dist / (autocvar_sv_maxspeed * 1.25);
 952         return dist / autocvar_sv_maxspeed;
 953 }
 954
 955 float waypoint_getlinearcost_underwater(float dist)
 956 {
 957         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 958         return dist / (autocvar_sv_maxspeed * 0.7);
 959 }
 960
 961 float waypoint_getlinearcost_crouched(float dist)
 962 {
 963         return dist / (autocvar_sv_maxspeed * 0.5);
 964 }
 965
 966 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 967 {
 968         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 969         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 970
 971         if (submerged_from && submerged_to)
 972                 return waypoint_getlinearcost_underwater(vlen(to - from));
 973
 974         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH && to_ent.wpflags & WAYPOINTFLAG_CROUCH)
 975                 return waypoint_getlinearcost_crouched(vlen(to - from));
 976
 977         float c = waypoint_getlinearcost(vlen(to - from));
 978
 979         float height = from.z - to.z;
 980         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 981         {
 982                 float height_cost; // fall cost
 983                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
 984                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
 985                 else
 986                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 987                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 988                 if(height_cost > c)
 989                         c = height_cost;
 990         }
 991
 992         // consider half path underwater
 993         if (submerged_from || submerged_to)
 994                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 995
 996         // consider half path crouched
 997         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH || to_ent.wpflags & WAYPOINTFLAG_CROUCH)
 998                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
 999
1000         return c;
1001 }
1002
1003 float waypoint_getlinkcost(entity from, entity to)
1004 {
1005         vector v1 = from.origin;
1006         vector v2 = to.origin;
1007         if (from.wpisbox)
1008         {
1009                 vector m1 = from.absmin, m2 = from.absmax;
1010                 v1.x = bound(m1.x, v2.x, m2.x);
1011                 v1.y = bound(m1.y, v2.y, m2.y);
1012                 v1.z = bound(m1.z, v2.z, m2.z);
1013         }
1014         if (to.wpisbox)
1015         {
1016                 vector m1 = to.absmin, m2 = to.absmax;
1017                 v2.x = bound(m1.x, v1.x, m2.x);
1018                 v2.y = bound(m1.y, v1.y, m2.y);
1019                 v2.z = bound(m1.z, v1.z, m2.z);
1020         }
1021         return waypoint_gettravelcost(v1, v2, from, to);
1022 }
1023
1024 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
1025 // if c == -1 automatically determine cost of the link
1026 void waypoint_addlink_customcost(entity from, entity to, float c)
1027 {
1028         if (from == to || waypoint_islinked(from, to))
1029                 return;
1030         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1031                 return;
1032
1033         if(c == -1)
1034                 c = waypoint_getlinkcost(from, to);
1035
1036         if (from.wp31mincost < c) return;
1037         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
1038         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
1039         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
1040         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
1041         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
1042         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
1043         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
1044         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
1045         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
1046         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
1047         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
1048         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
1049         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
1050         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
1051         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
1052         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
1053         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
1054         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
1055         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
1056         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1057         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1058         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1059         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1060         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1061         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1062         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1063         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1064         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1065         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1066         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1067         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1068         from.wp00 = to;from.wp00mincost = c;return;
1069 }
1070
1071 void waypoint_addlink(entity from, entity to)
1072 {
1073         if ((from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1074                 waypoint_addlink_for_custom_jumppad(from, to);
1075         else
1076                 waypoint_addlink_customcost(from, to, -1);
1077
1078         if (from.wpflags & WAYPOINTFLAG_SUPPORT)
1079                 to.SUPPORT_WP = from;
1080 }
1081
1082 // relink this spawnfunc_waypoint
1083 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1084 // (SLOW!)
1085 void waypoint_think(entity this)
1086 {
1087         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1088         float sv2_height = 0, ev2_height = 0;
1089
1090         bot_calculate_stepheightvec();
1091
1092         int dphitcontentsmask_save = this.dphitcontentsmask;
1093         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1094
1095         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1096
1097         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1098         IL_EACH(g_waypoints, this != it,
1099         {
1100                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1101                 {
1102                         if (!(this.wpflags & WAYPOINTFLAG_NORELINK))
1103                                 waypoint_addlink(this, it);
1104                         if (!(it.wpflags & WAYPOINTFLAG_NORELINK))
1105                                 waypoint_addlink(it, this);
1106                 }
1107                 else
1108                 {
1109                         ++relink_total;
1110                         if(!checkpvs(this.origin, it))
1111                         {
1112                                 ++relink_pvsculled;
1113                                 continue;
1114                         }
1115
1116                         sv = set_tracewalk_dest_2(this, it.origin);
1117                         sv2 = tracewalk_dest;
1118                         sv2_height = tracewalk_dest_height;
1119                         ev = set_tracewalk_dest_2(it, this.origin);
1120                         ev2 = tracewalk_dest;
1121                         ev2_height = tracewalk_dest_height;
1122
1123                         dv = ev - sv;
1124                         dv.z = 0;
1125                         int maxdist = 1050;
1126                         vector m1 = PL_MIN_CONST;
1127                         vector m2 = PL_MAX_CONST;
1128
1129                         if (this.wpflags & WAYPOINTFLAG_CROUCH || it.wpflags & WAYPOINTFLAG_CROUCH)
1130                         {
1131                                 m1 = PL_CROUCH_MIN_CONST;
1132                                 m2 = PL_CROUCH_MAX_CONST;
1133                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1134                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1135                                 // links from crouch wp to crouch wp can be as long as normal links
1136                                 if (!(this.wpflags & WAYPOINTFLAG_CROUCH && it.wpflags & WAYPOINTFLAG_CROUCH))
1137                                         maxdist = 100;
1138                         }
1139
1140                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1141                         {
1142                                 ++relink_lengthculled;
1143                                 continue;
1144                         }
1145
1146                         navigation_testtracewalk = 0;
1147
1148                         //traceline(this.origin, it.origin, false, NULL);
1149                         //if (trace_fraction == 1)
1150                         if (this.wpisbox || this.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT) // forbid outgoing links
1151                                 || it.SUPPORT_WP) // forbid incoming links
1152                         {
1153                                 relink_walkculled += 0.5;
1154                         }
1155                         else
1156                         {
1157                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1158                                         waypoint_addlink(this, it);
1159                                 else
1160                                         relink_walkculled += 0.5;
1161                         }
1162
1163                         // reverse direction
1164                         if (it.wpisbox || it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT) // forbid incoming links
1165                                 || this.SUPPORT_WP) // forbid outgoing links
1166                         {
1167                                 relink_walkculled += 0.5;
1168                         }
1169                         else
1170                         {
1171                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1172                                         waypoint_addlink(it, this);
1173                                 else
1174                                         relink_walkculled += 0.5;
1175                         }
1176                 }
1177         });
1178         navigation_testtracewalk = 0;
1179         this.wplinked = true;
1180         this.dphitcontentsmask = dphitcontentsmask_save;
1181
1182         setthink(this, func_null);
1183         this.nextthink = 0;
1184 }
1185
1186 void waypoint_clearlinks(entity wp)
1187 {
1188         // clear links to other waypoints
1189         float f = 10000000;
1190         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1191         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1192         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1193         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1194
1195         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1196         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1197         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1198         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1199
1200         wp.wplinked = false;
1201 }
1202
1203 // tell a spawnfunc_waypoint to relink
1204 void waypoint_schedulerelink(entity wp)
1205 {
1206         if (wp == NULL)
1207                 return;
1208
1209         waypoint_setupmodel(wp);
1210         wp.wpisbox = vdist(wp.size, >, 0);
1211         wp.enemy = NULL;
1212         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1213                 wp.owner = NULL;
1214         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
1215                 waypoint_clearlinks(wp);
1216         // schedule an actual relink on next frame
1217         setthink(wp, waypoint_think);
1218         wp.nextthink = time;
1219         wp.effects = EF_LOWPRECISION;
1220 }
1221
1222 // spawnfunc_waypoint map entity
1223 spawnfunc(waypoint)
1224 {
1225         IL_PUSH(g_waypoints, this);
1226
1227         setorigin(this, this.origin);
1228         // schedule a relink after other waypoints have had a chance to spawn
1229         waypoint_clearlinks(this);
1230         //waypoint_schedulerelink(this);
1231 }
1232
1233 // tell all waypoints to relink
1234 // actually this is useful only to update relink_* stats
1235 void waypoint_schedulerelinkall()
1236 {
1237         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1238         IL_EACH(g_waypoints, true,
1239         {
1240                 waypoint_schedulerelink(it);
1241         });
1242         waypoint_load_hardwiredlinks();
1243 }
1244
1245 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1246
1247 // Load waypoint links from file
1248 bool waypoint_load_links()
1249 {
1250         string s;
1251         float file, tokens, c = 0, found;
1252         entity wp_from = NULL, wp_to;
1253         vector wp_to_pos, wp_from_pos;
1254
1255         string gt_ext = GET_GAMETYPE_EXTENSION();
1256
1257         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1258         file = fopen(filename, FILE_READ);
1259
1260         if (gt_ext != "" && file < 0)
1261         {
1262                 // if race waypoint file doesn't exist load the default one
1263                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1264                 file = fopen(filename, FILE_READ);
1265         }
1266
1267         if (file < 0)
1268         {
1269                 LOG_TRACE("waypoint links load from ", filename, " failed");
1270                 waypoint_schedulerelinkall();
1271                 return false;
1272         }
1273
1274         bool parse_comments = true;
1275         float ver = 0;
1276         string links_time = string_null;
1277
1278         while ((s = fgets(file)))
1279         {
1280                 if(parse_comments)
1281                 {
1282                         if(substring(s, 0, 2) == "//")
1283                         {
1284                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1285                                         ver = stof(substring(s, 19, -1));
1286                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1287                                         links_time = substring(s, 16, -1);
1288                                 continue;
1289                         }
1290                         else
1291                         {
1292                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1293                                 {
1294                                         if (links_time != waypoint_time)
1295                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1296                                         else
1297                                                 LOG_TRACE("waypoint links for this map are outdated.");
1298                                         if (g_assault)
1299                                         {
1300                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1301                                         }
1302                                         else
1303                                         {
1304                                                 LOG_TRACE("automatically updating...");
1305                                                 waypoint_schedulerelinkall();
1306                                                 fclose(file);
1307                                                 return false;
1308                                         }
1309                                 }
1310                                 parse_comments = false;
1311                         }
1312                 }
1313
1314                 tokens = tokenizebyseparator(s, "*");
1315
1316                 if (tokens!=2)
1317                 {
1318                         // bad file format
1319                         fclose(file);
1320                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1321                         return false;
1322                 }
1323
1324                 wp_from_pos     = stov(argv(0));
1325                 wp_to_pos       = stov(argv(1));
1326
1327                 // Search "from" waypoint
1328                 if(!wp_from || wp_from.origin!=wp_from_pos)
1329                 {
1330                         wp_from = findradius(wp_from_pos, 1);
1331                         found = false;
1332                         while(wp_from)
1333                         {
1334                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1335                                 if(wp_from.classname == "waypoint")
1336                                 {
1337                                         found = true;
1338                                         break;
1339                                 }
1340                                 wp_from = wp_from.chain;
1341                         }
1342
1343                         if(!found)
1344                         {
1345                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1346                                 continue;
1347                         }
1348                 }
1349
1350                 // Search "to" waypoint
1351                 wp_to = findradius(wp_to_pos, 1);
1352                 found = false;
1353                 while(wp_to)
1354                 {
1355                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1356                         if(wp_to.classname == "waypoint")
1357                         {
1358                                 found = true;
1359                                 break;
1360                         }
1361                         wp_to = wp_to.chain;
1362                 }
1363
1364                 if(!found)
1365                 {
1366                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1367                         continue;
1368                 }
1369
1370                 ++c;
1371                 waypoint_addlink(wp_from, wp_to);
1372                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1373                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1374         }
1375
1376         fclose(file);
1377
1378         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1379
1380         bool scheduled = false;
1381         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1382         {
1383                 if (!it.wp00)
1384                 {
1385                         waypoint_schedulerelink(it);
1386                         scheduled = true;
1387                 }
1388         });
1389         if (scheduled)
1390                 return false;
1391
1392         botframe_cachedwaypointlinks = true;
1393         return true;
1394 }
1395
1396 void waypoint_load_hardwiredlinks()
1397 {
1398         string s;
1399         float file, tokens, c = 0, found;
1400         entity wp_from = NULL, wp_to;
1401         vector wp_to_pos, wp_from_pos;
1402
1403         string gt_ext = GET_GAMETYPE_EXTENSION();
1404
1405         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1406         file = fopen(filename, FILE_READ);
1407
1408         if (gt_ext != "" && file < 0)
1409         {
1410                 // if race waypoint file doesn't exist load the default one
1411                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1412                 file = fopen(filename, FILE_READ);
1413         }
1414
1415         botframe_loadedforcedlinks = true;
1416
1417         if (file < 0)
1418         {
1419                 LOG_TRACE("waypoint links load from ", filename, " failed");
1420                 return;
1421         }
1422
1423         bool is_special = false;
1424         while ((s = fgets(file)))
1425         {
1426                 if(substring(s, 0, 2)=="//")
1427                         continue;
1428
1429                 if(substring(s, 0, 1)=="#")
1430                         continue;
1431
1432                 // special links start with *, so old xonotic versions don't load them
1433                 is_special = false;
1434                 if (substring(s, 0, 1) == "*")
1435                 {
1436                         is_special = true;
1437                         s = substring(s, 1, -1);
1438                 }
1439
1440                 tokens = tokenizebyseparator(s, "*");
1441
1442                 if (tokens!=2)
1443                         continue;
1444
1445                 wp_from_pos     = stov(argv(0));
1446                 wp_to_pos       = stov(argv(1));
1447
1448                 // Search "from" waypoint
1449                 if(!wp_from || wp_from.origin!=wp_from_pos)
1450                 {
1451                         wp_from = findradius(wp_from_pos, 5);
1452                         found = false;
1453                         while(wp_from)
1454                         {
1455                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1456                                 if(wp_from.classname == "waypoint")
1457                                 {
1458                                         found = true;
1459                                         break;
1460                                 }
1461                                 wp_from = wp_from.chain;
1462                         }
1463
1464                         if(!found)
1465                         {
1466                                 LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1467                                 continue;
1468                         }
1469                 }
1470
1471                 // Search "to" waypoint
1472                 wp_to = findradius(wp_to_pos, 5);
1473                 found = false;
1474                 while(wp_to)
1475                 {
1476                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1477                         if(wp_to.classname == "waypoint")
1478                         {
1479                                 found = true;
1480                                 break;
1481                         }
1482                         wp_to = wp_to.chain;
1483                 }
1484
1485                 if(!found)
1486                 {
1487                         LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1488                         continue;
1489                 }
1490
1491                 ++c;
1492
1493                 if (!is_special)
1494                 {
1495                         waypoint_addlink(wp_from, wp_to);
1496                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1497                 } else if (wp_from.wpflags & WAYPOINTFLAG_NORELINK
1498                         && (wp_from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)
1499                                 || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1500                 {
1501                         waypoint_addlink(wp_from, wp_to);
1502                 }
1503         }
1504
1505         fclose(file);
1506
1507         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1508 }
1509
1510 entity waypoint_get_link(entity w, float i)
1511 {
1512         switch(i)
1513         {
1514                 case  0:return w.wp00;
1515                 case  1:return w.wp01;
1516                 case  2:return w.wp02;
1517                 case  3:return w.wp03;
1518                 case  4:return w.wp04;
1519                 case  5:return w.wp05;
1520                 case  6:return w.wp06;
1521                 case  7:return w.wp07;
1522                 case  8:return w.wp08;
1523                 case  9:return w.wp09;
1524                 case 10:return w.wp10;
1525                 case 11:return w.wp11;
1526                 case 12:return w.wp12;
1527                 case 13:return w.wp13;
1528                 case 14:return w.wp14;
1529                 case 15:return w.wp15;
1530                 case 16:return w.wp16;
1531                 case 17:return w.wp17;
1532                 case 18:return w.wp18;
1533                 case 19:return w.wp19;
1534                 case 20:return w.wp20;
1535                 case 21:return w.wp21;
1536                 case 22:return w.wp22;
1537                 case 23:return w.wp23;
1538                 case 24:return w.wp24;
1539                 case 25:return w.wp25;
1540                 case 26:return w.wp26;
1541                 case 27:return w.wp27;
1542                 case 28:return w.wp28;
1543                 case 29:return w.wp29;
1544                 case 30:return w.wp30;
1545                 case 31:return w.wp31;
1546                 default:return NULL;
1547         }
1548 }
1549
1550 // Save all hardwired waypoint links to a file
1551 void waypoint_save_hardwiredlinks()
1552 {
1553         string gt_ext = GET_GAMETYPE_EXTENSION();
1554
1555         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1556         int file = fopen(filename, FILE_WRITE);
1557         if (file < 0)
1558         {
1559                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1560                 return;
1561         }
1562
1563         // write hardwired links to file
1564         int count = 0;
1565         fputs(file, "// HARDWIRED LINKS\n");
1566         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1567         {
1568                 for (int j = 0; j < 32; ++j)
1569                 {
1570                         entity link = waypoint_get_link(it, j);
1571                         if (waypoint_is_hardwiredlink(it, link))
1572                         {
1573                                 // NOTE: vtos rounds vector components to 1 decimal place
1574                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1575                                 fputs(file, s);
1576                                 ++count;
1577                         }
1578                 }
1579         });
1580
1581         // write special links to file
1582         int count2 = 0;
1583         fputs(file, "\n// SPECIAL LINKS\n");
1584         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP),
1585         {
1586                 for (int j = 0; j < 32; ++j)
1587                 {
1588                         entity link = waypoint_get_link(it, j);
1589                         if (link)
1590                         {
1591                                 // NOTE: vtos rounds vector components to 1 decimal place
1592                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1593                                 fputs(file, s);
1594                                 ++count2;
1595                         }
1596                 }
1597         });
1598
1599         fclose(file);
1600
1601         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1602 }
1603
1604 // Save all waypoint links to a file
1605 void waypoint_save_links()
1606 {
1607         string gt_ext = GET_GAMETYPE_EXTENSION();
1608
1609         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1610         int file = fopen(filename, FILE_WRITE);
1611         if (file < 0)
1612         {
1613                 LOG_INFOF("waypoint link save to %s failed", filename);
1614                 return;
1615         }
1616
1617         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1618         if (waypoint_time != "")
1619                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1620
1621         int c = 0;
1622         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)),
1623         {
1624                 for(int j = 0; j < 32; ++j)
1625                 {
1626                         entity link = waypoint_get_link(it, j);
1627                         if (link && !waypoint_is_hardwiredlink(it, link))
1628                         {
1629                                 // NOTE: vtos rounds vector components to 1 decimal place
1630                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1631                                 fputs(file, s);
1632                                 ++c;
1633                         }
1634                 }
1635         });
1636         fclose(file);
1637
1638         botframe_cachedwaypointlinks = true;
1639
1640         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1641 }
1642
1643 // save waypoints to gamedir/data/maps/mapname.waypoints
1644 void waypoint_saveall()
1645 {
1646         if (WAYPOINT_VERSION < waypoint_version_loaded)
1647         {
1648                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1649                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1650                 return;
1651         }
1652         string gt_ext = GET_GAMETYPE_EXTENSION();
1653
1654         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1655         int file = fopen(filename, FILE_WRITE);
1656         if (file < 0)
1657         {
1658                 waypoint_save_links(); // save anyway?
1659                 botframe_loadedforcedlinks = false;
1660
1661                 LOG_INFOF("waypoint links: save to %s failed", filename);
1662                 return;
1663         }
1664
1665         float sym = autocvar_g_waypointeditor_symmetrical;
1666         string sym_str = ftos(sym);
1667         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1668         {
1669                 if (sym == 1)
1670                 {
1671                         sym_str = cons(sym_str, "-");
1672                         sym_str = cons(sym_str, "-");
1673                 }
1674                 else
1675                 {
1676                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1677                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1678                 }
1679                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1680                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1681         }
1682         else if (autocvar_g_waypointeditor_symmetrical == -2)
1683         {
1684                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1685                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1686         }
1687
1688         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1689         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1690         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1691         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1692
1693         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1694         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1695         //fputs(file, strcat("//", "\n"));
1696         //fputs(file, strcat("//", "\n"));
1697         //fputs(file, strcat("//", "\n"));
1698
1699         int c = 0;
1700         IL_EACH(g_waypoints, true,
1701         {
1702                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1703                         continue;
1704
1705                 string s;
1706                 // NOTE: vtos rounds vector components to 1 decimal place
1707                 s = strcat(vtos(it.origin + it.mins), "\n");
1708                 s = strcat(s, vtos(it.origin + it.maxs));
1709                 s = strcat(s, "\n");
1710                 s = strcat(s, ftos(it.wpflags));
1711                 s = strcat(s, "\n");
1712                 fputs(file, s);
1713                 c++;
1714         });
1715         fclose(file);
1716         waypoint_save_links();
1717         waypoint_save_hardwiredlinks();
1718
1719         botframe_loadedforcedlinks = false;
1720
1721         waypoint_version_loaded = WAYPOINT_VERSION;
1722         LOG_INFOF("saved %d waypoints to %s", c, filename);
1723 }
1724
1725 // load waypoints from file
1726 float waypoint_loadall()
1727 {
1728         string s;
1729         float file, cwp, cwb, fl;
1730         vector m1, m2;
1731         cwp = 0;
1732         cwb = 0;
1733
1734         string gt_ext = GET_GAMETYPE_EXTENSION();
1735
1736         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1737         file = fopen(filename, FILE_READ);
1738
1739         if (gt_ext != "" && file < 0)
1740         {
1741                 // if race waypoint file doesn't exist load the default one
1742                 filename = sprintf("maps/%s.waypoints", mapname);
1743                 file = fopen(filename, FILE_READ);
1744         }
1745
1746         if (file < 0)
1747         {
1748                 LOG_TRACE("waypoint load from ", filename, " failed");
1749                 return 0;
1750         }
1751
1752         bool parse_comments = true;
1753         float ver = 0;
1754         float sym = 0;
1755         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1756
1757         while ((s = fgets(file)))
1758         {
1759                 if(parse_comments)
1760                 {
1761                         if(substring(s, 0, 2) == "//")
1762                         {
1763                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1764                                         ver = stof(substring(s, 19, -1));
1765                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1766                                 {
1767                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1768                                         if (tokens) { sym = stof(argv(0)); }
1769                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1770                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1771                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1772                                 }
1773                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1774                                         strcpy(waypoint_time, substring(s, 16, -1));
1775                                 continue;
1776                         }
1777                         else
1778                         {
1779                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1780                                 {
1781                                         LOG_TRACE("waypoints for this map are outdated");
1782                                         LOG_TRACE("please update them in the editor");
1783                                 }
1784                                 parse_comments = false;
1785                         }
1786                 }
1787                 m1 = stov(s);
1788                 s = fgets(file);
1789                 if (!s)
1790                         break;
1791                 m2 = stov(s);
1792                 s = fgets(file);
1793                 if (!s)
1794                         break;
1795                 fl = stof(s);
1796                 waypoint_spawn(m1, m2, fl);
1797                 if (m1 == m2)
1798                         cwp = cwp + 1;
1799                 else
1800                         cwb = cwb + 1;
1801         }
1802         fclose(file);
1803         waypoint_version_loaded = ver;
1804         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1805
1806         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1807         {
1808                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1809                 if (sym == 1 && sym_param3 < 2)
1810                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1811                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1812                 {
1813                         string params;
1814                         if (sym == 1)
1815                                 params = cons("-", "-");
1816                         else
1817                         {
1818                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1819                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1820                         }
1821                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1822                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1823                 }
1824                 else if (sym == -2)
1825                 {
1826                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1827                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1828                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1829                 }
1830                 else
1831                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1832                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1833         }
1834
1835         if (WAYPOINT_VERSION < waypoint_version_loaded)
1836                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1837                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1838
1839         return cwp + cwb;
1840 }
1841
1842 #define waypoint_fixorigin(position, tracetest_ent) \
1843         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1844
1845 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1846 {
1847         vector endpos = position + down_dir * 3000;
1848         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1849         if(trace_startsolid)
1850                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1851         if(trace_startsolid)
1852                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1853         if(trace_fraction < 1)
1854                 position = trace_endpos;
1855         return position;
1856 }
1857
1858 void waypoint_spawnforitem_force(entity e, vector org)
1859 {
1860         // Fix the waypoint altitude if necessary
1861         org = waypoint_fixorigin(org, NULL);
1862
1863         // don't spawn an item spawnfunc_waypoint if it already exists
1864         IL_EACH(g_waypoints, true,
1865         {
1866                 if(it.wpisbox)
1867                 {
1868                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1869                         {
1870                                 e.nearestwaypoint = it;
1871                                 return;
1872                         }
1873                 }
1874                 else
1875                 {
1876                         if(vdist(it.origin - org, <, 16))
1877                         {
1878                                 e.nearestwaypoint = it;
1879                                 return;
1880                         }
1881                 }
1882         });
1883
1884         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1885 }
1886
1887 void waypoint_spawnforitem(entity e)
1888 {
1889         if(!bot_waypoints_for_items)
1890                 return;
1891
1892         waypoint_spawnforitem_force(e, e.origin);
1893 }
1894
1895 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1896 {
1897         entity w;
1898         entity dw;
1899         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1900         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1901         // one way link to the destination
1902         w.wp00_original = dw;
1903         w.wp00 = dw;
1904         w.wp00mincost = timetaken; // this is just for jump pads
1905         // the teleporter's nearest spawnfunc_waypoint is this one
1906         // (teleporters are not goals, so this is probably useless)
1907         e.nearestwaypoint = w;
1908         e.nearestwaypointtimeout = -1;
1909 }
1910
1911 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1912 {
1913         float src_angle = e.warpzone_angles.x;
1914         while (src_angle < -180) src_angle += 360;
1915         while (src_angle > 180) src_angle -= 360;
1916
1917         float dest_angle = e.enemy.warpzone_angles.x;
1918         while (dest_angle < -180) dest_angle += 360;
1919         while (dest_angle > 180) dest_angle -= 360;
1920
1921         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1922         if (src_angle == -90 || dest_angle == -90)
1923                 return;
1924
1925         makevectors(e.warpzone_angles);
1926         vector src = (e.absmin + e.absmax) * 0.5;
1927         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1928         vector down_dir_src = -v_up;
1929
1930         makevectors(e.enemy.warpzone_angles);
1931         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1932         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1933         vector down_dir_dest = -v_up;
1934
1935         int extra_flag = 0;
1936         // don't snap to the ground waypoints for source warpzones pointing downwards
1937         if (src_angle != 90)
1938         {
1939                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1940                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1941                 // oblique warpzones need a jump otherwise bots gets stuck
1942                 if (src_angle != 0)
1943                         extra_flag = WAYPOINTFLAG_JUMP;
1944         }
1945
1946         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1947 }
1948
1949 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1950 {
1951         destination = waypoint_fixorigin(destination, tracetest_ent);
1952         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1953 }
1954
1955 entity waypoint_spawnpersonal(entity this, vector position)
1956 {
1957         entity w;
1958
1959         // drop the waypoint to a proper location:
1960         //   first move it up by a player height
1961         //   then move it down to hit the floor with player bbox size
1962         position = waypoint_fixorigin(position, this);
1963
1964         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1965         w.nearestwaypoint = NULL;
1966         w.nearestwaypointtimeout = 0;
1967         w.owner = this;
1968
1969         waypoint_schedulerelink(w);
1970
1971         return w;
1972 }
1973
1974 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1975 {
1976         if (!(wp1 && wp2))
1977                 return;
1978
1979         if (waypoint_is_hardwiredlink(wp1, wp2) || wp1.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP))
1980                 te_beam(NULL, wp1.origin, wp2.origin);
1981         else if (display_type == 1)
1982                 te_lightning2(NULL, wp1.origin, wp2.origin);
1983 }
1984
1985 void waypoint_showlinks_to(entity wp, int display_type)
1986 {
1987         IL_EACH(g_waypoints, it != wp,
1988         {
1989                 if (waypoint_islinked(it, wp))
1990                         waypoint_showlink(it, wp, display_type);
1991         });
1992 }
1993
1994 void waypoint_showlinks_from(entity wp, int display_type)
1995 {
1996         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
1997         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
1998         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
1999         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
2000         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
2001         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
2002         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
2003         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
2004         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
2005         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
2006         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
2007         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
2008         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
2009         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
2010         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
2011         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
2012 }
2013
2014 void crosshair_trace_waypoints(entity pl)
2015 {
2016         IL_EACH(g_waypoints, true, {
2017                 it.solid = SOLID_BSP;
2018                 if (!it.wpisbox)
2019                         setsize(it, '-16 -16 -16', '16 16 16');
2020         });
2021
2022         crosshair_trace(pl);
2023
2024         IL_EACH(g_waypoints, true, {
2025                 it.solid = SOLID_TRIGGER;
2026                 if (!it.wpisbox)
2027                         setsize(it, '0 0 0', '0 0 0');
2028         });
2029         if (trace_ent.classname != "waypoint")
2030                 trace_ent = NULL;
2031 }
2032
2033 void botframe_showwaypointlinks()
2034 {
2035         if (time < botframe_waypointeditorlightningtime)
2036                 return;
2037         botframe_waypointeditorlightningtime = time + 0.5;
2038         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
2039         {
2040                 int display_type = 0;
2041                 if (wasfreed(it.wp_aimed))
2042                         it.wp_aimed = NULL;
2043                 if (wasfreed(it.wp_locked))
2044                         it.wp_locked = NULL;
2045                 if (PHYS_INPUT_BUTTON_USE(it))
2046                         it.wp_locked = it.wp_aimed;
2047                 entity head = it.wp_locked;
2048                 if (!head)
2049                         head = navigation_findnearestwaypoint(it, false);
2050                 it.nearestwaypoint = head; // mainly useful for debug
2051                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
2052                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
2053                         display_type = 1; // default
2054                 else if(waypoint_has_hardwiredlinks(head))
2055                         display_type = 2; // only hardwired
2056
2057                 if (display_type)
2058                 {
2059                         //navigation_testtracewalk = true;
2060                         //print("currently selected WP is ", etos(head), "\n");
2061                         //navigation_testtracewalk = false;
2062                         if (head)
2063                         {
2064                                 te_lightning2(NULL, head.origin, it.origin);
2065                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
2066                                         waypoint_showlinks_to(head, display_type);
2067                                 else
2068                                         waypoint_showlinks_from(head, display_type);
2069                         }
2070                 }
2071                 string str;
2072                 entity wp = NULL;
2073                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2074                 {
2075                         crosshair_trace_waypoints(it);
2076                         if (trace_ent)
2077                         {
2078                                 wp = trace_ent;
2079                                 if (wp != it.wp_aimed)
2080                                 {
2081                                         string wp_type_str = waypoint_get_type_name(wp);
2082                                         str = sprintf("\necho Entity %d: %s^7, flags: %d, origin: %s\n", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2083                                         if (wp.wpisbox)
2084                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2085                                         stuffcmd(it, str);
2086                                         str = sprintf("Entity %d: %s^7\nflags: %d\norigin: %s", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2087                                         if (wp.wpisbox)
2088                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2089                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2090                                 }
2091                         }
2092                 }
2093                 if (it.wp_aimed != wp)
2094                         it.wp_aimed = wp;
2095         });
2096 }
2097
2098 float botframe_autowaypoints_fixdown(vector v)
2099 {
2100         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2101         if(trace_fraction >= 1)
2102                 return 0;
2103         return 1;
2104 }
2105
2106 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2107 {
2108         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2109         {
2110                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2111                 return 0;
2112         });
2113
2114         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2115         return 1;
2116 }
2117
2118 // return value:
2119 //    1 = WP created
2120 //    0 = no action needed
2121 //   -1 = temp fail, try from world too
2122 //   -2 = permanent fail, do not retry
2123 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2124 {
2125         // make it possible to go from p to wp, if we can
2126         // if wp is NULL, nearest is chosen
2127
2128         entity w;
2129         vector porg;
2130         float t, tmin, tmax;
2131         vector o;
2132         vector save;
2133
2134         if(!botframe_autowaypoints_fixdown(p.origin))
2135                 return -2;
2136         porg = trace_endpos;
2137
2138         if(wp)
2139         {
2140                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2141
2142                 // if wp -> porg, then OK
2143                 float maxdist;
2144                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2145                 {
2146                         // we may find a better one
2147                         maxdist = vlen(wp.origin - porg);
2148                 }
2149                 else
2150                 {
2151                         // accept any "good"
2152                         maxdist = 2100;
2153                 }
2154
2155                 float bestdist = maxdist;
2156                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
2157                 {
2158                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2159                         if(d < bestdist)
2160                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2161                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2162                         {
2163                                 bestdist = d;
2164                                 p.(fld) = it;
2165                         }
2166                 });
2167                 if(bestdist < maxdist)
2168                 {
2169                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2170                         return 0;
2171                 }
2172
2173                 if(bestdist < 2100)
2174                 {
2175                         // we know maxdist < 2100
2176                         // so wp -> porg is still valid
2177                         // all is good
2178                         p.(fld) = wp;
2179                         return 0;
2180                 }
2181
2182                 // otherwise, no existing WP can fix our issues
2183         }
2184         else
2185         {
2186                 save = p.origin;
2187                 setorigin(p, porg);
2188                 w = navigation_findnearestwaypoint(p, walkfromwp);
2189                 setorigin(p, save);
2190                 if(w)
2191                 {
2192                         p.(fld) = w;
2193                         return 0;
2194                 }
2195         }
2196
2197         tmin = 0;
2198         tmax = 1;
2199         for (;;)
2200         {
2201                 if(tmax - tmin < 0.001)
2202                 {
2203                         // did not get a good candidate
2204                         return -1;
2205                 }
2206
2207                 t = (tmin + tmax) * 0.5;
2208                 o = antilag_takebackorigin(p, CS(p), time - t);
2209                 if(!botframe_autowaypoints_fixdown(o))
2210                         return -2;
2211                 o = trace_endpos;
2212
2213                 if(wp)
2214                 {
2215                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2216                         {
2217                                 // we cannot walk from wp.origin to o
2218                                 // get closer to tmax
2219                                 tmin = t;
2220                                 continue;
2221                         }
2222                 }
2223                 else
2224                 {
2225                         save = p.origin;
2226                         setorigin(p, o);
2227                         w = navigation_findnearestwaypoint(p, walkfromwp);
2228                         setorigin(p, save);
2229                         if(!w)
2230                         {
2231                                 // we cannot walk from any WP to o
2232                                 // get closer to tmax
2233                                 tmin = t;
2234                                 continue;
2235                         }
2236                 }
2237
2238                 // if we get here, o is valid regarding waypoints
2239                 // check if o is connected right to the player
2240                 // we break if it succeeds, as that means o is a good waypoint location
2241                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2242                         break;
2243
2244                 // o is no good, we need to get closer to the player
2245                 tmax = t;
2246         }
2247
2248         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2249         botframe_autowaypoints_createwp(o, p, fld, 0);
2250         return 1;
2251 }
2252
2253 // automatically create missing waypoints
2254 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
2255 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2256 {
2257         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2258         if(r != -1)
2259                 return;
2260         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2261         if(r != -1)
2262                 return;
2263
2264         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2265         if(!botframe_autowaypoints_fixdown(p.origin))
2266                 return; // shouldn't happen, caught above
2267         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2268 }
2269
2270 void botframe_deleteuselesswaypoints()
2271 {
2272         IL_EACH(g_items, it.bot_pickup,
2273         {
2274                 // NOTE: this protects waypoints if they're the ONLY nearest
2275                 // waypoint. That's the intention.
2276                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2277                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2278         });
2279         IL_EACH(g_waypoints, true,
2280         {
2281                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2282                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2283                 // WP is useful if:
2284                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2285                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2286                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2287                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2288                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2289                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2290                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2291                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2292                 // b) WP is closest WP for an item/spawnpoint/other entity
2293                 //    This has been done above by protecting these WPs.
2294         });
2295         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2296         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2297         {
2298                 for (int m = 0; m < 32; ++m)
2299                 {
2300                         entity w = waypoint_get_link(it, m);
2301                         if (!w)
2302                                 break;
2303                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2304                                 continue;
2305                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2306                                 continue;
2307                         for (int j = 0; j < 32; ++j)
2308                         {
2309                                 entity w2 = waypoint_get_link(w, j);
2310                                 if (!w2)
2311                                         break;
2312                                 if (it == w2)
2313                                         continue;
2314                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2315                                         continue;
2316                                 // If we got here, it != w2 exist with it -> w
2317                                 // and w -> w2. That means the waypoint is not
2318                                 // a dead end.
2319                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2320                                 for (int k = 0; k < 32; ++k)
2321                                 {
2322                                         if (waypoint_get_link(it, k) == w2)
2323                                                 continue;
2324                                         // IF WE GET HERE, w is proven useful
2325                                         // to get from it to w2!
2326                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2327                                         goto next;
2328                                 }
2329                         }
2330 LABEL(next)
2331                 }
2332         });
2333         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2334         //     they are needed to complete routes while autowaypointing.
2335
2336         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2337         {
2338                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2339                 te_explosion(it.origin);
2340                 waypoint_remove(it);
2341                 break;
2342         });
2343
2344         IL_EACH(g_waypoints, true,
2345         {
2346                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2347         });
2348 }
2349
2350 void botframe_autowaypoints()
2351 {
2352         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2353                 // going back is broken, so only fix waypoints to walk TO the player
2354                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2355                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2356                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2357         });
2358
2359         if (autocvar_g_waypointeditor_auto >= 2) {
2360                 botframe_deleteuselesswaypoints();
2361         }
2362 }
2363