qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/bot/default/waypoints.qh>
  50 #include <server/campaign.qh>
  51 #include <server/chat.qh>
  52 #include <server/cheats.qh>
  53 #include <server/clientkill.qh>
  54 #include <server/command/banning.qh>
  55 #include <server/command/cmd.qh>
  56 #include <server/command/common.qh>
  57 #include <server/command/vote.qh>
  58 #include <server/compat/quake3.qh>
  59 #include <server/damage.qh>
  60 #include <server/gamelog.qh>
  61 #include <server/handicap.qh>
  62 #include <server/hook.qh>
  63 #include <server/impulse.qh>
  64 #include <server/intermission.qh>
  65 #include <server/ipban.qh>
  66 #include <server/main.qh>
  67 #include <server/mutators/_mod.qh>
  68 #include <server/player.qh>
  69 #include <server/portals.qh>
  70 #include <server/race.qh>
  71 #include <server/scores.qh>
  72 #include <server/scores_rules.qh>
  73 #include <server/spawnpoints.qh>
  74 #include <server/teamplay.qh>
  75 #include <server/weapons/accuracy.qh>
  76 #include <server/weapons/common.qh>
  77 #include <server/weapons/hitplot.qh>
  78 #include <server/weapons/selection.qh>
  79 #include <server/weapons/tracing.qh>
  80 #include <server/weapons/weaponsystem.qh>
  81 #include <server/world.qh>
  82
  83 STATIC_METHOD(Client, Add, void(Client this, int _team))
  84 {
  85     ClientConnect(this);
  86     TRANSMUTE(Player, this);
  87     this.frame = 12; // 7
  88     this.team = _team;
  89     PutClientInServer(this);
  90 }
  91
  92 STATIC_METHOD(Client, Remove, void(Client this))
  93 {
  94     TRANSMUTE(Observer, this);
  95     PutClientInServer(this);
  96     ClientDisconnect(this);
  97 }
  98
  99 void send_CSQC_teamnagger() {
 100         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 101 }
 102
 103 int CountSpectators(entity player, entity to)
 104 {
 105         if(!player) { return 0; } // not sure how, but best to be safe
 106
 107         int spec_count = 0;
 108
 109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 110         {
 111                 spec_count++;
 112         });
 113
 114         return spec_count;
 115 }
 116
 117 void WriteSpectators(entity player, entity to)
 118 {
 119         if(!player) { return; } // not sure how, but best to be safe
 120
 121         int spec_count = 0;
 122         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 123         {
 124                 if(spec_count >= MAX_SPECTATORS)
 125                         break;
 126                 WriteByte(MSG_ENTITY, num_for_edict(it));
 127                 ++spec_count;
 128         });
 129 }
 130
 131 bool ClientData_Send(entity this, entity to, int sf)
 132 {
 133         assert(to == this.owner, return false);
 134
 135         entity e = to;
 136         if (IS_SPEC(e)) e = e.enemy;
 137
 138         sf = 0;
 139         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 140         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 141         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 142         if (observe_blocked_if_eliminated && INGAME(to))
 143                                         sf |= BIT(3); // observing blocked
 144         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 145                                         sf |= BIT(4); // show spectators
 146
 147         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 148         WriteByte(MSG_ENTITY, sf);
 149
 150         if (sf & BIT(1))
 151                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 152
 153         if(sf & BIT(4))
 154         {
 155                 float specs = CountSpectators(e, to);
 156                 WriteByte(MSG_ENTITY, specs);
 157                 WriteSpectators(e, to);
 158         }
 159
 160         return true;
 161 }
 162
 163 void ClientData_Attach(entity this)
 164 {
 165         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 166         CS(this).clientdata.drawonlytoclient = this;
 167         CS(this).clientdata.owner = this;
 168 }
 169
 170 void ClientData_Detach(entity this)
 171 {
 172         delete(CS(this).clientdata);
 173         CS(this).clientdata = NULL;
 174 }
 175
 176 void ClientData_Touch(entity e)
 177 {
 178         entity cd = CS(e).clientdata;
 179         if (cd) { cd.SendFlags = 1; }
 180
 181         // make it spectatable
 182         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 183         {
 184                 entity cd = CS(it).clientdata;
 185                 if (cd) { cd.SendFlags = 1; }
 186         });
 187 }
 188
 189
 190 /*
 191 =============
 192 CheckPlayerModel
 193
 194 Checks if the argument string can be a valid playermodel.
 195 Returns a valid one in doubt.
 196 =============
 197 */
 198 string FallbackPlayerModel;
 199 string CheckPlayerModel(string plyermodel) {
 200         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 201         {
 202                 // note: we cannot summon Don Strunzone here, some player may
 203                 // still have the model string set. In case anyone manages how
 204                 // to change a cvar default, we'll have a small leak here.
 205                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 206         }
 207         // only in right path
 208         if(substring(plyermodel, 0, 14) != "models/player/")
 209                 return FallbackPlayerModel;
 210         // only good file extensions
 211         if(substring(plyermodel, -4, 4) != ".iqm"
 212                 && substring(plyermodel, -4, 4) != ".zym"
 213                 && substring(plyermodel, -4, 4) != ".dpm"
 214                 && substring(plyermodel, -4, 4) != ".md3"
 215                 && substring(plyermodel, -4, 4) != ".psk")
 216         {
 217                 return FallbackPlayerModel;
 218         }
 219         // forbid the LOD models
 220         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 221                 return FallbackPlayerModel;
 222         if(plyermodel != strtolower(plyermodel))
 223                 return FallbackPlayerModel;
 224         // also, restrict to server models
 225         if(autocvar_sv_servermodelsonly)
 226         {
 227                 if(!fexists(plyermodel))
 228                         return FallbackPlayerModel;
 229         }
 230         return plyermodel;
 231 }
 232
 233 void setplayermodel(entity e, string modelname)
 234 {
 235         precache_model(modelname);
 236         _setmodel(e, modelname);
 237         player_setupanimsformodel(e);
 238         if(!autocvar_g_debug_globalsounds)
 239                 UpdatePlayerSounds(e);
 240 }
 241
 242 /** putting a client as observer in the server */
 243 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 244 {
 245         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 246         bool recount_ready = false;
 247         PlayerState_detach(this);
 248
 249         if (IS_PLAYER(this))
 250         {
 251                 if(GetResource(this, RES_HEALTH) >= 1)
 252                 {
 253                         // despawn effect
 254                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 255                 }
 256
 257                 // was a player, recount votes and ready status
 258                 if(IS_REAL_CLIENT(this))
 259                 {
 260                         if (vote_called) { VoteCount(false); }
 261                         this.ready = false;
 262                         if (warmup_stage || game_starttime > time) recount_ready = true;
 263                 }
 264                 entcs_update_players(this);
 265         }
 266
 267         if (use_spawnpoint)
 268         {
 269                 entity spot = SelectSpawnPoint(this, true);
 270                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 271                 this.angles = vec2(spot.angles);
 272                 // offset it so that the spectator spawns higher off the ground, looks better this way
 273                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 274         }
 275         else // change origin to restore previous view origin
 276                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 277         this.fixangle = true;
 278
 279         if (IS_REAL_CLIENT(this))
 280         {
 281                 msg_entity = this;
 282                 WriteByte(MSG_ONE, SVC_SETVIEW);
 283                 WriteEntity(MSG_ONE, this);
 284         }
 285         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 286         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 287         if(!autocvar_g_debug_globalsounds)
 288         {
 289                 // needed for player sounds
 290                 this.model = "";
 291                 FixPlayermodel(this);
 292         }
 293         setmodel(this, MDL_Null);
 294         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 295         this.view_ofs = '0 0 0';
 296
 297         RemoveGrapplingHooks(this);
 298         Portal_ClearAll(this);
 299         Unfreeze(this, false);
 300         SetSpectatee(this, NULL);
 301
 302         if (this.alivetime)
 303         {
 304                 if (!warmup_stage)
 305                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 306                 this.alivetime = 0;
 307         }
 308
 309         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 310
 311         TRANSMUTE(Observer, this);
 312
 313         if(recount_ready) ReadyCount(); // FIXME: please add comment about why this is delayed
 314
 315         WaypointSprite_PlayerDead(this);
 316         accuracy_resend(this);
 317
 318         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 319                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 320
 321         CS(this).spectatortime = time;
 322         if(this.bot_attack)
 323                 IL_REMOVE(g_bot_targets, this);
 324         this.bot_attack = false;
 325         if(this.monster_attack)
 326                 IL_REMOVE(g_monster_targets, this);
 327         this.monster_attack = false;
 328         STAT(HUD, this) = HUD_NORMAL;
 329         this.iscreature = false;
 330         this.teleportable = TELEPORT_SIMPLE;
 331         if(this.damagedbycontents)
 332                 IL_REMOVE(g_damagedbycontents, this);
 333         this.damagedbycontents = false;
 334         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 335         SetSpectatee_status(this, etof(this));
 336         this.takedamage = DAMAGE_NO;
 337         this.solid = SOLID_NOT;
 338         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 339         this.flags = FL_CLIENT | FL_NOTARGET;
 340         this.effects = 0;
 341         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 342         this.pauserotarmor_finished = 0;
 343         this.pauserothealth_finished = 0;
 344         this.pauseregen_finished = 0;
 345         this.damageforcescale = 0;
 346         this.death_time = 0;
 347         this.respawn_flags = 0;
 348         this.respawn_time = 0;
 349         STAT(RESPAWN_TIME, this) = 0;
 350         this.alpha = 0;
 351         this.scale = 0;
 352         this.fade_time = 0;
 353         this.pain_finished = 0;
 354         STAT(AIR_FINISHED, this) = 0;
 355         //this.dphitcontentsmask = 0;
 356         this.dphitcontentsmask = DPCONTENTS_SOLID;
 357         if (autocvar_g_playerclip_collisions)
 358                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 359         this.pushltime = 0;
 360         this.istypefrag = 0;
 361         setthink(this, func_null);
 362         this.nextthink = 0;
 363         this.deadflag = DEAD_NO;
 364         UNSET_DUCKED(this);
 365         STAT(REVIVE_PROGRESS, this) = 0;
 366         this.revival_time = 0;
 367         this.draggable = drag_undraggable;
 368
 369         player_powerups_remove_all(this);
 370         this.items = 0;
 371         STAT(WEAPONS, this) = '0 0 0';
 372         this.drawonlytoclient = this;
 373
 374         this.viewloc = NULL;
 375
 376         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 377
 378         this.weaponmodel = "";
 379         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 380         {
 381                 this.weaponentities[slot] = NULL;
 382         }
 383         this.exteriorweaponentity = NULL;
 384         CS(this).killcount = FRAGS_SPECTATOR;
 385         this.velocity = '0 0 0';
 386         this.avelocity = '0 0 0';
 387         this.punchangle = '0 0 0';
 388         this.punchvector = '0 0 0';
 389         this.oldvelocity = this.velocity;
 390         this.event_damage = func_null;
 391         this.event_heal = func_null;
 392
 393         for(int slot = 0; slot < MAX_AXH; ++slot)
 394         {
 395                 entity axh = this.(AuxiliaryXhair[slot]);
 396                 this.(AuxiliaryXhair[slot]) = NULL;
 397
 398                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 399                         delete(axh);
 400         }
 401
 402         if (mutator_returnvalue)
 403         {
 404                 // mutator prevents resetting teams+score
 405         }
 406         else
 407         {
 408                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 409                 this.frags = FRAGS_SPECTATOR;
 410         }
 411
 412         bot_relinkplayerlist();
 413
 414         if (CS(this).just_joined)
 415                 CS(this).just_joined = false;
 416 }
 417
 418 int player_getspecies(entity this)
 419 {
 420         get_model_parameters(this.model, this.skin);
 421         int s = get_model_parameters_species;
 422         get_model_parameters(string_null, 0);
 423         if (s < 0) return SPECIES_HUMAN;
 424         return s;
 425 }
 426
 427 .float model_randomizer;
 428 void FixPlayermodel(entity player)
 429 {
 430         string defaultmodel = "";
 431         int defaultskin = 0;
 432         if(autocvar_sv_defaultcharacter)
 433         {
 434                 if(teamplay)
 435                 {
 436                         switch(player.team)
 437                         {
 438                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 439                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 440                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 441                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 442                         }
 443                 }
 444
 445                 if(defaultmodel == "")
 446                 {
 447                         defaultmodel = autocvar_sv_defaultplayermodel;
 448                         defaultskin = autocvar_sv_defaultplayerskin;
 449                 }
 450
 451                 int n = tokenize_console(defaultmodel);
 452                 if(n > 0)
 453                 {
 454                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 455                         // However, do NOT randomize if the player-selected model is in the list.
 456                         for (int i = 0; i < n; ++i)
 457                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 458                                         defaultmodel = argv(i);
 459                 }
 460
 461                 int i = strstrofs(defaultmodel, ":", 0);
 462                 if(i >= 0)
 463                 {
 464                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 465                         defaultmodel = substring(defaultmodel, 0, i);
 466                 }
 467         }
 468         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 469         {
 470                 if(teamplay)
 471                 {
 472                         switch(player.team)
 473                         {
 474                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 475                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 476                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 477                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 478                         }
 479                 }
 480
 481                 if(!defaultskin)
 482                         defaultskin = autocvar_sv_defaultplayerskin;
 483         }
 484
 485         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 486         defaultmodel = M_ARGV(0, string);
 487         defaultskin = M_ARGV(1, int);
 488
 489         bool chmdl = false;
 490         int oldskin;
 491         if(defaultmodel != "")
 492         {
 493                 if (defaultmodel != player.model)
 494                 {
 495                         vector m1 = player.mins;
 496                         vector m2 = player.maxs;
 497                         setplayermodel (player, defaultmodel);
 498                         setsize (player, m1, m2);
 499                         chmdl = true;
 500                 }
 501
 502                 oldskin = player.skin;
 503                 player.skin = defaultskin;
 504         } else {
 505                 if (player.playermodel != player.model || player.playermodel == "")
 506                 {
 507                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 508                         vector m1 = player.mins;
 509                         vector m2 = player.maxs;
 510                         setplayermodel (player, player.playermodel);
 511                         setsize (player, m1, m2);
 512                         chmdl = true;
 513                 }
 514
 515                 if(!autocvar_sv_defaultcharacterskin)
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = stof(player.playerskin);
 519                 }
 520                 else
 521                 {
 522                         oldskin = player.skin;
 523                         player.skin = defaultskin;
 524                 }
 525         }
 526
 527         if(chmdl || oldskin != player.skin) // model or skin has changed
 528         {
 529                 player.species = player_getspecies(player); // update species
 530                 if(!autocvar_g_debug_globalsounds)
 531                         UpdatePlayerSounds(player); // update skin sounds
 532         }
 533
 534         if(!teamplay)
 535                 if(strlen(autocvar_sv_defaultplayercolors))
 536                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 537                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 538 }
 539
 540 void GiveWarmupResources(entity this)
 541 {
 542         SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 543         SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 544         SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 545         SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 546         SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 547         SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 548         SetResource(this, RES_HEALTH, warmup_start_health);
 549         SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 550         STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 551 }
 552
 553 void PutPlayerInServer(entity this)
 554 {
 555         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 556
 557         PlayerState_attach(this);
 558         accuracy_resend(this);
 559
 560         if (teamplay && this.bot_forced_team)
 561                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 562
 563         if (this.team < 0)
 564                 TeamBalance_JoinBestTeam(this);
 565
 566         entity spot = SelectSpawnPoint(this, false);
 567         if (!spot) {
 568                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 569                 return; // spawn failed
 570         }
 571
 572         TRANSMUTE(Player, this);
 573
 574         CS(this).wasplayer = true;
 575         this.iscreature = true;
 576         this.teleportable = TELEPORT_NORMAL;
 577         if(!this.damagedbycontents)
 578                 IL_PUSH(g_damagedbycontents, this);
 579         this.damagedbycontents = true;
 580         set_movetype(this, MOVETYPE_WALK);
 581         this.solid = SOLID_SLIDEBOX;
 582         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 583         if (autocvar_g_playerclip_collisions)
 584                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 585         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 586                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 587         this.frags = FRAGS_PLAYER;
 588         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 589         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 590         if (autocvar__notarget)
 591                 this.flags |= FL_NOTARGET;
 592         this.takedamage = DAMAGE_AIM;
 593         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 594
 595         if (warmup_stage)
 596                 GiveWarmupResources(this);
 597         else
 598         {
 599                 SetResource(this, RES_SHELLS, start_ammo_shells);
 600                 SetResource(this, RES_BULLETS, start_ammo_nails);
 601                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 602                 SetResource(this, RES_CELLS, start_ammo_cells);
 603                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 604                 SetResource(this, RES_FUEL, start_ammo_fuel);
 605                 SetResource(this, RES_HEALTH, start_health);
 606                 SetResource(this, RES_ARMOR, start_armorvalue);
 607                 STAT(WEAPONS, this) = start_weapons;
 608                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 609                 {
 610                         GiveRandomWeapons(this, random_start_weapons_count,
 611                                 autocvar_g_random_start_weapons, random_start_ammo);
 612                 }
 613         }
 614         SetSpectatee_status(this, 0);
 615
 616         PS(this).dual_weapons = '0 0 0';
 617
 618         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 619                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 620
 621         this.items = start_items;
 622
 623         float shieldtime = time + autocvar_g_spawnshieldtime;
 624
 625         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 626         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 627         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 628         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 629         if (!sv_ready_restart_after_countdown && time < game_starttime)
 630         {
 631                 float f = game_starttime - time;
 632                 shieldtime += f;
 633                 this.pauserotarmor_finished += f;
 634                 this.pauserothealth_finished += f;
 635                 this.pauseregen_finished += f;
 636         }
 637
 638         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 639
 640         this.damageforcescale = autocvar_g_player_damageforcescale;
 641         this.death_time = 0;
 642         this.respawn_flags = 0;
 643         this.respawn_time = 0;
 644         STAT(RESPAWN_TIME, this) = 0;
 645         // DP model scaling uses 1/16 accuracy and 13/16 is closest to 56/69
 646         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.8125 : autocvar_sv_player_scale);
 647         this.fade_time = 0;
 648         this.pain_finished = 0;
 649         this.pushltime = 0;
 650         setthink(this, func_null); // players have no think function
 651         this.nextthink = 0;
 652         this.dmg_team = 0;
 653         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 654
 655         this.deadflag = DEAD_NO;
 656
 657         this.angles = spot.angles;
 658         this.angles_z = 0; // never spawn tilted even if the spot says to
 659         if (IS_BOT_CLIENT(this))
 660         {
 661                 this.v_angle = this.angles;
 662                 bot_aim_reset(this);
 663         }
 664         this.fixangle = true; // turn this way immediately
 665         this.oldvelocity = this.velocity = '0 0 0';
 666         this.avelocity = '0 0 0';
 667         this.punchangle = '0 0 0';
 668         this.punchvector = '0 0 0';
 669
 670         STAT(REVIVE_PROGRESS, this) = 0;
 671         this.revival_time = 0;
 672
 673         STAT(AIR_FINISHED, this) = 0;
 674         this.waterlevel = WATERLEVEL_NONE;
 675         this.watertype = CONTENT_EMPTY;
 676
 677         entity spawnevent = new_pure(spawnevent);
 678         spawnevent.owner = this;
 679         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 680
 681         // Cut off any still running player sounds.
 682         stopsound(this, CH_PLAYER_SINGLE);
 683
 684         this.model = "";
 685         FixPlayermodel(this);
 686         this.drawonlytoclient = NULL;
 687
 688         this.viewloc = NULL;
 689
 690         for(int slot = 0; slot < MAX_AXH; ++slot)
 691         {
 692                 entity axh = this.(AuxiliaryXhair[slot]);
 693                 this.(AuxiliaryXhair[slot]) = NULL;
 694
 695                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 696                         delete(axh);
 697         }
 698
 699         this.spawnpoint_targ = NULL;
 700
 701         UNSET_DUCKED(this);
 702         this.view_ofs = STAT(PL_VIEW_OFS, this);
 703         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 704         this.spawnorigin = spot.origin;
 705         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 706         // don't reset back to last position, even if new position is stuck in solid
 707         this.oldorigin = this.origin;
 708         if(this.conveyor)
 709                 IL_REMOVE(g_conveyed, this);
 710         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 711         if(this.swampslug)
 712                 IL_REMOVE(g_swamped, this);
 713         this.swampslug = NULL;
 714         this.swamp_interval = 0;
 715         if(this.ladder_entity)
 716                 IL_REMOVE(g_ladderents, this);
 717         this.ladder_entity = NULL;
 718         IL_EACH(g_counters, it.realowner == this,
 719         {
 720                 delete(it);
 721         });
 722         STAT(HUD, this) = HUD_NORMAL;
 723
 724         this.event_damage = PlayerDamage;
 725         this.event_heal = PlayerHeal;
 726
 727         this.draggable = func_null;
 728
 729         if(!this.bot_attack)
 730                 IL_PUSH(g_bot_targets, this);
 731         this.bot_attack = true;
 732         if(!this.monster_attack)
 733                 IL_PUSH(g_monster_targets, this);
 734         this.monster_attack = true;
 735         navigation_dynamicgoal_init(this, false);
 736
 737         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 738
 739         // player was spectator
 740         if (CS(this).killcount == FRAGS_SPECTATOR) {
 741                 PlayerScore_Clear(this);
 742                 CS(this).killcount = 0;
 743                 CS(this).startplaytime = time;
 744         }
 745
 746         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 747         {
 748                 .entity weaponentity = weaponentities[slot];
 749                 CL_SpawnWeaponentity(this, weaponentity);
 750         }
 751         this.alpha = default_player_alpha;
 752         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 753         this.exteriorweaponentity.alpha = default_weapon_alpha;
 754
 755         this.speedrunning = false;
 756
 757         this.counter_cnt = 0;
 758         this.fragsfilter_cnt = 0;
 759
 760         target_voicescript_clear(this);
 761
 762         // reset fields the weapons may use
 763         FOREACH(Weapons, true, {
 764                 it.wr_resetplayer(it, this);
 765                         // reload all reloadable weapons
 766                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 767                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 768                         {
 769                                 .entity weaponentity = weaponentities[slot];
 770                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 771                         }
 772                 }
 773         });
 774
 775         Unfreeze(this, false);
 776
 777         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 778         {
 779                 string s = spot.target;
 780                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 781                         spot.target = string_null;
 782                 SUB_UseTargets(spot, this, NULL);
 783                 if(g_assault || g_race)
 784                         spot.target = s;
 785         }
 786
 787         if (autocvar_spawn_debug)
 788         {
 789                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 790                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 791         }
 792
 793         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 794         {
 795                 .entity weaponentity = weaponentities[slot];
 796                 entity w_ent = this.(weaponentity);
 797                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 798                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 799                 else
 800                         w_ent.m_switchweapon = WEP_Null;
 801                 w_ent.m_weapon = WEP_Null;
 802                 w_ent.weaponname = "";
 803                 w_ent.m_switchingweapon = WEP_Null;
 804                 w_ent.cnt = -1;
 805         }
 806
 807         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 808
 809         if (CS(this).impulse) ImpulseCommands(this);
 810
 811         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 812         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 813         {
 814                 .entity weaponentity = weaponentities[slot];
 815                 W_WeaponFrame(this, weaponentity);
 816         }
 817
 818         if (!warmup_stage && !this.alivetime)
 819                 this.alivetime = time;
 820
 821         antilag_clear(this, CS(this));
 822
 823         if (warmup_stage < 0 || warmup_stage > 1)
 824                 ReadyCount();
 825 }
 826
 827 /** Called when a client spawns in the server */
 828 void PutClientInServer(entity this)
 829 {
 830         if (IS_REAL_CLIENT(this)) {
 831                 msg_entity = this;
 832                 WriteByte(MSG_ONE, SVC_SETVIEW);
 833                 WriteEntity(MSG_ONE, this);
 834         }
 835         if (game_stopped)
 836                 TRANSMUTE(Observer, this);
 837
 838         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 839         SetSpectatee(this, NULL);
 840
 841         // reset player keys
 842         if(PS(this))
 843                 PS(this).itemkeys = 0;
 844
 845         MUTATOR_CALLHOOK(PutClientInServer, this);
 846
 847         if (IS_OBSERVER(this)) {
 848                 PutObserverInServer(this, false, use_spawnpoint);
 849         } else if (IS_PLAYER(this)) {
 850                 PutPlayerInServer(this);
 851         }
 852
 853         bot_relinkplayerlist();
 854 }
 855
 856 // TODO do we need all these fields, or should we stop autodetecting runtime
 857 // changes and just have a console command to update this?
 858 bool ClientInit_SendEntity(entity this, entity to, int sf)
 859 {
 860         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 861         return = true;
 862         msg_entity = to;
 863         // MSG_INIT replacement
 864         // TODO: make easier to use
 865         Registry_send_all();
 866         W_PROP_reload(MSG_ONE, to);
 867         ClientInit_misc(this);
 868         MUTATOR_CALLHOOK(Ent_Init);
 869 }
 870 void ClientInit_misc(entity this)
 871 {
 872         int channel = MSG_ONE;
 873         WriteHeader(channel, ENT_CLIENT_INIT);
 874         WriteByte(channel, g_nexball_meter_period * 32);
 875         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 876         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 877         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 878         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 879         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 880         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 881         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 882         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 883
 884         if(autocvar_sv_foginterval && world.fog != "")
 885                 WriteString(channel, world.fog);
 886         else
 887                 WriteString(channel, "");
 888         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 889         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 890         WriteByte(channel, serverflags);
 891         WriteCoord(channel, autocvar_g_trueaim_minrange);
 892 }
 893
 894 void ClientInit_CheckUpdate(entity this)
 895 {
 896         this.nextthink = time;
 897         if(this.count != autocvar_g_balance_armor_blockpercent)
 898         {
 899                 this.count = autocvar_g_balance_armor_blockpercent;
 900                 this.SendFlags |= 1;
 901         }
 902         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 903         {
 904                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 905                 this.SendFlags |= 1;
 906         }
 907 }
 908
 909 void ClientInit_Spawn()
 910 {
 911         entity e = new_pure(clientinit);
 912         setthink(e, ClientInit_CheckUpdate);
 913         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 914
 915         ClientInit_CheckUpdate(e);
 916 }
 917
 918 /*
 919 =============
 920 SetNewParms
 921 =============
 922 */
 923 void SetNewParms ()
 924 {
 925         // initialize parms for a new player
 926         parm1 = -(86400 * 366);
 927
 928         MUTATOR_CALLHOOK(SetNewParms);
 929 }
 930
 931 /*
 932 =============
 933 SetChangeParms
 934 =============
 935 */
 936 void SetChangeParms (entity this)
 937 {
 938         // save parms for level change
 939         parm1 = CS(this).parm_idlesince - time;
 940
 941         MUTATOR_CALLHOOK(SetChangeParms);
 942 }
 943
 944 /*
 945 =============
 946 DecodeLevelParms
 947 =============
 948 */
 949 void DecodeLevelParms(entity this)
 950 {
 951         // load parms
 952         CS(this).parm_idlesince = parm1;
 953         if (CS(this).parm_idlesince == -(86400 * 366))
 954                 CS(this).parm_idlesince = time;
 955
 956         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 957         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 958
 959         MUTATOR_CALLHOOK(DecodeLevelParms);
 960 }
 961
 962 void FixClientCvars(entity e)
 963 {
 964         // send prediction settings to the client
 965         if(autocvar_g_antilag == 3) // client side hitscan
 966                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 967         if(autocvar_sv_gentle)
 968                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 969
 970         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 971         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 972
 973         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 974
 975         MUTATOR_CALLHOOK(FixClientCvars, e);
 976 }
 977
 978 bool findinlist_abbrev(string tofind, string list)
 979 {
 980         if(list == "" || tofind == "")
 981                 return false; // empty list or search, just return
 982
 983         // this function allows abbreviated strings!
 984         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 985         {
 986                 return true;
 987         });
 988
 989         return false;
 990 }
 991
 992 bool PlayerInIPList(entity p, string iplist)
 993 {
 994         // some safety checks (never allow local?)
 995         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 996                 return false;
 997
 998         return findinlist_abbrev(p.netaddress, iplist);
 999 }
