qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "waypointsprites.qh"
   4
   5 #include "anticheat.qh"
   6 #include "cl_impulse.qh"
   7 #include "cl_player.qh"
   8 #include "ent_cs.qh"
   9 #include "g_subs.qh"
  10 #include "ipban.qh"
  11 #include "miscfunctions.qh"
  12 #include "portals.qh"
  13 #include "teamplay.qh"
  14 #include "playerdemo.qh"
  15 #include "secret.qh"
  16 #include "spawnpoints.qh"
  17 #include "g_damage.qh"
  18 #include "g_hook.qh"
  19 #include "t_teleporters.qh"
  20 #include "command/common.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27
  28 #include "bot/bot.qh"
  29 #include "bot/navigation.qh"
  30
  31 #include "vehicles/vehicle.qh"
  32
  33 #include "weapons/hitplot.qh"
  34 #include "weapons/weaponsystem.qh"
  35
  36 #include "../common/net_notice.qh"
  37
  38 #include "../common/monsters/sv_monsters.qh"
  39
  40 #include "../warpzonelib/server.qh"
  41
  42
  43 void send_CSQC_teamnagger() {
  44         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  45         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  46 }
  47
  48 float ClientData_Send(entity to, int sf)
  49 {
  50         if(to != self.owner)
  51         {
  52                 error("wtf");
  53                 return false;
  54         }
  55
  56         entity e;
  57
  58         e = to;
  59         if(IS_SPEC(to))
  60                 e = to.enemy;
  61
  62         sf = 0;
  63
  64         if(e.race_completed)
  65                 sf |= 1; // forced scoreboard
  66         if(to.spectatee_status)
  67                 sf |= 2; // spectator ent number follows
  68         if(e.zoomstate)
  69                 sf |= 4; // zoomed
  70         if(e.porto_v_angle_held)
  71                 sf |= 8; // angles held
  72
  73         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  74         WriteByte(MSG_ENTITY, sf);
  75
  76         if(sf & 2)
  77                 WriteByte(MSG_ENTITY, to.spectatee_status);
  78
  79         if(sf & 8)
  80         {
  81                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  82                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  83         }
  84
  85         return true;
  86 }
  87
  88 void ClientData_Attach()
  89 {
  90         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  91         self.clientdata.drawonlytoclient = self;
  92         self.clientdata.owner = self;
  93 }
  94
  95 void ClientData_Detach()
  96 {
  97         remove(self.clientdata);
  98         self.clientdata = world;
  99 }
 100
 101 void ClientData_Touch(entity e)
 102 {
 103         e.clientdata.SendFlags = 1;
 104
 105         // make it spectatable
 106         entity e2;
 107         FOR_EACH_REALCLIENT(e2)
 108         {
 109                 if(e2 != e)
 110                         if(IS_SPEC(e2))
 111                                 if(e2.enemy == e)
 112                                         e2.clientdata.SendFlags = 1;
 113         }
 114 }
 115
 116 .string netname_previous;
 117
 118 void SetSpectator(entity player, entity spectatee);
 119
 120
 121 /*
 122 =============
 123 CheckPlayerModel
 124
 125 Checks if the argument string can be a valid playermodel.
 126 Returns a valid one in doubt.
 127 =============
 128 */
 129 string FallbackPlayerModel;
 130 string CheckPlayerModel(string plyermodel) {
 131         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 132         {
 133                 // note: we cannot summon Don Strunzone here, some player may
 134                 // still have the model string set. In case anyone manages how
 135                 // to change a cvar default, we'll have a small leak here.
 136                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 137         }
 138         // only in right path
 139         if( substring(plyermodel,0,14) != "models/player/")
 140                 return FallbackPlayerModel;
 141         // only good file extensions
 142         if(substring(plyermodel,-4,4) != ".zym")
 143         if(substring(plyermodel,-4,4) != ".dpm")
 144         if(substring(plyermodel,-4,4) != ".iqm")
 145         if(substring(plyermodel,-4,4) != ".md3")
 146         if(substring(plyermodel,-4,4) != ".psk")
 147                 return FallbackPlayerModel;
 148         // forbid the LOD models
 149         if(substring(plyermodel, -9,5) == "_lod1")
 150                 return FallbackPlayerModel;
 151         if(substring(plyermodel, -9,5) == "_lod2")
 152                 return FallbackPlayerModel;
 153         if(plyermodel != strtolower(plyermodel))
 154                 return FallbackPlayerModel;
 155         // also, restrict to server models
 156         if(autocvar_sv_servermodelsonly)
 157         {
 158                 if(!fexists(plyermodel))
 159                         return FallbackPlayerModel;
 160         }
 161         return plyermodel;
 162 }
 163
 164 void setplayermodel(entity e, string modelname)
 165 {
 166         precache_model(modelname);
 167         setmodel(e, modelname);
 168         player_setupanimsformodel();
 169         UpdatePlayerSounds();
 170 }
 171
 172 /*
 173 =============
 174 PutObserverInServer
 175
 176 putting a client as observer in the server
 177 =============
 178 */
 179 void FixPlayermodel();
 180 void PutObserverInServer (void)
 181 {
 182         entity  spot;
 183     self.hud = HUD_NORMAL;
 184
 185         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 186
 187         spot = SelectSpawnPoint (true);
 188         if(!spot)
 189                 error("No spawnpoints for observers?!?\n");
 190         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 191
 192         if(IS_REAL_CLIENT(self))
 193         {
 194                 Item_ItemsTime_Get(self);
 195                 msg_entity = self;
 196                 WriteByte(MSG_ONE, SVC_SETVIEW);
 197                 WriteEntity(MSG_ONE, self);
 198         }
 199
 200         self.frags = FRAGS_SPECTATOR;
 201
 202         MUTATOR_CALLHOOK(MakePlayerObserver);
 203
 204         Portal_ClearAll(self);
 205
 206         Unfreeze(self);
 207
 208         if(self.alivetime)
 209         {
 210                 if(!warmup_stage)
 211                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 212                 self.alivetime = 0;
 213         }
 214
 215         if(self.vehicle)
 216                 vehicles_exit(VHEF_RELESE);
 217
 218         WaypointSprite_PlayerDead();
 219
 220         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 221                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 222
 223         if(self.killcount != -666)
 224         {
 225                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 226                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 227                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 228
 229                 if(self.just_joined == false) {
 230                         LogTeamchange(self.playerid, -1, 4);
 231                 } else
 232                         self.just_joined = false;
 233         }
 234
 235         PlayerScore_Clear(self); // clear scores when needed
 236
 237         accuracy_resend(self);
 238
 239         self.spectatortime = time;
 240
 241         self.classname = "observer";
 242         self.iscreature = false;
 243         self.teleportable = TELEPORT_SIMPLE;
 244         self.damagedbycontents = false;
 245         self.health = -666;
 246         self.takedamage = DAMAGE_NO;
 247         self.solid = SOLID_NOT;
 248         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 249         self.flags = FL_CLIENT | FL_NOTARGET;
 250         self.armorvalue = 666;
 251         self.effects = 0;
 252         self.armorvalue = autocvar_g_balance_armor_start;
 253         self.pauserotarmor_finished = 0;
 254         self.pauserothealth_finished = 0;
 255         self.pauseregen_finished = 0;
 256         self.damageforcescale = 0;
 257         self.death_time = 0;
 258         self.respawn_flags = 0;
 259         self.respawn_time = 0;
 260         self.stat_respawn_time = 0;
 261         self.alpha = 0;
 262         self.scale = 0;
 263         self.fade_time = 0;
 264         self.pain_frame = 0;
 265         self.pain_finished = 0;
 266         self.strength_finished = 0;
 267         self.invincible_finished = 0;
 268         self.superweapons_finished = 0;
 269         self.pushltime = 0;
 270         self.istypefrag = 0;
 271         self.think = func_null;
 272         self.nextthink = 0;
 273         self.hook_time = 0;
 274         self.deadflag = DEAD_NO;
 275         self.angles = spot.angles;
 276         self.angles_z = 0;
 277         self.fixangle = true;
 278         self.crouch = false;
 279         self.revival_time = 0;
 280
 281         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 282         self.prevorigin = self.origin;
 283         self.items = 0;
 284         self.weapons = '0 0 0';
 285         self.model = "";
 286         FixPlayermodel();
 287         setmodel(self, "null");
 288         self.drawonlytoclient = self;
 289
 290         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 291         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 292
 293         self.weapon = 0;
 294         self.weaponname = "";
 295         self.switchingweapon = 0;
 296         self.weaponmodel = "";
 297         self.weaponentity = world;
 298         self.exteriorweaponentity = world;
 299         self.killcount = -666;
 300         self.velocity = '0 0 0';
 301         self.avelocity = '0 0 0';
 302         self.punchangle = '0 0 0';
 303         self.punchvector = '0 0 0';
 304         self.oldvelocity = self.velocity;
 305         self.fire_endtime = -1;
 306         self.event_damage = func_null;
 307 }
 308
 309 .float model_randomizer;
 310 void FixPlayermodel()
 311 {
 312         string defaultmodel;
 313         float defaultskin, chmdl, oldskin, n, i;
 314         vector m1, m2;
 315
 316         defaultmodel = "";
 317         defaultskin = 0;
 318         chmdl = false;
 319
 320         if(autocvar_sv_defaultcharacter)
 321         {
 322                 if(teamplay)
 323                 {
 324                         string s;
 325                         s = Static_Team_ColorName_Lower(self.team);
 326                         if(s != "neutral")
 327                         {
 328                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 329                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 330                         }
 331                 }
 332
 333                 if(defaultmodel == "")
 334                 {
 335                         defaultmodel = autocvar_sv_defaultplayermodel;
 336                         defaultskin = autocvar_sv_defaultplayerskin;
 337                 }
 338
 339                 n = tokenize_console(defaultmodel);
 340                 if(n > 0)
 341                 {
 342                         defaultmodel = argv(floor(n * self.model_randomizer));
 343                         // However, do NOT randomize if the player-selected model is in the list.
 344                         for (i = 0; i < n; ++i)
 345                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 346                                         defaultmodel = argv(i);
 347                 }
 348
 349                 i = strstrofs(defaultmodel, ":", 0);
 350                 if(i >= 0)
 351                 {
 352                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 353                         defaultmodel = substring(defaultmodel, 0, i);
 354                 }
 355         }
 356
 357         if(defaultmodel != "")
 358         {
 359                 if (defaultmodel != self.model)
 360                 {
 361                         m1 = self.mins;
 362                         m2 = self.maxs;
 363                         setplayermodel (self, defaultmodel);
 364                         setsize (self, m1, m2);
 365                         chmdl = true;
 366                 }
 367
 368                 oldskin = self.skin;
 369                 self.skin = defaultskin;
 370         } else {
 371                 if (self.playermodel != self.model || self.playermodel == "")
 372                 {
 373                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 374                         m1 = self.mins;
 375                         m2 = self.maxs;
 376                         setplayermodel (self, self.playermodel);
 377                         setsize (self, m1, m2);
 378                         chmdl = true;
 379                 }
 380
 381                 oldskin = self.skin;
 382                 self.skin = stof(self.playerskin);
 383         }
 384
 385         if(chmdl || oldskin != self.skin) // model or skin has changed
 386         {
 387                 self.species = player_getspecies(); // update species
 388                 UpdatePlayerSounds(); // update skin sounds
 389         }
 390
 391         if(!teamplay)
 392                 if(strlen(autocvar_sv_defaultplayercolors))
 393                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 394                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 395 }
 396
 397 /*
 398 =============
 399 PutClientInServer
 400
 401 Called when a client spawns in the server
 402 =============
 403 */
 404 void PutClientInServer (void)
 405 {
 406         if(IS_BOT_CLIENT(self))
 407                 self.classname = "player";
 408         else if(IS_REAL_CLIENT(self))
 409         {
 410                 msg_entity = self;
 411                 WriteByte(MSG_ONE, SVC_SETVIEW);
 412                 WriteEntity(MSG_ONE, self);
 413         }
 414
 415         SetSpectator(self, world);
 416
 417         // reset player keys
 418         self.itemkeys = 0;
 419
 420         MUTATOR_CALLHOOK(PutClientInServer);
 421
 422         if(gameover)
 423                 self.classname = "observer";
 424
 425         if(IS_PLAYER(self))
 426         {
 427                 entity spot, oldself;
 428
 429                 accuracy_resend(self);
 430
 431                 if(self.team < 0)
 432                         JoinBestTeam(self, false, true);
 433
 434                 spot = SelectSpawnPoint (false);
 435                 if(!spot)
 436                 {
 437                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 438                         return; // spawn failed
 439                 }
 440
 441                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 442
 443                 if(self.vehicle)
 444                         vehicles_exit(VHEF_RELESE);
 445
 446                 self.classname = "player";
 447                 self.wasplayer = true;
 448                 self.iscreature = true;
 449                 self.teleportable = TELEPORT_NORMAL;
 450                 self.damagedbycontents = true;
 451                 self.movetype = MOVETYPE_WALK;
 452                 self.solid = SOLID_SLIDEBOX;
 453                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 454                 if(autocvar_g_playerclip_collisions)
 455                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 456                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 457                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 458                 self.frags = FRAGS_PLAYER;
 459                 if(INDEPENDENT_PLAYERS)
 460                         MAKE_INDEPENDENT_PLAYER(self);
 461                 self.flags = FL_CLIENT;
 462                 if(autocvar__notarget)
 463                         self.flags |= FL_NOTARGET;
 464                 self.takedamage = DAMAGE_AIM;
 465                 self.effects = 0;
 466                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 467                 self.air_finished = time + 12;
 468                 self.dmg = 2;
 469                 if(WEP_CVAR(vortex, charge))
 470                 {
 471                         if(WEP_CVAR_SEC(vortex, chargepool))
 472                                 self.vortex_chargepool_ammo = 1;
 473                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 474                 }
 475
 476                 if(warmup_stage)
 477                 {
 478                         self.ammo_shells = warmup_start_ammo_shells;
 479                         self.ammo_nails = warmup_start_ammo_nails;
 480                         self.ammo_rockets = warmup_start_ammo_rockets;
 481                         self.ammo_cells = warmup_start_ammo_cells;
 482                         self.ammo_plasma = warmup_start_ammo_plasma;
 483                         self.ammo_fuel = warmup_start_ammo_fuel;
 484                         self.health = warmup_start_health;
 485                         self.armorvalue = warmup_start_armorvalue;
 486                         self.weapons = WARMUP_START_WEAPONS;
 487                 }
 488                 else
 489                 {
 490                         self.ammo_shells = start_ammo_shells;
 491                         self.ammo_nails = start_ammo_nails;
 492                         self.ammo_rockets = start_ammo_rockets;
 493                         self.ammo_cells = start_ammo_cells;
 494                         self.ammo_plasma = start_ammo_plasma;
 495                         self.ammo_fuel = start_ammo_fuel;
 496                         self.health = start_health;
 497                         self.armorvalue = start_armorvalue;
 498                         self.weapons = start_weapons;
 499                 }
 500
 501                 if(self.weapons & WEPSET_SUPERWEAPONS)
 502                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 503                 else
 504                         self.superweapons_finished = 0;
 505
 506                 if(!warmup_stage)
 507                         Item_ItemsTime_ResetForPlayer(self);
 508
 509                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 510                 {
 511                         if(g_weaponarena_random_with_blaster)
 512                                 self.weapons &= ~WEPSET_BLASTER;
 513                         W_RandomWeapons(self, g_weaponarena_random);
 514                         if(g_weaponarena_random_with_blaster)
 515                                 self.weapons |= WEPSET_BLASTER;
 516                 }
 517
 518                 self.items = start_items;
 519
 520                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 521                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 522                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 523                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 524                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 525                 //extend the pause of rotting if client was reset at the beginning of the countdown
 526                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 527                         self.spawnshieldtime += game_starttime - time;
 528                         self.pauserotarmor_finished += game_starttime - time;
 529                         self.pauserothealth_finished += game_starttime - time;
 530                         self.pauseregen_finished += game_starttime - time;
 531                 }
 532                 self.damageforcescale = 2;
 533                 self.death_time = 0;
 534                 self.respawn_flags = 0;
 535                 self.respawn_time = 0;
 536                 self.stat_respawn_time = 0;
 537                 self.scale = 0;
 538                 self.fade_time = 0;
 539                 self.pain_frame = 0;
 540                 self.pain_finished = 0;
 541                 self.strength_finished = 0;
 542                 self.invincible_finished = 0;
 543                 self.pushltime = 0;
 544                 // players have no think function
 545                 self.think = func_null;
 546                 self.nextthink = 0;
 547                 self.hook_time = 0;
 548                 self.dmg_team = 0;
 549                 self.ballistics_density = autocvar_g_ballistics_density_player;
 550
 551                 self.metertime = 0;
 552
 553                 self.deadflag = DEAD_NO;
 554
 555                 self.angles = spot.angles;
 556
 557                 self.angles_z = 0; // never spawn tilted even if the spot says to
 558                 if(IS_BOT_CLIENT(self))
 559                         self.v_angle = self.angles;
 560                 self.fixangle = true; // turn this way immediately
 561                 self.velocity = '0 0 0';
 562                 self.avelocity = '0 0 0';
 563                 self.punchangle = '0 0 0';
 564                 self.punchvector = '0 0 0';
 565                 self.oldvelocity = self.velocity;
 566                 self.fire_endtime = -1;
 567                 self.revival_time = 0;
 568
 569                 entity spawnevent = spawn();
 570                 spawnevent.owner = self;
 571                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 572
 573                 // Cut off any still running player sounds.
 574                 stopsound(self, CH_PLAYER_SINGLE);
 575
 576                 self.model = "";
 577                 FixPlayermodel();
 578                 self.drawonlytoclient = world;
 579
 580                 self.crouch = false;
 581                 self.view_ofs = PL_VIEW_OFS;
 582                 setsize (self, PL_MIN, PL_MAX);
 583                 self.spawnorigin = spot.origin;
 584                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 585                 // don't reset back to last position, even if new position is stuck in solid
 586                 self.oldorigin = self.origin;
 587                 self.prevorigin = self.origin;
 588                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 589                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 590         self.hud = HUD_NORMAL;
 591
 592                 self.event_damage = PlayerDamage;
 593
 594                 self.bot_attack = true;
 595                 self.monster_attack = true;
 596
 597                 self.spider_slowness = 0;
 598
 599                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 600
 601                 if(self.killcount == -666) {
 602                         PlayerScore_Clear(self);
 603                         self.killcount = 0;
 604                 }
 605
 606                 CL_SpawnWeaponentity();
 607                 self.alpha = default_player_alpha;
 608                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 609                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 610
 611                 self.speedrunning = false;
 612
 613                 //stuffcmd(self, "chase_active 0");
 614                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 615
 616                 target_voicescript_clear(self);
 617
 618                 // reset fields the weapons may use
 619                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 620                 {
 621                         WEP_ACTION(j, WR_RESETPLAYER);
 622
 623                         // all weapons must be fully loaded when we spawn
 624                         entity e = get_weaponinfo(j);
 625                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 626                                 self.(weapon_load[j]) = e.reloading_ammo;
 627                 }
 628
 629                 oldself = self;
 630                 self = spot;
 631                         activator = oldself;
 632                                 string s;
 633                                 s = self.target;
 634                                 self.target = string_null;
 635                                 SUB_UseTargets();
 636                                 self.target = s;
 637                         activator = world;
 638                 self = oldself;
 639
 640                 Unfreeze(self);
 641
 642                 spawn_spot = spot;
 643                 MUTATOR_CALLHOOK(PlayerSpawn);
 644
 645                 if(autocvar_spawn_debug)
 646                 {
 647                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 648                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 649                 }
 650
 651                 self.switchweapon = w_getbestweapon(self);
 652                 self.cnt = -1; // W_LastWeapon will not complain
 653                 self.weapon = 0;
 654                 self.weaponname = "";
 655                 self.switchingweapon = 0;
 656
 657                 if(!warmup_stage)
 658                         if(!self.alivetime)
 659                                 self.alivetime = time;
 660
 661                 antilag_clear(self);
 662         }
 663         else if(IS_OBSERVER(self))
 664         {
 665                 PutObserverInServer ();
 666         }
 667 }
 668
 669 .float ebouncefactor, ebouncestop; // electro's values
 670 // TODO do we need all these fields, or should we stop autodetecting runtime
 671 // changes and just have a console command to update this?
 672 float ClientInit_SendEntity(entity to, int sf)
 673 {
 674         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 675         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 683         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 684
 685         if(sv_foginterval && world.fog != "")
 686                 WriteString(MSG_ENTITY, world.fog);
 687         else
 688                 WriteString(MSG_ENTITY, "");
 689         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 690         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 691         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 692         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 693         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 694         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 695         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 696         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 697         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 698         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 699         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 700         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 701         return true;
 702 }
 703
 704 void ClientInit_CheckUpdate()
 705 {
 706         self.nextthink = time;
 707         if(self.count != autocvar_g_balance_armor_blockpercent)
 708         {
 709                 self.count = autocvar_g_balance_armor_blockpercent;
 710                 self.SendFlags |= 1;
 711         }
 712         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 713         {
 714                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 715                 self.SendFlags |= 1;
 716         }
 717         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 718         {
 719                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 720                 self.SendFlags |= 1;
 721         }
 722         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 723         {
 724                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 725                 self.SendFlags |= 1;
 726         }
 727         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 728         {
 729                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 730                 self.SendFlags |= 1;
 731         }
 732 }
 733
 734 void ClientInit_Spawn()
 735 {
 736         entity o;
 737         entity e;
 738         e = spawn();
 739         e.classname = "clientinit";
 740         e.think = ClientInit_CheckUpdate;
 741         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 742
 743         o = self;
 744         self = e;
 745         ClientInit_CheckUpdate();
 746         self = o;
 747 }
 748
 749 /*
 750 =============
 751 SetNewParms
 752 =============
 753 */
 754 void SetNewParms (void)
 755 {
 756         // initialize parms for a new player
 757         parm1 = -(86400 * 366);
 758 }
 759
 760 /*
 761 =============
 762 SetChangeParms
 763 =============
 764 */
 765 void SetChangeParms (void)
 766 {
 767         // save parms for level change
 768         parm1 = self.parm_idlesince - time;
 769 }
 770
 771 /*
 772 =============
 773 DecodeLevelParms
 774 =============
 775 */
 776 void DecodeLevelParms (void)
 777 {
 778         // load parms
 779         self.parm_idlesince = parm1;
 780         if(self.parm_idlesince == -(86400 * 366))
 781                 self.parm_idlesince = time;
 782
 783         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 784         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 785 }
 786
 787 /*
 788 =============
 789 ClientKill
 790
 791 Called when a client types 'kill' in the console
 792 =============
 793 */
 794
 795 .float clientkill_nexttime;
 796 void ClientKill_Now_TeamChange()
 797 {
 798         if(self.killindicator_teamchange == -1)
 799         {
 800                 JoinBestTeam( self, false, true );
 801         }
 802         else if(self.killindicator_teamchange == -2)
 803         {
 804                 if(blockSpectators)
 805                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 806                 PutObserverInServer();
 807         }
 808         else
 809                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 810         self.killindicator_teamchange = 0;
 811 }
 812
 813 void ClientKill_Now()
 814 {
 815         if(self.vehicle)
 816         {
 817             vehicles_exit(VHEF_RELESE);
 818             if(!self.killindicator_teamchange)
 819             {
 820             self.vehicle_health = -1;
 821             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 822             }
 823         }
 824
 825         if(self.killindicator && !wasfreed(self.killindicator))
 826                 remove(self.killindicator);
 827
 828         self.killindicator = world;
 829
 830         if(self.killindicator_teamchange)
 831                 ClientKill_Now_TeamChange();
 832
 833         if(IS_PLAYER(self))
 834                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 835
 836         // now I am sure the player IS dead
 837 }
 838 void KillIndicator_Think()
 839 {
 840         if (gameover)
 841         {
 842                 self.owner.killindicator = world;
 843                 remove(self);
 844                 return;
 845         }
 846
 847         if (self.owner.alpha < 0 && !self.owner.vehicle)
 848         {
 849                 self.owner.killindicator = world;
 850                 remove(self);
 851                 return;
 852         }
 853
 854         if(self.cnt <= 0)
 855         {
 856                 self = self.owner;
 857                 ClientKill_Now(); // no oldself needed
 858                 return;
 859         }
 860     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 861     {
 862         self.nextthink = time + 1;
 863         self.cnt -= 1;
 864     }
 865         else
 866         {
 867                 if(self.cnt <= 10)
 868                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 869                 if(IS_REAL_CLIENT(self.owner))
 870                 {
 871                         if(self.cnt <= 10)
 872                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 873                 }
 874                 self.nextthink = time + 1;
 875                 self.cnt -= 1;
 876         }
 877 }
 878
 879 float clientkilltime;
 880 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 881 {
 882         float killtime;
 883         float starttime;
 884         entity e;
 885
 886         if (gameover)
 887                 return;
 888
 889         killtime = autocvar_g_balance_kill_delay;
 890
 891         if(g_race_qualifying || g_cts)
 892                 killtime = 0;
 893
 894     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 895     {
 896                 remove(self.killindicator);
 897                 self.killindicator = world;
 898
 899         ClientKill_Now(); // allow instant kill in this case
 900         return;
 901     }
 902
 903         self.killindicator_teamchange = targetteam;
 904
 905     if(!self.killindicator)
 906         {
 907                 if(self.deadflag == DEAD_NO)
 908                 {
 909                         killtime = max(killtime, self.clientkill_nexttime - time);
 910                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 911                 }
 912
 913                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 914                 {
 915                         ClientKill_Now();
 916                 }
 917                 else
 918                 {
 919                         starttime = max(time, clientkilltime);
 920
 921                         self.killindicator = spawn();
 922                         self.killindicator.owner = self;
 923                         self.killindicator.scale = 0.5;
 924                         setattachment(self.killindicator, self, "");
 925                         setorigin(self.killindicator, '0 0 52');
 926                         self.killindicator.think = KillIndicator_Think;
 927                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 928                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 929                         self.killindicator.cnt = ceil(killtime);
 930                         self.killindicator.count = bound(0, ceil(killtime), 10);
 931                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 932
 933                         for(e = world; (e = find(e, classname, "body")) != world; )
 934                         {
 935                                 if(e.enemy != self)
 936                                         continue;
 937                                 e.killindicator = spawn();
 938                                 e.killindicator.owner = e;
 939                                 e.killindicator.scale = 0.5;
 940                                 setattachment(e.killindicator, e, "");
 941                                 setorigin(e.killindicator, '0 0 52');
 942                                 e.killindicator.think = KillIndicator_Think;
 943                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 944                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 945                                 e.killindicator.cnt = ceil(killtime);
 946                         }
 947                         self.lip = 0;
 948                 }
 949         }
 950         if(self.killindicator)
 951         {
 952                 if(targetteam == 0) // just die
 953                 {
 954                         self.killindicator.colormod = '0 0 0';
 955                         if(IS_REAL_CLIENT(self))
 956                         if(self.killindicator.cnt > 0)
 957                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 958                 }
 959                 else if(targetteam == -1) // auto
 960                 {
 961                         self.killindicator.colormod = '0 1 0';
 962                         if(IS_REAL_CLIENT(self))
 963                         if(self.killindicator.cnt > 0)
 964                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 965                 }
 966                 else if(targetteam == -2) // spectate
 967                 {
 968                         self.killindicator.colormod = '0.5 0.5 0.5';
 969                         if(IS_REAL_CLIENT(self))
 970                         if(self.killindicator.cnt > 0)
 971                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 972                 }
 973                 else
 974                 {
 975                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 976                         if(IS_REAL_CLIENT(self))
 977                         if(self.killindicator.cnt > 0)
 978                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 979                 }
 980         }
 981
 982 }
 983
 984 void ClientKill (void)
 985 {
 986         if(gameover) return;
 987         if(self.player_blocked) return;
 988         if(self.frozen) return;
 989
 990         ClientKill_TeamChange(0);
 991 }
 992
 993 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 994 {
 995     e.killindicator = spawn();
 996     e.killindicator.owner = e;
 997     e.killindicator.think = KillIndicator_Think;
 998     e.killindicator.nextthink = time + (e.lip) * 0.05;
 999     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1000     e.killindicator.health = 1; // this is used to indicate that it should be silent
1001     e.lip = 0;
1002 }
1003
1004 void FixClientCvars(entity e)
1005 {
1006         // send prediction settings to the client
1007         stuffcmd(e, "\nin_bindmap 0 0\n");
1008         if(g_race || g_cts)
1009                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1010         if(autocvar_g_antilag == 3) // client side hitscan
1011                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1012         if(autocvar_sv_gentle)
1013                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1014 }
1015
1016 float PlayerInIDList(entity p, string idlist)
1017 {
1018         float n, i;
1019         string s;
1020
1021         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1022         if (!p.crypto_idfp)
1023                 return 0;
1024
1025         // this function allows abbreviated player IDs too!
1026         n = tokenize_console(idlist);
1027         for(i = 0; i < n; ++i)
1028         {
1029                 s = argv(i);
1030                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1031                         return 1;
1032         }
1033
1034         return 0;
1035 }
1036
1037 #ifdef DP_EXT_PRECONNECT
1038 /*
1039 =============
1040 ClientPreConnect
1041
1042 Called once (not at each match start) when a client begins a connection to the server
1043 =============
1044 */
1045 void ClientPreConnect (void)
1046 {
1047         if(autocvar_sv_eventlog)
1048         {
1049                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1050                         self.playerid,
1051                         num_for_edict(self),
1052                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1053                 ));
1054         }
1055 }
1056 #endif
1057
1058 /*
1059 =============
1060 ClientConnect
1061
1062 Called when a client connects to the server
1063 =============
1064 */
1065 void DecodeLevelParms (void);
1066 //void dom_player_join_team(entity pl);
1067 void set_dom_state(entity e);
1068 void ClientConnect (void)
1069 {
1070         float t;
1071
1072         if(IS_CLIENT(self))
1073         {
1074                 print("Warning: ClientConnect, but already connected!\n");
1075                 return;
1076         }
1077
1078         if(Ban_MaybeEnforceBanOnce(self))
1079                 return;
1080
1081         DecodeLevelParms();
1082
1083 #ifdef WATERMARK
1084         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1085 #endif
1086
1087         self.classname = "player_joining";
1088
1089         self.flags = FL_CLIENT;
1090         self.version_nagtime = time + 10 + random() * 10;
1091
1092         if(player_count<0)
1093         {
1094                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1095                 player_count = 0;
1096         }
1097
1098         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1099
1100         PlayerScore_Attach(self);
1101         ClientData_Attach();
1102         accuracy_init(self);
1103
1104         bot_clientconnect();
1105
1106         playerdemo_init();
1107
1108         anticheat_init();
1109
1110         // identify the right forced team
1111         if(autocvar_g_campaign)
1112         {
1113                 if(IS_REAL_CLIENT(self)) // only players, not bots
1114                 {
1115                         switch(autocvar_g_campaign_forceteam)
1116                         {
1117                                 case 1: self.team_forced = NUM_TEAM_1; break;
1118                                 case 2: self.team_forced = NUM_TEAM_2; break;
1119                                 case 3: self.team_forced = NUM_TEAM_3; break;
1120                                 case 4: self.team_forced = NUM_TEAM_4; break;
1121                                 default: self.team_forced = 0;
1122                         }
1123                 }
1124         }
1125         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1126                 self.team_forced = NUM_TEAM_1;
1127         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1128                 self.team_forced = NUM_TEAM_2;
1129         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1130                 self.team_forced = NUM_TEAM_3;
1131         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1132                 self.team_forced = NUM_TEAM_4;
1133         else if(autocvar_g_forced_team_otherwise == "red")
1134                 self.team_forced = NUM_TEAM_1;
1135         else if(autocvar_g_forced_team_otherwise == "blue")
1136                 self.team_forced = NUM_TEAM_2;
1137         else if(autocvar_g_forced_team_otherwise == "yellow")
1138                 self.team_forced = NUM_TEAM_3;
1139         else if(autocvar_g_forced_team_otherwise == "pink")
1140                 self.team_forced = NUM_TEAM_4;
1141         else if(autocvar_g_forced_team_otherwise == "spectate")
1142                 self.team_forced = -1;
1143         else if(autocvar_g_forced_team_otherwise == "spectator")
1144                 self.team_forced = -1;
1145         else
1146                 self.team_forced = 0;
1147
1148         if(!teamplay)
1149                 if(self.team_forced > 0)
1150                         self.team_forced = 0;
1151
1152         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1153
1154         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1155                 self.classname = "observer";
1156         } else {
1157                 if(teamplay)
1158                 {
1159                         if(autocvar_g_balance_teams)
1160                         {
1161                                 self.classname = "player";
1162                                 campaign_bots_may_start = 1;
1163                         }
1164                         else
1165                         {
1166                                 self.classname = "observer"; // do it anyway
1167                         }
1168                 }
1169                 else
1170                 {
1171                         self.classname = "player";
1172                         campaign_bots_may_start = 1;
1173                 }
1174         }
1175
1176         self.playerid = (playerid_last = playerid_last + 1);
1177
1178         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1179
1180     if(IS_BOT_CLIENT(self))
1181         PlayerStats_GameReport_AddPlayer(self);
1182
1183         if(autocvar_sv_eventlog)
1184                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1185
1186         LogTeamchange(self.playerid, self.team, 1);
1187
1188         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1189
1190         self.netname_previous = strzone(self.netname);
1191
1192         if(IS_PLAYER(self) && teamplay)
1193                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1194         else
1195                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1196
1197         stuffcmd(self, strcat(clientstuff, "\n"));
1198         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1199
1200         FixClientCvars(self);
1201
1202         // spawnfunc_waypoint sprites
1203         WaypointSprite_InitClient(self);
1204
1205         // Wazat's grappling hook
1206         SetGrappleHookBindings();
1207
1208         // Jetpack binds
1209         stuffcmd(self, "alias +jetpack +button10\n");
1210         stuffcmd(self, "alias -jetpack -button10\n");
1211
1212         // get version info from player
1213         stuffcmd(self, "cmd clientversion $gameversion\n");
1214
1215         // get other cvars from player
1216         GetCvars(0);
1217
1218         // notify about available teams
1219         if(teamplay)
1220         {
1221                 CheckAllowedTeams(self);
1222                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1223                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1224         }
1225         else
1226                 stuffcmd(self, "set _teams_available 0\n");
1227
1228         attach_entcs();
1229
1230         bot_relinkplayerlist();
1231
1232         self.spectatortime = time;
1233         if(blockSpectators)
1234         {
1235                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1236         }
1237
1238         self.jointime = time;
1239         self.allowed_timeouts = autocvar_sv_timeout_number;
1240
1241         if(IS_REAL_CLIENT(self))
1242         {
1243                 if(!autocvar_g_campaign)
1244                 {
1245                         self.motd_actived_time = -1;
1246                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1247                 }
1248
1249                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1250                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1251         }
1252
1253         if(!sv_foginterval && world.fog != "")
1254                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1255
1256         W_HitPlotOpen(self);
1257
1258         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1259                 send_CSQC_teamnagger();
1260
1261         CheatInitClient();
1262
1263         CSQCMODEL_AUTOINIT();
1264
1265         self.model_randomizer = random();
1266
1267         if(IS_REAL_CLIENT(self))
1268                 sv_notice_join();
1269
1270         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1271                 entity oldself = self;
1272                 self = e;
1273                 e.init_for_player(oldself);
1274                 self = oldself;
1275         }
1276
1277         MUTATOR_CALLHOOK(ClientConnect);
1278 }
1279 /*
1280 =============
1281 ClientDisconnect
1282
1283 Called when a client disconnects from the server
1284 =============
1285 */
1286 .entity chatbubbleentity;
1287 void ReadyCount();
1288 void ClientDisconnect (void)
1289 {
1290         if(self.vehicle)
1291             vehicles_exit(VHEF_RELESE);
1292
1293         if (!IS_CLIENT(self))
1294         {
1295                 print("Warning: ClientDisconnect without ClientConnect\n");
1296                 return;
1297         }
1298
1299         PlayerStats_GameReport_FinalizePlayer(self);
1300
1301         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1302
1303         CheatShutdownClient();
1304
1305         W_HitPlotClose(self);
1306
1307         anticheat_report();
1308         anticheat_shutdown();
1309
1310         playerdemo_shutdown();
1311
1312         bot_clientdisconnect();
1313
1314         if(self.entcs)
1315                 detach_entcs();
1316
1317         if(autocvar_sv_eventlog)
1318                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1319
1320         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1321
1322         MUTATOR_CALLHOOK(ClientDisconnect);
1323
1324         Portal_ClearAll(self);
1325
1326         Unfreeze(self);
1327
1328         RemoveGrapplingHook(self);
1329
1330         // Here, everything has been done that requires this player to be a client.
1331
1332         self.flags &= ~FL_CLIENT;
1333
1334         if (self.chatbubbleentity)
1335                 remove (self.chatbubbleentity);
1336
1337         if (self.killindicator)
1338                 remove (self.killindicator);
1339
1340         WaypointSprite_PlayerGone();
1341
1342         bot_relinkplayerlist();
1343
1344         accuracy_free(self);
1345         ClientData_Detach();
1346         PlayerScore_Detach(self);
1347
1348         if(self.netname_previous)
1349                 strunzone(self.netname_previous);
1350         if(self.clientstatus)
1351                 strunzone(self.clientstatus);
1352         if(self.weaponorder_byimpulse)
1353                 strunzone(self.weaponorder_byimpulse);
1354
1355         ClearPlayerSounds();
1356
1357         if(self.personal)
1358                 remove(self.personal);
1359
1360         self.playerid = 0;
1361         ReadyCount();
1362
1363         // free cvars
1364         GetCvars(-1);
1365 }
1366
1367 .float BUTTON_CHAT;
1368 void ChatBubbleThink()
1369 {
1370         self.nextthink = time;
1371         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1372         {
1373                 if(self.owner) // but why can that ever be world?
1374                         self.owner.chatbubbleentity = world;
1375                 remove(self);
1376                 return;
1377         }
1378         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1379 #ifdef TETRIS
1380                 || self.owner.tetris_on
1381 #endif
1382         )
1383                 self.model = self.mdl;
1384         else
1385                 self.model = "";
1386 }
1387
1388 void UpdateChatBubble()
1389 {
1390         if (self.alpha < 0)
1391                 return;
1392         // spawn a chatbubble entity if needed
1393         if (!self.chatbubbleentity)
1394         {
1395                 self.chatbubbleentity = spawn();
1396                 self.chatbubbleentity.owner = self;
1397                 self.chatbubbleentity.exteriormodeltoclient = self;
1398                 self.chatbubbleentity.think = ChatBubbleThink;
1399                 self.chatbubbleentity.nextthink = time;
1400                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1401                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1402                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1403                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1404                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1405                 self.chatbubbleentity.model = "";
1406                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1407         }
1408 }
1409
1410
1411 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1412 // added to the model skins
1413 /*void UpdateColorModHack()
1414 {
1415         float c;
1416         c = self.clientcolors & 15;
1417         // LordHavoc: only bothering to support white, green, red, yellow, blue
1418              if (!teamplay) self.colormod = '0 0 0';
1419         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1420         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1421         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1422         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1423         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1424         else self.colormod = '1 1 1';
1425 }*/
1426
1427 void respawn(void)
1428 {
1429         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1430         {
1431                 self.solid = SOLID_NOT;
1432                 self.takedamage = DAMAGE_NO;
1433                 self.movetype = MOVETYPE_FLY;
1434                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1435                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1436                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1437                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1438                 if(autocvar_g_respawn_ghosts_maxtime)
1439                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1440         }
1441
1442         CopyBody(1);
1443
1444         self.effects |= EF_NODRAW; // prevent another CopyBody
1445         PutClientInServer();
1446 }
1447
1448 void play_countdown(float finished, string samp)
1449 {
1450         if(IS_REAL_CLIENT(self))
1451                 if(floor(finished - time - frametime) != floor(finished - time))
1452                         if(finished - time < 6)
1453                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1454 }
1455
1456 void player_powerups (void)
1457 {
1458         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1459         olditems = self.items;
1460
1461         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1462                 self.modelflags |= MF_ROCKET;
1463         else
1464                 self.modelflags &= ~MF_ROCKET;
1465
1466         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1467
1468         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1469                 return;
1470
1471         Fire_ApplyDamage(self);
1472         Fire_ApplyEffect(self);
1473
1474         if (!g_instagib)
1475         {
1476                 if (self.items & IT_STRENGTH)
1477                 {
1478                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1479                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1480                         if (time > self.strength_finished)
1481                         {
1482                                 self.items = self.items - (self.items & IT_STRENGTH);
1483                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1484                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1485                         }
1486                 }
1487                 else
1488                 {
1489                         if (time < self.strength_finished)
1490                         {
1491                                 self.items = self.items | IT_STRENGTH;
1492                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1493                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1494                         }
1495                 }
1496                 if (self.items & IT_INVINCIBLE)
1497                 {
1498                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1499                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1500                         if (time > self.invincible_finished)
1501                         {
1502                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1503                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1504                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1505                         }
1506                 }
1507                 else
1508                 {
1509                         if (time < self.invincible_finished)
1510                         {
1511                                 self.items = self.items | IT_INVINCIBLE;
1512                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1513                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1514                         }
1515                 }
1516                 if (self.items & IT_SUPERWEAPON)
1517                 {
1518                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1519                         {
1520                                 self.superweapons_finished = 0;
1521                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1522                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1523                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1524                         }
1525                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1526                         {
1527                                 // don't let them run out
1528                         }
1529                         else
1530                         {
1531                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1532                                 if (time > self.superweapons_finished)
1533                                 {
1534                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1535                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1536                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1537                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1538                                 }
1539                         }
1540                 }
1541                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1542                 {
1543                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1544                         {
1545                                 self.items = self.items | IT_SUPERWEAPON;
1546                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1547                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1548                         }
1549                         else
1550                         {
1551                                 self.superweapons_finished = 0;
1552                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1553                         }
1554                 }
1555                 else
1556                 {
1557                         self.superweapons_finished = 0;
1558                 }
1559         }
1560
1561         if(autocvar_g_nodepthtestplayers)
1562                 self.effects = self.effects | EF_NODEPTHTEST;
1563
1564         if(autocvar_g_fullbrightplayers)
1565                 self.effects = self.effects | EF_FULLBRIGHT;
1566
1567         if (time >= game_starttime)
1568         if (time < self.spawnshieldtime)
1569                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1570
1571         MUTATOR_CALLHOOK(PlayerPowerups);
1572 }
1573
1574 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1575 {
1576         if(current > stable)
1577                 return current;
1578         else if(current > stable - 0.25) // when close enough, "snap"
1579                 return stable;
1580         else
1581                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1582 }
1583
1584 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1585 {
1586         if(current < stable)
1587                 return current;
1588         else if(current < stable + 0.25) // when close enough, "snap"
1589                 return stable;
1590         else
1591                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1592 }
1593
1594 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1595 {
1596         if(current > rotstable)
1597         {
1598                 if(rotframetime > 0)
1599                 {
1600                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1601                         current = max(rotstable, current - rotlinear * rotframetime);
1602                 }
1603         }
1604         else if(current < regenstable)
1605         {
1606                 if(regenframetime > 0)
1607                 {
1608                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1609                         current = min(regenstable, current + regenlinear * regenframetime);
1610                 }
1611         }
1612
1613         if(current > limit)
1614                 current = limit;
1615
1616         return current;
1617 }
1618
1619 void player_regen (void)
1620 {
1621         float max_mod, regen_mod, rot_mod, limit_mod;
1622         max_mod = regen_mod = rot_mod = limit_mod = 1;
1623         regen_mod_max = max_mod;
1624         regen_mod_regen = regen_mod;
1625         regen_mod_rot = rot_mod;
1626         regen_mod_limit = limit_mod;
1627         if(!MUTATOR_CALLHOOK(PlayerRegen))
1628         if(!self.frozen)
1629         {
1630                 float minh, mina, maxh, maxa, limith, limita;
1631                 maxh = autocvar_g_balance_health_rotstable;
1632                 maxa = autocvar_g_balance_armor_rotstable;
1633                 minh = autocvar_g_balance_health_regenstable;
1634                 mina = autocvar_g_balance_armor_regenstable;
1635                 limith = autocvar_g_balance_health_limit;
1636                 limita = autocvar_g_balance_armor_limit;
1637
1638                 max_mod = regen_mod_max;
1639                 regen_mod = regen_mod_regen;
1640                 rot_mod = regen_mod_rot;
1641                 limit_mod = regen_mod_limit;
1642
1643                 maxh = maxh * max_mod;
1644                 minh = minh * max_mod;
1645                 limith = limith * limit_mod;
1646                 limita = limita * limit_mod;
1647
1648                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1649                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1650         }
1651
1652         // if player rotted to death...  die!
1653         // check this outside above checks, as player may still be able to rot to death
1654         if(self.health < 1)
1655                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1656
1657         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1658         {
1659                 float minf, maxf, limitf;
1660
1661                 maxf = autocvar_g_balance_fuel_rotstable;
1662                 minf = autocvar_g_balance_fuel_regenstable;
1663                 limitf = autocvar_g_balance_fuel_limit;
1664
1665                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1666         }
1667 }
1668
1669 float zoomstate_set;
1670 void SetZoomState(float z)
1671 {
1672         if(z != self.zoomstate)
1673         {
1674                 self.zoomstate = z;
1675                 ClientData_Touch(self);
1676         }
1677         zoomstate_set = 1;
1678 }
1679
1680 void GetPressedKeys(void) {
1681         MUTATOR_CALLHOOK(GetPressedKeys);
1682         if (self.movement.x > 0) // get if movement keys are pressed
1683         {       // forward key pressed
1684                 self.pressedkeys |= KEY_FORWARD;
1685                 self.pressedkeys &= ~KEY_BACKWARD;
1686         }
1687         else if (self.movement.x < 0)
1688         {       // backward key pressed
1689                 self.pressedkeys |= KEY_BACKWARD;
1690                 self.pressedkeys &= ~KEY_FORWARD;
1691         }
1692         else
1693         {       // no x input
1694                 self.pressedkeys &= ~KEY_FORWARD;
1695                 self.pressedkeys &= ~KEY_BACKWARD;
1696         }
1697
1698         if (self.movement.y > 0)
1699         {       // right key pressed
1700                 self.pressedkeys |= KEY_RIGHT;
1701                 self.pressedkeys &= ~KEY_LEFT;
1702         }
1703         else if (self.movement.y < 0)
1704         {       // left key pressed
1705                 self.pressedkeys |= KEY_LEFT;
1706                 self.pressedkeys &= ~KEY_RIGHT;
1707         }
1708         else
1709         {       // no y input
1710                 self.pressedkeys &= ~KEY_RIGHT;
1711                 self.pressedkeys &= ~KEY_LEFT;
1712         }
1713
1714         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1715                 self.pressedkeys |= KEY_JUMP;
1716         else
1717                 self.pressedkeys &= ~KEY_JUMP;
1718         if (self.BUTTON_CROUCH)
1719                 self.pressedkeys |= KEY_CROUCH;
1720         else
1721                 self.pressedkeys &= ~KEY_CROUCH;
1722
1723         if (self.BUTTON_ATCK)
1724                 self.pressedkeys |= KEY_ATCK;
1725         else
1726                 self.pressedkeys &= ~KEY_ATCK;
1727         if (self.BUTTON_ATCK2)
1728                 self.pressedkeys |= KEY_ATCK2;
1729         else
1730                 self.pressedkeys &= ~KEY_ATCK2;
1731 }
1732
1733 /*
1734 ======================
1735 spectate mode routines
1736 ======================
1737 */
1738
1739 void SpectateCopy(entity spectatee) {
1740         other = spectatee;
1741         MUTATOR_CALLHOOK(SpectateCopy);
1742         self.armortype = spectatee.armortype;
1743         self.armorvalue = spectatee.armorvalue;
1744         self.ammo_cells = spectatee.ammo_cells;
1745         self.ammo_plasma = spectatee.ammo_plasma;
1746         self.ammo_shells = spectatee.ammo_shells;
1747         self.ammo_nails = spectatee.ammo_nails;
1748         self.ammo_rockets = spectatee.ammo_rockets;
1749         self.ammo_fuel = spectatee.ammo_fuel;
1750         self.clip_load = spectatee.clip_load;
1751         self.clip_size = spectatee.clip_size;
1752         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1753         self.health = spectatee.health;
1754         self.impulse = 0;
1755         self.items = spectatee.items;
1756         self.last_pickup = spectatee.last_pickup;
1757         self.hit_time = spectatee.hit_time;
1758         self.metertime = spectatee.metertime;
1759         self.strength_finished = spectatee.strength_finished;
1760         self.invincible_finished = spectatee.invincible_finished;
1761         self.pressedkeys = spectatee.pressedkeys;
1762         self.weapons = spectatee.weapons;
1763         self.switchweapon = spectatee.switchweapon;
1764         self.switchingweapon = spectatee.switchingweapon;
1765         self.weapon = spectatee.weapon;
1766         self.vortex_charge = spectatee.vortex_charge;
1767         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1768         self.hagar_load = spectatee.hagar_load;
1769         self.arc_heat_percent = spectatee.arc_heat_percent;
1770         self.minelayer_mines = spectatee.minelayer_mines;
1771         self.punchangle = spectatee.punchangle;
1772         self.view_ofs = spectatee.view_ofs;
1773         self.velocity = spectatee.velocity;
1774         self.dmg_take = spectatee.dmg_take;
1775         self.dmg_save = spectatee.dmg_save;
1776         self.dmg_inflictor = spectatee.dmg_inflictor;
1777         self.v_angle = spectatee.v_angle;
1778         self.angles = spectatee.v_angle;
1779         self.frozen = spectatee.frozen;
1780         self.revive_progress = spectatee.revive_progress;
1781         if(!self.BUTTON_USE)
1782                 self.fixangle = true;
1783         setorigin(self, spectatee.origin);
1784         setsize(self, spectatee.mins, spectatee.maxs);
1785         SetZoomState(spectatee.zoomstate);
1786
1787     anticheat_spectatecopy(spectatee);
1788         self.hud = spectatee.hud;
1789         if(spectatee.vehicle)
1790     {
1791         self.fixangle = false;
1792         //self.velocity = spectatee.vehicle.velocity;
1793         self.vehicle_health = spectatee.vehicle_health;
1794         self.vehicle_shield = spectatee.vehicle_shield;
1795         self.vehicle_energy = spectatee.vehicle_energy;
1796         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1797         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1798         self.vehicle_reload1 = spectatee.vehicle_reload1;
1799         self.vehicle_reload2 = spectatee.vehicle_reload2;
1800
1801         msg_entity = self;
1802
1803         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1804             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1805             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1806             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1807
1808         //WriteByte (MSG_ONE, SVC_SETVIEW);
1809         //    WriteEntity(MSG_ONE, self);
1810         //makevectors(spectatee.v_angle);
1811         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1812     }
1813 }
1814
1815 float SpectateUpdate()
1816 {
1817         if(!self.enemy)
1818             return 0;
1819
1820         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1821         {
1822                 SetSpectator(self, world);
1823                 return 0;
1824         }
1825
1826         SpectateCopy(self.enemy);
1827
1828         return 1;
1829 }
1830
1831 float SpectateSet()
1832 {
1833         if(self.enemy.classname != "player")
1834                 return false;
1835         /*if(self.enemy.vehicle)
1836         {
1837
1838                 msg_entity = self;
1839                 WriteByte(MSG_ONE, SVC_SETVIEW);
1840                 WriteEntity(MSG_ONE, self.enemy);
1841                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1842
1843                 self.movetype = MOVETYPE_NONE;
1844                 accuracy_resend(self);
1845         }
1846         else
1847         {*/
1848                 msg_entity = self;
1849                 WriteByte(MSG_ONE, SVC_SETVIEW);
1850                 WriteEntity(MSG_ONE, self.enemy);
1851                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1852                 self.movetype = MOVETYPE_NONE;
1853                 accuracy_resend(self);
1854
1855                 if(!SpectateUpdate())
1856                         PutObserverInServer();
1857         //}
1858         return true;
1859 }
1860
1861 void SetSpectator(entity player, entity spectatee)
1862 {
1863         entity old_spectatee = player.enemy;
1864
1865         player.enemy = spectatee;
1866
1867         // WEAPONTODO
1868         // these are required to fix the spectator bug with arc
1869         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1870         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1871 }
1872
1873 float Spectate(entity pl)
1874 {
1875         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1876         if(pl.team != self.team)
1877                 return 0;
1878
1879         SetSpectator(self, pl);
1880         return SpectateSet();
1881 }
1882
1883 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1884 entity CA_SpectateNext(entity start) {
1885         if (start.team == self.team) {
1886                 return start;
1887         }
1888
1889         other = start;
1890         // continue from current player
1891         while(other && other.team != self.team) {
1892                 other = find(other, classname, "player");
1893         }
1894
1895         if (!other) {
1896                 // restart from begining
1897                 other = find(other, classname, "player");
1898                 while(other && other.team != self.team) {
1899                         other = find(other, classname, "player");
1900                 }
1901         }
1902
1903         return other;
1904 }
1905
1906 float SpectateNext()
1907 {
1908         other = find(self.enemy, classname, "player");
1909
1910         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1911                 // CA and ca players when spectating enemies is forbidden
1912                 other = CA_SpectateNext(other);
1913         } else {
1914                 // other modes and ca spectators or spectating enemies is allowed
1915                 if (!other)
1916                         other = find(other, classname, "player");
1917         }
1918
1919         if(other) { SetSpectator(self, other); }
1920
1921         return SpectateSet();
1922 }
1923
1924 float SpectatePrev()
1925 {
1926         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1927         other = findchain(classname, "player");
1928         if (!other) // no player
1929                 return false;
1930
1931         entity first = other;
1932         // skip players until current spectated player
1933         if(self.enemy)
1934         while(other && other != self.enemy)
1935                 other = other.chain;
1936
1937         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1938         {
1939                 do { other = other.chain; }
1940                 while(other && other.team != self.team);
1941
1942                 if (!other)
1943                 {
1944                         other = first;
1945                         while(other.team != self.team)
1946                                 other = other.chain;
1947                         if(other == self.enemy)
1948                                 return true;
1949                 }
1950         }
1951         else
1952         {
1953                 if(other.chain)
1954                         other = other.chain;
1955                 else
1956                         other = first;
1957         }
1958         SetSpectator(self, other);
1959         return SpectateSet();
1960 }
1961
1962 /*
1963 =============
1964 ShowRespawnCountdown()
1965
1966 Update a respawn countdown display.
1967 =============
1968 */
1969 void ShowRespawnCountdown()
1970 {
1971         float number;
1972         if(self.deadflag == DEAD_NO) // just respawned?
1973                 return;
1974         else
1975         {
1976                 number = ceil(self.respawn_time - time);
1977                 if(number <= 0)
1978                         return;
1979                 if(number <= self.respawn_countdown)
1980                 {
1981                         self.respawn_countdown = number - 1;
1982                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1983                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1984                 }
1985         }
1986 }
1987
1988 void LeaveSpectatorMode()
1989 {
1990         if(self.caplayer)
1991                 return;
1992         if(nJoinAllowed(self))
1993         {
1994                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1995                 {
1996                         self.classname = "player";
1997                         nades_RemoveBonus(self);
1998
1999                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2000                                 { JoinBestTeam(self, false, true); }
2001
2002                         if(autocvar_g_campaign)
2003                                 { campaign_bots_may_start = 1; }
2004
2005                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2006
2007                         PutClientInServer();
2008
2009                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2010                 }
2011                 else
2012                         stuffcmd(self, "menu_showteamselect\n");
2013         }
2014         else
2015         {
2016                 // Player may not join because g_maxplayers is set
2017                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2018         }
2019 }
2020
2021 /**
2022  * Determines whether the player is allowed to join. This depends on cvar
2023  * g_maxplayers, if it isn't used this function always return true, otherwise
2024  * it checks whether the number of currently playing players exceeds g_maxplayers.
2025  * @return int number of free slots for players, 0 if none
2026  */
2027 float nJoinAllowed(entity ignore) {
2028         if(!ignore)
2029         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2030         // so report 0 free slots if restricted
2031         {
2032                 if(autocvar_g_forced_team_otherwise == "spectate")
2033                         return 0;
2034                 if(autocvar_g_forced_team_otherwise == "spectator")
2035                         return 0;
2036         }
2037
2038         if(self.team_forced < 0)
2039                 return 0; // forced spectators can never join
2040
2041         // TODO simplify this
2042         entity e;
2043         float totalClients = 0;
2044         FOR_EACH_CLIENT(e)
2045                 if(e != ignore)
2046                         totalClients += 1;
2047
2048         if (!autocvar_g_maxplayers)
2049                 return maxclients - totalClients;
2050
2051         float currentlyPlaying = 0;
2052         FOR_EACH_REALCLIENT(e)
2053                 if(IS_PLAYER(e) || e.caplayer)
2054                         currentlyPlaying += 1;
2055
2056         if(currentlyPlaying < autocvar_g_maxplayers)
2057                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2058
2059         return 0;
2060 }
2061
2062 /**
2063  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2064  * g_maxplayers_spectator_blocktime seconds
2065  */
2066 void checkSpectatorBlock() {
2067         if(IS_SPEC(self) || IS_OBSERVER(self))
2068         if(!self.caplayer)
2069         if(IS_REAL_CLIENT(self))
2070         {
2071                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2072                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2073                         dropclient(self);
2074                 }
2075         }
2076 }
2077
2078 void PrintWelcomeMessage()
2079 {
2080         if(self.motd_actived_time == 0)
2081         {
2082                 if (autocvar_g_campaign) {
2083                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2084                                 self.motd_actived_time = time;
2085                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2086                         }
2087                 } else {
2088                         if (self.BUTTON_INFO) {
2089                                 self.motd_actived_time = time;
2090                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2091                         }
2092                 }
2093         }
2094         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2095         {
2096                 if (autocvar_g_campaign) {
2097                         if (self.BUTTON_INFO)
2098                                 self.motd_actived_time = time;
2099                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2100                                 self.motd_actived_time = 0;
2101                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2102                         }
2103                 } else {
2104                         if (self.BUTTON_INFO)
2105                                 self.motd_actived_time = time;
2106                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2107                                 self.motd_actived_time = 0;
2108                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2109                         }
2110                 }
2111         }
2112         else //if(self.motd_actived_time < 0) // just connected, motd is active
2113         {
2114                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2115                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2116                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2117                 {
2118                         // instanctly hide MOTD
2119                         self.motd_actived_time = 0;
2120                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2121                 }
2122         }
2123 }
2124
2125 void ObserverThink()
2126 {
2127         float prefered_movetype;
2128         if (self.flags & FL_JUMPRELEASED) {
2129                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2130                         self.flags &= ~FL_JUMPRELEASED;
2131                         self.flags |= FL_SPAWNING;
2132                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2133                         self.flags &= ~FL_JUMPRELEASED;
2134                         if(SpectateNext()) {
2135                                 self.classname = "spectator";
2136                         }
2137                 } else {
2138                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2139                         if (self.movetype != prefered_movetype)
2140                                 self.movetype = prefered_movetype;
2141                 }
2142         } else {
2143                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2144                         self.flags |= FL_JUMPRELEASED;
2145                         if(self.flags & FL_SPAWNING)
2146                         {
2147                                 self.flags &= ~FL_SPAWNING;
2148                                 LeaveSpectatorMode();
2149                                 return;
2150                         }
2151                 }
2152         }
2153 }
2154
2155 void SpectatorThink()
2156 {
2157         if (self.flags & FL_JUMPRELEASED) {
2158                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2159                         self.flags &= ~FL_JUMPRELEASED;
2160                         self.flags |= FL_SPAWNING;
2161                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2162                         self.flags &= ~FL_JUMPRELEASED;
2163                         if(SpectateNext()) {
2164                                 self.classname = "spectator";
2165                         } else {
2166                                 self.classname = "observer";
2167                                 PutClientInServer();
2168                         }
2169                         self.impulse = 0;
2170                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2171                         self.flags &= ~FL_JUMPRELEASED;
2172                         if(SpectatePrev()) {
2173                                 self.classname = "spectator";
2174                         } else {
2175                                 self.classname = "observer";
2176                                 PutClientInServer();
2177                         }
2178                         self.impulse = 0;
2179                 } else if (self.BUTTON_ATCK2) {
2180                         self.flags &= ~FL_JUMPRELEASED;
2181                         self.classname = "observer";
2182                         PutClientInServer();
2183                 } else {
2184                         if(!SpectateUpdate())
2185                                 PutObserverInServer();
2186                 }
2187         } else {
2188                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2189                         self.flags |= FL_JUMPRELEASED;
2190                         if(self.flags & FL_SPAWNING)
2191                         {
2192                                 self.flags &= ~FL_SPAWNING;
2193                                 LeaveSpectatorMode();
2194                                 return;
2195                         }
2196                 }
2197                 if(!SpectateUpdate())
2198                         PutObserverInServer();
2199         }
2200
2201         self.flags |= FL_CLIENT | FL_NOTARGET;
2202 }
2203
2204 void PlayerUseKey()
2205 {
2206         if (!IS_PLAYER(self))
2207                 return;
2208
2209         if(self.vehicle)
2210         {
2211         vehicles_exit(VHEF_NORMAL);
2212         return;
2213         }
2214
2215         // a use key was pressed; call handlers
2216         MUTATOR_CALLHOOK(PlayerUseKey);
2217 }
2218
2219 float isInvisibleString(string s)
2220 {
2221         float i, n, c;
2222         s = strdecolorize(s);
2223         for((i = 0), (n = strlen(s)); i < n; ++i)
2224         {
2225                 c = str2chr(s, i);
2226                 switch(c)
2227                 {
2228                         case 0:
2229                         case 32: // space
2230                                 break;
2231                         case 192: // charmap space
2232                                 if (!autocvar_utf8_enable)
2233                                         break;
2234                                 return false;
2235                         case 160: // space in unicode fonts
2236                         case 0xE000 + 192: // utf8 charmap space
2237                                 if (autocvar_utf8_enable)
2238                                         break;
2239                         default:
2240                                 return false;
2241                 }
2242         }
2243         return true;
2244 }
2245
2246 /*
2247 =============
2248 PlayerPreThink
2249
2250 Called every frame for each client before the physics are run
2251 =============
2252 */
2253 .float usekeypressed;
2254 void() nexball_setstatus;
2255 .int items_added;
2256 void PlayerPreThink (void)
2257 {
2258         WarpZone_PlayerPhysics_FixVAngle();
2259
2260         self.stat_game_starttime = game_starttime;
2261         self.stat_round_starttime = round_starttime;
2262         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2263         self.stat_leadlimit = autocvar_leadlimit;
2264
2265         if(frametime)
2266         {
2267                 // physics frames: update anticheat stuff
2268                 anticheat_prethink();
2269         }
2270
2271         if(blockSpectators && frametime)
2272                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2273                 checkSpectatorBlock();
2274
2275         zoomstate_set = 0;
2276
2277         // Savage: Check for nameless players
2278         if (isInvisibleString(self.netname)) {
2279                 string new_name = strzone(strcat("Player@", self.netaddress));
2280                 if(autocvar_sv_eventlog)
2281                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2282                 if(self.netname_previous)
2283                         strunzone(self.netname_previous);
2284                 self.netname_previous = strzone(new_name);
2285                 self.netname = self.netname_previous;
2286                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2287         } else if(self.netname_previous != self.netname) {
2288                 if(autocvar_sv_eventlog)
2289                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2290                 if(self.netname_previous)
2291                         strunzone(self.netname_previous);
2292                 self.netname_previous = strzone(self.netname);
2293         }
2294
2295         // version nagging
2296         if(self.version_nagtime)
2297                 if(self.cvar_g_xonoticversion)
2298                         if(time > self.version_nagtime)
2299                         {
2300                                 // don't notify git users
2301                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2302                                 {
2303                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2304                                         {
2305                                                 // notify release users if connecting to git
2306                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2307                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2308                                         }
2309                                         else
2310                                         {
2311                                                 float r;
2312                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2313                                                 if(r < 0)
2314                                                 {
2315                                                         // give users new version
2316                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2317                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2318                                                 }
2319                                                 else if(r > 0)
2320                                                 {
2321                                                         // notify users about old server version
2322                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2323                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2324                                                 }
2325                                         }
2326                                 }
2327                                 self.version_nagtime = 0;
2328                         }
2329
2330         // GOD MODE info
2331         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2332         {
2333                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2334                 self.max_armorvalue = 0;
2335         }
2336
2337 #ifdef TETRIS
2338         if (TetrisPreFrame())
2339                 return;
2340 #endif
2341
2342         if(self.frozen == 2)
2343         {
2344                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2345                 self.health = max(1, self.revive_progress * start_health);
2346                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2347
2348                 if(self.revive_progress >= 1)
2349                         Unfreeze(self);
2350         }
2351         else if(self.frozen == 3)
2352         {
2353                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2354                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2355
2356                 if(self.health < 1)
2357                 {
2358                         if(self.vehicle)
2359                                 vehicles_exit(VHEF_RELESE);
2360                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2361                 }
2362                 else if ( self.revive_progress <= 0 )
2363                         Unfreeze(self);
2364         }
2365
2366         MUTATOR_CALLHOOK(PlayerPreThink);
2367
2368         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2369         {
2370                 if(self.BUTTON_USE && !self.usekeypressed)
2371                         PlayerUseKey();
2372                 self.usekeypressed = self.BUTTON_USE;
2373         }
2374
2375         if(IS_REAL_CLIENT(self))
2376                 PrintWelcomeMessage();
2377
2378         if(IS_PLAYER(self))
2379         {
2380
2381                 CheckRules_Player();
2382
2383                 if (intermission_running)
2384                 {
2385                         IntermissionThink ();   // otherwise a button could be missed between
2386                         return;                                 // the think tics
2387                 }
2388
2389                 //don't allow the player to turn around while game is paused!
2390                 if(timeout_status == TIMEOUT_ACTIVE) {
2391                         // FIXME turn this into CSQC stuff
2392                         self.v_angle = self.lastV_angle;
2393                         self.angles = self.lastV_angle;
2394                         self.fixangle = true;
2395                 }
2396
2397                 if(frametime)
2398                 {
2399                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2400                         {
2401                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2402                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2403                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2404
2405                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2406                                 {
2407                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2408                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2409                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2410                                 }
2411                         }
2412                         else
2413                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2414
2415                         player_powerups();
2416                 }
2417
2418                 if (self.deadflag != DEAD_NO)
2419                 {
2420                         if(self.personal && g_race_qualifying)
2421                         {
2422                                 if(time > self.respawn_time)
2423                                 {
2424                                         self.respawn_time = time + 1; // only retry once a second
2425                                         self.stat_respawn_time = self.respawn_time;
2426                                         respawn();
2427                                         self.impulse = 141;
2428                                 }
2429                         }
2430                         else
2431                         {
2432                                 float button_pressed;
2433                                 if(frametime)
2434                                         player_anim();
2435                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2436
2437                                 if (self.deadflag == DEAD_DYING)
2438                                 {
2439                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2440                                                 self.deadflag = DEAD_RESPAWNING;
2441                                         else if(!button_pressed)
2442                                                 self.deadflag = DEAD_DEAD;
2443                                 }
2444                                 else if (self.deadflag == DEAD_DEAD)
2445                                 {
2446                                         if(button_pressed)
2447                                                 self.deadflag = DEAD_RESPAWNABLE;
2448                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2449                                                 self.deadflag = DEAD_RESPAWNING;
2450                                 }
2451                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2452                                 {
2453                                         if(!button_pressed)
2454                                                 self.deadflag = DEAD_RESPAWNING;
2455                                 }
2456                                 else if (self.deadflag == DEAD_RESPAWNING)
2457                                 {
2458                                         if(time > self.respawn_time)
2459                                         {
2460                                                 self.respawn_time = time + 1; // only retry once a second
2461                                                 self.respawn_time_max = self.respawn_time;
2462                                                 respawn();
2463                                         }
2464                                 }
2465
2466                                 ShowRespawnCountdown();
2467
2468                                 if(self.respawn_flags & RESPAWN_SILENT)
2469                                         self.stat_respawn_time = 0;
2470                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2471                                         self.stat_respawn_time = self.respawn_time_max;
2472                                 else
2473                                         self.stat_respawn_time = self.respawn_time;
2474                         }
2475
2476                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2477                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2478                                 self.stat_respawn_time *= -1;
2479
2480                         return;
2481                 }
2482
2483                 self.prevorigin = self.origin;
2484
2485                 float do_crouch = self.BUTTON_CROUCH;
2486                 if(self.hook.state)
2487                         do_crouch = 0;
2488                 if(self.vehicle)
2489                         do_crouch = 0;
2490                 if(self.frozen)
2491                         do_crouch = 0;
2492
2493                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2494                 // It cannot be predicted by the engine!
2495                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2496                         do_crouch = 0;
2497
2498                 if (do_crouch)
2499                 {
2500                         if (!self.crouch)
2501                         {
2502                                 self.crouch = true;
2503                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2504                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2505                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2506                         }
2507                 }
2508                 else
2509                 {
2510                         if (self.crouch)
2511                         {
2512                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2513                                 if (!trace_startsolid)
2514                                 {
2515                                         self.crouch = false;
2516                                         self.view_ofs = PL_VIEW_OFS;
2517                                         setsize (self, PL_MIN, PL_MAX);
2518                                 }
2519                         }
2520                 }
2521
2522                 FixPlayermodel();
2523
2524                 GrapplingHookFrame();
2525
2526                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2527                 //if(frametime)
2528                 {
2529                         self.items &= ~self.items_added;
2530
2531                         W_WeaponFrame();
2532
2533                         self.items_added = 0;
2534                         if(self.items & IT_JETPACK)
2535                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2536                                         self.items_added |= IT_FUEL;
2537
2538                         self.items |= self.items_added;
2539                 }
2540
2541                 player_regen();
2542
2543                 // WEAPONTODO: Add a weapon request for this
2544                 // rot vortex charge to the charge limit
2545                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2546                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2547
2548                 if(frametime)
2549                         player_anim();
2550
2551                 // secret status
2552                 secrets_setstatus();
2553
2554                 // monsters status
2555                 monsters_setstatus();
2556
2557                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2558
2559                 //self.angles_y=self.v_angle_y + 90;   // temp
2560         } else if(gameover) {
2561                 if (intermission_running)
2562                         IntermissionThink ();   // otherwise a button could be missed between
2563                 return;
2564         } else if(IS_OBSERVER(self)) {
2565                 ObserverThink();
2566         } else if(IS_SPEC(self)) {
2567                 SpectatorThink();
2568         }
2569
2570         // WEAPONTODO: Add weapon request for this
2571         if(!zoomstate_set)
2572                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2573
2574         float oldspectatee_status;
2575         oldspectatee_status = self.spectatee_status;
2576         if(IS_SPEC(self))
2577                 self.spectatee_status = num_for_edict(self.enemy);
2578         else if(IS_OBSERVER(self))
2579                 self.spectatee_status = num_for_edict(self);
2580         else
2581                 self.spectatee_status = 0;
2582         if(self.spectatee_status != oldspectatee_status)
2583         {
2584                 ClientData_Touch(self);
2585         }
2586
2587         if(self.teamkill_soundtime)
2588         if(time > self.teamkill_soundtime)
2589         {
2590                 self.teamkill_soundtime = 0;
2591
2592                 entity oldpusher, oldself;
2593
2594                 oldself = self; self = self.teamkill_soundsource;
2595                 oldpusher = self.pusher; self.pusher = oldself;
2596
2597                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2598
2599                 self.pusher = oldpusher;
2600                 self = oldself;
2601         }
2602
2603         if(self.taunt_soundtime)
2604         if(time > self.taunt_soundtime)
2605         {
2606                 self.taunt_soundtime = 0;
2607                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2608         }
2609
2610         target_voicescript_next(self);
2611
2612         // WEAPONTODO: Move into weaponsystem somehow
2613         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2614         if(!self.weapon)
2615                 self.clip_load = self.clip_size = 0;
2616 }
2617
2618 /*
2619 =============
2620 PlayerPostThink
2621
2622 Called every frame for each client after the physics are run
2623 =============
2624 */
2625 .float idlekick_lasttimeleft;
2626 void PlayerPostThink (void)
2627 {
2628         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2629         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2630         {
2631                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2632                 {
2633                         if(self.idlekick_lasttimeleft)
2634                         {
2635                                 self.idlekick_lasttimeleft = 0;
2636                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2637                         }
2638                 }
2639                 else
2640                 {
2641                         float timeleft;
2642                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2643                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2644                         {
2645                                 if(!self.idlekick_lasttimeleft)
2646                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2647                         }
2648                         if(timeleft <= 0)
2649                         {
2650                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2651                                 dropclient(self);
2652                                 return;
2653                         }
2654                         else if(timeleft <= 10)
2655                         {
2656                                 if(timeleft != self.idlekick_lasttimeleft)
2657                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2658                                 self.idlekick_lasttimeleft = timeleft;
2659                         }
2660                 }
2661         }
2662
2663 #ifdef TETRIS
2664         if(self.impulse == 100)
2665                 ImpulseCommands();
2666         if (!TetrisPostFrame())
2667         {
2668 #endif
2669
2670         CheatFrame();
2671
2672         //CheckPlayerJump();
2673
2674         if(IS_PLAYER(self)) {
2675                 CheckRules_Player();
2676                 UpdateChatBubble();
2677                 if (self.impulse)
2678                         ImpulseCommands();
2679                 if (intermission_running)
2680                         return;         // intermission or finale
2681                 GetPressedKeys();
2682         }
2683
2684 #ifdef TETRIS
2685         }
2686 #endif
2687
2688         /*
2689         float i;
2690         for(i = 0; i < 1000; ++i)
2691         {
2692                 vector end;
2693                 end = self.origin + '0 0 1024' + 512 * randomvec();
2694                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2695                 if(trace_fraction < 1)
2696                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2697                 {
2698                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2699                         break;
2700                 }
2701         }
2702         */
2703
2704         if(self.waypointsprite_attachedforcarrier)
2705                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2706
2707         playerdemo_write();
2708
2709         CSQCMODEL_AUTOUPDATE();
2710 }