qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76 void SetSpectator(entity player, entity spectatee);
  77
  78
  79 /*
  80 =============
  81 CheckPlayerModel
  82
  83 Checks if the argument string can be a valid playermodel.
  84 Returns a valid one in doubt.
  85 =============
  86 */
  87 string FallbackPlayerModel;
  88 string CheckPlayerModel(string plyermodel) {
  89         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  90         {
  91                 // note: we cannot summon Don Strunzone here, some player may
  92                 // still have the model string set. In case anyone manages how
  93                 // to change a cvar default, we'll have a small leak here.
  94                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  95         }
  96         // only in right path
  97         if( substring(plyermodel,0,14) != "models/player/")
  98                 return FallbackPlayerModel;
  99         // only good file extensions
 100         if(substring(plyermodel,-4,4) != ".zym")
 101         if(substring(plyermodel,-4,4) != ".dpm")
 102         if(substring(plyermodel,-4,4) != ".iqm")
 103         if(substring(plyermodel,-4,4) != ".md3")
 104         if(substring(plyermodel,-4,4) != ".psk")
 105                 return FallbackPlayerModel;
 106         // forbid the LOD models
 107         if(substring(plyermodel, -9,5) == "_lod1")
 108                 return FallbackPlayerModel;
 109         if(substring(plyermodel, -9,5) == "_lod2")
 110                 return FallbackPlayerModel;
 111         if(plyermodel != strtolower(plyermodel))
 112                 return FallbackPlayerModel;
 113         // also, restrict to server models
 114         if(autocvar_sv_servermodelsonly)
 115         {
 116                 if(!fexists(plyermodel))
 117                         return FallbackPlayerModel;
 118         }
 119         return plyermodel;
 120 }
 121
 122 void setplayermodel(entity e, string modelname)
 123 {
 124         precache_model(modelname);
 125         setmodel(e, modelname);
 126         player_setupanimsformodel();
 127         UpdatePlayerSounds();
 128 }
 129
 130 /*
 131 =============
 132 PutObserverInServer
 133
 134 putting a client as observer in the server
 135 =============
 136 */
 137 void FixPlayermodel();
 138 void PutObserverInServer (void)
 139 {
 140         entity  spot;
 141     self.hud = HUD_NORMAL;
 142
 143         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         self.frags = FRAGS_SPECTATOR;
 158
 159         MUTATOR_CALLHOOK(MakePlayerObserver);
 160
 161         Portal_ClearAll(self);
 162
 163         Unfreeze(self);
 164
 165         if(self.alivetime)
 166         {
 167                 if(!warmup_stage)
 168                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 169                 self.alivetime = 0;
 170         }
 171
 172         if(self.vehicle)
 173                 vehicles_exit(VHEF_RELESE);
 174
 175         WaypointSprite_PlayerDead();
 176
 177         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 178                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 179
 180         if(self.killcount != -666)
 181         {
 182                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 183                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 184                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 185
 186                 if(self.just_joined == FALSE) {
 187                         LogTeamchange(self.playerid, -1, 4);
 188                 } else
 189                         self.just_joined = FALSE;
 190         }
 191
 192         PlayerScore_Clear(self); // clear scores when needed
 193
 194         accuracy_resend(self);
 195
 196         self.spectatortime = time;
 197
 198         self.classname = "observer";
 199         self.iscreature = FALSE;
 200         self.teleportable = TELEPORT_SIMPLE;
 201         self.damagedbycontents = FALSE;
 202         self.health = -666;
 203         self.takedamage = DAMAGE_NO;
 204         self.solid = SOLID_NOT;
 205         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 206         self.flags = FL_CLIENT | FL_NOTARGET;
 207         self.armorvalue = 666;
 208         self.effects = 0;
 209         self.armorvalue = autocvar_g_balance_armor_start;
 210         self.pauserotarmor_finished = 0;
 211         self.pauserothealth_finished = 0;
 212         self.pauseregen_finished = 0;
 213         self.damageforcescale = 0;
 214         self.death_time = 0;
 215         self.respawn_flags = 0;
 216         self.respawn_time = 0;
 217         self.stat_respawn_time = 0;
 218         self.alpha = 0;
 219         self.scale = 0;
 220         self.fade_time = 0;
 221         self.pain_frame = 0;
 222         self.pain_finished = 0;
 223         self.strength_finished = 0;
 224         self.invincible_finished = 0;
 225         self.superweapons_finished = 0;
 226         self.pushltime = 0;
 227         self.istypefrag = 0;
 228         self.think = func_null;
 229         self.nextthink = 0;
 230         self.hook_time = 0;
 231         self.deadflag = DEAD_NO;
 232         self.angles = spot.angles;
 233         self.angles_z = 0;
 234         self.fixangle = TRUE;
 235         self.crouch = FALSE;
 236         self.revival_time = 0;
 237
 238         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 239         self.prevorigin = self.origin;
 240         self.items = 0;
 241         self.weapons = '0 0 0';
 242         self.model = "";
 243         FixPlayermodel();
 244         setmodel(self, "null");
 245         self.drawonlytoclient = self;
 246
 247         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249
 250         self.weapon = 0;
 251         self.weaponname = "";
 252         self.switchingweapon = 0;
 253         self.weaponmodel = "";
 254         self.weaponentity = world;
 255         self.exteriorweaponentity = world;
 256         self.killcount = -666;
 257         self.velocity = '0 0 0';
 258         self.avelocity = '0 0 0';
 259         self.punchangle = '0 0 0';
 260         self.punchvector = '0 0 0';
 261         self.oldvelocity = self.velocity;
 262         self.fire_endtime = -1;
 263         self.event_damage = func_null;
 264 }
 265
 266 .float model_randomizer;
 267 void FixPlayermodel()
 268 {
 269         string defaultmodel;
 270         float defaultskin, chmdl, oldskin, n, i;
 271         vector m1, m2;
 272
 273         defaultmodel = "";
 274         defaultskin = 0;
 275         chmdl = FALSE;
 276
 277         if(autocvar_sv_defaultcharacter == 1)
 278         {
 279                 if(teamplay)
 280                 {
 281                         string s;
 282                         s = Static_Team_ColorName_Lower(self.team);
 283                         if(s != "neutral")
 284                         {
 285                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 286                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 287                         }
 288                 }
 289
 290                 if(defaultmodel == "")
 291                 {
 292                         defaultmodel = autocvar_sv_defaultplayermodel;
 293                         defaultskin = autocvar_sv_defaultplayerskin;
 294                 }
 295
 296                 n = tokenize_console(defaultmodel);
 297                 if(n > 0)
 298                 {
 299                         defaultmodel = argv(floor(n * self.model_randomizer));
 300                         // However, do NOT randomize if the player-selected model is in the list.
 301                         for (i = 0; i < n; ++i)
 302                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 303                                         defaultmodel = argv(i);
 304                 }
 305
 306                 i = strstrofs(defaultmodel, ":", 0);
 307                 if(i >= 0)
 308                 {
 309                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 310                         defaultmodel = substring(defaultmodel, 0, i);
 311                 }
 312         }
 313
 314         if(defaultmodel != "")
 315         {
 316                 if (defaultmodel != self.model)
 317                 {
 318                         m1 = self.mins;
 319                         m2 = self.maxs;
 320                         setplayermodel (self, defaultmodel);
 321                         setsize (self, m1, m2);
 322                         chmdl = TRUE;
 323                 }
 324
 325                 oldskin = self.skin;
 326                 self.skin = defaultskin;
 327         } else {
 328                 if (self.playermodel != self.model || self.playermodel == "")
 329                 {
 330                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 331                         m1 = self.mins;
 332                         m2 = self.maxs;
 333                         setplayermodel (self, self.playermodel);
 334                         setsize (self, m1, m2);
 335                         chmdl = TRUE;
 336                 }
 337
 338                 oldskin = self.skin;
 339                 self.skin = stof(self.playerskin);
 340         }
 341
 342         if(chmdl || oldskin != self.skin) // model or skin has changed
 343         {
 344                 self.species = player_getspecies(); // update species
 345                 UpdatePlayerSounds(); // update skin sounds
 346         }
 347
 348         if(!teamplay)
 349                 if(strlen(autocvar_sv_defaultplayercolors))
 350                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 351                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 352 }
 353
 354 /*
 355 =============
 356 PutClientInServer
 357
 358 Called when a client spawns in the server
 359 =============
 360 */
 361 void PutClientInServer (void)
 362 {
 363         if(IS_BOT_CLIENT(self))
 364                 self.classname = "player";
 365         else if(IS_REAL_CLIENT(self))
 366         {
 367                 msg_entity = self;
 368                 WriteByte(MSG_ONE, SVC_SETVIEW);
 369                 WriteEntity(MSG_ONE, self);
 370         }
 371
 372         SetSpectator(self, world);
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, FALSE, TRUE);
 391
 392                 spot = SelectSpawnPoint (FALSE);
 393                 if(!spot)
 394                 {
 395                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 396                         return; // spawn failed
 397                 }
 398
 399                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 400
 401                 if(self.vehicle)
 402                         vehicles_exit(VHEF_RELESE);
 403
 404                 self.classname = "player";
 405                 self.wasplayer = TRUE;
 406                 self.iscreature = TRUE;
 407                 self.teleportable = TELEPORT_NORMAL;
 408                 self.damagedbycontents = TRUE;
 409                 self.movetype = MOVETYPE_WALK;
 410                 self.solid = SOLID_SLIDEBOX;
 411                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 412                 if(autocvar_g_playerclip_collisions)
 413                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 414                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 415                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 416                 self.frags = FRAGS_PLAYER;
 417                 if(INDEPENDENT_PLAYERS)
 418                         MAKE_INDEPENDENT_PLAYER(self);
 419                 self.flags = FL_CLIENT;
 420                 if(autocvar__notarget)
 421                         self.flags |= FL_NOTARGET;
 422                 self.takedamage = DAMAGE_AIM;
 423                 self.effects = 0;
 424                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 425                 self.air_finished = time + 12;
 426                 self.dmg = 2;
 427                 if(WEP_CVAR(vortex, charge))
 428                 {
 429                         if(WEP_CVAR_SEC(vortex, chargepool))
 430                                 self.vortex_chargepool_ammo = 1;
 431                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 432                 }
 433
 434                 if(warmup_stage)
 435                 {
 436                         self.ammo_shells = warmup_start_ammo_shells;
 437                         self.ammo_nails = warmup_start_ammo_nails;
 438                         self.ammo_rockets = warmup_start_ammo_rockets;
 439                         self.ammo_cells = warmup_start_ammo_cells;
 440                         self.ammo_plasma = warmup_start_ammo_plasma;
 441                         self.ammo_fuel = warmup_start_ammo_fuel;
 442                         self.health = warmup_start_health;
 443                         self.armorvalue = warmup_start_armorvalue;
 444                         self.weapons = WARMUP_START_WEAPONS;
 445                 }
 446                 else
 447                 {
 448                         self.ammo_shells = start_ammo_shells;
 449                         self.ammo_nails = start_ammo_nails;
 450                         self.ammo_rockets = start_ammo_rockets;
 451                         self.ammo_cells = start_ammo_cells;
 452                         self.ammo_plasma = start_ammo_plasma;
 453                         self.ammo_fuel = start_ammo_fuel;
 454                         self.health = start_health;
 455                         self.armorvalue = start_armorvalue;
 456                         self.weapons = start_weapons;
 457                 }
 458
 459                 if(self.weapons & WEPSET_SUPERWEAPONS)
 460                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 461                 else
 462                         self.superweapons_finished = 0;
 463
 464                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 465                 {
 466                         if(g_weaponarena_random_with_blaster)
 467                                 self.weapons &= ~WEPSET_BLASTER;
 468                         W_RandomWeapons(self, g_weaponarena_random);
 469                         if(g_weaponarena_random_with_blaster)
 470                                 self.weapons |= WEPSET_BLASTER;
 471                 }
 472
 473                 self.items = start_items;
 474
 475                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 476                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 477                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 478                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 479                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 480                 //extend the pause of rotting if client was reset at the beginning of the countdown
 481                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 482                         self.spawnshieldtime += game_starttime - time;
 483                         self.pauserotarmor_finished += game_starttime - time;
 484                         self.pauserothealth_finished += game_starttime - time;
 485                         self.pauseregen_finished += game_starttime - time;
 486                 }
 487                 self.damageforcescale = 2;
 488                 self.death_time = 0;
 489                 self.respawn_flags = 0;
 490                 self.respawn_time = 0;
 491                 self.stat_respawn_time = 0;
 492                 self.scale = 0;
 493                 self.fade_time = 0;
 494                 self.pain_frame = 0;
 495                 self.pain_finished = 0;
 496                 self.strength_finished = 0;
 497                 self.invincible_finished = 0;
 498                 self.pushltime = 0;
 499                 // players have no think function
 500                 self.think = func_null;
 501                 self.nextthink = 0;
 502                 self.hook_time = 0;
 503                 self.dmg_team = 0;
 504                 self.ballistics_density = autocvar_g_ballistics_density_player;
 505
 506                 self.metertime = 0;
 507
 508                 self.deadflag = DEAD_NO;
 509
 510                 self.angles = spot.angles;
 511
 512                 self.angles_z = 0; // never spawn tilted even if the spot says to
 513                 if(IS_BOT_CLIENT(self))
 514                         self.v_angle = self.angles;
 515                 self.fixangle = TRUE; // turn this way immediately
 516                 self.velocity = '0 0 0';
 517                 self.avelocity = '0 0 0';
 518                 self.punchangle = '0 0 0';
 519                 self.punchvector = '0 0 0';
 520                 self.oldvelocity = self.velocity;
 521                 self.fire_endtime = -1;
 522                 self.revival_time = 0;
 523
 524                 entity spawnevent = spawn();
 525                 spawnevent.owner = self;
 526                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 527
 528                 // Cut off any still running player sounds.
 529                 stopsound(self, CH_PLAYER_SINGLE);
 530
 531                 self.model = "";
 532                 FixPlayermodel();
 533                 self.drawonlytoclient = world;
 534
 535                 self.crouch = FALSE;
 536                 self.view_ofs = PL_VIEW_OFS;
 537                 setsize (self, PL_MIN, PL_MAX);
 538                 self.spawnorigin = spot.origin;
 539                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 540                 // don't reset back to last position, even if new position is stuck in solid
 541                 self.oldorigin = self.origin;
 542                 self.prevorigin = self.origin;
 543                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 544                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 545         self.hud = HUD_NORMAL;
 546
 547                 self.event_damage = PlayerDamage;
 548
 549                 self.bot_attack = TRUE;
 550                 self.monster_attack = TRUE;
 551
 552                 self.spider_slowness = 0;
 553
 554                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 555
 556                 if(self.killcount == -666) {
 557                         PlayerScore_Clear(self);
 558                         self.killcount = 0;
 559                 }
 560
 561                 CL_SpawnWeaponentity();
 562                 self.alpha = default_player_alpha;
 563                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 564                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 565
 566                 self.speedrunning = FALSE;
 567
 568                 //stuffcmd(self, "chase_active 0");
 569                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 570
 571                 target_voicescript_clear(self);
 572
 573                 // reset fields the weapons may use
 574                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 575                 {
 576                         WEP_ACTION(j, WR_RESETPLAYER);
 577
 578                         // all weapons must be fully loaded when we spawn
 579                         entity e;
 580                         e = get_weaponinfo(j);
 581                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 582                                 self.(weapon_load[j]) = e.reloading_ammo;
 583                 }
 584
 585                 oldself = self;
 586                 self = spot;
 587                         activator = oldself;
 588                                 string s;
 589                                 s = self.target;
 590                                 self.target = string_null;
 591                                 SUB_UseTargets();
 592                                 self.target = s;
 593                         activator = world;
 594                 self = oldself;
 595
 596                 Unfreeze(self);
 597
 598                 spawn_spot = spot;
 599                 MUTATOR_CALLHOOK(PlayerSpawn);
 600
 601                 if(autocvar_spawn_debug)
 602                 {
 603                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 604                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 605                 }
 606
 607                 self.switchweapon = w_getbestweapon(self);
 608                 self.cnt = -1; // W_LastWeapon will not complain
 609                 self.weapon = 0;
 610                 self.weaponname = "";
 611                 self.switchingweapon = 0;
 612
 613                 if(!warmup_stage)
 614                         if(!self.alivetime)
 615                                 self.alivetime = time;
 616
 617                 antilag_clear(self);
 618         }
 619         else if(IS_OBSERVER(self))
 620         {
 621                 PutObserverInServer ();
 622         }
 623 }
 624
 625 .float ebouncefactor, ebouncestop; // electro's values
 626 // TODO do we need all these fields, or should we stop autodetecting runtime
 627 // changes and just have a console command to update this?
 628 float ClientInit_SendEntity(entity to, float sf)
 629 {
 630         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 631         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 640
 641         if(sv_foginterval && world.fog != "")
 642                 WriteString(MSG_ENTITY, world.fog);
 643         else
 644                 WriteString(MSG_ENTITY, "");
 645         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 646         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 647         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 648         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 649         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 650         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 651         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 652         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 653         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 654         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 655         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 656         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 657         return TRUE;
 658 }
 659
 660 void ClientInit_CheckUpdate()
 661 {
 662         self.nextthink = time;
 663         if(self.count != autocvar_g_balance_armor_blockpercent)
 664         {
 665                 self.count = autocvar_g_balance_armor_blockpercent;
 666                 self.SendFlags |= 1;
 667         }
 668         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 669         {
 670                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 674         {
 675                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 676                 self.SendFlags |= 1;
 677         }
 678         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 679         {
 680                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 681                 self.SendFlags |= 1;
 682         }
 683         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 684         {
 685                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 686                 self.SendFlags |= 1;
 687         }
 688 }
 689
 690 void ClientInit_Spawn()
 691 {
 692         entity o;
 693         entity e;
 694         e = spawn();
 695         e.classname = "clientinit";
 696         e.think = ClientInit_CheckUpdate;
 697         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 698
 699         o = self;
 700         self = e;
 701         ClientInit_CheckUpdate();
 702         self = o;
 703 }
 704
 705 /*
 706 =============
 707 SetNewParms
 708 =============
 709 */
 710 void SetNewParms (void)
 711 {
 712         // initialize parms for a new player
 713         parm1 = -(86400 * 366);
 714 }
 715
 716 /*
 717 =============
 718 SetChangeParms
 719 =============
 720 */
 721 void SetChangeParms (void)
 722 {
 723         // save parms for level change
 724         parm1 = self.parm_idlesince - time;
 725 }
 726
 727 /*
 728 =============
 729 DecodeLevelParms
 730 =============
 731 */
 732 void DecodeLevelParms (void)
 733 {
 734         // load parms
 735         self.parm_idlesince = parm1;
 736         if(self.parm_idlesince == -(86400 * 366))
 737                 self.parm_idlesince = time;
 738
 739         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 740         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 741 }
 742
 743 /*
 744 =============
 745 ClientKill
 746
 747 Called when a client types 'kill' in the console
 748 =============
 749 */
 750
 751 .float clientkill_nexttime;
 752 void ClientKill_Now_TeamChange()
 753 {
 754         if(self.killindicator_teamchange == -1)
 755         {
 756                 JoinBestTeam( self, FALSE, TRUE );
 757         }
 758         else if(self.killindicator_teamchange == -2)
 759         {
 760                 if(blockSpectators)
 761                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 762                 PutObserverInServer();
 763         }
 764         else
 765                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 766         self.killindicator_teamchange = 0;
 767 }
 768
 769 void ClientKill_Now()
 770 {
 771         if(self.vehicle)
 772         {
 773             vehicles_exit(VHEF_RELESE);
 774             if(!self.killindicator_teamchange)
 775             {
 776             self.vehicle_health = -1;
 777             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 778             }
 779         }
 780
 781         if(self.killindicator && !wasfreed(self.killindicator))
 782                 remove(self.killindicator);
 783
 784         self.killindicator = world;
 785
 786         if(self.killindicator_teamchange)
 787                 ClientKill_Now_TeamChange();
 788
 789         if(IS_PLAYER(self))
 790                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 791
 792         // now I am sure the player IS dead
 793 }
 794 void KillIndicator_Think()
 795 {
 796         if (gameover)
 797         {
 798                 self.owner.killindicator = world;
 799                 remove(self);
 800                 return;
 801         }
 802
 803         if (self.owner.alpha < 0 && !self.owner.vehicle)
 804         {
 805                 self.owner.killindicator = world;
 806                 remove(self);
 807                 return;
 808         }
 809
 810         if(self.cnt <= 0)
 811         {
 812                 self = self.owner;
 813                 ClientKill_Now(); // no oldself needed
 814                 return;
 815         }
 816     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 817     {
 818         self.nextthink = time + 1;
 819         self.cnt -= 1;
 820     }
 821         else
 822         {
 823                 if(self.cnt <= 10)
 824                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 825                 if(IS_REAL_CLIENT(self.owner))
 826                 {
 827                         if(self.cnt <= 10)
 828                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 829                 }
 830                 self.nextthink = time + 1;
 831                 self.cnt -= 1;
 832         }
 833 }
 834
 835 float clientkilltime;
 836 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 837 {
 838         float killtime;
 839         float starttime;
 840         entity e;
 841
 842         if (gameover)
 843                 return;
 844
 845         killtime = autocvar_g_balance_kill_delay;
 846
 847         if(g_race_qualifying || g_cts)
 848                 killtime = 0;
 849
 850     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 851     {
 852                 remove(self.killindicator);
 853                 self.killindicator = world;
 854
 855         ClientKill_Now(); // allow instant kill in this case
 856         return;
 857     }
 858
 859         self.killindicator_teamchange = targetteam;
 860
 861     if(!self.killindicator)
 862         {
 863                 if(self.deadflag == DEAD_NO)
 864                 {
 865                         killtime = max(killtime, self.clientkill_nexttime - time);
 866                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 867                 }
 868
 869                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 870                 {
 871                         ClientKill_Now();
 872                 }
 873                 else
 874                 {
 875                         starttime = max(time, clientkilltime);
 876
 877                         self.killindicator = spawn();
 878                         self.killindicator.owner = self;
 879                         self.killindicator.scale = 0.5;
 880                         setattachment(self.killindicator, self, "");
 881                         setorigin(self.killindicator, '0 0 52');
 882                         self.killindicator.think = KillIndicator_Think;
 883                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 884                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 885                         self.killindicator.cnt = ceil(killtime);
 886                         self.killindicator.count = bound(0, ceil(killtime), 10);
 887                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 888
 889                         for(e = world; (e = find(e, classname, "body")) != world; )
 890                         {
 891                                 if(e.enemy != self)
 892                                         continue;
 893                                 e.killindicator = spawn();
 894                                 e.killindicator.owner = e;
 895                                 e.killindicator.scale = 0.5;
 896                                 setattachment(e.killindicator, e, "");
 897                                 setorigin(e.killindicator, '0 0 52');
 898                                 e.killindicator.think = KillIndicator_Think;
 899                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 900                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 901                                 e.killindicator.cnt = ceil(killtime);
 902                         }
 903                         self.lip = 0;
 904                 }
 905         }
 906         if(self.killindicator)
 907         {
 908                 if(targetteam == 0) // just die
 909                 {
 910                         self.killindicator.colormod = '0 0 0';
 911                         if(IS_REAL_CLIENT(self))
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 914                 }
 915                 else if(targetteam == -1) // auto
 916                 {
 917                         self.killindicator.colormod = '0 1 0';
 918                         if(IS_REAL_CLIENT(self))
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 921                 }
 922                 else if(targetteam == -2) // spectate
 923                 {
 924                         self.killindicator.colormod = '0.5 0.5 0.5';
 925                         if(IS_REAL_CLIENT(self))
 926                         if(self.killindicator.cnt > 0)
 927                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 928                 }
 929                 else
 930                 {
 931                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 932                         if(IS_REAL_CLIENT(self))
 933                         if(self.killindicator.cnt > 0)
 934                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 935                 }
 936         }
 937
 938 }
 939
 940 void ClientKill (void)
 941 {
 942         if(gameover) return;
 943         if(self.player_blocked) return;
 944         if(self.frozen) return;
 945
 946         ClientKill_TeamChange(0);
 947 }
 948
 949 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 950 {
 951     e.killindicator = spawn();
 952     e.killindicator.owner = e;
 953     e.killindicator.think = KillIndicator_Think;
 954     e.killindicator.nextthink = time + (e.lip) * 0.05;
 955     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 956     e.killindicator.health = 1; // this is used to indicate that it should be silent
 957     e.lip = 0;
 958 }
 959
 960 void FixClientCvars(entity e)
 961 {
 962         // send prediction settings to the client
 963         stuffcmd(e, "\nin_bindmap 0 0\n");
 964         if(g_race || g_cts)
 965                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 966         if(autocvar_g_antilag == 3) // client side hitscan
 967                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 968         if(autocvar_sv_gentle)
 969                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 970 }
 971
 972 float PlayerInIDList(entity p, string idlist)
 973 {
 974         float n, i;
 975         string s;
 976
 977         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 978         if (!p.crypto_idfp)
 979                 return 0;
 980
 981         // this function allows abbreviated player IDs too!
 982         n = tokenize_console(idlist);
 983         for(i = 0; i < n; ++i)
 984         {
 985                 s = argv(i);
 986                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 987                         return 1;
 988         }
 989
 990         return 0;
 991 }
 992
 993 /*
 994 =============
 995 ClientConnect
 996
 997 Called when a client connects to the server
 998 =============
 999 */
1000 void DecodeLevelParms (void);
1001 //void dom_player_join_team(entity pl);
1002 void set_dom_state(entity e);
1003 void ClientConnect (void)
1004 {
1005         float t;
1006
1007         if(IS_CLIENT(self))
1008         {
1009                 print("Warning: ClientConnect, but already connected!\n");
1010                 return;
1011         }
1012
1013         if(Ban_MaybeEnforceBanOnce(self))
1014                 return;
1015
1016         DecodeLevelParms();
1017
1018 #ifdef WATERMARK
1019         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1020 #endif
1021
1022         self.classname = "player_joining";
1023
1024         self.flags = FL_CLIENT;
1025         self.version_nagtime = time + 10 + random() * 10;
1026
1027         if(player_count<0)
1028         {
1029                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1030                 player_count = 0;
1031         }
1032
1033         PlayerScore_Attach(self);
1034         ClientData_Attach();
1035         accuracy_init(self);
1036
1037         bot_clientconnect();
1038
1039         playerdemo_init();
1040
1041         anticheat_init();
1042
1043         // identify the right forced team
1044         if(autocvar_g_campaign)
1045         {
1046                 if(IS_REAL_CLIENT(self)) // only players, not bots
1047                 {
1048                         switch(autocvar_g_campaign_forceteam)
1049                         {
1050                                 case 1: self.team_forced = NUM_TEAM_1; break;
1051                                 case 2: self.team_forced = NUM_TEAM_2; break;
1052                                 case 3: self.team_forced = NUM_TEAM_3; break;
1053                                 case 4: self.team_forced = NUM_TEAM_4; break;
1054                                 default: self.team_forced = 0;
1055                         }
1056                 }
1057         }
1058         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1059                 self.team_forced = NUM_TEAM_1;
1060         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1061                 self.team_forced = NUM_TEAM_2;
1062         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1063                 self.team_forced = NUM_TEAM_3;
1064         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1065                 self.team_forced = NUM_TEAM_4;
1066         else if(autocvar_g_forced_team_otherwise == "red")
1067                 self.team_forced = NUM_TEAM_1;
1068         else if(autocvar_g_forced_team_otherwise == "blue")
1069                 self.team_forced = NUM_TEAM_2;
1070         else if(autocvar_g_forced_team_otherwise == "yellow")
1071                 self.team_forced = NUM_TEAM_3;
1072         else if(autocvar_g_forced_team_otherwise == "pink")
1073                 self.team_forced = NUM_TEAM_4;
1074         else if(autocvar_g_forced_team_otherwise == "spectate")
1075                 self.team_forced = -1;
1076         else if(autocvar_g_forced_team_otherwise == "spectator")
1077                 self.team_forced = -1;
1078         else
1079                 self.team_forced = 0;
1080
1081         if(!teamplay)
1082                 if(self.team_forced > 0)
1083                         self.team_forced = 0;
1084
1085         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1086
1087         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1088                 self.classname = "observer";
1089         } else {
1090                 if(teamplay)
1091                 {
1092                         if(autocvar_g_balance_teams)
1093                         {
1094                                 self.classname = "player";
1095                                 campaign_bots_may_start = 1;
1096                         }
1097                         else
1098                         {
1099                                 self.classname = "observer"; // do it anyway
1100                         }
1101                 }
1102                 else
1103                 {
1104                         self.classname = "player";
1105                         campaign_bots_may_start = 1;
1106                 }
1107         }
1108
1109         self.playerid = (playerid_last = playerid_last + 1);
1110
1111         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1112
1113     if(IS_BOT_CLIENT(self))
1114         PlayerStats_AddPlayer(self);
1115
1116         if(autocvar_sv_eventlog)
1117                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1118
1119         LogTeamchange(self.playerid, self.team, 1);
1120
1121         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1122
1123         self.netname_previous = strzone(self.netname);
1124
1125         if(IS_PLAYER(self) && teamplay)
1126                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1127         else
1128                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1129
1130         stuffcmd(self, strcat(clientstuff, "\n"));
1131         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1132
1133         FixClientCvars(self);
1134
1135         // spawnfunc_waypoint sprites
1136         WaypointSprite_InitClient(self);
1137
1138         // Wazat's grappling hook
1139         SetGrappleHookBindings();
1140
1141         // get version info from player
1142         stuffcmd(self, "cmd clientversion $gameversion\n");
1143
1144         // get other cvars from player
1145         GetCvars(0);
1146
1147         // notify about available teams
1148         if(teamplay)
1149         {
1150                 CheckAllowedTeams(self);
1151                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1152                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1153         }
1154         else
1155                 stuffcmd(self, "set _teams_available 0\n");
1156
1157         attach_entcs();
1158
1159         bot_relinkplayerlist();
1160
1161         self.spectatortime = time;
1162         if(blockSpectators)
1163         {
1164                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1165         }
1166
1167         self.jointime = time;
1168         self.allowed_timeouts = autocvar_sv_timeout_number;
1169
1170         if(IS_REAL_CLIENT(self))
1171         {
1172                 if(!autocvar_g_campaign)
1173                 {
1174                         self.motd_actived_time = -1;
1175                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1176                 }
1177
1178                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1179                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1180         }
1181
1182         if(!sv_foginterval && world.fog != "")
1183                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1184
1185         W_HitPlotOpen(self);
1186
1187         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1188                 send_CSQC_teamnagger();
1189
1190         CheatInitClient();
1191
1192         CSQCMODEL_AUTOINIT();
1193
1194         self.model_randomizer = random();
1195
1196         if(IS_REAL_CLIENT(self))
1197                 sv_notice_join();
1198
1199         MUTATOR_CALLHOOK(ClientConnect);
1200 }
1201 /*
1202 =============
1203 ClientDisconnect
1204
1205 Called when a client disconnects from the server
1206 =============
1207 */
1208 .entity chatbubbleentity;
1209 void ReadyCount();
1210 void ClientDisconnect (void)
1211 {
1212         if(self.vehicle)
1213             vehicles_exit(VHEF_RELESE);
1214
1215         if (!IS_CLIENT(self))
1216         {
1217                 print("Warning: ClientDisconnect without ClientConnect\n");
1218                 return;
1219         }
1220
1221         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1222
1223         PlayerStats_AddGlobalInfo(self);
1224
1225         CheatShutdownClient();
1226
1227         W_HitPlotClose(self);
1228
1229         anticheat_report();
1230         anticheat_shutdown();
1231
1232         playerdemo_shutdown();
1233
1234         bot_clientdisconnect();
1235
1236         if(self.entcs)
1237                 detach_entcs();
1238
1239         if(autocvar_sv_eventlog)
1240                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1241
1242         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1243
1244         MUTATOR_CALLHOOK(ClientDisconnect);
1245
1246         Portal_ClearAll(self);
1247
1248         Unfreeze(self);
1249
1250         RemoveGrapplingHook(self);
1251
1252         // Here, everything has been done that requires this player to be a client.
1253
1254         self.flags &= ~FL_CLIENT;
1255
1256         if (self.chatbubbleentity)
1257                 remove (self.chatbubbleentity);
1258
1259         if (self.killindicator)
1260                 remove (self.killindicator);
1261
1262         WaypointSprite_PlayerGone();
1263
1264         bot_relinkplayerlist();
1265
1266         accuracy_free(self);
1267         ClientData_Detach();
1268         PlayerScore_Detach(self);
1269
1270         if(self.netname_previous)
1271                 strunzone(self.netname_previous);
1272         if(self.clientstatus)
1273                 strunzone(self.clientstatus);
1274         if(self.weaponorder_byimpulse)
1275                 strunzone(self.weaponorder_byimpulse);
1276
1277         ClearPlayerSounds();
1278
1279         if(self.personal)
1280                 remove(self.personal);
1281
1282         self.playerid = 0;
1283         ReadyCount();
1284
1285         // free cvars
1286         GetCvars(-1);
1287 }
1288
1289 .float BUTTON_CHAT;
1290 void ChatBubbleThink()
1291 {
1292         self.nextthink = time;
1293         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1294         {
1295                 if(self.owner) // but why can that ever be world?
1296                         self.owner.chatbubbleentity = world;
1297                 remove(self);
1298                 return;
1299         }
1300         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1301 #ifdef TETRIS
1302                 || self.owner.tetris_on
1303 #endif
1304         )
1305                 self.model = self.mdl;
1306         else
1307                 self.model = "";
1308 }
1309
1310 void UpdateChatBubble()
1311 {
1312         if (self.alpha < 0)
1313                 return;
1314         // spawn a chatbubble entity if needed
1315         if (!self.chatbubbleentity)
1316         {
1317                 self.chatbubbleentity = spawn();
1318                 self.chatbubbleentity.owner = self;
1319                 self.chatbubbleentity.exteriormodeltoclient = self;
1320                 self.chatbubbleentity.think = ChatBubbleThink;
1321                 self.chatbubbleentity.nextthink = time;
1322                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1323                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1324                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1325                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1326                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1327                 self.chatbubbleentity.model = "";
1328                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1329         }
1330 }
1331
1332
1333 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1334 // added to the model skins
1335 /*void UpdateColorModHack()
1336 {
1337         float c;
1338         c = self.clientcolors & 15;
1339         // LordHavoc: only bothering to support white, green, red, yellow, blue
1340              if (!teamplay) self.colormod = '0 0 0';
1341         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1342         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1343         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1344         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1345         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1346         else self.colormod = '1 1 1';
1347 }*/
1348
1349 void respawn(void)
1350 {
1351         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1352         {
1353                 self.solid = SOLID_NOT;
1354                 self.takedamage = DAMAGE_NO;
1355                 self.movetype = MOVETYPE_FLY;
1356                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1357                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1358                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1359                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1360                 if(autocvar_g_respawn_ghosts_maxtime)
1361                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1362         }
1363
1364         CopyBody(1);
1365
1366         self.effects |= EF_NODRAW; // prevent another CopyBody
1367         PutClientInServer();
1368 }
1369
1370 void play_countdown(float finished, string samp)
1371 {
1372         if(IS_REAL_CLIENT(self))
1373                 if(floor(finished - time - frametime) != floor(finished - time))
1374                         if(finished - time < 6)
1375                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1376 }
1377
1378 void player_powerups (void)
1379 {
1380         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1381         olditems = self.items;
1382
1383         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1384                 self.modelflags |= MF_ROCKET;
1385         else
1386                 self.modelflags &= ~MF_ROCKET;
1387
1388         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1389
1390         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1391                 return;
1392
1393         Fire_ApplyDamage(self);
1394         Fire_ApplyEffect(self);
1395
1396         if (!g_instagib)
1397         {
1398                 if (self.items & IT_STRENGTH)
1399                 {
1400                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1401                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1402                         if (time > self.strength_finished)
1403                         {
1404                                 self.items = self.items - (self.items & IT_STRENGTH);
1405                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1406                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1407                         }
1408                 }
1409                 else
1410                 {
1411                         if (time < self.strength_finished)
1412                         {
1413                                 self.items = self.items | IT_STRENGTH;
1414                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1415                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1416                         }
1417                 }
1418                 if (self.items & IT_INVINCIBLE)
1419                 {
1420                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1421                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1422                         if (time > self.invincible_finished)
1423                         {
1424                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1425                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1426                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1427                         }
1428                 }
1429                 else
1430                 {
1431                         if (time < self.invincible_finished)
1432                         {
1433                                 self.items = self.items | IT_INVINCIBLE;
1434                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1435                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1436                         }
1437                 }
1438                 if (self.items & IT_SUPERWEAPON)
1439                 {
1440                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1441                         {
1442                                 self.superweapons_finished = 0;
1443                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1444                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1445                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1446                         }
1447                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1448                         {
1449                                 // don't let them run out
1450                         }
1451                         else
1452                         {
1453                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1454                                 if (time > self.superweapons_finished)
1455                                 {
1456                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1457                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1458                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1459                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1460                                 }
1461                         }
1462                 }
1463                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1464                 {
1465                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1466                         {
1467                                 self.items = self.items | IT_SUPERWEAPON;
1468                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1469                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1470                         }
1471                         else
1472                         {
1473                                 self.superweapons_finished = 0;
1474                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1475                         }
1476                 }
1477                 else
1478                 {
1479                         self.superweapons_finished = 0;
1480                 }
1481         }
1482
1483         if(autocvar_g_nodepthtestplayers)
1484                 self.effects = self.effects | EF_NODEPTHTEST;
1485
1486         if(autocvar_g_fullbrightplayers)
1487                 self.effects = self.effects | EF_FULLBRIGHT;
1488
1489         if (time >= game_starttime)
1490         if (time < self.spawnshieldtime)
1491                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1492
1493         MUTATOR_CALLHOOK(PlayerPowerups);
1494 }
1495
1496 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1497 {
1498         if(current > stable)
1499                 return current;
1500         else if(current > stable - 0.25) // when close enough, "snap"
1501                 return stable;
1502         else
1503                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1504 }
1505
1506 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1507 {
1508         if(current < stable)
1509                 return current;
1510         else if(current < stable + 0.25) // when close enough, "snap"
1511                 return stable;
1512         else
1513                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1514 }
1515
1516 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1517 {
1518         if(current > rotstable)
1519         {
1520                 if(rotframetime > 0)
1521                 {
1522                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1523                         current = max(rotstable, current - rotlinear * rotframetime);
1524                 }
1525         }
1526         else if(current < regenstable)
1527         {
1528                 if(regenframetime > 0)
1529                 {
1530                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1531                         current = min(regenstable, current + regenlinear * regenframetime);
1532                 }
1533         }
1534
1535         if(current > limit)
1536                 current = limit;
1537
1538         return current;
1539 }
1540
1541 void player_regen (void)
1542 {
1543         float max_mod, regen_mod, rot_mod, limit_mod;
1544         max_mod = regen_mod = rot_mod = limit_mod = 1;
1545         regen_mod_max = max_mod;
1546         regen_mod_regen = regen_mod;
1547         regen_mod_rot = rot_mod;
1548         regen_mod_limit = limit_mod;
1549         if(!MUTATOR_CALLHOOK(PlayerRegen))
1550         if(!self.frozen)
1551         {
1552                 float minh, mina, maxh, maxa, limith, limita;
1553                 maxh = autocvar_g_balance_health_rotstable;
1554                 maxa = autocvar_g_balance_armor_rotstable;
1555                 minh = autocvar_g_balance_health_regenstable;
1556                 mina = autocvar_g_balance_armor_regenstable;
1557                 limith = autocvar_g_balance_health_limit;
1558                 limita = autocvar_g_balance_armor_limit;
1559
1560                 max_mod = regen_mod_max;
1561                 regen_mod = regen_mod_regen;
1562                 rot_mod = regen_mod_rot;
1563                 limit_mod = regen_mod_limit;
1564
1565                 maxh = maxh * max_mod;
1566                 minh = minh * max_mod;
1567                 limith = limith * limit_mod;
1568                 limita = limita * limit_mod;
1569
1570                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1571                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1572         }
1573
1574         // if player rotted to death...  die!
1575         // check this outside above checks, as player may still be able to rot to death
1576         if(self.health < 1)
1577                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1578
1579         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1580         {
1581                 float minf, maxf, limitf;
1582
1583                 maxf = autocvar_g_balance_fuel_rotstable;
1584                 minf = autocvar_g_balance_fuel_regenstable;
1585                 limitf = autocvar_g_balance_fuel_limit;
1586
1587                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1588         }
1589 }
1590
1591 float zoomstate_set;
1592 void SetZoomState(float z)
1593 {
1594         if(z != self.zoomstate)
1595         {
1596                 self.zoomstate = z;
1597                 ClientData_Touch(self);
1598         }
1599         zoomstate_set = 1;
1600 }
1601
1602 void GetPressedKeys(void) {
1603         MUTATOR_CALLHOOK(GetPressedKeys);
1604         if (self.movement_x > 0) // get if movement keys are pressed
1605         {       // forward key pressed
1606                 self.pressedkeys |= KEY_FORWARD;
1607                 self.pressedkeys &= ~KEY_BACKWARD;
1608         }
1609         else if (self.movement_x < 0)
1610         {       // backward key pressed
1611                 self.pressedkeys |= KEY_BACKWARD;
1612                 self.pressedkeys &= ~KEY_FORWARD;
1613         }
1614         else
1615         {       // no x input
1616                 self.pressedkeys &= ~KEY_FORWARD;
1617                 self.pressedkeys &= ~KEY_BACKWARD;
1618         }
1619
1620         if (self.movement_y > 0)
1621         {       // right key pressed
1622                 self.pressedkeys |= KEY_RIGHT;
1623                 self.pressedkeys &= ~KEY_LEFT;
1624         }
1625         else if (self.movement_y < 0)
1626         {       // left key pressed
1627                 self.pressedkeys |= KEY_LEFT;
1628                 self.pressedkeys &= ~KEY_RIGHT;
1629         }
1630         else
1631         {       // no y input
1632                 self.pressedkeys &= ~KEY_RIGHT;
1633                 self.pressedkeys &= ~KEY_LEFT;
1634         }
1635
1636         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1637                 self.pressedkeys |= KEY_JUMP;
1638         else
1639                 self.pressedkeys &= ~KEY_JUMP;
1640         if (self.BUTTON_CROUCH)
1641                 self.pressedkeys |= KEY_CROUCH;
1642         else
1643                 self.pressedkeys &= ~KEY_CROUCH;
1644
1645         if (self.BUTTON_ATCK)
1646                 self.pressedkeys |= KEY_ATCK;
1647         else
1648                 self.pressedkeys &= ~KEY_ATCK;
1649         if (self.BUTTON_ATCK2)
1650                 self.pressedkeys |= KEY_ATCK2;
1651         else
1652                 self.pressedkeys &= ~KEY_ATCK2;
1653 }
1654
1655 /*
1656 ======================
1657 spectate mode routines
1658 ======================
1659 */
1660
1661 void SpectateCopy(entity spectatee) {
1662         other = spectatee;
1663         MUTATOR_CALLHOOK(SpectateCopy);
1664         self.armortype = spectatee.armortype;
1665         self.armorvalue = spectatee.armorvalue;
1666         self.ammo_cells = spectatee.ammo_cells;
1667         self.ammo_plasma = spectatee.ammo_plasma;
1668         self.ammo_shells = spectatee.ammo_shells;
1669         self.ammo_nails = spectatee.ammo_nails;
1670         self.ammo_rockets = spectatee.ammo_rockets;
1671         self.ammo_fuel = spectatee.ammo_fuel;
1672         self.clip_load = spectatee.clip_load;
1673         self.clip_size = spectatee.clip_size;
1674         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1675         self.health = spectatee.health;
1676         self.impulse = 0;
1677         self.items = spectatee.items;
1678         self.last_pickup = spectatee.last_pickup;
1679         self.hit_time = spectatee.hit_time;
1680         self.metertime = spectatee.metertime;
1681         self.strength_finished = spectatee.strength_finished;
1682         self.invincible_finished = spectatee.invincible_finished;
1683         self.pressedkeys = spectatee.pressedkeys;
1684         self.weapons = spectatee.weapons;
1685         self.switchweapon = spectatee.switchweapon;
1686         self.switchingweapon = spectatee.switchingweapon;
1687         self.weapon = spectatee.weapon;
1688         self.vortex_charge = spectatee.vortex_charge;
1689         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1690         self.hagar_load = spectatee.hagar_load;
1691         self.arc_heat_percent = spectatee.arc_heat_percent;
1692         self.minelayer_mines = spectatee.minelayer_mines;
1693         self.punchangle = spectatee.punchangle;
1694         self.view_ofs = spectatee.view_ofs;
1695         self.velocity = spectatee.velocity;
1696         self.dmg_take = spectatee.dmg_take;
1697         self.dmg_save = spectatee.dmg_save;
1698         self.dmg_inflictor = spectatee.dmg_inflictor;
1699         self.v_angle = spectatee.v_angle;
1700         self.angles = spectatee.v_angle;
1701         self.frozen = spectatee.frozen;
1702         self.revive_progress = spectatee.revive_progress;
1703         if(!self.BUTTON_USE)
1704                 self.fixangle = TRUE;
1705         setorigin(self, spectatee.origin);
1706         setsize(self, spectatee.mins, spectatee.maxs);
1707         SetZoomState(spectatee.zoomstate);
1708
1709     anticheat_spectatecopy(spectatee);
1710         self.hud = spectatee.hud;
1711         if(spectatee.vehicle)
1712     {
1713         self.fixangle = FALSE;
1714         //self.velocity = spectatee.vehicle.velocity;
1715         self.vehicle_health = spectatee.vehicle_health;
1716         self.vehicle_shield = spectatee.vehicle_shield;
1717         self.vehicle_energy = spectatee.vehicle_energy;
1718         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1719         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1720         self.vehicle_reload1 = spectatee.vehicle_reload1;
1721         self.vehicle_reload2 = spectatee.vehicle_reload2;
1722
1723         msg_entity = self;
1724
1725         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1726             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1727             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1728             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1729
1730         //WriteByte (MSG_ONE, SVC_SETVIEW);
1731         //    WriteEntity(MSG_ONE, self);
1732         //makevectors(spectatee.v_angle);
1733         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1734     }
1735 }
1736
1737 float SpectateUpdate()
1738 {
1739         if(!self.enemy)
1740             return 0;
1741
1742         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1743         {
1744                 SetSpectator(self, world);
1745                 return 0;
1746         }
1747
1748         SpectateCopy(self.enemy);
1749
1750         return 1;
1751 }
1752
1753
1754 float SpectateSet()
1755 {
1756         if(self.enemy.classname != "player")
1757                 return FALSE;
1758         /*if(self.enemy.vehicle)
1759         {
1760
1761                 msg_entity = self;
1762                 WriteByte(MSG_ONE, SVC_SETVIEW);
1763                 WriteEntity(MSG_ONE, self.enemy);
1764                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1765
1766                 self.movetype = MOVETYPE_NONE;
1767                 accuracy_resend(self);
1768         }
1769         else
1770         {*/
1771                 msg_entity = self;
1772                 WriteByte(MSG_ONE, SVC_SETVIEW);
1773                 WriteEntity(MSG_ONE, self.enemy);
1774                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1775                 self.movetype = MOVETYPE_NONE;
1776                 accuracy_resend(self);
1777
1778                 if(!SpectateUpdate())
1779                         PutObserverInServer();
1780         //}
1781         return TRUE;
1782 }
1783
1784 void SetSpectator(entity player, entity spectatee)
1785 {
1786         entity old_spectatee = player.enemy;
1787
1788         player.enemy = spectatee;
1789
1790         // WEAPONTODO
1791         // these are required to fix the spectator bug with arc
1792         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1793         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1794 }
1795
1796 float Spectate(entity pl)
1797 {
1798         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1799         if(pl.team != self.team)
1800                 return 0;
1801
1802         SetSpectator(self, pl);
1803         return SpectateSet();
1804 }
1805
1806 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1807 entity CA_SpectateNext(entity start) {
1808         if (start.team == self.team) {
1809                 return start;
1810         }
1811
1812         other = start;
1813         // continue from current player
1814         while(other && other.team != self.team) {
1815                 other = find(other, classname, "player");
1816         }
1817
1818         if (!other) {
1819                 // restart from begining
1820                 other = find(other, classname, "player");
1821                 while(other && other.team != self.team) {
1822                         other = find(other, classname, "player");
1823                 }
1824         }
1825
1826         return other;
1827 }
1828
1829 float SpectateNext()
1830 {
1831         other = find(self.enemy, classname, "player");
1832
1833         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1834                 // CA and ca players when spectating enemies is forbidden
1835                 other = CA_SpectateNext(other);
1836         } else {
1837                 // other modes and ca spectators or spectating enemies is allowed
1838                 if (!other)
1839                         other = find(other, classname, "player");
1840         }
1841
1842         if(other) { SetSpectator(self, other); }
1843
1844         return SpectateSet();
1845 }
1846
1847 float SpectatePrev()
1848 {
1849         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1850         other = findchain(classname, "player");
1851         if (!other) // no player
1852                 return FALSE;
1853
1854         entity first = other;
1855         // skip players until current spectated player
1856         if(self.enemy)
1857         while(other && other != self.enemy)
1858                 other = other.chain;
1859
1860         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1861         {
1862                 do { other = other.chain; }
1863                 while(other && other.team != self.team);
1864
1865                 if (!other)
1866                 {
1867                         other = first;
1868                         while(other.team != self.team)
1869                                 other = other.chain;
1870                         if(other == self.enemy)
1871                                 return TRUE;
1872                 }
1873         }
1874         else
1875         {
1876                 if(other.chain)
1877                         other = other.chain;
1878                 else
1879                         other = first;
1880         }
1881         SetSpectator(self, other);
1882         return SpectateSet();
1883 }
1884
1885 /*
1886 =============
1887 ShowRespawnCountdown()
1888
1889 Update a respawn countdown display.
1890 =============
1891 */
1892 void ShowRespawnCountdown()
1893 {
1894         float number;
1895         if(self.deadflag == DEAD_NO) // just respawned?
1896                 return;
1897         else
1898         {
1899                 number = ceil(self.respawn_time - time);
1900                 if(number <= 0)
1901                         return;
1902                 if(number <= self.respawn_countdown)
1903                 {
1904                         self.respawn_countdown = number - 1;
1905                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1906                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1907                 }
1908         }
1909 }
1910
1911 void LeaveSpectatorMode()
1912 {
1913         if(self.caplayer)
1914                 return;
1915         if(nJoinAllowed(self))
1916         {
1917                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1918                 {
1919                         self.classname = "player";
1920                         nades_RemoveBonus(self);
1921
1922                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1923                                 { JoinBestTeam(self, FALSE, TRUE); }
1924
1925                         if(autocvar_g_campaign)
1926                                 { campaign_bots_may_start = 1; }
1927
1928                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1929
1930                         PutClientInServer();
1931
1932                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1933                 }
1934                 else
1935                         stuffcmd(self, "menu_showteamselect\n");
1936         }
1937         else
1938         {
1939                 // Player may not join because g_maxplayers is set
1940                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1941         }
1942 }
1943
1944 /**
1945  * Determines whether the player is allowed to join. This depends on cvar
1946  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1947  * it checks whether the number of currently playing players exceeds g_maxplayers.
1948  * @return int number of free slots for players, 0 if none
1949  */
1950 float nJoinAllowed(entity ignore) {
1951         if(!ignore)
1952         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1953         // so report 0 free slots if restricted
1954         {
1955                 if(autocvar_g_forced_team_otherwise == "spectate")
1956                         return 0;
1957                 if(autocvar_g_forced_team_otherwise == "spectator")
1958                         return 0;
1959         }
1960
1961         if(self.team_forced < 0)
1962                 return 0; // forced spectators can never join
1963
1964         // TODO simplify this
1965         entity e;
1966         float totalClients = 0;
1967         FOR_EACH_CLIENT(e)
1968                 if(e != ignore)
1969                         totalClients += 1;
1970
1971         if (!autocvar_g_maxplayers)
1972                 return maxclients - totalClients;
1973
1974         float currentlyPlaying = 0;
1975         FOR_EACH_REALCLIENT(e)
1976                 if(IS_PLAYER(e) || e.caplayer)
1977                         currentlyPlaying += 1;
1978
1979         if(currentlyPlaying < autocvar_g_maxplayers)
1980                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1981
1982         return 0;
1983 }
1984
1985 /**
1986  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1987  * g_maxplayers_spectator_blocktime seconds
1988  */
1989 void checkSpectatorBlock() {
1990         if(IS_SPEC(self) || IS_OBSERVER(self))
1991         if(!self.caplayer)
1992         if(IS_REAL_CLIENT(self))
1993         {
1994                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1995                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1996                         dropclient(self);
1997                 }
1998         }
1999 }
2000
2001 void PrintWelcomeMessage()
2002 {
2003         if(self.motd_actived_time == 0)
2004         {
2005                 if (autocvar_g_campaign) {
2006                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2007                                 self.motd_actived_time = time;
2008                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2009                         }
2010                 } else {
2011                         if (self.BUTTON_INFO) {
2012                                 self.motd_actived_time = time;
2013                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2014                         }
2015                 }
2016         }
2017         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2018         {
2019                 if (autocvar_g_campaign) {
2020                         if (self.BUTTON_INFO)
2021                                 self.motd_actived_time = time;
2022                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2023                                 self.motd_actived_time = 0;
2024                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2025                         }
2026                 } else {
2027                         if (self.BUTTON_INFO)
2028                                 self.motd_actived_time = time;
2029                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2030                                 self.motd_actived_time = 0;
2031                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2032                         }
2033                 }
2034         }
2035         else //if(self.motd_actived_time < 0) // just connected, motd is active
2036         {
2037                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2038                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2039                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2040                 {
2041                         // instanctly hide MOTD
2042                         self.motd_actived_time = 0;
2043                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2044                 }
2045         }
2046 }
2047
2048 void ObserverThink()
2049 {
2050         float prefered_movetype;
2051         if (self.flags & FL_JUMPRELEASED) {
2052                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2053                         self.flags &= ~FL_JUMPRELEASED;
2054                         self.flags |= FL_SPAWNING;
2055                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2056                         self.flags &= ~FL_JUMPRELEASED;
2057                         if(SpectateNext()) {
2058                                 self.classname = "spectator";
2059                         }
2060                 } else {
2061                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2062                         if (self.movetype != prefered_movetype)
2063                                 self.movetype = prefered_movetype;
2064                 }
2065         } else {
2066                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2067                         self.flags |= FL_JUMPRELEASED;
2068                         if(self.flags & FL_SPAWNING)
2069                         {
2070                                 self.flags &= ~FL_SPAWNING;
2071                                 LeaveSpectatorMode();
2072                                 return;
2073                         }
2074                 }
2075         }
2076 }
2077
2078 void SpectatorThink()
2079 {
2080         if (self.flags & FL_JUMPRELEASED) {
2081                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2082                         self.flags &= ~FL_JUMPRELEASED;
2083                         self.flags |= FL_SPAWNING;
2084                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2085                         self.flags &= ~FL_JUMPRELEASED;
2086                         if(SpectateNext()) {
2087                                 self.classname = "spectator";
2088                         } else {
2089                                 self.classname = "observer";
2090                                 PutClientInServer();
2091                         }
2092                         self.impulse = 0;
2093                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2094                         self.flags &= ~FL_JUMPRELEASED;
2095                         if(SpectatePrev()) {
2096                                 self.classname = "spectator";
2097                         } else {
2098                                 self.classname = "observer";
2099                                 PutClientInServer();
2100                         }
2101                         self.impulse = 0;
2102                 } else if (self.BUTTON_ATCK2) {
2103                         self.flags &= ~FL_JUMPRELEASED;
2104                         self.classname = "observer";
2105                         PutClientInServer();
2106                 } else {
2107                         if(!SpectateUpdate())
2108                                 PutObserverInServer();
2109                 }
2110         } else {
2111                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2112                         self.flags |= FL_JUMPRELEASED;
2113                         if(self.flags & FL_SPAWNING)
2114                         {
2115                                 self.flags &= ~FL_SPAWNING;
2116                                 LeaveSpectatorMode();
2117                                 return;
2118                         }
2119                 }
2120                 if(!SpectateUpdate())
2121                         PutObserverInServer();
2122         }
2123
2124         self.flags |= FL_CLIENT | FL_NOTARGET;
2125 }
2126
2127 void PlayerUseKey()
2128 {
2129         if (!IS_PLAYER(self))
2130                 return;
2131
2132         if(self.vehicle)
2133         {
2134         vehicles_exit(VHEF_NORMAL);
2135         return;
2136         }
2137
2138         // a use key was pressed; call handlers
2139         MUTATOR_CALLHOOK(PlayerUseKey);
2140 }
2141
2142 /*
2143 =============
2144 PlayerPreThink
2145
2146 Called every frame for each client before the physics are run
2147 =============
2148 */
2149 .float usekeypressed;
2150 void() nexball_setstatus;
2151 .float items_added;
2152 void PlayerPreThink (void)
2153 {
2154         WarpZone_PlayerPhysics_FixVAngle();
2155
2156         self.stat_game_starttime = game_starttime;
2157         self.stat_round_starttime = round_starttime;
2158         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2159         self.stat_leadlimit = autocvar_leadlimit;
2160
2161         if(frametime)
2162         {
2163                 // physics frames: update anticheat stuff
2164                 anticheat_prethink();
2165         }
2166
2167         if(blockSpectators && frametime)
2168                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2169                 checkSpectatorBlock();
2170
2171         zoomstate_set = 0;
2172
2173         if(self.netname_previous != self.netname)
2174         {
2175                 if(autocvar_sv_eventlog)
2176                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2177                 if(self.netname_previous)
2178                         strunzone(self.netname_previous);
2179                 self.netname_previous = strzone(self.netname);
2180         }
2181
2182         // version nagging
2183         if(self.version_nagtime)
2184                 if(self.cvar_g_xonoticversion)
2185                         if(time > self.version_nagtime)
2186                         {
2187                                 // don't notify git users
2188                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2189                                 {
2190                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2191                                         {
2192                                                 // notify release users if connecting to git
2193                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2194                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2195                                         }
2196                                         else
2197                                         {
2198                                                 float r;
2199                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2200                                                 if(r < 0)
2201                                                 {
2202                                                         // give users new version
2203                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2204                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2205                                                 }
2206                                                 else if(r > 0)
2207                                                 {
2208                                                         // notify users about old server version
2209                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2210                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2211                                                 }
2212                                         }
2213                                 }
2214                                 self.version_nagtime = 0;
2215                         }
2216
2217         // GOD MODE info
2218         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2219         {
2220                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2221                 self.max_armorvalue = 0;
2222         }
2223
2224 #ifdef TETRIS
2225         if (TetrisPreFrame())
2226                 return;
2227 #endif
2228
2229         if(self.frozen == 2)
2230         {
2231                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2232                 self.health = max(1, self.revive_progress * start_health);
2233                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2234
2235                 if(self.revive_progress >= 1)
2236                         Unfreeze(self);
2237         }
2238         else if(self.frozen == 3)
2239         {
2240                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2241                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2242
2243                 if(self.health < 1)
2244                 {
2245                         if(self.vehicle)
2246                                 vehicles_exit(VHEF_RELESE);
2247                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2248                 }
2249                 else if ( self.revive_progress <= 0 )
2250                         Unfreeze(self);
2251         }
2252
2253         MUTATOR_CALLHOOK(PlayerPreThink);
2254
2255         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2256         {
2257                 if(self.BUTTON_USE && !self.usekeypressed)
2258                         PlayerUseKey();
2259                 self.usekeypressed = self.BUTTON_USE;
2260         }
2261
2262         if(IS_REAL_CLIENT(self))
2263                 PrintWelcomeMessage();
2264
2265         if(IS_PLAYER(self))
2266         {
2267
2268                 CheckRules_Player();
2269
2270                 if (intermission_running)
2271                 {
2272                         IntermissionThink ();   // otherwise a button could be missed between
2273                         return;                                 // the think tics
2274                 }
2275
2276                 //don't allow the player to turn around while game is paused!
2277                 if(timeout_status == TIMEOUT_ACTIVE) {
2278                         // FIXME turn this into CSQC stuff
2279                         self.v_angle = self.lastV_angle;
2280                         self.angles = self.lastV_angle;
2281                         self.fixangle = TRUE;
2282                 }
2283
2284                 if(frametime)
2285                 {
2286                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2287                         {
2288                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2289                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2290                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2291
2292                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2293                                 {
2294                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2295                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2296                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2297                                 }
2298                         }
2299                         else
2300                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2301
2302                         player_powerups();
2303                 }
2304
2305                 if (self.deadflag != DEAD_NO)
2306                 {
2307                         if(self.personal && g_race_qualifying)
2308                         {
2309                                 if(time > self.respawn_time)
2310                                 {
2311                                         self.respawn_time = time + 1; // only retry once a second
2312                                         self.stat_respawn_time = self.respawn_time;
2313                                         respawn();
2314                                         self.impulse = 141;
2315                                 }
2316                         }
2317                         else
2318                         {
2319                                 float button_pressed;
2320                                 if(frametime)
2321                                         player_anim();
2322                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2323
2324                                 if (self.deadflag == DEAD_DYING)
2325                                 {
2326                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2327                                                 self.deadflag = DEAD_RESPAWNING;
2328                                         else if(!button_pressed)
2329                                                 self.deadflag = DEAD_DEAD;
2330                                 }
2331                                 else if (self.deadflag == DEAD_DEAD)
2332                                 {
2333                                         if(button_pressed)
2334                                                 self.deadflag = DEAD_RESPAWNABLE;
2335                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2336                                                 self.deadflag = DEAD_RESPAWNING;
2337                                 }
2338                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2339                                 {
2340                                         if(!button_pressed)
2341                                                 self.deadflag = DEAD_RESPAWNING;
2342                                 }
2343                                 else if (self.deadflag == DEAD_RESPAWNING)
2344                                 {
2345                                         if(time > self.respawn_time)
2346                                         {
2347                                                 self.respawn_time = time + 1; // only retry once a second
2348                                                 self.respawn_time_max = self.respawn_time;
2349                                                 respawn();
2350                                         }
2351                                 }
2352
2353                                 ShowRespawnCountdown();
2354
2355                                 if(self.respawn_flags & RESPAWN_SILENT)
2356                                         self.stat_respawn_time = 0;
2357                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2358                                         self.stat_respawn_time = self.respawn_time_max;
2359                                 else
2360                                         self.stat_respawn_time = self.respawn_time;
2361                         }
2362
2363                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2364                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2365                                 self.stat_respawn_time *= -1;
2366
2367                         return;
2368                 }
2369
2370                 self.prevorigin = self.origin;
2371
2372                 float do_crouch = self.BUTTON_CROUCH;
2373                 if(self.hook.state)
2374                         do_crouch = 0;
2375                 if(self.vehicle)
2376                         do_crouch = 0;
2377                 if(self.frozen)
2378                         do_crouch = 0;
2379
2380                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2381                 // It cannot be predicted by the engine!
2382                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2383                         do_crouch = 0;
2384
2385                 if (do_crouch)
2386                 {
2387                         if (!self.crouch)
2388                         {
2389                                 self.crouch = TRUE;
2390                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2391                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2392                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2393                         }
2394                 }
2395                 else
2396                 {
2397                         if (self.crouch)
2398                         {
2399                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2400                                 if (!trace_startsolid)
2401                                 {
2402                                         self.crouch = FALSE;
2403                                         self.view_ofs = PL_VIEW_OFS;
2404                                         setsize (self, PL_MIN, PL_MAX);
2405                                 }
2406                         }
2407                 }
2408
2409                 FixPlayermodel();
2410
2411                 GrapplingHookFrame();
2412
2413                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2414                 //if(frametime)
2415                 {
2416                         self.items &= ~self.items_added;
2417
2418                         W_WeaponFrame();
2419
2420                         self.items_added = 0;
2421                         if(self.items & IT_JETPACK)
2422                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2423                                         self.items_added |= IT_FUEL;
2424
2425                         self.items |= self.items_added;
2426                 }
2427
2428                 player_regen();
2429
2430                 // WEAPONTODO: Add a weapon request for this
2431                 // rot vortex charge to the charge limit
2432                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2433                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2434
2435                 if(frametime)
2436                         player_anim();
2437
2438                 // secret status
2439                 secrets_setstatus();
2440
2441                 // monsters status
2442                 monsters_setstatus();
2443
2444                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2445
2446                 //self.angles_y=self.v_angle_y + 90;   // temp
2447         } else if(gameover) {
2448                 if (intermission_running)
2449                         IntermissionThink ();   // otherwise a button could be missed between
2450                 return;
2451         } else if(IS_OBSERVER(self)) {
2452                 ObserverThink();
2453         } else if(IS_SPEC(self)) {
2454                 SpectatorThink();
2455         }
2456
2457         // WEAPONTODO: Add weapon request for this
2458         if(!zoomstate_set)
2459                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2460
2461         float oldspectatee_status;
2462         oldspectatee_status = self.spectatee_status;
2463         if(IS_SPEC(self))
2464                 self.spectatee_status = num_for_edict(self.enemy);
2465         else if(IS_OBSERVER(self))
2466                 self.spectatee_status = num_for_edict(self);
2467         else
2468                 self.spectatee_status = 0;
2469         if(self.spectatee_status != oldspectatee_status)
2470         {
2471                 ClientData_Touch(self);
2472         }
2473
2474         if(self.teamkill_soundtime)
2475         if(time > self.teamkill_soundtime)
2476         {
2477                 self.teamkill_soundtime = 0;
2478
2479                 entity oldpusher, oldself;
2480
2481                 oldself = self; self = self.teamkill_soundsource;
2482                 oldpusher = self.pusher; self.pusher = oldself;
2483
2484                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2485
2486                 self.pusher = oldpusher;
2487                 self = oldself;
2488         }
2489
2490         if(self.taunt_soundtime)
2491         if(time > self.taunt_soundtime)
2492         {
2493                 self.taunt_soundtime = 0;
2494                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2495         }
2496
2497         target_voicescript_next(self);
2498
2499         // WEAPONTODO: Move into weaponsystem somehow
2500         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2501         if(!self.weapon)
2502                 self.clip_load = self.clip_size = 0;
2503 }
2504
2505 float isInvisibleString(string s)
2506 {
2507         float i, n, c;
2508         s = strdecolorize(s);
2509         for((i = 0), (n = strlen(s)); i < n; ++i)
2510         {
2511                 c = str2chr(s, i);
2512                 switch(c)
2513                 {
2514                         case 0:
2515                         case 32: // space
2516                                 break;
2517                         case 192: // charmap space
2518                                 if (!autocvar_utf8_enable)
2519                                         break;
2520                                 return FALSE;
2521                         case 160: // space in unicode fonts
2522                         case 0xE000 + 192: // utf8 charmap space
2523                                 if (autocvar_utf8_enable)
2524                                         break;
2525                         default:
2526                                 return FALSE;
2527                 }
2528         }
2529         return TRUE;
2530 }
2531
2532 /*
2533 =============
2534 PlayerPostThink
2535
2536 Called every frame for each client after the physics are run
2537 =============
2538 */
2539 .float idlekick_lasttimeleft;
2540 void PlayerPostThink (void)
2541 {
2542         // Savage: Check for nameless players
2543         if (isInvisibleString(self.netname)) {
2544                 self.netname = "Player";
2545                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2546         }
2547
2548         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2549         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2550         {
2551                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2552                 {
2553                         if(self.idlekick_lasttimeleft)
2554                         {
2555                                 self.idlekick_lasttimeleft = 0;
2556                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2557                         }
2558                 }
2559                 else
2560                 {
2561                         float timeleft;
2562                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2563                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2564                         {
2565                                 if(!self.idlekick_lasttimeleft)
2566                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2567                         }
2568                         if(timeleft <= 0)
2569                         {
2570                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2571                                 dropclient(self);
2572                                 return;
2573                         }
2574                         else if(timeleft <= 10)
2575                         {
2576                                 if(timeleft != self.idlekick_lasttimeleft)
2577                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2578                                 self.idlekick_lasttimeleft = timeleft;
2579                         }
2580                 }
2581         }
2582
2583 #ifdef TETRIS
2584         if(self.impulse == 100)
2585                 ImpulseCommands();
2586         if (!TetrisPostFrame())
2587         {
2588 #endif
2589
2590         CheatFrame();
2591
2592         //CheckPlayerJump();
2593
2594         if(IS_PLAYER(self)) {
2595                 CheckRules_Player();
2596                 UpdateChatBubble();
2597                 if (self.impulse)
2598                         ImpulseCommands();
2599                 if (intermission_running)
2600                         return;         // intermission or finale
2601                 GetPressedKeys();
2602         }
2603
2604 #ifdef TETRIS
2605         }
2606 #endif
2607
2608         /*
2609         float i;
2610         for(i = 0; i < 1000; ++i)
2611         {
2612                 vector end;
2613                 end = self.origin + '0 0 1024' + 512 * randomvec();
2614                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2615                 if(trace_fraction < 1)
2616                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2617                 {
2618                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2619                         break;
2620                 }
2621         }
2622         */
2623
2624         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2625
2626         if(self.waypointsprite_attachedforcarrier)
2627                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2628
2629         playerdemo_write();
2630
2631         CSQCMODEL_AUTOUPDATE();
2632 }