1000
1001 bool PlayerInIDList(entity p, string idlist)
1002 {
1003         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1004         if(!p.crypto_idfp)
1005                 return false;
1006
1007         return findinlist_abbrev(p.crypto_idfp, idlist);
1008 }
1009
1010 bool PlayerInList(entity player, string list)
1011 {
1012         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1013 }
1014
1015 #ifdef DP_EXT_PRECONNECT
1016 /*
1017 =============
1018 ClientPreConnect
1019
1020 Called once (not at each match start) when a client begins a connection to the server
1021 =============
1022 */
1023 void ClientPreConnect(entity this)
1024 {
1025         if(autocvar_sv_eventlog)
1026         {
1027                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1028                         this.playerid,
1029                         etof(this),
1030                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1031                 ));
1032         }
1033 }
1034 #endif
1035
1036 // NOTE csqc uses the active mutators list sent by this function
1037 // to understand which mutators are enabled
1038 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1039 void SendWelcomeMessage(entity this, int msg_type)
1040 {
1041         WriteByte(msg_type, boolean(autocvar_g_campaign));
1042         if (boolean(autocvar_g_campaign))
1043         {
1044                 WriteString(msg_type, Campaign_GetTitle());
1045                 WriteByte(msg_type, Campaign_GetLevelNum());
1046                 WriteString(msg_type, Campaign_GetMessage());
1047                 return;
1048         }
1049         WriteString(msg_type, autocvar_hostname);
1050         WriteString(msg_type, autocvar_g_xonoticversion);
1051         WriteByte(msg_type, CS(this).version_mismatch);
1052         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1053         WriteByte(msg_type, autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers);
1054         WriteByte(msg_type, GetPlayerLimit());
1055
1056         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1057         string modifications = M_ARGV(0, string);
1058
1059         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1060                 modifications = strcat(modifications, ", No start weapons");
1061         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1062                 modifications = strcat(modifications, ", Low gravity");
1063         if(g_weapon_stay && !g_cts)
1064                 modifications = strcat(modifications, ", Weapons stay");
1065         if(autocvar_g_jetpack)
1066                 modifications = strcat(modifications, ", Jetpack");
1067         modifications = substring(modifications, 2, strlen(modifications) - 2);
1068
1069         WriteString(msg_type, modifications);
1070
1071         WriteString(msg_type, g_weaponarena_list);
1072
1073         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1074         {
1075                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1076                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1077         }
1078
1079         WriteString(msg_type, cache_mutatormsg);
1080
1081         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1082 }
1083
1084 /**
1085 =============
1086 ClientConnect
1087
1088 Called when a client connects to the server
1089 =============
1090 */
1091 void ClientConnect(entity this)
1092 {
1093         if (Ban_MaybeEnforceBanOnce(this)) return;
1094         assert(!IS_CLIENT(this), return);
1095         this.flags |= FL_CLIENT;
1096         assert(player_count >= 0, player_count = 0);
1097
1098         TRANSMUTE(Client, this);
1099         CS(this).version_nagtime = time + 10 + random() * 10;
1100
1101         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1102
1103         bot_clientconnect(this);
1104
1105         Player_DetermineForcedTeam(this);
1106
1107         TRANSMUTE(Observer, this);
1108
1109         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1110
1111         // always track bots, don't ask for cl_allow_uidtracking
1112         if (IS_BOT_CLIENT(this))
1113                 PlayerStats_GameReport_AddPlayer(this);
1114         else
1115                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1116
1117         if (autocvar_sv_eventlog)
1118                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1119
1120         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1121
1122         stuffcmd(this, clientstuff, "\n");
1123         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1124
1125         FixClientCvars(this);
1126
1127         // get version info from player
1128         stuffcmd(this, "cmd clientversion $gameversion\n");
1129
1130         // notify about available teams
1131         if (teamplay)
1132         {
1133                 entity balance = TeamBalance_CheckAllowedTeams(this);
1134                 int t = TeamBalance_GetAllowedTeams(balance);
1135                 TeamBalance_Destroy(balance);
1136                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1137         }
1138         else
1139         {
1140                 stuffcmd(this, "set _teams_available 0\n");
1141         }
1142
1143         bot_relinkplayerlist();
1144
1145         CS(this).spectatortime = time;
1146         if (blockSpectators)
1147         {
1148                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1149         }
1150
1151         CS(this).jointime = time;
1152
1153         if (IS_REAL_CLIENT(this))
1154         {
1155                 if (g_weaponarena_weapons == WEPSET(TUBA))
1156                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1157                 // quickmenu file must be put in a subfolder with an unique name
1158                 // to reduce chances of overriding custom client quickmenus
1159                 if (waypointeditor_enabled)
1160                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1161                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1162                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1163         }
1164
1165         if (!autocvar_sv_foginterval && world.fog != "")
1166                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1167
1168         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
1169                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1170                         send_CSQC_teamnagger();
1171
1172         CSQCMODEL_AUTOINIT(this);
1173
1174         CS(this).model_randomizer = random();
1175
1176         if (IS_REAL_CLIENT(this))
1177                 sv_notice_join(this);
1178
1179         this.move_qcphysics = true;
1180
1181         // update physics stats (players can spawn before physics runs)
1182         Physics_UpdateStats(this);
1183
1184         IL_EACH(g_initforplayer, it.init_for_player, {
1185                 it.init_for_player(it, this);
1186         });
1187
1188         Handicap_Initialize(this);
1189
1190         // playban
1191         if (PlayerInList(this, autocvar_g_playban_list))
1192                 TRANSMUTE(Observer, this);
1193
1194         if (PlayerInList(this, autocvar_g_muteban_list)) // muteban
1195                 CS(this).muted = true;
1196
1197         MUTATOR_CALLHOOK(ClientConnect, this);
1198
1199         if (player_count == 1)
1200         {
1201                 if (autocvar_sv_autopause && server_is_dedicated)
1202                         setpause(0);
1203                 localcmd("\nsv_hook_firstjoin\n");
1204         }
1205 }
1206 /*
1207 =============
1208 ClientDisconnect
1209
1210 Called when a client disconnects from the server
1211 =============
1212 */
1213 .entity chatbubbleentity;
1214 void player_powerups_remove_all(entity this);
1215
1216 void ClientDisconnect(entity this)
1217 {
1218         assert(IS_CLIENT(this), return);
1219
1220         /* from "ignore" command */
1221         strfree(this.ignore_list);
1222         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it.ignore_list,
1223         {
1224                 if(it.crypto_idfp && it.crypto_idfp != "")
1225                         continue;
1226                 string mylist = ignore_removefromlist(it, this);
1227                 if(it.ignore_list)
1228                         strunzone(it.ignore_list);
1229
1230                 it.ignore_list = strzone(mylist);
1231         });
1232         /* from "ignore" command */
1233
1234         PlayerStats_GameReport_FinalizePlayer(this);
1235         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1236         if (CS(this).active_minigame) part_minigame(this);
1237         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1238
1239         if (autocvar_sv_eventlog)
1240                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1241
1242         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1243
1244         if(IS_SPEC(this))
1245                 SetSpectatee(this, NULL);
1246
1247         MUTATOR_CALLHOOK(ClientDisconnect, this);
1248
1249         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1250         strfree(CS_CVAR(this).weaponorder_byimpulse);
1251         ClientState_detach(this);
1252
1253         Portal_ClearAll(this);
1254
1255         Unfreeze(this, false);
1256
1257         RemoveGrapplingHooks(this);
1258
1259         // Here, everything has been done that requires this player to be a client.
1260
1261         this.flags &= ~FL_CLIENT;
1262
1263         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1264         if (this.killindicator) delete(this.killindicator);
1265
1266         IL_EACH(g_counters, it.realowner == this,
1267         {
1268                 delete(it);
1269         });
1270
1271         WaypointSprite_PlayerGone(this);
1272
1273         bot_relinkplayerlist();
1274
1275         strfree(this.clientstatus);
1276         if (this.personal) delete(this.personal);
1277
1278         this.playerid = 0;
1279         if (warmup_stage || game_starttime > time) ReadyCount();
1280         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1281
1282         player_powerups_remove_all(this); // stop powerup sound
1283
1284         ONREMOVE(this);
1285
1286         if (player_count == 0)
1287                 localcmd("\nsv_hook_lastleave\n");
1288 }
1289
1290 void ChatBubbleThink(entity this)
1291 {
1292         this.nextthink = time;
1293         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1294         {
1295                 if(this.owner) // but why can that ever be NULL?
1296                         this.owner.chatbubbleentity = NULL;
1297                 delete(this);
1298                 return;
1299         }
1300
1301         this.mdl = "";
1302
1303         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1304         {
1305                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1306                         this.mdl = "models/sprites/minigame_busy.iqm";
1307                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1308                         this.mdl = "models/misc/chatbubble.spr";
1309         }
1310
1311         if ( this.model != this.mdl )
1312                 _setmodel(this, this.mdl);
1313
1314 }
1315
1316 void UpdateChatBubble(entity this)
1317 {
1318         if (this.alpha < 0)
1319                 return;
1320         // spawn a chatbubble entity if needed
1321         if (!this.chatbubbleentity)
1322         {
1323                 this.chatbubbleentity = new(chatbubbleentity);
1324                 this.chatbubbleentity.owner = this;
1325                 this.chatbubbleentity.exteriormodeltoclient = this;
1326                 setthink(this.chatbubbleentity, ChatBubbleThink);
1327                 this.chatbubbleentity.nextthink = time;
1328                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1329                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1330                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1331                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1332                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1333                 //this.chatbubbleentity.model = "";
1334                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1335         }
1336 }
1337
1338 void calculate_player_respawn_time(entity this)
1339 {
1340         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1341                 return;
1342
1343         float gametype_setting_tmp;
1344         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1345         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1346         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1347         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1348         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1349         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1350
1351         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1352         if (teamplay)
1353         {
1354                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1355                         if(it.team == this.team)
1356                                 ++pcount;
1357                 });
1358                 if (sdelay_small_count == 0)
1359                         sdelay_small_count = 1;
1360                 if (sdelay_large_count == 0)
1361                         sdelay_large_count = 1;
1362         }
1363         else
1364         {
1365                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1366                         ++pcount;
1367                 });
1368                 if (sdelay_small_count == 0)
1369                 {
1370                         if (IS_INDEPENDENT_PLAYER(this))
1371                         {
1372                                 // Players play independently. No point in requiring enemies.
1373                                 sdelay_small_count = 1;
1374                         }
1375                         else
1376                         {
1377                                 // Players play AGAINST each other. Enemies required.
1378                                 sdelay_small_count = 2;
1379                         }
1380                 }
1381                 if (sdelay_large_count == 0)
1382                 {
1383                         if (IS_INDEPENDENT_PLAYER(this))
1384                         {
1385                                 // Players play independently. No point in requiring enemies.
1386                                 sdelay_large_count = 1;
1387                         }
1388                         else
1389                         {
1390                                 // Players play AGAINST each other. Enemies required.
1391                                 sdelay_large_count = 2;
1392                         }
1393                 }
1394         }
1395
1396         float sdelay;
1397
1398         if (pcount <= sdelay_small_count)
1399                 sdelay = sdelay_small;
1400         else if (pcount >= sdelay_large_count)
1401                 sdelay = sdelay_large;
1402         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1403                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1404
1405         if(waves)
1406                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1407         else
1408                 this.respawn_time = time + sdelay;
1409
1410         if(sdelay < sdelay_max)
1411                 this.respawn_time_max = time + sdelay_max;
1412         else
1413                 this.respawn_time_max = this.respawn_time;
1414
1415         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1416                 this.respawn_countdown = 10; // first number to count down from is 10
1417         else
1418                 this.respawn_countdown = -1; // do not count down
1419
1420         if(autocvar_g_forced_respawn)
1421                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1422 }
1423
1424 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1425 // added to the model skins
1426 /*void UpdateColorModHack()
1427 {
1428         float c;
1429         c = this.clientcolors & 15;
1430         // LordHavoc: only bothering to support white, green, red, yellow, blue
1431              if (!teamplay) this.colormod = '0 0 0';
1432         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1433         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1434         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1435         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1436         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1437         else this.colormod = '1 1 1';
1438 }*/
1439
1440 void respawn(entity this)
1441 {
1442         bool damagedbycontents_prev = this.damagedbycontents;
1443         if(this.alpha >= 0)
1444         {
1445                 if(autocvar_g_respawn_ghosts)
1446                 {
1447                         this.solid = SOLID_NOT;
1448                         this.takedamage = DAMAGE_NO;
1449                         this.damagedbycontents = false;
1450                         set_movetype(this, MOVETYPE_FLY);
1451                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1452                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1453                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1454                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1455                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1456                         if(autocvar_g_respawn_ghosts_time > 0)
1457                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1458                 }
1459                 else
1460                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1461         }
1462
1463         CopyBody(this, 1);
1464         this.damagedbycontents = damagedbycontents_prev;
1465
1466         this.effects |= EF_NODRAW; // prevent another CopyBody
1467         PutClientInServer(this);
1468 }
1469
1470 void play_countdown(entity this, float finished, Sound samp)
1471 {
1472         TC(Sound, samp);
1473         float time_left = finished - time;
1474         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1475                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1476 }
1477
1478 // it removes special powerups not handled by StatusEffects
1479 void player_powerups_remove_all(entity this)
1480 {
1481         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1482         {
1483                 // don't play the poweroff sound when the game restarts or the player disconnects
1484                 if (time > game_starttime + 1 && IS_CLIENT(this)
1485                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1486                 {
1487                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1488                 }
1489                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1490                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1491                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1492         }
1493 }
1494
1495 void player_powerups(entity this)
1496 {
1497         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1498                 this.modelflags |= MF_ROCKET;
1499         else
1500                 this.modelflags &= ~MF_ROCKET;
1501
1502         this.effects &= ~EF_NODEPTHTEST;
1503
1504         if (IS_DEAD(this))
1505                 player_powerups_remove_all(this);
1506
1507         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1508                 return;
1509
1510         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1511         int items_prev = this.items;
1512
1513         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1514         {
1515                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1516                 if (this.items & IT_SUPERWEAPON)
1517                 {
1518                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1519                         {
1520                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1521                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1522                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1523                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1524                         }
1525                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1526                         {
1527                                 // don't let them run out
1528                         }
1529                         else
1530                         {
1531                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1532                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1533                                 {
1534                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1535                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1536                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1537                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1538                                 }
1539                         }
1540                 }
1541                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1542                 {
1543                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1544                         {
1545                                 this.items = this.items | IT_SUPERWEAPON;
1546                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1547                                 {
1548                                         if(!g_cts)
1549                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1550                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1551                                 }
1552                         }
1553                         else
1554                         {
1555                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1556                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1557                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1558                         }
1559                 }
1560                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1561                 {
1562                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1563                 }
1564         }
1565
1566         if(autocvar_g_nodepthtestplayers)
1567                 this.effects = this.effects | EF_NODEPTHTEST;
1568
1569         if(autocvar_g_fullbrightplayers)
1570                 this.effects = this.effects | EF_FULLBRIGHT;
1571
1572         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1573 }
1574
1575 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1576 {
1577         if(current > stable)
1578                 return current;
1579         else if(current > stable - 0.25) // when close enough, "snap"
1580                 return stable;
1581         else
1582                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1583 }
1584
1585 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1586 {
1587         if(current < stable)
1588                 return current;
1589         else if(current < stable + 0.25) // when close enough, "snap"
1590                 return stable;
1591         else
1592                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1593 }
1594
1595 void RotRegen(entity this, Resource res, float limit_mod,
1596         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1597         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1598 {
1599         float old = GetResource(this, res);
1600         float current = old;
1601         if(current > rotstable)
1602         {
1603                 if(rotframetime > 0)
1604                 {
1605                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1606                         current = max(rotstable, current - rotlinear * rotframetime);
1607                 }
1608         }
1609         else if(current < regenstable)
1610         {
1611                 if(regenframetime > 0)
1612                 {
1613                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1614                         current = min(regenstable, current + regenlinear * regenframetime);
1615                 }
1616         }
1617
1618         float limit = GetResourceLimit(this, res) * limit_mod;
1619         if(current > limit)
1620                 current = limit;
1621
1622         if (current != old)
1623                 SetResource(this, res, current);
1624 }
1625
1626 void player_regen(entity this)
1627 {
1628         float max_mod, regen_mod, rot_mod, limit_mod;
1629         max_mod = regen_mod = rot_mod = limit_mod = 1;
1630
1631         float regen_health = autocvar_g_balance_health_regen;
1632         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1633         float regen_health_rot = autocvar_g_balance_health_rot;
1634         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1635         float regen_health_stable = autocvar_g_balance_health_regenstable;
1636         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1637         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1638                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1639         max_mod = M_ARGV(1, float);
1640         regen_mod = M_ARGV(2, float);
1641         rot_mod = M_ARGV(3, float);
1642         limit_mod = M_ARGV(4, float);
1643         regen_health = M_ARGV(5, float);
1644         regen_health_linear = M_ARGV(6, float);
1645         regen_health_rot = M_ARGV(7, float);
1646         regen_health_rotlinear = M_ARGV(8, float);
1647         regen_health_stable = M_ARGV(9, float);
1648         regen_health_rotstable = M_ARGV(10, float);
1649
1650         float rotstable, regenstable, rotframetime, regenframetime;
1651
1652         if(!mutator_returnvalue)
1653         if(!STAT(FROZEN, this))
1654         {
1655                 regenstable = autocvar_g_balance_armor_regenstable;
1656                 rotstable = autocvar_g_balance_armor_rotstable;
1657                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1658                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1659                 RotRegen(this, RES_ARMOR, limit_mod,
1660                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1661                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1662
1663                 // NOTE: max_mod is only applied to health
1664                 regenstable = regen_health_stable * max_mod;
1665                 rotstable = regen_health_rotstable * max_mod;
1666                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1667                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1668                 RotRegen(this, RES_HEALTH, limit_mod,
1669                         regenstable, regen_health, regen_health_linear, regenframetime,
1670                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1671         }
1672
1673         // if player rotted to death...  die!
1674         // check this outside above checks, as player may still be able to rot to death
1675         if(GetResource(this, RES_HEALTH) < 1)
1676         {
1677                 if(this.vehicle)
1678                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1679                 if(this.event_damage)
1680                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1681         }
1682
1683         if (!(this.items & IT_UNLIMITED_AMMO))
1684         {
1685                 regenstable = autocvar_g_balance_fuel_regenstable;
1686                 rotstable = autocvar_g_balance_fuel_rotstable;
1687                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1688                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1689                 RotRegen(this, RES_FUEL, 1,
1690                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1691                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1692         }
1693 }
1694
1695 bool zoomstate_set;
1696 void SetZoomState(entity this, float newzoom)
1697 {
1698         if(newzoom != CS(this).zoomstate)
1699         {
1700                 CS(this).zoomstate = newzoom;
1701                 ClientData_Touch(this);
1702         }
1703         zoomstate_set = true;
1704 }
1705
1706 void GetPressedKeys(entity this)
1707 {
1708         MUTATOR_CALLHOOK(GetPressedKeys, this);
1709         if (game_stopped)
1710         {
1711                 CS(this).pressedkeys = 0;
1712                 STAT(PRESSED_KEYS, this) = 0;
1713                 return;
1714         }
1715
1716         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1717         int keys = STAT(PRESSED_KEYS, this);
1718         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1719         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1720         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1721         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1722
1723         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1724         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1725         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1726         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1727         CS(this).pressedkeys = keys; // store for other users
1728
1729         STAT(PRESSED_KEYS, this) = keys;
1730 }
1731
1732 /*
1733 ======================
1734 spectate mode routines
1735 ======================
1736 */
1737
1738 void SpectateCopy(entity this, entity spectatee)
1739 {
1740         TC(Client, this); TC(Client, spectatee);
1741
1742         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1743         PS(this) = PS(spectatee);
1744         this.armortype = spectatee.armortype;
1745         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1746         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1747         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1748         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1749         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1750         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1751         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1752         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1753         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1754         CS(this).impulse = 0;
1755         this.disableclientprediction = 1; // no need to run prediction on a spectator
1756         this.items = spectatee.items;
1757         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1758         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1759         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1760         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1761         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1762         this.punchangle = spectatee.punchangle;
1763         this.view_ofs = spectatee.view_ofs;
1764         this.velocity = spectatee.velocity;
1765         this.dmg_take = spectatee.dmg_take;
1766         this.dmg_save = spectatee.dmg_save;
1767         this.dmg_inflictor = spectatee.dmg_inflictor;
1768         this.v_angle = spectatee.v_angle;
1769         this.angles = spectatee.v_angle;
1770         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1771         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1772         this.viewloc = spectatee.viewloc;
1773         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1774                 this.fixangle = true;
1775         setorigin(this, spectatee.origin);
1776         setsize(this, spectatee.mins, spectatee.maxs);
1777         SetZoomState(this, CS(spectatee).zoomstate);
1778
1779     anticheat_spectatecopy(this, spectatee);
1780         STAT(HUD, this) = STAT(HUD, spectatee);
1781         if(spectatee.vehicle)
1782     {
1783         this.angles = spectatee.v_angle;
1784
1785         //this.fixangle = false;
1786         //this.velocity = spectatee.vehicle.velocity;
1787         this.vehicle_health = spectatee.vehicle_health;
1788         this.vehicle_shield = spectatee.vehicle_shield;
1789         this.vehicle_energy = spectatee.vehicle_energy;
1790         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1791         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1792         this.vehicle_reload1 = spectatee.vehicle_reload1;
1793         this.vehicle_reload2 = spectatee.vehicle_reload2;
1794
1795         //msg_entity = this;
1796
1797        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1798             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1799            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1800            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1801
1802         //WriteByte (MSG_ONE, SVC_SETVIEW);
1803         //    WriteEntity(MSG_ONE, this);
1804         //makevectors(spectatee.v_angle);
1805         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1806     }
1807 }
1808
1809 bool SpectateUpdate(entity this)
1810 {
1811         if(!this.enemy)
1812                 return false;
1813
1814         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1815         {
1816                 SetSpectatee(this, NULL);
1817                 return false;
1818         }
1819
1820         SpectateCopy(this, this.enemy);
1821
1822         return true;
1823 }
1824
1825 bool SpectateSet(entity this)
1826 {
1827         if(!IS_PLAYER(this.enemy))
1828                 return false;
1829
1830         ClientData_Touch(this.enemy);
1831
1832         msg_entity = this;
1833         WriteByte(MSG_ONE, SVC_SETVIEW);
1834         WriteEntity(MSG_ONE, this.enemy);
1835         set_movetype(this, MOVETYPE_NONE);
1836         accuracy_resend(this);
1837
1838         if(!SpectateUpdate(this))
1839                 PutObserverInServer(this, false, true);
1840
1841         return true;
1842 }
1843
1844 void SetSpectatee_status(entity this, int spectatee_num)
1845 {
1846         int oldspectatee_status = CS(this).spectatee_status;
1847         CS(this).spectatee_status = spectatee_num;
1848
1849         if (CS(this).spectatee_status != oldspectatee_status)
1850         {
1851                 if (STAT(PRESSED_KEYS, this))
1852                 {
1853                         CS(this).pressedkeys = 0;
1854                         STAT(PRESSED_KEYS, this) = 0;
1855                 }
1856                 ClientData_Touch(this);
1857                 if (g_race || g_cts) race_InitSpectator();
1858         }
1859 }
1860
1861 void SetSpectatee(entity this, entity spectatee)
1862 {
1863         if(IS_BOT_CLIENT(this))
1864                 return; // bots abuse .enemy, this code is useless to them
1865
1866         entity old_spectatee = this.enemy;
1867
1868         this.enemy = spectatee;
1869
1870         // WEAPONTODO
1871         // these are required to fix the spectator bug with arc
1872         if(old_spectatee)
1873         {
1874                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1875                 {
1876                         .entity weaponentity = weaponentities[slot];
1877                         if(old_spectatee.(weaponentity).arc_beam)
1878                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1879                 }
1880         }
1881         if(spectatee)
1882         {
1883                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1884                 {
1885                         .entity weaponentity = weaponentities[slot];
1886                         if(spectatee.(weaponentity).arc_beam)
1887                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1888                 }
1889         }
1890
1891         if (spectatee)
1892                 SetSpectatee_status(this, etof(spectatee));
1893
1894         // needed to update spectator list
1895         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1896 }
1897
1898 bool Spectate(entity this, entity pl)
1899 {
1900         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1901                 return false;
1902         pl = M_ARGV(1, entity);
1903
1904         SetSpectatee(this, pl);
1905         return SpectateSet(this);
1906 }
1907
1908 bool SpectateNext(entity this)
1909 {
1910         entity ent = find(this.enemy, classname, STR_PLAYER);
1911
1912         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1913                 ent = M_ARGV(1, entity);
1914         else if (!ent)
1915                 ent = find(ent, classname, STR_PLAYER);
1916
1917         if(ent) { SetSpectatee(this, ent); }
1918
1919         return SpectateSet(this);
1920 }
1921
1922 bool SpectatePrev(entity this)
1923 {
1924         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1925         entity ent = findchain(classname, STR_PLAYER);
1926         if (!ent) // no player
1927                 return false;
1928
1929         entity first = ent;
1930         // skip players until current spectated player
1931         if(this.enemy)
1932         while(ent && ent != this.enemy)
1933                 ent = ent.chain;
1934
1935         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1936         {
1937                 case MUT_SPECPREV_FOUND:
1938                         ent = M_ARGV(1, entity);
1939                         break;
1940                 case MUT_SPECPREV_RETURN:
1941                         return true;
1942                 case MUT_SPECPREV_CONTINUE:
1943                 default:
1944                 {
1945                         if(ent.chain)
1946                                 ent = ent.chain;
1947                         else
1948                                 ent = first;
1949                         break;
1950                 }
1951         }
1952
1953         SetSpectatee(this, ent);
1954         return SpectateSet(this);
1955 }
1956
1957 /*
1958 =============
1959 ShowRespawnCountdown()
1960
1961 Update a respawn countdown display.
1962 =============
1963 */
1964 void ShowRespawnCountdown(entity this)
1965 {
1966         float number;
1967         if(!IS_DEAD(this)) // just respawned?
1968                 return;
1969         else
1970         {
1971                 number = ceil(this.respawn_time - time);
1972                 if(number <= 0)
1973                         return;
1974                 if(number <= this.respawn_countdown)
1975                 {
1976                         this.respawn_countdown = number - 1;
1977                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1978                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1979                 }
1980         }
1981 }
1982
1983 .bool team_selected;
1984 bool ShowTeamSelection(entity this)
1985 {
1986         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1987                 return false;
1988         if (frametime) // once per frame is more than enough
1989                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1990         return true;
1991 }
1992 void Join(entity this)
1993 {
1994         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1995                 ReadyRestart(true);
1996
1997         TRANSMUTE(Player, this);
1998
1999         if(!this.team_selected)
2000         if(autocvar_g_campaign || autocvar_g_balance_teams)
2001                 TeamBalance_JoinBestTeam(this);
2002
2003         if(autocvar_g_campaign)
2004                 campaign_bots_may_start = true;
2005
2006         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2007
2008         PutClientInServer(this);
2009
2010         if(IS_PLAYER(this))
2011         if(teamplay && this.team != -1)
2012         {
2013         }
2014         else
2015                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2016         this.team_selected = false;
2017 }
2018
2019 int GetPlayerLimit()
2020 {
2021         if(g_duel)
2022                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2023         // don't return map_maxplayers during intermission as it would interfere with MapHasRightSize()
2024         int player_limit = (autocvar_g_maxplayers >= 0 || intermission_running) ? autocvar_g_maxplayers : map_maxplayers;
2025         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2026         player_limit = M_ARGV(0, int);
2027         return player_limit < maxclients ? player_limit : 0;
2028 }
2029
2030 /**
2031  * Determines whether the player is allowed to join. This depends on cvar
2032  * g_maxplayers, if it isn't used this function always return true, otherwise
2033  * it checks whether the number of currently playing players exceeds g_maxplayers.
2034  * @return int number of free slots for players, 0 if none
2035  */
2036 int nJoinAllowed(entity this, entity ignore)
2037 {
2038         if(!ignore)
2039         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2040         // so report 0 free slots if restricted
2041         {
2042                 if(autocvar_g_forced_team_otherwise == "spectate")
2043                         return 0;
2044                 if(autocvar_g_forced_team_otherwise == "spectator")
2045                         return 0;
2046         }
2047
2048         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2049                 return 0; // forced spectators can never join
2050
2051         static float msg_time = 0;
2052         if(this && !INGAME(this) && ignore && PlayerInList(this, autocvar_g_playban_list))
2053         {
2054                 if(time > msg_time)
2055                 {
2056                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PLAYBAN);
2057                         msg_time = time + 0.5;
2058                 }
2059                 return 0;
2060         }
2061
2062         // TODO simplify this
2063         int totalClients = 0;
2064         int currentlyPlaying = 0;
2065         FOREACH_CLIENT(true, {
2066                 if(it != ignore)
2067                         ++totalClients;
2068                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2069                         ++currentlyPlaying;
2070         });
2071
2072         int player_limit = GetPlayerLimit();
2073
2074         int free_slots = 0;
2075         if (!player_limit)
2076                 free_slots = maxclients - totalClients;
2077         else if(player_limit > 0 && currentlyPlaying < player_limit)
2078                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2079
2080         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2081         {
2082                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT, player_limit);
2083                 msg_time = time + 0.5;
2084         }
2085
2086         return free_slots;
2087 }
2088
2089 bool joinAllowed(entity this)
2090 {
2091         if (CS(this).version_mismatch) return false;
2092         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2093         if (!nJoinAllowed(this, this)) return false;
2094         if (teamplay && lockteams) return false;
2095         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2096         if (ShowTeamSelection(this)) return false;
2097         return true;
2098 }
2099
2100 .string shootfromfixedorigin;
2101 .bool dualwielding_prev;
2102 bool PlayerThink(entity this)
2103 {
2104         if (game_stopped || intermission_running) {
2105                 this.modelflags &= ~MF_ROCKET;
2106                 if(intermission_running)
2107                         IntermissionThink(this);
2108                 return false;
2109         }
2110
2111         if (timeout_status == TIMEOUT_ACTIVE) {
2112                 // don't allow the player to turn around while game is paused
2113                 // FIXME turn this into CSQC stuff
2114                 this.v_angle = this.lastV_angle;
2115                 this.angles = this.lastV_angle;
2116                 this.fixangle = true;
2117         }
2118
2119         if (frametime) player_powerups(this);
2120
2121         if (IS_DEAD(this)) {
2122                 if (this.personal && g_race_qualifying) {
2123                         if (time > this.respawn_time) {
2124                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2125                                 respawn(this);
2126                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2127                         }
2128                 } else {
2129                         if (frametime) player_anim(this);
2130
2131                         if (this.respawn_flags & RESPAWN_DENY)
2132                         {
2133                                 STAT(RESPAWN_TIME, this) = 0;
2134                                 return false;
2135                         }
2136
2137                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2138
2139                         switch(this.deadflag)
2140                         {
2141                                 case DEAD_DYING:
2142                                 {
2143                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2144                                                 this.deadflag = DEAD_RESPAWNING;
2145                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2146                                                 this.deadflag = DEAD_DEAD;
2147                                         break;
2148                                 }
2149                                 case DEAD_DEAD:
2150                                 {
2151                                         if (button_pressed)
2152                                                 this.deadflag = DEAD_RESPAWNABLE;
2153                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2154                                                 this.deadflag = DEAD_RESPAWNING;
2155                                         break;
2156                                 }
2157                                 case DEAD_RESPAWNABLE:
2158                                 {
2159                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2160                                                 this.deadflag = DEAD_RESPAWNING;
2161                                         break;
2162                                 }
2163                                 case DEAD_RESPAWNING:
2164                                 {
2165                                         if (time > this.respawn_time)
2166                                         {
2167                                                 this.respawn_time = time + 1; // only retry once a second
2168                                                 this.respawn_time_max = this.respawn_time;
2169                                                 respawn(this);
2170                                         }
2171                                         break;
2172                                 }
2173                         }
2174
2175                         ShowRespawnCountdown(this);
2176
2177                         if (this.respawn_flags & RESPAWN_SILENT)
2178                                 STAT(RESPAWN_TIME, this) = 0;
2179                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2180                         {
2181                                 if (time < this.respawn_time)
2182                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2183                                 else if (this.deadflag != DEAD_RESPAWNING)
2184                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2185                         }
2186                         else
2187                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2188                 }
2189
2190                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2191                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2192                         STAT(RESPAWN_TIME, this) *= -1;
2193
2194                 return false;
2195         }
2196
2197         FixPlayermodel(this);
2198
2199         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2200                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2201                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2202         }
2203
2204         // reset gun alignment when dual wielding status changes
2205         // to ensure guns are always aligned right and left
2206         bool dualwielding = W_DualWielding(this);
2207         if(this.dualwielding_prev != dualwielding)
2208         {
2209                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2210                 this.dualwielding_prev = dualwielding;
2211         }
2212
2213         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2214         //if(frametime)
2215         {
2216                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2217                 {
2218                         .entity weaponentity = weaponentities[slot];
2219                         if(WEP_CVAR(vortex, charge_always))
2220                                 W_Vortex_Charge(this, weaponentity, frametime);
2221                         W_WeaponFrame(this, weaponentity);
2222                 }
2223         }
2224
2225         if (frametime)
2226         {
2227                 // WEAPONTODO: Add a weapon request for this
2228                 // rot vortex charge to the charge limit
2229                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2230                 {
2231                         .entity weaponentity = weaponentities[slot];
2232                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2233                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2234                 }
2235
2236                 player_regen(this);
2237                 player_anim(this);
2238                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2239         }
2240
2241         monsters_setstatus(this);
2242
2243         return true;
2244 }
2245
2246 .bool would_spectate;
2247 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2248 void ObserverOrSpectatorThink(entity this)
2249 {
2250         bool is_spec = IS_SPEC(this);
2251         if ( CS(this).impulse )
2252         {
2253                 int r = MinigameImpulse(this, CS(this).impulse);
2254                 if (!is_spec || r)
2255                         CS(this).impulse = 0;
2256
2257                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2258                 {
2259                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2260                         CS(this).impulse = 0;
2261                         return;
2262                 }
2263         }
2264
2265         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2266         {
2267                 CS(this).autojoin_checked = true;
2268                 TRANSMUTE(Player, this);
2269                 PutClientInServer(this);
2270                 return;
2271         }
2272
2273         if (this.flags & FL_JUMPRELEASED) {
2274                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2275                         this.flags &= ~FL_JUMPRELEASED;
2276                         this.flags |= FL_SPAWNING;
2277                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2278                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2279                         this.flags &= ~FL_JUMPRELEASED;
2280                         if(SpectateNext(this)) {
2281                                 TRANSMUTE(Spectator, this);
2282                         } else if (is_spec) {
2283                                 TRANSMUTE(Observer, this);
2284                                 PutClientInServer(this);
2285                         }
2286                         else
2287                                 this.would_spectate = false; // unable to spectate anyone
2288                         if (is_spec)
2289                                 CS(this).impulse = 0;
2290                 } else if (is_spec) {
2291                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2292                                 this.flags &= ~FL_JUMPRELEASED;
2293                                 if(SpectatePrev(this)) {
2294                                         TRANSMUTE(Spectator, this);
2295                                 } else {
2296                                         TRANSMUTE(Observer, this);
2297                                         PutClientInServer(this);
2298                                 }
2299                                 CS(this).impulse = 0;
2300                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2301                                 if(!observe_blocked_if_eliminated || !INGAME(this)) {
2302                                         this.would_spectate = false;
2303                                         this.flags &= ~FL_JUMPRELEASED;
2304                                         TRANSMUTE(Observer, this);
2305                                         PutClientInServer(this);
2306                                 }
2307                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2308                                 PutObserverInServer(this, false, true);
2309                                 this.would_spectate = true;
2310                         }
2311                 }
2312                 else {
2313                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2314                         if (PHYS_INPUT_BUTTON_USE(this))
2315                                 wouldclip = !wouldclip;
2316                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2317                         set_movetype(this, preferred_movetype);
2318                 }
2319         } else { // jump pressed
2320                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2321                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2322                         this.flags |= FL_JUMPRELEASED;
2323                         // primary attack pressed
2324                         if(this.flags & FL_SPAWNING)
2325                         {
2326                                 this.flags &= ~FL_SPAWNING;
2327                                 if(joinAllowed(this))
2328                                         Join(this);
2329                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2330                                         CS(this).autojoin_checked = -1;
2331                                 return;
2332                         }
2333                 }
2334                 if(is_spec && !SpectateUpdate(this))
2335                         PutObserverInServer(this, false, true);
2336         }
2337         if (is_spec)
2338                 this.flags |= FL_CLIENT | FL_NOTARGET;
2339 }
2340
2341 void PlayerUseKey(entity this)
2342 {
2343         if (!IS_PLAYER(this))
2344                 return;
2345
2346         if(this.vehicle)
2347         {
2348                 if(!game_stopped)
2349                 {
2350                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2351                         return;
2352                 }
2353         }
2354         else if(autocvar_g_vehicles_enter)
2355         {
2356                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2357                 {
2358                         entity head, closest_target = NULL;
2359                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2360
2361                         while(head) // find the closest acceptable target to enter
2362                         {
2363                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2364                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2365                                 {
2366                                         if(closest_target)
2367                                         {
2368                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2369                                                 { closest_target = head; }
2370                                         }
2371                                         else { closest_target = head; }
2372                                 }
2373
2374                                 head = head.chain;
2375                         }
2376
2377                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2378                 }
2379         }
2380
2381         // a use key was pressed; call handlers
2382         MUTATOR_CALLHOOK(PlayerUseKey, this);
2383 }
2384
2385
2386 /*
2387 =============
2388 PlayerPreThink
2389
2390 Called every frame for each client before the physics are run
2391 =============
2392 */
2393 .float last_vehiclecheck;
2394 void PlayerPreThink (entity this)
2395 {
2396         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2397         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2398
2399         WarpZone_PlayerPhysics_FixVAngle(this);
2400
2401         if (frametime) {
2402                 // physics frames: update anticheat stuff
2403                 anticheat_prethink(this);
2404
2405                 // WORKAROUND: only use dropclient in server frames (frametime set).
2406                 // Never use it in cl_movement frames (frametime zero).
2407                 if (blockSpectators && IS_REAL_CLIENT(this)
2408                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2409                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2410                 {
2411                         if (dropclient_schedule(this))
2412                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2413                 }
2414         }
2415
2416         zoomstate_set = false;
2417
2418         // Check for nameless players
2419         if (this.netname == "" || this.netname != CS(this).netname_previous)
2420         {
2421                 bool assume_unchanged = (CS(this).netname_previous == "");
2422                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2423                 {
2424                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2425                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2426                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2427                         assume_unchanged = false;
2428                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2429                 }
2430                 if (isInvisibleString(this.netname))
2431                 {
2432                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2433                         sprint(this, "Warning: invisible names are not allowed.\n");
2434                         assume_unchanged = false;
2435                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2436                 }
2437                 if (!assume_unchanged && autocvar_sv_eventlog)
2438                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2439                 strcpy(CS(this).netname_previous, this.netname);
2440         }
2441
2442         // version nagging
2443         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2444         CS(this).version_nagtime = 0;
2445         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2446             // git client
2447         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2448             // git server
2449             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2450         } else {
2451             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2452             if (r < 0) { // old client
2453                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2454             } else if (r > 0) { // old server
2455                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2456             }
2457         }
2458     }
2459
2460         // GOD MODE info
2461         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2462         {
2463                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2464                 this.max_armorvalue = 0;
2465         }
2466
2467         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2468         {
2469                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2470                 {
2471                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2472                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2473                         if (this.iceblock)
2474                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2475
2476                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2477                                 Unfreeze(this, false);
2478                 }
2479                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2480                 {
2481                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2482                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2483
2484                         if (GetResource(this, RES_HEALTH) < 1)
2485                         {
2486                                 if (this.vehicle)
2487                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2488                                 if(this.event_damage)
2489                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2490                         }
2491                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2492                                 Unfreeze(this, false);
2493                 }
2494         }
2495
2496         MUTATOR_CALLHOOK(PlayerPreThink, this);
2497
2498         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2499         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2500         {
2501                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2502                 {
2503                         if(!it.owner)
2504                         {
2505                                 if(!it.team || SAME_TEAM(this, it))
2506                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2507                                 else if(autocvar_g_vehicles_steal)
2508                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2509                         }
2510                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2511                         {
2512                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2513                         }
2514                 });
2515
2516                 this.last_vehiclecheck = time + 1;
2517         }
2518
2519         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2520                 PlayerUseKey(this);
2521         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2522
2523         if (IS_PLAYER(this)) {
2524                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2525                         error("Client can't be spawned as player on connection!");
2526                 if(!PlayerThink(this))
2527                         return;
2528         }
2529         else if (game_stopped || intermission_running) {
2530                 if(intermission_running)
2531                         IntermissionThink(this);
2532                 return;
2533         }
2534         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2535         {
2536                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2537                 CS(this).autojoin_checked = 1;
2538                 // don't do this in ClientConnect
2539                 // many things can go wrong if a client is spawned as player on connection
2540                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2541                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2542                                 && (!teamplay || autocvar_g_balance_teams)))
2543                 {
2544                         if(joinAllowed(this))
2545                                 Join(this);
2546                         return;
2547                 }
2548         }
2549         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2550                 ObserverOrSpectatorThink(this);
2551         }
2552
2553         // WEAPONTODO: Add weapon request for this
2554         if (!zoomstate_set) {
2555                 bool wep_zoomed = false;
2556                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2557                 {
2558                         .entity weaponentity = weaponentities[slot];
2559                         Weapon thiswep = this.(weaponentity).m_weapon;
2560                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2561                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2562                 }
2563                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2564         }
2565
2566         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2567         {
2568                 CS(this).teamkill_soundtime = 0;
2569
2570                 entity e = CS(this).teamkill_soundsource;
2571                 entity oldpusher = e.pusher;
2572                 e.pusher = this;
2573                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2574                 e.pusher = oldpusher;
2575         }
2576
2577         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2578                 CS(this).taunt_soundtime = 0;
2579                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2580         }
2581
2582         target_voicescript_next(this);
2583 }
2584
2585 void DrownPlayer(entity this)
2586 {
2587         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2588                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2589         {
2590                 STAT(AIR_FINISHED, this) = 0;
2591                 return;
2592         }
2593
2594         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2595         {
2596                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2597                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2598                 STAT(AIR_FINISHED, this) = 0;
2599         }
2600         else
2601         {
2602                 if (!STAT(AIR_FINISHED, this))
2603                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2604                 if (STAT(AIR_FINISHED, this) < time)
2605                 {       // drown!
2606                         if (this.pain_finished < time)
2607                         {
2608                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2609                                 this.pain_finished = time + 0.5;
2610                         }
2611                 }
2612         }
2613 }
2614
2615 .bool move_qcphysics;
2616
2617 void Player_Physics(entity this)
2618 {
2619         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2620
2621         if(!this.move_qcphysics)
2622                 return;
2623
2624         if(!frametime && !CS(this).pm_frametime)
2625                 return;
2626
2627         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2628
2629         CS(this).pm_frametime = 0;
2630 }
2631
2632 /*
2633 =============
2634 PlayerPostThink
2635
2636 Called every frame for each client after the physics are run
2637 =============
2638 */
2639 void PlayerPostThink (entity this)
2640 {
2641         Player_Physics(this);
2642
2643         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2644         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2645         if (IS_REAL_CLIENT(this))
2646         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2647         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2648         {
2649                 int totalClients = 0;
2650                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2651                 {
2652                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2653                         if (server_is_dedicated)
2654                         {
2655                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2656                                 {
2657                                         ++totalClients;
2658                                 });
2659                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2660                                         totalClients = 0;
2661                         }
2662                 }
2663                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2664                 {
2665                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2666                         {
2667                                 ++totalClients;
2668                         });
2669                 }
2670
2671                 if (totalClients < autocvar_sv_maxidle_minplayers)
2672                 {
2673                         // idle kick disabled
2674                         CS(this).parm_idlesince = time;
2675                 }
2676                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2677                 {
2678                         if (CS(this).idlekick_lasttimeleft)
2679                         {
2680                                 CS(this).idlekick_lasttimeleft = 0;
2681                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2682                         }
2683                 }
2684                 else
2685                 {
2686                         float maxidle_time = autocvar_sv_maxidle;
2687                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2688                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2689                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2690                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2691                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2692                         {
2693                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2694                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2695                                 else
2696                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2697                         }
2698                         if (timeleft <= 0) {
2699                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2700                                 {
2701                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2702                                         PutObserverInServer(this, true, true);
2703                                 }
2704                                 else
2705                                 {
2706                                         if (dropclient_schedule(this))
2707                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2708                                 }
2709                                 return;
2710                         }
2711                         else if (timeleft <= countdown_time) {
2712                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2713                                         play2(this, SND(TALK2));
2714                                 CS(this).idlekick_lasttimeleft = timeleft;
2715                         }
2716                 }
2717         }
2718
2719         CheatFrame(this);
2720
2721         if (game_stopped)
2722         {
2723                 this.solid = SOLID_NOT;
2724                 this.takedamage = DAMAGE_NO;
2725                 set_movetype(this, MOVETYPE_NONE);
2726                 CS(this).teamkill_complain = 0;
2727                 CS(this).teamkill_soundtime = 0;
2728                 CS(this).teamkill_soundsource = NULL;
2729         }
2730
2731         if (IS_PLAYER(this)) {
2732                 if(this.death_time == time && IS_DEAD(this))
2733                 {
2734                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2735                         // once all the damage events of this frame have been processed with normal size
2736                         this.maxs.z = 5;
2737                         setsize(this, this.mins, this.maxs);
2738                 }
2739                 DrownPlayer(this);
2740                 UpdateChatBubble(this);
2741                 if (CS(this).impulse) ImpulseCommands(this);
2742                 GetPressedKeys(this);
2743                 if (game_stopped)
2744                 {
2745                         CSQCMODEL_AUTOUPDATE(this);
2746                         return;
2747                 }
2748         }
2749         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2750         {
2751                 CS(this).pressedkeys = 0;
2752                 STAT(PRESSED_KEYS, this) = 0;
2753         }
2754
2755         if (this.waypointsprite_attachedforcarrier) {
2756                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2757                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2758         }
2759
2760         CSQCMODEL_AUTOUPDATE(this);
2761 }
2762
2763 // hack to copy the button fields from the client entity to the Client State
2764 void PM_UpdateButtons(entity this, entity store)
2765 {
2766         if(this.impulse)
2767                 store.impulse = this.impulse;
2768         this.impulse = 0;
2769
2770         bool typing = this.buttonchat || this.button12;
2771
2772         store.button0 = (typing) ? 0 : this.button0;
2773         //button1?!
2774         store.button2 = (typing) ? 0 : this.button2;
2775         store.button3 = (typing) ? 0 : this.button3;
2776         store.button4 = this.button4;
2777         store.button5 = (typing) ? 0 : this.button5;
2778         store.button6 = this.button6;
2779         store.button7 = this.button7;
2780         store.button8 = this.button8;
2781         store.button9 = this.button9;
2782         store.button10 = this.button10;
2783         store.button11 = this.button11;
2784         store.button12 = this.button12;
2785         store.button13 = this.button13;
2786         store.button14 = this.button14;
2787         store.button15 = this.button15;
2788         store.button16 = this.button16;
2789         store.buttonuse = this.buttonuse;
2790         store.buttonchat = this.buttonchat;
2791
2792         store.cursor_active = this.cursor_active;
2793         store.cursor_screen = this.cursor_screen;
2794         store.cursor_trace_start = this.cursor_trace_start;
2795         store.cursor_trace_endpos = this.cursor_trace_endpos;
2796         store.cursor_trace_ent = this.cursor_trace_ent;
2797
2798         store.ping = this.ping;
2799         store.ping_packetloss = this.ping_packetloss;
2800         store.ping_movementloss = this.ping_movementloss;
2801
2802         store.v_angle = this.v_angle;
2803         store.movement = this.movement;
2804 }
2805
2806 NET_HANDLE(fpsreport, bool)
2807 {
2808         int fps = ReadShort();
2809         PlayerScore_Set(sender, SP_FPS, fps);
2810         return true;
2811 }