qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 142
 143         spot = SelectSpawnPoint (TRUE);
 144         if(!spot)
 145                 error("No spawnpoints for observers?!?\n");
 146         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 147
 148         if(IS_REAL_CLIENT(self))
 149         {
 150                 msg_entity = self;
 151                 WriteByte(MSG_ONE, SVC_SETVIEW);
 152                 WriteEntity(MSG_ONE, self);
 153         }
 154
 155         self.frags = FRAGS_SPECTATOR;
 156
 157         MUTATOR_CALLHOOK(MakePlayerObserver);
 158
 159         Portal_ClearAll(self);
 160
 161         Unfreeze(self);
 162
 163         if(self.alivetime)
 164         {
 165                 if(!warmup_stage)
 166                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 167                 self.alivetime = 0;
 168         }
 169
 170         if(self.vehicle)
 171                 vehicles_exit(VHEF_RELEASE);
 172
 173         WaypointSprite_PlayerDead();
 174
 175         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 176                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 177
 178         if(self.killcount != -666)
 179         {
 180                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 181                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 182                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 183
 184                 if(self.just_joined == FALSE) {
 185                         LogTeamchange(self.playerid, -1, 4);
 186                 } else
 187                         self.just_joined = FALSE;
 188         }
 189
 190         PlayerScore_Clear(self); // clear scores when needed
 191
 192         accuracy_resend(self);
 193
 194         self.spectatortime = time;
 195
 196         self.classname = "observer";
 197         self.iscreature = FALSE;
 198         self.teleportable = TELEPORT_SIMPLE;
 199         self.damagedbycontents = FALSE;
 200         self.health = -666;
 201         self.takedamage = DAMAGE_NO;
 202         self.solid = SOLID_NOT;
 203         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 204         self.flags = FL_CLIENT | FL_NOTARGET;
 205         self.armorvalue = 666;
 206         self.effects = 0;
 207         self.armorvalue = autocvar_g_balance_armor_start;
 208         self.pauserotarmor_finished = 0;
 209         self.pauserothealth_finished = 0;
 210         self.pauseregen_finished = 0;
 211         self.damageforcescale = 0;
 212         self.death_time = 0;
 213         self.respawn_flags = 0;
 214         self.respawn_time = 0;
 215         self.stat_respawn_time = 0;
 216         self.alpha = 0;
 217         self.scale = 0;
 218         self.fade_time = 0;
 219         self.pain_frame = 0;
 220         self.pain_finished = 0;
 221         self.strength_finished = 0;
 222         self.invincible_finished = 0;
 223         self.superweapons_finished = 0;
 224         self.pushltime = 0;
 225         self.istypefrag = 0;
 226         self.think = func_null;
 227         self.nextthink = 0;
 228         self.hook_time = 0;
 229         self.deadflag = DEAD_NO;
 230         self.angles = spot.angles;
 231         self.angles_z = 0;
 232         self.fixangle = TRUE;
 233         self.crouch = FALSE;
 234         self.revival_time = 0;
 235
 236         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 237         self.prevorigin = self.origin;
 238         self.items = 0;
 239         self.weapons = '0 0 0';
 240         self.model = "";
 241         FixPlayermodel();
 242         setmodel(self, "null");
 243         self.drawonlytoclient = self;
 244
 245         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247
 248         self.weapon = 0;
 249         self.weaponname = "";
 250         self.switchingweapon = 0;
 251         self.weaponmodel = "";
 252         self.weaponentity = world;
 253         self.exteriorweaponentity = world;
 254         self.killcount = -666;
 255         self.velocity = '0 0 0';
 256         self.avelocity = '0 0 0';
 257         self.punchangle = '0 0 0';
 258         self.punchvector = '0 0 0';
 259         self.oldvelocity = self.velocity;
 260         self.fire_endtime = -1;
 261 }
 262
 263 .float model_randomizer;
 264 void FixPlayermodel()
 265 {
 266         string defaultmodel;
 267         float defaultskin, chmdl, oldskin, n, i;
 268         vector m1, m2;
 269
 270         defaultmodel = "";
 271         defaultskin = 0;
 272         chmdl = FALSE;
 273
 274         if(autocvar_sv_defaultcharacter == 1)
 275         {
 276                 if(teamplay)
 277                 {
 278                         string s;
 279                         s = Static_Team_ColorName_Lower(self.team);
 280                         if(s != "neutral")
 281                         {
 282                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 283                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 284                         }
 285                 }
 286
 287                 if(defaultmodel == "")
 288                 {
 289                         defaultmodel = autocvar_sv_defaultplayermodel;
 290                         defaultskin = autocvar_sv_defaultplayerskin;
 291                 }
 292
 293                 n = tokenize_console(defaultmodel);
 294                 if(n > 0)
 295                 {
 296                         defaultmodel = argv(floor(n * self.model_randomizer));
 297                         // However, do NOT randomize if the player-selected model is in the list.
 298                         for (i = 0; i < n; ++i)
 299                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 300                                         defaultmodel = argv(i);
 301                 }
 302
 303                 i = strstrofs(defaultmodel, ":", 0);
 304                 if(i >= 0)
 305                 {
 306                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 307                         defaultmodel = substring(defaultmodel, 0, i);
 308                 }
 309         }
 310
 311         if(defaultmodel != "")
 312         {
 313                 if (defaultmodel != self.model)
 314                 {
 315                         m1 = self.mins;
 316                         m2 = self.maxs;
 317                         setplayermodel (self, defaultmodel);
 318                         setsize (self, m1, m2);
 319                         chmdl = TRUE;
 320                 }
 321
 322                 oldskin = self.skin;
 323                 self.skin = defaultskin;
 324         } else {
 325                 if (self.playermodel != self.model || self.playermodel == "")
 326                 {
 327                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 328                         m1 = self.mins;
 329                         m2 = self.maxs;
 330                         setplayermodel (self, self.playermodel);
 331                         setsize (self, m1, m2);
 332                         chmdl = TRUE;
 333                 }
 334
 335                 oldskin = self.skin;
 336                 self.skin = stof(self.playerskin);
 337         }
 338
 339         if(chmdl || oldskin != self.skin) // model or skin has changed
 340         {
 341                 self.species = player_getspecies(); // update species
 342                 UpdatePlayerSounds(); // update skin sounds
 343         }
 344
 345         if(!teamplay)
 346                 if(strlen(autocvar_sv_defaultplayercolors))
 347                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 348                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 349 }
 350
 351 /*
 352 =============
 353 PutClientInServer
 354
 355 Called when a client spawns in the server
 356 =============
 357 */
 358 void PutClientInServer (void)
 359 {
 360         if(IS_BOT_CLIENT(self))
 361                 self.classname = "player";
 362         else if(IS_REAL_CLIENT(self))
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         // reset player keys
 370         self.itemkeys = 0;
 371
 372         MUTATOR_CALLHOOK(PutClientInServer);
 373
 374         if(gameover)
 375                 self.classname = "observer";
 376
 377         if(IS_PLAYER(self))
 378         {
 379                 entity spot, oldself;
 380                 float j;
 381
 382                 accuracy_resend(self);
 383
 384                 if(self.team < 0)
 385                         JoinBestTeam(self, FALSE, TRUE);
 386
 387                 spot = SelectSpawnPoint (FALSE);
 388                 if(!spot)
 389                 {
 390                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 391                         return; // spawn failed
 392                 }
 393
 394                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 395
 396                 self.classname = "player";
 397                 self.wasplayer = TRUE;
 398                 self.iscreature = TRUE;
 399                 self.teleportable = TELEPORT_NORMAL;
 400                 self.damagedbycontents = TRUE;
 401                 self.movetype = MOVETYPE_WALK;
 402                 self.solid = SOLID_SLIDEBOX;
 403                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 404                 if(autocvar_g_playerclip_collisions)
 405                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 406                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 407                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 408                 self.frags = FRAGS_PLAYER;
 409                 if(INDEPENDENT_PLAYERS)
 410                         MAKE_INDEPENDENT_PLAYER(self);
 411                 self.flags = FL_CLIENT;
 412                 if(autocvar__notarget)
 413                         self.flags |= FL_NOTARGET;
 414                 self.takedamage = DAMAGE_AIM;
 415                 self.effects = 0;
 416                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 417                 self.air_finished = time + 12;
 418                 self.dmg = 2;
 419                 if(autocvar_g_balance_nex_charge)
 420                 {
 421                         if(autocvar_g_balance_nex_secondary_chargepool)
 422                                 self.nex_chargepool_ammo = 1;
 423                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 424                 }
 425
 426                 if(warmup_stage)
 427                 {
 428                         self.ammo_shells = warmup_start_ammo_shells;
 429                         self.ammo_nails = warmup_start_ammo_nails;
 430                         self.ammo_rockets = warmup_start_ammo_rockets;
 431                         self.ammo_cells = warmup_start_ammo_cells;
 432                         self.ammo_fuel = warmup_start_ammo_fuel;
 433                         self.health = warmup_start_health;
 434                         self.armorvalue = warmup_start_armorvalue;
 435                         self.weapons = WARMUP_START_WEAPONS;
 436                 }
 437                 else
 438                 {
 439                         self.ammo_shells = start_ammo_shells;
 440                         self.ammo_nails = start_ammo_nails;
 441                         self.ammo_rockets = start_ammo_rockets;
 442                         self.ammo_cells = start_ammo_cells;
 443                         self.ammo_fuel = start_ammo_fuel;
 444                         self.health = start_health;
 445                         self.armorvalue = start_armorvalue;
 446                         self.weapons = start_weapons;
 447                 }
 448
 449                 if(self.weapons & WEPSET_SUPERWEAPONS)
 450                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 451                 else
 452                         self.superweapons_finished = 0;
 453
 454                 if(g_weaponarena_random)
 455                 {
 456                         if(g_weaponarena_random_with_laser)
 457                                 self.weapons &= ~WEPSET_LASER;
 458                         W_RandomWeapons(self, g_weaponarena_random);
 459                         if(g_weaponarena_random_with_laser)
 460                                 self.weapons |= WEPSET_LASER;
 461                 }
 462
 463                 self.items = start_items;
 464
 465                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 466                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 467                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 468                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 469                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 470                 //extend the pause of rotting if client was reset at the beginning of the countdown
 471                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 472                         self.spawnshieldtime += game_starttime - time;
 473                         self.pauserotarmor_finished += game_starttime - time;
 474                         self.pauserothealth_finished += game_starttime - time;
 475                         self.pauseregen_finished += game_starttime - time;
 476                 }
 477                 self.damageforcescale = 2;
 478                 self.death_time = 0;
 479                 self.respawn_flags = 0;
 480                 self.respawn_time = 0;
 481                 self.stat_respawn_time = 0;
 482                 self.scale = 0;
 483                 self.fade_time = 0;
 484                 self.pain_frame = 0;
 485                 self.pain_finished = 0;
 486                 self.strength_finished = 0;
 487                 self.invincible_finished = 0;
 488                 self.pushltime = 0;
 489                 // players have no think function
 490                 self.think = func_null;
 491                 self.nextthink = 0;
 492                 self.hook_time = 0;
 493                 self.dmg_team = 0;
 494                 self.ballistics_density = autocvar_g_ballistics_density_player;
 495
 496                 self.metertime = 0;
 497
 498                 self.deadflag = DEAD_NO;
 499
 500                 self.angles = spot.angles;
 501
 502                 self.angles_z = 0; // never spawn tilted even if the spot says to
 503                 if(IS_BOT_CLIENT(self))
 504                         self.v_angle = self.angles;
 505                 self.fixangle = TRUE; // turn this way immediately
 506                 self.velocity = '0 0 0';
 507                 self.avelocity = '0 0 0';
 508                 self.punchangle = '0 0 0';
 509                 self.punchvector = '0 0 0';
 510                 self.oldvelocity = self.velocity;
 511                 self.fire_endtime = -1;
 512                 self.revival_time = 0;
 513
 514                 entity spawnevent = spawn();
 515                 spawnevent.owner = self;
 516                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 517
 518                 // Cut off any still running player sounds.
 519                 stopsound(self, CH_PLAYER_SINGLE);
 520
 521                 self.model = "";
 522                 FixPlayermodel();
 523                 self.drawonlytoclient = world;
 524
 525                 self.crouch = FALSE;
 526                 self.view_ofs = PL_VIEW_OFS;
 527                 setsize (self, PL_MIN, PL_MAX);
 528                 self.spawnorigin = spot.origin;
 529                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 530                 // don't reset back to last position, even if new position is stuck in solid
 531                 self.oldorigin = self.origin;
 532                 self.prevorigin = self.origin;
 533                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 534                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 535         self.hud = HUD_NORMAL;
 536
 537                 self.event_damage = PlayerDamage;
 538
 539                 self.bot_attack = TRUE;
 540                 self.monster_attack = TRUE;
 541
 542                 self.spider_slowness = 0;
 543
 544                 self.statdraintime = time + 5;
 545                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 546
 547                 if(self.killcount == -666) {
 548                         PlayerScore_Clear(self);
 549                         self.killcount = 0;
 550                 }
 551
 552                 CL_SpawnWeaponentity();
 553                 self.alpha = default_player_alpha;
 554                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 555                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 556
 557                 self.speedrunning = FALSE;
 558
 559                 //stuffcmd(self, "chase_active 0");
 560                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 561
 562                 target_voicescript_clear(self);
 563
 564                 // reset fields the weapons may use
 565                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 566                 {
 567                         weapon_action(j, WR_RESETPLAYER);
 568
 569                         // all weapons must be fully loaded when we spawn
 570                         entity e;
 571                         e = get_weaponinfo(j);
 572                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 573                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 574                 }
 575
 576                 oldself = self;
 577                 self = spot;
 578                         activator = oldself;
 579                                 string s;
 580                                 s = self.target;
 581                                 self.target = string_null;
 582                                 SUB_UseTargets();
 583                                 self.target = s;
 584                         activator = world;
 585                 self = oldself;
 586
 587                 Unfreeze(self);
 588
 589                 spawn_spot = spot;
 590                 MUTATOR_CALLHOOK(PlayerSpawn);
 591
 592                 if(autocvar_spawn_debug)
 593                 {
 594                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 595                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 596                 }
 597
 598                 self.switchweapon = w_getbestweapon(self);
 599                 self.cnt = -1; // W_LastWeapon will not complain
 600                 self.weapon = 0;
 601                 self.weaponname = "";
 602                 self.switchingweapon = 0;
 603
 604                 if(!warmup_stage)
 605                         if(!self.alivetime)
 606                                 self.alivetime = time;
 607
 608                 antilag_clear(self);
 609         }
 610         else if(IS_OBSERVER(self))
 611         {
 612                 PutObserverInServer ();
 613         }
 614 }
 615
 616 .float ebouncefactor, ebouncestop; // electro's values
 617 // TODO do we need all these fields, or should we stop autodetecting runtime
 618 // changes and just have a console command to update this?
 619 float ClientInit_SendEntity(entity to, float sf)
 620 {
 621         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 622         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 635         if(sv_foginterval && world.fog != "")
 636                 WriteString(MSG_ENTITY, world.fog);
 637         else
 638                 WriteString(MSG_ENTITY, "");
 639         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 640         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 641         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 642         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 643         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 644         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 645         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 646         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 647         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 649         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 650         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 651         return TRUE;
 652 }
 653
 654 void ClientInit_CheckUpdate()
 655 {
 656         self.nextthink = time;
 657         if(self.count != autocvar_g_balance_armor_blockpercent)
 658         {
 659                 self.count = autocvar_g_balance_armor_blockpercent;
 660                 self.SendFlags |= 1;
 661         }
 662         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 663         {
 664                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 665                 self.SendFlags |= 1;
 666         }
 667         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 668         {
 669                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 670                 self.SendFlags |= 1;
 671         }
 672         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 673         {
 674                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 675                 self.SendFlags |= 1;
 676         }
 677         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 678         {
 679                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 680                 self.SendFlags |= 1;
 681         }
 682 }
 683
 684 void ClientInit_Spawn()
 685 {
 686         entity o;
 687         entity e;
 688         e = spawn();
 689         e.classname = "clientinit";
 690         e.think = ClientInit_CheckUpdate;
 691         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 692
 693         o = self;
 694         self = e;
 695         ClientInit_CheckUpdate();
 696         self = o;
 697 }
 698
 699 /*
 700 =============
 701 SetNewParms
 702 =============
 703 */
 704 void SetNewParms (void)
 705 {
 706         // initialize parms for a new player
 707         parm1 = -(86400 * 366);
 708 }
 709
 710 /*
 711 =============
 712 SetChangeParms
 713 =============
 714 */
 715 void SetChangeParms (void)
 716 {
 717         // save parms for level change
 718         parm1 = self.parm_idlesince - time;
 719 }
 720
 721 /*
 722 =============
 723 DecodeLevelParms
 724 =============
 725 */
 726 void DecodeLevelParms (void)
 727 {
 728         // load parms
 729         self.parm_idlesince = parm1;
 730         if(self.parm_idlesince == -(86400 * 366))
 731                 self.parm_idlesince = time;
 732
 733         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 734         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 735 }
 736
 737 /*
 738 =============
 739 ClientKill
 740
 741 Called when a client types 'kill' in the console
 742 =============
 743 */
 744
 745 .float clientkill_nexttime;
 746 void ClientKill_Now_TeamChange()
 747 {
 748         if(self.killindicator_teamchange == -1)
 749         {
 750                 JoinBestTeam( self, FALSE, TRUE );
 751         }
 752         else if(self.killindicator_teamchange == -2)
 753         {
 754                 if(blockSpectators)
 755                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 756                 PutObserverInServer();
 757         }
 758         else
 759                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 760         self.killindicator_teamchange = 0;
 761 }
 762
 763 void ClientKill_Now()
 764 {
 765         if(self.vehicle)
 766         {
 767             vehicles_exit(VHEF_RELEASE);
 768             if(!self.killindicator_teamchange)
 769             {
 770             self.vehicle_health = -1;
 771             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 772             }
 773         }
 774
 775         if(self.killindicator && !wasfreed(self.killindicator))
 776                 remove(self.killindicator);
 777
 778         self.killindicator = world;
 779
 780         if(self.killindicator_teamchange)
 781                 ClientKill_Now_TeamChange();
 782
 783         // in any case:
 784         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 785
 786         // now I am sure the player IS dead
 787 }
 788 void KillIndicator_Think()
 789 {
 790         if (gameover)
 791         {
 792                 self.owner.killindicator = world;
 793                 remove(self);
 794                 return;
 795         }
 796
 797         if (self.owner.alpha < 0 && !self.owner.vehicle)
 798         {
 799                 self.owner.killindicator = world;
 800                 remove(self);
 801                 return;
 802         }
 803
 804         if(self.cnt <= 0)
 805         {
 806                 self = self.owner;
 807                 ClientKill_Now(); // no oldself needed
 808                 return;
 809         }
 810     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 811     {
 812         self.nextthink = time + 1;
 813         self.cnt -= 1;
 814     }
 815         else
 816         {
 817                 if(self.cnt <= 10)
 818                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 819                 if(IS_REAL_CLIENT(self.owner))
 820                 {
 821                         if(self.cnt <= 10)
 822                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 823                 }
 824                 self.nextthink = time + 1;
 825                 self.cnt -= 1;
 826         }
 827 }
 828
 829 float clientkilltime;
 830 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 831 {
 832         float killtime;
 833         float starttime;
 834         entity e;
 835
 836         if (gameover)
 837                 return;
 838
 839         killtime = autocvar_g_balance_kill_delay;
 840
 841         if(g_race_qualifying || g_cts)
 842                 killtime = 0;
 843
 844     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 845     {
 846                 remove(self.killindicator);
 847                 self.killindicator = world;
 848
 849         ClientKill_Now(); // allow instant kill in this case
 850         return;
 851     }
 852
 853         self.killindicator_teamchange = targetteam;
 854
 855     if(!self.killindicator)
 856         {
 857                 if(self.deadflag == DEAD_NO)
 858                 {
 859                         killtime = max(killtime, self.clientkill_nexttime - time);
 860                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 861                 }
 862
 863                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 864                 {
 865                         ClientKill_Now();
 866                 }
 867                 else
 868                 {
 869                         starttime = max(time, clientkilltime);
 870
 871                         self.killindicator = spawn();
 872                         self.killindicator.owner = self;
 873                         self.killindicator.scale = 0.5;
 874                         setattachment(self.killindicator, self, "");
 875                         setorigin(self.killindicator, '0 0 52');
 876                         self.killindicator.think = KillIndicator_Think;
 877                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 878                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 879                         self.killindicator.cnt = ceil(killtime);
 880                         self.killindicator.count = bound(0, ceil(killtime), 10);
 881                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 882
 883                         for(e = world; (e = find(e, classname, "body")) != world; )
 884                         {
 885                                 if(e.enemy != self)
 886                                         continue;
 887                                 e.killindicator = spawn();
 888                                 e.killindicator.owner = e;
 889                                 e.killindicator.scale = 0.5;
 890                                 setattachment(e.killindicator, e, "");
 891                                 setorigin(e.killindicator, '0 0 52');
 892                                 e.killindicator.think = KillIndicator_Think;
 893                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 894                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 895                                 e.killindicator.cnt = ceil(killtime);
 896                         }
 897                         self.lip = 0;
 898                 }
 899         }
 900         if(self.killindicator)
 901         {
 902                 if(targetteam == 0) // just die
 903                 {
 904                         self.killindicator.colormod = '0 0 0';
 905                         if(IS_REAL_CLIENT(self))
 906                         if(self.killindicator.cnt > 0)
 907                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 908                 }
 909                 else if(targetteam == -1) // auto
 910                 {
 911                         self.killindicator.colormod = '0 1 0';
 912                         if(IS_REAL_CLIENT(self))
 913                         if(self.killindicator.cnt > 0)
 914                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 915                 }
 916                 else if(targetteam == -2) // spectate
 917                 {
 918                         self.killindicator.colormod = '0.5 0.5 0.5';
 919                         if(IS_REAL_CLIENT(self))
 920                         if(self.killindicator.cnt > 0)
 921                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 922                 }
 923                 else
 924                 {
 925                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 926                         if(IS_REAL_CLIENT(self))
 927                         if(self.killindicator.cnt > 0)
 928                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 929                 }
 930         }
 931
 932 }
 933
 934 void ClientKill (void)
 935 {
 936         if(gameover) return;
 937         if(self.player_blocked) return;
 938         if(self.frozen) return;
 939
 940         ClientKill_TeamChange(0);
 941 }
 942
 943 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 944 {
 945     e.killindicator = spawn();
 946     e.killindicator.owner = e;
 947     e.killindicator.think = KillIndicator_Think;
 948     e.killindicator.nextthink = time + (e.lip) * 0.05;
 949     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 950     e.killindicator.health = 1; // this is used to indicate that it should be silent
 951     e.lip = 0;
 952 }
 953
 954 void FixClientCvars(entity e)
 955 {
 956         // send prediction settings to the client
 957         stuffcmd(e, "\nin_bindmap 0 0\n");
 958         if(g_race || g_cts)
 959                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 960         if(autocvar_g_antilag == 3) // client side hitscan
 961                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 962         if(autocvar_sv_gentle)
 963                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 964         /*
 965          * we no longer need to stuff this. Remove this comment block if you feel
 966          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 967         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 968         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 969         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 970         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 971         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 972         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 973         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 974         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 975         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 976         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 977         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 978         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 979         stuffcmd(e, "cl_movement_edgefriction 1\n");
 980          */
 981 }
 982
 983 float PlayerInIDList(entity p, string idlist)
 984 {
 985         float n, i;
 986         string s;
 987
 988         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 989         if (!p.crypto_idfp)
 990                 return 0;
 991
 992         // this function allows abbreviated player IDs too!
 993         n = tokenize_console(idlist);
 994         for(i = 0; i < n; ++i)
 995         {
 996                 s = argv(i);
 997                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 998                         return 1;
 999         }
1000
1001         return 0;
1002 }
1003
1004 /*
1005 =============
1006 ClientConnect
1007
1008 Called when a client connects to the server
1009 =============
1010 */
1011 void DecodeLevelParms (void);
1012 //void dom_player_join_team(entity pl);
1013 void set_dom_state(entity e);
1014 void ClientConnect (void)
1015 {
1016         float t;
1017
1018         if(IS_CLIENT(self))
1019         {
1020                 print("Warning: ClientConnect, but already connected!\n");
1021                 return;
1022         }
1023
1024         if(Ban_MaybeEnforceBanOnce(self))
1025                 return;
1026
1027         DecodeLevelParms();
1028
1029 #ifdef WATERMARK
1030         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1031 #endif
1032
1033         self.classname = "player_joining";
1034
1035         self.flags = FL_CLIENT;
1036         self.version_nagtime = time + 10 + random() * 10;
1037
1038         if(player_count<0)
1039         {
1040                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1041                 player_count = 0;
1042         }
1043
1044         PlayerScore_Attach(self);
1045         ClientData_Attach();
1046         accuracy_init(self);
1047
1048         bot_clientconnect();
1049
1050         playerdemo_init();
1051
1052         anticheat_init();
1053
1054         // identify the right forced team
1055         if(autocvar_g_campaign)
1056         {
1057                 if(IS_REAL_CLIENT(self)) // only players, not bots
1058                 {
1059                         switch(autocvar_g_campaign_forceteam)
1060                         {
1061                                 case 1: self.team_forced = NUM_TEAM_1; break;
1062                                 case 2: self.team_forced = NUM_TEAM_2; break;
1063                                 case 3: self.team_forced = NUM_TEAM_3; break;
1064                                 case 4: self.team_forced = NUM_TEAM_4; break;
1065                                 default: self.team_forced = 0;
1066                         }
1067                 }
1068         }
1069         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1070                 self.team_forced = NUM_TEAM_1;
1071         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1072                 self.team_forced = NUM_TEAM_2;
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1074                 self.team_forced = NUM_TEAM_3;
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1076                 self.team_forced = NUM_TEAM_4;
1077         else if(autocvar_g_forced_team_otherwise == "red")
1078                 self.team_forced = NUM_TEAM_1;
1079         else if(autocvar_g_forced_team_otherwise == "blue")
1080                 self.team_forced = NUM_TEAM_2;
1081         else if(autocvar_g_forced_team_otherwise == "yellow")
1082                 self.team_forced = NUM_TEAM_3;
1083         else if(autocvar_g_forced_team_otherwise == "pink")
1084                 self.team_forced = NUM_TEAM_4;
1085         else if(autocvar_g_forced_team_otherwise == "spectate")
1086                 self.team_forced = -1;
1087         else if(autocvar_g_forced_team_otherwise == "spectator")
1088                 self.team_forced = -1;
1089         else
1090                 self.team_forced = 0;
1091
1092         if(!teamplay)
1093                 if(self.team_forced > 0)
1094                         self.team_forced = 0;
1095
1096         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1097
1098         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1099                 self.classname = "observer";
1100         } else {
1101                 if(teamplay)
1102                 {
1103                         if(autocvar_g_balance_teams)
1104                         {
1105                                 self.classname = "player";
1106                                 campaign_bots_may_start = 1;
1107                         }
1108                         else
1109                         {
1110                                 self.classname = "observer"; // do it anyway
1111                         }
1112                 }
1113                 else
1114                 {
1115                         self.classname = "player";
1116                         campaign_bots_may_start = 1;
1117                 }
1118         }
1119
1120         self.playerid = (playerid_last = playerid_last + 1);
1121
1122         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1123
1124     if(IS_BOT_CLIENT(self))
1125         PlayerStats_AddPlayer(self);
1126
1127         if(autocvar_sv_eventlog)
1128                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1129
1130         LogTeamchange(self.playerid, self.team, 1);
1131
1132         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1133
1134         self.netname_previous = strzone(self.netname);
1135
1136         if(IS_PLAYER(self) && teamplay)
1137                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1138         else
1139                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1140
1141         stuffcmd(self, strcat(clientstuff, "\n"));
1142         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1143
1144         FixClientCvars(self);
1145
1146         // spawnfunc_waypoint sprites
1147         WaypointSprite_InitClient(self);
1148
1149         // Wazat's grappling hook
1150         SetGrappleHookBindings();
1151
1152         // get version info from player
1153         stuffcmd(self, "cmd clientversion $gameversion\n");
1154
1155         // get other cvars from player
1156         GetCvars(0);
1157
1158         // notify about available teams
1159         if(teamplay)
1160         {
1161                 CheckAllowedTeams(self);
1162                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1163                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1164         }
1165         else
1166                 stuffcmd(self, "set _teams_available 0\n");
1167
1168         attach_entcs();
1169
1170         bot_relinkplayerlist();
1171
1172         self.spectatortime = time;
1173         if(blockSpectators)
1174         {
1175                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1176         }
1177
1178         self.jointime = time;
1179         self.allowed_timeouts = autocvar_sv_timeout_number;
1180
1181         if(IS_REAL_CLIENT(self))
1182         {
1183                 if(!autocvar_g_campaign)
1184                 {
1185                         self.motd_actived_time = -1;
1186                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1187                 }
1188
1189                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1190                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1191         }
1192
1193         if(!sv_foginterval && world.fog != "")
1194                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1195
1196         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1197         {
1198                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1199                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1200         }
1201         else
1202                 self.hitplotfh = -1;
1203
1204         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1205                 send_CSQC_teamnagger();
1206
1207         CheatInitClient();
1208
1209         CSQCMODEL_AUTOINIT();
1210
1211         self.model_randomizer = random();
1212
1213         if(IS_REAL_CLIENT(self))
1214                 sv_notice_join();
1215
1216         MUTATOR_CALLHOOK(ClientConnect);
1217 }
1218 /*
1219 =============
1220 ClientDisconnect
1221
1222 Called when a client disconnects from the server
1223 =============
1224 */
1225 .entity chatbubbleentity;
1226 void ReadyCount();
1227 void ClientDisconnect (void)
1228 {
1229         if(self.vehicle)
1230             vehicles_exit(VHEF_RELEASE);
1231
1232         if (!IS_CLIENT(self))
1233         {
1234                 print("Warning: ClientDisconnect without ClientConnect\n");
1235                 return;
1236         }
1237
1238         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1239
1240         PlayerStats_AddGlobalInfo(self);
1241
1242         CheatShutdownClient();
1243
1244         if(self.hitplotfh >= 0)
1245         {
1246                 fclose(self.hitplotfh);
1247                 self.hitplotfh = -1;
1248         }
1249
1250         anticheat_report();
1251         anticheat_shutdown();
1252
1253         playerdemo_shutdown();
1254
1255         bot_clientdisconnect();
1256
1257         if(self.entcs)
1258                 detach_entcs();
1259
1260         if(autocvar_sv_eventlog)
1261                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1262
1263         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1264
1265         MUTATOR_CALLHOOK(ClientDisconnect);
1266
1267         Portal_ClearAll(self);
1268
1269         Unfreeze(self);
1270
1271         RemoveGrapplingHook(self);
1272
1273         // Here, everything has been done that requires this player to be a client.
1274
1275         self.flags &= ~FL_CLIENT;
1276
1277         if (self.chatbubbleentity)
1278                 remove (self.chatbubbleentity);
1279
1280         if (self.killindicator)
1281                 remove (self.killindicator);
1282
1283         WaypointSprite_PlayerGone();
1284
1285         bot_relinkplayerlist();
1286
1287         accuracy_free(self);
1288         ClientData_Detach();
1289         PlayerScore_Detach(self);
1290
1291         if(self.netname_previous)
1292                 strunzone(self.netname_previous);
1293         if(self.clientstatus)
1294                 strunzone(self.clientstatus);
1295         if(self.weaponorder_byimpulse)
1296                 strunzone(self.weaponorder_byimpulse);
1297
1298         ClearPlayerSounds();
1299
1300         if(self.personal)
1301                 remove(self.personal);
1302
1303         self.playerid = 0;
1304         ReadyCount();
1305
1306         // free cvars
1307         GetCvars(-1);
1308 }
1309
1310 .float BUTTON_CHAT;
1311 void ChatBubbleThink()
1312 {
1313         self.nextthink = time;
1314         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1315         {
1316                 if(self.owner) // but why can that ever be world?
1317                         self.owner.chatbubbleentity = world;
1318                 remove(self);
1319                 return;
1320         }
1321         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1322 #ifdef TETRIS
1323                 || self.owner.tetris_on
1324 #endif
1325         )
1326                 self.model = self.mdl;
1327         else
1328                 self.model = "";
1329 }
1330
1331 void UpdateChatBubble()
1332 {
1333         if (self.alpha < 0)
1334                 return;
1335         // spawn a chatbubble entity if needed
1336         if (!self.chatbubbleentity)
1337         {
1338                 self.chatbubbleentity = spawn();
1339                 self.chatbubbleentity.owner = self;
1340                 self.chatbubbleentity.exteriormodeltoclient = self;
1341                 self.chatbubbleentity.think = ChatBubbleThink;
1342                 self.chatbubbleentity.nextthink = time;
1343                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1344                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1345                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1346                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1347                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1348                 self.chatbubbleentity.model = "";
1349                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1350         }
1351 }
1352
1353
1354 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1355 // added to the model skins
1356 /*void UpdateColorModHack()
1357 {
1358         float c;
1359         c = self.clientcolors & 15;
1360         // LordHavoc: only bothering to support white, green, red, yellow, blue
1361              if (!teamplay) self.colormod = '0 0 0';
1362         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1363         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1364         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1365         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1366         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1367         else self.colormod = '1 1 1';
1368 }*/
1369
1370 void respawn(void)
1371 {
1372         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1373         {
1374                 self.solid = SOLID_NOT;
1375                 self.takedamage = DAMAGE_NO;
1376                 self.movetype = MOVETYPE_FLY;
1377                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1378                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1379                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1380                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1381                 if(autocvar_g_respawn_ghosts_maxtime)
1382                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1383         }
1384
1385         CopyBody(1);
1386
1387         self.effects |= EF_NODRAW; // prevent another CopyBody
1388         PutClientInServer();
1389 }
1390
1391 void play_countdown(float finished, string samp)
1392 {
1393         if(IS_REAL_CLIENT(self))
1394                 if(floor(finished - time - frametime) != floor(finished - time))
1395                         if(finished - time < 6)
1396                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1397 }
1398
1399 void player_powerups (void)
1400 {
1401         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1402         olditems = self.items;
1403
1404         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1405                 self.modelflags |= MF_ROCKET;
1406         else
1407                 self.modelflags &= ~MF_ROCKET;
1408
1409         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1410
1411         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1412                 return;
1413
1414         Fire_ApplyDamage(self);
1415         Fire_ApplyEffect(self);
1416
1417         if (!g_instagib)
1418         {
1419                 if (self.items & IT_STRENGTH)
1420                 {
1421                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1422                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1423                         if (time > self.strength_finished)
1424                         {
1425                                 self.items = self.items - (self.items & IT_STRENGTH);
1426                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1427                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1428                         }
1429                 }
1430                 else
1431                 {
1432                         if (time < self.strength_finished)
1433                         {
1434                                 self.items = self.items | IT_STRENGTH;
1435                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1436                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1437                         }
1438                 }
1439                 if (self.items & IT_INVINCIBLE)
1440                 {
1441                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1442                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1443                         if (time > self.invincible_finished)
1444                         {
1445                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1446                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1447                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1448                         }
1449                 }
1450                 else
1451                 {
1452                         if (time < self.invincible_finished)
1453                         {
1454                                 self.items = self.items | IT_INVINCIBLE;
1455                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1456                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1457                         }
1458                 }
1459                 if (self.items & IT_SUPERWEAPON)
1460                 {
1461                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1462                         {
1463                                 self.superweapons_finished = 0;
1464                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1465                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1466                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1467                         }
1468                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1469                         {
1470                                 // don't let them run out
1471                         }
1472                         else
1473                         {
1474                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1475                                 if (time > self.superweapons_finished)
1476                                 {
1477                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1478                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1479                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1480                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1481                                 }
1482                         }
1483                 }
1484                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1485                 {
1486                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1487                         {
1488                                 self.items = self.items | IT_SUPERWEAPON;
1489                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1490                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1491                         }
1492                         else
1493                         {
1494                                 self.superweapons_finished = 0;
1495                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1496                         }
1497                 }
1498                 else
1499                 {
1500                         self.superweapons_finished = 0;
1501                 }
1502         }
1503
1504         if(autocvar_g_nodepthtestplayers)
1505                 self.effects = self.effects | EF_NODEPTHTEST;
1506
1507         if(autocvar_g_fullbrightplayers)
1508                 self.effects = self.effects | EF_FULLBRIGHT;
1509
1510         if (time >= game_starttime)
1511         if (time < self.spawnshieldtime)
1512                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1513
1514         MUTATOR_CALLHOOK(PlayerPowerups);
1515 }
1516
1517 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1518 {
1519         if(current > stable)
1520                 return current;
1521         else if(current > stable - 0.25) // when close enough, "snap"
1522                 return stable;
1523         else
1524                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1525 }
1526
1527 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1528 {
1529         if(current < stable)
1530                 return current;
1531         else if(current < stable + 0.25) // when close enough, "snap"
1532                 return stable;
1533         else
1534                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1535 }
1536
1537 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1538 {
1539         if(current > rotstable)
1540         {
1541                 if(rotframetime > 0)
1542                 {
1543                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1544                         current = max(rotstable, current - rotlinear * rotframetime);
1545                 }
1546         }
1547         else if(current < regenstable)
1548         {
1549                 if(regenframetime > 0)
1550                 {
1551                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1552                         current = min(regenstable, current + regenlinear * regenframetime);
1553                 }
1554         }
1555
1556         if(current > limit)
1557                 current = limit;
1558
1559         return current;
1560 }
1561
1562 void player_regen (void)
1563 {
1564         float max_mod, regen_mod, rot_mod, limit_mod;
1565         max_mod = regen_mod = rot_mod = limit_mod = 1;
1566         regen_mod_max = max_mod;
1567         regen_mod_regen = regen_mod;
1568         regen_mod_rot = rot_mod;
1569         regen_mod_limit = limit_mod;
1570         if(!MUTATOR_CALLHOOK(PlayerRegen))
1571         if(!self.frozen)
1572         {
1573                 float minh, mina, maxh, maxa, limith, limita;
1574                 maxh = autocvar_g_balance_health_rotstable;
1575                 maxa = autocvar_g_balance_armor_rotstable;
1576                 minh = autocvar_g_balance_health_regenstable;
1577                 mina = autocvar_g_balance_armor_regenstable;
1578                 limith = autocvar_g_balance_health_limit;
1579                 limita = autocvar_g_balance_armor_limit;
1580
1581                 max_mod = regen_mod_max;
1582                 regen_mod = regen_mod_regen;
1583                 rot_mod = regen_mod_rot;
1584                 limit_mod = regen_mod_limit;
1585
1586                 maxh = maxh * max_mod;
1587                 minh = minh * max_mod;
1588                 limith = limith * limit_mod;
1589                 limita = limita * limit_mod;
1590
1591                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1592                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1593         }
1594
1595         // if player rotted to death...  die!
1596         // check this outside above checks, as player may still be able to rot to death
1597         if(self.health < 1)
1598         {
1599                 if(self.vehicle)
1600                         vehicles_exit(VHEF_RELEASE);
1601                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1602         }
1603
1604         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1605         {
1606                 float minf, maxf, limitf;
1607
1608                 maxf = autocvar_g_balance_fuel_rotstable;
1609                 minf = autocvar_g_balance_fuel_regenstable;
1610                 limitf = autocvar_g_balance_fuel_limit;
1611
1612                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1613         }
1614 }
1615
1616 float zoomstate_set;
1617 void SetZoomState(float z)
1618 {
1619         if(z != self.zoomstate)
1620         {
1621                 self.zoomstate = z;
1622                 ClientData_Touch(self);
1623         }
1624         zoomstate_set = 1;
1625 }
1626
1627 void GetPressedKeys(void) {
1628         MUTATOR_CALLHOOK(GetPressedKeys);
1629         if (self.movement_x > 0) // get if movement keys are pressed
1630         {       // forward key pressed
1631                 self.pressedkeys |= KEY_FORWARD;
1632                 self.pressedkeys &= ~KEY_BACKWARD;
1633         }
1634         else if (self.movement_x < 0)
1635         {       // backward key pressed
1636                 self.pressedkeys |= KEY_BACKWARD;
1637                 self.pressedkeys &= ~KEY_FORWARD;
1638         }
1639         else
1640         {       // no x input
1641                 self.pressedkeys &= ~KEY_FORWARD;
1642                 self.pressedkeys &= ~KEY_BACKWARD;
1643         }
1644
1645         if (self.movement_y > 0)
1646         {       // right key pressed
1647                 self.pressedkeys |= KEY_RIGHT;
1648                 self.pressedkeys &= ~KEY_LEFT;
1649         }
1650         else if (self.movement_y < 0)
1651         {       // left key pressed
1652                 self.pressedkeys |= KEY_LEFT;
1653                 self.pressedkeys &= ~KEY_RIGHT;
1654         }
1655         else
1656         {       // no y input
1657                 self.pressedkeys &= ~KEY_RIGHT;
1658                 self.pressedkeys &= ~KEY_LEFT;
1659         }
1660
1661         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1662                 self.pressedkeys |= KEY_JUMP;
1663         else
1664                 self.pressedkeys &= ~KEY_JUMP;
1665         if (self.BUTTON_CROUCH)
1666                 self.pressedkeys |= KEY_CROUCH;
1667         else
1668                 self.pressedkeys &= ~KEY_CROUCH;
1669
1670         if (self.BUTTON_ATCK)
1671                 self.pressedkeys |= KEY_ATCK;
1672         else
1673                 self.pressedkeys &= ~KEY_ATCK;
1674         if (self.BUTTON_ATCK2)
1675                 self.pressedkeys |= KEY_ATCK2;
1676         else
1677                 self.pressedkeys &= ~KEY_ATCK2;
1678 }
1679
1680 /*
1681 ======================
1682 spectate mode routines
1683 ======================
1684 */
1685
1686 void SpectateCopy(entity spectatee) {
1687         other = spectatee;
1688         MUTATOR_CALLHOOK(SpectateCopy);
1689         self.armortype = spectatee.armortype;
1690         self.armorvalue = spectatee.armorvalue;
1691         self.ammo_cells = spectatee.ammo_cells;
1692         self.ammo_shells = spectatee.ammo_shells;
1693         self.ammo_nails = spectatee.ammo_nails;
1694         self.ammo_rockets = spectatee.ammo_rockets;
1695         self.ammo_fuel = spectatee.ammo_fuel;
1696         self.clip_load = spectatee.clip_load;
1697         self.clip_size = spectatee.clip_size;
1698         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1699         self.health = spectatee.health;
1700         self.impulse = 0;
1701         self.items = spectatee.items;
1702         self.last_pickup = spectatee.last_pickup;
1703         self.hit_time = spectatee.hit_time;
1704         self.metertime = spectatee.metertime;
1705         self.strength_finished = spectatee.strength_finished;
1706         self.invincible_finished = spectatee.invincible_finished;
1707         self.pressedkeys = spectatee.pressedkeys;
1708         self.weapons = spectatee.weapons;
1709         self.switchweapon = spectatee.switchweapon;
1710         self.switchingweapon = spectatee.switchingweapon;
1711         self.weapon = spectatee.weapon;
1712         self.nex_charge = spectatee.nex_charge;
1713         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1714         self.hagar_load = spectatee.hagar_load;
1715         self.minelayer_mines = spectatee.minelayer_mines;
1716         self.punchangle = spectatee.punchangle;
1717         self.view_ofs = spectatee.view_ofs;
1718         self.velocity = spectatee.velocity;
1719         self.dmg_take = spectatee.dmg_take;
1720         self.dmg_save = spectatee.dmg_save;
1721         self.dmg_inflictor = spectatee.dmg_inflictor;
1722         self.v_angle = spectatee.v_angle;
1723         self.angles = spectatee.v_angle;
1724         self.frozen = spectatee.frozen;
1725         self.revive_progress = spectatee.revive_progress;
1726         if(!self.BUTTON_USE)
1727                 self.fixangle = TRUE;
1728         setorigin(self, spectatee.origin);
1729         setsize(self, spectatee.mins, spectatee.maxs);
1730         SetZoomState(spectatee.zoomstate);
1731
1732     anticheat_spectatecopy(spectatee);
1733         self.hud = spectatee.hud;
1734         if(spectatee.vehicle)
1735     {
1736         self.fixangle = FALSE;
1737         //self.velocity = spectatee.vehicle.velocity;
1738         self.vehicle_health = spectatee.vehicle_health;
1739         self.vehicle_shield = spectatee.vehicle_shield;
1740         self.vehicle_energy = spectatee.vehicle_energy;
1741         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1742         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1743         self.vehicle_reload1 = spectatee.vehicle_reload1;
1744         self.vehicle_reload2 = spectatee.vehicle_reload2;
1745
1746         msg_entity = self;
1747
1748         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1749             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1750             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1751             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1752
1753         //WriteByte (MSG_ONE, SVC_SETVIEW);
1754         //    WriteEntity(MSG_ONE, self);
1755         //makevectors(spectatee.v_angle);
1756         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1757     }
1758 }
1759
1760 float SpectateUpdate() {
1761         if(!self.enemy)
1762             return 0;
1763
1764         if (self == self.enemy)
1765                 return 0;
1766
1767         if (!IS_PLAYER(self.enemy))
1768                 return 0;
1769
1770         SpectateCopy(self.enemy);
1771
1772         return 1;
1773 }
1774
1775
1776 float SpectateSet()
1777 {
1778         if(self.enemy.classname != "player")
1779                 return FALSE;
1780         /*if(self.enemy.vehicle)
1781         {
1782
1783                 msg_entity = self;
1784                 WriteByte(MSG_ONE, SVC_SETVIEW);
1785                 WriteEntity(MSG_ONE, self.enemy);
1786                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1787
1788                 self.movetype = MOVETYPE_NONE;
1789                 accuracy_resend(self);
1790         }
1791         else
1792         {*/
1793                 msg_entity = self;
1794                 WriteByte(MSG_ONE, SVC_SETVIEW);
1795                 WriteEntity(MSG_ONE, self.enemy);
1796                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1797                 self.movetype = MOVETYPE_NONE;
1798                 accuracy_resend(self);
1799
1800                 if(!SpectateUpdate())
1801                         PutObserverInServer();
1802         //}
1803         return TRUE;
1804 }
1805
1806 float Spectate(entity pl)
1807 {
1808         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1809         if(pl.team != self.team)
1810                 return 0;
1811
1812         self.enemy = pl;
1813         return SpectateSet();
1814 }
1815
1816 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1817 entity CA_SpectateNext(entity start) {
1818         if (start.team == self.team) {
1819                 return start;
1820         }
1821
1822         other = start;
1823         // continue from current player
1824         while(other && other.team != self.team) {
1825                 other = find(other, classname, "player");
1826         }
1827
1828         if (!other) {
1829                 // restart from begining
1830                 other = find(other, classname, "player");
1831                 while(other && other.team != self.team) {
1832                         other = find(other, classname, "player");
1833                 }
1834         }
1835
1836         return other;
1837 }
1838
1839 float SpectateNext()
1840 {
1841         other = find(self.enemy, classname, "player");
1842
1843         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1844                 // CA and ca players when spectating enemies is forbidden
1845                 other = CA_SpectateNext(other);
1846         } else {
1847                 // other modes and ca spectators or spectating enemies is allowed
1848                 if (!other)
1849                         other = find(other, classname, "player");
1850         }
1851
1852         if (other)
1853                 self.enemy = other;
1854
1855         return SpectateSet();
1856 }
1857
1858 float SpectatePrev()
1859 {
1860         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1861         other = findchain(classname, "player");
1862         if (!other) // no player
1863                 return FALSE;
1864
1865         entity first = other;
1866         // skip players until current spectated player
1867         if(self.enemy)
1868         while(other && other != self.enemy)
1869                 other = other.chain;
1870
1871         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1872         {
1873                 do { other = other.chain; }
1874                 while(other && other.team != self.team);
1875
1876                 if (!other)
1877                 {
1878                         other = first;
1879                         while(other.team != self.team)
1880                                 other = other.chain;
1881                         if(other == self.enemy)
1882                                 return TRUE;
1883                 }
1884         }
1885         else
1886         {
1887                 if(other.chain)
1888                         other = other.chain;
1889                 else
1890                         other = first;
1891         }
1892         self.enemy = other;
1893         return SpectateSet();
1894 }
1895
1896 /*
1897 =============
1898 ShowRespawnCountdown()
1899
1900 Update a respawn countdown display.
1901 =============
1902 */
1903 void ShowRespawnCountdown()
1904 {
1905         float number;
1906         if(self.deadflag == DEAD_NO) // just respawned?
1907                 return;
1908         else
1909         {
1910                 number = ceil(self.respawn_time - time);
1911                 if(number <= 0)
1912                         return;
1913                 if(number <= self.respawn_countdown)
1914                 {
1915                         self.respawn_countdown = number - 1;
1916                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1917                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1918                 }
1919         }
1920 }
1921
1922 void LeaveSpectatorMode()
1923 {
1924         if(self.caplayer)
1925                 return;
1926         if(nJoinAllowed(self))
1927         {
1928                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1929                 {
1930                         self.classname = "player";
1931                         nades_RemoveBonus(self);
1932
1933                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1934                                 { JoinBestTeam(self, FALSE, TRUE); }
1935
1936                         if(autocvar_g_campaign)
1937                                 { campaign_bots_may_start = 1; }
1938
1939                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1940
1941                         PutClientInServer();
1942
1943                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1944                 }
1945                 else
1946                         stuffcmd(self, "menu_showteamselect\n");
1947         }
1948         else
1949         {
1950                 // Player may not join because g_maxplayers is set
1951                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1952         }
1953 }
1954
1955 /**
1956  * Determines whether the player is allowed to join. This depends on cvar
1957  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1958  * it checks whether the number of currently playing players exceeds g_maxplayers.
1959  * @return int number of free slots for players, 0 if none
1960  */
1961 float nJoinAllowed(entity ignore) {
1962         if(!ignore)
1963         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1964         // so report 0 free slots if restricted
1965         {
1966                 if(autocvar_g_forced_team_otherwise == "spectate")
1967                         return 0;
1968                 if(autocvar_g_forced_team_otherwise == "spectator")
1969                         return 0;
1970         }
1971
1972         if(self.team_forced < 0)
1973                 return 0; // forced spectators can never join
1974
1975         // TODO simplify this
1976         entity e;
1977         float totalClients = 0;
1978         FOR_EACH_CLIENT(e)
1979                 if(e != ignore)
1980                         totalClients += 1;
1981
1982         if (!autocvar_g_maxplayers)
1983                 return maxclients - totalClients;
1984
1985         float currentlyPlaying = 0;
1986         FOR_EACH_REALCLIENT(e)
1987                 if(IS_PLAYER(e) || e.caplayer == 1)
1988                         currentlyPlaying += 1;
1989
1990         if(currentlyPlaying < autocvar_g_maxplayers)
1991                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1992
1993         return 0;
1994 }
1995
1996 /**
1997  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1998  * g_maxplayers_spectator_blocktime seconds
1999  */
2000 void checkSpectatorBlock() {
2001         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2002                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2003                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2004                         dropclient(self);
2005                 }
2006         }
2007 }
2008
2009 void PrintWelcomeMessage()
2010 {
2011         if(self.motd_actived_time == 0)
2012         {
2013                 if (autocvar_g_campaign) {
2014                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2015                                 self.motd_actived_time = time;
2016                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2017                         }
2018                 } else {
2019                         if (self.BUTTON_INFO) {
2020                                 self.motd_actived_time = time;
2021                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2022                         }
2023                 }
2024         }
2025         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2026         {
2027                 if (autocvar_g_campaign) {
2028                         if (self.BUTTON_INFO)
2029                                 self.motd_actived_time = time;
2030                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2031                                 self.motd_actived_time = 0;
2032                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2033                         }
2034                 } else {
2035                         if (self.BUTTON_INFO)
2036                                 self.motd_actived_time = time;
2037                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2038                                 self.motd_actived_time = 0;
2039                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2040                         }
2041                 }
2042         }
2043         else //if(self.motd_actived_time < 0) // just connected, motd is active
2044         {
2045                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2046                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2047                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2048                 {
2049                         // instanctly hide MOTD
2050                         self.motd_actived_time = 0;
2051                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2052                 }
2053         }
2054 }
2055
2056 void ObserverThink()
2057 {
2058         float prefered_movetype;
2059         if (self.flags & FL_JUMPRELEASED) {
2060                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2061                         self.flags &= ~FL_JUMPRELEASED;
2062                         self.flags |= FL_SPAWNING;
2063                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2064                         self.flags &= ~FL_JUMPRELEASED;
2065                         if(SpectateNext()) {
2066                                 self.classname = "spectator";
2067                         }
2068                 } else {
2069                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2070                         if (self.movetype != prefered_movetype)
2071                                 self.movetype = prefered_movetype;
2072                 }
2073         } else {
2074                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2075                         self.flags |= FL_JUMPRELEASED;
2076                         if(self.flags & FL_SPAWNING)
2077                         {
2078                                 self.flags &= ~FL_SPAWNING;
2079                                 LeaveSpectatorMode();
2080                                 return;
2081                         }
2082                 }
2083         }
2084 }
2085
2086 void SpectatorThink()
2087 {
2088         if (self.flags & FL_JUMPRELEASED) {
2089                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2090                         self.flags &= ~FL_JUMPRELEASED;
2091                         self.flags |= FL_SPAWNING;
2092                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2093                         self.flags &= ~FL_JUMPRELEASED;
2094                         if(SpectateNext()) {
2095                                 self.classname = "spectator";
2096                         } else {
2097                                 self.classname = "observer";
2098                                 PutClientInServer();
2099                         }
2100                         self.impulse = 0;
2101                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2102                         self.flags &= ~FL_JUMPRELEASED;
2103                         if(SpectatePrev()) {
2104                                 self.classname = "spectator";
2105                         } else {
2106                                 self.classname = "observer";
2107                                 PutClientInServer();
2108                         }
2109                         self.impulse = 0;
2110                 } else if (self.BUTTON_ATCK2) {
2111                         self.flags &= ~FL_JUMPRELEASED;
2112                         self.classname = "observer";
2113                         PutClientInServer();
2114                 } else {
2115                         if(!SpectateUpdate())
2116                                 PutObserverInServer();
2117                 }
2118         } else {
2119                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2120                         self.flags |= FL_JUMPRELEASED;
2121                         if(self.flags & FL_SPAWNING)
2122                         {
2123                                 self.flags &= ~FL_SPAWNING;
2124                                 LeaveSpectatorMode();
2125                                 return;
2126                         }
2127                 }
2128                 if(!SpectateUpdate())
2129                         PutObserverInServer();
2130         }
2131
2132         self.flags |= FL_CLIENT | FL_NOTARGET;
2133 }
2134
2135 void vehicles_enter (entity pl, entity veh);
2136 void PlayerUseKey()
2137 {
2138         if (!IS_PLAYER(self))
2139                 return;
2140
2141         if(self.vehicle)
2142         {
2143                 if(!gameover)
2144                 {
2145                         vehicles_exit(VHEF_NORMAL);
2146                         return;
2147                 }
2148         }
2149         else if(autocvar_g_vehicles_enter)
2150         {
2151                 if(!self.frozen)
2152                 if(self.deadflag == DEAD_NO)
2153                 if(!gameover)
2154                 {
2155                         entity head, closest_target = world;
2156                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2157
2158                         while(head) // find the closest acceptable target to enter
2159                         {
2160                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2161                                 if(head.deadflag == DEAD_NO)
2162                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2163                                 if(head.takedamage != DAMAGE_NO)
2164                                 {
2165                                         if(closest_target)
2166                                         {
2167                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2168                                                 { closest_target = head; }
2169                                         }
2170                                         else { closest_target = head; }
2171                                 }
2172
2173                                 head = head.chain;
2174                         }
2175
2176                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2177                 }
2178         }
2179
2180         // a use key was pressed; call handlers
2181         MUTATOR_CALLHOOK(PlayerUseKey);
2182 }
2183
2184 /*
2185 =============
2186 PlayerPreThink
2187
2188 Called every frame for each client before the physics are run
2189 =============
2190 */
2191 .float usekeypressed;
2192 void() nexball_setstatus;
2193 .float items_added;
2194 .float last_vehiclecheck;
2195 void PlayerPreThink (void)
2196 {
2197         WarpZone_PlayerPhysics_FixVAngle();
2198
2199         self.stat_game_starttime = game_starttime;
2200         self.stat_round_starttime = round_starttime;
2201         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2202         self.stat_leadlimit = autocvar_leadlimit;
2203
2204         if(frametime)
2205         {
2206                 // physics frames: update anticheat stuff
2207                 anticheat_prethink();
2208         }
2209
2210         if(blockSpectators && frametime)
2211                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2212                 checkSpectatorBlock();
2213
2214         zoomstate_set = 0;
2215
2216         if(self.netname_previous != self.netname)
2217         {
2218                 if(autocvar_sv_eventlog)
2219                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2220                 if(self.netname_previous)
2221                         strunzone(self.netname_previous);
2222                 self.netname_previous = strzone(self.netname);
2223         }
2224
2225         // version nagging
2226         if(self.version_nagtime)
2227                 if(self.cvar_g_xonoticversion)
2228                         if(time > self.version_nagtime)
2229                         {
2230                                 // don't notify git users
2231                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2232                                 {
2233                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2234                                         {
2235                                                 // notify release users if connecting to git
2236                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2237                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2238                                         }
2239                                         else
2240                                         {
2241                                                 float r;
2242                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2243                                                 if(r < 0)
2244                                                 {
2245                                                         // give users new version
2246                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2247                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2248                                                 }
2249                                                 else if(r > 0)
2250                                                 {
2251                                                         // notify users about old server version
2252                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2253                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2254                                                 }
2255                                         }
2256                                 }
2257                                 self.version_nagtime = 0;
2258                         }
2259
2260         // GOD MODE info
2261         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2262         {
2263                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2264                 self.max_armorvalue = 0;
2265         }
2266
2267 #ifdef TETRIS
2268         if (TetrisPreFrame())
2269                 return;
2270 #endif
2271
2272         if(self.frozen == 2)
2273         {
2274                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2275                 self.health = max(1, self.revive_progress * start_health);
2276                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2277
2278                 if(self.revive_progress >= 1)
2279                         Unfreeze(self);
2280         }
2281         else if(self.frozen == 3)
2282         {
2283                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2284                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2285
2286                 if(self.health < 1)
2287                 {
2288                         if(self.vehicle)
2289                                 vehicles_exit(VHEF_RELEASE);
2290                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2291                 }
2292                 else if ( self.revive_progress <= 0 )
2293                         Unfreeze(self);
2294         }
2295
2296         MUTATOR_CALLHOOK(PlayerPreThink);
2297
2298         if(autocvar_g_vehicles_enter)
2299         if(time > self.last_vehiclecheck)
2300         if(IS_PLAYER(self))
2301         if(!gameover)
2302         if(!self.frozen)
2303         if(!self.vehicle)
2304         if(self.deadflag == DEAD_NO)
2305         {
2306                 entity veh;
2307                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2308                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2309                 if(veh.deadflag == DEAD_NO)
2310                 if(veh.takedamage != DAMAGE_NO)
2311                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2312                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2313                 else if(!veh.owner)
2314                 if(!veh.team || SAME_TEAM(self, veh))
2315                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2316                 else if(autocvar_g_vehicles_steal)
2317                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2318
2319                 self.last_vehiclecheck = time + 1;
2320         }
2321
2322         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2323         {
2324                 if(self.BUTTON_USE && !self.usekeypressed)
2325                         PlayerUseKey();
2326                 self.usekeypressed = self.BUTTON_USE;
2327         }
2328
2329         if(IS_REAL_CLIENT(self))
2330                 PrintWelcomeMessage();
2331
2332         if(IS_PLAYER(self))
2333         {
2334
2335                 CheckRules_Player();
2336
2337                 if (intermission_running)
2338                 {
2339                         IntermissionThink ();   // otherwise a button could be missed between
2340                         return;                                 // the think tics
2341                 }
2342
2343                 //don't allow the player to turn around while game is paused!
2344                 if(timeout_status == TIMEOUT_ACTIVE) {
2345                         // FIXME turn this into CSQC stuff
2346                         self.v_angle = self.lastV_angle;
2347                         self.angles = self.lastV_angle;
2348                         self.fixangle = TRUE;
2349                 }
2350
2351                 if(frametime)
2352                 {
2353                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2354                         {
2355                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2356                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2357                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2358
2359                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2360                                 {
2361                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2362                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2363                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2364                                 }
2365                         }
2366                         else
2367                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2368
2369                         player_powerups();
2370                 }
2371
2372                 if (self.deadflag != DEAD_NO)
2373                 {
2374                         if(self.personal && g_race_qualifying)
2375                         {
2376                                 if(time > self.respawn_time)
2377                                 {
2378                                         self.respawn_time = time + 1; // only retry once a second
2379                                         self.stat_respawn_time = self.respawn_time;
2380                                         respawn();
2381                                         self.impulse = 141;
2382                                 }
2383                         }
2384                         else
2385                         {
2386                                 float button_pressed;
2387                                 if(frametime)
2388                                         player_anim();
2389                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2390
2391                                 if (self.deadflag == DEAD_DYING)
2392                                 {
2393                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2394                                                 self.deadflag = DEAD_RESPAWNING;
2395                                         else if(!button_pressed)
2396                                                 self.deadflag = DEAD_DEAD;
2397                                 }
2398                                 else if (self.deadflag == DEAD_DEAD)
2399                                 {
2400                                         if(button_pressed)
2401                                                 self.deadflag = DEAD_RESPAWNABLE;
2402                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2403                                                 self.deadflag = DEAD_RESPAWNING;
2404                                 }
2405                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2406                                 {
2407                                         if(!button_pressed)
2408                                                 self.deadflag = DEAD_RESPAWNING;
2409                                 }
2410                                 else if (self.deadflag == DEAD_RESPAWNING)
2411                                 {
2412                                         if(time > self.respawn_time)
2413                                         {
2414                                                 self.respawn_time = time + 1; // only retry once a second
2415                                                 self.respawn_time_max = self.respawn_time;
2416                                                 respawn();
2417                                         }
2418                                 }
2419
2420                                 ShowRespawnCountdown();
2421
2422                                 if(self.respawn_flags & RESPAWN_SILENT)
2423                                         self.stat_respawn_time = 0;
2424                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2425                                         self.stat_respawn_time = self.respawn_time_max;
2426                                 else
2427                                         self.stat_respawn_time = self.respawn_time;
2428                         }
2429
2430                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2431                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2432                                 self.stat_respawn_time *= -1;
2433
2434                         return;
2435                 }
2436
2437                 self.prevorigin = self.origin;
2438
2439                 float do_crouch = self.BUTTON_CROUCH;
2440                 if(self.hook.state)
2441                         do_crouch = 0;
2442                 if(self.vehicle)
2443                         do_crouch = 0;
2444                 if(self.frozen)
2445                         do_crouch = 0;
2446                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2447                         do_crouch = 0;
2448
2449                 if (do_crouch)
2450                 {
2451                         if (!self.crouch)
2452                         {
2453                                 self.crouch = TRUE;
2454                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2455                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2456                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2457                         }
2458                 }
2459                 else
2460                 {
2461                         if (self.crouch)
2462                         {
2463                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2464                                 if (!trace_startsolid)
2465                                 {
2466                                         self.crouch = FALSE;
2467                                         self.view_ofs = PL_VIEW_OFS;
2468                                         setsize (self, PL_MIN, PL_MAX);
2469                                 }
2470                         }
2471                 }
2472
2473                 FixPlayermodel();
2474
2475                 GrapplingHookFrame();
2476
2477                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2478                 //if(frametime)
2479                 {
2480                         self.items &= ~self.items_added;
2481
2482                         W_WeaponFrame();
2483
2484                         self.items_added = 0;
2485                         if(self.items & IT_JETPACK)
2486                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2487                                         self.items_added |= IT_FUEL;
2488
2489                         self.items |= self.items_added;
2490                 }
2491
2492                 player_regen();
2493
2494                 // rot nex charge to the charge limit
2495                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2496                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2497
2498                 if(frametime)
2499                         player_anim();
2500
2501                 // secret status
2502                 secrets_setstatus();
2503
2504                 // monsters status
2505                 monsters_setstatus();
2506
2507                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2508
2509                 //self.angles_y=self.v_angle_y + 90;   // temp
2510         } else if(gameover) {
2511                 if (intermission_running)
2512                         IntermissionThink ();   // otherwise a button could be missed between
2513                 return;
2514         } else if(IS_OBSERVER(self)) {
2515                 ObserverThink();
2516         } else if(IS_SPEC(self)) {
2517                 SpectatorThink();
2518         }
2519
2520         if(!zoomstate_set)
2521                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2522
2523         float oldspectatee_status;
2524         oldspectatee_status = self.spectatee_status;
2525         if(IS_SPEC(self))
2526                 self.spectatee_status = num_for_edict(self.enemy);
2527         else if(IS_OBSERVER(self))
2528                 self.spectatee_status = num_for_edict(self);
2529         else
2530                 self.spectatee_status = 0;
2531         if(self.spectatee_status != oldspectatee_status)
2532         {
2533                 ClientData_Touch(self);
2534         }
2535
2536         if(self.teamkill_soundtime)
2537         if(time > self.teamkill_soundtime)
2538         {
2539                 self.teamkill_soundtime = 0;
2540
2541                 entity oldpusher, oldself;
2542
2543                 oldself = self; self = self.teamkill_soundsource;
2544                 oldpusher = self.pusher; self.pusher = oldself;
2545
2546                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2547
2548                 self.pusher = oldpusher;
2549                 self = oldself;
2550         }
2551
2552         if(self.taunt_soundtime)
2553         if(time > self.taunt_soundtime)
2554         {
2555                 self.taunt_soundtime = 0;
2556                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2557         }
2558
2559         target_voicescript_next(self);
2560
2561         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2562         if(!self.weapon)
2563                 self.clip_load = self.clip_size = 0;
2564 }
2565
2566 float isInvisibleString(string s)
2567 {
2568         float i, n, c;
2569         s = strdecolorize(s);
2570         for((i = 0), (n = strlen(s)); i < n; ++i)
2571         {
2572                 c = str2chr(s, i);
2573                 switch(c)
2574                 {
2575                         case 0:
2576                         case 32: // space
2577                                 break;
2578                         case 192: // charmap space
2579                                 if (!autocvar_utf8_enable)
2580                                         break;
2581                                 return FALSE;
2582                         case 160: // space in unicode fonts
2583                         case 0xE000 + 192: // utf8 charmap space
2584                                 if (autocvar_utf8_enable)
2585                                         break;
2586                         default:
2587                                 return FALSE;
2588                 }
2589         }
2590         return TRUE;
2591 }
2592
2593 /*
2594 =============
2595 PlayerPostThink
2596
2597 Called every frame for each client after the physics are run
2598 =============
2599 */
2600 .float idlekick_lasttimeleft;
2601 void PlayerPostThink (void)
2602 {
2603         // Savage: Check for nameless players
2604         if (isInvisibleString(self.netname)) {
2605                 self.netname = "Player";
2606                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2607         }
2608
2609         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2610         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2611         {
2612                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2613                 {
2614                         if(self.idlekick_lasttimeleft)
2615                         {
2616                                 self.idlekick_lasttimeleft = 0;
2617                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2618                         }
2619                 }
2620                 else
2621                 {
2622                         float timeleft;
2623                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2624                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2625                         {
2626                                 if(!self.idlekick_lasttimeleft)
2627                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2628                         }
2629                         if(timeleft <= 0)
2630                         {
2631                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2632                                 dropclient(self);
2633                                 return;
2634                         }
2635                         else if(timeleft <= 10)
2636                         {
2637                                 if(timeleft != self.idlekick_lasttimeleft)
2638                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2639                                 self.idlekick_lasttimeleft = timeleft;
2640                         }
2641                 }
2642         }
2643
2644 #ifdef TETRIS
2645         if(self.impulse == 100)
2646                 ImpulseCommands();
2647         if (!TetrisPostFrame())
2648         {
2649 #endif
2650
2651         CheatFrame();
2652
2653         //CheckPlayerJump();
2654
2655         if(IS_PLAYER(self)) {
2656                 CheckRules_Player();
2657                 UpdateChatBubble();
2658                 if (self.impulse)
2659                         ImpulseCommands();
2660                 if (intermission_running)
2661                         return;         // intermission or finale
2662                 GetPressedKeys();
2663         }
2664
2665 #ifdef TETRIS
2666         }
2667 #endif
2668
2669         /*
2670         float i;
2671         for(i = 0; i < 1000; ++i)
2672         {
2673                 vector end;
2674                 end = self.origin + '0 0 1024' + 512 * randomvec();
2675                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2676                 if(trace_fraction < 1)
2677                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2678                 {
2679                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2680                         break;
2681                 }
2682         }
2683         */
2684
2685         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2686
2687         if(self.waypointsprite_attachedforcarrier)
2688                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2689
2690         playerdemo_write();
2691
2692         CSQCMODEL_AUTOUPDATE();
2693 }