qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21
  22 #include "bot/bot.qh"
  23 #include "bot/navigation.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/triggers/teleporters.qh"
  28
  29 #include "weapons/hitplot.qh"
  30 #include "weapons/weaponsystem.qh"
  31
  32 #include "../common/net_notice.qh"
  33 #include "../common/physics.qh"
  34
  35 #include "../common/items/all.qc"
  36
  37 #include "../common/mutators/mutator/waypoints/all.qh"
  38
  39 #include "../common/triggers/subs.qh"
  40 #include "../common/triggers/triggers.qh"
  41 #include "../common/triggers/trigger/secret.qh"
  42
  43 #include "../common/minigames/sv_minigames.qh"
  44
  45 #include "../common/items/inventory.qh"
  46
  47 #include "../common/monsters/sv_monsters.qh"
  48
  49 #include "../lib/warpzone/server.qh"
  50
  51
  52 void send_CSQC_teamnagger() {
  53         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  54 }
  55
  56 bool ClientData_Send(entity this, entity to, int sf)
  57 {
  58         if(to != self.owner)
  59         {
  60                 error("wtf");
  61                 return false;
  62         }
  63
  64         entity e;
  65
  66         e = to;
  67         if(IS_SPEC(to))
  68                 e = to.enemy;
  69
  70         sf = 0;
  71
  72         if(e.race_completed)
  73                 sf |= 1; // forced scoreboard
  74         if(to.spectatee_status)
  75                 sf |= 2; // spectator ent number follows
  76         if(e.zoomstate)
  77                 sf |= 4; // zoomed
  78         if(e.porto_v_angle_held)
  79                 sf |= 8; // angles held
  80
  81         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  82         WriteByte(MSG_ENTITY, sf);
  83
  84         if(sf & 2)
  85                 WriteByte(MSG_ENTITY, to.spectatee_status);
  86
  87         if(sf & 8)
  88         {
  89                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  90                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  91         }
  92
  93         return true;
  94 }
  95
  96 void ClientData_Attach()
  97 {SELFPARAM();
  98         Net_LinkEntity(this.clientdata = new(clientdata), false, 0, ClientData_Send);
  99         make_pure(this.clientdata);
 100         self.clientdata.drawonlytoclient = this;
 101         self.clientdata.owner = this;
 102 }
 103
 104 void ClientData_Detach()
 105 {SELFPARAM();
 106         remove(self.clientdata);
 107         self.clientdata = world;
 108 }
 109
 110 void ClientData_Touch(entity e)
 111 {
 112         e.clientdata.SendFlags = 1;
 113
 114         // make it spectatable
 115         entity e2;
 116         FOR_EACH_REALCLIENT(e2)
 117         {
 118                 if(e2 != e)
 119                         if(IS_SPEC(e2))
 120                                 if(e2.enemy == e)
 121                                         e2.clientdata.SendFlags = 1;
 122         }
 123 }
 124
 125 .string netname_previous;
 126
 127 void SetSpectatee(entity player, entity spectatee);
 128
 129
 130 /*
 131 =============
 132 CheckPlayerModel
 133
 134 Checks if the argument string can be a valid playermodel.
 135 Returns a valid one in doubt.
 136 =============
 137 */
 138 string FallbackPlayerModel;
 139 string CheckPlayerModel(string plyermodel) {
 140         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 141         {
 142                 // note: we cannot summon Don Strunzone here, some player may
 143                 // still have the model string set. In case anyone manages how
 144                 // to change a cvar default, we'll have a small leak here.
 145                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 146         }
 147         // only in right path
 148         if( substring(plyermodel,0,14) != "models/player/")
 149                 return FallbackPlayerModel;
 150         // only good file extensions
 151         if(substring(plyermodel,-4,4) != ".zym")
 152         if(substring(plyermodel,-4,4) != ".dpm")
 153         if(substring(plyermodel,-4,4) != ".iqm")
 154         if(substring(plyermodel,-4,4) != ".md3")
 155         if(substring(plyermodel,-4,4) != ".psk")
 156                 return FallbackPlayerModel;
 157         // forbid the LOD models
 158         if(substring(plyermodel, -9,5) == "_lod1")
 159                 return FallbackPlayerModel;
 160         if(substring(plyermodel, -9,5) == "_lod2")
 161                 return FallbackPlayerModel;
 162         if(plyermodel != strtolower(plyermodel))
 163                 return FallbackPlayerModel;
 164         // also, restrict to server models
 165         if(autocvar_sv_servermodelsonly)
 166         {
 167                 if(!fexists(plyermodel))
 168                         return FallbackPlayerModel;
 169         }
 170         return plyermodel;
 171 }
 172
 173 void setplayermodel(entity e, string modelname)
 174 {
 175         precache_model(modelname);
 176         _setmodel(e, modelname);
 177         player_setupanimsformodel();
 178 }
 179
 180 /*
 181 =============
 182 PutObserverInServer
 183
 184 putting a client as observer in the server
 185 =============
 186 */
 187 void FixPlayermodel(entity player);
 188 void PutObserverInServer()
 189 {SELFPARAM();
 190         entity  spot;
 191     self.hud = HUD_NORMAL;
 192
 193         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 194
 195         spot = SelectSpawnPoint (true);
 196         if(!spot)
 197                 error("No spawnpoints for observers?!?\n");
 198         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 199
 200         if(IS_REAL_CLIENT(self))
 201         {
 202                 msg_entity = self;
 203                 WriteByte(MSG_ONE, SVC_SETVIEW);
 204                 WriteEntity(MSG_ONE, self);
 205         }
 206
 207         self.frags = FRAGS_SPECTATOR;
 208         self.bot_attack = false;
 209
 210         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 211
 212         Portal_ClearAll(self);
 213
 214         Unfreeze(self);
 215
 216         if(self.alivetime)
 217         {
 218                 if(!warmup_stage)
 219                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 220                 self.alivetime = 0;
 221         }
 222
 223         if(self.vehicle)
 224                 vehicles_exit(VHEF_RELEASE);
 225
 226         WaypointSprite_PlayerDead();
 227
 228         if(!mutator_returnvalue)  // mutator prevents resetting teams
 229                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 230
 231         if(self.killcount != FRAGS_SPECTATOR)
 232         {
 233                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 234                 if(!intermission_running)
 235                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 236                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 237
 238                 if(self.just_joined == false) {
 239                         LogTeamchange(self.playerid, -1, 4);
 240                 } else
 241                         self.just_joined = false;
 242         }
 243
 244         PlayerScore_Clear(self); // clear scores when needed
 245
 246         accuracy_resend(self);
 247
 248         self.spectatortime = time;
 249
 250         self.classname = STR_OBSERVER;
 251         self.iscreature = false;
 252         self.teleportable = TELEPORT_SIMPLE;
 253         self.damagedbycontents = false;
 254         self.health = FRAGS_SPECTATOR;
 255         self.takedamage = DAMAGE_NO;
 256         self.solid = SOLID_NOT;
 257         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 258         self.flags = FL_CLIENT | FL_NOTARGET;
 259         self.armorvalue = 666;
 260         self.effects = 0;
 261         self.armorvalue = autocvar_g_balance_armor_start;
 262         self.pauserotarmor_finished = 0;
 263         self.pauserothealth_finished = 0;
 264         self.pauseregen_finished = 0;
 265         self.damageforcescale = 0;
 266         self.death_time = 0;
 267         self.respawn_flags = 0;
 268         self.respawn_time = 0;
 269         self.stat_respawn_time = 0;
 270         self.alpha = 0;
 271         self.scale = 0;
 272         self.fade_time = 0;
 273         self.pain_frame = 0;
 274         self.pain_finished = 0;
 275         self.strength_finished = 0;
 276         self.invincible_finished = 0;
 277         self.superweapons_finished = 0;
 278         self.pushltime = 0;
 279         self.istypefrag = 0;
 280         self.think = func_null;
 281         self.nextthink = 0;
 282         self.hook_time = 0;
 283         self.deadflag = DEAD_NO;
 284         self.angles = spot.angles;
 285         self.angles_z = 0;
 286         self.fixangle = true;
 287         self.crouch = false;
 288         self.revival_time = 0;
 289
 290         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 291         self.prevorigin = self.origin;
 292         self.items = 0;
 293         self.weapons = '0 0 0';
 294         self.model = "";
 295         FixPlayermodel(self);
 296         setmodel(self, MDL_Null);
 297         self.drawonlytoclient = self;
 298
 299         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 300         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 301
 302         self.weapon = 0;
 303         self.weaponname = "";
 304         self.switchingweapon = 0;
 305         self.weaponmodel = "";
 306         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 307         {
 308                 self.weaponentities[slot] = NULL;
 309         }
 310         self.exteriorweaponentity = world;
 311         self.killcount = FRAGS_SPECTATOR;
 312         self.velocity = '0 0 0';
 313         self.avelocity = '0 0 0';
 314         self.punchangle = '0 0 0';
 315         self.punchvector = '0 0 0';
 316         self.oldvelocity = self.velocity;
 317         self.fire_endtime = -1;
 318         self.event_damage = func_null;
 319 }
 320
 321 int player_getspecies(entity this)
 322 {
 323         get_model_parameters(this.model, this.skin);
 324         int s = get_model_parameters_species;
 325         get_model_parameters(string_null, 0);
 326         if (s < 0) return SPECIES_HUMAN;
 327         return s;
 328 }
 329
 330 .float model_randomizer;
 331 void FixPlayermodel(entity player)
 332 {
 333         string defaultmodel = "";
 334         int defaultskin = 0;
 335         if(autocvar_sv_defaultcharacter)
 336         {
 337                 if(teamplay)
 338                 {
 339                         string s = Static_Team_ColorName_Lower(player.team);
 340                         if (s != "neutral")
 341                         {
 342                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 343                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 344                         }
 345                 }
 346
 347                 if(defaultmodel == "")
 348                 {
 349                         defaultmodel = autocvar_sv_defaultplayermodel;
 350                         defaultskin = autocvar_sv_defaultplayerskin;
 351                 }
 352
 353                 int n = tokenize_console(defaultmodel);
 354                 if(n > 0)
 355                 {
 356                         defaultmodel = argv(floor(n * player.model_randomizer));
 357                         // However, do NOT randomize if the player-selected model is in the list.
 358                         for (int i = 0; i < n; ++i)
 359                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 360                                         defaultmodel = argv(i);
 361                 }
 362
 363                 int i = strstrofs(defaultmodel, ":", 0);
 364                 if(i >= 0)
 365                 {
 366                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 367                         defaultmodel = substring(defaultmodel, 0, i);
 368                 }
 369         }
 370         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 371         defaultmodel = ret_string;
 372         defaultskin = ret_int;
 373
 374         bool chmdl = false;
 375         int oldskin;
 376         if(defaultmodel != "")
 377         {
 378                 if (defaultmodel != player.model)
 379                 {
 380                         vector m1 = player.mins;
 381                         vector m2 = player.maxs;
 382                         setplayermodel (player, defaultmodel);
 383                         setsize (player, m1, m2);
 384                         chmdl = true;
 385                 }
 386
 387                 oldskin = player.skin;
 388                 player.skin = defaultskin;
 389         } else {
 390                 if (player.playermodel != player.model || player.playermodel == "")
 391                 {
 392                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 393                         vector m1 = player.mins;
 394                         vector m2 = player.maxs;
 395                         setplayermodel (player, player.playermodel);
 396                         setsize (player, m1, m2);
 397                         chmdl = true;
 398                 }
 399
 400                 oldskin = player.skin;
 401                 player.skin = stof(player.playerskin);
 402         }
 403
 404         if(chmdl || oldskin != player.skin) // model or skin has changed
 405         {
 406                 player.species = player_getspecies(player); // update species
 407         }
 408
 409         if(!teamplay)
 410                 if(strlen(autocvar_sv_defaultplayercolors))
 411                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 412                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 413 }
 414
 415
 416 /** Called when a client spawns in the server */
 417 void PutClientInServer()
 418 {
 419         SELFPARAM();
 420         if (IS_BOT_CLIENT(this)) {
 421                 this.classname = STR_PLAYER;
 422         } else if (IS_REAL_CLIENT(this)) {
 423                 msg_entity = this;
 424                 WriteByte(MSG_ONE, SVC_SETVIEW);
 425                 WriteEntity(MSG_ONE, this);
 426         }
 427         if (gameover) {
 428                 this.classname = STR_OBSERVER;
 429         }
 430
 431         SetSpectatee(this, NULL);
 432
 433         // reset player keys
 434         this.itemkeys = 0;
 435
 436         MUTATOR_CALLHOOK(PutClientInServer, this);
 437
 438         if (IS_OBSERVER(this)) {
 439                 PutObserverInServer();
 440         } else if (IS_PLAYER(this)) {
 441                 accuracy_resend(this);
 442
 443                 if (this.team < 0)
 444                         JoinBestTeam(this, false, true);
 445
 446                 entity spot = SelectSpawnPoint(false);
 447                 if (!spot) {
 448                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 449                         return; // spawn failed
 450                 }
 451
 452                 this.classname = STR_PLAYER;
 453                 this.wasplayer = true;
 454                 this.iscreature = true;
 455                 this.teleportable = TELEPORT_NORMAL;
 456                 this.damagedbycontents = true;
 457                 this.movetype = MOVETYPE_WALK;
 458                 this.solid = SOLID_SLIDEBOX;
 459                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 460                 if (autocvar_g_playerclip_collisions)
 461                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 462                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 463                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 464                 this.frags = FRAGS_PLAYER;
 465                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 466                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 467                 if (autocvar__notarget)
 468                         this.flags |= FL_NOTARGET;
 469                 this.takedamage = DAMAGE_AIM;
 470                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 471                 this.dmg = 2; // WTF
 472
 473                 if (warmup_stage) {
 474                         this.ammo_shells = warmup_start_ammo_shells;
 475                         this.ammo_nails = warmup_start_ammo_nails;
 476                         this.ammo_rockets = warmup_start_ammo_rockets;
 477                         this.ammo_cells = warmup_start_ammo_cells;
 478                         this.ammo_plasma = warmup_start_ammo_plasma;
 479                         this.ammo_fuel = warmup_start_ammo_fuel;
 480                         this.health = warmup_start_health;
 481                         this.armorvalue = warmup_start_armorvalue;
 482                         this.weapons = WARMUP_START_WEAPONS;
 483                 } else {
 484                         this.ammo_shells = start_ammo_shells;
 485                         this.ammo_nails = start_ammo_nails;
 486                         this.ammo_rockets = start_ammo_rockets;
 487                         this.ammo_cells = start_ammo_cells;
 488                         this.ammo_plasma = start_ammo_plasma;
 489                         this.ammo_fuel = start_ammo_fuel;
 490                         this.health = start_health;
 491                         this.armorvalue = start_armorvalue;
 492                         this.weapons = start_weapons;
 493                 }
 494
 495                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 496
 497                 this.items = start_items;
 498
 499                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 500                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 501                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 502                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 503                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 504                 // extend the pause of rotting if client was reset at the beginning of the countdown
 505                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 506                         float f = game_starttime - time;
 507                         this.spawnshieldtime += f;
 508                         this.pauserotarmor_finished += f;
 509                         this.pauserothealth_finished += f;
 510                         this.pauseregen_finished += f;
 511                 }
 512                 this.damageforcescale = 2;
 513                 this.death_time = 0;
 514                 this.respawn_flags = 0;
 515                 this.respawn_time = 0;
 516                 this.stat_respawn_time = 0;
 517                 this.scale = autocvar_sv_player_scale;
 518                 this.fade_time = 0;
 519                 this.pain_frame = 0;
 520                 this.pain_finished = 0;
 521                 this.pushltime = 0;
 522                 this.think = func_null; // players have no think function
 523                 this.nextthink = 0;
 524                 this.dmg_team = 0;
 525                 this.ballistics_density = autocvar_g_ballistics_density_player;
 526
 527                 this.deadflag = DEAD_NO;
 528
 529                 this.angles = spot.angles;
 530                 this.angles_z = 0; // never spawn tilted even if the spot says to
 531                 if (IS_BOT_CLIENT(this))
 532                         this.v_angle = this.angles;
 533                 this.fixangle = true; // turn this way immediately
 534                 this.oldvelocity = this.velocity = '0 0 0';
 535                 this.avelocity = '0 0 0';
 536                 this.punchangle = '0 0 0';
 537                 this.punchvector = '0 0 0';
 538
 539                 this.strength_finished = 0;
 540                 this.invincible_finished = 0;
 541                 this.fire_endtime = -1;
 542                 this.revival_time = 0;
 543                 this.air_finished = time + 12;
 544
 545                 entity spawnevent = new(spawnevent);
 546                 make_pure(spawnevent);
 547                 spawnevent.owner = this;
 548                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 549
 550                 // Cut off any still running player sounds.
 551                 stopsound(this, CH_PLAYER_SINGLE);
 552
 553                 this.model = "";
 554                 FixPlayermodel(this);
 555                 this.drawonlytoclient = NULL;
 556
 557                 this.crouch = false;
 558                 this.view_ofs = PL_VIEW_OFS;
 559                 setsize(this, PL_MIN, PL_MAX);
 560                 this.spawnorigin = spot.origin;
 561                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 562                 // don't reset back to last position, even if new position is stuck in solid
 563                 this.oldorigin = this.origin;
 564                 this.prevorigin = this.origin;
 565                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 566         this.hud = HUD_NORMAL;
 567
 568                 this.event_damage = PlayerDamage;
 569
 570                 this.bot_attack = true;
 571                 this.monster_attack = true;
 572
 573                 this.BUTTON_ATCK = this.BUTTON_JUMP = this.BUTTON_ATCK2 = false;
 574
 575                 if (this.killcount == FRAGS_SPECTATOR) {
 576                         PlayerScore_Clear(this);
 577                         this.killcount = 0;
 578                 }
 579
 580                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 581                 {
 582                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 583                 }
 584                 this.alpha = default_player_alpha;
 585                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 586                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 587
 588                 this.speedrunning = false;
 589
 590                 target_voicescript_clear(this);
 591
 592                 // reset fields the weapons may use
 593                 FOREACH(Weapons, true, LAMBDA(
 594                         it.wr_resetplayer(it);
 595                         // reload all reloadable weapons
 596                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 597                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 598                         }
 599                 ));
 600
 601                 {
 602                         string s = spot.target;
 603                         spot.target = string_null;
 604                         WITH(entity, activator, this, LAMBDA(
 605                                 WITH(entity, self, spot, SUB_UseTargets())
 606                         ));
 607                         spot.target = s;
 608                 }
 609
 610                 Unfreeze(this);
 611
 612                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 613
 614                 if (autocvar_spawn_debug)
 615                 {
 616                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 617                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 618                 }
 619
 620                 this.switchweapon = w_getbestweapon(this);
 621                 this.cnt = -1; // W_LastWeapon will not complain
 622                 this.weapon = 0;
 623                 this.weaponname = "";
 624                 this.switchingweapon = 0;
 625
 626                 if (!warmup_stage && !this.alivetime)
 627                         this.alivetime = time;
 628
 629                 antilag_clear(this);
 630         }
 631 }
 632
 633 .float ebouncefactor, ebouncestop; // electro's values
 634 // TODO do we need all these fields, or should we stop autodetecting runtime
 635 // changes and just have a console command to update this?
 636 bool ClientInit_SendEntity(entity this, entity to, int sf)
 637 {
 638         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 639         return = true;
 640         msg_entity = to;
 641         Registry_send_all();
 642         int channel = MSG_ONE;
 643         WriteHeader(channel, ENT_CLIENT_INIT);
 644         WriteByte(channel, g_nexball_meter_period * 32);
 645         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 646         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 647         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 648         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 649         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 650         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 651         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 652         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 653
 654         if(sv_foginterval && world.fog != "")
 655                 WriteString(channel, world.fog);
 656         else
 657                 WriteString(channel, "");
 658         WriteByte(channel, self.count * 255.0); // g_balance_armor_blockpercent
 659         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 660         WriteCoord(channel, autocvar_g_trueaim_minrange);
 661
 662         MUTATOR_CALLHOOK(Ent_Init);
 663 }
 664
 665 void ClientInit_CheckUpdate()
 666 {SELFPARAM();
 667         self.nextthink = time;
 668         if(self.count != autocvar_g_balance_armor_blockpercent)
 669         {
 670                 self.count = autocvar_g_balance_armor_blockpercent;
 671                 self.SendFlags |= 1;
 672         }
 673 }
 674
 675 void ClientInit_Spawn()
 676 {SELFPARAM();
 677
 678         entity e = new(clientinit);
 679         make_pure(e);
 680         e.think = ClientInit_CheckUpdate;
 681         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 682
 683         WITH(entity, self, e, ClientInit_CheckUpdate());
 684 }
 685
 686 /*
 687 =============
 688 SetNewParms
 689 =============
 690 */
 691 void SetNewParms ()
 692 {
 693         // initialize parms for a new player
 694         parm1 = -(86400 * 366);
 695
 696         MUTATOR_CALLHOOK(SetNewParms);
 697 }
 698
 699 /*
 700 =============
 701 SetChangeParms
 702 =============
 703 */
 704 void SetChangeParms ()
 705 {SELFPARAM();
 706         // save parms for level change
 707         parm1 = self.parm_idlesince - time;
 708
 709         MUTATOR_CALLHOOK(SetChangeParms);
 710 }
 711
 712 /*
 713 =============
 714 DecodeLevelParms
 715 =============
 716 */
 717 void DecodeLevelParms ()
 718 {SELFPARAM();
 719         // load parms
 720         self.parm_idlesince = parm1;
 721         if(self.parm_idlesince == -(86400 * 366))
 722                 self.parm_idlesince = time;
 723
 724         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 725         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 726
 727         MUTATOR_CALLHOOK(DecodeLevelParms);
 728 }
 729
 730 /*
 731 =============
 732 ClientKill
 733
 734 Called when a client types 'kill' in the console
 735 =============
 736 */
 737
 738 .float clientkill_nexttime;
 739 void ClientKill_Now_TeamChange()
 740 {SELFPARAM();
 741         if(self.killindicator_teamchange == -1)
 742         {
 743                 JoinBestTeam( self, false, true );
 744         }
 745         else if(self.killindicator_teamchange == -2)
 746         {
 747                 if(blockSpectators)
 748                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 749                 PutObserverInServer();
 750         }
 751         else
 752                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 753         self.killindicator_teamchange = 0;
 754 }
 755
 756 void ClientKill_Now()
 757 {SELFPARAM();
 758         if(self.vehicle)
 759         {
 760             vehicles_exit(VHEF_RELEASE);
 761             if(!self.killindicator_teamchange)
 762             {
 763             self.vehicle_health = -1;
 764             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 765             }
 766         }
 767
 768         if(self.killindicator && !wasfreed(self.killindicator))
 769                 remove(self.killindicator);
 770
 771         self.killindicator = world;
 772
 773         if(self.killindicator_teamchange)
 774                 ClientKill_Now_TeamChange();
 775
 776         if(IS_PLAYER(self))
 777                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 778
 779         // now I am sure the player IS dead
 780 }
 781 void KillIndicator_Think()
 782 {SELFPARAM();
 783         if (gameover)
 784         {
 785                 self.owner.killindicator = world;
 786                 remove(self);
 787                 return;
 788         }
 789
 790         if (self.owner.alpha < 0 && !self.owner.vehicle)
 791         {
 792                 self.owner.killindicator = world;
 793                 remove(self);
 794                 return;
 795         }
 796
 797         if(self.cnt <= 0)
 798         {
 799                 WITH(entity, self, self.owner, ClientKill_Now());
 800                 return;
 801         }
 802     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 803     {
 804         self.nextthink = time + 1;
 805         self.cnt -= 1;
 806     }
 807         else
 808         {
 809                 if(self.cnt <= 10)
 810                         setmodel(self, MDL_NUM(self.cnt));
 811                 if(IS_REAL_CLIENT(self.owner))
 812                 {
 813                         if(self.cnt <= 10)
 814                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 815                 }
 816                 self.nextthink = time + 1;
 817                 self.cnt -= 1;
 818         }
 819 }
 820
 821 float clientkilltime;
 822 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 823 {SELFPARAM();
 824         float killtime;
 825         float starttime;
 826         entity e;
 827
 828         if (gameover)
 829                 return;
 830
 831         killtime = autocvar_g_balance_kill_delay;
 832
 833         if(g_race_qualifying || g_cts)
 834                 killtime = 0;
 835
 836     if(MUTATOR_CALLHOOK(ClientKill, self, killtime))
 837         return;
 838
 839         self.killindicator_teamchange = targetteam;
 840
 841     if(!self.killindicator)
 842         {
 843                 if(self.deadflag == DEAD_NO)
 844                 {
 845                         killtime = max(killtime, self.clientkill_nexttime - time);
 846                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 847                 }
 848
 849                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 850                 {
 851                         ClientKill_Now();
 852                 }
 853                 else
 854                 {
 855                         starttime = max(time, clientkilltime);
 856
 857                         self.killindicator = spawn();
 858                         self.killindicator.owner = self;
 859                         self.killindicator.scale = 0.5;
 860                         setattachment(self.killindicator, self, "");
 861                         setorigin(self.killindicator, '0 0 52');
 862                         self.killindicator.think = KillIndicator_Think;
 863                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 864                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 865                         self.killindicator.cnt = ceil(killtime);
 866                         self.killindicator.count = bound(0, ceil(killtime), 10);
 867                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 868
 869                         for(e = world; (e = find(e, classname, "body")) != world; )
 870                         {
 871                                 if(e.enemy != self)
 872                                         continue;
 873                                 e.killindicator = spawn();
 874                                 e.killindicator.owner = e;
 875                                 e.killindicator.scale = 0.5;
 876                                 setattachment(e.killindicator, e, "");
 877                                 setorigin(e.killindicator, '0 0 52');
 878                                 e.killindicator.think = KillIndicator_Think;
 879                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 880                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 881                                 e.killindicator.cnt = ceil(killtime);
 882                         }
 883                         self.lip = 0;
 884                 }
 885         }
 886         if(self.killindicator)
 887         {
 888                 if(targetteam == 0) // just die
 889                 {
 890                         self.killindicator.colormod = '0 0 0';
 891                         if(IS_REAL_CLIENT(self))
 892                         if(self.killindicator.cnt > 0)
 893                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 894                 }
 895                 else if(targetteam == -1) // auto
 896                 {
 897                         self.killindicator.colormod = '0 1 0';
 898                         if(IS_REAL_CLIENT(self))
 899                         if(self.killindicator.cnt > 0)
 900                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 901                 }
 902                 else if(targetteam == -2) // spectate
 903                 {
 904                         self.killindicator.colormod = '0.5 0.5 0.5';
 905                         if(IS_REAL_CLIENT(self))
 906                         if(self.killindicator.cnt > 0)
 907                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 908                 }
 909                 else
 910                 {
 911                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 912                         if(IS_REAL_CLIENT(self))
 913                         if(self.killindicator.cnt > 0)
 914                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 915                 }
 916         }
 917
 918 }
 919
 920 void ClientKill ()
 921 {SELFPARAM();
 922         if(gameover) return;
 923         if(self.player_blocked) return;
 924         if(self.frozen) return;
 925
 926         ClientKill_TeamChange(0);
 927 }
 928
 929 void FixClientCvars(entity e)
 930 {
 931         // send prediction settings to the client
 932         stuffcmd(e, "\nin_bindmap 0 0\n");
 933         if(autocvar_g_antilag == 3) // client side hitscan
 934                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 935         if(autocvar_sv_gentle)
 936                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 937
 938         MUTATOR_CALLHOOK(FixClientCvars, e);
 939 }
 940
 941 float PlayerInIDList(entity p, string idlist)
 942 {
 943         float n, i;
 944         string s;
 945
 946         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 947         if (!p.crypto_idfp)
 948                 return 0;
 949
 950         // this function allows abbreviated player IDs too!
 951         n = tokenize_console(idlist);
 952         for(i = 0; i < n; ++i)
 953         {
 954                 s = argv(i);
 955                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 956                         return 1;
 957         }
 958
 959         return 0;
 960 }
 961
 962 #ifdef DP_EXT_PRECONNECT
 963 /*
 964 =============
 965 ClientPreConnect
 966
 967 Called once (not at each match start) when a client begins a connection to the server
 968 =============
 969 */
 970 void ClientPreConnect ()
 971 {SELFPARAM();
 972         if(autocvar_sv_eventlog)
 973         {
 974                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 975                         self.playerid,
 976                         num_for_edict(self),
 977                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
 978                 ));
 979         }
 980 }
 981 #endif
 982
 983 /*
 984 =============
 985 ClientConnect
 986
 987 Called when a client connects to the server
 988 =============
 989 */
 990 void DecodeLevelParms ();
 991 void ClientConnect ()
 992 {SELFPARAM();
 993         float t;
 994
 995         if(IS_CLIENT(self))
 996         {
 997                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
 998                 return;
 999         }
1000
1001         if(Ban_MaybeEnforceBanOnce(self))
1002                 return;
1003
1004         DecodeLevelParms();
1005
1006 #ifdef WATERMARK
1007         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1008 #endif
1009
1010         self.classname = "player_joining";
1011
1012         self.flags = FL_CLIENT;
1013         self.version_nagtime = time + 10 + random() * 10;
1014
1015         if(player_count<0)
1016         {
1017                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1018                 player_count = 0;
1019         }
1020
1021         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1022
1023         PlayerScore_Attach(self);
1024         ClientData_Attach();
1025         accuracy_init(self);
1026         Inventory_new(self);
1027
1028         bot_clientconnect();
1029
1030         playerdemo_init();
1031
1032         anticheat_init();
1033
1034         // identify the right forced team
1035         if(autocvar_g_campaign)
1036         {
1037                 if(IS_REAL_CLIENT(self)) // only players, not bots
1038                 {
1039                         switch(autocvar_g_campaign_forceteam)
1040                         {
1041                                 case 1: self.team_forced = NUM_TEAM_1; break;
1042                                 case 2: self.team_forced = NUM_TEAM_2; break;
1043                                 case 3: self.team_forced = NUM_TEAM_3; break;
1044                                 case 4: self.team_forced = NUM_TEAM_4; break;
1045                                 default: self.team_forced = 0;
1046                         }
1047                 }
1048         }
1049         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1050                 self.team_forced = NUM_TEAM_1;
1051         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1052                 self.team_forced = NUM_TEAM_2;
1053         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1054                 self.team_forced = NUM_TEAM_3;
1055         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1056                 self.team_forced = NUM_TEAM_4;
1057         else if(autocvar_g_forced_team_otherwise == "red")
1058                 self.team_forced = NUM_TEAM_1;
1059         else if(autocvar_g_forced_team_otherwise == "blue")
1060                 self.team_forced = NUM_TEAM_2;
1061         else if(autocvar_g_forced_team_otherwise == "yellow")
1062                 self.team_forced = NUM_TEAM_3;
1063         else if(autocvar_g_forced_team_otherwise == "pink")
1064                 self.team_forced = NUM_TEAM_4;
1065         else if(autocvar_g_forced_team_otherwise == "spectate")
1066                 self.team_forced = -1;
1067         else if(autocvar_g_forced_team_otherwise == "spectator")
1068                 self.team_forced = -1;
1069         else
1070                 self.team_forced = 0;
1071
1072         if(!teamplay)
1073                 if(self.team_forced > 0)
1074                         self.team_forced = 0;
1075
1076         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1077
1078         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1079                 self.classname = STR_OBSERVER;
1080         } else {
1081                 if(teamplay)
1082                 {
1083                         if(autocvar_g_balance_teams)
1084                         {
1085                                 self.classname = STR_PLAYER;
1086                                 campaign_bots_may_start = 1;
1087                         }
1088                         else
1089                         {
1090                                 self.classname = STR_OBSERVER; // do it anyway
1091                         }
1092                 }
1093                 else
1094                 {
1095                         self.classname = STR_PLAYER;
1096                         campaign_bots_may_start = 1;
1097                 }
1098         }
1099
1100         self.playerid = (playerid_last = playerid_last + 1);
1101
1102         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1103
1104     if(IS_BOT_CLIENT(self))
1105         PlayerStats_GameReport_AddPlayer(self);
1106
1107         if(autocvar_sv_eventlog)
1108                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1109
1110         LogTeamchange(self.playerid, self.team, 1);
1111
1112         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1113
1114         self.netname_previous = strzone(self.netname);
1115
1116         if(IS_PLAYER(self) && teamplay)
1117                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1118         else
1119                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1120
1121         stuffcmd(self, strcat(clientstuff, "\n"));
1122         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1123
1124         FixClientCvars(self);
1125
1126         // spawnfunc_waypoint sprites
1127         WaypointSprite_InitClient(self);
1128
1129         // Wazat's grappling hook
1130         SetGrappleHookBindings();
1131
1132         // Jetpack binds
1133         stuffcmd(self, "alias +jetpack +button10\n");
1134         stuffcmd(self, "alias -jetpack -button10\n");
1135
1136         // get version info from player
1137         stuffcmd(self, "cmd clientversion $gameversion\n");
1138
1139         // get other cvars from player
1140         GetCvars(0);
1141
1142         // notify about available teams
1143         if(teamplay)
1144         {
1145                 CheckAllowedTeams(self);
1146                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1147                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1148         }
1149         else
1150                 stuffcmd(self, "set _teams_available 0\n");
1151
1152         entcs_attach(self);
1153
1154         bot_relinkplayerlist();
1155
1156         self.spectatortime = time;
1157         if(blockSpectators)
1158         {
1159                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1160         }
1161
1162         self.jointime = time;
1163         self.allowed_timeouts = autocvar_sv_timeout_number;
1164
1165         if(IS_REAL_CLIENT(self))
1166         {
1167                 if(!autocvar_g_campaign)
1168                 {
1169                         self.motd_actived_time = -1;
1170                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1171                 }
1172
1173                 if(g_weaponarena_weapons == WEPSET(TUBA))
1174                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1175         }
1176
1177         if(!sv_foginterval && world.fog != "")
1178                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1179
1180         W_HitPlotOpen(self);
1181
1182         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1183                 send_CSQC_teamnagger();
1184
1185         CheatInitClient();
1186
1187         CSQCMODEL_AUTOINIT(self);
1188
1189         self.model_randomizer = random();
1190
1191         if(IS_REAL_CLIENT(self))
1192                 sv_notice_join(self);
1193
1194         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1195                 WITH(entity, self, e, e.init_for_player(this));
1196         }
1197
1198         MUTATOR_CALLHOOK(ClientConnect, self);
1199 }
1200 /*
1201 =============
1202 ClientDisconnect
1203
1204 Called when a client disconnects from the server
1205 =============
1206 */
1207 .entity chatbubbleentity;
1208 void ReadyCount();
1209 void ClientDisconnect ()
1210 {SELFPARAM();
1211         if(self.vehicle)
1212             vehicles_exit(VHEF_RELEASE);
1213
1214         if (!IS_CLIENT(self))
1215         {
1216                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1217                 return;
1218         }
1219
1220         PlayerStats_GameReport_FinalizePlayer(self);
1221
1222         if ( self.active_minigame )
1223                 part_minigame(self);
1224
1225         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1226
1227         CheatShutdownClient();
1228
1229         W_HitPlotClose(self);
1230
1231         anticheat_report();
1232         anticheat_shutdown();
1233
1234         playerdemo_shutdown();
1235
1236         bot_clientdisconnect();
1237
1238         entcs_detach(self);
1239
1240         if(autocvar_sv_eventlog)
1241                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1242
1243         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1244
1245         MUTATOR_CALLHOOK(ClientDisconnect);
1246
1247         Portal_ClearAll(self);
1248
1249         Unfreeze(self);
1250
1251         RemoveGrapplingHook(self);
1252
1253         // Here, everything has been done that requires this player to be a client.
1254
1255         self.flags &= ~FL_CLIENT;
1256
1257         if (self.chatbubbleentity)
1258                 remove (self.chatbubbleentity);
1259
1260         if (self.killindicator)
1261                 remove (self.killindicator);
1262
1263         WaypointSprite_PlayerGone();
1264
1265         bot_relinkplayerlist();
1266
1267         accuracy_free(self);
1268         Inventory_delete(self);
1269         ClientData_Detach();
1270         PlayerScore_Detach(self);
1271
1272         if(self.netname_previous)
1273                 strunzone(self.netname_previous);
1274         if(self.clientstatus)
1275                 strunzone(self.clientstatus);
1276         if(self.weaponorder_byimpulse)
1277                 strunzone(self.weaponorder_byimpulse);
1278
1279         if(self.personal)
1280                 remove(self.personal);
1281
1282         self.playerid = 0;
1283         ReadyCount();
1284
1285         // free cvars
1286         GetCvars(-1);
1287 }
1288
1289 .float BUTTON_CHAT;
1290 void ChatBubbleThink()
1291 {SELFPARAM();
1292         self.nextthink = time;
1293         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1294         {
1295                 if(self.owner) // but why can that ever be world?
1296                         self.owner.chatbubbleentity = world;
1297                 remove(self);
1298                 return;
1299         }
1300
1301         self.mdl = "";
1302
1303         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1304         {
1305                 if ( self.owner.active_minigame )
1306                         self.mdl = "models/sprites/minigame_busy.iqm";
1307                 else if ( self.owner.BUTTON_CHAT )
1308                         self.mdl = "models/misc/chatbubble.spr";
1309         }
1310
1311         if ( self.model != self.mdl )
1312                 _setmodel(self, self.mdl);
1313
1314 }
1315
1316 void UpdateChatBubble()
1317 {SELFPARAM();
1318         if (self.alpha < 0)
1319                 return;
1320         // spawn a chatbubble entity if needed
1321         if (!self.chatbubbleentity)
1322         {
1323                 self.chatbubbleentity = new(chatbubbleentity);
1324                 self.chatbubbleentity.owner = self;
1325                 self.chatbubbleentity.exteriormodeltoclient = self;
1326                 self.chatbubbleentity.think = ChatBubbleThink;
1327                 self.chatbubbleentity.nextthink = time;
1328                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1329                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1330                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1331                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1332                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1333                 //self.chatbubbleentity.model = "";
1334                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1335         }
1336 }
1337
1338
1339 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1340 // added to the model skins
1341 /*void UpdateColorModHack()
1342 {
1343         float c;
1344         c = self.clientcolors & 15;
1345         // LordHavoc: only bothering to support white, green, red, yellow, blue
1346              if (!teamplay) self.colormod = '0 0 0';
1347         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1348         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1349         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1350         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1351         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1352         else self.colormod = '1 1 1';
1353 }*/
1354
1355 void respawn()
1356 {SELFPARAM();
1357         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1358         {
1359                 self.solid = SOLID_NOT;
1360                 self.takedamage = DAMAGE_NO;
1361                 self.movetype = MOVETYPE_FLY;
1362                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1363                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1364                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1365                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1366                 if(autocvar_g_respawn_ghosts_maxtime)
1367                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1368         }
1369
1370         CopyBody(1);
1371
1372         self.effects |= EF_NODRAW; // prevent another CopyBody
1373         PutClientInServer();
1374 }
1375
1376 void play_countdown(float finished, string samp)
1377 {SELFPARAM();
1378         if(IS_REAL_CLIENT(self))
1379                 if(floor(finished - time - frametime) != floor(finished - time))
1380                         if(finished - time < 6)
1381                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1382 }
1383
1384 void player_powerups ()
1385 {SELFPARAM();
1386         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1387         int items_prev = self.items;
1388
1389         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1390                 self.modelflags |= MF_ROCKET;
1391         else
1392                 self.modelflags &= ~MF_ROCKET;
1393
1394         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1395
1396         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1397                 return;
1398
1399         Fire_ApplyDamage(self);
1400         Fire_ApplyEffect(self);
1401
1402         if (!g_instagib)
1403         {
1404                 if (self.items & ITEM_Strength.m_itemid)
1405                 {
1406                         play_countdown(self.strength_finished, SND(POWEROFF));
1407                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1408                         if (time > self.strength_finished)
1409                         {
1410                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1411                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1412                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1413                         }
1414                 }
1415                 else
1416                 {
1417                         if (time < self.strength_finished)
1418                         {
1419                                 self.items = self.items | ITEM_Strength.m_itemid;
1420                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1421                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1422                         }
1423                 }
1424                 if (self.items & ITEM_Shield.m_itemid)
1425                 {
1426                         play_countdown(self.invincible_finished, SND(POWEROFF));
1427                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1428                         if (time > self.invincible_finished)
1429                         {
1430                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1431                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1432                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1433                         }
1434                 }
1435                 else
1436                 {
1437                         if (time < self.invincible_finished)
1438                         {
1439                                 self.items = self.items | ITEM_Shield.m_itemid;
1440                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1441                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1442                         }
1443                 }
1444                 if (self.items & IT_SUPERWEAPON)
1445                 {
1446                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1447                         {
1448                                 self.superweapons_finished = 0;
1449                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1450                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1451                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1452                         }
1453                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1454                         {
1455                                 // don't let them run out
1456                         }
1457                         else
1458                         {
1459                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1460                                 if (time > self.superweapons_finished)
1461                                 {
1462                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1463                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1464                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1465                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1466                                 }
1467                         }
1468                 }
1469                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1470                 {
1471                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1472                         {
1473                                 self.items = self.items | IT_SUPERWEAPON;
1474                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1475                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1476                         }
1477                         else
1478                         {
1479                                 self.superweapons_finished = 0;
1480                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1481                         }
1482                 }
1483                 else
1484                 {
1485                         self.superweapons_finished = 0;
1486                 }
1487         }
1488
1489         if(autocvar_g_nodepthtestplayers)
1490                 self.effects = self.effects | EF_NODEPTHTEST;
1491
1492         if(autocvar_g_fullbrightplayers)
1493                 self.effects = self.effects | EF_FULLBRIGHT;
1494
1495         if (time >= game_starttime)
1496         if (time < self.spawnshieldtime)
1497                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1498
1499         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1500 }
1501
1502 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1503 {
1504         if(current > stable)
1505                 return current;
1506         else if(current > stable - 0.25) // when close enough, "snap"
1507                 return stable;
1508         else
1509                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1510 }
1511
1512 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1513 {
1514         if(current < stable)
1515                 return current;
1516         else if(current < stable + 0.25) // when close enough, "snap"
1517                 return stable;
1518         else
1519                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1520 }
1521
1522 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1523 {
1524         if(current > rotstable)
1525         {
1526                 if(rotframetime > 0)
1527                 {
1528                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1529                         current = max(rotstable, current - rotlinear * rotframetime);
1530                 }
1531         }
1532         else if(current < regenstable)
1533         {
1534                 if(regenframetime > 0)
1535                 {
1536                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1537                         current = min(regenstable, current + regenlinear * regenframetime);
1538                 }
1539         }
1540
1541         if(current > limit)
1542                 current = limit;
1543
1544         return current;
1545 }
1546
1547 void player_regen ()
1548 {SELFPARAM();
1549         float max_mod, regen_mod, rot_mod, limit_mod;
1550         max_mod = regen_mod = rot_mod = limit_mod = 1;
1551         regen_mod_max = max_mod;
1552         regen_mod_regen = regen_mod;
1553         regen_mod_rot = rot_mod;
1554         regen_mod_limit = limit_mod;
1555
1556         regen_health = autocvar_g_balance_health_regen;
1557         regen_health_linear = autocvar_g_balance_health_regenlinear;
1558         regen_health_rot = autocvar_g_balance_health_rot;
1559         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1560         regen_health_stable = autocvar_g_balance_health_regenstable;
1561         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1562         if(!MUTATOR_CALLHOOK(PlayerRegen))
1563         if(!self.frozen)
1564         {
1565                 float mina, maxa, limith, limita;
1566                 maxa = autocvar_g_balance_armor_rotstable;
1567                 mina = autocvar_g_balance_armor_regenstable;
1568                 limith = autocvar_g_balance_health_limit;
1569                 limita = autocvar_g_balance_armor_limit;
1570
1571                 max_mod = regen_mod_max;
1572                 regen_mod = regen_mod_regen;
1573                 rot_mod = regen_mod_rot;
1574                 limit_mod = regen_mod_limit;
1575
1576                 regen_health_rotstable = regen_health_rotstable * max_mod;
1577                 regen_health_stable = regen_health_stable * max_mod;
1578                 limith = limith * limit_mod;
1579                 limita = limita * limit_mod;
1580
1581                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1582                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1583         }
1584
1585         // if player rotted to death...  die!
1586         // check this outside above checks, as player may still be able to rot to death
1587         if(self.health < 1)
1588         {
1589                 if(self.vehicle)
1590                         vehicles_exit(VHEF_RELEASE);
1591                 self.event_damage(self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1592         }
1593
1594         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1595         {
1596                 float minf, maxf, limitf;
1597
1598                 maxf = autocvar_g_balance_fuel_rotstable;
1599                 minf = autocvar_g_balance_fuel_regenstable;
1600                 limitf = autocvar_g_balance_fuel_limit;
1601
1602                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1603         }
1604 }
1605
1606 float zoomstate_set;
1607 void SetZoomState(float z)
1608 {SELFPARAM();
1609         if(z != self.zoomstate)
1610         {
1611                 self.zoomstate = z;
1612                 ClientData_Touch(self);
1613         }
1614         zoomstate_set = 1;
1615 }
1616
1617 void GetPressedKeys()
1618 {
1619         SELFPARAM();
1620         MUTATOR_CALLHOOK(GetPressedKeys);
1621         int keys = this.pressedkeys;
1622         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1623         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1624         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1625         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1626
1627         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1628         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1629         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1630         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1631         this.pressedkeys = keys;
1632 }
1633
1634 /*
1635 ======================
1636 spectate mode routines
1637 ======================
1638 */
1639
1640 void SpectateCopy(entity this, entity spectatee)
1641 {
1642         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1643         self.armortype = spectatee.armortype;
1644         self.armorvalue = spectatee.armorvalue;
1645         self.ammo_cells = spectatee.ammo_cells;
1646         self.ammo_plasma = spectatee.ammo_plasma;
1647         self.ammo_shells = spectatee.ammo_shells;
1648         self.ammo_nails = spectatee.ammo_nails;
1649         self.ammo_rockets = spectatee.ammo_rockets;
1650         self.ammo_fuel = spectatee.ammo_fuel;
1651         self.clip_load = spectatee.clip_load;
1652         self.clip_size = spectatee.clip_size;
1653         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1654         self.health = spectatee.health;
1655         self.impulse = 0;
1656         self.items = spectatee.items;
1657         self.last_pickup = spectatee.last_pickup;
1658         self.hit_time = spectatee.hit_time;
1659         self.strength_finished = spectatee.strength_finished;
1660         self.invincible_finished = spectatee.invincible_finished;
1661         self.pressedkeys = spectatee.pressedkeys;
1662         self.weapons = spectatee.weapons;
1663         self.switchweapon = spectatee.switchweapon;
1664         self.switchingweapon = spectatee.switchingweapon;
1665         self.weapon = spectatee.weapon;
1666         self.vortex_charge = spectatee.vortex_charge;
1667         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1668         self.hagar_load = spectatee.hagar_load;
1669         self.arc_heat_percent = spectatee.arc_heat_percent;
1670         self.minelayer_mines = spectatee.minelayer_mines;
1671         self.punchangle = spectatee.punchangle;
1672         self.view_ofs = spectatee.view_ofs;
1673         self.velocity = spectatee.velocity;
1674         self.dmg_take = spectatee.dmg_take;
1675         self.dmg_save = spectatee.dmg_save;
1676         self.dmg_inflictor = spectatee.dmg_inflictor;
1677         self.v_angle = spectatee.v_angle;
1678         self.angles = spectatee.v_angle;
1679         self.frozen = spectatee.frozen;
1680         self.revive_progress = spectatee.revive_progress;
1681         if(!self.BUTTON_USE)
1682                 self.fixangle = true;
1683         setorigin(self, spectatee.origin);
1684         setsize(self, spectatee.mins, spectatee.maxs);
1685         SetZoomState(spectatee.zoomstate);
1686
1687     anticheat_spectatecopy(spectatee);
1688         self.hud = spectatee.hud;
1689         if(spectatee.vehicle)
1690     {
1691         self.fixangle = false;
1692         //self.velocity = spectatee.vehicle.velocity;
1693         self.vehicle_health = spectatee.vehicle_health;
1694         self.vehicle_shield = spectatee.vehicle_shield;
1695         self.vehicle_energy = spectatee.vehicle_energy;
1696         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1697         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1698         self.vehicle_reload1 = spectatee.vehicle_reload1;
1699         self.vehicle_reload2 = spectatee.vehicle_reload2;
1700
1701         msg_entity = self;
1702
1703         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1704             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1705             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1706             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1707
1708         //WriteByte (MSG_ONE, SVC_SETVIEW);
1709         //    WriteEntity(MSG_ONE, self);
1710         //makevectors(spectatee.v_angle);
1711         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1712     }
1713 }
1714
1715 bool SpectateUpdate()
1716 {SELFPARAM();
1717         if(!self.enemy)
1718             return false;
1719
1720         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1721         {
1722                 SetSpectatee(self, NULL);
1723                 return false;
1724         }
1725
1726         SpectateCopy(this, this.enemy);
1727
1728         return true;
1729 }
1730
1731 bool SpectateSet()
1732 {SELFPARAM();
1733         if(!IS_PLAYER(self.enemy))
1734                 return false;
1735
1736         msg_entity = self;
1737         WriteByte(MSG_ONE, SVC_SETVIEW);
1738         WriteEntity(MSG_ONE, self.enemy);
1739         self.movetype = MOVETYPE_NONE;
1740         accuracy_resend(self);
1741
1742         if(!SpectateUpdate())
1743                 PutObserverInServer();
1744
1745         return true;
1746 }
1747
1748 void SetSpectatee(entity player, entity spectatee)
1749 {
1750         entity old_spectatee = player.enemy;
1751
1752         player.enemy = spectatee;
1753
1754         // WEAPONTODO
1755         // these are required to fix the spectator bug with arc
1756         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1757         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1758 }
1759
1760 bool Spectate(entity pl)
1761 {SELFPARAM();
1762         if(MUTATOR_CALLHOOK(SpectateSet, self, pl))
1763                 return false;
1764         pl = spec_player;
1765
1766         SetSpectatee(self, pl);
1767         return SpectateSet();
1768 }
1769
1770 bool SpectateNext()
1771 {SELFPARAM();
1772         other = find(self.enemy, classname, "player");
1773
1774         if (MUTATOR_CALLHOOK(SpectateNext, self, other))
1775                 other = spec_player;
1776         else if (!other)
1777                 other = find(other, classname, "player");
1778
1779         if(other) { SetSpectatee(self, other); }
1780
1781         return SpectateSet();
1782 }
1783
1784 bool SpectatePrev()
1785 {SELFPARAM();
1786         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1787         other = findchain(classname, "player");
1788         if (!other) // no player
1789                 return false;
1790
1791         entity first = other;
1792         // skip players until current spectated player
1793         if(self.enemy)
1794         while(other && other != self.enemy)
1795                 other = other.chain;
1796
1797         switch (MUTATOR_CALLHOOK(SpectatePrev, self, other, first))
1798         {
1799                 case MUT_SPECPREV_FOUND:
1800                     other = spec_player;
1801                     break;
1802                 case MUT_SPECPREV_RETURN:
1803                     other = spec_player;
1804                     return true;
1805                 case MUT_SPECPREV_CONTINUE:
1806                 default:
1807                 {
1808                         if(other.chain)
1809                                 other = other.chain;
1810                         else
1811                                 other = first;
1812                         break;
1813                 }
1814         }
1815
1816         SetSpectatee(self, other);
1817         return SpectateSet();
1818 }
1819
1820 /*
1821 =============
1822 ShowRespawnCountdown()
1823
1824 Update a respawn countdown display.
1825 =============
1826 */
1827 void ShowRespawnCountdown()
1828 {SELFPARAM();
1829         float number;
1830         if(self.deadflag == DEAD_NO) // just respawned?
1831                 return;
1832         else
1833         {
1834                 number = ceil(self.respawn_time - time);
1835                 if(number <= 0)
1836                         return;
1837                 if(number <= self.respawn_countdown)
1838                 {
1839                         self.respawn_countdown = number - 1;
1840                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1841                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1842                 }
1843         }
1844 }
1845
1846 void LeaveSpectatorMode()
1847 {SELFPARAM();
1848         if(self.caplayer)
1849                 return;
1850         if(nJoinAllowed(self))
1851         {
1852                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1853                 {
1854                         self.classname = STR_PLAYER;
1855
1856                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1857                                 { JoinBestTeam(self, false, true); }
1858
1859                         if(autocvar_g_campaign)
1860                                 { campaign_bots_may_start = 1; }
1861
1862                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1863
1864                         PutClientInServer();
1865
1866                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1867                 }
1868                 else
1869                         stuffcmd(self, "menu_showteamselect\n");
1870         }
1871         else
1872         {
1873                 // Player may not join because g_maxplayers is set
1874                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1875         }
1876 }
1877
1878 /**
1879  * Determines whether the player is allowed to join. This depends on cvar
1880  * g_maxplayers, if it isn't used this function always return true, otherwise
1881  * it checks whether the number of currently playing players exceeds g_maxplayers.
1882  * @return int number of free slots for players, 0 if none
1883  */
1884 float nJoinAllowed(entity ignore)
1885 {SELFPARAM();
1886         if(!ignore)
1887         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1888         // so report 0 free slots if restricted
1889         {
1890                 if(autocvar_g_forced_team_otherwise == "spectate")
1891                         return 0;
1892                 if(autocvar_g_forced_team_otherwise == "spectator")
1893                         return 0;
1894         }
1895
1896         if(self.team_forced < 0)
1897                 return 0; // forced spectators can never join
1898
1899         // TODO simplify this
1900         entity e;
1901         float totalClients = 0;
1902         FOR_EACH_CLIENT(e)
1903                 if(e != ignore)
1904                         totalClients += 1;
1905
1906         if (!autocvar_g_maxplayers)
1907                 return maxclients - totalClients;
1908
1909         float currentlyPlaying = 0;
1910         FOR_EACH_REALCLIENT(e)
1911                 if(IS_PLAYER(e) || e.caplayer)
1912                         currentlyPlaying += 1;
1913
1914         if(currentlyPlaying < autocvar_g_maxplayers)
1915                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1916
1917         return 0;
1918 }
1919
1920 /**
1921  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1922  * g_maxplayers_spectator_blocktime seconds
1923  */
1924 void checkSpectatorBlock()
1925 {SELFPARAM();
1926         if(IS_SPEC(self) || IS_OBSERVER(self))
1927         if(!self.caplayer)
1928         if(IS_REAL_CLIENT(self))
1929         {
1930                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1931                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1932                         dropclient(self);
1933                 }
1934         }
1935 }
1936
1937 void PrintWelcomeMessage()
1938 {SELFPARAM();
1939         if(self.motd_actived_time == 0)
1940         {
1941                 if (autocvar_g_campaign) {
1942                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1943                                 self.motd_actived_time = time;
1944                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1945                         }
1946                 } else {
1947                         if (self.BUTTON_INFO) {
1948                                 self.motd_actived_time = time;
1949                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1950                         }
1951                 }
1952         }
1953         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1954         {
1955                 if (autocvar_g_campaign) {
1956                         if (self.BUTTON_INFO)
1957                                 self.motd_actived_time = time;
1958                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
1959                                 self.motd_actived_time = 0;
1960                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1961                         }
1962                 } else {
1963                         if (self.BUTTON_INFO)
1964                                 self.motd_actived_time = time;
1965                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1966                                 self.motd_actived_time = 0;
1967                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1968                         }
1969                 }
1970         }
1971         else //if(self.motd_actived_time < 0) // just connected, motd is active
1972         {
1973                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
1974                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1975                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || IS_SPEC(self))
1976                 {
1977                         // instanctly hide MOTD
1978                         self.motd_actived_time = 0;
1979                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1980                 }
1981         }
1982 }
1983
1984 void ObserverThink()
1985 {SELFPARAM();
1986         if ( self.impulse )
1987         {
1988                 MinigameImpulse(self, self.impulse);
1989                 self.impulse = 0;
1990         }
1991         float prefered_movetype;
1992         if (self.flags & FL_JUMPRELEASED) {
1993                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1994                         self.flags &= ~FL_JUMPRELEASED;
1995                         self.flags |= FL_SPAWNING;
1996                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1997                         self.flags &= ~FL_JUMPRELEASED;
1998                         if(SpectateNext()) {
1999                                 self.classname = STR_SPECTATOR;
2000                         }
2001                 } else {
2002                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2003                         if (self.movetype != prefered_movetype)
2004                                 self.movetype = prefered_movetype;
2005                 }
2006         } else {
2007                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2008                         self.flags |= FL_JUMPRELEASED;
2009                         if(self.flags & FL_SPAWNING)
2010                         {
2011                                 self.flags &= ~FL_SPAWNING;
2012                                 LeaveSpectatorMode();
2013                                 return;
2014                         }
2015                 }
2016         }
2017 }
2018
2019 void SpectatorThink()
2020 {SELFPARAM();
2021         if ( self.impulse )
2022         {
2023                 if(MinigameImpulse(self, self.impulse))
2024                         self.impulse = 0;
2025         }
2026         if (self.flags & FL_JUMPRELEASED) {
2027                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2028                         self.flags &= ~FL_JUMPRELEASED;
2029                         self.flags |= FL_SPAWNING;
2030                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2031                         self.flags &= ~FL_JUMPRELEASED;
2032                         if(SpectateNext()) {
2033                                 self.classname = STR_SPECTATOR;
2034                         } else {
2035                                 self.classname = STR_OBSERVER;
2036                                 PutClientInServer();
2037                         }
2038                         self.impulse = 0;
2039                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2040                         self.flags &= ~FL_JUMPRELEASED;
2041                         if(SpectatePrev()) {
2042                                 self.classname = STR_SPECTATOR;
2043                         } else {
2044                                 self.classname = STR_OBSERVER;
2045                                 PutClientInServer();
2046                         }
2047                         self.impulse = 0;
2048                 } else if (self.BUTTON_ATCK2) {
2049                         self.flags &= ~FL_JUMPRELEASED;
2050                         self.classname = STR_OBSERVER;
2051                         PutClientInServer();
2052                 } else {
2053                         if(!SpectateUpdate())
2054                                 PutObserverInServer();
2055                 }
2056         } else {
2057                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2058                         self.flags |= FL_JUMPRELEASED;
2059                         if(self.flags & FL_SPAWNING)
2060                         {
2061                                 self.flags &= ~FL_SPAWNING;
2062                                 LeaveSpectatorMode();
2063                                 return;
2064                         }
2065                 }
2066                 if(!SpectateUpdate())
2067                         PutObserverInServer();
2068         }
2069
2070         self.flags |= FL_CLIENT | FL_NOTARGET;
2071 }
2072
2073 void vehicles_enter (entity pl, entity veh);
2074 void PlayerUseKey()
2075 {SELFPARAM();
2076         if (!IS_PLAYER(self))
2077                 return;
2078
2079         if(self.vehicle)
2080         {
2081                 if(!gameover)
2082                 {
2083                         vehicles_exit(VHEF_NORMAL);
2084                         return;
2085                 }
2086         }
2087         else if(autocvar_g_vehicles_enter)
2088         {
2089                 if(!self.frozen)
2090                 if(self.deadflag == DEAD_NO)
2091                 if(!gameover)
2092                 {
2093                         entity head, closest_target = world;
2094                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2095
2096                         while(head) // find the closest acceptable target to enter
2097                         {
2098                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2099                                 if(head.deadflag == DEAD_NO)
2100                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2101                                 if(head.takedamage != DAMAGE_NO)
2102                                 {
2103                                         if(closest_target)
2104                                         {
2105                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2106                                                 { closest_target = head; }
2107                                         }
2108                                         else { closest_target = head; }
2109                                 }
2110
2111                                 head = head.chain;
2112                         }
2113
2114                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2115                 }
2116         }
2117
2118         // a use key was pressed; call handlers
2119         MUTATOR_CALLHOOK(PlayerUseKey);
2120 }
2121
2122
2123 /*
2124 =============
2125 PlayerPreThink
2126
2127 Called every frame for each client before the physics are run
2128 =============
2129 */
2130 .float usekeypressed;
2131 void() nexball_setstatus;
2132 .float last_vehiclecheck;
2133 .int items_added;
2134 void PlayerPreThink ()
2135 {SELFPARAM();
2136         WarpZone_PlayerPhysics_FixVAngle();
2137
2138         self.stat_game_starttime = game_starttime;
2139         self.stat_round_starttime = round_starttime;
2140         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2141         self.stat_leadlimit = autocvar_leadlimit;
2142
2143         self.weaponsinmap = weaponsInMap;
2144
2145         if(frametime)
2146         {
2147                 // physics frames: update anticheat stuff
2148                 anticheat_prethink();
2149         }
2150
2151         if(blockSpectators && frametime)
2152                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2153                 checkSpectatorBlock();
2154
2155         zoomstate_set = 0;
2156
2157         // Savage: Check for nameless players
2158         if (isInvisibleString(self.netname)) {
2159                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2160                 if(autocvar_sv_eventlog)
2161                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2162                 if(self.netname_previous)
2163                         strunzone(self.netname_previous);
2164                 self.netname_previous = strzone(new_name);
2165                 self.netname = self.netname_previous;
2166                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2167         } else if(self.netname_previous != self.netname) {
2168                 if(autocvar_sv_eventlog)
2169                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2170                 if(self.netname_previous)
2171                         strunzone(self.netname_previous);
2172                 self.netname_previous = strzone(self.netname);
2173         }
2174
2175         // version nagging
2176         if(self.version_nagtime)
2177                 if(self.cvar_g_xonoticversion)
2178                         if(time > self.version_nagtime)
2179                         {
2180                                 // don't notify git users
2181                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2182                                 {
2183                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2184                                         {
2185                                                 // notify release users if connecting to git
2186                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2187                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2188                                         }
2189                                         else
2190                                         {
2191                                                 float r;
2192                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2193                                                 if(r < 0)
2194                                                 {
2195                                                         // give users new version
2196                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2197                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2198                                                 }
2199                                                 else if(r > 0)
2200                                                 {
2201                                                         // notify users about old server version
2202                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2203                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2204                                                 }
2205                                         }
2206                                 }
2207                                 self.version_nagtime = 0;
2208                         }
2209
2210         // GOD MODE info
2211         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2212         {
2213                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2214                 self.max_armorvalue = 0;
2215         }
2216
2217         if(self.frozen == 2)
2218         {
2219                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2220                 self.health = max(1, self.revive_progress * start_health);
2221                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2222
2223                 if(self.revive_progress >= 1)
2224                         Unfreeze(self);
2225         }
2226         else if(self.frozen == 3)
2227         {
2228                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2229                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2230
2231                 if(self.health < 1)
2232                 {
2233                         if(self.vehicle)
2234                                 vehicles_exit(VHEF_RELEASE);
2235                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2236                 }
2237                 else if ( self.revive_progress <= 0 )
2238                         Unfreeze(self);
2239         }
2240
2241         MUTATOR_CALLHOOK(PlayerPreThink);
2242
2243         if(autocvar_g_vehicles_enter)
2244         if(time > self.last_vehiclecheck)
2245         if(IS_PLAYER(self))
2246         if(!gameover)
2247         if(!self.frozen)
2248         if(!self.vehicle)
2249         if(self.deadflag == DEAD_NO)
2250         {
2251                 entity veh;
2252                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2253                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2254                 if(veh.deadflag == DEAD_NO)
2255                 if(veh.takedamage != DAMAGE_NO)
2256                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2257                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2258                 else if(!veh.owner)
2259                 if(!veh.team || SAME_TEAM(self, veh))
2260                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2261                 else if(autocvar_g_vehicles_steal)
2262                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2263
2264                 self.last_vehiclecheck = time + 1;
2265         }
2266
2267         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2268         {
2269                 if(self.BUTTON_USE && !self.usekeypressed)
2270                         PlayerUseKey();
2271                 self.usekeypressed = self.BUTTON_USE;
2272         }
2273
2274         if(IS_REAL_CLIENT(self))
2275                 PrintWelcomeMessage();
2276
2277         if(IS_PLAYER(self))
2278         {
2279
2280                 CheckRules_Player();
2281
2282                 if (intermission_running)
2283                 {
2284                         IntermissionThink ();   // otherwise a button could be missed between
2285                         return;                                 // the think tics
2286                 }
2287
2288                 //don't allow the player to turn around while game is paused!
2289                 if(timeout_status == TIMEOUT_ACTIVE) {
2290                         // FIXME turn this into CSQC stuff
2291                         self.v_angle = self.lastV_angle;
2292                         self.angles = self.lastV_angle;
2293                         self.fixangle = true;
2294                 }
2295
2296                 if(frametime)
2297                 {
2298                         player_powerups();
2299                 }
2300
2301                 if (self.deadflag != DEAD_NO)
2302                 {
2303                         if(self.personal && g_race_qualifying)
2304                         {
2305                                 if(time > self.respawn_time)
2306                                 {
2307                                         self.respawn_time = time + 1; // only retry once a second
2308                                         self.stat_respawn_time = self.respawn_time;
2309                                         respawn();
2310                                         self.impulse = 141;
2311                                 }
2312                         }
2313                         else
2314                         {
2315                                 float button_pressed;
2316                                 if(frametime)
2317                                         player_anim();
2318                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2319
2320                                 if (self.deadflag == DEAD_DYING)
2321                                 {
2322                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2323                                                 self.deadflag = DEAD_RESPAWNING;
2324                                         else if(!button_pressed)
2325                                                 self.deadflag = DEAD_DEAD;
2326                                 }
2327                                 else if (self.deadflag == DEAD_DEAD)
2328                                 {
2329                                         if(button_pressed)
2330                                                 self.deadflag = DEAD_RESPAWNABLE;
2331                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2332                                                 self.deadflag = DEAD_RESPAWNING;
2333                                 }
2334                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2335                                 {
2336                                         if(!button_pressed)
2337                                                 self.deadflag = DEAD_RESPAWNING;
2338                                 }
2339                                 else if (self.deadflag == DEAD_RESPAWNING)
2340                                 {
2341                                         if(time > self.respawn_time)
2342                                         {
2343                                                 self.respawn_time = time + 1; // only retry once a second
2344                                                 self.respawn_time_max = self.respawn_time;
2345                                                 respawn();
2346                                         }
2347                                 }
2348
2349                                 ShowRespawnCountdown();
2350
2351                                 if(self.respawn_flags & RESPAWN_SILENT)
2352                                         self.stat_respawn_time = 0;
2353                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2354                                         self.stat_respawn_time = self.respawn_time_max;
2355                                 else
2356                                         self.stat_respawn_time = self.respawn_time;
2357                         }
2358
2359                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2360                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2361                                 self.stat_respawn_time *= -1;
2362
2363                         return;
2364                 }
2365
2366                 self.prevorigin = self.origin;
2367
2368                 float do_crouch = self.BUTTON_CROUCH;
2369                 if(self.hook.state)
2370                         do_crouch = 0;
2371                 if(self.vehicle)
2372                         do_crouch = 0;
2373                 if(self.frozen)
2374                         do_crouch = 0;
2375
2376                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2377                 // It cannot be predicted by the engine!
2378                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2379                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.(weaponentity).wframe == WFRAME_FIRE2 && time < self.(weaponentity).weapon_nextthink)
2380                         do_crouch = 0;
2381
2382                 if (do_crouch)
2383                 {
2384                         if (!self.crouch)
2385                         {
2386                                 self.crouch = true;
2387                                 self.view_ofs = STAT(PL_CROUCH_VIEW_OFS, self);
2388                                 setsize (self, STAT(PL_CROUCH_MIN, self), STAT(PL_CROUCH_MAX, self));
2389                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2390                         }
2391                 }
2392                 else
2393                 {
2394                         if (self.crouch)
2395                         {
2396                                 tracebox(self.origin, STAT(PL_MIN, self), STAT(PL_MAX, self), self.origin, false, self);
2397                                 if (!trace_startsolid)
2398                                 {
2399                                         self.crouch = false;
2400                                         self.view_ofs = STAT(PL_VIEW_OFS, self);
2401                                         setsize (self, STAT(PL_MIN, self), STAT(PL_MAX, self));
2402                                 }
2403                         }
2404                 }
2405
2406                 FixPlayermodel(self);
2407
2408                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2409                 //if(frametime)
2410                 {
2411                         self.items &= ~self.items_added;
2412
2413                         W_WeaponFrame(self);
2414
2415                         self.items_added = 0;
2416                         if(self.items & ITEM_Jetpack.m_itemid)
2417                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2418                                         self.items_added |= IT_FUEL;
2419
2420                         self.items |= self.items_added;
2421                 }
2422
2423                 player_regen();
2424
2425                 // WEAPONTODO: Add a weapon request for this
2426                 // rot vortex charge to the charge limit
2427                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2428                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2429
2430                 if(frametime)
2431                         player_anim();
2432
2433                 // secret status
2434                 secrets_setstatus();
2435
2436                 // monsters status
2437                 monsters_setstatus();
2438
2439                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2440
2441                 //self.angles_y=self.v_angle_y + 90;   // temp
2442         } else if(gameover) {
2443                 if (intermission_running)
2444                         IntermissionThink ();   // otherwise a button could be missed between
2445                 return;
2446         } else if(IS_OBSERVER(self)) {
2447                 ObserverThink();
2448         } else if(IS_SPEC(self)) {
2449                 SpectatorThink();
2450         }
2451
2452         // WEAPONTODO: Add weapon request for this
2453         if(!zoomstate_set)
2454                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2455
2456         float oldspectatee_status;
2457         oldspectatee_status = self.spectatee_status;
2458         if(IS_SPEC(self))
2459                 self.spectatee_status = num_for_edict(self.enemy);
2460         else if(IS_OBSERVER(self))
2461                 self.spectatee_status = num_for_edict(self);
2462         else
2463                 self.spectatee_status = 0;
2464         if(self.spectatee_status != oldspectatee_status)
2465         {
2466                 ClientData_Touch(self);
2467                 if(g_race || g_cts)
2468                         race_InitSpectator();
2469         }
2470
2471         if(self.teamkill_soundtime)
2472         if(time > self.teamkill_soundtime)
2473         {
2474                 self.teamkill_soundtime = 0;
2475
2476                 entity e = self.teamkill_soundsource;
2477                 entity oldpusher = e.pusher;
2478                 e.pusher = this;
2479                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2480                 e.pusher = oldpusher;
2481         }
2482
2483         if(self.taunt_soundtime)
2484         if(time > self.taunt_soundtime)
2485         {
2486                 self.taunt_soundtime = 0;
2487                 PlayerSound(self, playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2488         }
2489
2490         target_voicescript_next(self);
2491
2492         // WEAPONTODO: Move into weaponsystem somehow
2493         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2494         if(!self.weapon)
2495                 self.clip_load = self.clip_size = 0;
2496 }
2497
2498 void DrownPlayer(entity this)
2499 {
2500         if(this.deadflag != DEAD_NO)
2501                 return;
2502
2503         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2504         {
2505                 if(this.air_finished < time)
2506                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
2507                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2508                 this.dmg = 2;
2509         }
2510         else if (this.air_finished < time)
2511         {       // drown!
2512                 if (this.pain_finished < time)
2513                 {
2514                         Damage (this, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2515                         this.pain_finished = time + 0.5;
2516                 }
2517         }
2518 }
2519
2520 /*
2521 =============
2522 PlayerPostThink
2523
2524 Called every frame for each client after the physics are run
2525 =============
2526 */
2527 .float idlekick_lasttimeleft;
2528 void PlayerPostThink ()
2529 {SELFPARAM();
2530         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2531         if(IS_REAL_CLIENT(self))
2532         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2533         {
2534                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2535                 {
2536                         if(self.idlekick_lasttimeleft)
2537                         {
2538                                 self.idlekick_lasttimeleft = 0;
2539                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2540                         }
2541                 }
2542                 else
2543                 {
2544                         float timeleft;
2545                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2546                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2547                         {
2548                                 if(!self.idlekick_lasttimeleft)
2549                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2550                         }
2551                         if(timeleft <= 0)
2552                         {
2553                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2554                                 dropclient(self);
2555                                 return;
2556                         }
2557                         else if(timeleft <= 10)
2558                         {
2559                                 if(timeleft != self.idlekick_lasttimeleft)
2560                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2561                                 self.idlekick_lasttimeleft = timeleft;
2562                         }
2563                 }
2564         }
2565
2566         CheatFrame();
2567
2568         //CheckPlayerJump();
2569
2570         if(IS_PLAYER(self)) {
2571                 DrownPlayer(self);
2572                 CheckRules_Player();
2573                 UpdateChatBubble();
2574                 if (self.impulse)
2575                         ImpulseCommands(self);
2576                 if (intermission_running)
2577                         return;         // intermission or finale
2578                 GetPressedKeys();
2579         }
2580
2581         /*
2582         float i;
2583         for(i = 0; i < 1000; ++i)
2584         {
2585                 vector end;
2586                 end = self.origin + '0 0 1024' + 512 * randomvec();
2587                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2588                 if(trace_fraction < 1)
2589                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2590                 {
2591                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2592                         break;
2593                 }
2594         }
2595         */
2596
2597         if(self.waypointsprite_attachedforcarrier)
2598                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2599
2600         playerdemo_write();
2601
2602         CSQCMODEL_AUTOUPDATE(self);
2603 }