qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.animstate_startframe = oldself.animstate_startframe;
 165         self.animstate_numframes = oldself.animstate_numframes;
 166         self.animstate_framerate = oldself.animstate_framerate;
 167         self.animstate_starttime = oldself.animstate_starttime;
 168         self.animstate_endtime = oldself.animstate_endtime;
 169         self.animstate_override = oldself.animstate_override;
 170         self.animstate_looping = oldself.animstate_looping;
 171         self.dphitcontentsmask = oldself.dphitcontentsmask;
 172         self.death_time = oldself.death_time;
 173         self.frame = oldself.frame;
 174         self.pain_finished = oldself.pain_finished;
 175         self.health = oldself.health;
 176         self.armorvalue = oldself.armorvalue;
 177         self.armortype = oldself.armortype;
 178         self.model = oldself.model;
 179         self.modelindex = oldself.modelindex;
 180         self.skin = oldself.skin;
 181         self.species = oldself.species;
 182         self.movetype = oldself.movetype;
 183         self.solid = oldself.solid;
 184         self.ballistics_density = oldself.ballistics_density;
 185         self.takedamage = oldself.takedamage;
 186         self.customizeentityforclient = oldself.customizeentityforclient;
 187         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 188         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 189         if (keepvelocity == 1)
 190                 self.velocity = oldself.velocity;
 191         self.oldvelocity = self.velocity;
 192         self.alpha = oldself.alpha;
 193         self.fade_time = oldself.fade_time;
 194         self.fade_rate = oldself.fade_rate;
 195         //self.weapon = oldself.weapon;
 196         setorigin(self, oldself.origin);
 197         setsize(self, oldself.mins, oldself.maxs);
 198         self.prevorigin = oldself.origin;
 199         self.reset = SUB_Remove;
 200
 201         Drag_MoveDrag(oldself, self);
 202
 203         if(self.colormap <= maxclients && self.colormap > 0)
 204                 self.colormap = 1024 + oldself.clientcolors;
 205
 206         CSQCMODEL_AUTOINIT();
 207         self.CopyBody_nextthink = oldself.nextthink;
 208         self.CopyBody_think = oldself.think;
 209         self.nextthink = time;
 210         self.think = CopyBody_Think;
 211
 212         self = oldself;
 213 }
 214
 215 float player_getspecies()
 216 {
 217         float s;
 218         get_model_parameters(self.model, self.skin);
 219         s = get_model_parameters_species;
 220         get_model_parameters(string_null, 0);
 221         if(s < 0)
 222                 return SPECIES_HUMAN;
 223         return s;
 224 }
 225
 226 void player_setupanimsformodel()
 227 {
 228         // defaults for legacy .zym models without animinfo files
 229         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 230         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 231         self.anim_draw = animfixfps(self, '2 1 3');
 232         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 233         self.anim_duckwalk = animfixfps(self, '4 1 1');
 234         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 235         self.anim_duckidle = animfixfps(self, '6 1 1');
 236         self.anim_idle = animfixfps(self, '7 1 1');
 237         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 238         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 239         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 240         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 241         self.anim_taunt = animfixfps(self, '12 1 0.33');
 242         self.anim_run = animfixfps(self, '13 1 1');
 243         self.anim_runbackwards = animfixfps(self, '14 1 1');
 244         self.anim_strafeleft = animfixfps(self, '15 1 1');
 245         self.anim_straferight = animfixfps(self, '16 1 1');
 246         //self.anim_dead1 = animfixfps(self, '17 1 1');
 247         //self.anim_dead2 = animfixfps(self, '18 1 1');
 248         self.anim_forwardright = animfixfps(self, '19 1 1');
 249         self.anim_forwardleft = animfixfps(self, '20 1 1');
 250         self.anim_backright = animfixfps(self, '21 1 1');
 251         self.anim_backleft  = animfixfps(self, '22 1 1');
 252         self.anim_melee = animfixfps(self, '23 1 1');
 253         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 254         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 255         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 256         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 257         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 258         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 259         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 260         // TODO introspect models for finding right "fps" value (1/duration)
 261         // reset animstate now
 262         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 263 }
 264
 265 void player_anim (void)
 266 {
 267         updateanim(self);
 268         if (self.weaponentity)
 269                 updateanim(self.weaponentity);
 270
 271         if (self.deadflag != DEAD_NO)
 272                 return;
 273
 274         if (!self.animstate_override)
 275         {
 276                 if (self.freezetag_frozen)
 277                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 278                 else if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 279                 {
 280                         if (self.crouch)
 281                         {
 282                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 283                                 {
 284                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 285                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 286                                         {
 287                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 288                                                 self.restart_jump = FALSE;
 289                                         }
 290                                 }
 291                         }
 292                         else
 293                         {
 294                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 295                 {
 296                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 297                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 298                     {
 299                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 300                         self.restart_jump = FALSE;
 301                     }
 302                 }
 303                         }
 304                 }
 305                 else if (self.crouch)
 306                 {
 307                         if (self.movement_x > 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x < 0 && self.movement_y == 0)
 310                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x == 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x > 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y > 0)
 320                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x < 0 && self.movement_y < 0)
 322                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 325                 }
 326                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 327                 {
 328                         if (self.movement_x > 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x < 0 && self.movement_y == 0)
 331                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x == 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x > 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x < 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 344                         else
 345                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 346                 }
 347                 else
 348                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 349         }
 350
 351         if (self.weaponentity)
 352         if (!self.weaponentity.animstate_override)
 353                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 354 }
 355
 356 void SpawnThrownWeapon (vector org, float w)
 357 {
 358         if(g_minstagib)
 359         if(self.ammo_cells <= 0)
 360                 return;
 361
 362         if(g_pinata)
 363         {
 364                 float j;
 365                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 366                 {
 367                         if(WEPSET_CONTAINS_EW(self, j))
 368                                 if(W_IsWeaponThrowable(j))
 369                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 370                 }
 371         }
 372         else
 373         {
 374                 if(W_IsWeaponThrowable(self.weapon))
 375                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 376         }
 377 }
 378
 379 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 380 {
 381         float take, save;
 382         vector v;
 383         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 384
 385         // damage resistance (ignore most of the damage from a bullet or similar)
 386         damage = max(damage - 5, 1);
 387
 388         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 389         take = v_x;
 390         save = v_y;
 391
 392         if(sound_allowed(MSG_BROADCAST, attacker))
 393         {
 394                 if (save > 10)
 395                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 396                 else if (take > 30)
 397                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 398                 else if (take > 10)
 399                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 400         }
 401
 402         if (take > 50)
 403                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 404         if (take > 100)
 405                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 406
 407         if (!(self.flags & FL_GODMODE))
 408         {
 409                 self.armorvalue = self.armorvalue - save;
 410                 self.health = self.health - take;
 411                 // pause regeneration for 5 seconds
 412                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 413         }
 414         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 415         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 416         self.dmg_inflictor = inflictor;
 417
 418         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 419         {
 420                 // don't use any animations as a gib
 421                 self.frame = 0;
 422                 // view just above the floor
 423                 self.view_ofs = '0 0 4';
 424
 425                 Violence_GibSplash(self, 1, 1, attacker);
 426                 self.alpha = -1;
 427                 self.solid = SOLID_NOT; // restore later
 428                 self.takedamage = DAMAGE_NO; // restore later
 429                 self.damagedbycontents = FALSE;
 430         }
 431 }
 432
 433 void ClientKill_Now_TeamChange();
 434 void freezetag_CheckWinner();
 435
 436 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 437 {
 438         float take, save, waves, sdelay, dh, da, j;
 439         vector v;
 440         float valid_damage_for_weaponstats;
 441         float excess;
 442
 443         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 444                 return;
 445
 446         dh = max(self.health, 0);
 447         da = max(self.armorvalue, 0);
 448
 449         if(!DEATH_ISSPECIAL(deathtype))
 450         {
 451                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 452                 if(self != attacker)
 453                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 454         }
 455
 456         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 457         {
 458                 // tuba causes blood to come out of the ears
 459                 vector ear1, ear2;
 460                 vector d;
 461                 float f;
 462                 ear1 = self.origin;
 463                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 464                 ear2 = ear1;
 465                 makevectors(self.angles);
 466                 ear1 += v_right * -10;
 467                 ear2 += v_right * +10;
 468                 d = inflictor.origin - self.origin;
 469                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 470                 force = v_right * vlen(force);
 471                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 472                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 473                 if(f > 0)
 474                 {
 475                         hitloc = ear1;
 476                         force = force * -1;
 477                 }
 478                 else
 479                 {
 480                         hitloc = ear2;
 481                         // force is already good
 482                 }
 483         }
 484         else
 485                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 486
 487         if (!g_minstagib)
 488         {
 489                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 490                 take = v_x;
 491                 save = v_y;
 492         }
 493         else
 494         {
 495                 save = 0;
 496                 take = damage;
 497         }
 498
 499         if(attacker == self)
 500         {
 501                 // don't reset pushltime for self damage as it may be an attempt to
 502                 // escape a lava pit or similar
 503                 //self.pushltime = 0;
 504                 self.istypefrag = 0;
 505         }
 506         else if(attacker.classname == "player")
 507         {
 508                 self.pusher = attacker;
 509                 self.pushltime = time + autocvar_g_maxpushtime;
 510                 self.istypefrag = self.BUTTON_CHAT;
 511         }
 512         else if(time < self.pushltime)
 513         {
 514                 attacker = self.pusher;
 515                 self.pushltime = max(self.pushltime, time + 0.6);
 516         }
 517         else
 518         {
 519                 self.pushltime = 0;
 520                 self.istypefrag = 0;
 521         }
 522
 523         frag_inflictor = inflictor;
 524         frag_attacker = attacker;
 525         frag_target = self;
 526         damage_take = take;
 527         damage_save = save;
 528         damage_force = force;
 529         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 530         take = bound(0, damage_take, self.health);
 531         save = bound(0, damage_save, self.armorvalue);
 532         excess = max(0, damage - take - save);
 533
 534         if(sound_allowed(MSG_BROADCAST, attacker))
 535         {
 536                 if (save > 10)
 537                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 538                 else if (take > 30)
 539                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 540                 else if (take > 10)
 541                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 542         }
 543
 544         if (take > 50)
 545                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 546         if (take > 100)
 547                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 548
 549         if (time >= self.spawnshieldtime)
 550         {
 551                 if (!(self.flags & FL_GODMODE))
 552                 {
 553                         self.armorvalue = self.armorvalue - save;
 554                         self.health = self.health - take;
 555                         // pause regeneration for 5 seconds
 556                         if(take)
 557                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 558
 559                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 560                         {
 561                                 self.pain_finished = time + 0.5;        //Supajoe
 562
 563                                 if(sv_gentle < 1) {
 564                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 565                                         {
 566                                                 if (!self.animstate_override)
 567                                                 {
 568                                                         if (random() > 0.5)
 569                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 570                                                         else
 571                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 572                                                 }
 573                                         }
 574
 575                                         if(sound_allowed(MSG_BROADCAST, attacker))
 576                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 577                                         if(self.health > 1)
 578                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 579                                         {
 580                                                 if(deathtype == DEATH_FALL)
 581                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 582                                                 else if(self.health > 75) // TODO make a "gentle" version?
 583                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 584                                                 else if(self.health > 50)
 585                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 586                                                 else if(self.health > 25)
 587                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 588                                                 else
 589                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 590                                         }
 591                                 }
 592
 593                                 // throw off bot aim temporarily
 594                                 float shake;
 595                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 596                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 597                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 598                         }
 599                 }
 600                 else
 601                         self.max_armorvalue += (save + take);
 602         }
 603         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 604         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 605         self.dmg_inflictor = inflictor;
 606
 607         if(g_ca && self != attacker && attacker.classname == "player")
 608                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 609
 610         float abot, vbot, awep;
 611         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 612         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 613
 614         valid_damage_for_weaponstats = 0;
 615         awep = 0;
 616
 617         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 618         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 619         if(attacker && self != attacker)
 620         if(IsDifferentTeam(self, attacker))
 621         {
 622                 if(DEATH_ISSPECIAL(deathtype))
 623                         awep = attacker.weapon;
 624                 else
 625                         awep = DEATH_WEAPONOF(deathtype);
 626                 valid_damage_for_weaponstats = 1;
 627         }
 628
 629         if(valid_damage_for_weaponstats)
 630         {
 631                 dh = dh - max(self.health, 0);
 632                 da = da - max(self.armorvalue, 0);
 633                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 634         }
 635
 636         if (self.health < 1)
 637         {
 638                 float defer_ClientKill_Now_TeamChange;
 639                 defer_ClientKill_Now_TeamChange = FALSE;
 640
 641                 if(self.alivetime)
 642                 {
 643                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 644                         self.alivetime = 0;
 645                 }
 646
 647                 if(valid_damage_for_weaponstats)
 648                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 649
 650                 if(sv_gentle < 1) // TODO make a "gentle" version?
 651                 if(sound_allowed(MSG_BROADCAST, attacker))
 652                 {
 653                         if(deathtype == DEATH_DROWN)
 654                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 655                         else
 656                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 657                 }
 658
 659                 // get rid of kill indicator
 660                 if(self.killindicator)
 661                 {
 662                         remove(self.killindicator);
 663                         self.killindicator = world;
 664                         if(self.killindicator_teamchange)
 665                                 defer_ClientKill_Now_TeamChange = TRUE;
 666
 667                         if(self.classname == "body")
 668                         if(deathtype == DEATH_KILL)
 669                         {
 670                                 // for the lemmings fans, a small harmless explosion
 671                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 672                         }
 673                 }
 674
 675                 if(!g_freezetag)
 676                 {
 677                         // become fully visible
 678                         self.alpha = default_player_alpha;
 679                         // throw a weapon
 680                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 681                 }
 682
 683                 // print an obituary message
 684                 Obituary (attacker, inflictor, self, deathtype);
 685                 race_PreDie();
 686                 DropAllRunes(self);
 687
 688         // increment frag counter for used weapon type
 689         float w;
 690         w = DEATH_WEAPONOF(deathtype);
 691         if(WEP_VALID(w))
 692         if(accuracy_isgooddamage(attacker, self))
 693         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 694
 695                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 696                 {
 697                         PutClientInServer();
 698                         count_alive_players(); // re-count players
 699                         freezetag_CheckWinner();
 700                         return;
 701                 }
 702
 703                 frag_attacker = attacker;
 704                 frag_inflictor = inflictor;
 705                 frag_target = self;
 706                 MUTATOR_CALLHOOK(PlayerDies);
 707                 weapon_action(self.weapon, WR_PLAYERDEATH);
 708
 709                 RemoveGrapplingHook(self);
 710
 711                 Portal_ClearAllLater(self);
 712
 713                 if(clienttype(self) == CLIENTTYPE_REAL)
 714                 {
 715                         stuffcmd(self, "-zoom\n");
 716                         self.fixangle = TRUE;
 717                         //msg_entity = self;
 718                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 719                         //WriteAngle (MSG_ONE, self.v_angle_x);
 720                         //WriteAngle (MSG_ONE, self.v_angle_y);
 721                         //WriteAngle (MSG_ONE, 80);
 722                 }
 723
 724                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 725                         ClientKill_Now_TeamChange();
 726
 727                 if(g_arena)
 728                         Spawnqueue_Unmark(self);
 729
 730                 if(g_freezetag)
 731                         return;
 732
 733                 // when we get here, player actually dies
 734                 // clear waypoints (do this AFTER FreezeTag)
 735                 WaypointSprite_PlayerDead();
 736
 737                 // make the corpse upright (not tilted)
 738                 self.angles_x = 0;
 739                 self.angles_z = 0;
 740                 // don't spin
 741                 self.avelocity = '0 0 0';
 742                 // view from the floor
 743                 self.view_ofs = '0 0 -8';
 744                 // toss the corpse
 745                 self.movetype = MOVETYPE_TOSS;
 746                 // shootable corpse
 747                 self.solid = SOLID_CORPSE;
 748                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 749                 // don't stick to the floor
 750                 self.flags &~= FL_ONGROUND;
 751                 // dying animation
 752                 self.deadflag = DEAD_DYING;
 753                 // when to allow respawn
 754                 sdelay = 0;
 755                 waves = 0;
 756                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 757                 if(!sdelay)
 758                 {
 759                         if(g_cts)
 760                                 sdelay = 0; // no respawn delay in CTS
 761                         else
 762                                 sdelay = autocvar_g_respawn_delay;
 763                 }
 764                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 765                 if(!waves)
 766                         waves = autocvar_g_respawn_waves;
 767                 if(waves)
 768                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 769                 else
 770                         self.respawn_time = time + sdelay;
 771                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 772                         self.respawn_countdown = 10; // first number to count down from is 10
 773                 else
 774                         self.respawn_countdown = -1; // do not count down
 775                 self.death_time = time;
 776                 if (random() < 0.5)
 777                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 778                 else
 779                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 780                 if (self.maxs_z > 5)
 781                 {
 782                         self.maxs_z = 5;
 783                         setsize(self, self.mins, self.maxs);
 784                 }
 785                 // set damage function to corpse damage
 786                 self.event_damage = PlayerCorpseDamage;
 787                 // call the corpse damage function just in case it wants to gib
 788                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 789                 // set up to fade out later
 790                 SUB_SetFade (self, time + 6 + random (), 1);
 791
 792                 if(sv_gentle > 0 || autocvar_ekg) {
 793                         // remove corpse
 794                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 795                 }
 796
 797                 // reset fields the weapons may use just in case
 798                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 799                 {
 800                         weapon_action(j, WR_RESETPLAYER);
 801                         ATTACK_FINISHED_FOR(self, j) = 0;
 802                 }
 803         }
 804 }
 805
 806 .float muted; // to be used by prvm_edictset server playernumber muted 1
 807 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 808 // message "": do not say, just test flood control
 809 // return value:
 810 //   1 = accept
 811 //   0 = reject
 812 //  -1 = fake accept
 813 {
 814         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 815         float flood;
 816         var .float flood_field;
 817         entity head;
 818         float ret;
 819         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 820
 821         if(!teamsay && !privatesay)
 822                 if(substring(msgin, 0, 1) == " ")
 823                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 824
 825         msgin = formatmessage(msgin);
 826
 827         if(source.classname != "player")
 828                 colorstr = "^0"; // black for spectators
 829         else if(teamplay)
 830                 colorstr = Team_ColorCode(source.team);
 831         else
 832         {
 833                 colorstr = "";
 834                 teamsay = FALSE;
 835         }
 836
 837         if(intermission_running)
 838                 teamsay = FALSE;
 839
 840         if(msgin != "")
 841                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 842
 843         /*
 844          * using bprint solves this... me stupid
 845         // how can we prevent the message from appearing in a listen server?
 846         // for now, just give "say" back and only handle say_team
 847         if(!teamsay)
 848         {
 849                 clientcommand(self, strcat("say ", msgin));
 850                 return;
 851         }
 852         */
 853
 854         if(autocvar_g_chat_teamcolors)
 855                 namestr = playername(source);
 856         else
 857                 namestr = source.netname;
 858
 859         if(msgin != "")
 860         {
 861                 if(privatesay)
 862                 {
 863                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 864                         privatemsgprefixlen = strlen(msgstr);
 865                         msgstr = strcat(msgstr, msgin);
 866                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 867                         if(autocvar_g_chat_teamcolors)
 868                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 869                         else
 870                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 871                 }
 872                 else if(teamsay)
 873                 {
 874                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 875                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 876                 }
 877                 else
 878                 {
 879                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 880                         cmsgstr = "";
 881                 }
 882                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 883         }
 884         else
 885         {
 886                 msgstr = cmsgstr = "";
 887         }
 888
 889         fullmsgstr = msgstr;
 890         fullcmsgstr = cmsgstr;
 891
 892         // FLOOD CONTROL
 893         flood = 0;
 894         flood_field = floodcontrol_chat;
 895         if(floodcontrol)
 896         {
 897                 float flood_spl;
 898                 float flood_burst;
 899                 float flood_lmax;
 900                 float lines;
 901                 if(privatesay)
 902                 {
 903                         flood_spl = autocvar_g_chat_flood_spl_tell;
 904                         flood_burst = autocvar_g_chat_flood_burst_tell;
 905                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 906                         flood_field = floodcontrol_chattell;
 907                 }
 908                 else if(teamsay)
 909                 {
 910                         flood_spl = autocvar_g_chat_flood_spl_team;
 911                         flood_burst = autocvar_g_chat_flood_burst_team;
 912                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 913                         flood_field = floodcontrol_chatteam;
 914                 }
 915                 else
 916                 {
 917                         flood_spl = autocvar_g_chat_flood_spl;
 918                         flood_burst = autocvar_g_chat_flood_burst;
 919                         flood_lmax = autocvar_g_chat_flood_lmax;
 920                         flood_field = floodcontrol_chat;
 921                 }
 922                 flood_burst = max(0, flood_burst - 1);
 923                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 924
 925                 // do flood control for the default line size
 926                 if(msgstr != "")
 927                 {
 928                         getWrappedLine_remaining = msgstr;
 929                         msgstr = "";
 930                         lines = 0;
 931                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 932                         {
 933                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 934                                 ++lines;
 935                         }
 936                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 937
 938                         if(getWrappedLine_remaining != "")
 939                         {
 940                                 msgstr = strcat(msgstr, "\n");
 941                                 flood = 2;
 942                         }
 943
 944                         if(time >= source.flood_field)
 945                         {
 946                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 947                         }
 948                         else
 949                         {
 950                                 flood = 1;
 951                                 msgstr = fullmsgstr;
 952                         }
 953                 }
 954                 else
 955                 {
 956                         if(time >= source.flood_field)
 957                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 958                         else
 959                                 flood = 1;
 960                 }
 961
 962                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 963                         source.flood_field = flood = 0;
 964         }
 965
 966         if(flood == 2) // cannot happen for empty msgstr
 967         {
 968                 if(autocvar_g_chat_flood_notify_flooder)
 969                 {
 970                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 971                         sourcecmsgstr = "";
 972                 }
 973                 else
 974                 {
 975                         sourcemsgstr = fullmsgstr;
 976                         sourcecmsgstr = fullcmsgstr;
 977                 }
 978                 cmsgstr = "";
 979         }
 980         else
 981         {
 982                 sourcemsgstr = msgstr;
 983                 sourcecmsgstr = cmsgstr;
 984         }
 985
 986         if(!privatesay)
 987         if(source.classname != "player")
 988         {
 989                 if not(intermission_running)
 990                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 991                                 teamsay = -1; // spectators
 992         }
 993
 994         if(flood)
 995                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 996
 997         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 998         if(privatesay)
 999                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1000
1001         if(source.muted)
1002         {
1003                 // always fake the message
1004                 ret = -1;
1005         }
1006         else if(flood == 1)
1007         {
1008                 if(autocvar_g_chat_flood_notify_flooder)
1009                 {
1010                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1011                         ret = 0;
1012                 }
1013                 else
1014                         ret = -1;
1015         }
1016         else
1017         {
1018                 ret = 1;
1019         }
1020
1021         if(sourcemsgstr != "" && ret != 0)
1022         {
1023                 if(ret < 0) // faked message, because the player is muted
1024                 {
1025                         sprint(source, sourcemsgstr);
1026                         if(sourcecmsgstr != "" && !privatesay)
1027                                 centerprint(source, sourcecmsgstr);
1028                 }
1029                 else if(privatesay) // private message, between 2 people only, not sent to server console
1030                 {
1031                         sprint(source, sourcemsgstr);
1032                         sprint(privatesay, msgstr);
1033                         if(cmsgstr != "")
1034                                 centerprint(privatesay, cmsgstr);
1035                 }
1036                 else if(teamsay > 0) // team message, only sent to team mates
1037                 {
1038                         sprint(source, sourcemsgstr);
1039                         //print(msgstr); // send to server console too
1040                         if(sourcecmsgstr != "")
1041                                 centerprint(source, sourcecmsgstr);
1042                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1043                                 if(head != source)
1044                                 {
1045                                         sprint(head, msgstr);
1046                                         if(cmsgstr != "")
1047                                                 centerprint(head, cmsgstr);
1048                                 }
1049                 }
1050                 else if(teamsay < 0) // spectator message, only sent to spectators
1051                 {
1052                         sprint(source, sourcemsgstr);
1053                         //print(msgstr); // send to server console too
1054                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1055                                 if(head != source)
1056                                         sprint(head, msgstr);
1057                 }
1058                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1059                 {
1060                         sprint(source, sourcemsgstr);
1061                         //print(msgstr); // send to server console too
1062                         FOR_EACH_REALCLIENT(head)
1063                                 if(head != source)
1064                                         sprint(head, msgstr);
1065                 }
1066                 else
1067                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1068         }
1069
1070         return ret;
1071 }
1072
1073 float GetVoiceMessageVoiceType(string type)
1074 {
1075         if(type == "taunt")
1076                 return VOICETYPE_TAUNT;
1077         if(type == "teamshoot")
1078                 return VOICETYPE_LASTATTACKER;
1079         return VOICETYPE_TEAMRADIO;
1080 }
1081
1082 string allvoicesamples;
1083 .string GetVoiceMessageSampleField(string type)
1084 {
1085         GetPlayerSoundSampleField_notFound = 0;
1086         switch(type)
1087         {
1088 #define _VOICEMSG(m) case #m: return playersound_##m;
1089                 ALLVOICEMSGS
1090 #undef _VOICEMSG
1091         }
1092         GetPlayerSoundSampleField_notFound = 1;
1093         return playersound_taunt;
1094 }
1095
1096 .string GetPlayerSoundSampleField(string type)
1097 {
1098         GetPlayerSoundSampleField_notFound = 0;
1099         switch(type)
1100         {
1101 #define _VOICEMSG(m) case #m: return playersound_##m;
1102                 ALLPLAYERSOUNDS
1103 #undef _VOICEMSG
1104         }
1105         GetPlayerSoundSampleField_notFound = 1;
1106         return playersound_taunt;
1107 }
1108
1109 void PrecacheGlobalSound(string samplestring)
1110 {
1111         float n, i;
1112         tokenize_console(samplestring);
1113         n = stof(argv(1));
1114         if(n > 0)
1115         {
1116                 for(i = 1; i <= n; ++i)
1117                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1118         }
1119         else
1120         {
1121                 precache_sound(strcat(argv(0), ".wav"));
1122         }
1123 }
1124
1125 void PrecachePlayerSounds(string f)
1126 {
1127         float fh;
1128         string s;
1129         fh = fopen(f, FILE_READ);
1130         if(fh < 0)
1131                 return;
1132         while((s = fgets(fh)))
1133         {
1134                 if(tokenize_console(s) != 3)
1135                 {
1136                         dprint("Invalid sound info line: ", s, "\n");
1137                         continue;
1138                 }
1139                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1140         }
1141         fclose(fh);
1142
1143         if not(allvoicesamples)
1144         {
1145 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1146                 ALLVOICEMSGS
1147 #undef _VOICEMSG
1148                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1149         }
1150 }
1151
1152 void ClearPlayerSounds()
1153 {
1154 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1155         ALLPLAYERSOUNDS
1156         ALLVOICEMSGS
1157 #undef _VOICEMSG
1158 }
1159
1160 float LoadPlayerSounds(string f, float first)
1161 {
1162         float fh;
1163         string s;
1164         var .string field;
1165         fh = fopen(f, FILE_READ);
1166         if(fh < 0)
1167         {
1168                 dprint("Player sound file not found: ", f, "\n");
1169                 return 0;
1170         }
1171         while((s = fgets(fh)))
1172         {
1173                 if(tokenize_console(s) != 3)
1174                         continue;
1175                 field = GetPlayerSoundSampleField(argv(0));
1176                 if(GetPlayerSoundSampleField_notFound)
1177                         field = GetVoiceMessageSampleField(argv(0));
1178                 if(GetPlayerSoundSampleField_notFound)
1179                         continue;
1180                 if(self.field)
1181                         strunzone(self.field);
1182                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1183         }
1184         fclose(fh);
1185         return 1;
1186 }
1187
1188 .float modelindex_for_playersound;
1189 .float skin_for_playersound;
1190 void UpdatePlayerSounds()
1191 {
1192         if(self.modelindex == self.modelindex_for_playersound)
1193         if(self.skin == self.skin_for_playersound)
1194                 return;
1195         self.modelindex_for_playersound = self.modelindex;
1196         self.skin_for_playersound = self.skin;
1197         ClearPlayerSounds();
1198         LoadPlayerSounds("sound/player/default.sounds", 1);
1199         if(!autocvar_g_debug_defaultsounds)
1200                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1201                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1202 }
1203
1204 void FakeGlobalSound(string sample, float chan, float voicetype)
1205 {
1206         float n;
1207         float tauntrand;
1208
1209         if(sample == "")
1210                 return;
1211
1212         tokenize_console(sample);
1213         n = stof(argv(1));
1214         if(n > 0)
1215                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1216         else
1217                 sample = strcat(argv(0), ".wav"); // randomization
1218
1219         switch(voicetype)
1220         {
1221                 case VOICETYPE_LASTATTACKER_ONLY:
1222                         break;
1223                 case VOICETYPE_LASTATTACKER:
1224                         if(self.pusher)
1225                         {
1226                                 msg_entity = self;
1227                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1228                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1229                         }
1230                         break;
1231                 case VOICETYPE_TEAMRADIO:
1232                         msg_entity = self;
1233                         if(msg_entity.cvar_cl_voice_directional == 1)
1234                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1235                         else
1236                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1237                         break;
1238                 case VOICETYPE_AUTOTAUNT:
1239                         if(!sv_autotaunt)
1240                                 break;
1241                         if(!sv_taunt)
1242                                 break;
1243                         if(sv_gentle)
1244                                 break;
1245                         tauntrand = random();
1246                         msg_entity = self;
1247                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1248                         {
1249                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1250                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1251                                 else
1252                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1253                         }
1254                         break;
1255                 case VOICETYPE_TAUNT:
1256                         if(self.classname == "player")
1257                                 if(self.deadflag == DEAD_NO)
1258                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1259                         if(!sv_taunt)
1260                                 break;
1261                         if(sv_gentle)
1262                                 break;
1263                         msg_entity = self;
1264                         if (msg_entity.cvar_cl_voice_directional >= 1)
1265                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1266                         else
1267                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1268                         break;
1269                 case VOICETYPE_PLAYERSOUND:
1270                         msg_entity = self;
1271                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1272                         break;
1273                 default:
1274                         backtrace("Invalid voice type!");
1275                         break;
1276         }
1277 }
1278
1279 void GlobalSound(string sample, float chan, float voicetype)
1280 {
1281         float n;
1282         float tauntrand;
1283
1284         if(sample == "")
1285                 return;
1286
1287         tokenize_console(sample);
1288         n = stof(argv(1));
1289         if(n > 0)
1290                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1291         else
1292                 sample = strcat(argv(0), ".wav"); // randomization
1293
1294         switch(voicetype)
1295         {
1296                 case VOICETYPE_LASTATTACKER_ONLY:
1297                         if(self.pusher)
1298                         {
1299                                 msg_entity = self.pusher;
1300                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1301                                 {
1302                                         if(msg_entity.cvar_cl_voice_directional == 1)
1303                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1304                                         else
1305                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1306                                 }
1307                         }
1308                         break;
1309                 case VOICETYPE_LASTATTACKER:
1310                         if(self.pusher)
1311                         {
1312                                 msg_entity = self.pusher;
1313                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1314                                 {
1315                                         if(msg_entity.cvar_cl_voice_directional == 1)
1316                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1317                                         else
1318                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1319                                 }
1320                                 msg_entity = self;
1321                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1322                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1323                         }
1324                         break;
1325                 case VOICETYPE_TEAMRADIO:
1326                         FOR_EACH_REALCLIENT(msg_entity)
1327                                 if(!teamplay || msg_entity.team == self.team)
1328                                 {
1329                                         if(msg_entity.cvar_cl_voice_directional == 1)
1330                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1331                                         else
1332                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1333                                 }
1334                         break;
1335                 case VOICETYPE_AUTOTAUNT:
1336                         if(!sv_autotaunt)
1337                                 break;
1338                         if(!sv_taunt)
1339                                 break;
1340                         if(sv_gentle)
1341                                 break;
1342                         tauntrand = random();
1343                         FOR_EACH_REALCLIENT(msg_entity)
1344                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1345                                 {
1346                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1347                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1348                                         else
1349                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1350                                 }
1351                         break;
1352                 case VOICETYPE_TAUNT:
1353                         if(self.classname == "player")
1354                                 if(self.deadflag == DEAD_NO)
1355                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1356                         if(!sv_taunt)
1357                                 break;
1358                         if(sv_gentle)
1359                                 break;
1360                         FOR_EACH_REALCLIENT(msg_entity)
1361                         {
1362                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1363                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1364                                 else
1365                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1366                         }
1367                         break;
1368                 case VOICETYPE_PLAYERSOUND:
1369                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1370                         break;
1371                 default:
1372                         backtrace("Invalid voice type!");
1373                         break;
1374         }
1375 }
1376
1377 void PlayerSound(.string samplefield, float chan, float voicetype)
1378 {
1379         GlobalSound(self.samplefield, chan, voicetype);
1380 }
1381
1382 void VoiceMessage(string type, string msg)
1383 {
1384         var .string sample;
1385         float voicetype, ownteam;
1386         float flood;
1387         sample = GetVoiceMessageSampleField(type);
1388
1389         if(GetPlayerSoundSampleField_notFound)
1390         {
1391                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1392                 return;
1393         }
1394
1395         voicetype = GetVoiceMessageVoiceType(type);
1396         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1397
1398         flood = Say(self, ownteam, world, msg, 1);
1399
1400         if (flood > 0)
1401                 GlobalSound(self.sample, CH_VOICE, voicetype);
1402         else if (flood < 0)
1403                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1404 }
1405
1406 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1407 {
1408 //      show_message
1409 //      0 (00) automove centerprint, admin message
1410 //      1 (01) automove centerprint, no admin message
1411 //      2 (10) no centerprint, admin message
1412 //      3 (11) no centerprint, no admin message
1413
1414         float lockteams_backup;
1415
1416         lockteams_backup = lockteams;  // backup any team lock
1417
1418         lockteams = 0;  // disable locked teams
1419
1420         TeamchangeFrags(client);  // move the players frags
1421         SetPlayerColors(client, team_colour - 1);  // set the players colour
1422         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1423
1424         lockteams = lockteams_backup;  // restore the team lock
1425
1426         LogTeamchange(client.playerid, client.team, type);
1427
1428         if not(show_message & 1) // admin message
1429                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1430
1431         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1432 }