qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.damagedbycontents = oldself.damagedbycontents;
 156         self.angles = oldself.angles;
 157         self.avelocity = oldself.avelocity;
 158         self.classname = "body";
 159         self.damageforcescale = oldself.damageforcescale;
 160         self.effects = oldself.effects;
 161         self.glowmod = oldself.glowmod;
 162         self.event_damage = oldself.event_damage;
 163         self.animstate_startframe = oldself.animstate_startframe;
 164         self.animstate_numframes = oldself.animstate_numframes;
 165         self.animstate_framerate = oldself.animstate_framerate;
 166         self.animstate_starttime = oldself.animstate_starttime;
 167         self.animstate_endtime = oldself.animstate_endtime;
 168         self.animstate_override = oldself.animstate_override;
 169         self.animstate_looping = oldself.animstate_looping;
 170         self.dphitcontentsmask = oldself.dphitcontentsmask;
 171         self.death_time = oldself.death_time;
 172         self.frame = oldself.frame;
 173         self.pain_finished = oldself.pain_finished;
 174         self.health = oldself.health;
 175         self.armorvalue = oldself.armorvalue;
 176         self.armortype = oldself.armortype;
 177         self.model = oldself.model;
 178         self.modelindex = oldself.modelindex;
 179         self.skin = oldself.skin;
 180         self.species = oldself.species;
 181         self.movetype = oldself.movetype;
 182         self.solid = oldself.solid;
 183         self.ballistics_density = oldself.ballistics_density;
 184         self.takedamage = oldself.takedamage;
 185         self.customizeentityforclient = oldself.customizeentityforclient;
 186         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 187         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 188         if (keepvelocity == 1)
 189                 self.velocity = oldself.velocity;
 190         self.oldvelocity = self.velocity;
 191         self.alpha = oldself.alpha;
 192         self.fade_time = oldself.fade_time;
 193         self.fade_rate = oldself.fade_rate;
 194         //self.weapon = oldself.weapon;
 195         setorigin(self, oldself.origin);
 196         setsize(self, oldself.mins, oldself.maxs);
 197         self.prevorigin = oldself.origin;
 198         self.reset = SUB_Remove;
 199
 200         Drag_MoveDrag(oldself, self);
 201
 202         if(self.colormap <= maxclients && self.colormap > 0)
 203                 self.colormap = 1024 + oldself.clientcolors;
 204
 205         CSQCMODEL_AUTOINIT();
 206         self.CopyBody_nextthink = oldself.nextthink;
 207         self.CopyBody_think = oldself.think;
 208         self.nextthink = time;
 209         self.think = CopyBody_Think;
 210
 211         self = oldself;
 212 }
 213
 214 float player_getspecies()
 215 {
 216         float s;
 217         get_model_parameters(self.model, self.skin);
 218         s = get_model_parameters_species;
 219         get_model_parameters(string_null, 0);
 220         if(s < 0)
 221                 return SPECIES_HUMAN;
 222         return s;
 223 }
 224
 225 void player_setupanimsformodel()
 226 {
 227         // defaults for legacy .zym models without animinfo files
 228         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 229         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 230         self.anim_draw = animfixfps(self, '2 1 3');
 231         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 232         self.anim_duckwalk = animfixfps(self, '4 1 1');
 233         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 234         self.anim_duckidle = animfixfps(self, '6 1 1');
 235         self.anim_idle = animfixfps(self, '7 1 1');
 236         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 237         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 238         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 239         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 240         self.anim_taunt = animfixfps(self, '12 1 0.33');
 241         self.anim_run = animfixfps(self, '13 1 1');
 242         self.anim_runbackwards = animfixfps(self, '14 1 1');
 243         self.anim_strafeleft = animfixfps(self, '15 1 1');
 244         self.anim_straferight = animfixfps(self, '16 1 1');
 245         //self.anim_dead1 = animfixfps(self, '17 1 1');
 246         //self.anim_dead2 = animfixfps(self, '18 1 1');
 247         self.anim_forwardright = animfixfps(self, '19 1 1');
 248         self.anim_forwardleft = animfixfps(self, '20 1 1');
 249         self.anim_backright = animfixfps(self, '21 1 1');
 250         self.anim_backleft  = animfixfps(self, '22 1 1');
 251         self.anim_melee = animfixfps(self, '23 1 1');
 252         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 253         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 254         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 255         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 256         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 257         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 258         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 259         // TODO introspect models for finding right "fps" value (1/duration)
 260         // reset animstate now
 261         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 262 }
 263
 264 void player_anim (void)
 265 {
 266         updateanim(self);
 267         if (self.weaponentity)
 268                 updateanim(self.weaponentity);
 269
 270         if (self.deadflag != DEAD_NO)
 271                 return;
 272
 273         if (!self.animstate_override)
 274         {
 275                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 276                 {
 277                         if (self.crouch)
 278                         {
 279                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 280                                 {
 281                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 282                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 283                                         {
 284                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 285                                                 self.restart_jump = FALSE;
 286                                         }
 287                                 }
 288                         }
 289                         else
 290                         {
 291                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 292                 {
 293                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 294                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 295                     {
 296                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 297                         self.restart_jump = FALSE;
 298                     }
 299                 }
 300                         }
 301                 }
 302                 else if (self.crouch)
 303                 {
 304                         if (self.movement_x > 0 && self.movement_y == 0)
 305                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 306                         else if (self.movement_x < 0 && self.movement_y == 0)
 307                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 308                         else if (self.movement_x == 0 && self.movement_y > 0)
 309                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 310                         else if (self.movement_x == 0 && self.movement_y < 0)
 311                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 312                         else if (self.movement_x > 0 && self.movement_y > 0)
 313                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 314                         else if (self.movement_x > 0 && self.movement_y < 0)
 315                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 316                         else if (self.movement_x < 0 && self.movement_y > 0)
 317                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 318                         else if (self.movement_x < 0 && self.movement_y < 0)
 319                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 320                         else
 321                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 322                 }
 323                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 324                 {
 325                         if (self.movement_x > 0 && self.movement_y == 0)
 326                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 327                         else if (self.movement_x < 0 && self.movement_y == 0)
 328                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 329                         else if (self.movement_x == 0 && self.movement_y > 0)
 330                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 331                         else if (self.movement_x == 0 && self.movement_y < 0)
 332                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 333                         else if (self.movement_x > 0 && self.movement_y > 0)
 334                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 335                         else if (self.movement_x > 0 && self.movement_y < 0)
 336                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 337                         else if (self.movement_x < 0 && self.movement_y > 0)
 338                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 339                         else if (self.movement_x < 0 && self.movement_y < 0)
 340                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 341                         else
 342                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 343                 }
 344                 else
 345                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 346         }
 347
 348         if (self.weaponentity)
 349         if (!self.weaponentity.animstate_override)
 350                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 351 }
 352
 353 void SpawnThrownWeapon (vector org, float w)
 354 {
 355         if(g_minstagib)
 356         if(self.ammo_cells <= 0)
 357                 return;
 358
 359         if(g_pinata)
 360         {
 361                 float j;
 362                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 363                 {
 364                         if(WEPSET_CONTAINS_EW(self, j))
 365                                 if(W_IsWeaponThrowable(j))
 366                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 367                 }
 368         }
 369         else
 370         {
 371                 if(W_IsWeaponThrowable(self.weapon))
 372                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 373         }
 374 }
 375
 376 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 377 {
 378         float take, save;
 379         vector v;
 380         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 381
 382         // damage resistance (ignore most of the damage from a bullet or similar)
 383         damage = max(damage - 5, 1);
 384
 385         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 386         take = v_x;
 387         save = v_y;
 388
 389         if(sound_allowed(MSG_BROADCAST, attacker))
 390         {
 391                 if (save > 10)
 392                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 393                 else if (take > 30)
 394                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 395                 else if (take > 10)
 396                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 397         }
 398
 399         if (take > 50)
 400                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 401         if (take > 100)
 402                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 403
 404         if (!(self.flags & FL_GODMODE))
 405         {
 406                 self.armorvalue = self.armorvalue - save;
 407                 self.health = self.health - take;
 408                 // pause regeneration for 5 seconds
 409                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 410         }
 411         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 412         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 413         self.dmg_inflictor = inflictor;
 414
 415         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 416         {
 417                 // don't use any animations as a gib
 418                 self.frame = 0;
 419                 // view just above the floor
 420                 self.view_ofs = '0 0 4';
 421
 422                 Violence_GibSplash(self, 1, 1, attacker);
 423                 self.alpha = -1;
 424                 self.solid = SOLID_NOT; // restore later
 425                 self.takedamage = DAMAGE_NO; // restore later
 426         }
 427 }
 428
 429 void ClientKill_Now_TeamChange();
 430 void freezetag_CheckWinner();
 431
 432 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 433 {
 434         float take, save, waves, sdelay, dh, da, j;
 435         vector v;
 436         float valid_damage_for_weaponstats;
 437         float excess;
 438
 439         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 440                 return;
 441
 442         dh = max(self.health, 0);
 443         da = max(self.armorvalue, 0);
 444
 445         if(!DEATH_ISSPECIAL(deathtype))
 446         {
 447                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 448                 if(self != attacker)
 449                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 450         }
 451
 452         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 453         {
 454                 // tuba causes blood to come out of the ears
 455                 vector ear1, ear2;
 456                 vector d;
 457                 float f;
 458                 ear1 = self.origin;
 459                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 460                 ear2 = ear1;
 461                 makevectors(self.angles);
 462                 ear1 += v_right * -10;
 463                 ear2 += v_right * +10;
 464                 d = inflictor.origin - self.origin;
 465                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 466                 force = v_right * vlen(force);
 467                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 468                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 469                 if(f > 0)
 470                 {
 471                         hitloc = ear1;
 472                         force = force * -1;
 473                 }
 474                 else
 475                 {
 476                         hitloc = ear2;
 477                         // force is already good
 478                 }
 479         }
 480         else
 481                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 482
 483         if (!g_minstagib)
 484         {
 485                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 486                 take = v_x;
 487                 save = v_y;
 488         }
 489         else
 490         {
 491                 save = 0;
 492                 take = damage;
 493         }
 494
 495         frag_inflictor = inflictor;
 496         frag_attacker = attacker;
 497         frag_target = self;
 498         damage_take = take;
 499         damage_save = save;
 500         damage_force = force;
 501         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 502         take = bound(0, damage_take, self.health);
 503         save = bound(0, damage_save, self.armorvalue);
 504         excess = max(0, damage - take - save);
 505
 506         if(sound_allowed(MSG_BROADCAST, attacker))
 507         {
 508                 if (save > 10)
 509                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 510                 else if (take > 30)
 511                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 512                 else if (take > 10)
 513                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 514         }
 515
 516         if (take > 50)
 517                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 518         if (take > 100)
 519                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 520
 521         if (time >= self.spawnshieldtime)
 522         {
 523                 if (!(self.flags & FL_GODMODE))
 524                 {
 525                         self.armorvalue = self.armorvalue - save;
 526                         self.health = self.health - take;
 527                         // pause regeneration for 5 seconds
 528                         if(take)
 529                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 530
 531                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 532                         {
 533                                 self.pain_finished = time + 0.5;        //Supajoe
 534
 535                                 if(sv_gentle < 1) {
 536                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 537                                         {
 538                                                 if (!self.animstate_override)
 539                                                 {
 540                                                         if (random() > 0.5)
 541                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 542                                                         else
 543                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 544                                                 }
 545                                         }
 546
 547                                         if(sound_allowed(MSG_BROADCAST, attacker))
 548                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 549                                         if(self.health > 1)
 550                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 551                                         {
 552                                                 if(deathtype == DEATH_FALL)
 553                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 554                                                 else if(self.health > 75) // TODO make a "gentle" version?
 555                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 556                                                 else if(self.health > 50)
 557                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 558                                                 else if(self.health > 25)
 559                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 560                                                 else
 561                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 562                                         }
 563                                 }
 564
 565                                 // throw off bot aim temporarily
 566                                 float shake;
 567                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 568                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 569                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 570                         }
 571                 }
 572                 else
 573                         self.max_armorvalue += (save + take);
 574         }
 575         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 576         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 577         self.dmg_inflictor = inflictor;
 578
 579         if(attacker == self)
 580         {
 581                 // don't reset pushltime for self damage as it may be an attempt to
 582                 // escape a lava pit or similar
 583                 //self.pushltime = 0;
 584                 self.istypefrag = 0;
 585         }
 586         else if(attacker.classname == "player")
 587         {
 588                 self.pusher = attacker;
 589                 self.pushltime = time + autocvar_g_maxpushtime;
 590                 self.istypefrag = self.BUTTON_CHAT;
 591         }
 592         else if(time < self.pushltime)
 593         {
 594                 attacker = self.pusher;
 595                 self.pushltime = max(self.pushltime, time + 0.6);
 596         }
 597         else
 598         {
 599                 self.pushltime = 0;
 600                 self.istypefrag = 0;
 601         }
 602
 603         float abot, vbot, awep;
 604         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 605         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 606
 607         valid_damage_for_weaponstats = 0;
 608         awep = 0;
 609
 610         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 611         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 612         if(attacker && self != attacker)
 613         if(IsDifferentTeam(self, attacker))
 614         {
 615                 if(DEATH_ISSPECIAL(deathtype))
 616                         awep = attacker.weapon;
 617                 else
 618                         awep = DEATH_WEAPONOF(deathtype);
 619                 valid_damage_for_weaponstats = 1;
 620         }
 621
 622         if(valid_damage_for_weaponstats)
 623         {
 624                 dh = dh - max(self.health, 0);
 625                 da = da - max(self.armorvalue, 0);
 626                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 627         }
 628
 629         if (self.health < 1)
 630         {
 631                 float defer_ClientKill_Now_TeamChange;
 632                 defer_ClientKill_Now_TeamChange = FALSE;
 633
 634                 if(self.alivetime)
 635                 {
 636                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 637                         self.alivetime = 0;
 638                 }
 639
 640                 if(valid_damage_for_weaponstats)
 641                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 642
 643                 if(sv_gentle < 1) // TODO make a "gentle" version?
 644                 if(sound_allowed(MSG_BROADCAST, attacker))
 645                 {
 646                         if(deathtype == DEATH_DROWN)
 647                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 648                         else
 649                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 650                 }
 651
 652                 // get rid of kill indicator
 653                 if(self.killindicator)
 654                 {
 655                         remove(self.killindicator);
 656                         self.killindicator = world;
 657                         if(self.killindicator_teamchange)
 658                                 defer_ClientKill_Now_TeamChange = TRUE;
 659
 660                         if(self.classname == "body")
 661                         if(deathtype == DEATH_KILL)
 662                         {
 663                                 // for the lemmings fans, a small harmless explosion
 664                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 665                         }
 666                 }
 667
 668                 if(!g_freezetag)
 669                 {
 670                         // become fully visible
 671                         self.alpha = default_player_alpha;
 672                         // throw a weapon
 673                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 674                 }
 675
 676                 // print an obituary message
 677                 Obituary (attacker, inflictor, self, deathtype);
 678                 race_PreDie();
 679                 DropAllRunes(self);
 680
 681         // increment frag counter for used weapon type
 682         float w;
 683         w = DEATH_WEAPONOF(deathtype);
 684         if(WEP_VALID(w))
 685         if(accuracy_isgooddamage(attacker, self))
 686         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 687
 688                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 689                 {
 690                         PutClientInServer();
 691                         count_alive_players(); // re-count players
 692                         freezetag_CheckWinner();
 693                         return;
 694                 }
 695
 696                 frag_attacker = attacker;
 697                 frag_inflictor = inflictor;
 698                 frag_target = self;
 699                 MUTATOR_CALLHOOK(PlayerDies);
 700                 weapon_action(self.weapon, WR_PLAYERDEATH);
 701
 702                 RemoveGrapplingHook(self);
 703
 704                 if(self.flagcarried)
 705                 {
 706                         if(attacker.classname != "player")
 707                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 708                         else if(attacker.team == self.team)
 709                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 710                         else
 711                                 DropFlag(self.flagcarried, world, attacker);
 712                 }
 713                 Portal_ClearAllLater(self);
 714
 715                 if(clienttype(self) == CLIENTTYPE_REAL)
 716                 {
 717                         stuffcmd(self, "-zoom\n");
 718                         self.fixangle = TRUE;
 719                         //msg_entity = self;
 720                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 721                         //WriteAngle (MSG_ONE, self.v_angle_x);
 722                         //WriteAngle (MSG_ONE, self.v_angle_y);
 723                         //WriteAngle (MSG_ONE, 80);
 724                 }
 725
 726                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 727                         ClientKill_Now_TeamChange();
 728
 729                 if(g_arena)
 730                         Spawnqueue_Unmark(self);
 731
 732                 if(g_freezetag)
 733                         return;
 734
 735                 // when we get here, player actually dies
 736                 // clear waypoints (do this AFTER FreezeTag)
 737                 WaypointSprite_PlayerDead();
 738
 739                 // make the corpse upright (not tilted)
 740                 self.angles_x = 0;
 741                 self.angles_z = 0;
 742                 // don't spin
 743                 self.avelocity = '0 0 0';
 744                 // view from the floor
 745                 self.view_ofs = '0 0 -8';
 746                 // toss the corpse
 747                 self.movetype = MOVETYPE_TOSS;
 748                 // shootable corpse
 749                 self.solid = SOLID_CORPSE;
 750                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 751                 // don't stick to the floor
 752                 self.flags &~= FL_ONGROUND;
 753                 // dying animation
 754                 self.deadflag = DEAD_DYING;
 755                 // when to allow respawn
 756                 sdelay = 0;
 757                 waves = 0;
 758                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 759                 if(!sdelay)
 760                 {
 761                         if(g_cts)
 762                                 sdelay = 0; // no respawn delay in CTS
 763                         else
 764                                 sdelay = autocvar_g_respawn_delay;
 765                 }
 766                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 767                 if(!waves)
 768                         waves = autocvar_g_respawn_waves;
 769                 if(waves)
 770                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 771                 else
 772                         self.respawn_time = time + sdelay;
 773                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 774                         self.respawn_countdown = 10; // first number to count down from is 10
 775                 else
 776                         self.respawn_countdown = -1; // do not count down
 777                 self.death_time = time;
 778                 if (random() < 0.5)
 779                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 780                 else
 781                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 782                 if (self.maxs_z > 5)
 783                 {
 784                         self.maxs_z = 5;
 785                         setsize(self, self.mins, self.maxs);
 786                 }
 787                 // set damage function to corpse damage
 788                 self.event_damage = PlayerCorpseDamage;
 789                 // call the corpse damage function just in case it wants to gib
 790                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 791                 // set up to fade out later
 792                 SUB_SetFade (self, time + 6 + random (), 1);
 793
 794                 if(sv_gentle > 0 || autocvar_ekg) {
 795                         // remove corpse
 796                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 797                 }
 798
 799                 // reset fields the weapons may use just in case
 800                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 801                 {
 802                         weapon_action(j, WR_RESETPLAYER);
 803                         ATTACK_FINISHED_FOR(self, j) = 0;
 804                 }
 805         }
 806 }
 807
 808 .float muted; // to be used by prvm_edictset server playernumber muted 1
 809 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 810 // message "": do not say, just test flood control
 811 // return value:
 812 //   1 = accept
 813 //   0 = reject
 814 //  -1 = fake accept
 815 {
 816         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 817         float flood;
 818         var .float flood_field;
 819         entity head;
 820         float ret;
 821         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 822
 823         if(!teamsay && !privatesay)
 824                 if(substring(msgin, 0, 1) == " ")
 825                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 826
 827         msgin = formatmessage(msgin);
 828
 829         if(source.classname != "player")
 830                 colorstr = "^0"; // black for spectators
 831         else if(teamplay)
 832                 colorstr = Team_ColorCode(source.team);
 833         else
 834         {
 835                 colorstr = "";
 836                 teamsay = FALSE;
 837         }
 838
 839         if(intermission_running)
 840                 teamsay = FALSE;
 841
 842         if(msgin != "")
 843                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 844
 845         /*
 846          * using bprint solves this... me stupid
 847         // how can we prevent the message from appearing in a listen server?
 848         // for now, just give "say" back and only handle say_team
 849         if(!teamsay)
 850         {
 851                 clientcommand(self, strcat("say ", msgin));
 852                 return;
 853         }
 854         */
 855
 856         if(autocvar_g_chat_teamcolors)
 857                 namestr = playername(source);
 858         else
 859                 namestr = source.netname;
 860
 861         if(msgin != "")
 862         {
 863                 if(privatesay)
 864                 {
 865                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 866                         privatemsgprefixlen = strlen(msgstr);
 867                         msgstr = strcat(msgstr, msgin);
 868                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 869                         if(autocvar_g_chat_teamcolors)
 870                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 871                         else
 872                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 873                 }
 874                 else if(teamsay)
 875                 {
 876                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 877                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 878                 }
 879                 else
 880                 {
 881                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 882                         cmsgstr = "";
 883                 }
 884                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 885         }
 886         else
 887         {
 888                 msgstr = cmsgstr = "";
 889         }
 890
 891         fullmsgstr = msgstr;
 892         fullcmsgstr = cmsgstr;
 893
 894         // FLOOD CONTROL
 895         flood = 0;
 896         flood_field = floodcontrol_chat;
 897         if(floodcontrol)
 898         {
 899                 float flood_spl;
 900                 float flood_burst;
 901                 float flood_lmax;
 902                 float lines;
 903                 if(privatesay)
 904                 {
 905                         flood_spl = autocvar_g_chat_flood_spl_tell;
 906                         flood_burst = autocvar_g_chat_flood_burst_tell;
 907                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 908                         flood_field = floodcontrol_chattell;
 909                 }
 910                 else if(teamsay)
 911                 {
 912                         flood_spl = autocvar_g_chat_flood_spl_team;
 913                         flood_burst = autocvar_g_chat_flood_burst_team;
 914                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 915                         flood_field = floodcontrol_chatteam;
 916                 }
 917                 else
 918                 {
 919                         flood_spl = autocvar_g_chat_flood_spl;
 920                         flood_burst = autocvar_g_chat_flood_burst;
 921                         flood_lmax = autocvar_g_chat_flood_lmax;
 922                         flood_field = floodcontrol_chat;
 923                 }
 924                 flood_burst = max(0, flood_burst - 1);
 925                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 926
 927                 // do flood control for the default line size
 928                 if(msgstr != "")
 929                 {
 930                         getWrappedLine_remaining = msgstr;
 931                         msgstr = "";
 932                         lines = 0;
 933                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 934                         {
 935                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 936                                 ++lines;
 937                         }
 938                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 939
 940                         if(getWrappedLine_remaining != "")
 941                         {
 942                                 msgstr = strcat(msgstr, "\n");
 943                                 flood = 2;
 944                         }
 945
 946                         if(time >= source.flood_field)
 947                         {
 948                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 949                         }
 950                         else
 951                         {
 952                                 flood = 1;
 953                                 msgstr = fullmsgstr;
 954                         }
 955                 }
 956                 else
 957                 {
 958                         if(time >= source.flood_field)
 959                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 960                         else
 961                                 flood = 1;
 962                 }
 963
 964                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 965                         source.flood_field = flood = 0;
 966         }
 967
 968         if(flood == 2) // cannot happen for empty msgstr
 969         {
 970                 if(autocvar_g_chat_flood_notify_flooder)
 971                 {
 972                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 973                         sourcecmsgstr = "";
 974                 }
 975                 else
 976                 {
 977                         sourcemsgstr = fullmsgstr;
 978                         sourcecmsgstr = fullcmsgstr;
 979                 }
 980                 cmsgstr = "";
 981         }
 982         else
 983         {
 984                 sourcemsgstr = msgstr;
 985                 sourcecmsgstr = cmsgstr;
 986         }
 987
 988         if(!privatesay)
 989         if(source.classname != "player")
 990         {
 991                 if not(intermission_running)
 992                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 993                                 teamsay = -1; // spectators
 994         }
 995
 996         if(flood)
 997                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 998
 999         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1000         if(privatesay)
1001                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1002
1003         if(source.muted)
1004         {
1005                 // always fake the message
1006                 ret = -1;
1007         }
1008         else if(flood == 1)
1009         {
1010                 if(autocvar_g_chat_flood_notify_flooder)
1011                 {
1012                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1013                         ret = 0;
1014                 }
1015                 else
1016                         ret = -1;
1017         }
1018         else
1019         {
1020                 ret = 1;
1021         }
1022
1023         if(sourcemsgstr != "" && ret != 0)
1024         {
1025                 if(ret < 0) // faked message, because the player is muted
1026                 {
1027                         sprint(source, sourcemsgstr);
1028                         if(sourcecmsgstr != "" && !privatesay)
1029                                 centerprint(source, sourcecmsgstr);
1030                 }
1031                 else if(privatesay) // private message, between 2 people only, not sent to server console
1032                 {
1033                         sprint(source, sourcemsgstr);
1034                         sprint(privatesay, msgstr);
1035                         if(cmsgstr != "")
1036                                 centerprint(privatesay, cmsgstr);
1037                 }
1038                 else if(teamsay > 0) // team message, only sent to team mates
1039                 {
1040                         sprint(source, sourcemsgstr);
1041                         //print(msgstr); // send to server console too
1042                         if(sourcecmsgstr != "")
1043                                 centerprint(source, sourcecmsgstr);
1044                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1045                                 if(head != source)
1046                                 {
1047                                         sprint(head, msgstr);
1048                                         if(cmsgstr != "")
1049                                                 centerprint(head, cmsgstr);
1050                                 }
1051                 }
1052                 else if(teamsay < 0) // spectator message, only sent to spectators
1053                 {
1054                         sprint(source, sourcemsgstr);
1055                         //print(msgstr); // send to server console too
1056                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1057                                 if(head != source)
1058                                         sprint(head, msgstr);
1059                 }
1060                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1061                 {
1062                         sprint(source, sourcemsgstr);
1063                         //print(msgstr); // send to server console too
1064                         FOR_EACH_REALCLIENT(head)
1065                                 if(head != source)
1066                                         sprint(head, msgstr);
1067                 }
1068                 else
1069                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1070         }
1071
1072         return ret;
1073 }
1074
1075 float GetVoiceMessageVoiceType(string type)
1076 {
1077         if(type == "taunt")
1078                 return VOICETYPE_TAUNT;
1079         if(type == "teamshoot")
1080                 return VOICETYPE_LASTATTACKER;
1081         return VOICETYPE_TEAMRADIO;
1082 }
1083
1084 string allvoicesamples;
1085 .string GetVoiceMessageSampleField(string type)
1086 {
1087         GetPlayerSoundSampleField_notFound = 0;
1088         switch(type)
1089         {
1090 #define _VOICEMSG(m) case #m: return playersound_##m;
1091                 ALLVOICEMSGS
1092 #undef _VOICEMSG
1093         }
1094         GetPlayerSoundSampleField_notFound = 1;
1095         return playersound_taunt;
1096 }
1097
1098 .string GetPlayerSoundSampleField(string type)
1099 {
1100         GetPlayerSoundSampleField_notFound = 0;
1101         switch(type)
1102         {
1103 #define _VOICEMSG(m) case #m: return playersound_##m;
1104                 ALLPLAYERSOUNDS
1105 #undef _VOICEMSG
1106         }
1107         GetPlayerSoundSampleField_notFound = 1;
1108         return playersound_taunt;
1109 }
1110
1111 void PrecacheGlobalSound(string samplestring)
1112 {
1113         float n, i;
1114         tokenize_console(samplestring);
1115         n = stof(argv(1));
1116         if(n > 0)
1117         {
1118                 for(i = 1; i <= n; ++i)
1119                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1120         }
1121         else
1122         {
1123                 precache_sound(strcat(argv(0), ".wav"));
1124         }
1125 }
1126
1127 void PrecachePlayerSounds(string f)
1128 {
1129         float fh;
1130         string s;
1131         fh = fopen(f, FILE_READ);
1132         if(fh < 0)
1133                 return;
1134         while((s = fgets(fh)))
1135         {
1136                 if(tokenize_console(s) != 3)
1137                 {
1138                         dprint("Invalid sound info line: ", s, "\n");
1139                         continue;
1140                 }
1141                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1142         }
1143         fclose(fh);
1144
1145         if not(allvoicesamples)
1146         {
1147 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1148                 ALLVOICEMSGS
1149 #undef _VOICEMSG
1150                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1151         }
1152 }
1153
1154 void ClearPlayerSounds()
1155 {
1156 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1157         ALLPLAYERSOUNDS
1158         ALLVOICEMSGS
1159 #undef _VOICEMSG
1160 }
1161
1162 float LoadPlayerSounds(string f, float first)
1163 {
1164         float fh;
1165         string s;
1166         var .string field;
1167         fh = fopen(f, FILE_READ);
1168         if(fh < 0)
1169         {
1170                 dprint("Player sound file not found: ", f, "\n");
1171                 return 0;
1172         }
1173         while((s = fgets(fh)))
1174         {
1175                 if(tokenize_console(s) != 3)
1176                         continue;
1177                 field = GetPlayerSoundSampleField(argv(0));
1178                 if(GetPlayerSoundSampleField_notFound)
1179                         field = GetVoiceMessageSampleField(argv(0));
1180                 if(GetPlayerSoundSampleField_notFound)
1181                         continue;
1182                 if(self.field)
1183                         strunzone(self.field);
1184                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1185         }
1186         fclose(fh);
1187         return 1;
1188 }
1189
1190 .float modelindex_for_playersound;
1191 .float skin_for_playersound;
1192 void UpdatePlayerSounds()
1193 {
1194         if(self.modelindex == self.modelindex_for_playersound)
1195         if(self.skin == self.skin_for_playersound)
1196                 return;
1197         self.modelindex_for_playersound = self.modelindex;
1198         self.skin_for_playersound = self.skin;
1199         ClearPlayerSounds();
1200         LoadPlayerSounds("sound/player/default.sounds", 1);
1201         if(!autocvar_g_debug_defaultsounds)
1202                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1203                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1204 }
1205
1206 void FakeGlobalSound(string sample, float chan, float voicetype)
1207 {
1208         float n;
1209         float tauntrand;
1210
1211         if(sample == "")
1212                 return;
1213
1214         tokenize_console(sample);
1215         n = stof(argv(1));
1216         if(n > 0)
1217                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1218         else
1219                 sample = strcat(argv(0), ".wav"); // randomization
1220
1221         switch(voicetype)
1222         {
1223                 case VOICETYPE_LASTATTACKER_ONLY:
1224                         break;
1225                 case VOICETYPE_LASTATTACKER:
1226                         if(self.pusher)
1227                         {
1228                                 msg_entity = self;
1229                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1230                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1231                         }
1232                         break;
1233                 case VOICETYPE_TEAMRADIO:
1234                         msg_entity = self;
1235                         if(msg_entity.cvar_cl_voice_directional == 1)
1236                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1237                         else
1238                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1239                         break;
1240                 case VOICETYPE_AUTOTAUNT:
1241                         if(!sv_autotaunt)
1242                                 break;
1243                         if(!sv_taunt)
1244                                 break;
1245                         if(sv_gentle)
1246                                 break;
1247                         tauntrand = random();
1248                         msg_entity = self;
1249                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1250                         {
1251                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1252                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1253                                 else
1254                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1255                         }
1256                         break;
1257                 case VOICETYPE_TAUNT:
1258                         if(self.classname == "player")
1259                                 if(self.deadflag == DEAD_NO)
1260                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1261                         if(!sv_taunt)
1262                                 break;
1263                         if(sv_gentle)
1264                                 break;
1265                         msg_entity = self;
1266                         if (msg_entity.cvar_cl_voice_directional >= 1)
1267                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1268                         else
1269                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1270                         break;
1271                 case VOICETYPE_PLAYERSOUND:
1272                         msg_entity = self;
1273                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1274                         break;
1275                 default:
1276                         backtrace("Invalid voice type!");
1277                         break;
1278         }
1279 }
1280
1281 void GlobalSound(string sample, float chan, float voicetype)
1282 {
1283         float n;
1284         float tauntrand;
1285
1286         if(sample == "")
1287                 return;
1288
1289         tokenize_console(sample);
1290         n = stof(argv(1));
1291         if(n > 0)
1292                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1293         else
1294                 sample = strcat(argv(0), ".wav"); // randomization
1295
1296         switch(voicetype)
1297         {
1298                 case VOICETYPE_LASTATTACKER_ONLY:
1299                         if(self.pusher)
1300                         {
1301                                 msg_entity = self.pusher;
1302                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1303                                 {
1304                                         if(msg_entity.cvar_cl_voice_directional == 1)
1305                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1306                                         else
1307                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1308                                 }
1309                         }
1310                         break;
1311                 case VOICETYPE_LASTATTACKER:
1312                         if(self.pusher)
1313                         {
1314                                 msg_entity = self.pusher;
1315                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1316                                 {
1317                                         if(msg_entity.cvar_cl_voice_directional == 1)
1318                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1319                                         else
1320                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1321                                 }
1322                                 msg_entity = self;
1323                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1324                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1325                         }
1326                         break;
1327                 case VOICETYPE_TEAMRADIO:
1328                         FOR_EACH_REALCLIENT(msg_entity)
1329                                 if(!teamplay || msg_entity.team == self.team)
1330                                 {
1331                                         if(msg_entity.cvar_cl_voice_directional == 1)
1332                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1333                                         else
1334                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1335                                 }
1336                         break;
1337                 case VOICETYPE_AUTOTAUNT:
1338                         if(!sv_autotaunt)
1339                                 break;
1340                         if(!sv_taunt)
1341                                 break;
1342                         if(sv_gentle)
1343                                 break;
1344                         tauntrand = random();
1345                         FOR_EACH_REALCLIENT(msg_entity)
1346                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1347                                 {
1348                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1349                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1350                                         else
1351                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1352                                 }
1353                         break;
1354                 case VOICETYPE_TAUNT:
1355                         if(self.classname == "player")
1356                                 if(self.deadflag == DEAD_NO)
1357                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1358                         if(!sv_taunt)
1359                                 break;
1360                         if(sv_gentle)
1361                                 break;
1362                         FOR_EACH_REALCLIENT(msg_entity)
1363                         {
1364                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1365                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1366                                 else
1367                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1368                         }
1369                         break;
1370                 case VOICETYPE_PLAYERSOUND:
1371                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1372                         break;
1373                 default:
1374                         backtrace("Invalid voice type!");
1375                         break;
1376         }
1377 }
1378
1379 void PlayerSound(.string samplefield, float chan, float voicetype)
1380 {
1381         GlobalSound(self.samplefield, chan, voicetype);
1382 }
1383
1384 void VoiceMessage(string type, string msg)
1385 {
1386         var .string sample;
1387         float voicetype, ownteam;
1388         float flood;
1389         sample = GetVoiceMessageSampleField(type);
1390
1391         if(GetPlayerSoundSampleField_notFound)
1392         {
1393                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1394                 return;
1395         }
1396
1397         voicetype = GetVoiceMessageVoiceType(type);
1398         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1399
1400         flood = Say(self, ownteam, world, msg, 1);
1401
1402         if (flood > 0)
1403                 GlobalSound(self.sample, CH_VOICE, voicetype);
1404         else if (flood < 0)
1405                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1406 }
1407
1408 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1409 {
1410 //      show_message
1411 //      0 (00) automove centerprint, admin message
1412 //      1 (01) automove centerprint, no admin message
1413 //      2 (10) no centerprint, admin message
1414 //      3 (11) no centerprint, no admin message
1415
1416         float lockteams_backup;
1417
1418         lockteams_backup = lockteams;  // backup any team lock
1419
1420         lockteams = 0;  // disable locked teams
1421
1422         TeamchangeFrags(client);  // move the players frags
1423         SetPlayerColors(client, team_colour - 1);  // set the players colour
1424         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1425
1426         lockteams = lockteams_backup;  // restore the team lock
1427
1428         LogTeamchange(client.playerid, client.team, type);
1429
1430         if not(show_message & 1) // admin message
1431                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1432
1433         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1434 }