qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 if(!inWarmupStage)
 414                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419                 vehicles_exit(VHEF_RELESE);
 420
 421         WaypointSprite_PlayerDead();
 422
 423         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 424                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 425
 426         if(self.killcount != -666) {
 427                 if(g_lms) {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 } else
 433                         bprint ("^4", self.netname, "^4 is spectating now\n");
 434
 435                 if(self.just_joined == FALSE) {
 436                         LogTeamchange(self.playerid, -1, 4);
 437                 } else
 438                         self.just_joined = FALSE;
 439         }
 440
 441         PlayerScore_Clear(self); // clear scores when needed
 442
 443         accuracy_resend(self);
 444
 445         self.spectatortime = time;
 446
 447         self.classname = "observer";
 448         self.iscreature = FALSE;
 449         self.teleportable = TELEPORT_SIMPLE;
 450         self.damagedbycontents = FALSE;
 451         self.health = -666;
 452         self.takedamage = DAMAGE_NO;
 453         self.solid = SOLID_NOT;
 454         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 455         self.flags = FL_CLIENT | FL_NOTARGET;
 456         self.armorvalue = 666;
 457         self.effects = 0;
 458         self.armorvalue = autocvar_g_balance_armor_start;
 459         self.pauserotarmor_finished = 0;
 460         self.pauserothealth_finished = 0;
 461         self.pauseregen_finished = 0;
 462         self.damageforcescale = 0;
 463         self.death_time = 0;
 464         self.respawn_time = 0;
 465         self.alpha = 0;
 466         self.scale = 0;
 467         self.fade_time = 0;
 468         self.pain_frame = 0;
 469         self.pain_finished = 0;
 470         self.strength_finished = 0;
 471         self.invincible_finished = 0;
 472         self.superweapons_finished = 0;
 473         self.pushltime = 0;
 474         self.istypefrag = 0;
 475         self.think = func_null;
 476         self.nextthink = 0;
 477         self.hook_time = 0;
 478         self.runes = 0;
 479         self.deadflag = DEAD_NO;
 480         self.angles = spot.angles;
 481         self.angles_z = 0;
 482         self.fixangle = TRUE;
 483         self.crouch = FALSE;
 484
 485         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 486         self.prevorigin = self.origin;
 487         self.items = 0;
 488         WEPSET_CLEAR_E(self);
 489         self.model = "";
 490         FixPlayermodel();
 491         setmodel(self, "null");
 492         self.drawonlytoclient = self;
 493
 494         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 495         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 496
 497         self.weapon = 0;
 498         self.weaponname = "";
 499         self.switchingweapon = 0;
 500         self.weaponmodel = "";
 501         self.weaponentity = world;
 502         self.exteriorweaponentity = world;
 503         self.killcount = -666;
 504         self.velocity = '0 0 0';
 505         self.avelocity = '0 0 0';
 506         self.punchangle = '0 0 0';
 507         self.punchvector = '0 0 0';
 508         self.oldvelocity = self.velocity;
 509         self.fire_endtime = -1;
 510
 511         if(g_arena)
 512         {
 513                 if(self.version_mismatch)
 514                 {
 515                         self.frags = FRAGS_SPECTATOR;
 516                         Spawnqueue_Unmark(self);
 517                         Spawnqueue_Remove(self);
 518                 }
 519                 else
 520                 {
 521                         self.frags = FRAGS_LMS_LOSER;
 522                         Spawnqueue_Insert(self);
 523                 }
 524         }
 525         else if(g_lms)
 526         {
 527                 // Only if the player cannot play at all
 528                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 529                         self.frags = FRAGS_SPECTATOR;
 530                 else
 531                         self.frags = FRAGS_LMS_LOSER;
 532         }
 533         else if(g_ca)
 534         {
 535                 if(self.caplayer)
 536                         self.frags = FRAGS_LMS_LOSER;
 537                 else
 538                         self.frags = FRAGS_SPECTATOR;
 539         }
 540         else if((g_race && g_race_qualifying) || g_cts)
 541         {
 542                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 543                         self.frags = FRAGS_LMS_LOSER;
 544                 else
 545                         self.frags = FRAGS_SPECTATOR;
 546         }
 547         else
 548                 self.frags = FRAGS_SPECTATOR;
 549 }
 550
 551 .float model_randomizer;
 552 void FixPlayermodel()
 553 {
 554         string defaultmodel;
 555         float defaultskin, chmdl, oldskin, n, i;
 556         vector m1, m2;
 557
 558         defaultmodel = "";
 559         defaultskin = 0;
 560         chmdl = FALSE;
 561
 562         if(autocvar_sv_defaultcharacter == 1)
 563         {
 564                 if(teamplay)
 565                 {
 566                         string s;
 567                         s = Team_ColorNameLowerCase(self.team);
 568                         if(s != "neutral")
 569                         {
 570                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 571                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 572                         }
 573                 }
 574
 575                 if(defaultmodel == "")
 576                 {
 577                         defaultmodel = autocvar_sv_defaultplayermodel;
 578                         defaultskin = autocvar_sv_defaultplayerskin;
 579                 }
 580
 581                 n = tokenize_console(defaultmodel);
 582                 if(n > 0)
 583                         defaultmodel = argv(floor(n * self.model_randomizer));
 584
 585                 i = strstrofs(defaultmodel, ":", 0);
 586                 if(i >= 0)
 587                 {
 588                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 589                         defaultmodel = substring(defaultmodel, 0, i);
 590                 }
 591         }
 592
 593         if(defaultmodel != "")
 594         {
 595                 if (defaultmodel != self.model)
 596                 {
 597                         m1 = self.mins;
 598                         m2 = self.maxs;
 599                         setplayermodel (self, defaultmodel);
 600                         setsize (self, m1, m2);
 601                         chmdl = TRUE;
 602                 }
 603
 604                 oldskin = self.skin;
 605                 self.skin = defaultskin;
 606         } else {
 607                 if (self.playermodel != self.model || self.playermodel == "")
 608                 {
 609                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 610                         m1 = self.mins;
 611                         m2 = self.maxs;
 612                         setplayermodel (self, self.playermodel);
 613                         setsize (self, m1, m2);
 614                         chmdl = TRUE;
 615                 }
 616
 617                 oldskin = self.skin;
 618                 self.skin = stof(self.playerskin);
 619         }
 620
 621         if(chmdl || oldskin != self.skin) // model or skin has changed
 622         {
 623                 self.species = player_getspecies(); // update species
 624                 UpdatePlayerSounds(); // update skin sounds
 625         }
 626
 627         if(!teamplay)
 628                 if(strlen(autocvar_sv_defaultplayercolors))
 629                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 630                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 631 }
 632
 633 void PlayerTouchExplode(entity p1, entity p2)
 634 {
 635         vector org;
 636         org = (p1.origin + p2.origin) * 0.5;
 637         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 638
 639         te_explosion(org);
 640
 641         entity e;
 642         e = spawn();
 643         setorigin(e, org);
 644         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 645         remove(e);
 646 }
 647
 648 /*
 649 =============
 650 PutClientInServer
 651
 652 Called when a client spawns in the server
 653 =============
 654 */
 655
 656 void PutClientInServer (void)
 657 {
 658         if(clienttype(self) == CLIENTTYPE_BOT)
 659         {
 660                 self.classname = "player";
 661                 if(g_ca)
 662                         self.caplayer = 1;
 663         }
 664         else if(clienttype(self) == CLIENTTYPE_REAL)
 665         {
 666                 msg_entity = self;
 667                 WriteByte(MSG_ONE, SVC_SETVIEW);
 668                 WriteEntity(MSG_ONE, self);
 669         }
 670
 671         // reset player keys
 672         self.itemkeys = 0;
 673
 674         // player is dead and becomes observer
 675         // FIXME fix LMS scoring for new system
 676         if(g_lms)
 677         {
 678                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 679                         self.classname = "observer";
 680         }
 681
 682         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 683                 self.classname = "observer";
 684
 685         if(gameover)
 686                 self.classname = "observer";
 687
 688         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 689                 entity spot, oldself;
 690                 float j;
 691
 692                 accuracy_resend(self);
 693
 694                 if(self.team < 0)
 695                         JoinBestTeam(self, FALSE, TRUE);
 696
 697                 race_PreSpawn();
 698
 699                 spot = SelectSpawnPoint (FALSE);
 700                 if(!spot)
 701                 {
 702                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 703                         return; // spawn failed
 704                 }
 705
 706                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 707
 708                 self.classname = "player";
 709                 self.wasplayer = TRUE;
 710                 self.iscreature = TRUE;
 711                 self.teleportable = TELEPORT_NORMAL;
 712                 self.damagedbycontents = TRUE;
 713                 self.movetype = MOVETYPE_WALK;
 714                 self.solid = SOLID_SLIDEBOX;
 715                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 716                 if(autocvar_g_playerclip_collisions)
 717                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 718                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 719                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 720                 self.frags = FRAGS_PLAYER;
 721                 if(INDEPENDENT_PLAYERS)
 722                         MAKE_INDEPENDENT_PLAYER(self);
 723                 self.flags = FL_CLIENT;
 724                 if(autocvar__notarget)
 725                         self.flags |= FL_NOTARGET;
 726                 self.takedamage = DAMAGE_AIM;
 727                 if(g_minstagib)
 728                         self.effects = EF_FULLBRIGHT;
 729                 else
 730                         self.effects = 0;
 731                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 732                 self.air_finished = time + 12;
 733                 self.dmg = 2;
 734                 if(autocvar_g_balance_nex_charge)
 735                 {
 736                         if(autocvar_g_balance_nex_secondary_chargepool)
 737                                 self.nex_chargepool_ammo = 1;
 738                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 739                 }
 740
 741                 if(inWarmupStage)
 742                 {
 743                         self.ammo_shells = warmup_start_ammo_shells;
 744                         self.ammo_nails = warmup_start_ammo_nails;
 745                         self.ammo_rockets = warmup_start_ammo_rockets;
 746                         self.ammo_cells = warmup_start_ammo_cells;
 747                         self.ammo_fuel = warmup_start_ammo_fuel;
 748                         self.health = warmup_start_health;
 749                         self.armorvalue = warmup_start_armorvalue;
 750                         WEPSET_COPY_EA(self, warmup_start_weapons);
 751                 }
 752                 else
 753                 {
 754                         self.ammo_shells = start_ammo_shells;
 755                         self.ammo_nails = start_ammo_nails;
 756                         self.ammo_rockets = start_ammo_rockets;
 757                         self.ammo_cells = start_ammo_cells;
 758                         self.ammo_fuel = start_ammo_fuel;
 759                         self.health = start_health;
 760                         self.armorvalue = start_armorvalue;
 761                         WEPSET_COPY_EA(self, start_weapons);
 762                 }
 763
 764                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 765                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 766                 else
 767                         self.superweapons_finished = 0;
 768
 769                 if(g_weaponarena_random)
 770                 {
 771                         if(g_weaponarena_random_with_laser)
 772                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 773                         W_RandomWeapons(self, g_weaponarena_random);
 774                         if(g_weaponarena_random_with_laser)
 775                                 WEPSET_OR_EW(self, WEP_LASER);
 776                 }
 777
 778                 self.items = start_items;
 779
 780                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 781                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 782                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 783                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 784                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 785                 //extend the pause of rotting if client was reset at the beginning of the countdown
 786                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 787                         self.spawnshieldtime += game_starttime - time;
 788                         self.pauserotarmor_finished += game_starttime - time;
 789                         self.pauserothealth_finished += game_starttime - time;
 790                         self.pauseregen_finished += game_starttime - time;
 791                 }
 792                 self.damageforcescale = 2;
 793                 self.death_time = 0;
 794                 self.respawn_time = 0;
 795                 self.scale = 0;
 796                 self.fade_time = 0;
 797                 self.pain_frame = 0;
 798                 self.pain_finished = 0;
 799                 self.strength_finished = 0;
 800                 self.invincible_finished = 0;
 801                 self.pushltime = 0;
 802                 // players have no think function
 803                 self.think = func_null;
 804                 self.nextthink = 0;
 805                 self.hook_time = 0;
 806                 self.dmg_team = 0;
 807                 self.ballistics_density = autocvar_g_ballistics_density_player;
 808
 809                 self.metertime = 0;
 810
 811                 self.runes = 0;
 812
 813                 self.deadflag = DEAD_NO;
 814
 815                 self.angles = spot.angles;
 816
 817                 self.angles_z = 0; // never spawn tilted even if the spot says to
 818                 self.fixangle = TRUE; // turn this way immediately
 819                 self.velocity = '0 0 0';
 820                 self.avelocity = '0 0 0';
 821                 self.punchangle = '0 0 0';
 822                 self.punchvector = '0 0 0';
 823                 self.oldvelocity = self.velocity;
 824                 self.fire_endtime = -1;
 825
 826                 msg_entity = self;
 827                 WRITESPECTATABLE_MSG_ONE({
 828                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 829                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 830                 });
 831
 832                 self.model = "";
 833                 FixPlayermodel();
 834                 self.drawonlytoclient = world;
 835
 836                 self.crouch = FALSE;
 837                 self.view_ofs = PL_VIEW_OFS;
 838                 setsize (self, PL_MIN, PL_MAX);
 839                 self.spawnorigin = spot.origin;
 840                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 841                 // don't reset back to last position, even if new position is stuck in solid
 842                 self.oldorigin = self.origin;
 843                 self.prevorigin = self.origin;
 844                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 845                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 846         self.hud = HUD_NORMAL;
 847
 848                 if(g_arena)
 849                 {
 850                         Spawnqueue_Remove(self);
 851                         Spawnqueue_Mark(self);
 852                 }
 853                 else if(g_ca)
 854                         self.caplayer = 1;
 855
 856                 self.event_damage = PlayerDamage;
 857
 858                 self.bot_attack = TRUE;
 859                 self.monster_attack = TRUE;
 860
 861                 self.statdraintime = time + 5;
 862                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 863
 864                 if(self.killcount == -666) {
 865                         PlayerScore_Clear(self);
 866                         self.killcount = 0;
 867                 }
 868
 869                 CL_SpawnWeaponentity();
 870                 self.alpha = default_player_alpha;
 871                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 872                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 873
 874                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 875                 self.lms_traveled_distance = 0;
 876                 self.speedrunning = FALSE;
 877
 878                 race_PostSpawn(spot);
 879
 880                 //stuffcmd(self, "chase_active 0");
 881                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 882
 883                 if(g_assault) {
 884                         if(self.team == assault_attacker_team)
 885                                 centerprint(self, "You are attacking!");
 886                         else
 887                                 centerprint(self, "You are defending!");
 888                 }
 889
 890                 target_voicescript_clear(self);
 891
 892                 // reset fields the weapons may use
 893                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 894                 {
 895                         weapon_action(j, WR_RESETPLAYER);
 896
 897                         // all weapons must be fully loaded when we spawn
 898                         entity e;
 899                         e = get_weaponinfo(j);
 900                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 901                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 902                 }
 903
 904                 oldself = self;
 905                 self = spot;
 906                         activator = oldself;
 907                                 string s;
 908                                 s = self.target;
 909                                 self.target = string_null;
 910                                 SUB_UseTargets();
 911                                 self.target = s;
 912                         activator = world;
 913                 self = oldself;
 914
 915                 Unfreeze(self);
 916
 917                 spawn_spot = spot;
 918                 MUTATOR_CALLHOOK(PlayerSpawn);
 919
 920                 if(autocvar_spawn_debug)
 921                 {
 922                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 923                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 924                 }
 925
 926                 self.switchweapon = w_getbestweapon(self);
 927                 self.cnt = -1; // W_LastWeapon will not complain
 928                 self.weapon = 0;
 929                 self.weaponname = "";
 930                 self.switchingweapon = 0;
 931
 932                 if(!inWarmupStage)
 933                         if(!self.alivetime)
 934                                 self.alivetime = time;
 935
 936                 antilag_clear(self);
 937
 938                 if (autocvar_g_spawnsound)
 939                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 940         } else if(self.classname == "observer") {
 941                 PutObserverInServer ();
 942         }
 943 }
 944
 945 .float ebouncefactor, ebouncestop; // electro's values
 946 // TODO do we need all these fields, or should we stop autodetecting runtime
 947 // changes and just have a console command to update this?
 948 float ClientInit_SendEntity(entity to, float sf)
 949 {
 950         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 951         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 954         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 955         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 956         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 957         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 958         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 959         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 960         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 961         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 962         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 963         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 964         if(sv_foginterval && world.fog != "")
 965                 WriteString(MSG_ENTITY, world.fog);
 966         else
 967                 WriteString(MSG_ENTITY, "");
 968         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 969         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 970         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 971         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 972         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 973         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 974         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 975         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 976         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 977         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 978         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 979         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 980         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 981         return TRUE;
 982 }
 983
 984 void ClientInit_CheckUpdate()
 985 {
 986         self.nextthink = time;
 987         if(self.count != autocvar_g_balance_armor_blockpercent)
 988         {
 989                 self.count = autocvar_g_balance_armor_blockpercent;
 990                 self.SendFlags |= 1;
 991         }
 992         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 993         {
 994                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 995                 self.SendFlags |= 1;
 996         }
 997         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 998         {
 999                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1000                 self.SendFlags |= 1;
1001         }
1002         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1003         {
1004                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1005                 self.SendFlags |= 1;
1006         }
1007         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1008         {
1009                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1010                 self.SendFlags |= 1;
1011         }
1012         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1013         {
1014                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1015                 self.SendFlags |= 1;
1016         }
1017 }
1018
1019 void ClientInit_Spawn()
1020 {
1021         entity o;
1022         entity e;
1023         e = spawn();
1024         e.classname = "clientinit";
1025         e.think = ClientInit_CheckUpdate;
1026         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1027
1028         o = self;
1029         self = e;
1030         ClientInit_CheckUpdate();
1031         self = o;
1032 }
1033
1034 /*
1035 =============
1036 SetNewParms
1037 =============
1038 */
1039 void SetNewParms (void)
1040 {
1041         // initialize parms for a new player
1042         parm1 = -(86400 * 366);
1043 }
1044
1045 /*
1046 =============
1047 SetChangeParms
1048 =============
1049 */
1050 void SetChangeParms (void)
1051 {
1052         // save parms for level change
1053         parm1 = self.parm_idlesince - time;
1054 }
1055
1056 /*
1057 =============
1058 DecodeLevelParms
1059 =============
1060 */
1061 void DecodeLevelParms (void)
1062 {
1063         // load parms
1064         self.parm_idlesince = parm1;
1065         if(self.parm_idlesince == -(86400 * 366))
1066                 self.parm_idlesince = time;
1067
1068         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1069         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1070 }
1071
1072 /*
1073 =============
1074 ClientKill
1075
1076 Called when a client types 'kill' in the console
1077 =============
1078 */
1079
1080 .float clientkill_nexttime;
1081 void ClientKill_Now_TeamChange()
1082 {
1083         if(self.killindicator_teamchange == -1)
1084         {
1085                 JoinBestTeam( self, FALSE, TRUE );
1086         }
1087         else if(self.killindicator_teamchange == -2)
1088         {
1089                 if(g_ca)
1090                         self.caplayer = 0;
1091                 if(blockSpectators)
1092                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1093                 PutObserverInServer();
1094         }
1095         else
1096                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1097 }
1098
1099 void ClientKill_Now()
1100 {
1101         if(self.vehicle)
1102         {
1103             vehicles_exit(VHEF_RELESE);
1104             if(!self.killindicator_teamchange)
1105             {
1106             self.vehicle_health = -1;
1107             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1108             }
1109         }
1110
1111         if(self.killindicator && !wasfreed(self.killindicator))
1112                 remove(self.killindicator);
1113
1114         self.killindicator = world;
1115
1116         if(self.killindicator_teamchange)
1117                 ClientKill_Now_TeamChange();
1118
1119         // in any case:
1120         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1121
1122         // now I am sure the player IS dead
1123 }
1124 void KillIndicator_Think()
1125 {
1126         if (gameover)
1127         {
1128                 self.owner.killindicator = world;
1129                 remove(self);
1130                 return;
1131         }
1132
1133         if (self.owner.alpha < 0 && !self.owner.vehicle)
1134         {
1135                 self.owner.killindicator = world;
1136                 remove(self);
1137                 return;
1138         }
1139
1140         if(self.cnt <= 0)
1141         {
1142                 self = self.owner;
1143                 ClientKill_Now(); // no oldself needed
1144                 return;
1145         }
1146     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1147     {
1148         self.nextthink = time + 1;
1149         self.cnt -= 1;
1150     }
1151         else
1152         {
1153                 if(self.cnt <= 10)
1154                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1155                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1156                 {
1157                         if(self.cnt <= 10)
1158                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1159                 }
1160                 self.nextthink = time + 1;
1161                 self.cnt -= 1;
1162         }
1163 }
1164
1165 float clientkilltime;
1166 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1167 {
1168         float killtime;
1169         float starttime;
1170         entity e;
1171
1172         if (gameover)
1173                 return;
1174
1175         killtime = autocvar_g_balance_kill_delay;
1176
1177         if(g_race_qualifying || g_cts)
1178                 killtime = 0;
1179
1180     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1181     {
1182                 remove(self.killindicator);
1183                 self.killindicator = world;
1184
1185         ClientKill_Now(); // allow instant kill in this case
1186         return;
1187     }
1188
1189         self.killindicator_teamchange = targetteam;
1190
1191     if(!self.killindicator)
1192         {
1193                 if(self.deadflag == DEAD_NO)
1194                 {
1195                         killtime = max(killtime, self.clientkill_nexttime - time);
1196                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1197                 }
1198
1199                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1200                 {
1201                         ClientKill_Now();
1202                 }
1203                 else
1204                 {
1205                         starttime = max(time, clientkilltime);
1206
1207                         self.killindicator = spawn();
1208                         self.killindicator.owner = self;
1209                         self.killindicator.scale = 0.5;
1210                         setattachment(self.killindicator, self, "");
1211                         setorigin(self.killindicator, '0 0 52');
1212                         self.killindicator.think = KillIndicator_Think;
1213                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1214                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1215                         self.killindicator.cnt = ceil(killtime);
1216                         self.killindicator.count = bound(0, ceil(killtime), 10);
1217                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1218
1219                         for(e = world; (e = find(e, classname, "body")) != world; )
1220                         {
1221                                 if(e.enemy != self)
1222                                         continue;
1223                                 e.killindicator = spawn();
1224                                 e.killindicator.owner = e;
1225                                 e.killindicator.scale = 0.5;
1226                                 setattachment(e.killindicator, e, "");
1227                                 setorigin(e.killindicator, '0 0 52');
1228                                 e.killindicator.think = KillIndicator_Think;
1229                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1230                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1231                                 e.killindicator.cnt = ceil(killtime);
1232                         }
1233                         self.lip = 0;
1234                 }
1235         }
1236         if(self.killindicator)
1237         {
1238                 if(targetteam == 0) // just die
1239                 {
1240                         self.killindicator.colormod = '0 0 0';
1241                         if(clienttype(self) == CLIENTTYPE_REAL)
1242                         if(self.killindicator.cnt > 0)
1243                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1244                 }
1245                 else if(targetteam == -1) // auto
1246                 {
1247                         self.killindicator.colormod = '0 1 0';
1248                         if(clienttype(self) == CLIENTTYPE_REAL)
1249                         if(self.killindicator.cnt > 0)
1250                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1251                 }
1252                 else if(targetteam == -2) // spectate
1253                 {
1254                         self.killindicator.colormod = '0.5 0.5 0.5';
1255                         if(clienttype(self) == CLIENTTYPE_REAL)
1256                         if(self.killindicator.cnt > 0)
1257                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1258                 }
1259                 else
1260                 {
1261                         self.killindicator.colormod = TeamColor(targetteam);
1262                         if(clienttype(self) == CLIENTTYPE_REAL)
1263                         if(self.killindicator.cnt > 0)
1264                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1265                 }
1266         }
1267
1268 }
1269
1270 void ClientKill (void)
1271 {
1272         if (gameover)
1273                 return;
1274
1275         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1276         {
1277                 // do nothing
1278         }
1279     else if(self.freezetag_frozen)
1280     {
1281         // do nothing
1282     }
1283         else
1284                 ClientKill_TeamChange(0);
1285 }
1286
1287 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1288 {
1289     e.killindicator = spawn();
1290     e.killindicator.owner = e;
1291     e.killindicator.think = KillIndicator_Think;
1292     e.killindicator.nextthink = time + (e.lip) * 0.05;
1293     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1294     e.killindicator.health = 1; // this is used to indicate that it should be silent
1295     e.lip = 0;
1296 }
1297
1298 void FixClientCvars(entity e)
1299 {
1300         // send prediction settings to the client
1301         stuffcmd(e, "\nin_bindmap 0 0\n");
1302         if(g_race || g_cts)
1303                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1304         if(autocvar_g_antilag == 3) // client side hitscan
1305                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1306         if(sv_gentle)
1307                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1308         /*
1309          * we no longer need to stuff this. Remove this comment block if you feel
1310          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1311         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1312         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1313         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1314         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1315         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1316         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1317         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1318         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1319         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1320         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1321         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1322         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1323         stuffcmd(e, "cl_movement_edgefriction 1\n");
1324          */
1325 }
1326
1327 float PlayerInIDList(entity p, string idlist)
1328 {
1329         float n, i;
1330         string s;
1331
1332         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1333         if not(p.crypto_idfp)
1334                 return 0;
1335
1336         // this function allows abbreviated player IDs too!
1337         n = tokenize_console(idlist);
1338         for(i = 0; i < n; ++i)
1339         {
1340                 s = argv(i);
1341                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1342                         return 1;
1343         }
1344
1345         return 0;
1346 }
1347
1348 /*
1349 =============
1350 ClientConnect
1351
1352 Called when a client connects to the server
1353 =============
1354 */
1355 string ColoredTeamName(float t);
1356 void DecodeLevelParms (void);
1357 //void dom_player_join_team(entity pl);
1358 void set_dom_state(entity e);
1359 void ClientConnect (void)
1360 {
1361         float t;
1362
1363         if(self.flags & FL_CLIENT)
1364         {
1365                 print("Warning: ClientConnect, but already connected!\n");
1366                 return;
1367         }
1368
1369         if(Ban_MaybeEnforceBanOnce(self))
1370                 return;
1371
1372         DecodeLevelParms();
1373
1374 #ifdef WATERMARK
1375         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1376 #endif
1377
1378         self.classname = "player_joining";
1379
1380         self.flags = FL_CLIENT;
1381         self.version_nagtime = time + 10 + random() * 10;
1382
1383         if(player_count<0)
1384         {
1385                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1386                 player_count = 0;
1387         }
1388
1389         PlayerScore_Attach(self);
1390         ClientData_Attach();
1391         accuracy_init(self);
1392
1393         bot_clientconnect();
1394
1395         playerdemo_init();
1396
1397         anticheat_init();
1398
1399         race_PreSpawnObserver();
1400
1401         // identify the right forced team
1402         if(autocvar_g_campaign)
1403         {
1404                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1405                 {
1406                         switch(autocvar_g_campaign_forceteam)
1407                         {
1408                                 case 1: self.team_forced = COLOR_TEAM1; break;
1409                                 case 2: self.team_forced = COLOR_TEAM2; break;
1410                                 case 3: self.team_forced = COLOR_TEAM3; break;
1411                                 case 4: self.team_forced = COLOR_TEAM4; break;
1412                                 default: self.team_forced = 0;
1413                         }
1414                 }
1415         }
1416         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1417                 self.team_forced = COLOR_TEAM1;
1418         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1419                 self.team_forced = COLOR_TEAM2;
1420         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1421                 self.team_forced = COLOR_TEAM3;
1422         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1423                 self.team_forced = COLOR_TEAM4;
1424         else if(autocvar_g_forced_team_otherwise == "red")
1425                 self.team_forced = COLOR_TEAM1;
1426         else if(autocvar_g_forced_team_otherwise == "blue")
1427                 self.team_forced = COLOR_TEAM2;
1428         else if(autocvar_g_forced_team_otherwise == "yellow")
1429                 self.team_forced = COLOR_TEAM3;
1430         else if(autocvar_g_forced_team_otherwise == "pink")
1431                 self.team_forced = COLOR_TEAM4;
1432         else if(autocvar_g_forced_team_otherwise == "spectate")
1433                 self.team_forced = -1;
1434         else if(autocvar_g_forced_team_otherwise == "spectator")
1435                 self.team_forced = -1;
1436         else
1437                 self.team_forced = 0;
1438
1439         if(!teamplay)
1440                 if(self.team_forced > 0)
1441                         self.team_forced = 0;
1442
1443         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1444
1445         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1446                 self.classname = "observer";
1447         } else {
1448                 if(teamplay)
1449                 {
1450                         if(autocvar_g_balance_teams)
1451                         {
1452                                 self.classname = "player";
1453                                 campaign_bots_may_start = 1;
1454                         }
1455                         else
1456                         {
1457                                 self.classname = "observer"; // do it anyway
1458                         }
1459                 }
1460                 else
1461                 {
1462                         self.classname = "player";
1463                         campaign_bots_may_start = 1;
1464                 }
1465         }
1466
1467         self.playerid = (playerid_last = playerid_last + 1);
1468
1469         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1470
1471     if(clienttype(self) == CLIENTTYPE_BOT)
1472         PlayerStats_AddPlayer(self);
1473
1474         if(autocvar_sv_eventlog)
1475                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1476
1477         LogTeamchange(self.playerid, self.team, 1);
1478
1479         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1480
1481         self.netname_previous = strzone(self.netname);
1482
1483         bprint("^4", self.netname, "^4 connected");
1484
1485         if(self.classname != "observer" && (g_domination || g_ctf))
1486                 bprint(" and joined the ", ColoredTeamName(self.team));
1487
1488         bprint("\n");
1489
1490         stuffcmd(self, strcat(clientstuff, "\n"));
1491         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1492
1493         FixClientCvars(self);
1494
1495         // spawnfunc_waypoint sprites
1496         WaypointSprite_InitClient(self);
1497
1498         // Wazat's grappling hook
1499         SetGrappleHookBindings();
1500
1501         // get version info from player
1502         stuffcmd(self, "cmd clientversion $gameversion\n");
1503
1504         // get other cvars from player
1505         GetCvars(0);
1506
1507         // notify about available teams
1508         if(teamplay)
1509         {
1510                 CheckAllowedTeams(self);
1511                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1512                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1513         }
1514         else
1515                 stuffcmd(self, "set _teams_available 0\n");
1516
1517         if(g_arena || g_ca)
1518         {
1519                 self.classname = "observer";
1520                 if(g_arena)
1521                         Spawnqueue_Insert(self);
1522         }
1523
1524         attach_entcs();
1525
1526         bot_relinkplayerlist();
1527
1528         self.spectatortime = time;
1529         if(blockSpectators)
1530         {
1531                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1532         }
1533
1534         self.jointime = time;
1535         self.allowed_timeouts = autocvar_sv_timeout_number;
1536
1537         if(clienttype(self) == CLIENTTYPE_REAL)
1538         {
1539                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1540                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1541         }
1542
1543         if(g_lms)
1544         {
1545                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1546                 {
1547                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1548                         self.frags = FRAGS_SPECTATOR;
1549                 }
1550         }
1551
1552         if(!sv_foginterval && world.fog != "")
1553                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1554
1555         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1556         {
1557                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1558                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1559         }
1560         else
1561                 self.hitplotfh = -1;
1562
1563         if(g_race || g_cts) {
1564                 string rr;
1565                 if(g_cts)
1566                         rr = CTS_RECORD;
1567                 else
1568                         rr = RACE_RECORD;
1569
1570                 msg_entity = self;
1571                 race_send_recordtime(MSG_ONE);
1572                 race_send_speedaward(MSG_ONE);
1573
1574                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1575                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1576                 race_send_speedaward_alltimebest(MSG_ONE);
1577
1578                 float i;
1579                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1580                         race_SendRankings(i, 0, 0, MSG_ONE);
1581                 }
1582         }
1583         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1584                 send_CSQC_teamnagger();
1585
1586         CheatInitClient();
1587
1588         if(!autocvar_g_campaign)
1589                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1590
1591         CSQCMODEL_AUTOINIT();
1592
1593         self.model_randomizer = random();
1594
1595     if(clienttype(self) != CLIENTTYPE_REAL)
1596         return;
1597
1598     sv_notice_join();
1599
1600     MUTATOR_CALLHOOK(ClientConnect);
1601 }
1602 /*
1603 =============
1604 ClientDisconnect
1605
1606 Called when a client disconnects from the server
1607 =============
1608 */
1609 .entity chatbubbleentity;
1610 void ReadyCount();
1611 void ClientDisconnect (void)
1612 {
1613         if(self.vehicle)
1614             vehicles_exit(VHEF_RELESE);
1615
1616         if not(self.flags & FL_CLIENT)
1617         {
1618                 print("Warning: ClientDisconnect without ClientConnect\n");
1619                 return;
1620         }
1621
1622         PlayerStats_AddGlobalInfo(self);
1623
1624         CheatShutdownClient();
1625
1626         if(self.hitplotfh >= 0)
1627         {
1628                 fclose(self.hitplotfh);
1629                 self.hitplotfh = -1;
1630         }
1631
1632         anticheat_report();
1633         anticheat_shutdown();
1634
1635         playerdemo_shutdown();
1636
1637         bot_clientdisconnect();
1638
1639         if(self.entcs)
1640                 detach_entcs();
1641
1642         if(autocvar_sv_eventlog)
1643                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1644         bprint ("^4",self.netname);
1645         bprint ("^4 disconnected\n");
1646
1647         DropAllRunes(self);
1648         MUTATOR_CALLHOOK(ClientDisconnect);
1649
1650         Portal_ClearAll(self);
1651
1652         RemoveGrapplingHook(self);
1653
1654         // Here, everything has been done that requires this player to be a client.
1655
1656         self.flags &~= FL_CLIENT;
1657
1658         if (self.chatbubbleentity)
1659                 remove (self.chatbubbleentity);
1660
1661         if (self.killindicator)
1662                 remove (self.killindicator);
1663
1664         WaypointSprite_PlayerGone();
1665
1666         bot_relinkplayerlist();
1667
1668         if(g_arena)
1669         {
1670                 Spawnqueue_Unmark(self);
1671                 Spawnqueue_Remove(self);
1672         }
1673
1674         accuracy_free(self);
1675         ClientData_Detach();
1676         PlayerScore_Detach(self);
1677
1678         if(self.netname_previous)
1679                 strunzone(self.netname_previous);
1680         if(self.clientstatus)
1681                 strunzone(self.clientstatus);
1682         if(self.weaponorder_byimpulse)
1683                 strunzone(self.weaponorder_byimpulse);
1684
1685         ClearPlayerSounds();
1686
1687         if(self.personal)
1688                 remove(self.personal);
1689
1690         self.playerid = 0;
1691         ReadyCount();
1692
1693         // free cvars
1694         GetCvars(-1);
1695 }
1696
1697 .float BUTTON_CHAT;
1698 void ChatBubbleThink()
1699 {
1700         self.nextthink = time;
1701         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1702         {
1703                 if(self.owner) // but why can that ever be world?
1704                         self.owner.chatbubbleentity = world;
1705                 remove(self);
1706                 return;
1707         }
1708         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1709 #ifdef TETRIS
1710                 || self.owner.tetris_on
1711 #endif
1712         )
1713                 self.model = self.mdl;
1714         else
1715                 self.model = "";
1716 }
1717
1718 void UpdateChatBubble()
1719 {
1720         if (self.alpha < 0)
1721                 return;
1722         // spawn a chatbubble entity if needed
1723         if (!self.chatbubbleentity)
1724         {
1725                 self.chatbubbleentity = spawn();
1726                 self.chatbubbleentity.owner = self;
1727                 self.chatbubbleentity.exteriormodeltoclient = self;
1728                 self.chatbubbleentity.think = ChatBubbleThink;
1729                 self.chatbubbleentity.nextthink = time;
1730                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1731                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1732                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1733                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1734                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1735                 self.chatbubbleentity.model = "";
1736                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1737         }
1738 }
1739
1740
1741 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1742 // added to the model skins
1743 /*void UpdateColorModHack()
1744 {
1745         float c;
1746         c = self.clientcolors & 15;
1747         // LordHavoc: only bothering to support white, green, red, yellow, blue
1748              if (!teamplay) self.colormod = '0 0 0';
1749         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1750         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1751         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1752         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1753         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1754         else self.colormod = '1 1 1';
1755 }*/
1756
1757 void respawn(void)
1758 {
1759         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1760         {
1761                 self.solid = SOLID_NOT;
1762                 self.takedamage = DAMAGE_NO;
1763                 self.movetype = MOVETYPE_FLY;
1764                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1765                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1766                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1767                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1768                 if(autocvar_g_respawn_ghosts_maxtime)
1769                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1770         }
1771
1772         CopyBody(1);
1773
1774         self.effects |= EF_NODRAW; // prevent another CopyBody
1775         PutClientInServer();
1776 }
1777
1778 void play_countdown(float finished, string samp)
1779 {
1780         if(clienttype(self) == CLIENTTYPE_REAL)
1781                 if(floor(finished - time - frametime) != floor(finished - time))
1782                         if(finished - time < 6)
1783                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1784 }
1785
1786 void player_powerups (void)
1787 {
1788         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1789         olditems = self.items;
1790
1791         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1792                 self.modelflags |= MF_ROCKET;
1793         else
1794                 self.modelflags &~= MF_ROCKET;
1795
1796         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1797
1798         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1799                 return;
1800
1801         Fire_ApplyDamage(self);
1802         Fire_ApplyEffect(self);
1803
1804         if (g_minstagib)
1805         {
1806                 self.effects |= EF_FULLBRIGHT;
1807
1808                 if (self.items & IT_STRENGTH)
1809                 {
1810                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1811                         if (time > self.strength_finished)
1812                         {
1813                                 self.alpha = default_player_alpha;
1814                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1815                                 self.items &~= IT_STRENGTH;
1816                                 sprint(self, "^3Invisibility has worn off\n");
1817                         }
1818                 }
1819                 else
1820                 {
1821                         if (time < self.strength_finished)
1822                         {
1823                                 self.alpha = g_minstagib_invis_alpha;
1824                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1825                                 self.items |= IT_STRENGTH;
1826                                 sprint(self, "^3You are invisible\n");
1827                         }
1828                 }
1829
1830                 if (self.items & IT_INVINCIBLE)
1831                 {
1832                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1833                         if (time > self.invincible_finished)
1834                         {
1835                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1836                                 sprint(self, "^3Speed has worn off\n");
1837                         }
1838                 }
1839                 else
1840                 {
1841                         if (time < self.invincible_finished)
1842                         {
1843                                 self.items = self.items | IT_INVINCIBLE;
1844                                 sprint(self, "^3You are on speed\n");
1845                         }
1846                 }
1847         }
1848         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1849         {
1850                 if (self.items & IT_STRENGTH)
1851                 {
1852                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1853                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1854                         if (time > self.strength_finished)
1855                         {
1856                                 self.items = self.items - (self.items & IT_STRENGTH);
1857                                 sprint(self, "^3Strength has worn off\n");
1858                         }
1859                 }
1860                 else
1861                 {
1862                         if (time < self.strength_finished)
1863                         {
1864                                 self.items = self.items | IT_STRENGTH;
1865                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1866                         }
1867                 }
1868                 if (self.items & IT_INVINCIBLE)
1869                 {
1870                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1871                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1872                         if (time > self.invincible_finished)
1873                         {
1874                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1875                                 sprint(self, "^3Shield has worn off\n");
1876                         }
1877                 }
1878                 else
1879                 {
1880                         if (time < self.invincible_finished)
1881                         {
1882                                 self.items = self.items | IT_INVINCIBLE;
1883                                 sprint(self, "^3Shield surrounds you\n");
1884                         }
1885                 }
1886                 if (self.items & IT_SUPERWEAPON)
1887                 {
1888                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1889                         {
1890                                 self.superweapons_finished = 0;
1891                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1892                                 sprint(self, "^3Superweapons have been lost\n");
1893                         }
1894                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1895                         {
1896                                 // don't let them run out
1897                         }
1898                         else
1899                         {
1900                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1901                                 if (time > self.superweapons_finished)
1902                                 {
1903                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1904                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1905                                         sprint(self, "^3Superweapons have broken down\n");
1906                                 }
1907                         }
1908                 }
1909                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1910                 {
1911                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1912                         {
1913                                 self.items = self.items | IT_SUPERWEAPON;
1914                                 sprint(self, "^3You now have a superweapon\n");
1915                         }
1916                         else
1917                         {
1918                                 self.superweapons_finished = 0;
1919                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1920                         }
1921                 }
1922                 else
1923                 {
1924                         self.superweapons_finished = 0;
1925                 }
1926         }
1927
1928         if(autocvar_g_nodepthtestplayers)
1929                 self.effects = self.effects | EF_NODEPTHTEST;
1930
1931         if(autocvar_g_fullbrightplayers)
1932                 self.effects = self.effects | EF_FULLBRIGHT;
1933
1934         // midair gamemode: damage only while in the air
1935         // if in midair mode, being on ground grants temporary invulnerability
1936         // (this is so that multishot weapon don't clear the ground flag on the
1937         // first damage in the frame, leaving the player vulnerable to the
1938         // remaining hits in the same frame)
1939         if (self.flags & FL_ONGROUND)
1940         if (g_midair)
1941                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1942
1943         if (time >= game_starttime)
1944         if (time < self.spawnshieldtime)
1945                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1946
1947         MUTATOR_CALLHOOK(PlayerPowerups);
1948 }
1949
1950 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1951 {
1952         if(current > stable)
1953                 return current;
1954         else if(current > stable - 0.25) // when close enough, "snap"
1955                 return stable;
1956         else
1957                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1958 }
1959
1960 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1961 {
1962         if(current < stable)
1963                 return current;
1964         else if(current < stable + 0.25) // when close enough, "snap"
1965                 return stable;
1966         else
1967                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1968 }
1969
1970 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1971 {
1972         if(current > rotstable)
1973         {
1974                 if(rotframetime > 0)
1975                 {
1976                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1977                         current = max(rotstable, current - rotlinear * rotframetime);
1978                 }
1979         }
1980         else if(current < regenstable)
1981         {
1982                 if(regenframetime > 0)
1983                 {
1984                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1985                         current = min(regenstable, current + regenlinear * regenframetime);
1986                 }
1987         }
1988
1989         if(current > limit)
1990                 current = limit;
1991
1992         return current;
1993 }
1994
1995 void player_regen (void)
1996 {
1997         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1998         maxh = autocvar_g_balance_health_rotstable;
1999         maxa = autocvar_g_balance_armor_rotstable;
2000         maxf = autocvar_g_balance_fuel_rotstable;
2001         minh = autocvar_g_balance_health_regenstable;
2002         mina = autocvar_g_balance_armor_regenstable;
2003         minf = autocvar_g_balance_fuel_regenstable;
2004         limith = autocvar_g_balance_health_limit;
2005         limita = autocvar_g_balance_armor_limit;
2006         limitf = autocvar_g_balance_fuel_limit;
2007
2008         max_mod = regen_mod = rot_mod = limit_mod = 1;
2009
2010         if (self.runes & RUNE_REGEN)
2011         {
2012                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2013                 {
2014                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2015                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2016                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2017                 }
2018                 else
2019                 {
2020                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2021                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2022                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2023                 }
2024         }
2025         else if (self.runes & CURSE_VENOM)
2026         {
2027                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2028                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2029                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2030                 else
2031                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2032                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2033                 //if (!self.runes & RUNE_REGEN)
2034                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2035         }
2036         maxh = maxh * max_mod;
2037         //maxa = maxa * max_mod;
2038         //maxf = maxf * max_mod;
2039         minh = minh * max_mod;
2040         //mina = mina * max_mod;
2041         //minf = minf * max_mod;
2042         limith = limith * limit_mod;
2043         limita = limita * limit_mod;
2044         //limitf = limitf * limit_mod;
2045
2046         if(g_lms && g_ca)
2047                 rot_mod = 0;
2048
2049         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2050         {
2051                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2052                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2053
2054                 // if player rotted to death...  die!
2055                 if(self.health < 1)
2056                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2057         }
2058
2059         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2060                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2061 }
2062
2063 float zoomstate_set;
2064 void SetZoomState(float z)
2065 {
2066         if(z != self.zoomstate)
2067         {
2068                 self.zoomstate = z;
2069                 ClientData_Touch(self);
2070         }
2071         zoomstate_set = 1;
2072 }
2073
2074 void GetPressedKeys(void) {
2075         MUTATOR_CALLHOOK(GetPressedKeys);
2076         if (self.movement_x > 0) // get if movement keys are pressed
2077         {       // forward key pressed
2078                 self.pressedkeys |= KEY_FORWARD;
2079                 self.pressedkeys &~= KEY_BACKWARD;
2080         }
2081         else if (self.movement_x < 0)
2082         {       // backward key pressed
2083                 self.pressedkeys |= KEY_BACKWARD;
2084                 self.pressedkeys &~= KEY_FORWARD;
2085         }
2086         else
2087         {       // no x input
2088                 self.pressedkeys &~= KEY_FORWARD;
2089                 self.pressedkeys &~= KEY_BACKWARD;
2090         }
2091
2092         if (self.movement_y > 0)
2093         {       // right key pressed
2094                 self.pressedkeys |= KEY_RIGHT;
2095                 self.pressedkeys &~= KEY_LEFT;
2096         }
2097         else if (self.movement_y < 0)
2098         {       // left key pressed
2099                 self.pressedkeys |= KEY_LEFT;
2100                 self.pressedkeys &~= KEY_RIGHT;
2101         }
2102         else
2103         {       // no y input
2104                 self.pressedkeys &~= KEY_RIGHT;
2105                 self.pressedkeys &~= KEY_LEFT;
2106         }
2107
2108         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2109                 self.pressedkeys |= KEY_JUMP;
2110         else
2111                 self.pressedkeys &~= KEY_JUMP;
2112         if (self.BUTTON_CROUCH)
2113                 self.pressedkeys |= KEY_CROUCH;
2114         else
2115                 self.pressedkeys &~= KEY_CROUCH;
2116
2117         if (self.BUTTON_ATCK)
2118                 self.pressedkeys |= KEY_ATCK;
2119         else
2120                 self.pressedkeys &~= KEY_ATCK;
2121         if (self.BUTTON_ATCK2)
2122                 self.pressedkeys |= KEY_ATCK2;
2123         else
2124                 self.pressedkeys &~= KEY_ATCK2;
2125 }
2126
2127 /*
2128 ======================
2129 spectate mode routines
2130 ======================
2131 */
2132
2133 void SpectateCopy(entity spectatee) {
2134         other = spectatee;
2135         MUTATOR_CALLHOOK(SpectateCopy);
2136         self.armortype = spectatee.armortype;
2137         self.armorvalue = spectatee.armorvalue;
2138         self.ammo_cells = spectatee.ammo_cells;
2139         self.ammo_shells = spectatee.ammo_shells;
2140         self.ammo_nails = spectatee.ammo_nails;
2141         self.ammo_rockets = spectatee.ammo_rockets;
2142         self.ammo_fuel = spectatee.ammo_fuel;
2143         self.clip_load = spectatee.clip_load;
2144         self.clip_size = spectatee.clip_size;
2145         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2146         self.health = spectatee.health;
2147         self.impulse = 0;
2148         self.items = spectatee.items;
2149         self.last_pickup = spectatee.last_pickup;
2150         self.hit_time = spectatee.hit_time;
2151         self.metertime = spectatee.metertime;
2152         self.strength_finished = spectatee.strength_finished;
2153         self.invincible_finished = spectatee.invincible_finished;
2154         self.pressedkeys = spectatee.pressedkeys;
2155         WEPSET_COPY_EE(self, spectatee);
2156         self.switchweapon = spectatee.switchweapon;
2157         self.switchingweapon = spectatee.switchingweapon;
2158         self.weapon = spectatee.weapon;
2159         self.nex_charge = spectatee.nex_charge;
2160         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2161         self.hagar_load = spectatee.hagar_load;
2162         self.minelayer_mines = spectatee.minelayer_mines;
2163         self.punchangle = spectatee.punchangle;
2164         self.view_ofs = spectatee.view_ofs;
2165         self.velocity = spectatee.velocity;
2166         self.dmg_take = spectatee.dmg_take;
2167         self.dmg_save = spectatee.dmg_save;
2168         self.dmg_inflictor = spectatee.dmg_inflictor;
2169         self.v_angle = spectatee.v_angle;
2170         self.angles = spectatee.v_angle;
2171         self.stat_respawn_time = spectatee.stat_respawn_time;
2172         if(!self.BUTTON_USE)
2173                 self.fixangle = TRUE;
2174         setorigin(self, spectatee.origin);
2175         setsize(self, spectatee.mins, spectatee.maxs);
2176         SetZoomState(spectatee.zoomstate);
2177
2178     anticheat_spectatecopy(spectatee);
2179         self.hud = spectatee.hud;
2180         if(spectatee.vehicle)
2181     {
2182         self.fixangle = FALSE;
2183         //self.velocity = spectatee.vehicle.velocity;
2184         self.vehicle_health = spectatee.vehicle_health;
2185         self.vehicle_shield = spectatee.vehicle_shield;
2186         self.vehicle_energy = spectatee.vehicle_energy;
2187         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2188         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2189         self.vehicle_reload1 = spectatee.vehicle_reload1;
2190         self.vehicle_reload2 = spectatee.vehicle_reload2;
2191
2192         msg_entity = self;
2193
2194         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2195             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2196             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2197             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2198
2199         //WriteByte (MSG_ONE, SVC_SETVIEW);
2200         //    WriteEntity(MSG_ONE, self);
2201         //makevectors(spectatee.v_angle);
2202         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2203     }
2204 }
2205
2206 float SpectateUpdate() {
2207         if(!self.enemy)
2208             return 0;
2209
2210         if (self == self.enemy)
2211                 return 0;
2212
2213         if(self.enemy.classname != "player")
2214                 return 0;
2215
2216         SpectateCopy(self.enemy);
2217
2218         return 1;
2219 }
2220
2221
2222 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2223 entity CA_SpectateNext(entity start) {
2224         if (start.team == self.team) {
2225                 return start;
2226         }
2227
2228         other = start;
2229         // continue from current player
2230         while(other && other.team != self.team) {
2231                 other = find(other, classname, "player");
2232         }
2233
2234         if (!other) {
2235                 // restart from begining
2236                 other = find(other, classname, "player");
2237                 while(other && other.team != self.team) {
2238                         other = find(other, classname, "player");
2239                 }
2240         }
2241
2242         return other;
2243 }
2244
2245 float SpectateNext(entity _prefer) {
2246
2247         if(_prefer)
2248                 other = _prefer;
2249         else
2250                 other = find(self.enemy, classname, "player");
2251
2252         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2253                 // CA and ca players when spectating enemies is forbidden
2254                 other = CA_SpectateNext(other);
2255         } else {
2256                 // other modes and ca spectators or spectating enemies is allowed
2257                 if (!other)
2258                         other = find(other, classname, "player");
2259         }
2260
2261         if (other)
2262                 self.enemy = other;
2263
2264         if(self.enemy.classname == "player") {
2265             /*if(self.enemy.vehicle)
2266             {
2267
2268             msg_entity = self;
2269             WriteByte(MSG_ONE, SVC_SETVIEW);
2270             WriteEntity(MSG_ONE, self.enemy);
2271             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2272
2273             self.movetype = MOVETYPE_NONE;
2274             accuracy_resend(self);
2275             }
2276             else
2277             {*/
2278             msg_entity = self;
2279             WriteByte(MSG_ONE, SVC_SETVIEW);
2280             WriteEntity(MSG_ONE, self.enemy);
2281             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2282             self.movetype = MOVETYPE_NONE;
2283             accuracy_resend(self);
2284
2285             if(!SpectateUpdate())
2286                 PutObserverInServer();
2287         //}
2288         return 1;
2289         } else {
2290                 return 0;
2291         }
2292 }
2293
2294 /*
2295 =============
2296 ShowRespawnCountdown()
2297
2298 Update a respawn countdown display.
2299 =============
2300 */
2301 void ShowRespawnCountdown()
2302 {
2303         float number;
2304         if(self.deadflag == DEAD_NO) // just respawned?
2305                 return;
2306         else
2307         {
2308                 number = ceil(self.respawn_time - time);
2309                 if(number <= 0)
2310                         return;
2311                 if(number <= self.respawn_countdown)
2312                 {
2313                         self.respawn_countdown = number - 1;
2314                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2315                                 AnnounceTo(self, strcat(ftos(number), ""));
2316                 }
2317         }
2318 }
2319
2320 .float prevent_join_msgtime;
2321 void LeaveSpectatorMode()
2322 {
2323         if(nJoinAllowed(self)) {
2324                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2325                         self.classname = "player";
2326
2327                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2328                                 JoinBestTeam(self, FALSE, TRUE);
2329
2330                         if(autocvar_g_campaign)
2331                                 campaign_bots_may_start = 1;
2332
2333                         PutClientInServer();
2334
2335                         if(self.classname == "player")
2336                                 bprint ("^4", self.netname, "^4 is playing now\n");
2337
2338                         if(!autocvar_g_campaign)
2339                         if (time < self.jointime + autocvar_welcome_message_time)
2340                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2341
2342                         if (self.prevent_join_msgtime)
2343                         {
2344                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2345                                 self.prevent_join_msgtime = 0;
2346                         }
2347
2348                         return;
2349                 } else {
2350                         if (g_ca && self.caplayer) {
2351                         }       // do nothing
2352                         else
2353                                 stuffcmd(self,"menu_showteamselect\n");
2354                         return;
2355                 }
2356         }
2357         else {
2358                 //player may not join because of g_maxplayers is set
2359                 if (time - self.prevent_join_msgtime > 2)
2360                 {
2361                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2362                         self.prevent_join_msgtime = time;
2363                 }
2364         }
2365 }
2366
2367 /**
2368  * Determines whether the player is allowed to join. This depends on cvar
2369  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2370  * it checks whether the number of currently playing players exceeds g_maxplayers.
2371  * @return int number of free slots for players, 0 if none
2372  */
2373 float nJoinAllowed(entity ignore) {
2374         if(!ignore)
2375         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2376         // so report 0 free slots if restricted
2377         {
2378                 if(autocvar_g_forced_team_otherwise == "spectate")
2379                         return 0;
2380                 if(autocvar_g_forced_team_otherwise == "spectator")
2381                         return 0;
2382         }
2383
2384         if(self.team_forced < 0)
2385                 return 0; // forced spectators can never join
2386
2387         // TODO simplify this
2388         entity e;
2389         float totalClients = 0;
2390         FOR_EACH_CLIENT(e)
2391                 if(e != ignore)
2392                         totalClients += 1;
2393
2394         if (!autocvar_g_maxplayers)
2395                 return maxclients - totalClients;
2396
2397         float currentlyPlaying = 0;
2398         FOR_EACH_REALPLAYER(e)
2399                 currentlyPlaying += 1;
2400
2401         if(currentlyPlaying < autocvar_g_maxplayers)
2402                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2403
2404         return 0;
2405 }
2406
2407 /**
2408  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2409  * g_maxplayers_spectator_blocktime seconds
2410  */
2411 void checkSpectatorBlock() {
2412         if(self.classname == "spectator" || self.classname == "observer") {
2413                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2414                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2415                         dropclient(self);
2416                 }
2417         }
2418 }
2419
2420 .float motd_actived_time; // used for both motd and campaign_message
2421 void PrintWelcomeMessage()
2422 {
2423         if (self.motd_actived_time == 0) { // is there already a message showing?
2424                 if (autocvar_g_campaign) {
2425                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2426                                 self.motd_actived_time = time;
2427                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2428                         }
2429                 } else {
2430                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2431                                 self.motd_actived_time = time;
2432                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2433                         }
2434                 }
2435         } else { // showing MOTD or campaign message
2436                 if (autocvar_g_campaign) {
2437                         if (self.BUTTON_INFO)
2438                                 self.motd_actived_time = time;
2439                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2440                                 self.motd_actived_time = 0;
2441                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2442                         }
2443                 } else {
2444                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2445                                 if (self.BUTTON_INFO)
2446                                         self.motd_actived_time = time;
2447                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2448                                         self.motd_actived_time = 0;
2449                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2450                                 }
2451                         }
2452                 }
2453         }
2454 }
2455
2456 void ObserverThink()
2457 {
2458         float prefered_movetype;
2459         if (self.flags & FL_JUMPRELEASED) {
2460                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2461                         self.flags &~= FL_JUMPRELEASED;
2462                         self.flags |= FL_SPAWNING;
2463                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2464                         self.flags &~= FL_JUMPRELEASED;
2465                         if(SpectateNext(world) == 1) {
2466                                 self.classname = "spectator";
2467                         }
2468                 } else {
2469                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2470                         if (self.movetype != prefered_movetype)
2471                                 self.movetype = prefered_movetype;
2472                 }
2473         } else {
2474                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2475                         self.flags |= FL_JUMPRELEASED;
2476                         if(self.flags & FL_SPAWNING)
2477                         {
2478                                 self.flags &~= FL_SPAWNING;
2479                                 LeaveSpectatorMode();
2480                                 return;
2481                         }
2482                 }
2483         }
2484
2485         PrintWelcomeMessage();
2486 }
2487
2488 void SpectatorThink()
2489 {
2490         if (self.flags & FL_JUMPRELEASED) {
2491                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2492                         self.flags &~= FL_JUMPRELEASED;
2493                         self.flags |= FL_SPAWNING;
2494                 } else if(self.BUTTON_ATCK) {
2495                         self.flags &~= FL_JUMPRELEASED;
2496                         if(SpectateNext(world) == 1) {
2497                                 self.classname = "spectator";
2498                         } else {
2499                                 self.classname = "observer";
2500                                 PutClientInServer();
2501                         }
2502                 } else if (self.BUTTON_ATCK2) {
2503                         self.flags &~= FL_JUMPRELEASED;
2504                         self.classname = "observer";
2505                         PutClientInServer();
2506                 } else {
2507                         if(!SpectateUpdate())
2508                                 PutObserverInServer();
2509                 }
2510         } else {
2511                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2512                         self.flags |= FL_JUMPRELEASED;
2513                         if(self.flags & FL_SPAWNING)
2514                         {
2515                                 self.flags &~= FL_SPAWNING;
2516                                 LeaveSpectatorMode();
2517                                 return;
2518                         }
2519                 }
2520                 if(!SpectateUpdate())
2521                         PutObserverInServer();
2522         }
2523
2524         PrintWelcomeMessage();
2525         self.flags |= FL_CLIENT | FL_NOTARGET;
2526 }
2527
2528 void PlayerUseKey()
2529 {
2530         if(self.classname != "player")
2531                 return;
2532
2533         if(self.vehicle)
2534         {
2535         vehicles_exit(VHEF_NORMAL);
2536         return;
2537         }
2538
2539         // a use key was pressed; call handlers
2540         MUTATOR_CALLHOOK(PlayerUseKey);
2541 }
2542
2543 .float touchexplode_time;
2544
2545 /*
2546 =============
2547 PlayerPreThink
2548
2549 Called every frame for each client before the physics are run
2550 =============
2551 */
2552 .float usekeypressed;
2553 void() nexball_setstatus;
2554 .float items_added;
2555 void PlayerPreThink (void)
2556 {
2557         WarpZone_PlayerPhysics_FixVAngle();
2558
2559         self.stat_game_starttime = game_starttime;
2560         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2561         self.stat_leadlimit = autocvar_leadlimit;
2562
2563         if(g_arena || (g_ca && !allowed_to_spawn))
2564                 self.stat_respawn_time = 0;
2565         else
2566                 self.stat_respawn_time = self.respawn_time;
2567
2568         if(frametime)
2569         {
2570                 // physics frames: update anticheat stuff
2571                 anticheat_prethink();
2572         }
2573
2574         if(blockSpectators && frametime)
2575                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2576                 checkSpectatorBlock();
2577
2578         zoomstate_set = 0;
2579
2580         if(self.netname_previous != self.netname)
2581         {
2582                 if(autocvar_sv_eventlog)
2583                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2584                 if(self.netname_previous)
2585                         strunzone(self.netname_previous);
2586                 self.netname_previous = strzone(self.netname);
2587         }
2588
2589         // version nagging
2590         if(self.version_nagtime)
2591                 if(self.cvar_g_xonoticversion)
2592                         if(time > self.version_nagtime)
2593                         {
2594                                 // don't notify git users
2595                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2596                                 {
2597                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2598                                         {
2599                                                 // notify release users if connecting to git
2600                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2601                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2602                                         }
2603                                         else
2604                                         {
2605                                                 float r;
2606                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2607                                                 if(r < 0)
2608                                                 {
2609                                                         // give users new version
2610                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2611                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2612                                                 }
2613                                                 else if(r > 0)
2614                                                 {
2615                                                         // notify users about old server version
2616                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2617                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2618                                                 }
2619                                         }
2620                                 }
2621                                 self.version_nagtime = 0;
2622                         }
2623
2624         // GOD MODE info
2625         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2626         {
2627                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2628                 self.max_armorvalue = 0;
2629         }
2630
2631 #ifdef TETRIS
2632         if (TetrisPreFrame())
2633                 return;
2634 #endif
2635
2636         if(self.frozen)
2637         {
2638                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2639                 self.health = max(1, self.revive_progress * autocvar_g_balance_health_start);
2640
2641                 if(self.revive_progress >= 1)
2642                         Unfreeze(self);
2643         }
2644
2645         MUTATOR_CALLHOOK(PlayerPreThink);
2646
2647         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2648         {
2649                 if(self.BUTTON_USE && !self.usekeypressed)
2650                         PlayerUseKey();
2651                 self.usekeypressed = self.BUTTON_USE;
2652         }
2653
2654         PrintWelcomeMessage();
2655
2656         if(self.classname == "player") {
2657 //              if(self.netname == "Wazat")
2658 //                      bprint(self.classname, "\n");
2659
2660                 CheckRules_Player();
2661
2662                 if (intermission_running)
2663                 {
2664                         IntermissionThink ();   // otherwise a button could be missed between
2665                         return;                                 // the think tics
2666                 }
2667
2668                 //don't allow the player to turn around while game is paused!
2669                 if(timeout_status == TIMEOUT_ACTIVE) {
2670                         // FIXME turn this into CSQC stuff
2671                         self.v_angle = self.lastV_angle;
2672                         self.angles = self.lastV_angle;
2673                         self.fixangle = TRUE;
2674                 }
2675
2676                 if(frametime)
2677                 {
2678                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2679                         {
2680                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2681                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2682                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2683
2684                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2685                                 {
2686                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2687                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2688                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2689                                 }
2690                         }
2691                         else
2692                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2693
2694                         player_powerups();
2695                 }
2696
2697                 if (g_minstagib)
2698                         minstagib_ammocheck();
2699
2700                 if (self.deadflag != DEAD_NO)
2701                 {
2702                         float button_pressed, force_respawn;
2703                         if(self.personal && g_race_qualifying)
2704                         {
2705                                 if(time > self.respawn_time)
2706                                 {
2707                                         self.respawn_time = time + 1; // only retry once a second
2708                                         respawn();
2709                                         self.impulse = 141;
2710                                 }
2711                         }
2712                         else
2713                         {
2714                                 if(frametime)
2715                                         player_anim();
2716                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2717                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2718                                 if (self.deadflag == DEAD_DYING)
2719                                 {
2720                                         if(force_respawn)
2721                                                 self.deadflag = DEAD_RESPAWNING;
2722                                         else if(!button_pressed)
2723                                                 self.deadflag = DEAD_DEAD;
2724                                 }
2725                                 else if (self.deadflag == DEAD_DEAD)
2726                                 {
2727                                         if(button_pressed)
2728                                                 self.deadflag = DEAD_RESPAWNABLE;
2729                                 }
2730                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2731                                 {
2732                                         if(!button_pressed)
2733                                                 self.deadflag = DEAD_RESPAWNING;
2734                                 }
2735                                 else if (self.deadflag == DEAD_RESPAWNING)
2736                                 {
2737                                         if(time > self.respawn_time)
2738                                         {
2739                                                 self.respawn_time = time + 1; // only retry once a second
2740                                                 respawn();
2741                                         }
2742                                 }
2743                                 ShowRespawnCountdown();
2744                         }
2745
2746                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2747                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2748                                 self.stat_respawn_time *= -1;
2749
2750                         return;
2751                 }
2752                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2753                 // so (self.deadflag == DEAD_NO) is always true in the code below
2754
2755                 if(g_touchexplode)
2756                 if(time > self.touchexplode_time)
2757                 if(self.classname == "player")
2758                 if(self.deadflag == DEAD_NO)
2759                 if not(IS_INDEPENDENT_PLAYER(self))
2760                 FOR_EACH_PLAYER(other) if(self != other)
2761                 {
2762                         if(time > other.touchexplode_time)
2763                         if(other.deadflag == DEAD_NO)
2764                         if not(IS_INDEPENDENT_PLAYER(other))
2765                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2766                         {
2767                                 PlayerTouchExplode(self, other);
2768                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2769                         }
2770                 }
2771
2772                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2773                 {
2774                         vector dist;
2775
2776                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2777                         dist = self.prevorigin - self.origin;
2778                         dist_z = 0;
2779                         self.lms_traveled_distance += fabs(vlen(dist));
2780
2781                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2782                         {
2783                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2784                                 self.lms_traveled_distance = 0;
2785                         }
2786
2787                         if(time > self.lms_nextcheck)
2788                         {
2789                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2790                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2791                                 {
2792                                         centerprint(self, autocvar_g_lms_campcheck_message);
2793                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2794                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2795                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2796                                 }
2797                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2798                                 self.lms_traveled_distance = 0;
2799                         }
2800                 }
2801
2802                 self.prevorigin = self.origin;
2803
2804                 float do_crouch = self.BUTTON_CROUCH;
2805                 if(self.hook.state)
2806                         do_crouch = 0;
2807                 if(self.health <= g_bloodloss)
2808                         do_crouch = 1;
2809                 if(self.vehicle)
2810                         do_crouch = 0;
2811                 if(self.freezetag_frozen || self.frozen)
2812                         do_crouch = 0;
2813                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2814                         do_crouch = 0;
2815
2816                 if (do_crouch)
2817                 {
2818                         if (!self.crouch)
2819                         {
2820                                 self.crouch = TRUE;
2821                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2822                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2823                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2824                         }
2825                 }
2826                 else
2827                 {
2828                         if (self.crouch)
2829                         {
2830                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2831                                 if (!trace_startsolid)
2832                                 {
2833                                         self.crouch = FALSE;
2834                                         self.view_ofs = PL_VIEW_OFS;
2835                                         setsize (self, PL_MIN, PL_MAX);
2836                                 }
2837                         }
2838                 }
2839
2840                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2841                 {
2842                         if(self.bloodloss_timer < time)
2843                         {
2844                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2845                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2846                         }
2847                 }
2848
2849                 FixPlayermodel();
2850
2851                 GrapplingHookFrame();
2852
2853                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2854                 //if(frametime)
2855                 {
2856                         self.items &~= self.items_added;
2857
2858                         W_WeaponFrame();
2859
2860                         self.items_added = 0;
2861                         if(self.items & IT_JETPACK)
2862                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2863                                         self.items_added |= IT_FUEL;
2864
2865                         self.items |= self.items_added;
2866                 }
2867
2868                 player_regen();
2869
2870                 // rot nex charge to the charge limit
2871                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2872                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2873
2874                 if(frametime)
2875                         player_anim();
2876
2877                 if(g_nexball)
2878                         nexball_setstatus();
2879
2880                 // secret status
2881                 secrets_setstatus();
2882
2883                 // monsters status
2884                 monsters_setstatus();
2885
2886                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2887
2888                 //self.angles_y=self.v_angle_y + 90;   // temp
2889         } else if(gameover) {
2890                 if (intermission_running)
2891                         IntermissionThink ();   // otherwise a button could be missed between
2892                 return;
2893         } else if(self.classname == "observer") {
2894                 ObserverThink();
2895         } else if(self.classname == "spectator") {
2896                 SpectatorThink();
2897         }
2898
2899         if(!zoomstate_set)
2900                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2901
2902         float oldspectatee_status;
2903         oldspectatee_status = self.spectatee_status;
2904         if(self.classname == "spectator")
2905                 self.spectatee_status = num_for_edict(self.enemy);
2906         else if(self.classname == "observer")
2907                 self.spectatee_status = num_for_edict(self);
2908         else
2909                 self.spectatee_status = 0;
2910         if(self.spectatee_status != oldspectatee_status)
2911         {
2912                 ClientData_Touch(self);
2913                 if(g_race || g_cts)
2914                         race_InitSpectator();
2915         }
2916
2917         if(self.teamkill_soundtime)
2918         if(time > self.teamkill_soundtime)
2919         {
2920                 self.teamkill_soundtime = 0;
2921
2922                 entity oldpusher, oldself;
2923
2924                 oldself = self; self = self.teamkill_soundsource;
2925                 oldpusher = self.pusher; self.pusher = oldself;
2926
2927                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2928
2929                 self.pusher = oldpusher;
2930                 self = oldself;
2931         }
2932
2933         if(self.taunt_soundtime)
2934         if(time > self.taunt_soundtime)
2935         {
2936                 self.taunt_soundtime = 0;
2937                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2938         }
2939
2940         target_voicescript_next(self);
2941
2942         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2943         if(!self.weapon)
2944                 self.clip_load = self.clip_size = 0;
2945 }
2946
2947 float isInvisibleString(string s)
2948 {
2949         float i, n, c;
2950         s = strdecolorize(s);
2951         for((i = 0), (n = strlen(s)); i < n; ++i)
2952         {
2953                 c = str2chr(s, i);
2954                 switch(c)
2955                 {
2956                         case 0:
2957                         case 32: // space
2958                                 break;
2959                         case 192: // charmap space
2960                                 if (!autocvar_utf8_enable)
2961                                         break;
2962                                 return FALSE;
2963                         case 160: // space in unicode fonts
2964                         case 0xE000 + 192: // utf8 charmap space
2965                                 if (autocvar_utf8_enable)
2966                                         break;
2967                         default:
2968                                 return FALSE;
2969                 }
2970         }
2971         return TRUE;
2972 }
2973
2974 /*
2975 =============
2976 PlayerPostThink
2977
2978 Called every frame for each client after the physics are run
2979 =============
2980 */
2981 .float idlekick_lasttimeleft;
2982 void PlayerPostThink (void)
2983 {
2984         // Savage: Check for nameless players
2985         if (isInvisibleString(self.netname)) {
2986                 self.netname = "Player";
2987                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2988         }
2989
2990         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2991         {
2992                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2993                 {
2994                         if(self.idlekick_lasttimeleft)
2995                         {
2996                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2997                                 self.idlekick_lasttimeleft = 0;
2998                         }
2999                 }
3000                 else
3001                 {
3002                         float timeleft;
3003                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3004                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3005                         {
3006                                 if(!self.idlekick_lasttimeleft)
3007                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3008                         }
3009                         if(timeleft <= 0)
3010                         {
3011                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3012                                 AnnounceTo(self, "terminated");
3013                                 dropclient(self);
3014                                 return;
3015                         }
3016                         else if(timeleft <= 10)
3017                         {
3018                                 if(timeleft != self.idlekick_lasttimeleft)
3019                                         AnnounceTo(self, ftos(timeleft));
3020                                 self.idlekick_lasttimeleft = timeleft;
3021                         }
3022                 }
3023         }
3024
3025 #ifdef TETRIS
3026         if(self.impulse == 100)
3027                 ImpulseCommands();
3028         if (!TetrisPostFrame())
3029         {
3030 #endif
3031
3032         CheatFrame();
3033
3034         //CheckPlayerJump();
3035
3036         if(self.classname == "player") {
3037                 CheckRules_Player();
3038                 UpdateChatBubble();
3039                 if (self.impulse)
3040                         ImpulseCommands();
3041                 if (intermission_running)
3042                         return;         // intermission or finale
3043                 GetPressedKeys();
3044         }
3045
3046 #ifdef TETRIS
3047         }
3048 #endif
3049
3050         /*
3051         float i;
3052         for(i = 0; i < 1000; ++i)
3053         {
3054                 vector end;
3055                 end = self.origin + '0 0 1024' + 512 * randomvec();
3056                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3057                 if(trace_fraction < 1)
3058                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3059                 {
3060                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3061                         break;
3062                 }
3063         }
3064         */
3065
3066         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3067
3068         if(self.waypointsprite_attachedforcarrier)
3069                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3070
3071         playerdemo_write();
3072
3073         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3074         {
3075                 if not(self.stored_netname)
3076                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3077                 if(self.stored_netname != self.netname)
3078                 {
3079                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3080                         strunzone(self.stored_netname);
3081                         self.stored_netname = strzone(self.netname);
3082                 }
3083         }
3084
3085         /*
3086         if(g_race)
3087                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3088         */
3089
3090         CSQCMODEL_AUTOUPDATE();
3091 }