qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         msg_entity = e;
  17         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  18         WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ONE, snd);
  20 }
  21
  22 float ClientData_Send(entity to, float sf)
  23 {
  24         if(to != self.owner)
  25         {
  26                 error("wtf");
  27                 return FALSE;
  28         }
  29
  30         entity e;
  31
  32         e = to;
  33         if(to.classname == "spectator")
  34                 e = to.enemy;
  35
  36         sf = 0;
  37
  38         if(e.race_completed)
  39                 sf |= 1; // forced scoreboard
  40         if(to.spectatee_status)
  41                 sf |= 2; // spectator ent number follows
  42         if(e.zoomstate)
  43                 sf |= 4; // zoomed
  44         if(e.porto_v_angle_held)
  45                 sf |= 8; // angles held
  46
  47         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  48         WriteByte(MSG_ENTITY, sf);
  49
  50         if(sf & 2)
  51                 WriteByte(MSG_ENTITY, to.spectatee_status);
  52
  53         if(sf & 8)
  54         {
  55                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  56                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  57         }
  58
  59         return TRUE;
  60 }
  61
  62 void ClientData_Attach()
  63 {
  64         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  65         self.clientdata.drawonlytoclient = self;
  66         self.clientdata.owner = self;
  67 }
  68
  69 void ClientData_Detach()
  70 {
  71         remove(self.clientdata);
  72         self.clientdata = world;
  73 }
  74
  75 void ClientData_Touch(entity e)
  76 {
  77         e.clientdata.SendFlags = 1;
  78
  79         // make it spectatable
  80         entity e2;
  81         FOR_EACH_REALCLIENT(e2)
  82         {
  83                 if(e2 != e)
  84                         if(e2.classname == "spectator")
  85                                 if(e2.enemy == e)
  86                                         e2.clientdata.SendFlags = 1;
  87         }
  88 }
  89
  90
  91 .vector spawnpoint_score;
  92 .string netname_previous;
  93
  94 void spawnfunc_info_player_survivor (void)
  95 {
  96         spawnfunc_info_player_deathmatch();
  97 }
  98
  99 void spawnfunc_info_player_start (void)
 100 {
 101         spawnfunc_info_player_deathmatch();
 102 }
 103
 104 void spawnfunc_info_player_deathmatch (void)
 105 {
 106         self.classname = "info_player_deathmatch";
 107         relocate_spawnpoint();
 108 }
 109
 110 void spawnpoint_use()
 111 {
 112         if(teams_matter)
 113         if(have_team_spawns > 0)
 114         {
 115                 self.team = activator.team;
 116                 some_spawn_has_been_used = 1;
 117         }
 118 };
 119
 120 // Returns:
 121 //   _x: prio (-1 if unusable)
 122 //   _y: weight
 123 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 124 {
 125         float shortest, thisdist;
 126         float prio;
 127         entity player;
 128
 129         prio = 0;
 130
 131         // filter out spots for the wrong team
 132         if(teamcheck)
 133         if(spot.team != teamcheck)
 134                 return '-1 0 0';
 135
 136         if(race_spawns)
 137                 if(spot.target == "")
 138                         return '-1 0 0';
 139
 140         if(clienttype(self) == CLIENTTYPE_REAL)
 141         {
 142                 if(spot.restriction == 1)
 143                         return '-1 0 0';
 144         }
 145         else
 146         {
 147                 if(spot.restriction == 2)
 148                         return '-1 0 0';
 149         }
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 local entity ent;
 154                 float good, found;
 155                 ent = find(world, targetname, spot.target);
 156
 157                 while(ent) {
 158                         if(ent.classname == "target_objective")
 159                         {
 160                                 found = 1;
 161                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 162                                         return '-1 0 0';
 163                                 good = 1;
 164                         }
 165                         else if(ent.classname == "trigger_race_checkpoint")
 166                         {
 167                                 found = 1;
 168                                 if(!anypoint) // spectators may spawn everywhere
 169
 170                                 {
 171                                         if(g_race_qualifying)
 172                                         {
 173                                                 // spawn at first
 174                                                 if(ent.race_checkpoint != 0)
 175                                                         return '-1 0 0';
 176                                                 if(spot.race_place != race_lowest_place_spawn)
 177                                                         return '-1 0 0';
 178                                         }
 179                                         else
 180                                         {
 181                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 182                                                         return '-1 0 0';
 183                                                 // try reusing the previous spawn
 184                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 185                                                         prio += 1;
 186                                                 if(ent.race_checkpoint == 0)
 187                                                 {
 188                                                         float pl;
 189                                                         pl = self.race_place;
 190                                                         if(pl > race_highest_place_spawn)
 191                                                                 pl = 0;
 192                                                         if(pl == 0 && !self.race_started)
 193                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 194                                                         if(spot.race_place != pl)
 195                                                                 return '-1 0 0';
 196                                                 }
 197                                         }
 198                                 }
 199                                 good = 1;
 200                         }
 201                         ent = find(ent, targetname, spot.target);
 202                 }
 203
 204                 if(found && !good)
 205                         return '-1 0 0';
 206         }
 207
 208         player = playerlist;
 209         shortest = vlen(world.maxs - world.mins);
 210         for(player = playerlist; player; player = player.chain)
 211                 if (player != self)
 212                 {
 213                         thisdist = vlen(player.origin - spot.origin);
 214                         if (thisdist < shortest)
 215                                 shortest = thisdist;
 216                 }
 217         return prio * '1 0 0' + shortest * '0 1 0';
 218 }
 219
 220 float spawn_allbad;
 221 float spawn_allgood;
 222 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 223 {
 224         local entity spot, spotlist, spotlistend;
 225         spawn_allgood = TRUE;
 226         spawn_allbad = TRUE;
 227
 228         spotlist = world;
 229         spotlistend = world;
 230
 231         for(spot = firstspot; spot; spot = spot.chain)
 232         {
 233                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 234
 235                 if(cvar("spawn_debugview"))
 236                 {
 237                         setmodel(spot, "models/runematch/rune.mdl");
 238                         if(spot.spawnpoint_score_y < mindist)
 239                         {
 240                                 spot.colormod = '1 0 0';
 241                                 spot.scale = 1;
 242                         }
 243                         else
 244                         {
 245                                 spot.colormod = '0 1 0';
 246                                 spot.scale = spot.spawnpoint_score_y / mindist;
 247                         }
 248                 }
 249
 250                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 251                 {
 252                         if(spot.spawnpoint_score_y < mindist)
 253                         {
 254                                 // too short distance
 255                                 spawn_allgood = FALSE;
 256                         }
 257                         else
 258                         {
 259                                 // perfect
 260                                 spawn_allbad = FALSE;
 261
 262                                 if(spotlistend)
 263                                         spotlistend.chain = spot;
 264                                 spotlistend = spot;
 265                                 if(!spotlist)
 266                                         spotlist = spot;
 267
 268                                 /*
 269                                 if(teamcheck)
 270                                 if(spot.team != teamcheck)
 271                                         error("invalid spawn added");
 272
 273                                 print("added ", etos(spot), "\n");
 274                                 */
 275                         }
 276                 }
 277         }
 278         if(spotlistend)
 279                 spotlistend.chain = world;
 280
 281         /*
 282                 entity e;
 283                 if(teamcheck)
 284                         for(e = spotlist; e; e = e.chain)
 285                         {
 286                                 print("seen ", etos(e), "\n");
 287                                 if(e.team != teamcheck)
 288                                         error("invalid spawn found");
 289                         }
 290         */
 291
 292         return spotlist;
 293 }
 294
 295 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 296 {
 297         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 298         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 299         local entity spot;
 300
 301         RandomSelection_Init();
 302         for(spot = firstspot; spot; spot = spot.chain)
 303                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 304
 305         return RandomSelection_chosen_ent;
 306 }
 307
 308 /*
 309 =============
 310 SelectSpawnPoint
 311
 312 Finds a point to respawn
 313 =============
 314 */
 315 entity SelectSpawnPoint (float anypoint)
 316 {
 317         local float teamcheck;
 318         local entity firstspot_new;
 319         local entity spot, firstspot, playerlist;
 320
 321         spot = find (world, classname, "testplayerstart");
 322         if (spot)
 323                 return spot;
 324
 325         teamcheck = 0;
 326
 327         if(!anypoint && have_team_spawns > 0)
 328                 teamcheck = self.team;
 329
 330         // get the list of players
 331         playerlist = findchain(classname, "player");
 332         // get the entire list of spots
 333         firstspot = findchain(classname, "info_player_deathmatch");
 334         // filter out the bad ones
 335         // (note this returns the original list if none survived)
 336         if(anypoint)
 337         {
 338                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 339         }
 340         else
 341         {
 342                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 343                 if(!firstspot_new)
 344                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 345                 firstspot = firstspot_new;
 346
 347                 // there is 50/50 chance of choosing a random spot or the furthest spot
 348                 // (this means that roughly every other spawn will be furthest, so you
 349                 // usually won't get fragged at spawn twice in a row)
 350                 if (arena_roundbased && !g_ca)
 351                 {
 352                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 353                         if(firstspot_new)
 354                                 firstspot = firstspot_new;
 355                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 356                 }
 357                 else if (random() > cvar("g_spawn_furthest"))
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 else
 360                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 361         }
 362
 363         if(cvar("spawn_debugview"))
 364         {
 365                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 366
 367                 entity e;
 368                 if(teamcheck)
 369                         for(e = firstspot; e; e = e.chain)
 370                                 if(e.team != teamcheck)
 371                                         error("invalid spawn found");
 372         }
 373
 374         if (!spot)
 375         {
 376                 if(cvar("spawn_debug"))
 377                         GotoNextMap();
 378                 else
 379                 {
 380                         if(some_spawn_has_been_used)
 381                                 return world; // team can't spawn any more, because of actions of other team
 382                         else
 383                                 error("Cannot find a spawn point - please fix the map!");
 384                 }
 385         }
 386
 387         return spot;
 388 }
 389
 390 /*
 391 =============
 392 CheckPlayerModel
 393
 394 Checks if the argument string can be a valid playermodel.
 395 Returns a valid one in doubt.
 396 =============
 397 */
 398 string FallbackPlayerModel = "models/player/marine.zym";
 399 string CheckPlayerModel(string plyermodel) {
 400         if(strlen(plyermodel) < 4)
 401                 return FallbackPlayerModel;
 402         if( substring(plyermodel,0,14) != "models/player/")
 403                 return FallbackPlayerModel;
 404         else if(cvar("sv_servermodelsonly"))
 405         {
 406                 if(substring(plyermodel,-4,4) != ".zym")
 407                 if(substring(plyermodel,-4,4) != ".dpm")
 408                 if(substring(plyermodel,-4,4) != ".iqm")
 409                 if(substring(plyermodel,-4,4) != ".md3")
 410                 if(substring(plyermodel,-4,4) != ".psk")
 411                         return FallbackPlayerModel;
 412                 // forbid the LOD models
 413                 if(substring(plyermodel, -9,5) == "_lod1")
 414                         return FallbackPlayerModel;
 415                 if(substring(plyermodel, -9,5) == "_lod2")
 416                         return FallbackPlayerModel;
 417                 if(plyermodel != strtolower(plyermodel))
 418                         return FallbackPlayerModel;
 419                 if(!fexists(plyermodel))
 420                         return FallbackPlayerModel;
 421         }
 422         return plyermodel;
 423 }
 424
 425 /*
 426 =============
 427 Client_customizeentityforclient
 428
 429 LOD reduction
 430 =============
 431 */
 432 void Client_uncustomizeentityforclient()
 433 {
 434         if(self.modelindex == 0) // no need to uncustomize then
 435                 return;
 436         self.modelindex = self.modelindex_lod0;
 437         self.skin = self.skinindex;
 438 }
 439
 440 float Client_customizeentityforclient()
 441 {
 442         entity modelsource;
 443
 444         if(self.modelindex == 0)
 445                 return TRUE;
 446
 447         // forcemodel stuff
 448
 449 #ifdef PROFILING
 450         float t0;
 451         t0 = gettime(GETTIME_HIRES); // reference
 452 #endif
 453
 454         modelsource = self;
 455
 456 #ifdef ALLOW_FORCEMODELS
 457         if(other.cvar_cl_forceplayermodelsfromxonotic)
 458                 if not(self.modelindex_lod0_from_xonotic)
 459                         modelsource = other;
 460         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 461                 modelsource = other;
 462 #endif
 463
 464         self.skin = modelsource.skinindex;
 465
 466 #if 0
 467         if(modelsource == self)
 468                 self.skin = modelsource.skinindex;
 469         else
 470                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 471 #endif
 472
 473         // self: me
 474         // other: the player viewing me
 475         float distance;
 476         float f;
 477
 478         if(other.cvar_cl_playerdetailreduction <= 0)
 479         {
 480                 if(other.cvar_cl_playerdetailreduction <= -2)
 481                         self.modelindex = modelsource.modelindex_lod2;
 482                 else if(other.cvar_cl_playerdetailreduction <= -1)
 483                         self.modelindex = modelsource.modelindex_lod1;
 484                 else
 485                         self.modelindex = modelsource.modelindex_lod0;
 486         }
 487         else
 488         {
 489                 distance = vlen(self.origin - other.origin);
 490                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 491                 if(f > sv_loddistance2)
 492                         self.modelindex = modelsource.modelindex_lod2;
 493                 else if(f > sv_loddistance1)
 494                         self.modelindex = modelsource.modelindex_lod1;
 495                 else
 496                         self.modelindex = modelsource.modelindex_lod0;
 497         }
 498
 499 #ifdef PROFILING
 500         float t1;
 501         t1 = gettime(GETTIME_HIRES); // reference
 502         client_cefc_accumulator += (t1 - t0);
 503 #endif
 504
 505         return TRUE;
 506 }
 507
 508 void UpdatePlayerSounds();
 509 void setmodel_lod(entity e, string modelname)
 510 {
 511         string s;
 512
 513         if(sv_loddistance1)
 514         {
 515                 // FIXME: this only supports 3-letter extensions
 516                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 517                 if(fexists(s))
 518                 {
 519                         setmodel(e, s); // players have high precision
 520                         self.modelindex_lod1 = self.modelindex;
 521                 }
 522                 else
 523                         self.modelindex_lod1 = -1;
 524
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod2 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod2 = -1;
 533
 534                 precache_model(modelname);
 535                 setmodel(e, modelname); // players have high precision
 536                 self.modelindex_lod0 = self.modelindex;
 537
 538                 if(self.modelindex_lod1 < 0)
 539                         self.modelindex_lod1 = self.modelindex;
 540
 541                 if(self.modelindex_lod2 < 0)
 542                         self.modelindex_lod2 = self.modelindex;
 543         }
 544         else
 545         {
 546                 precache_model(modelname);
 547                 setmodel(e, modelname); // players have high precision
 548                 self.modelindex_lod0 = self.modelindex;
 549                         // save it for possible player model forcing
 550         }
 551
 552         s = whichpack(self.model);
 553         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 554
 555         player_setupanimsformodel();
 556         UpdatePlayerSounds();
 557 }
 558
 559 /*
 560 =============
 561 PutObserverInServer
 562
 563 putting a client as observer in the server
 564 =============
 565 */
 566 void FixPlayermodel();
 567 void PutObserverInServer (void)
 568 {
 569         entity  spot;
 570
 571         race_PreSpawnObserver();
 572
 573         spot = SelectSpawnPoint (TRUE);
 574         if(!spot)
 575                 error("No spawnpoints for observers?!?\n");
 576         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 577
 578         if(clienttype(self) == CLIENTTYPE_REAL)
 579         {
 580                 msg_entity = self;
 581                 WriteByte(MSG_ONE, SVC_SETVIEW);
 582                 WriteEntity(MSG_ONE, self);
 583         }
 584
 585         DropAllRunes(self);
 586
 587         Portal_ClearAll(self);
 588
 589         if(self.flagcarried)
 590                 DropFlag(self.flagcarried, world, world);
 591
 592         if(self.ballcarried)
 593                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 594
 595         WaypointSprite_PlayerDead();
 596
 597         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 598                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 599
 600         if(self.killcount != -666) {
 601                 if(g_lms) {
 602                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 603                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 604                         else
 605                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 606                 } else
 607                         bprint ("^4", self.netname, "^4 is spectating now\n");
 608
 609                 if(self.just_joined == FALSE) {
 610                         LogTeamchange(self.playerid, -1, 4);
 611                 } else
 612                         self.just_joined = FALSE;
 613         }
 614
 615         PlayerScore_Clear(self); // clear scores when needed
 616
 617         self.spectatortime = time;
 618
 619         self.classname = "observer";
 620         self.iscreature = FALSE;
 621         self.health = -666;
 622         self.takedamage = DAMAGE_NO;
 623         self.solid = SOLID_NOT;
 624         self.movetype = MOVETYPE_NOCLIP;
 625         self.flags = FL_CLIENT | FL_NOTARGET;
 626         self.armorvalue = 666;
 627         self.effects = 0;
 628         self.armorvalue = cvar("g_balance_armor_start");
 629         self.pauserotarmor_finished = 0;
 630         self.pauserothealth_finished = 0;
 631         self.pauseregen_finished = 0;
 632         self.damageforcescale = 0;
 633         self.death_time = 0;
 634         self.dead_frame = 0;
 635         self.alpha = 0;
 636         self.scale = 0;
 637         self.fade_time = 0;
 638         self.pain_frame = 0;
 639         self.pain_finished = 0;
 640         self.strength_finished = 0;
 641         self.invincible_finished = 0;
 642         self.pushltime = 0;
 643         self.think = SUB_Null;
 644         self.nextthink = 0;
 645         self.hook_time = 0;
 646         self.runes = 0;
 647         self.deadflag = DEAD_NO;
 648         self.angles = spot.angles;
 649         self.angles_z = 0;
 650         self.fixangle = TRUE;
 651         self.crouch = FALSE;
 652
 653         self.view_ofs = PL_VIEW_OFS;
 654         setorigin (self, spot.origin);
 655         setsize (self, '0 0 0', '0 0 0');
 656         self.prevorigin = self.origin;
 657         self.items = 0;
 658         self.weapons = 0;
 659         self.model = "";
 660         FixPlayermodel();
 661         self.model = "";
 662         self.modelindex = 0;
 663         self.weapon = 0;
 664         self.weaponmodel = "";
 665         self.weaponentity = world;
 666         self.exteriorweaponentity = world;
 667         self.killcount = -666;
 668         self.velocity = '0 0 0';
 669         self.avelocity = '0 0 0';
 670         self.punchangle = '0 0 0';
 671         self.punchvector = '0 0 0';
 672         self.oldvelocity = self.velocity;
 673         self.fire_endtime = -1;
 674
 675         if(sv_loddistance1)
 676                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 677
 678         if(g_arena)
 679         {
 680                 if(self.version_mismatch)
 681                 {
 682                         Spawnqueue_Unmark(self);
 683                         Spawnqueue_Remove(self);
 684                 }
 685                 else
 686                 {
 687                         Spawnqueue_Insert(self);
 688                 }
 689         }
 690         else if(g_lms)
 691         {
 692                 // Only if the player cannot play at all
 693                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 694                         self.frags = FRAGS_SPECTATOR;
 695                 else
 696                         self.frags = FRAGS_LMS_LOSER;
 697         }
 698         else
 699                 self.frags = FRAGS_SPECTATOR;
 700
 701         MUTATOR_CALLHOOK(MakePlayerObserver);
 702 }
 703
 704 float RestrictSkin(float s)
 705 {
 706         if(!teams_matter)
 707                 return s;
 708         if(s == 6)
 709                 return 6;
 710         return mod(s, 3);
 711 }
 712
 713 void FixPlayermodel()
 714 {
 715         local string defaultmodel;
 716         local float defaultskin, chmdl, oldskin;
 717         local vector m1, m2;
 718
 719         defaultmodel = "";
 720
 721         if(cvar("sv_defaultcharacter") == 1) {
 722                 defaultskin = 0;
 723
 724                 if(teams_matter)
 725                 {
 726                         string s;
 727                         s = Team_ColorNameLowerCase(self.team);
 728                         if(s != "neutral")
 729                         {
 730                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 731                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 732                         }
 733                 }
 734
 735                 if(defaultmodel == "")
 736                 {
 737                         defaultmodel = cvar_string("sv_defaultplayermodel");
 738                         defaultskin = cvar("sv_defaultplayerskin");
 739                 }
 740         }
 741
 742         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 743         {
 744                 if(self.model != "")
 745                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 746                 self.model = ""; // force the != checks to return true
 747         }
 748
 749         if(defaultmodel != "")
 750         {
 751                 if (defaultmodel != self.model)
 752                 {
 753                         m1 = self.mins;
 754                         m2 = self.maxs;
 755                         setmodel_lod (self, defaultmodel);
 756                         setsize (self, m1, m2);
 757                         chmdl = TRUE;
 758                 }
 759
 760                 oldskin = self.skinindex;
 761                 self.skinindex = defaultskin;
 762         } else {
 763                 if (self.playermodel != self.model || self.playermodel == "")
 764                 {
 765                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 766                         m1 = self.mins;
 767                         m2 = self.maxs;
 768                         setmodel_lod (self, self.playermodel);
 769                         setsize (self, m1, m2);
 770                         chmdl = TRUE;
 771                 }
 772
 773                 oldskin = self.skinindex;
 774                 self.skinindex = RestrictSkin(stof(self.playerskin));
 775         }
 776
 777         if(chmdl || oldskin != self.skinindex)
 778                 self.species = player_getspecies(); // model or skin has changed
 779
 780         if(!teams_matter)
 781                 if(strlen(cvar_string("sv_defaultplayercolors")))
 782                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 783                                 setcolor(self, cvar("sv_defaultplayercolors"));
 784 }
 785
 786 void PlayerTouchExplode(entity p1, entity p2)
 787 {
 788         vector org;
 789         org = (p1.origin + p2.origin) * 0.5;
 790         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 791
 792         te_explosion(org);
 793
 794         entity e;
 795         e = spawn();
 796         setorigin(e, org);
 797         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 798         remove(e);
 799 }
 800
 801 /*
 802 =============
 803 PutClientInServer
 804
 805 Called when a client spawns in the server
 806 =============
 807 */
 808 //void() ctf_playerchanged;
 809 void PutClientInServer (void)
 810 {
 811         if(clienttype(self) == CLIENTTYPE_BOT)
 812         {
 813                 self.classname = "player";
 814         }
 815         else if(clienttype(self) == CLIENTTYPE_REAL)
 816         {
 817                 msg_entity = self;
 818                 WriteByte(MSG_ONE, SVC_SETVIEW);
 819                 WriteEntity(MSG_ONE, self);
 820         }
 821
 822         // player is dead and becomes observer
 823         // FIXME fix LMS scoring for new system
 824         if(g_lms)
 825         {
 826                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 827                         self.classname = "observer";
 828         }
 829
 830         if(g_arena || (g_ca && !allowed_to_spawn))
 831         if(!self.spawned)
 832                 self.classname = "observer";
 833
 834         if(gameover)
 835                 self.classname = "observer";
 836
 837         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 838                 entity spot, oldself;
 839                 float j;
 840
 841                 if(self.team < 0)
 842                         JoinBestTeam(self, FALSE, TRUE);
 843
 844                 race_PreSpawn();
 845
 846                 spot = SelectSpawnPoint (FALSE);
 847                 if(!spot)
 848                 {
 849                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 850                         return; // spawn failed
 851                 }
 852
 853                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 854
 855                 self.classname = "player";
 856                 self.wasplayer = TRUE;
 857                 self.iscreature = TRUE;
 858                 self.movetype = MOVETYPE_WALK;
 859                 self.solid = SOLID_SLIDEBOX;
 860                 if(cvar("g_playerclip_collisions"))
 861                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 862                 else
 863                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 864                 self.frags = FRAGS_PLAYER;
 865                 if(independent_players)
 866                         MAKE_INDEPENDENT_PLAYER(self);
 867                 self.flags = FL_CLIENT;
 868                 self.takedamage = DAMAGE_AIM;
 869                 if(g_minstagib)
 870                         self.effects = EF_FULLBRIGHT;
 871                 else
 872                         self.effects = 0;
 873                 self.air_finished = time + 12;
 874                 self.dmg = 2;
 875
 876                 if(inWarmupStage)
 877                 {
 878                         self.ammo_shells = warmup_start_ammo_shells;
 879                         self.ammo_nails = warmup_start_ammo_nails;
 880                         self.ammo_rockets = warmup_start_ammo_rockets;
 881                         self.ammo_cells = warmup_start_ammo_cells;
 882                         self.ammo_fuel = warmup_start_ammo_fuel;
 883                         self.health = warmup_start_health;
 884                         self.armorvalue = warmup_start_armorvalue;
 885                         self.weapons = warmup_start_weapons;
 886                 }
 887                 else
 888                 {
 889                         self.ammo_shells = start_ammo_shells;
 890                         self.ammo_nails = start_ammo_nails;
 891                         self.ammo_rockets = start_ammo_rockets;
 892                         self.ammo_cells = start_ammo_cells;
 893                         self.ammo_fuel = start_ammo_fuel;
 894                         self.health = start_health;
 895                         self.armorvalue = start_armorvalue;
 896                         self.weapons = start_weapons;
 897                 }
 898
 899                 if(g_weaponarena_random)
 900                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 901
 902                 self.items = start_items;
 903                 self.jump_interval = time;
 904
 905                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 906                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 907                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 908                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 909                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 910                 //extend the pause of rotting if client was reset at the beginning of the countdown
 911                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 912                         self.spawnshieldtime += game_starttime - time;
 913                         self.pauserotarmor_finished += game_starttime - time;
 914                         self.pauserothealth_finished += game_starttime - time;
 915                         self.pauseregen_finished += game_starttime - time;
 916                 }
 917                 self.damageforcescale = 2;
 918                 self.death_time = 0;
 919                 self.dead_frame = 0;
 920                 self.alpha = 0;
 921                 self.scale = 0;
 922                 self.fade_time = 0;
 923                 self.pain_frame = 0;
 924                 self.pain_finished = 0;
 925                 self.strength_finished = 0;
 926                 self.invincible_finished = 0;
 927                 self.pushltime = 0;
 928                 // players have no think function
 929                 self.think = SUB_Null;
 930                 self.nextthink = 0;
 931                 self.hook_time = 0;
 932                 self.dmg_team = 0;
 933
 934                 self.metertime = 0;
 935
 936                 self.runes = 0;
 937
 938                 self.deadflag = DEAD_NO;
 939
 940                 self.angles = spot.angles;
 941
 942                 self.angles_z = 0; // never spawn tilted even if the spot says to
 943                 self.fixangle = TRUE; // turn this way immediately
 944                 self.velocity = '0 0 0';
 945                 self.avelocity = '0 0 0';
 946                 self.punchangle = '0 0 0';
 947                 self.punchvector = '0 0 0';
 948                 self.oldvelocity = self.velocity;
 949                 self.fire_endtime = -1;
 950
 951                 msg_entity = self;
 952                 WRITESPECTATABLE_MSG_ONE({
 953                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 954                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 955                 });
 956
 957                 if(sv_loddistance1)
 958                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 959
 960                 self.model = "";
 961                 FixPlayermodel();
 962
 963                 self.crouch = FALSE;
 964                 self.view_ofs = PL_VIEW_OFS;
 965                 setsize (self, PL_MIN, PL_MAX);
 966                 self.spawnorigin = spot.origin;
 967                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 968                 // don't reset back to last position, even if new position is stuck in solid
 969                 self.oldorigin = self.origin;
 970                 self.prevorigin = self.origin;
 971                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 972
 973                 if(g_arena)
 974                 {
 975                         Spawnqueue_Remove(self);
 976                         Spawnqueue_Mark(self);
 977                 }
 978
 979                 else if(g_ca)
 980                         self.caplayer = 1;
 981
 982                 self.event_damage = PlayerDamage;
 983
 984                 self.bot_attack = TRUE;
 985
 986                 self.statdraintime = time + 5;
 987                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 988
 989                 if(self.killcount == -666) {
 990                         PlayerScore_Clear(self);
 991                         self.killcount = 0;
 992                 }
 993
 994                 self.cnt = WEP_LASER;
 995
 996                 CL_SpawnWeaponentity();
 997                 self.alpha = default_player_alpha;
 998                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 999                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1000
