qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.playermodel, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389 void freezetag_CheckWinner();
 390 void freezetag_Unfreeze();
 391
 392 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 393 {
 394         local float take, save, waves, sdelay, dh, da, j;
 395         vector v;
 396         float valid_damage_for_weaponstats;
 397
 398         dh = max(self.health, 0);
 399         da = max(self.armorvalue, 0);
 400
 401         if(!DEATH_ISSPECIAL(deathtype))
 402         {
 403                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 404                 if(self != attacker)
 405                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 406         }
 407
 408         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 409         {
 410                 // tuba causes blood to come out of the ears
 411                 vector ear1, ear2;
 412                 vector d;
 413                 float f;
 414                 ear1 = self.origin;
 415                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 416                 ear2 = ear1;
 417                 makevectors(self.angles);
 418                 ear1 += v_right * -10;
 419                 ear2 += v_right * +10;
 420                 d = inflictor.origin - self.origin;
 421                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 422                 force = v_right * vlen(force);
 423                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 424                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 425                 if(f > 0)
 426                 {
 427                         hitloc = ear1;
 428                         force = force * -1;
 429                 }
 430                 else
 431                 {
 432                         hitloc = ear2;
 433                         // force is already good
 434                 }
 435         }
 436         else
 437                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 438
 439         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 440                 return;
 441
 442         if (!g_minstagib)
 443         {
 444                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 445                 take = v_x;
 446                 save = v_y;
 447         }
 448         else
 449         {
 450                 save = 0;
 451                 take = damage;
 452         }
 453
 454         frag_inflictor = inflictor;
 455         frag_attacker = attacker;
 456         frag_target = self;
 457         damage_take = take;
 458         damage_save = save;
 459         damage_force = force;
 460         MUTATOR_CALLHOOK(PlayerDamage);
 461         take = bound(0, damage_take, self.health);
 462         save = bound(0, damage_save, self.armorvalue);
 463
 464         if(sound_allowed(MSG_BROADCAST, attacker))
 465         {
 466                 if (save > 10)
 467                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 468                 else if (take > 30)
 469                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 470                 else if (take > 10)
 471                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 472         }
 473
 474         if (take > 50)
 475                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 476         if (take > 100)
 477                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 478
 479         if (time >= self.spawnshieldtime)
 480         {
 481                 if (!(self.flags & FL_GODMODE))
 482                 {
 483                         self.armorvalue = self.armorvalue - save;
 484                         self.health = self.health - take;
 485                         // pause regeneration for 5 seconds
 486                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 487
 488                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 489                         {
 490                                 self.pain_finished = time + 0.5;        //Supajoe
 491
 492                                 if(sv_gentle < 1) {
 493                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 494                                         {
 495                                                 if (random() > 0.5)
 496                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 497                                                 else
 498                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 499                                         }
 500
 501                                         if(sound_allowed(MSG_BROADCAST, attacker))
 502                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 503                                         if(self.health > 1)
 504                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 505                                         {
 506                                                 if(deathtype == DEATH_FALL)
 507                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else if(self.health > 75) // TODO make a "gentle" version?
 509                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                                 else if(self.health > 50)
 511                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 512                                                 else if(self.health > 25)
 513                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 514                                                 else
 515                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 516                                         }
 517                                 }
 518
 519                                 // throw off bot aim temporarily
 520                                 local float shake;
 521                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 522                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 523                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 524                         }
 525                 }
 526                 else
 527                         self.max_armorvalue += (save + take);
 528         }
 529         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 530         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 531         self.dmg_inflictor = inflictor;
 532
 533         if(attacker == self)
 534         {
 535                 // don't reset pushltime for self damage as it may be an attempt to
 536                 // escape a lava pit or similar
 537                 //self.pushltime = 0;
 538         }
 539         else if(attacker.classname == "player" || attacker.classname == "gib")
 540         {
 541                 self.pusher = attacker;
 542                 self.pushltime = time + cvar("g_maxpushtime");
 543         }
 544         else if(time < self.pushltime)
 545         {
 546                 attacker = self.pusher;
 547                 self.pushltime = max(self.pushltime, time + 0.6);
 548         }
 549         else
 550                 self.pushltime = 0;
 551
 552         valid_damage_for_weaponstats = 0;
 553         if(clienttype(self) == CLIENTTYPE_REAL)
 554         if(clienttype(attacker) == CLIENTTYPE_REAL)
 555         if(self != attacker)
 556         if(!DEATH_ISSPECIAL(deathtype))
 557         if(IsDifferentTeam(self, attacker))
 558                 valid_damage_for_weaponstats = 1;
 559
 560         if(valid_damage_for_weaponstats)
 561         {
 562                 dh = dh - max(self.health, 0);
 563                 da = da - max(self.armorvalue, 0);
 564                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 565         }
 566
 567         if (self.health < 1)
 568         {
 569                 float defer_ClientKill_Now_TeamChange;
 570                 defer_ClientKill_Now_TeamChange = FALSE;
 571
 572                 if(valid_damage_for_weaponstats)
 573                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 574
 575                 if(sv_gentle < 1) // TODO make a "gentle" version?
 576                 if(sound_allowed(MSG_BROADCAST, attacker))
 577                 {
 578                         if(deathtype == DEATH_DROWN)
 579                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 580                         else
 581                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 582                 }
 583
 584                 // get rid of kill indicator
 585                 if(self.killindicator)
 586                 {
 587                         remove(self.killindicator);
 588                         self.killindicator = world;
 589                         if(self.killindicator_teamchange)
 590                                 defer_ClientKill_Now_TeamChange = TRUE;
 591
 592                         if(self.classname == "body")
 593                         if(deathtype == DEATH_KILL)
 594                         {
 595                                 // for the lemmings fans, a small harmless explosion
 596                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 597                         }
 598                 }
 599
 600                 if(!g_freezetag)
 601                 {
 602                         // become fully visible
 603                         self.alpha = 1;
 604                         // clear selected player display
 605                         ClearSelectedPlayer();
 606                         // throw a weapon
 607                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 608                 }
 609
 610                 // print an obituary message
 611                 Obituary (attacker, inflictor, self, deathtype);
 612                 race_PreDie();
 613                 DropAllRunes(self);
 614
 615                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 616                 {
 617                         PutClientInServer();
 618                         count_alive_players(); // re-count players
 619                         freezetag_CheckWinner();
 620                         return;
 621                 }
 622
 623                 frag_attacker = attacker;
 624                 frag_inflictor = inflictor;
 625                 frag_target = self;
 626                 MUTATOR_CALLHOOK(PlayerDies);
 627
 628                 if(g_freezetag)
 629         {
 630             if(deathtype != DEATH_KILL || attacker == self)
 631                 return;
 632             else // team change or kill trigger
 633                 freezetag_Unfreeze(); // remove all ice blocks
 634         }
 635
 636                 if(self.flagcarried)
 637                 {
 638                         if(attacker.classname != "player" && attacker.classname != "gib")
 639                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 640                         else if(attacker.team == self.team)
 641                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 642                         else
 643                                 DropFlag(self.flagcarried, world, attacker);
 644                 }
 645                 if(self.ballcarried)
 646                         DropBall(self.ballcarried, self.origin, self.velocity);
 647                 Portal_ClearAllLater(self);
 648                 // clear waypoints
 649                 WaypointSprite_PlayerDead();
 650                 // make the corpse upright (not tilted)
 651                 self.angles_x = 0;
 652                 self.angles_z = 0;
 653                 // don't spin
 654                 self.avelocity = '0 0 0';
 655                 // view from the floor
 656                 self.view_ofs = '0 0 -8';
 657                 // toss the corpse
 658                 self.movetype = MOVETYPE_TOSS;
 659                 // shootable corpse
 660                 self.solid = SOLID_CORPSE;
 661                 self.ballistics_density = cvar("g_ballistics_density_corpse");
 662                 // don't stick to the floor
 663                 self.flags &~= FL_ONGROUND;
 664                 // dying animation
 665                 self.deadflag = DEAD_DYING;
 666                 // when to allow respawn
 667                 sdelay = 0;
 668                 waves = 0;
 669                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 670                 if(!sdelay)
 671                         sdelay = cvar("g_respawn_delay");
 672                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 673                 if(!waves)
 674                         waves = cvar("g_respawn_waves");
 675                 if(waves)
 676                         self.death_time = ceil((time + sdelay) / waves) * waves;
 677                 else
 678                         self.death_time = time + sdelay;
 679                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 680                         self.respawn_countdown = 10; // first number to count down from is 10
 681                 else
 682                         self.respawn_countdown = -1; // do not count down
 683                 if (random() < 0.5)
 684                 {
 685                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 686                         self.dead_frame = self.anim_dead1_x;
 687                 }
 688                 else
 689                 {
 690                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 691                         self.dead_frame = self.anim_dead2_x;
 692                 }
 693                 // set damage function to corpse damage
 694                 self.event_damage = PlayerCorpseDamage;
 695                 // call the corpse damage function just in case it wants to gib
 696                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 697                 // set up to fade out later
 698                 SUB_SetFade (self, time + 6 + random (), 1);
 699
 700                 if(clienttype(self) == CLIENTTYPE_REAL)
 701                 {
 702                         self.fixangle = TRUE;
 703                         //msg_entity = self;
 704                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 705                         //WriteAngle (MSG_ONE, self.v_angle_x);
 706                         //WriteAngle (MSG_ONE, self.v_angle_y);
 707                         //WriteAngle (MSG_ONE, 80);
 708                 }
 709
 710                 if(g_arena)
 711                         Spawnqueue_Unmark(self);
 712
 713                 if(defer_ClientKill_Now_TeamChange)
 714                         ClientKill_Now_TeamChange();
 715
 716                 if(sv_gentle > 0 || cvar("ekg")) {
 717                         // remove corpse
 718                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 719                 }
 720
 721                 // reset fields the weapons may use just in case
 722         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 723                 {
 724             weapon_action(j, WR_RESETPLAYER);
 725                         ATTACK_FINISHED_FOR(self, j) = 0;
 726                 }
 727         }
 728 }
 729
 730 float UpdateSelectedPlayer_countvalue(float v)
 731 {
 732         return max(0, (v - 1.0) / 0.5);
 733 }
 734
 735 // returns: -2 if no hit, otherwise cos of the angle
 736 // uses the global v_angle
 737 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 738 {
 739         vector so, d;
 740         float c;
 741
 742         if(p == self)
 743                 return -2;
 744
 745         if(p.deadflag)
 746                 return -2;
 747
 748         so = self.origin + self.view_ofs;
 749         d = p.origin - so;
 750
 751         // misaimed?
 752         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 753                 return -2;
 754
 755         // now find the cos of the angle...
 756         c = normalize(d) * v_forward;
 757
 758         if(c <= mincosangle)
 759                 return -2;
 760
 761         // not visible in any way? forget it
 762         if(!checkpvs(so, p))
 763                 return -2;
 764
 765         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 766         if(trace_fraction < 1)
 767                 return -2;
 768
 769         return c;
 770 }
 771
 772 void ClearSelectedPlayer()
 773 {
 774         if(self.selected_player)
 775         {
 776                 centerprint_expire(self, CENTERPRIO_POINT);
 777                 self.selected_player = world;
 778                 self.selected_player_display_needs_update = FALSE;
 779         }
 780 }
 781
 782 void UpdateSelectedPlayer()
 783 {
 784         entity selected;
 785         float selected_score;
 786         selected = world;
 787         selected_score = 0.95; // 18 degrees
 788
 789         if(!cvar("sv_allow_shownames"))
 790                 return;
 791
 792         if(clienttype(self) != CLIENTTYPE_REAL)
 793                 return;
 794
 795         if(self.cvar_cl_shownames == 0)
 796                 return;
 797
 798         if(self.cvar_cl_shownames == 1 && !teams_matter)
 799                 return;
 800
 801         makevectors(self.v_angle); // sets v_forward
 802
 803         // 1. cursor trace is always right
 804         WarpZone_crosshair_trace(self);
 805         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 806         {
 807                 selected = trace_ent;
 808         }
 809         else
 810         {
 811                 // 2. if we don't have a cursor trace, find the player which is least
 812                 //    mis-aimed at
 813                 entity p;
 814                 FOR_EACH_PLAYER(p)
 815                 {
 816                         float c;
 817                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 818                         if(c >= -1)
 819                         {
 820                                 selected = p;
 821                                 selected_score = c;
 822                         }
 823                 }
 824         }
 825
 826         if(selected)
 827         {
 828                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 829         }
 830         else
 831         {
 832                 if(time < self.selected_player_display_timeout)
 833                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 834                                 selected = self.selected_player;
 835         }
 836
 837         if(selected)
 838         {
 839                 if(selected == self.selected_player)
 840                 {
 841                         float save;
 842                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 843                         self.selected_player_count = self.selected_player_count + frametime;
 844                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 845                         {
 846                                 string namestr, healthstr;
 847                                 namestr = playername(selected);
 848                                 if(teams_matter)
 849                                 {
 850                                         healthstr = ftos(floor(selected.health));
 851                                         if(self.team == selected.team)
 852                                         {
 853                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 854                                                 self.selected_player_display_needs_update = TRUE;
 855                                         }
 856                                 }
 857                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 858                         }
 859                 }
 860                 else
 861                 {
 862                         ClearSelectedPlayer();
 863                         self.selected_player = selected;
 864                         self.selected_player_time = time;
 865                         self.selected_player_count = 0;
 866                         self.selected_player_display_needs_update = FALSE;
 867                 }
 868         }
 869         else
 870         {
 871                 ClearSelectedPlayer();
 872         }
 873
 874         if(self.selected_player)
 875                 self.last_selected_player = self.selected_player;
 876 }
 877
 878 .float muted; // to be used by prvm_edictset server playernumber muted 1
 879 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 880 // message "": do not say, just test flood control
 881 // return value:
 882 //   1 = accept
 883 //   0 = reject
 884 //  -1 = fake accept
 885 {
 886         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 887         float flood, privatemsgprefixlen;
 888         var .float flood_field;
 889         entity head;
 890         float ret;
 891
 892         if(Ban_MaybeEnforceBan(source))
 893                 return 0;
 894
 895         if(!teamsay && !privatesay)
 896                 if(substring(msgin, 0, 1) == " ")
 897                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 898
 899         msgin = formatmessage(msgin);
 900
 901         if(source.classname != "player")
 902                 colorstr = "^0"; // black for spectators
 903         else if(teams_matter)
 904                 colorstr = Team_ColorCode(source.team);
 905         else
 906                 teamsay = FALSE;
 907
 908         if(intermission_running)
 909                 teamsay = FALSE;
 910
 911         if(msgin != "")
 912                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 913
 914         /*
 915          * using bprint solves this... me stupid
 916         // how can we prevent the message from appearing in a listen server?
 917         // for now, just give "say" back and only handle say_team
 918         if(!teamsay)
 919         {
 920                 clientcommand(self, strcat("say ", msgin));
 921                 return;
 922         }
 923         */
 924
 925         if(cvar("g_chat_teamcolors"))
 926                 namestr = playername(source);
 927         else
 928                 namestr = source.netname;
 929
 930         if(msgin != "")
 931         {
 932                 if(privatesay)
 933                 {
 934                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 935                         privatemsgprefixlen = strlen(msgstr);
 936                         msgstr = strcat(msgstr, msgin);
 937                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 938                         if(cvar("g_chat_teamcolors"))
 939                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 940                         else
 941                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 942                 }
 943                 else if(teamsay)
 944                 {
 945                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 946                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 947                 }
 948                 else
 949                 {
 950                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 951                         cmsgstr = "";
 952                 }
 953                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 954         }
 955         else
 956         {
 957                 msgstr = cmsgstr = "";
 958         }
 959
 960         fullmsgstr = msgstr;
 961         fullcmsgstr = cmsgstr;
 962
 963         // FLOOD CONTROL
 964         flood = 0;
 965         if(floodcontrol)
 966         {
 967                 float flood_spl;
 968                 float flood_burst;
 969                 float flood_lmax;
 970                 float lines;
 971                 if(privatesay)
 972                 {
 973                         flood_spl = cvar("g_chat_flood_spl_tell");
 974                         flood_burst = cvar("g_chat_flood_burst_tell");
 975                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 976                         flood_field = floodcontrol_chattell;
 977                 }
 978                 else if(teamsay)
 979                 {
 980                         flood_spl = cvar("g_chat_flood_spl_team");
 981                         flood_burst = cvar("g_chat_flood_burst_team");
 982                         flood_lmax = cvar("g_chat_flood_lmax_team");
 983                         flood_field = floodcontrol_chatteam;
 984                 }
 985                 else
 986                 {
 987                         flood_spl = cvar("g_chat_flood_spl");
 988                         flood_burst = cvar("g_chat_flood_burst");
 989                         flood_lmax = cvar("g_chat_flood_lmax");
 990                         flood_field = floodcontrol_chat;
 991                 }
 992                 flood_burst = max(0, flood_burst - 1);
 993                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 994
 995                 // do flood control for the default line size
 996                 if(msgstr != "")
 997                 {
 998                         getWrappedLine_remaining = msgstr;
 999                         msgstr = "";
1000                         lines = 0;
1001                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1002                         {
1003                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1004                                 ++lines;
1005                         }
1006                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1007
1008                         if(getWrappedLine_remaining != "")
1009                         {
1010                                 msgstr = strcat(msgstr, "\n");
1011                                 flood = 2;
1012                         }
1013
1014                         if(time >= source.flood_field)
1015                         {
1016                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1017                         }
1018                         else
1019                         {
1020                                 flood = 1;
1021                                 msgstr = fullmsgstr;
1022                         }
1023                 }
1024                 else
1025                 {
1026                         if(time >= source.flood_field)
1027                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1028                         else
1029                                 flood = 1;
1030                 }
1031
1032                 if (timeoutStatus == 2) //when game is paused, no flood protection
1033                         source.flood_field = flood = 0;
1034         }
1035
1036         if(flood == 2) // cannot happen for empty msgstr
1037         {
1038                 if(cvar("g_chat_flood_notify_flooder"))
1039                 {
1040                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1041                         sourcecmsgstr = "";
1042                 }
1043                 else
1044                 {
1045                         sourcemsgstr = fullmsgstr;
1046                         sourcecmsgstr = fullcmsgstr;
1047                 }
1048                 cmsgstr = "";
1049         }
1050         else
1051         {
1052                 sourcemsgstr = msgstr;
1053                 sourcecmsgstr = cmsgstr;
1054         }
1055
1056         if(!privatesay)
1057         if(source.classname != "player")
1058         {
1059                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1060                         teamsay = -1; // spectators
1061         }
1062
1063         if(flood)
1064                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1065
1066         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1067         if(privatesay)
1068                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1069
1070         if(source.muted)
1071         {
1072                 // always fake the message
1073                 ret = -1;
1074         }
1075         else if(flood == 1)
1076         {
1077                 if(cvar("g_chat_flood_notify_flooder"))
1078                 {
1079                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1080                         ret = 0;
1081                 }
1082                 else
1083                         ret = -1;
1084         }
1085         else
1086         {
1087                 ret = 1;
1088         }
1089
1090         if(sourcemsgstr != "" && ret != 0)
1091         {
1092                 if(ret < 0) // fake
1093                 {
1094                         sprint(source, sourcemsgstr);
1095                         if(sourcecmsgstr != "" && !privatesay)
1096                                 centerprint(source, sourcecmsgstr);
1097                 }
1098                 else if(privatesay)
1099                 {
1100                         sprint(source, sourcemsgstr);
1101                         sprint(privatesay, msgstr);
1102                         if(cmsgstr != "")
1103                                 centerprint(privatesay, cmsgstr);
1104                 }
1105                 else if(teamsay > 0)
1106                 {
1107                         sprint(source, sourcemsgstr);
1108                         if(sourcecmsgstr != "")
1109                                 centerprint(source, sourcecmsgstr);
1110                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1111                                 if(head != source)
1112                                 {
1113                                         sprint(head, msgstr);
1114                                         if(cmsgstr != "")
1115                                                 centerprint(head, cmsgstr);
1116                                 }
1117                 }
1118                 else if(teamsay < 0)
1119                 {
1120                         sprint(source, sourcemsgstr);
1121                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1122                                 if(head != source)
1123                                         sprint(head, msgstr);
1124                 }
1125                 else if(sourcemsgstr != msgstr)
1126                 {
1127                         sprint(source, sourcemsgstr);
1128                         FOR_EACH_REALCLIENT(head)
1129                                 if(head != source)
1130                                         sprint(head, msgstr);
1131                 }
1132                 else
1133                         bprint(msgstr);
1134         }
1135
1136         return ret;
1137 }
1138
1139 float GetVoiceMessageVoiceType(string type)
1140 {
1141         if(type == "taunt")
1142                 return VOICETYPE_TAUNT;
1143         if(type == "teamshoot")
1144                 return VOICETYPE_LASTATTACKER;
1145         return VOICETYPE_TEAMRADIO;
1146 }
1147
1148 string allvoicesamples;
1149 float GetPlayerSoundSampleField_notFound;
1150 float GetPlayerSoundSampleField_fixed;
1151 .string GetVoiceMessageSampleField(string type)
1152 {
1153         GetPlayerSoundSampleField_notFound = 0;
1154         GetPlayerSoundSampleField_fixed = 0;
1155         switch(type)
1156         {
1157 #define _VOICEMSG(m) case #m: return playersound_##m;
1158                 ALLVOICEMSGS
1159 #undef _VOICEMSG
1160         }
1161         GetPlayerSoundSampleField_notFound = 1;
1162         return playersound_taunt;
1163 }
1164
1165 .string GetPlayerSoundSampleField(string type)
1166 {
1167         GetPlayerSoundSampleField_notFound = 0;
1168         GetPlayerSoundSampleField_fixed = 0;
1169         switch(type)
1170         {
1171 #define _VOICEMSG(m) case #m: return playersound_##m;
1172                 ALLPLAYERSOUNDS
1173 #undef _VOICEMSG
1174         }
1175         GetPlayerSoundSampleField_notFound = 1;
1176         return playersound_taunt;
1177 }
1178
1179 void PrecacheGlobalSound(string samplestring)
1180 {
1181         float n, i;
1182         tokenize_console(samplestring);
1183         n = stof(argv(1));
1184         if(n > 0)
1185         {
1186                 for(i = 1; i <= n; ++i)
1187                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1188         }
1189         else
1190         {
1191                 precache_sound(strcat(argv(0), ".wav"));
1192         }
1193 }
1194
1195 void PrecachePlayerSounds(string f)
1196 {
1197         float fh;
1198         string s;
1199         fh = fopen(f, FILE_READ);
1200         if(fh < 0)
1201                 return;
1202         while((s = fgets(fh)))
1203         {
1204                 if(tokenize_console(s) != 3)
1205                 {
1206                         dprint("Invalid sound info line: ", s, "\n");
1207                         continue;
1208                 }
1209                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1210         }
1211         fclose(fh);
1212
1213         if not(allvoicesamples)
1214         {
1215 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1216                 ALLVOICEMSGS
1217 #undef _VOICEMSG
1218                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1219         }
1220 }
1221
1222 void ClearPlayerSounds()
1223 {
1224 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1225         ALLPLAYERSOUNDS
1226         ALLVOICEMSGS
1227 #undef _VOICEMSG
1228 }
1229
1230 void LoadPlayerSounds(string f, float first)
1231 {
1232         float fh;
1233         string s;
1234         var .string field;
1235         fh = fopen(f, FILE_READ);
1236         if(fh < 0)
1237         {
1238                 dprint("Player sound file not found: ", f, "\n");
1239                 return;
1240         }
1241         while((s = fgets(fh)))
1242         {
1243                 if(tokenize_console(s) != 3)
1244                         continue;
1245                 field = GetPlayerSoundSampleField(argv(0));
1246                 if(GetPlayerSoundSampleField_notFound)
1247                         field = GetVoiceMessageSampleField(argv(0));
1248                 if(GetPlayerSoundSampleField_notFound)
1249                         continue;
1250                 if(GetPlayerSoundSampleField_fixed)
1251                         if not(first)
1252                                 continue;
1253                 if(self.field)
1254                         strunzone(self.field);
1255                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1256         }
1257         fclose(fh);
1258 }
1259
1260 .float modelindex_for_playersound;
1261 .float skinindex_for_playersound;
1262 void UpdatePlayerSounds()
1263 {
1264         if(self.modelindex == self.modelindex_for_playersound)
1265         if(self.skinindex == self.skinindex_for_playersound)
1266                 return;
1267         self.modelindex_for_playersound = self.modelindex;
1268         self.skinindex_for_playersound = self.skinindex;
1269         ClearPlayerSounds();
1270         LoadPlayerSounds("sound/player/default.sounds", 1);
1271         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1272 }
1273
1274 void FakeGlobalSound(string sample, float chan, float voicetype)
1275 {
1276         float n;
1277         float tauntrand;
1278
1279         if(sample == "")
1280                 return;
1281
1282         tokenize_console(sample);
1283         n = stof(argv(1));
1284         if(n > 0)
1285                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1286         else
1287                 sample = strcat(argv(0), ".wav"); // randomization
1288
1289         switch(voicetype)
1290         {
1291                 case VOICETYPE_LASTATTACKER_ONLY:
1292                         break;
1293                 case VOICETYPE_LASTATTACKER:
1294                         if(self.pusher)
1295                         {
1296                                 msg_entity = self;
1297                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1298                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1299                         }
1300                         break;
1301                 case VOICETYPE_TEAMRADIO:
1302                         msg_entity = self;
1303                         if(msg_entity.cvar_cl_voice_directional == 1)
1304                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1305                         else
1306                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1307                         break;
1308                 case VOICETYPE_AUTOTAUNT:
1309                         if(!sv_autotaunt)
1310                                 break;
1311                         if(!sv_taunt)
1312                                 break;
1313                         if(sv_gentle)
1314                                 break;
1315                         tauntrand = random();
1316                         msg_entity = self;
1317                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1318                         {
1319                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1320                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1321                                 else
1322                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1323                         }
1324                         break;
1325                 case VOICETYPE_TAUNT:
1326                         if(self.classname == "player")
1327                                 if(self.deadflag == DEAD_NO)
1328                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1329                         if(!sv_taunt)
1330                                 break;
1331                         if(sv_gentle)
1332                                 break;
1333                         msg_entity = self;
1334                         if (msg_entity.cvar_cl_voice_directional >= 1)
1335                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1336                         else
1337                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1338                         break;
1339                 case VOICETYPE_PLAYERSOUND:
1340                         msg_entity = self;
1341                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1342                         break;
1343                 default:
1344                         backtrace("Invalid voice type!");
1345                         break;
1346         }
1347 }
1348
1349 void GlobalSound(string sample, float chan, float voicetype)
1350 {
1351         float n;
1352         float tauntrand;
1353
1354         if(sample == "")
1355                 return;
1356
1357         tokenize_console(sample);
1358         n = stof(argv(1));
1359         if(n > 0)
1360                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1361         else
1362                 sample = strcat(argv(0), ".wav"); // randomization
1363
1364         switch(voicetype)
1365         {
1366                 case VOICETYPE_LASTATTACKER_ONLY:
1367                         if(self.pusher)
1368                         {
1369                                 msg_entity = self.pusher;
1370                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1371                                 {
1372                                         if(msg_entity.cvar_cl_voice_directional == 1)
1373                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1374                                         else
1375                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1376                                 }
1377                         }
1378                         break;
1379                 case VOICETYPE_LASTATTACKER:
1380                         if(self.pusher)
1381                         {
1382                                 msg_entity = self.pusher;
1383                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1384                                 {
1385                                         if(msg_entity.cvar_cl_voice_directional == 1)
1386                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1387                                         else
1388                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1389                                 }
1390                                 msg_entity = self;
1391                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1392                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1393                         }
1394                         break;
1395                 case VOICETYPE_TEAMRADIO:
1396                         FOR_EACH_REALCLIENT(msg_entity)
1397                                 if(!teams_matter || msg_entity.team == self.team)
1398                                 {
1399                                         if(msg_entity.cvar_cl_voice_directional == 1)
1400                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1401                                         else
1402                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1403                                 }
1404                         break;
1405                 case VOICETYPE_AUTOTAUNT:
1406                         if(!sv_autotaunt)
1407                                 break;
1408                         if(!sv_taunt)
1409                                 break;
1410                         if(sv_gentle)
1411                                 break;
1412                         tauntrand = random();
1413                         FOR_EACH_REALCLIENT(msg_entity)
1414                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1415                                 {
1416                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1417                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1418                                         else
1419                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1420                                 }
1421                         break;
1422                 case VOICETYPE_TAUNT:
1423                         if(self.classname == "player")
1424                                 if(self.deadflag == DEAD_NO)
1425                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1426                         if(!sv_taunt)
1427                                 break;
1428                         if(sv_gentle)
1429                                 break;
1430                         FOR_EACH_REALCLIENT(msg_entity)
1431                         {
1432                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1433                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1434                                 else
1435                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1436                         }
1437                         break;
1438                 case VOICETYPE_PLAYERSOUND:
1439                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1440                         break;
1441                 default:
1442                         backtrace("Invalid voice type!");
1443                         break;
1444         }
1445 }
1446
1447 void PlayerSound(.string samplefield, float chan, float voicetype)
1448 {
1449         GlobalSound(self.samplefield, chan, voicetype);
1450 }
1451
1452 void VoiceMessage(string type, string msg)
1453 {
1454         var .string sample;
1455         float voicetype, ownteam;
1456         float flood;
1457         sample = GetVoiceMessageSampleField(type);
1458
1459         if(GetPlayerSoundSampleField_notFound)
1460         {
1461                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1462                 return;
1463         }
1464
1465         voicetype = GetVoiceMessageVoiceType(type);
1466         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1467
1468         flood = Say(self, ownteam, world, msg, 1);
1469
1470         if (flood > 0)
1471                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1472         else if (flood < 0)
1473                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1474 }
1475
1476 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1477 {
1478 //      show_message
1479 //      0 (00) automove centerprint, admin message
1480 //      1 (01) automove centerprint, no admin message
1481 //      2 (10) no centerprint, admin message
1482 //      3 (11) no centerprint, no admin message
1483
1484         float lockteams_backup;
1485
1486         lockteams_backup = lockteams;  // backup any team lock
1487
1488         lockteams = 0;  // disable locked teams
1489
1490         TeamchangeFrags(client);  // move the players frags
1491         SetPlayerColors(client, team_colour - 1);  // set the players colour
1492         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1493
1494         lockteams = lockteams_backup;  // restore the team lock
1495
1496         LogTeamchange(client.playerid, client.team, type);
1497
1498         if not(show_message & 1) // admin message
1499                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1500
1501         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1502 }