qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.dphitcontentsmask = oldself.dphitcontentsmask;
 171         self.death_time = oldself.death_time;
 172         self.pain_finished = oldself.pain_finished;
 173         self.health = oldself.health;
 174         self.armorvalue = oldself.armorvalue;
 175         self.armortype = oldself.armortype;
 176         self.model = oldself.model;
 177         self.modelindex = oldself.modelindex;
 178         self.skin = oldself.skin;
 179         self.species = oldself.species;
 180         self.movetype = oldself.movetype;
 181         self.solid = oldself.solid;
 182         self.ballistics_density = oldself.ballistics_density;
 183         self.takedamage = oldself.takedamage;
 184         self.customizeentityforclient = oldself.customizeentityforclient;
 185         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 186         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 187         if (keepvelocity == 1)
 188                 self.velocity = oldself.velocity;
 189         self.oldvelocity = self.velocity;
 190         self.alpha = oldself.alpha;
 191         self.fade_time = oldself.fade_time;
 192         self.fade_rate = oldself.fade_rate;
 193         //self.weapon = oldself.weapon;
 194         setorigin(self, oldself.origin);
 195         setsize(self, oldself.mins, oldself.maxs);
 196         self.prevorigin = oldself.origin;
 197         self.reset = SUB_Remove;
 198
 199         Drag_MoveDrag(oldself, self);
 200
 201         if(self.colormap <= maxclients && self.colormap > 0)
 202                 self.colormap = 1024 + oldself.clientcolors;
 203
 204         CSQCMODEL_AUTOINIT();
 205         self.CopyBody_nextthink = oldself.nextthink;
 206         self.CopyBody_think = oldself.think;
 207         self.nextthink = time;
 208         self.think = CopyBody_Think;
 209         // "bake" the current animation frame for clones (they don't get clientside animation)
 210         animdecide_setframes(self, self.flags, FALSE, frame, frame1time, frame2, frame2time);
 211
 212         self = oldself;
 213 }
 214
 215 float player_getspecies()
 216 {
 217         float s;
 218         get_model_parameters(self.model, self.skin);
 219         s = get_model_parameters_species;
 220         get_model_parameters(string_null, 0);
 221         if(s < 0)
 222                 return SPECIES_HUMAN;
 223         return s;
 224 }
 225
 226 void player_setupanimsformodel()
 227 {
 228         // load animation info
 229         animdecide_init(self);
 230         animdecide_setstate(self, 0, FALSE);
 231 }
 232
 233 void player_anim (void)
 234 {
 235         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 236         if(self.deadflag && !deadbits)
 237                 if(random() < 0.5)
 238                         deadbits = ANIMSTATE_DEAD1;
 239                 else
 240                         deadbits = ANIMSTATE_DEAD2;
 241         float animbits = deadbits;
 242         if(self.freezetag_frozen)
 243                 animbits |= ANIMSTATE_FROZEN;
 244         if(self.crouch)
 245                 animbits |= ANIMSTATE_DUCK;
 246         animdecide_setstate(self, animbits, FALSE);
 247
 248         if (self.weaponentity)
 249         {
 250                 updateanim(self.weaponentity);
 251                 if (!self.weaponentity.animstate_override)
 252                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 253         }
 254 }
 255
 256 void SpawnThrownWeapon (vector org, float w)
 257 {
 258         if(g_minstagib)
 259         if(self.ammo_cells <= 0)
 260                 return;
 261
 262         if(g_pinata)
 263         {
 264                 float j;
 265                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 266                 {
 267                         if(WEPSET_CONTAINS_EW(self, j))
 268                                 if(W_IsWeaponThrowable(j))
 269                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 270                 }
 271         }
 272         else
 273         {
 274                 if(W_IsWeaponThrowable(self.weapon))
 275                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 276         }
 277 }
 278
 279 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 280 {
 281         float take, save;
 282         vector v;
 283         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 284
 285         // damage resistance (ignore most of the damage from a bullet or similar)
 286         damage = max(damage - 5, 1);
 287
 288         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 289         take = v_x;
 290         save = v_y;
 291
 292         if(sound_allowed(MSG_BROADCAST, attacker))
 293         {
 294                 if (save > 10)
 295                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 296                 else if (take > 30)
 297                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 298                 else if (take > 10)
 299                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 300         }
 301
 302         if (take > 50)
 303                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 304         if (take > 100)
 305                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 306
 307         if (!(self.flags & FL_GODMODE))
 308         {
 309                 self.armorvalue = self.armorvalue - save;
 310                 self.health = self.health - take;
 311                 // pause regeneration for 5 seconds
 312                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 313         }
 314         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 315         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 316         self.dmg_inflictor = inflictor;
 317
 318         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 319         {
 320                 // don't use any animations as a gib
 321                 self.frame = 0;
 322                 // view just above the floor
 323                 self.view_ofs = '0 0 4';
 324
 325                 Violence_GibSplash(self, 1, 1, attacker);
 326                 self.alpha = -1;
 327                 self.solid = SOLID_NOT; // restore later
 328                 self.takedamage = DAMAGE_NO; // restore later
 329                 self.damagedbycontents = FALSE;
 330         }
 331 }
 332
 333 void ClientKill_Now_TeamChange();
 334 void freezetag_CheckWinner();
 335
 336 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 337 {
 338         float take, save, waves, sdelay, dh, da, j;
 339         vector v;
 340         float valid_damage_for_weaponstats;
 341         float excess;
 342
 343         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 344                 return;
 345
 346         dh = max(self.health, 0);
 347         da = max(self.armorvalue, 0);
 348
 349         if(!DEATH_ISSPECIAL(deathtype))
 350         {
 351                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 352                 if(self != attacker)
 353                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 354         }
 355
 356         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 357         {
 358                 // tuba causes blood to come out of the ears
 359                 vector ear1, ear2;
 360                 vector d;
 361                 float f;
 362                 ear1 = self.origin;
 363                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 364                 ear2 = ear1;
 365                 makevectors(self.angles);
 366                 ear1 += v_right * -10;
 367                 ear2 += v_right * +10;
 368                 d = inflictor.origin - self.origin;
 369                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 370                 force = v_right * vlen(force);
 371                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 372                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 373                 if(f > 0)
 374                 {
 375                         hitloc = ear1;
 376                         force = force * -1;
 377                 }
 378                 else
 379                 {
 380                         hitloc = ear2;
 381                         // force is already good
 382                 }
 383         }
 384         else
 385                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 386
 387         if (!g_minstagib)
 388         {
 389                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 390                 take = v_x;
 391                 save = v_y;
 392         }
 393         else
 394         {
 395                 save = 0;
 396                 take = damage;
 397         }
 398
 399         frag_inflictor = inflictor;
 400         frag_attacker = attacker;
 401         frag_target = self;
 402         damage_take = take;
 403         damage_save = save;
 404         damage_force = force;
 405         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 406         take = bound(0, damage_take, self.health);
 407         save = bound(0, damage_save, self.armorvalue);
 408         excess = max(0, damage - take - save);
 409
 410         if(sound_allowed(MSG_BROADCAST, attacker))
 411         {
 412                 if (save > 10)
 413                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 414                 else if (take > 30)
 415                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 416                 else if (take > 10)
 417                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 418         }
 419
 420         if (take > 50)
 421                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 422         if (take > 100)
 423                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 424
 425         if (time >= self.spawnshieldtime)
 426         {
 427                 if (!(self.flags & FL_GODMODE))
 428                 {
 429                         self.armorvalue = self.armorvalue - save;
 430                         self.health = self.health - take;
 431                         // pause regeneration for 5 seconds
 432                         if(take)
 433                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 434
 435                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 436                         {
 437                                 self.pain_finished = time + 0.5;        //Supajoe
 438
 439                                 if(sv_gentle < 1) {
 440                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 441                                         {
 442                                                 if (!self.animstate_override)
 443                                                 {
 444                                                         if (random() > 0.5)
 445                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 446                                                         else
 447                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 448                                                 }
 449                                         }
 450
 451                                         if(sound_allowed(MSG_BROADCAST, attacker))
 452                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 453                                         if(self.health > 1)
 454                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 455                                         {
 456                                                 if(deathtype == DEATH_FALL)
 457                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 458                                                 else if(self.health > 75) // TODO make a "gentle" version?
 459                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 460                                                 else if(self.health > 50)
 461                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 462                                                 else if(self.health > 25)
 463                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 464                                                 else
 465                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 466                                         }
 467                                 }
 468
 469                                 // throw off bot aim temporarily
 470                                 float shake;
 471                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 472                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 473                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 474                         }
 475                 }
 476                 else
 477                         self.max_armorvalue += (save + take);
 478         }
 479         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 480         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 481         self.dmg_inflictor = inflictor;
 482
 483         if(attacker == self)
 484         {
 485                 // don't reset pushltime for self damage as it may be an attempt to
 486                 // escape a lava pit or similar
 487                 //self.pushltime = 0;
 488                 self.istypefrag = 0;
 489         }
 490         else if(attacker.classname == "player")
 491         {
 492                 self.pusher = attacker;
 493                 self.pushltime = time + autocvar_g_maxpushtime;
 494                 self.istypefrag = self.BUTTON_CHAT;
 495         }
 496         else if(time < self.pushltime)
 497         {
 498                 attacker = self.pusher;
 499                 self.pushltime = max(self.pushltime, time + 0.6);
 500         }
 501         else
 502         {
 503                 self.pushltime = 0;
 504                 self.istypefrag = 0;
 505         }
 506
 507         float abot, vbot, awep;
 508         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 509         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 510
 511         valid_damage_for_weaponstats = 0;
 512         awep = 0;
 513
 514         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 515         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 516         if(attacker && self != attacker)
 517         if(IsDifferentTeam(self, attacker))
 518         {
 519                 if(DEATH_ISSPECIAL(deathtype))
 520                         awep = attacker.weapon;
 521                 else
 522                         awep = DEATH_WEAPONOF(deathtype);
 523                 valid_damage_for_weaponstats = 1;
 524         }
 525
 526         if(valid_damage_for_weaponstats)
 527         {
 528                 dh = dh - max(self.health, 0);
 529                 da = da - max(self.armorvalue, 0);
 530                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 531         }
 532
 533         if (self.health < 1)
 534         {
 535                 float defer_ClientKill_Now_TeamChange;
 536                 defer_ClientKill_Now_TeamChange = FALSE;
 537
 538                 if(self.alivetime)
 539                 {
 540                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 541                         self.alivetime = 0;
 542                 }
 543
 544                 if(valid_damage_for_weaponstats)
 545                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 546
 547                 if(sv_gentle < 1) // TODO make a "gentle" version?
 548                 if(sound_allowed(MSG_BROADCAST, attacker))
 549                 {
 550                         if(deathtype == DEATH_DROWN)
 551                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 552                         else
 553                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 554                 }
 555
 556                 // get rid of kill indicator
 557                 if(self.killindicator)
 558                 {
 559                         remove(self.killindicator);
 560                         self.killindicator = world;
 561                         if(self.killindicator_teamchange)
 562                                 defer_ClientKill_Now_TeamChange = TRUE;
 563
 564                         if(self.classname == "body")
 565                         if(deathtype == DEATH_KILL)
 566                         {
 567                                 // for the lemmings fans, a small harmless explosion
 568                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 569                         }
 570                 }
 571
 572                 if(!g_freezetag)
 573                 {
 574                         // become fully visible
 575                         self.alpha = default_player_alpha;
 576                         // throw a weapon
 577                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 578                 }
 579
 580                 // print an obituary message
 581                 Obituary (attacker, inflictor, self, deathtype);
 582                 race_PreDie();
 583                 DropAllRunes(self);
 584
 585         // increment frag counter for used weapon type
 586         float w;
 587         w = DEATH_WEAPONOF(deathtype);
 588         if(WEP_VALID(w))
 589         if(accuracy_isgooddamage(attacker, self))
 590         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 591
 592                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 593                 {
 594                         PutClientInServer();
 595                         count_alive_players(); // re-count players
 596                         freezetag_CheckWinner();
 597                         return;
 598                 }
 599
 600                 frag_attacker = attacker;
 601                 frag_inflictor = inflictor;
 602                 frag_target = self;
 603                 MUTATOR_CALLHOOK(PlayerDies);
 604                 weapon_action(self.weapon, WR_PLAYERDEATH);
 605
 606                 RemoveGrapplingHook(self);
 607
 608                 Portal_ClearAllLater(self);
 609
 610                 if(clienttype(self) == CLIENTTYPE_REAL)
 611                 {
 612                         stuffcmd(self, "-zoom\n");
 613                         self.fixangle = TRUE;
 614                         //msg_entity = self;
 615                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 616                         //WriteAngle (MSG_ONE, self.v_angle_x);
 617                         //WriteAngle (MSG_ONE, self.v_angle_y);
 618                         //WriteAngle (MSG_ONE, 80);
 619                 }
 620
 621                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 622                         ClientKill_Now_TeamChange();
 623
 624                 if(g_arena)
 625                         Spawnqueue_Unmark(self);
 626
 627                 if(g_freezetag)
 628                         return;
 629
 630                 // when we get here, player actually dies
 631                 // clear waypoints (do this AFTER FreezeTag)
 632                 WaypointSprite_PlayerDead();
 633
 634                 // make the corpse upright (not tilted)
 635                 self.angles_x = 0;
 636                 self.angles_z = 0;
 637                 // don't spin
 638                 self.avelocity = '0 0 0';
 639                 // view from the floor
 640                 self.view_ofs = '0 0 -8';
 641                 // toss the corpse
 642                 self.movetype = MOVETYPE_TOSS;
 643                 // shootable corpse
 644                 self.solid = SOLID_CORPSE;
 645                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 646                 // don't stick to the floor
 647                 self.flags &~= FL_ONGROUND;
 648                 // dying animation
 649                 self.deadflag = DEAD_DYING;
 650                 // when to allow respawn
 651                 sdelay = 0;
 652                 waves = 0;
 653                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 654                 if(!sdelay)
 655                 {
 656                         if(g_cts)
 657                                 sdelay = 0; // no respawn delay in CTS
 658                         else
 659                                 sdelay = autocvar_g_respawn_delay;
 660                 }
 661                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 662                 if(!waves)
 663                         waves = autocvar_g_respawn_waves;
 664                 if(waves)
 665                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 666                 else
 667                         self.respawn_time = time + sdelay;
 668                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 669                         self.respawn_countdown = 10; // first number to count down from is 10
 670                 else
 671                         self.respawn_countdown = -1; // do not count down
 672                 self.death_time = time;
 673                 if (random() < 0.5)
 674                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 675                 else
 676                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 677                 if (self.maxs_z > 5)
 678                 {
 679                         self.maxs_z = 5;
 680                         setsize(self, self.mins, self.maxs);
 681                 }
 682                 // set damage function to corpse damage
 683                 self.event_damage = PlayerCorpseDamage;
 684                 // call the corpse damage function just in case it wants to gib
 685                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 686                 // set up to fade out later
 687                 SUB_SetFade (self, time + 6 + random (), 1);
 688
 689                 if(sv_gentle > 0 || autocvar_ekg) {
 690                         // remove corpse
 691                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 692                 }
 693
 694                 // reset fields the weapons may use just in case
 695                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 696                 {
 697                         weapon_action(j, WR_RESETPLAYER);
 698                         ATTACK_FINISHED_FOR(self, j) = 0;
 699                 }
 700         }
 701 }
 702
 703 .float muted; // to be used by prvm_edictset server playernumber muted 1
 704 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 705 // message "": do not say, just test flood control
 706 // return value:
 707 //   1 = accept
 708 //   0 = reject
 709 //  -1 = fake accept
 710 {
 711         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 712         float flood;
 713         var .float flood_field;
 714         entity head;
 715         float ret;
 716         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 717
 718         if(!teamsay && !privatesay)
 719                 if(substring(msgin, 0, 1) == " ")
 720                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 721
 722         msgin = formatmessage(msgin);
 723
 724         if(source.classname != "player")
 725                 colorstr = "^0"; // black for spectators
 726         else if(teamplay)
 727                 colorstr = Team_ColorCode(source.team);
 728         else
 729         {
 730                 colorstr = "";
 731                 teamsay = FALSE;
 732         }
 733
 734         if(intermission_running)
 735                 teamsay = FALSE;
 736
 737         if(msgin != "")
 738                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 739
 740         /*
 741          * using bprint solves this... me stupid
 742         // how can we prevent the message from appearing in a listen server?
 743         // for now, just give "say" back and only handle say_team
 744         if(!teamsay)
 745         {
 746                 clientcommand(self, strcat("say ", msgin));
 747                 return;
 748         }
 749         */
 750
 751         if(autocvar_g_chat_teamcolors)
 752                 namestr = playername(source);
 753         else
 754                 namestr = source.netname;
 755
 756         if(msgin != "")
 757         {
 758                 if(privatesay)
 759                 {
 760                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 761                         privatemsgprefixlen = strlen(msgstr);
 762                         msgstr = strcat(msgstr, msgin);
 763                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 764                         if(autocvar_g_chat_teamcolors)
 765                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 766                         else
 767                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 768                 }
 769                 else if(teamsay)
 770                 {
 771                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 772                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 773                 }
 774                 else
 775                 {
 776                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 777                         cmsgstr = "";
 778                 }
 779                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 780         }
 781         else
 782         {
 783                 msgstr = cmsgstr = "";
 784         }
 785
 786         fullmsgstr = msgstr;
 787         fullcmsgstr = cmsgstr;
 788
 789         // FLOOD CONTROL
 790         flood = 0;
 791         flood_field = floodcontrol_chat;
 792         if(floodcontrol)
 793         {
 794                 float flood_spl;
 795                 float flood_burst;
 796                 float flood_lmax;
 797                 float lines;
 798                 if(privatesay)
 799                 {
 800                         flood_spl = autocvar_g_chat_flood_spl_tell;
 801                         flood_burst = autocvar_g_chat_flood_burst_tell;
 802                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 803                         flood_field = floodcontrol_chattell;
 804                 }
 805                 else if(teamsay)
 806                 {
 807                         flood_spl = autocvar_g_chat_flood_spl_team;
 808                         flood_burst = autocvar_g_chat_flood_burst_team;
 809                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 810                         flood_field = floodcontrol_chatteam;
 811                 }
 812                 else
 813                 {
 814                         flood_spl = autocvar_g_chat_flood_spl;
 815                         flood_burst = autocvar_g_chat_flood_burst;
 816                         flood_lmax = autocvar_g_chat_flood_lmax;
 817                         flood_field = floodcontrol_chat;
 818                 }
 819                 flood_burst = max(0, flood_burst - 1);
 820                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 821
 822                 // do flood control for the default line size
 823                 if(msgstr != "")
 824                 {
 825                         getWrappedLine_remaining = msgstr;
 826                         msgstr = "";
 827                         lines = 0;
 828                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 829                         {
 830                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 831                                 ++lines;
 832                         }
 833                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 834
 835                         if(getWrappedLine_remaining != "")
 836                         {
 837                                 msgstr = strcat(msgstr, "\n");
 838                                 flood = 2;
 839                         }
 840
 841                         if(time >= source.flood_field)
 842                         {
 843                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 844                         }
 845                         else
 846                         {
 847                                 flood = 1;
 848                                 msgstr = fullmsgstr;
 849                         }
 850                 }
 851                 else
 852                 {
 853                         if(time >= source.flood_field)
 854                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 855                         else
 856                                 flood = 1;
 857                 }
 858
 859                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 860                         source.flood_field = flood = 0;
 861         }
 862
 863         if(flood == 2) // cannot happen for empty msgstr
 864         {
 865                 if(autocvar_g_chat_flood_notify_flooder)
 866                 {
 867                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 868                         sourcecmsgstr = "";
 869                 }
 870                 else
 871                 {
 872                         sourcemsgstr = fullmsgstr;
 873                         sourcecmsgstr = fullcmsgstr;
 874                 }
 875                 cmsgstr = "";
 876         }
 877         else
 878         {
 879                 sourcemsgstr = msgstr;
 880                 sourcecmsgstr = cmsgstr;
 881         }
 882
 883         if(!privatesay)
 884         if(source.classname != "player")
 885         {
 886                 if not(intermission_running)
 887                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 888                                 teamsay = -1; // spectators
 889         }
 890
 891         if(flood)
 892                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 893
 894         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 895         if(privatesay)
 896                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 897
 898         if(source.muted)
 899         {
 900                 // always fake the message
 901                 ret = -1;
 902         }
 903         else if(flood == 1)
 904         {
 905                 if(autocvar_g_chat_flood_notify_flooder)
 906                 {
 907                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 908                         ret = 0;
 909                 }
 910                 else
 911                         ret = -1;
 912         }
 913         else
 914         {
 915                 ret = 1;
 916         }
 917
 918         if(sourcemsgstr != "" && ret != 0)
 919         {
 920                 if(ret < 0) // faked message, because the player is muted
 921                 {
 922                         sprint(source, sourcemsgstr);
 923                         if(sourcecmsgstr != "" && !privatesay)
 924                                 centerprint(source, sourcecmsgstr);
 925                 }
 926                 else if(privatesay) // private message, between 2 people only, not sent to server console
 927                 {
 928                         sprint(source, sourcemsgstr);
 929                         sprint(privatesay, msgstr);
 930                         if(cmsgstr != "")
 931                                 centerprint(privatesay, cmsgstr);
 932                 }
 933                 else if(teamsay > 0) // team message, only sent to team mates
 934                 {
 935                         sprint(source, sourcemsgstr);
 936                         //print(msgstr); // send to server console too
 937                         if(sourcecmsgstr != "")
 938                                 centerprint(source, sourcecmsgstr);
 939                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 940                                 if(head != source)
 941                                 {
 942                                         sprint(head, msgstr);
 943                                         if(cmsgstr != "")
 944                                                 centerprint(head, cmsgstr);
 945                                 }
 946                 }
 947                 else if(teamsay < 0) // spectator message, only sent to spectators
 948                 {
 949                         sprint(source, sourcemsgstr);
 950                         //print(msgstr); // send to server console too
 951                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 952                                 if(head != source)
 953                                         sprint(head, msgstr);
 954                 }
 955                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 956                 {
 957                         sprint(source, sourcemsgstr);
 958                         //print(msgstr); // send to server console too
 959                         FOR_EACH_REALCLIENT(head)
 960                                 if(head != source)
 961                                         sprint(head, msgstr);
 962                 }
 963                 else
 964                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 965         }
 966
 967         return ret;
 968 }
 969
 970 float GetVoiceMessageVoiceType(string type)
 971 {
 972         if(type == "taunt")
 973                 return VOICETYPE_TAUNT;
 974         if(type == "teamshoot")
 975                 return VOICETYPE_LASTATTACKER;
 976         return VOICETYPE_TEAMRADIO;
 977 }
 978
 979 string allvoicesamples;
 980 .string GetVoiceMessageSampleField(string type)
 981 {
 982         GetPlayerSoundSampleField_notFound = 0;
 983         switch(type)
 984         {
 985 #define _VOICEMSG(m) case #m: return playersound_##m;
 986                 ALLVOICEMSGS
 987 #undef _VOICEMSG
 988         }
 989         GetPlayerSoundSampleField_notFound = 1;
 990         return playersound_taunt;
 991 }
 992
 993 .string GetPlayerSoundSampleField(string type)
 994 {
 995         GetPlayerSoundSampleField_notFound = 0;
 996         switch(type)
 997         {
 998 #define _VOICEMSG(m) case #m: return playersound_##m;
 999                 ALLPLAYERSOUNDS
1000 #undef _VOICEMSG
1001         }
1002         GetPlayerSoundSampleField_notFound = 1;
1003         return playersound_taunt;
1004 }
1005
1006 void PrecacheGlobalSound(string samplestring)
1007 {
1008         float n, i;
1009         tokenize_console(samplestring);
1010         n = stof(argv(1));
1011         if(n > 0)
1012         {
1013                 for(i = 1; i <= n; ++i)
1014                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1015         }
1016         else
1017         {
1018                 precache_sound(strcat(argv(0), ".wav"));
1019         }
1020 }
1021
1022 void PrecachePlayerSounds(string f)
1023 {
1024         float fh;
1025         string s;
1026         fh = fopen(f, FILE_READ);
1027         if(fh < 0)
1028                 return;
1029         while((s = fgets(fh)))
1030         {
1031                 if(tokenize_console(s) != 3)
1032                 {
1033                         dprint("Invalid sound info line: ", s, "\n");
1034                         continue;
1035                 }
1036                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1037         }
1038         fclose(fh);
1039
1040         if not(allvoicesamples)
1041         {
1042 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1043                 ALLVOICEMSGS
1044 #undef _VOICEMSG
1045                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1046         }
1047 }
1048
1049 void ClearPlayerSounds()
1050 {
1051 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1052         ALLPLAYERSOUNDS
1053         ALLVOICEMSGS
1054 #undef _VOICEMSG
1055 }
1056
1057 float LoadPlayerSounds(string f, float first)
1058 {
1059         float fh;
1060         string s;
1061         var .string field;
1062         fh = fopen(f, FILE_READ);
1063         if(fh < 0)
1064         {
1065                 dprint("Player sound file not found: ", f, "\n");
1066                 return 0;
1067         }
1068         while((s = fgets(fh)))
1069         {
1070                 if(tokenize_console(s) != 3)
1071                         continue;
1072                 field = GetPlayerSoundSampleField(argv(0));
1073                 if(GetPlayerSoundSampleField_notFound)
1074                         field = GetVoiceMessageSampleField(argv(0));
1075                 if(GetPlayerSoundSampleField_notFound)
1076                         continue;
1077                 if(self.field)
1078                         strunzone(self.field);
1079                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1080         }
1081         fclose(fh);
1082         return 1;
1083 }
1084
1085 .float modelindex_for_playersound;
1086 .float skin_for_playersound;
1087 void UpdatePlayerSounds()
1088 {
1089         if(self.modelindex == self.modelindex_for_playersound)
1090         if(self.skin == self.skin_for_playersound)
1091                 return;
1092         self.modelindex_for_playersound = self.modelindex;
1093         self.skin_for_playersound = self.skin;
1094         ClearPlayerSounds();
1095         LoadPlayerSounds("sound/player/default.sounds", 1);
1096         if(!autocvar_g_debug_defaultsounds)
1097                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1098                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1099 }
1100
1101 void FakeGlobalSound(string sample, float chan, float voicetype)
1102 {
1103         float n;
1104         float tauntrand;
1105
1106         if(sample == "")
1107                 return;
1108
1109         tokenize_console(sample);
1110         n = stof(argv(1));
1111         if(n > 0)
1112                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1113         else
1114                 sample = strcat(argv(0), ".wav"); // randomization
1115
1116         switch(voicetype)
1117         {
1118                 case VOICETYPE_LASTATTACKER_ONLY:
1119                         break;
1120                 case VOICETYPE_LASTATTACKER:
1121                         if(self.pusher)
1122                         {
1123                                 msg_entity = self;
1124                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1125                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1126                         }
1127                         break;
1128                 case VOICETYPE_TEAMRADIO:
1129                         msg_entity = self;
1130                         if(msg_entity.cvar_cl_voice_directional == 1)
1131                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1132                         else
1133                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1134                         break;
1135                 case VOICETYPE_AUTOTAUNT:
1136                         if(!sv_autotaunt)
1137                                 break;
1138                         if(!sv_taunt)
1139                                 break;
1140                         if(sv_gentle)
1141                                 break;
1142                         tauntrand = random();
1143                         msg_entity = self;
1144                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1145                         {
1146                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1147                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1148                                 else
1149                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1150                         }
1151                         break;
1152                 case VOICETYPE_TAUNT:
1153                         if(self.classname == "player")
1154                                 if(self.deadflag == DEAD_NO)
1155                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1156                         if(!sv_taunt)
1157                                 break;
1158                         if(sv_gentle)
1159                                 break;
1160                         msg_entity = self;
1161                         if (msg_entity.cvar_cl_voice_directional >= 1)
1162                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1163                         else
1164                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1165                         break;
1166                 case VOICETYPE_PLAYERSOUND:
1167                         msg_entity = self;
1168                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1169                         break;
1170                 default:
1171                         backtrace("Invalid voice type!");
1172                         break;
1173         }
1174 }
1175
1176 void GlobalSound(string sample, float chan, float voicetype)
1177 {
1178         float n;
1179         float tauntrand;
1180
1181         if(sample == "")
1182                 return;
1183
1184         tokenize_console(sample);
1185         n = stof(argv(1));
1186         if(n > 0)
1187                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1188         else
1189                 sample = strcat(argv(0), ".wav"); // randomization
1190
1191         switch(voicetype)
1192         {
1193                 case VOICETYPE_LASTATTACKER_ONLY:
1194                         if(self.pusher)
1195                         {
1196                                 msg_entity = self.pusher;
1197                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1198                                 {
1199                                         if(msg_entity.cvar_cl_voice_directional == 1)
1200                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1201                                         else
1202                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1203                                 }
1204                         }
1205                         break;
1206                 case VOICETYPE_LASTATTACKER:
1207                         if(self.pusher)
1208                         {
1209                                 msg_entity = self.pusher;
1210                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1211                                 {
1212                                         if(msg_entity.cvar_cl_voice_directional == 1)
1213                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1214                                         else
1215                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1216                                 }
1217                                 msg_entity = self;
1218                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1219                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1220                         }
1221                         break;
1222                 case VOICETYPE_TEAMRADIO:
1223                         FOR_EACH_REALCLIENT(msg_entity)
1224                                 if(!teamplay || msg_entity.team == self.team)
1225                                 {
1226                                         if(msg_entity.cvar_cl_voice_directional == 1)
1227                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1228                                         else
1229                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1230                                 }
1231                         break;
1232                 case VOICETYPE_AUTOTAUNT:
1233                         if(!sv_autotaunt)
1234                                 break;
1235                         if(!sv_taunt)
1236                                 break;
1237                         if(sv_gentle)
1238                                 break;
1239                         tauntrand = random();
1240                         FOR_EACH_REALCLIENT(msg_entity)
1241                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1242                                 {
1243                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1244                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1245                                         else
1246                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1247                                 }
1248                         break;
1249                 case VOICETYPE_TAUNT:
1250                         if(self.classname == "player")
1251                                 if(self.deadflag == DEAD_NO)
1252                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1253                         if(!sv_taunt)
1254                                 break;
1255                         if(sv_gentle)
1256                                 break;
1257                         FOR_EACH_REALCLIENT(msg_entity)
1258                         {
1259                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1260                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1261                                 else
1262                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1263                         }
1264                         break;
1265                 case VOICETYPE_PLAYERSOUND:
1266                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1267                         break;
1268                 default:
1269                         backtrace("Invalid voice type!");
1270                         break;
1271         }
1272 }
1273
1274 void PlayerSound(.string samplefield, float chan, float voicetype)
1275 {
1276         GlobalSound(self.samplefield, chan, voicetype);
1277 }
1278
1279 void VoiceMessage(string type, string msg)
1280 {
1281         var .string sample;
1282         float voicetype, ownteam;
1283         float flood;
1284         sample = GetVoiceMessageSampleField(type);
1285
1286         if(GetPlayerSoundSampleField_notFound)
1287         {
1288                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1289                 return;
1290         }
1291
1292         voicetype = GetVoiceMessageVoiceType(type);
1293         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1294
1295         flood = Say(self, ownteam, world, msg, 1);
1296
1297         if (flood > 0)
1298                 GlobalSound(self.sample, CH_VOICE, voicetype);
1299         else if (flood < 0)
1300                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1301 }
1302
1303 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1304 {
1305 //      show_message
1306 //      0 (00) automove centerprint, admin message
1307 //      1 (01) automove centerprint, no admin message
1308 //      2 (10) no centerprint, admin message
1309 //      3 (11) no centerprint, no admin message
1310
1311         float lockteams_backup;
1312
1313         lockteams_backup = lockteams;  // backup any team lock
1314
1315         lockteams = 0;  // disable locked teams
1316
1317         TeamchangeFrags(client);  // move the players frags
1318         SetPlayerColors(client, team_colour - 1);  // set the players colour
1319         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1320
1321         lockteams = lockteams_backup;  // restore the team lock
1322
1323         LogTeamchange(client.playerid, client.team, type);
1324
1325         if not(show_message & 1) // admin message
1326                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1327
1328         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1329 }