1001                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1002                 self.lms_traveled_distance = 0;
1003                 self.speedrunning = FALSE;
1004
1005                 race_PostSpawn(spot);
1006
1007                 if(cvar("spawn_debug"))
1008                 {
1009                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1010                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1011                 }
1012
1013                 //stuffcmd(self, "chase_active 0");
1014                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1015
1016                 if (cvar("g_spawnsound"))
1017                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1018
1019                 if(g_assault) {
1020                         if(self.team == assault_attacker_team)
1021                                 centerprint(self, "You are attacking!");
1022                         else
1023                                 centerprint(self, "You are defending!");
1024                 }
1025
1026                 target_voicescript_clear(self);
1027
1028                 // reset fields the weapons may use
1029                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1030                         weapon_action(j, WR_RESETPLAYER);
1031
1032                 oldself = self;
1033                 self = spot;
1034                         activator = oldself;
1035                                 SUB_UseTargets();
1036                         activator = world;
1037                 self = oldself;
1038
1039                 MUTATOR_CALLHOOK(PlayerSpawn);
1040
1041                 self.switchweapon = w_getbestweapon(self);
1042                 self.cnt = self.switchweapon;
1043                 self.weapon = 0;
1044         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1045                 PutObserverInServer ();
1046         }
1047
1048         //if(g_ctf)
1049         //      ctf_playerchanged();
1050 }
1051
1052 float ClientInit_SendEntity(entity to, float sf)
1053 {
1054         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1055         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1056         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1057         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1058         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1059
1060         if(sv_foginterval && world.fog != "")
1061                 WriteString(MSG_ENTITY, world.fog);
1062         else
1063                 WriteString(MSG_ENTITY, "");
1064         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1065         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1066         return TRUE;
1067 }
1068
1069 void ClientInit_Spawn()
1070 {
1071         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1072 }
1073
1074 /*
1075 =============
1076 SetNewParms
1077 =============
1078 */
1079 void SetNewParms (void)
1080 {
1081         // initialize parms for a new player
1082         parm1 = -(86400 * 366);
1083 }
1084
1085 /*
1086 =============
1087 SetChangeParms
1088 =============
1089 */
1090 void SetChangeParms (void)
1091 {
1092         // save parms for level change
1093         parm1 = self.parm_idlesince - time;
1094 }
1095
1096 /*
1097 =============
1098 DecodeLevelParms
1099 =============
1100 */
1101 void DecodeLevelParms (void)
1102 {
1103         // load parms
1104         self.parm_idlesince = parm1;
1105         if(self.parm_idlesince == -(86400 * 366))
1106                 self.parm_idlesince = time;
1107
1108         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1109         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1110 }
1111
1112 /*
1113 =============
1114 ClientKill
1115
1116 Called when a client types 'kill' in the console
1117 =============
1118 */
1119
1120 void ClientKill_Now_TeamChange()
1121 {
1122         if(self.killindicator_teamchange == -1)
1123         {
1124                 self.team = -1;
1125                 JoinBestTeam( self, FALSE, FALSE );
1126         }
1127         else
1128                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1129 }
1130
1131 void ClientKill_Now()
1132 {
1133         if(self.killindicator_teamchange)
1134                 ClientKill_Now_TeamChange();
1135
1136         // in any case:
1137         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1138
1139         if(self.killindicator)
1140         {
1141                 dprint("Cleaned up after a leaked kill indicator.\n");
1142                 remove(self.killindicator);
1143                 self.killindicator = world;
1144         }
1145 }
1146 void KillIndicator_Think()
1147 {
1148         if (!self.owner.modelindex)
1149         {
1150                 self.owner.killindicator = world;
1151                 remove(self);
1152                 return;
1153         }
1154
1155         if(self.cnt <= 0)
1156         {
1157                 self = self.owner;
1158                 ClientKill_Now(); // no oldself needed
1159                 return;
1160         }
1161         else
1162         {
1163                 if(self.cnt <= 10)
1164                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1165                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1166                 {
1167                         if(self.cnt <= 10)
1168                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1169                         if(self.owner.killindicator_teamchange)
1170                         {
1171                                 if(self.owner.killindicator_teamchange == -1)
1172                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1173                                 else
1174                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1175                         }
1176                         else
1177                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1178                 }
1179                 self.nextthink = time + 1;
1180                 self.cnt -= 1;
1181         }
1182 }
1183
1184 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1185 {
1186         float killtime;
1187         entity e;
1188         killtime = cvar("g_balance_kill_delay");
1189
1190         if(g_race_qualifying)
1191                 killtime = 0;
1192
1193         self.killindicator_teamchange = targetteam;
1194
1195         if(!self.killindicator)
1196         {
1197                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1198                 {
1199                         ClientKill_Now();
1200                 }
1201                 else
1202                 {
1203                         self.killindicator = spawn();
1204                         self.killindicator.owner = self;
1205                         self.killindicator.scale = 0.5;
1206                         setattachment(self.killindicator, self, "");
1207                         setorigin(self.killindicator, '0 0 52');
1208                         self.killindicator.think = KillIndicator_Think;
1209                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1210                         self.killindicator.cnt = ceil(killtime);
1211                         self.killindicator.count = bound(0, ceil(killtime), 10);
1212                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1213
1214                         for(e = world; (e = find(e, classname, "body")) != world; )
1215                         {
1216                                 if(e.enemy != self)
1217                                         continue;
1218                                 e.killindicator = spawn();
1219                                 e.killindicator.owner = e;
1220                                 e.killindicator.scale = 0.5;
1221                                 setattachment(e.killindicator, e, "");
1222                                 setorigin(e.killindicator, '0 0 52');
1223                                 e.killindicator.think = KillIndicator_Think;
1224                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1225                                 e.killindicator.cnt = ceil(killtime);
1226                         }
1227                         self.lip = 0;
1228                 }
1229         }
1230         if(self.killindicator)
1231         {
1232                 if(targetteam)
1233                         self.killindicator.colormod = TeamColor(targetteam);
1234                 else
1235                         self.killindicator.colormod = '0 0 0';
1236         }
1237 }
1238
1239 void ClientKill (void)
1240 {
1241         ClientKill_TeamChange(0);
1242 }
1243
1244 void DoTeamChange(float destteam)
1245 {
1246         float t, c0;
1247         if(!teams_matter)
1248         {
1249                 if(destteam >= 0)
1250                         SetPlayerColors(self, destteam);
1251                 return;
1252         }
1253         if(self.classname == "player")
1254         if(destteam == -1)
1255         {
1256                 CheckAllowedTeams(self);
1257                 t = FindSmallestTeam(self, TRUE);
1258                 switch(self.team)
1259                 {
1260                         case COLOR_TEAM1: c0 = c1; break;
1261                         case COLOR_TEAM2: c0 = c2; break;
1262                         case COLOR_TEAM3: c0 = c3; break;
1263                         case COLOR_TEAM4: c0 = c4; break;
1264                         default:          c0 = 999;
1265                 }
1266                 switch(t)
1267                 {
1268                         case 1:
1269                                 if(c0 > c1)
1270                                         destteam = COLOR_TEAM1;
1271                                 break;
1272                         case 2:
1273                                 if(c0 > c2)
1274                                         destteam = COLOR_TEAM2;
1275                                 break;
1276                         case 3:
1277                                 if(c0 > c3)
1278                                         destteam = COLOR_TEAM3;
1279                                 break;
1280                         case 4:
1281                                 if(c0 > c4)
1282                                         destteam = COLOR_TEAM4;
1283                                 break;
1284                 }
1285                 if(destteam == -1)
1286                         return;
1287         }
1288         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1289                 return;
1290         ClientKill_TeamChange(destteam);
1291 }
1292
1293 void FixClientCvars(entity e)
1294 {
1295         // send prediction settings to the client
1296         stuffcmd(e, "\nin_bindmap 0 0\n");
1297         if(g_race || g_cts)
1298                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1299         if(cvar("g_antilag") == 3) // client side hitscan
1300                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1301                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1302         /*
1303          * we no longer need to stuff this. Remove this comment block if you feel
1304          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1305         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1306         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1307         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1308         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1309         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1310         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1311         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1312         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1313         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1314         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1315         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1316         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1317         stuffcmd(e, "cl_movement_edgefriction 1\n");
1318          */
1319 }
1320
1321 /*
1322 =============
1323 ClientConnect
1324
1325 Called when a client connects to the server
1326 =============
1327 */
1328 //void ctf_clientconnect();
1329 string ColoredTeamName(float t);
1330 void DecodeLevelParms (void);
1331 //void dom_player_join_team(entity pl);
1332 #ifdef UID
1333 .float uid_kicktime;
1334 .string uid;
1335 #endif
1336 void ClientConnect (void)
1337 {
1338         float t;
1339
1340         if(self.flags & FL_CLIENT)
1341         {
1342                 print("Warning: ClientConnect, but already connected!\n");
1343                 return;
1344         }
1345
1346         if(Ban_MaybeEnforceBan(self))
1347                 return;
1348
1349         DecodeLevelParms();
1350
1351         self.classname = "player_joining";
1352
1353         self.flags = FL_CLIENT;
1354         self.version_nagtime = time + 10 + random() * 10;
1355
1356         if(player_count<0)
1357         {
1358                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1359                 player_count = 0;
1360         }
1361
1362         PlayerScore_Attach(self);
1363         ClientData_Attach();
1364
1365         bot_clientconnect();
1366
1367         playerdemo_init();
1368
1369         anticheat_init();
1370
1371         race_PreSpawnObserver();
1372
1373         //if(g_domination)
1374         //      dom_player_join_team(self);
1375
1376         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1377
1378         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1379                 self.classname = "observer";
1380         } else {
1381                 if(teams_matter)
1382                 {
1383                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1384                         {
1385                                 self.classname = "player";
1386                                 campaign_bots_may_start = 1;
1387                         }
1388                         else
1389                         {
1390                                 self.classname = "observer"; // do it anyway
1391                         }
1392                 }
1393                 else
1394                 {
1395                         self.classname = "player";
1396                         campaign_bots_may_start = 1;
1397                 }
1398         }
1399
1400         self.playerid = (playerid_last = playerid_last + 1);
1401
1402         if(cvar("sv_eventlog"))
1403                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1404
1405         LogTeamchange(self.playerid, self.team, 1);
1406
1407         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1408
1409         self.netname_previous = strzone(self.netname);
1410
1411         bprint("^4", self.netname, "^4 connected");
1412
1413         if(self.classname != "observer" && (g_domination || g_ctf))
1414                 bprint(" and joined the ", ColoredTeamName(self.team));
1415
1416         bprint("\n");
1417
1418         self.welcomemessage_time = 0;
1419
1420         stuffcmd(self, strcat(clientstuff, "\n"));
1421         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1422         stuffcmd(self, "cl_particles_reloadeffects\n");
1423
1424         FixClientCvars(self);
1425
1426         // spawnfunc_waypoint sprites
1427         WaypointSprite_InitClient(self);
1428
1429         // Wazat's grappling hook
1430         SetGrappleHookBindings();
1431
1432         // get autoswitch state from player when he toggles it
1433         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1434
1435         // get version info from player
1436         stuffcmd(self, "cmd clientversion $gameversion\n");
1437
1438         // get other cvars from player
1439         GetCvars(0);
1440
1441         // set cvar for team scoreboard
1442         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1443
1444         // notify about available teams
1445         if(teams_matter)
1446         {
1447                 CheckAllowedTeams(self);
1448                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1449                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1450         }
1451         else
1452                 stuffcmd(self, "set _teams_available 0\n");
1453
1454         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1455
1456         if(g_arena || g_ca)
1457         {
1458                 self.classname = "observer";
1459                 if(g_arena)
1460                         Spawnqueue_Insert(self);
1461         }
1462         /*else if(g_ctf)
1463         {
1464                 ctf_clientconnect();
1465         }*/
1466
1467         if(teams_matter || radar_showennemies)
1468                 attach_entcs();
1469
1470         bot_relinkplayerlist();
1471
1472         self.spectatortime = time;
1473         if(blockSpectators)
1474         {
1475                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1476         }
1477
1478         self.jointime = time;
1479         self.allowedTimeouts = cvar("sv_timeout_number");
1480
1481         if(clienttype(self) == CLIENTTYPE_REAL)
1482         {
1483                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1484                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1485         }
1486
1487         if(g_lms)
1488         {
1489                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1490                 {
1491                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1492                         self.frags = FRAGS_SPECTATOR;
1493                 }
1494         }
1495
1496         if(!sv_foginterval && world.fog != "")
1497                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1498
1499         SoundEntity_Attach(self);
1500
1501         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1502         {
1503                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1504                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1505         }
1506         else
1507                 self.hitplotfh = -1;
1508
1509 #ifdef UID
1510         if(clienttype(self) == CLIENTTYPE_REAL)
1511         if not(self.uid)
1512                 self.uid_kicktime = time + 60;
1513 #endif
1514
1515         if(g_race || g_cts) {
1516                 string rr;
1517                 if(g_cts)
1518                         rr = CTS_RECORD;
1519                 else
1520                         rr = RACE_RECORD;
1521                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1522
1523                 race_send_recordtime(MSG_ONE);
1524                 race_send_speedaward(MSG_ONE);
1525
1526                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1527                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1528                 race_send_speedaward_alltimebest(MSG_ONE);
1529
1530                 float i;
1531                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1532                         race_SendRankings(i, 0, 0, MSG_ONE);
1533                 }
1534         }
1535         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1536                 send_CSQC_teamnagger();
1537
1538         CheatInitClient();
1539 }
1540
1541 /*
1542 =============
1543 ClientDisconnect
1544
1545 Called when a client disconnects from the server
1546 =============
1547 */
1548 .entity chatbubbleentity;
1549 .entity teambubbleentity;
1550 void ReadyCount();
1551 void ClientDisconnect (void)
1552 {
1553         if not(self.flags & FL_CLIENT)
1554         {
1555                 print("Warning: ClientDisconnect without ClientConnect\n");
1556                 return;
1557         }
1558
1559         CheatShutdownClient();
1560
1561         if(self.hitplotfh >= 0)
1562         {
1563                 fclose(self.hitplotfh);
1564                 self.hitplotfh = -1;
1565         }
1566
1567         anticheat_report();
1568         anticheat_shutdown();
1569
1570         playerdemo_shutdown();
1571
1572         bot_clientdisconnect();
1573
1574         if(self.entcs)
1575                 detach_entcs();
1576
1577         if(cvar("sv_eventlog"))
1578                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1579         bprint ("^4",self.netname);
1580         bprint ("^4 disconnected\n");
1581
1582         SoundEntity_Detach(self);
1583
1584         DropAllRunes(self);
1585         MUTATOR_CALLHOOK(ClientDisconnect);
1586
1587         Portal_ClearAll(self);
1588
1589         if(self.flagcarried)
1590                 DropFlag(self.flagcarried, world, world);
1591         if(self.ballcarried)
1592                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1593
1594         // Here, everything has been done that requires this player to be a client.
1595
1596         self.flags &~= FL_CLIENT;
1597
1598         if (self.chatbubbleentity)
1599                 remove (self.chatbubbleentity);
1600
1601         if (self.teambubbleentity)
1602                 remove (self.teambubbleentity);
1603
1604         if (self.killindicator)
1605                 remove (self.killindicator);
1606
1607         WaypointSprite_PlayerGone();
1608
1609         bot_relinkplayerlist();
1610
1611         // remove laserdot
1612         if(self.weaponentity)
1613                 if(self.weaponentity.lasertarget)
1614                         remove(self.weaponentity.lasertarget);
1615
1616         if(g_arena)
1617         {
1618                 Spawnqueue_Unmark(self);
1619                 Spawnqueue_Remove(self);
1620         }
1621
1622         ClientData_Detach();
1623         PlayerScore_Detach(self);
1624
1625         if(self.netname_previous)
1626                 strunzone(self.netname_previous);
1627         if(self.clientstatus)
1628                 strunzone(self.clientstatus);
1629
1630         ClearPlayerSounds();
1631
1632         if(self.personal)
1633                 remove(self.personal);
1634
1635         self.playerid = 0;
1636         ReadyCount();
1637
1638         // free cvars
1639         GetCvars(-1);
1640 }
1641
1642 .float BUTTON_CHAT;
1643 void ChatBubbleThink()
1644 {
1645         self.nextthink = time;
1646         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1647         {
1648                 if(self.owner) // but why can that ever be world?
1649                         self.owner.chatbubbleentity = world;
1650                 remove(self);
1651                 return;
1652         }
1653         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1654 #ifdef TETRIS
1655                 || self.owner.tetris_on
1656 #endif
1657         )
1658                 self.model = self.mdl;
1659         else
1660                 self.model = "";
1661 };
1662
1663 void UpdateChatBubble()
1664 {
1665         if (!self.modelindex)
1666                 return;
1667         // spawn a chatbubble entity if needed
1668         if (!self.chatbubbleentity)
1669         {
1670                 self.chatbubbleentity = spawn();
1671                 self.chatbubbleentity.owner = self;
1672                 self.chatbubbleentity.exteriormodeltoclient = self;
1673                 self.chatbubbleentity.think = ChatBubbleThink;
1674                 self.chatbubbleentity.nextthink = time;
1675                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1676                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1677                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1678                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1679                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1680                 self.chatbubbleentity.model = "";
1681                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1682         }
1683 }
1684
1685
1686 void TeamBubbleThink()
1687 {
1688         self.nextthink = time;
1689         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1690         {
1691                 if(self.owner) // but why can that ever be world?
1692                         self.owner.teambubbleentity = world;
1693                 remove(self);
1694                 return;
1695         }
1696 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1697         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1698                 self.model = "";
1699         else
1700                 self.model = self.mdl;
1701
1702 };
1703
1704 float TeamBubble_customizeentityforclient()
1705 {
1706         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1707 }
1708
1709 void UpdateTeamBubble()
1710 {
1711         if (!self.modelindex || !teams_matter)
1712                 return;
1713         // spawn a teambubble entity if needed
1714         if (!self.teambubbleentity && teams_matter)
1715         {
1716                 self.teambubbleentity = spawn();
1717                 self.teambubbleentity.owner = self;
1718                 self.teambubbleentity.exteriormodeltoclient = self;
1719                 self.teambubbleentity.think = TeamBubbleThink;
1720                 self.teambubbleentity.nextthink = time;
1721                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1722 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1723                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1724                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1725                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1726                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1727                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1728                 self.teambubbleentity.effects = EF_LOWPRECISION;
1729         }
1730 }
1731
1732 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1733 // added to the model skins
1734 /*void UpdateColorModHack()
1735 {
1736         local float c;
1737         c = self.clientcolors & 15;
1738         // LordHavoc: only bothering to support white, green, red, yellow, blue
1739              if (!teams_matter) self.colormod = '0 0 0';
1740         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1741         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1742         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1743         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1744         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1745         else self.colormod = '1 1 1';
1746 };*/
1747
1748 void respawn(void)
1749 {
1750         CopyBody(1);
1751         self.effects |= EF_NODRAW; // prevent another CopyBody
1752         PutClientInServer();
1753 }
1754
1755 void play_countdown(float finished, string samp)
1756 {
1757         if(clienttype(self) == CLIENTTYPE_REAL)
1758                 if(floor(finished - time - frametime) != floor(finished - time))
1759                         if(finished - time < 6)
1760                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1761 }
1762
1763 /**
1764  * When sv_timeout is used this function returs strings like
1765  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1766  * Called by centerprint functions
1767  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1768  */
1769 string getTimeoutText(float addOneSecond) {
1770         if (!cvar("sv_timeout") || !timeoutStatus)
1771                 return "";
1772
1773         local string retStr;
1774         if (timeoutStatus == 1) {
1775                 if (addOneSecond == 1) {
1776                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1777                 }
1778                 else {
1779                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1780                 }
1781                 return retStr;
1782         }
1783         else if (timeoutStatus == 2) {
1784                 if (addOneSecond) {
1785                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1786                         //don't show messages like "Timeout ends in 0 seconds"...
1787                         if ((remainingTimeoutTime + 1) > 0)
1788                                 return retStr;
1789                         else
1790                                 return "";
1791                 }
1792                 else {
1793                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1794                         //don't show messages like "Timeout ends in 0 seconds"...
1795                         if (remainingTimeoutTime > 0)
1796                                 return retStr;
1797                         else
1798                                 return "";
1799                 }
1800         }
1801         else return "";
1802 }
1803
1804 void player_powerups (void)
1805 {
1806         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1807         {
1808                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1809                 self.modelflags |= MF_ROCKET;
1810         }
1811         else
1812         {
1813                 SoundEntity_StopSound(self, CHAN_PLAYER);
1814                 self.modelflags &~= MF_ROCKET;
1815         }
1816
1817         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1818
1819         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1820                 return;
1821
1822         Fire_ApplyDamage(self);
1823         Fire_ApplyEffect(self);
1824
1825         if (g_minstagib)
1826         {
1827                 self.effects |= EF_FULLBRIGHT;
1828
1829                 if (self.items & IT_STRENGTH)
1830                 {
1831                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1832                         if (time > self.strength_finished)
1833                         {
1834                                 self.alpha = default_player_alpha;
1835                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1836                                 self.items &~= IT_STRENGTH;
1837                                 sprint(self, "^3Invisibility has worn off\n");
1838                         }
1839                 }
1840                 else
1841                 {
1842                         if (time < self.strength_finished)
1843                         {
1844                                 self.alpha = g_minstagib_invis_alpha;
1845                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1846                                 self.items |= IT_STRENGTH;
1847                                 sprint(self, "^3You are invisible\n");
1848                         }
1849                 }
1850
1851                 if (self.items & IT_INVINCIBLE)
1852                 {
1853                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1854                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1855                         {
1856                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1857                                 sprint(self, "^3Speed has worn off\n");
1858                         }
1859                 }
1860                 else
1861                 {
1862                         if (time < self.invincible_finished)
1863                         {
1864                                 self.items = self.items | IT_INVINCIBLE;
1865                                 sprint(self, "^3You are on speed\n");
1866                         }
1867                 }
1868                 return;
1869         }
1870
1871         if (self.items & IT_STRENGTH)
1872         {
1873                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1874                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1875                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1876                 {
1877                         self.items = self.items - (self.items & IT_STRENGTH);
1878                         sprint(self, "^3Strength has worn off\n");
1879                 }
1880         }
1881         else
1882         {
1883                 if (time < self.strength_finished)
1884                 {
1885                         self.items = self.items | IT_STRENGTH;
1886                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1887                 }
1888         }
1889         if (self.items & IT_INVINCIBLE)
1890         {
1891                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1892                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1893                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1894                 {
1895                         self.items = self.items - (self.items & IT_INVINCIBLE);
1896                         sprint(self, "^3Shield has worn off\n");
1897                 }
1898         }
1899         else
1900         {
1901                 if (time < self.invincible_finished)
1902                 {
1903                         self.items = self.items | IT_INVINCIBLE;
1904                         sprint(self, "^3Shield surrounds you\n");
1905                 }
1906         }
1907
1908         if(cvar("g_nodepthtestplayers"))
1909                 self.effects = self.effects | EF_NODEPTHTEST;
1910
1911         if(cvar("g_fullbrightplayers"))
1912                 self.effects = self.effects | EF_FULLBRIGHT;
1913
1914         // midair gamemode: damage only while in the air
1915         // if in midair mode, being on ground grants temporary invulnerability
1916         // (this is so that multishot weapon don't clear the ground flag on the
1917         // first damage in the frame, leaving the player vulnerable to the
1918         // remaining hits in the same frame)
1919         if (self.flags & FL_ONGROUND)
1920         if (g_midair)
1921                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1922
1923         if (time >= game_starttime)
1924         if (time < self.spawnshieldtime)
1925                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1926 }
1927
1928 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1929 {
1930         if(current > stable)
1931                 return current;
1932         else if(current > stable - 0.25) // when close enough, "snap"
1933                 return stable;
1934         else
1935                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1936 }
1937
1938 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1939 {
1940         if(current < stable)
1941                 return current;
1942         else if(current < stable + 0.25) // when close enough, "snap"
1943                 return stable;
1944         else
1945                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1946 }
1947
1948 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1949 {
1950         if(current > rotstable)
1951         {
1952                 if(rotframetime > 0)
1953                 {
1954                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1955                         current = max(rotstable, current - rotlinear * rotframetime);
1956                 }
1957         }
1958         else if(current < regenstable)
1959         {
1960                 if(regenframetime > 0)
1961                 {
1962                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1963                         current = min(regenstable, current + regenlinear * regenframetime);
1964                 }
1965         }
1966
1967         if(current > limit)
1968                 current = limit;
1969
1970         return current;
1971 }
1972
1973 void player_regen (void)
1974 {
1975         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1976         maxh = cvar("g_balance_health_rotstable");
1977         maxa = cvar("g_balance_armor_rotstable");
1978         maxf = cvar("g_balance_fuel_rotstable");
1979         minh = cvar("g_balance_health_regenstable");
1980         mina = cvar("g_balance_armor_regenstable");
1981         minf = cvar("g_balance_fuel_regenstable");
1982         limith = cvar("g_balance_health_limit");
1983         limita = cvar("g_balance_armor_limit");
1984         limitf = cvar("g_balance_fuel_limit");
1985
1986         max_mod = regen_mod = rot_mod = limit_mod = 1;
1987
1988         if (self.runes & RUNE_REGEN)
1989         {
1990                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1991                 {
1992                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1993                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1994                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1995                 }
1996                 else
1997                 {
1998                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1999                         max_mod = cvar("g_balance_rune_regen_hpmod");
2000                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2001                 }
2002         }
2003         else if (self.runes & CURSE_VENOM)
2004         {
2005                 max_mod = cvar("g_balance_curse_venom_hpmod");
2006                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2007                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2008                 else
2009                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2010                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2011                 //if (!self.runes & RUNE_REGEN)
2012                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2013         }
2014         maxh = maxh * max_mod;
2015         //maxa = maxa * max_mod;
2016         //maxf = maxf * max_mod;
2017         minh = minh * max_mod;
2018         //mina = mina * max_mod;
2019         //minf = minf * max_mod;
2020         limith = limith * limit_mod;
2021         limita = limita * limit_mod;
2022         //limitf = limitf * limit_mod;
2023
2024         if(g_lms && g_ca)
2025                 rot_mod = 0;
2026
2027         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2028         {
2029                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2030                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2031
2032                 // if player rotted to death...  die!
2033                 if(self.health < 1)
2034                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2035         }
2036
2037         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2038                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2039 }
2040
2041 float zoomstate_set;
2042 void SetZoomState(float z)
2043 {
2044         if(z != self.zoomstate)
2045         {
2046                 self.zoomstate = z;
2047                 ClientData_Touch(self);
2048         }
2049         zoomstate_set = 1;
2050 }
2051
2052 void GetPressedKeys(void) {
2053         if (self.movement_x > 0) // get if movement keys are pressed
2054         {       // forward key pressed
2055                 self.pressedkeys |= KEY_FORWARD;
2056                 self.pressedkeys &~= KEY_BACKWARD;
2057         }
2058         else if (self.movement_x < 0)
2059         {       // backward key pressed
2060                 self.pressedkeys |= KEY_BACKWARD;
2061                 self.pressedkeys &~= KEY_FORWARD;
2062         }
2063         else
2064         {       // no x input
2065                 self.pressedkeys &~= KEY_FORWARD;
2066                 self.pressedkeys &~= KEY_BACKWARD;
2067         }
2068
2069         if (self.movement_y > 0)
2070         {       // right key pressed
2071                 self.pressedkeys |= KEY_RIGHT;
2072                 self.pressedkeys &~= KEY_LEFT;
2073         }
2074         else if (self.movement_y < 0)
2075         {       // left key pressed
2076                 self.pressedkeys |= KEY_LEFT;
2077                 self.pressedkeys &~= KEY_RIGHT;
2078         }
2079         else
2080         {       // no y input
2081                 self.pressedkeys &~= KEY_RIGHT;
2082                 self.pressedkeys &~= KEY_LEFT;
2083         }
2084
2085         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2086                 self.pressedkeys |= KEY_JUMP;
2087         else
2088                 self.pressedkeys &~= KEY_JUMP;
2089         if (self.BUTTON_CROUCH)
2090                 self.pressedkeys |= KEY_CROUCH;
2091         else
2092                 self.pressedkeys &~= KEY_CROUCH;
2093 }
2094
2095 void update_stats (float number, float hit, float fired) {
2096 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2097 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2098
2099         if(number) {
2100                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2101                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2102         } else {
2103                 self.stat_hit = hit * sv_accuracy_data_share;
2104                 self.stat_fired = fired * sv_accuracy_data_share;
2105         }
2106 }
2107
2108 /*
2109 ======================
2110 spectate mode routines
2111 ======================
2112 */
2113
2114 .float weapon_count;
2115 void SpectateCopy(entity spectatee) {
2116         if(spectatee.weapon_count < WEP_LAST) {
2117                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2118                 spectatee.weapon_count ++;
2119         } else
2120                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2121
2122         other = spectatee;
2123         MUTATOR_CALLHOOK(SpectateCopy);
2124         self.armortype = spectatee.armortype;
2125         self.armorvalue = spectatee.armorvalue;
2126         self.ammo_cells = spectatee.ammo_cells;
2127         self.ammo_shells = spectatee.ammo_shells;
2128         self.ammo_nails = spectatee.ammo_nails;
2129         self.ammo_rockets = spectatee.ammo_rockets;
2130         self.ammo_fuel = spectatee.ammo_fuel;
2131         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2132         self.health = spectatee.health;
2133         self.impulse = 0;
2134         self.items = spectatee.items;
2135         self.metertime = spectatee.metertime;
2136         self.strength_finished = spectatee.strength_finished;
2137         self.invincible_finished = spectatee.invincible_finished;
2138         self.pressedkeys = spectatee.pressedkeys;
2139         self.weapons = spectatee.weapons;
2140         self.switchweapon = spectatee.switchweapon;
2141         self.weapon = spectatee.weapon;
2142         self.punchangle = spectatee.punchangle;
2143         self.view_ofs = spectatee.view_ofs;
2144         self.v_angle = spectatee.v_angle;
2145         self.velocity = spectatee.velocity;
2146         self.dmg_take = spectatee.dmg_take;
2147         self.dmg_save = spectatee.dmg_save;
2148         self.dmg_inflictor = spectatee.dmg_inflictor;
2149         self.angles = spectatee.v_angle;
2150         self.fixangle = TRUE;
2151         setorigin(self, spectatee.origin);
2152         setsize(self, spectatee.mins, spectatee.maxs);
2153         SetZoomState(spectatee.zoomstate);
2154
2155         anticheat_spectatecopy(spectatee);
2156 }
2157
2158 float SpectateUpdate() {
2159         if(!self.enemy)
2160                 return 0;
2161
2162         if (self == self.enemy)
2163                 return 0;
2164
2165         if(self.enemy.classname != "player")
2166                 return 0;
2167
2168         SpectateCopy(self.enemy);
2169
2170         return 1;
2171 }
2172
2173 float SpectateNext() {
2174         other = find(self.enemy, classname, "player");
2175
2176         if (!other)
2177                 other = find(other, classname, "player");
2178
2179         if (other)
2180                 self.enemy = other;
2181
2182         if(self.enemy.classname == "player") {
2183                 msg_entity = self;
2184                 WriteByte(MSG_ONE, SVC_SETVIEW);
2185                 WriteEntity(MSG_ONE, self.enemy);
2186                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2187                 self.movetype = MOVETYPE_NONE;
2188
2189                 self.enemy.weapon_count = 0;
2190
2191                 if(!SpectateUpdate())
2192                         PutObserverInServer();
2193
2194                 return 1;
2195         } else {
2196                 return 0;
2197         }
2198 }
2199
2200 /*
2201 =============
2202 ShowRespawnCountdown()
2203
2204 Update a respawn countdown display.
2205 =============
2206 */
2207 void ShowRespawnCountdown()
2208 {
2209         float number;
2210         if(self.deadflag == DEAD_NO) // just respawned?
2211                 return;
2212         else
2213         {
2214                 number = ceil(self.death_time - time);
2215                 if(number <= 0)
2216                         return;
2217                 if(number <= self.respawn_countdown)
2218                 {
2219                         self.respawn_countdown = number - 1;
2220                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2221                                 AnnounceTo(self, strcat(ftos(number), ""));
2222                 }
2223         }
2224 }
2225
2226 void LeaveSpectatorMode()
2227 {
2228         if(isJoinAllowed()) {
2229                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2230                         self.classname = "player";
2231
2232                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2233                                 JoinBestTeam(self, FALSE, TRUE);
2234
2235                         if(cvar("g_campaign"))
2236                                 campaign_bots_may_start = 1;
2237
2238                         self.stat_count = WEP_LAST;
2239
2240                         PutClientInServer();
2241
2242                         if(self.classname == "player")
2243                                 bprint ("^4", self.netname, "^4 is playing now\n");
2244
2245                         if(!cvar("g_campaign"))
2246                                 centerprint(self,""); // clear MOTD
2247
2248                         return;
2249                 } else {
2250                         if (g_ca && self.caplayer) {
2251                         }       // do nothing
2252                         else
2253                                 stuffcmd(self,"menu_showteamselect\n");
2254                         return;
2255                 }
2256         }
2257         else {
2258                 //player may not join because of g_maxplayers is set
2259                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2260         }
2261 }
2262
2263 /**
2264  * Determines whether the player is allowed to join. This depends on cvar
2265  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2266  * it checks whether the number of currently playing players exceeds g_maxplayers.
2267  * @return bool TRUE if the player is allowed to join, false otherwise
2268  */
2269 float isJoinAllowed() {
2270         if (!cvar("g_maxplayers"))
2271                 return TRUE;
2272
2273         local entity e;
2274         local float currentlyPlaying;
2275         FOR_EACH_REALPLAYER(e) {
2276                 if(e.classname == "player")
2277                         currentlyPlaying += 1;
2278         }
2279         if(currentlyPlaying < cvar("g_maxplayers"))
2280                 return TRUE;
2281
2282         return FALSE;
2283 }
2284
2285 /**
2286  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2287  * g_maxplayers_spectator_blocktime seconds
2288  */
2289 void checkSpectatorBlock() {
2290         if(self.classname == "spectator" || self.classname == "observer") {
2291                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2292                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2293                         dropclient(self);
2294                 }
2295         }
2296 }
2297
2298 float vercmp_recursive(string v1, string v2)
2299 {
2300         float dot1, dot2;
2301         string s1, s2;
2302         float r;
2303
2304         dot1 = strstrofs(v1, ".", 0);
2305         dot2 = strstrofs(v2, ".", 0);
2306         if(dot1 == -1)
2307                 s1 = v1;
2308         else
2309                 s1 = substring(v1, 0, dot1);
2310         if(dot2 == -1)
2311                 s2 = v2;
2312         else
2313                 s2 = substring(v2, 0, dot2);
2314
2315         r = stof(s1) - stof(s2);
2316         if(r != 0)
2317                 return r;
2318
2319         r = strcasecmp(s1, s2);
2320         if(r != 0)
2321                 return r;
2322
2323         if(dot1 == -1)
2324                 if(dot2 == -1)
2325                         return 0;
2326                 else
2327                         return -1;
2328         else
2329                 if(dot2 == -1)
2330                         return 1;
2331                 else
2332                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2333 }
2334
2335 float vercmp(string v1, string v2)
2336 {
2337         if(strcasecmp(v1, v2) == 0) // early out check
2338                 return 0;
2339         return vercmp_recursive(v1, v2);
2340 }
2341
2342 void ObserverThink()
2343 {
2344         if (self.flags & FL_JUMPRELEASED) {
2345                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2346                         self.welcomemessage_time = 0;
2347                         self.flags &~= FL_JUMPRELEASED;
2348                         self.flags |= FL_SPAWNING;
2349                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2350                         self.welcomemessage_time = 0;
2351                         self.flags &~= FL_JUMPRELEASED;
2352                         if(SpectateNext() == 1) {
2353                                 self.classname = "spectator";
2354                         }
2355                 }
2356         } else {
2357                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2358                         self.flags |= FL_JUMPRELEASED;
2359                         if(self.flags & FL_SPAWNING)
2360                         {
2361                                 self.flags &~= FL_SPAWNING;
2362                                 LeaveSpectatorMode();
2363                                 return;
2364                         }
2365                 }
2366         }
2367         PrintWelcomeMessage(self);
2368 }
2369
2370 void SpectatorThink()
2371 {
2372         if (self.flags & FL_JUMPRELEASED) {
2373                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2374                         self.welcomemessage_time = 0;
2375                         self.flags &~= FL_JUMPRELEASED;
2376                         self.flags |= FL_SPAWNING;
2377                 } else if(self.BUTTON_ATCK) {
2378                         self.welcomemessage_time = 0;
2379                         self.flags &~= FL_JUMPRELEASED;
2380                         if(SpectateNext() == 1) {
2381                                 self.classname = "spectator";
2382                         } else {
2383                                 self.classname = "observer";
2384                                 self.stat_count = WEP_LAST;
2385                                 PutClientInServer();
2386                         }
2387                 } else if (self.BUTTON_ATCK2) {
2388                         self.welcomemessage_time = 0;
2389                         self.flags &~= FL_JUMPRELEASED;
2390                         self.classname = "observer";
2391                         self.stat_count = WEP_LAST;
2392                         PutClientInServer();
2393                 } else {
2394                         if(!SpectateUpdate())
2395                                 PutObserverInServer();
2396                 }
2397         } else {
2398                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2399                         self.flags |= FL_JUMPRELEASED;
2400                         if(self.flags & FL_SPAWNING)
2401                         {
2402                                 self.flags &~= FL_SPAWNING;
2403                                 LeaveSpectatorMode();
2404                                 return;
2405                         }
2406                 }
2407         }
2408
2409         PrintWelcomeMessage(self);
2410         self.flags |= FL_CLIENT | FL_NOTARGET;
2411 }
2412
2413 .float touchexplode_time;
2414
2415 /*
2416 =============
2417 PlayerPreThink
2418
2419 Called every frame for each client before the physics are run
2420 =============
2421 */
2422 void() ctf_setstatus;
2423 void() nexball_setstatus;
2424 .float items_added;
2425 void PlayerPreThink (void)
2426 {
2427         self.stat_game_starttime = game_starttime;
2428         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2429         self.stat_leadlimit = cvar("leadlimit");
2430
2431         if(frametime)
2432         {
2433                 // physics frames: update anticheat stuff
2434                 anticheat_prethink();
2435         }
2436
2437         if(blockSpectators && frametime)
2438                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2439                 checkSpectatorBlock();
2440
2441         zoomstate_set = 0;
2442
2443         if(self.netname_previous != self.netname)
2444         {
2445                 if(cvar("sv_eventlog"))
2446                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2447                 if(self.netname_previous)
2448                         strunzone(self.netname_previous);
2449                 self.netname_previous = strzone(self.netname);
2450         }
2451
2452         // version nagging
2453         if(self.version_nagtime)
2454                 if(self.cvar_g_xonoticversion)
2455                         if(time > self.version_nagtime)
2456                         {
2457                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2458                                 {
2459                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2460                                         {
2461                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2462                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2463                                         }
2464                                         else
2465                                         {
2466                                                 float r;
2467                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2468                                                 if(r < 0)
2469                                                 {
2470                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2471                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2472                                                 }
2473                                                 else if(r > 0)
2474                                                 {
2475                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2476                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2477                                                 }
2478                                         }
2479                                 }
2480                                 self.version_nagtime = 0;
2481                         }
2482
2483         // GOD MODE info
2484         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2485         {
2486                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2487                 self.max_armorvalue = 0;
2488         }
2489
2490 #ifdef TETRIS
2491         if (TetrisPreFrame())
2492                 return;
2493 #endif
2494
2495         MUTATOR_CALLHOOK(PlayerPreThink);
2496
2497         if(self.classname == "player") {
2498 //              if(self.netname == "Wazat")
2499 //                      bprint(self.classname, "\n");
2500
2501                 CheckRules_Player();
2502
2503                 PrintWelcomeMessage(self);
2504
2505                 if (intermission_running)
2506                 {
2507                         IntermissionThink ();   // otherwise a button could be missed between
2508                         return;                                 // the think tics
2509                 }
2510
2511                 if(self.teleport_time)
2512                 if(time > self.teleport_time)
2513                 {
2514                         self.teleport_time = 0;
2515                         self.effects = self.effects - (self.effects & EF_NODRAW);
2516                 }
2517
2518                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2519                         UpdateSelectedPlayer();
2520
2521                 //don't allow the player to turn around while game is paused!
2522                 if(timeoutStatus == 2) {
2523                         self.v_angle = self.lastV_angle;
2524                         self.angles = self.lastV_angle;
2525                         self.fixangle = TRUE;
2526                 }
2527
2528                 if(frametime)
2529                 {
2530                         if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
2531                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2532                         player_powerups();
2533                 }
2534
2535                 if (self.deadflag != DEAD_NO)
2536                 {
2537                         float button_pressed, force_respawn;
2538                         if(self.personal && g_race_qualifying)
2539                         {
2540                                 if(time > self.death_time)
2541                                 {
2542                                         self.death_time = time + 1; // only retry once a second
2543                                         respawn();
2544                                         self.impulse = 141;
2545                                 }
2546                         }
2547                         else
2548                         {
2549                                 if(frametime)
2550                                         player_anim();
2551                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2552                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2553                                 if (self.deadflag == DEAD_DYING)
2554                                 {
2555                                         if(force_respawn)
2556                                                 self.deadflag = DEAD_RESPAWNING;
2557                                         else if(!button_pressed)
2558                                                 self.deadflag = DEAD_DEAD;
2559                                 }
2560                                 else if (self.deadflag == DEAD_DEAD)
2561                                 {
2562                                         if(button_pressed)
2563                                                 self.deadflag = DEAD_RESPAWNABLE;
2564                                 }
2565                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2566                                 {
2567                                         if(!button_pressed)
2568                                                 self.deadflag = DEAD_RESPAWNING;
2569                                 }
2570                                 else if (self.deadflag == DEAD_RESPAWNING)
2571                                 {
2572                                         if(time > self.death_time)
2573                                         {
2574                                                 self.death_time = time + 1; // only retry once a second
2575                                                 respawn();
2576                                         }
2577                                 }
2578                                 ShowRespawnCountdown();
2579                         }
2580                         return;
2581                 }
2582
2583                 if(g_touchexplode)
2584                 if(time > self.touchexplode_time)
2585                 if(self.classname == "player")
2586                 if(self.deadflag == DEAD_NO)
2587                 if not(IS_INDEPENDENT_PLAYER(self))
2588                 FOR_EACH_PLAYER(other) if(self != other)
2589                 {
2590                         if(time > other.touchexplode_time)
2591                         if(other.classname == "player")
2592                         if(other.deadflag == DEAD_NO)
2593                         if not(IS_INDEPENDENT_PLAYER(other))
2594                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2595                         {
2596                                 PlayerTouchExplode(self, other);
2597                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2598                         }
2599                 }
2600
2601                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2602                 {
2603                         vector dist;
2604
2605                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2606                         dist = self.prevorigin - self.origin;
2607                         dist_z = 0;
2608                         self.lms_traveled_distance += fabs(vlen(dist));
2609
2610                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2611                         {
2612                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2613                                 self.lms_traveled_distance = 0;
2614                         }
2615
2616                         if(time > self.lms_nextcheck)
2617                         {
2618                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2619                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2620                                 {
2621                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2622                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2623                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2624                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2625                                 }
2626                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2627                                 self.lms_traveled_distance = 0;
2628                         }
2629                 }
2630
2631                 self.prevorigin = self.origin;
2632
2633                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2634                 {
2635                         if (!self.crouch)
2636                         {
2637                                 self.crouch = TRUE;
2638                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2639                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2640                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2641                         }
2642                 }
2643                 else
2644                 {
2645                         if (self.crouch)
2646                         {
2647                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2648                                 if (!trace_startsolid)
2649                                 {
2650                                         self.crouch = FALSE;
2651                                         self.view_ofs = PL_VIEW_OFS;
2652                                         setsize (self, PL_MIN, PL_MAX);
2653                                 }
2654                         }
2655                 }
2656
2657                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2658                 {
2659                         if(self.bloodloss_timer < time)
2660                         {
2661                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2662                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2663                         }
2664                 }
2665
2666                 FixPlayermodel();
2667
2668                 GrapplingHookFrame();
2669
2670                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2671                 //if(frametime)
2672                 {
2673                         self.items &~= self.items_added;
2674
2675                         W_WeaponFrame();
2676
2677                         self.items_added = 0;
2678                         if(self.items & IT_JETPACK)
2679                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2680                                         self.items_added |= IT_FUEL;
2681
2682                         self.items |= self.items_added;
2683                 }
2684
2685                 player_regen();
2686                 if(frametime)
2687                         player_anim();
2688
2689                 if (g_minstagib)
2690                         minstagib_ammocheck();
2691
2692                 ctf_setstatus();
2693                 nexball_setstatus();
2694
2695                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2696
2697                 //self.angles_y=self.v_angle_y + 90;   // temp
2698         } else if(gameover) {
2699                 if (intermission_running)
2700                         IntermissionThink ();   // otherwise a button could be missed between
2701                 return;
2702         } else if(self.classname == "observer") {
2703                 ObserverThink();
2704         } else if(self.classname == "spectator") {
2705                 SpectatorThink();
2706         }
2707
2708         if(!zoomstate_set)
2709                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2710
2711         float oldspectatee_status;
2712         oldspectatee_status = self.spectatee_status;
2713         if(self.classname == "spectator")
2714                 self.spectatee_status = num_for_edict(self.enemy);
2715         else if(self.classname == "observer")
2716                 self.spectatee_status = num_for_edict(self);
2717         else
2718                 self.spectatee_status = 0;
2719         if(self.spectatee_status != oldspectatee_status)
2720         {
2721                 ClientData_Touch(self);
2722                 if(g_race || g_cts)
2723                         race_InitSpectator();
2724         }
2725
2726         if(self.teamkill_soundtime)
2727         if(time > self.teamkill_soundtime)
2728         {
2729                 self.teamkill_soundtime = 0;
2730
2731                 entity oldpusher, oldself;
2732
2733                 oldself = self; self = self.teamkill_soundsource;
2734                 oldpusher = self.pusher; self.pusher = oldself;
2735
2736                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2737
2738                 self.pusher = oldpusher;
2739                 self = oldself;
2740         }
2741
2742         if(self.taunt_soundtime)
2743         if(time > self.taunt_soundtime)
2744         {
2745                 self.taunt_soundtime = 0;
2746                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2747         }
2748
2749         target_voicescript_next(self);
2750 }
2751
2752 float isInvisibleString(string s)
2753 {
2754         float i, n, c;
2755         s = strdecolorize(s);
2756         for((i = 0), (n = strlen(s)); i < n; ++i)
2757         {
2758                 c = str2chr(s, i);
2759                 switch(c)
2760                 {
2761                         case 0:
2762                         case 32:
2763                         case 160:
2764                                 break;
2765                         default:
2766                                 return FALSE;
2767                 }
2768         }
2769         return TRUE;
2770 }
2771
2772 /*
2773 =============
2774 PlayerPostThink
2775
2776 Called every frame for each client after the physics are run
2777 =============
2778 */
2779 .float idlekick_lasttimeleft;
2780 void PlayerPostThink (void)
2781 {
2782         // Savage: Check for nameless players
2783         if (isInvisibleString(self.netname)) {
2784                 self.netname = "Player";
2785                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2786         }
2787
2788         // send the clients accuracy stats to the client
2789         if(self.stat_count > 0)
2790         if(frametime)
2791         {
2792                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2793                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2794                 self.stat_count -= 1;
2795         }
2796
2797 #ifdef UID
2798         if(self.uid_kicktime)
2799         if(time > self.uid_kicktime)
2800         {
2801                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2802                 dropclient(self);
2803                 return;
2804         }
2805 #endif
2806
2807         if(sv_maxidle && frametime)
2808         {
2809                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2810                 float timeleft;
2811                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2812                 if(timeleft <= 0)
2813                 {
2814                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2815                         AnnounceTo(self, "terminated");
2816                         dropclient(self);
2817                         return;
2818                 }
2819                 else if(timeleft <= 10)
2820                 {
2821                         if(timeleft != self.idlekick_lasttimeleft)
2822                         {
2823                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2824                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2825                         }
2826                 }
2827                 else
2828                 {
2829                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2830                 }
2831                 self.idlekick_lasttimeleft = timeleft;
2832         }
2833
2834 #ifdef TETRIS
2835         if(self.impulse == 100)
2836                 ImpulseCommands();
2837         if (TetrisPostFrame())
2838                 return;
2839 #endif
2840
2841         CheatFrame();
2842
2843         if(self.classname == "player") {
2844                 CheckRules_Player();
2845                 UpdateChatBubble();
2846                 UpdateTeamBubble();
2847                 if (self.impulse)
2848                         ImpulseCommands();
2849                 if (intermission_running)
2850                         return;         // intermission or finale
2851
2852                 GetPressedKeys();
2853         } else if (self.classname == "observer") {
2854                 //do nothing
2855         } else if (self.classname == "spectator") {
2856                 //do nothing
2857         }
2858
2859         /*
2860         float i;
2861         for(i = 0; i < 1000; ++i)
2862         {
2863                 vector end;
2864                 end = self.origin + '0 0 1024' + 512 * randomvec();
2865                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2866                 if(trace_fraction < 1)
2867                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2868                 {
2869                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2870                         break;
2871                 }
2872         }
2873         */
2874
2875         Arena_Warmup();
2876
2877         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2878
2879         if(self.waypointsprite_attachedforcarrier)
2880                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2881
2882         playerdemo_write();
2883
2884         /*
2885         if(g_race)
2886                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2887         */
2888 }