qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float gamestart_sv_cheats;
  18
  19 #define CHIMPULSE_SPEEDRUN_INIT 30
  20 #define CHIMPULSE_GIVE_ALL 99
  21 #define CHIMPULSE_CLONE_MOVING 140
  22 #define CHIMPULSE_SPEEDRUN 141
  23 #define CHIMPULSE_CLONE_STANDING 142
  24 #define CHIMPULSE_TELEPORT 143
  25 #define CHIMPULSE_R00T 148
  26
  27 #define CHRAME_DRAG 8
  28
  29 void CheatInit()
  30 {
  31         gamestart_sv_cheats = autocvar_sv_cheats;
  32 }
  33
  34 void CheatShutdown()
  35 {
  36 }
  37
  38 void CheatInitClient()
  39 {
  40 }
  41
  42 void CheatShutdownClient()
  43 {
  44 }
  45
  46 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  47 {
  48         // dead people cannot cheat
  49         if(self.deadflag != DEAD_NO)
  50                 return 0;
  51         if(self.classname != "player")
  52                 return 0;
  53
  54         // sv_clones
  55         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  56                 if(self.lip < sv_clones)
  57                         return 1;
  58
  59         // haha
  60         if(self.maycheat)
  61                 return 1;
  62
  63         // sv_cheats
  64         if(gamestart_sv_cheats && autocvar_sv_cheats)
  65                 return 1;
  66
  67         // if we get here, player is not allowed to cheat. Log it.
  68         if(i)
  69                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  70         else if(argc)
  71                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  72         else if(fr)
  73                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  74         else
  75                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  76
  77         return 0;
  78 }
  79
  80 #define BEGIN_CHEAT_FUNCTION() \
  81         float cheating, attempting; \
  82         cheating = 0; attempting = 0
  83 #define DID_CHEAT() \
  84         ++cheating
  85 #define ADD_CHEATS(e,n) \
  86         cheatcount_total += n; \
  87         e.cheatcount += n
  88 #define END_CHEAT_FUNCTION() \
  89         ADD_CHEATS(self,cheating); \
  90         return attempting
  91 #define IS_CHEAT(i,argc,fr) \
  92         if((++attempting, !CheatsAllowed(i,argc,fr))) \
  93                 break
  94
  95 float num_autoscreenshot;
  96 void info_autoscreenshot_findtarget()
  97 {
  98         entity e;
  99         e = find(world, targetname, self.target);
 100         if(!e)
 101         {
 102                 objerror("Missing target. FAIL!");
 103                 return;
 104         }
 105         vector a = vectoangles(e.origin - self.origin);
 106         self.angles_x = a_x;
 107         self.angles_y = a_y;
 108         // we leave Rick Roll alone
 109 }
 110 void spawnfunc_info_autoscreenshot()
 111 {
 112         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 113         {
 114                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 115                 return;
 116         }
 117         if(self.target != "")
 118                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 119         // this one just has to exist
 120 }
 121
 122 float CheatImpulse(float i)
 123 {
 124         BEGIN_CHEAT_FUNCTION();
 125         switch(i)
 126         {
 127                 entity e, e2;
 128                 vector org;
 129
 130                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 131                         // shared with regular waypoint init, so this is not a cheat by itself
 132                         if(!self.personal)
 133                         {
 134                                 self.personal = spawn();
 135                                 self.personal.classname = "personal_wp";
 136                         }
 137                         self.personal.origin = self.origin;
 138                         self.personal.v_angle = self.v_angle;
 139                         self.personal.velocity = self.velocity;
 140                         self.personal.ammo_rockets = self.ammo_rockets;
 141                         self.personal.ammo_nails = self.ammo_nails;
 142                         self.personal.ammo_cells = self.ammo_cells;
 143                         self.personal.ammo_shells = self.ammo_shells;
 144                         self.personal.ammo_fuel = self.ammo_fuel;
 145                         self.personal.health = self.health;
 146                         self.personal.armorvalue = self.armorvalue;
 147                         self.personal.weapons = self.weapons;
 148                         self.personal.items = self.items;
 149                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 150                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 151                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 152                         self.personal.pauseregen_finished = self.pauseregen_finished;
 153                         self.personal.strength_finished = self.strength_finished;
 154                         self.personal.invincible_finished = self.invincible_finished;
 155                         self.personal.teleport_time = time;
 156                         break; // this part itself doesn't cheat, so let's not count this
 157                 case CHIMPULSE_CLONE_MOVING:
 158                         IS_CHEAT(i, 0, 0);
 159                         makevectors (self.v_angle);
 160                         self.velocity = self.velocity + v_forward * 300;
 161                         CopyBody(1);
 162                         self.lip += 1;
 163                         self.velocity = self.velocity - v_forward * 300;
 164                         DID_CHEAT();
 165                         break;
 166                 case CHIMPULSE_CLONE_STANDING:
 167                         IS_CHEAT(i, 0, 0);
 168                         CopyBody(0);
 169                         self.lip += 1;
 170                         DID_CHEAT();
 171                         break;
 172                 case CHIMPULSE_GIVE_ALL:
 173                         IS_CHEAT(i, 0, 0);
 174                         CheatCommand(tokenize_console("give all"));
 175                         break; // already counted as cheat
 176                 case CHIMPULSE_SPEEDRUN:
 177                         IS_CHEAT(i, 0, 0);
 178                         if(self.personal)
 179                         {
 180                                 self.speedrunning = TRUE;
 181                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 182                                 if(trace_startsolid)
 183                                 {
 184                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 185                                 }
 186                                 else
 187                                 {
 188                                         // Abort speedrun, teleport back
 189                                         setorigin(self, self.personal.origin);
 190                                         self.oldvelocity = self.velocity = self.personal.velocity;
 191                                         self.angles = self.personal.v_angle;
 192                                         self.fixangle = TRUE;
 193                                         if(self.flagcarried)
 194                                         {
 195                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 196                                                 ReturnFlag(self.flagcarried);
 197                                         }
 198                                 }
 199                                 if(g_ctf)
 200                                 {
 201                                         self.ammo_rockets = 999;
 202                                         self.ammo_nails = 999;
 203                                         self.ammo_cells = 999;
 204                                         self.ammo_shells = 999;
 205                                         self.ammo_fuel = 999;
 206                                         self.health = start_health;
 207                                         self.armorvalue = start_armorvalue;
 208                                         self.weapons |= weaponsInMap;
 209                                         self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 210                                         self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 211                                         self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 212                                         self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 213                                         self.strength_finished = 0;
 214                                         self.invincible_finished = 0;
 215                                 }
 216                                 else
 217                                 {
 218                                         self.ammo_rockets = self.personal.ammo_rockets;
 219                                         self.ammo_nails = self.personal.ammo_nails;
 220                                         self.ammo_cells = self.personal.ammo_cells;
 221                                         self.ammo_shells = self.personal.ammo_shells;
 222                                         self.ammo_fuel = self.personal.ammo_fuel;
 223                                         self.health = self.personal.health;
 224                                         self.armorvalue = self.personal.armorvalue;
 225                                         self.weapons = self.personal.weapons;
 226                                         self.items = self.personal.items;
 227                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 228                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 229                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 230                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 231                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 232                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 233                                 }
 234                                 DID_CHEAT();
 235                                 break;
 236                         }
 237                         if(self.deadflag != DEAD_NO)
 238                                 sprint(self, "UR DEAD AHAHAH))\n");
 239                         else
 240                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 241                         break;
 242                 case CHIMPULSE_TELEPORT:
 243                         IS_CHEAT(i, 0, 0);
 244                         if(self.movetype == MOVETYPE_NOCLIP)
 245                         {
 246                                 e = find(world, classname, "info_autoscreenshot");
 247                                 if(e)
 248                                 {
 249                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 250                                         setorigin(self, e.origin);
 251                                         self.angles = e.angles;
 252                                         remove(e);
 253                                         // should we? self.angles_x = -self.angles_x;
 254                                         self.fixangle = TRUE;
 255                                         self.velocity = '0 0 0';
 256                                         DID_CHEAT();
 257                                         break;
 258                                 }
 259                         }
 260                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 261                         {
 262                                 sprint(self, "Emergency teleport used random location\n");
 263                                 self.angles_x = -self.angles_x;
 264                                 self.fixangle = TRUE;
 265                                 self.velocity = '0 0 0';
 266                                 DID_CHEAT();
 267                                 break;
 268                         }
 269                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 270                         break;
 271                 case CHIMPULSE_R00T:
 272                         IS_CHEAT(i, 0, 0);
 273                         FOR_EACH_PLAYER(e)
 274                         {
 275                                 get_model_parameters(e.playermodel, e.skin);
 276                                 if(get_model_parameters_sex == "Female")
 277                                 {
 278                                         makevectors(e.angles);
 279                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 280                                 }
 281                                 else
 282                                 {
 283                                         org_x = random();
 284                                         org_y = random();
 285                                         org_z = 0;
 286                                         org = normalize(org);
 287                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 288                                 }
 289
 290                                 org = findbetterlocation(trace_endpos, 12);
 291
 292                                 e2 = spawn();
 293                                 setorigin(e2, org);
 294                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 295                                 sound(e2, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 296                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 297                                 remove(e2);
 298                         }
 299                         print("404 Sportsmanship not found.\n");
 300                         DID_CHEAT();
 301                         break;
 302         }
 303
 304         END_CHEAT_FUNCTION();
 305 }
 306
 307 void DragBox_Think();
 308 float drag_lastcnt;
 309 float CheatCommand(float argc)
 310 {
 311         BEGIN_CHEAT_FUNCTION();
 312         string cmd;
 313         cmd = argv(0);
 314         switch(cmd)
 315         {
 316                 entity e;
 317                 float effectnum, f;
 318                 vector start, end;
 319                 entity oldself;
 320
 321                 case "pointparticles":
 322                         IS_CHEAT(0, argc, 0);
 323                         if(argc == 5)
 324                         {
 325                                 // arguments:
 326                                 //   effectname
 327                                 //   origin (0..1, on crosshair line)
 328                                 //   velocity
 329                                 //   howmany
 330                                 effectnum = particleeffectnum(argv(1));
 331                                 f = stof(argv(2));
 332                                 crosshair_trace(self);
 333                                 start = (1-f) * self.origin + f * trace_endpos;
 334                                 end = stov(argv(3));
 335                                 f = stof(argv(4));
 336                                 pointparticles(effectnum, start, end, f);
 337                                 DID_CHEAT();
 338                                 break;
 339                         }
 340                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 341                         break;
 342                 case "trailparticles":
 343                         IS_CHEAT(0, argc, 0);
 344                         if(argc == 2)
 345                         {
 346                                 // arguments:
 347                                 //   effectname
 348                                 effectnum = particleeffectnum(argv(1));
 349                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 350                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 351                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 352                                 DID_CHEAT();
 353                                 break;
 354                         }
 355                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 356                         break;
 357                 case "make":
 358                         IS_CHEAT(0, argc, 0);
 359                         if(argc == 3)
 360                         {
 361                                 // arguments:
 362                                 //   modelname mode
 363                                 f = stof(argv(2));
 364                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 365                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 366                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 367                                 {
 368                                         sprint(self, "cannot make stuff there (bad surface)\n");
 369                                 }
 370                                 else
 371                                 {
 372                                         e = spawn();
 373                                         e.model = strzone(argv(1));
 374                                         e.mdl = "rocket_explode";
 375                                         e.health = 1000;
 376                                         setorigin(e, trace_endpos);
 377                                         e.effects = EF_NOMODELFLAGS;
 378                                         if(f == 1)
 379                                         {
 380                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 381                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 382                                         }
 383                                         oldself = self;
 384                                         self = e;
 385                                         spawnfunc_func_breakable();
 386                                         self = oldself;
 387                                         // now, is it valid?
 388                                         if(f == 0)
 389                                         {
 390                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 391                                                 if(trace_startsolid)
 392                                                 {
 393                                                         remove(e);
 394                                                         sprint(self, "cannot make stuff there (no space)\n");
 395                                                 }
 396                                                 else
 397                                                         DID_CHEAT();
 398                                         }
 399                                         else
 400                                                 DID_CHEAT();
 401                                 }
 402                         }
 403                         else
 404                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 405                         break;
 406                 case "penalty":
 407                         IS_CHEAT(0, argc, 0);
 408                         if(argc == 3)
 409                         {
 410                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 411                                 DID_CHEAT();
 412                                 break;
 413                         }
 414                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 415                         break;
 416                 case "dragbox_spawn":
 417                         IS_CHEAT(0, argc, 0);
 418                         e = spawn();
 419                         e.classname = "dragbox_box";
 420                         e.think = DragBox_Think;
 421                         e.nextthink = time;
 422                         e.solid = -1; // black
 423                         setmodel(e, "null"); // network it
 424                         if(argc == 4)
 425                                 e.cnt = stof(argv(1));
 426                         else
 427                                 e.cnt = max(0, drag_lastcnt);
 428
 429                         e.aiment = spawn();
 430                         e.aiment.classname = "dragbox_corner_1";
 431                         e.aiment.owner = e;
 432                         setmodel(e.aiment, "models/marker.md3");
 433                         e.aiment.skin = 0;
 434                         setsize(e.aiment, '0 0 0', '0 0 0');
 435                         if(argc == 4)
 436                                 setorigin(e.aiment, stov(argv(2)));
 437                         else
 438                         {
 439                                 crosshair_trace(self);
 440                                 setorigin(e.aiment, trace_endpos);
 441                         }
 442
 443                         e.enemy = spawn();
 444                         e.enemy.classname = "dragbox_corner_2";
 445                         e.enemy.owner = e;
 446                         setmodel(e.enemy, "models/marker.md3");
 447                         e.enemy.skin = 1;
 448                         setsize(e.enemy, '0 0 0', '0 0 0');
 449                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 450                         end_x = (end_x > 0) * 2 - 1;
 451                         end_y = (end_y > 0) * 2 - 1;
 452                         end_z = (end_z > 0) * 2 - 1;
 453                         if(argc == 4)
 454                                 setorigin(e.enemy, stov(argv(3)));
 455                         else
 456                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 457
 458                         e.killindicator = spawn();
 459                         e.killindicator.classname = "drag_digit";
 460                         e.killindicator.owner = e;
 461                         setattachment(e.killindicator, e, "");
 462                         setorigin(e.killindicator, '0 0 -8');
 463                         e.killindicator.killindicator = spawn();
 464                         e.killindicator.killindicator.classname = "drag_digit";
 465                         e.killindicator.killindicator.owner = e;
 466                         setattachment(e.killindicator.killindicator, e, "");
 467                         setorigin(e.killindicator.killindicator, '0 0 8');
 468                         DID_CHEAT();
 469                         break;
 470                 case "dragpoint_spawn":
 471                         IS_CHEAT(0, argc, 0);
 472                         e = spawn();
 473                         e.classname = "dragpoint";
 474                         e.think = DragBox_Think;
 475                         e.nextthink = time;
 476                         e.solid = 0; // nothing special
 477                         setmodel(e, "models/marker.md3");
 478                         setsize(e, PL_MIN, PL_MAX);
 479                         e.skin = 2;
 480                         if(argc == 3)
 481                                 e.cnt = stof(argv(1));
 482                         else
 483                                 e.cnt = drag_lastcnt;
 484                         if(argc == 3)
 485                                 setorigin(e, stov(argv(2)));
 486                         else
 487                         {
 488                                 crosshair_trace(self);
 489                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 490                                 move_out_of_solid(e);
 491                         }
 492
 493                         e.killindicator = spawn();
 494                         e.killindicator.classname = "drag_digit";
 495                         e.killindicator.owner = e;
 496                         setattachment(e.killindicator, e, "");
 497                         setorigin(e.killindicator, '0 0 40');
 498                         e.killindicator.killindicator = spawn();
 499                         e.killindicator.killindicator.classname = "drag_digit";
 500                         e.killindicator.killindicator.owner = e;
 501                         setattachment(e.killindicator.killindicator, e, "");
 502                         setorigin(e.killindicator.killindicator, '0 0 56');
 503                         DID_CHEAT();
 504                         break;
 505                 case "drag_remove":
 506                         IS_CHEAT(0, argc, 0);
 507                         RandomSelection_Init();
 508                         crosshair_trace(self);
 509                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 510                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 511                         for(e = world; (e = find(e, classname, "dragpoint")); )
 512                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 513                         if(RandomSelection_chosen_ent)
 514                         {
 515                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 516                                 remove(RandomSelection_chosen_ent.killindicator);
 517                                 if(RandomSelection_chosen_ent.aiment)
 518                                         remove(RandomSelection_chosen_ent.aiment);
 519                                 if(RandomSelection_chosen_ent.enemy)
 520                                         remove(RandomSelection_chosen_ent.enemy);
 521                                 remove(RandomSelection_chosen_ent);
 522                         }
 523                         DID_CHEAT();
 524                         break;
 525                 case "drag_setcnt":
 526                         IS_CHEAT(0, argc, 0);
 527                         if(argc == 2)
 528                         {
 529                                 RandomSelection_Init();
 530                                 crosshair_trace(self);
 531                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 532                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 533                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 534                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 535                                 if(RandomSelection_chosen_ent)
 536                                 {
 537                                         if(substring(argv(1), 0, 1) == "*")
 538                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 539                                         else
 540                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 541                                 }
 542                                 DID_CHEAT();
 543                                 break;
 544                         }
 545                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 546                         break;
 547                 case "drag_save":
 548                         IS_CHEAT(0, argc, 0);
 549                         if(argc == 2)
 550                         {
 551                                 f = fopen(argv(1), FILE_WRITE);
 552                                 fputs(f, "cmd drag_clear\n");
 553                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 554                                 {
 555                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 556                                 }
 557                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 558                                 {
 559                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 560                                 }
 561                                 fclose(f);
 562                                 DID_CHEAT();
 563                                 break;
 564                         }
 565                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 566                         break;
 567                 case "drag_saveraceent":
 568                         IS_CHEAT(0, argc, 0);
 569                         if(argc == 2)
 570                         {
 571                                 f = fopen(argv(1), FILE_WRITE);
 572                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 573                                 {
 574                                         fputs(f, "{\n");
 575                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 576                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 577                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 578                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 579                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 580                                         fputs(f, "}\n");
 581                                 }
 582                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 583                                 {
 584                                         start = '0 0 0';
 585                                         effectnum = 0;
 586                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 587                                         {
 588                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 589                                                 {
 590                                                         start = start + oldself.origin;
 591                                                         ++effectnum;
 592                                                 }
 593                                         }
 594                                         start *= 1 / effectnum;
 595                                         fputs(f, "{\n");
 596                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 597                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 598                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 599                                         if(e.cnt == -2)
 600                                         {
 601                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 602                                                 fputs(f, "\"race_place\" \"0\"\n");
 603                                         }
 604                                         else if(e.cnt == -1)
 605                                         {
 606                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 607                                                 fputs(f, "\"race_place\" \"-1\"\n");
 608                                         }
 609                                         else
 610                                         {
 611                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 612                                                 if(e.cnt == 0)
 613                                                 {
 614                                                         // these need race_place
 615                                                         // counting...
 616                                                         effectnum = 1;
 617                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 618                                                         if(oldself.cnt == 0)
 619                                                         {
 620                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 621                                                                         ++effectnum;
 622                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 623                                                                         ++effectnum;
 624                                                         }
 625                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 626                                                 }
 627                                         }
 628                                         fputs(f, "}\n");
 629                                 }
 630                                 fclose(f);
 631                                 DID_CHEAT();
 632                                 break;
 633                         }
 634                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 635                         break;
 636                 case "drag_clear":
 637                         IS_CHEAT(0, argc, 0);
 638                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 639                                 remove(e);
 640                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 641                                 remove(e);
 642                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 643                                 remove(e);
 644                         for(e = world; (e = find(e, classname, "dragpoint")); )
 645                                 remove(e);
 646                         for(e = world; (e = find(e, classname, "drag_digit")); )
 647                                 remove(e);
 648                         DID_CHEAT();
 649                         break;
 650                 case "god":
 651                         IS_CHEAT(0, argc, 0);
 652                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 653                         if(self.flags & FL_GODMODE)
 654                         {
 655                                 sprint(self, "godmode ON\n");
 656                                 DID_CHEAT();
 657                         }
 658                         else
 659                                 sprint(self, "godmode OFF\n");
 660                         break;
 661                 case "notarget":
 662                         IS_CHEAT(0, argc, 0);
 663                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 664                         if(self.flags & FL_NOTARGET)
 665                         {
 666                                 sprint(self, "notarget ON\n");
 667                                 DID_CHEAT();
 668                         }
 669                         else
 670                                 sprint(self, "notarget OFF\n");
 671                         break;
 672                 case "noclip":
 673                         IS_CHEAT(0, argc, 0);
 674                         if(self.movetype != MOVETYPE_NOCLIP)
 675                         {
 676                                 self.movetype = MOVETYPE_NOCLIP;
 677                                 sprint(self, "noclip ON\n");
 678                                 DID_CHEAT();
 679                         }
 680                         else
 681                         {
 682                                 self.movetype = MOVETYPE_WALK;
 683                                 sprint(self, "noclip OFF\n");
 684                         }
 685                         break;
 686                 case "fly":
 687                         IS_CHEAT(0, argc, 0);
 688                         if(self.movetype != MOVETYPE_FLY)
 689                         {
 690                                 self.movetype = MOVETYPE_FLY;
 691                                 sprint(self, "flymode ON\n");
 692                                 DID_CHEAT();
 693                         }
 694                         else
 695                         {
 696                                 self.movetype = MOVETYPE_WALK;
 697                                 sprint(self, "flymode OFF\n");
 698                         }
 699                         break;
 700                 case "give":
 701                         IS_CHEAT(0, argc, 0);
 702                         if(GiveItems(self, 1, argc))
 703                                 DID_CHEAT();
 704                         break;
 705         }
 706
 707         END_CHEAT_FUNCTION();
 708 }
 709
 710 float Drag(entity e, float grab, float ischeat);
 711 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 712 void Drag_Finish(entity dragger);
 713 float Drag_IsDraggable(entity draggee);
 714 float Drag_MayChangeAngles(entity draggee);
 715 void Drag_MoveForward(entity dragger);
 716 void Drag_SetSpeed(entity dragger, float s);
 717 void Drag_MoveBackward(entity dragger);
 718 void Drag_Update(entity dragger);
 719 float Drag_CanDrag(entity dragger);
 720 float Drag_IsDragging(entity dragger);
 721 void Drag_MoveDrag(entity from, entity to);
 722 .entity dragentity;
 723
 724 float CheatFrame()
 725 {
 726         BEGIN_CHEAT_FUNCTION();
 727
 728         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 729         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 730         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 731         // grabbing itself no longer being accounted as cheating.
 732
 733         switch(0)
 734         {
 735                 default:
 736                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 737                         {
 738                                 // use cheat dragging if cheats are enabled
 739                                 crosshair_trace_plusvisibletriggers(self);
 740                                 Drag(trace_ent, TRUE, TRUE);
 741                         }
 742                         else
 743                         {
 744                                 // drag is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 745                                 // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 746                                 // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 747                                 // it goes out of range while slinging it around.
 748
 749                                 float drag;
 750                                 crosshair_trace_plusvisibletriggers(self);
 751                                 if(vlen(self.origin - trace_ent.origin) <= autocvar_g_grab_range)
 752                                 {
 753                                         switch(trace_ent.grab)
 754                                         {
 755                                                 case 0: // can't grab
 756                                                         break;
 757                                                 case 1: // owner can grab
 758                                                         if(trace_ent.owner == self || trace_ent.realowner == self)
 759                                                                 drag = TRUE;
 760                                                         break;
 761                                                 case 2: // owner and team mates can grab
 762                                                         if(!IsDifferentTeam(trace_ent.owner, self) || !IsDifferentTeam(trace_ent.realowner, self) || trace_ent.team == self.team)
 763                                                                 drag = TRUE;
 764                                                         break;
 765                                                 case 3: // anyone can grab
 766                                                         drag = TRUE;
 767                                                         break;
 768                                                 default:
 769                                                         break;
 770                                         }
 771                                 }
 772                                 Drag(trace_ent, drag, FALSE); // execute dragging
 773                         }
 774                         break;
 775         }
 776
 777         END_CHEAT_FUNCTION();
 778 }
 779
 780
 781
 782
 783
 784 // ENTITY DRAGGING
 785
 786 float Drag(entity e, float pick, float ischeat)
 787 {
 788         BEGIN_CHEAT_FUNCTION();
 789
 790         // returns TRUE when an entity has been picked up
 791         // If pick is TRUE, the object can also be picked up if it's not being held already
 792         // If pick is FALSE, only keep dragging the object if it's already being held
 793
 794         switch(0)
 795         {
 796                 default:
 797                         if(Drag_IsDragging(self))
 798                         {
 799                                 if(self.BUTTON_DRAG)
 800                                 {
 801                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 802                                         {
 803                                                 Drag_MoveForward(self);
 804                                                 self.impulse = 0;
 805                                         }
 806                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 807                                         {
 808                                                 Drag_MoveBackward(self);
 809                                                 self.impulse = 0;
 810                                         }
 811                                         else if(self.impulse >= 1 && self.impulse <= 9)
 812                                         {
 813                                                 Drag_SetSpeed(self, self.impulse - 1);
 814                                         }
 815                                         else if(self.impulse == 14)
 816                                         {
 817                                                 Drag_SetSpeed(self, 9);
 818                                         }
 819
 820                                         if(frametime)
 821                                                 Drag_Update(self);
 822                                 }
 823                                 else
 824                                 {
 825                                         Drag_Finish(self);
 826                                 }
 827                         }
 828                         else
 829                         {
 830                                 if(Drag_CanDrag(self))
 831                                         if(self.BUTTON_DRAG && pick)
 832                                         {
 833                                                 if(e)
 834                                                         if(Drag_IsDraggable(e))
 835                                                         {
 836                                                                 if(ischeat)
 837                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 838                                                                 if(e.draggedby)
 839                                                                         Drag_Finish(e.draggedby);
 840                                                                 if(e.tag_entity)
 841                                                                         detach_sameorigin(e);
 842                                                                 Drag_Begin(self, e, trace_endpos);
 843                                                                 if(ischeat)
 844                                                                         DID_CHEAT();
 845                                                                 return TRUE;
 846                                                         }
 847                                         }
 848                         }
 849                         break;
 850         }
 851         return FALSE;
 852 }
 853
 854 // on dragger:
 855 .float draggravity;
 856 .float dragspeed; // speed of mouse wheel action
 857 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 858 .vector draglocalvector; // local attachment vector of the dragentity
 859 .float draglocalangle;
 860 // on draggee:
 861 .entity draggedby;
 862 .float dragmovetype;
 863 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 864 {
 865         float tagscale;
 866
 867         draggee.dragmovetype = draggee.movetype;
 868         draggee.draggravity = draggee.gravity;
 869         draggee.movetype = MOVETYPE_WALK;
 870         draggee.gravity = 0.00001;
 871         draggee.flags &~= FL_ONGROUND;
 872         draggee.draggedby = dragger;
 873
 874         dragger.dragentity = draggee;
 875
 876         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 877         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 878         touchpoint = touchpoint - gettaginfo(draggee, 0);
 879         tagscale = pow(vlen(v_forward), -2);
 880         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 881         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 882         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 883
 884         dragger.dragspeed = 64;
 885 }
 886
 887 void Drag_Finish(entity dragger)
 888 {
 889         entity draggee;
 890         draggee = dragger.dragentity;
 891         if(dragger)
 892                 dragger.dragentity = world;
 893         draggee.draggedby = world;
 894         draggee.movetype = draggee.dragmovetype;
 895         draggee.gravity = draggee.draggravity;
 896
 897         switch(draggee.movetype)
 898         {
 899                 case MOVETYPE_TOSS:
 900                 case MOVETYPE_WALK:
 901                 case MOVETYPE_STEP:
 902                 case MOVETYPE_FLYMISSILE:
 903                 case MOVETYPE_BOUNCE:
 904                 case MOVETYPE_BOUNCEMISSILE:
 905                 case MOVETYPE_PHYSICS:
 906                         break;
 907                 default:
 908                         draggee.velocity = '0 0 0';
 909                         break;
 910         }
 911
 912         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 913         {
 914                 draggee.velocity = '0 0 0';
 915                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 916         }
 917 }
 918
 919 float Drag_IsDraggable(entity draggee)
 920 {
 921         // TODO add more checks for bad stuff here
 922         if(draggee == world)
 923                 return FALSE;
 924         if(draggee.classname == "func_bobbing")
 925                 return FALSE;
 926         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 927                 return FALSE;
 928         if(draggee.classname == "plat")
 929                 return FALSE;
 930         if(draggee.classname == "func_button")
 931                 return FALSE;
 932 //      if(draggee.model == "")
 933 //              return FALSE;
 934         if(draggee.classname == "spectator")
 935                 return FALSE;
 936         if(draggee.classname == "observer")
 937                 return FALSE;
 938         if(draggee.classname == "exteriorweaponentity")
 939                 return FALSE;
 940         if(draggee.classname == "weaponentity")
 941                 return FALSE;
 942
 943         return TRUE;
 944 }
 945
 946 float Drag_MayChangeAngles(entity draggee)
 947 {
 948         // TODO add more checks for bad stuff here
 949         if(substring(draggee.model, 0, 1) == "*")
 950                 return FALSE;
 951         return TRUE;
 952 }
 953
 954 void Drag_MoveForward(entity dragger)
 955 {
 956         dragger.dragdistance += dragger.dragspeed;
 957 }
 958
 959 void Drag_SetSpeed(entity dragger, float s)
 960 {
 961         dragger.dragspeed = pow(2, s);
 962 }
 963
 964 void Drag_MoveBackward(entity dragger)
 965 {
 966         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 967 }
 968
 969 void Drag_Update(entity dragger)
 970 {
 971         vector curorigin, neworigin, goodvelocity;
 972         float f;
 973         entity draggee;
 974
 975         draggee = dragger.dragentity;
 976         draggee.flags &~= FL_ONGROUND;
 977
 978         curorigin = gettaginfo(draggee, 0);
 979         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 980         makevectors(dragger.v_angle);
 981         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 982         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 983
 984         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 985                 dragger.draglocalangle += 360;
 986         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 987                 dragger.draglocalangle -= 360;
 988
 989         f = min(frametime * 10, 1);
 990         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 991
 992         if(Drag_MayChangeAngles(draggee))
 993                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 994
 995         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 996
 997         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 998 }
 999
1000 float Drag_CanDrag(entity dragger)
1001 {
1002         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
1003 }
1004
1005 float Drag_IsDragging(entity dragger)
1006 {
1007         if(!dragger.dragentity)
1008                 return FALSE;
1009         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1010         {
1011                 dragger.dragentity = world;
1012                 return FALSE;
1013         }
1014         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1015         {
1016                 Drag_Finish(dragger);
1017                 return FALSE;
1018         }
1019         return TRUE;
1020 }
1021
1022 void Drag_MoveDrag(entity from, entity to)
1023 {
1024         if(from.draggedby)
1025         {
1026                 to.draggedby = from.draggedby;
1027                 to.draggedby.dragentity = to;
1028                 from.draggedby = world;
1029         }
1030 }
1031
1032 void DragBox_Think()
1033 {
1034         if(self.aiment && self.enemy)
1035         {
1036                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
1037                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
1038                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
1039                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
1040                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
1041                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
1042                 self.mins = -1 * self.maxs;
1043                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1044         }
1045
1046         if(self.cnt == -1) // actually race_place -1
1047         {
1048                 // show "10 10" for qualifying spawns
1049                 setmodel(self.killindicator, "models/sprites/10.spr32");
1050                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1051         }
1052         else if(self.cnt == -2) // actually race_place 0
1053         {
1054                 // show "10 0" for loser spawns
1055                 setmodel(self.killindicator, "models/sprites/10.spr32");
1056                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1057         }
1058         else
1059         {
1060                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
1061                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1062         }
1063
1064         self.nextthink = time;
1065 }
1066
1067 #endif