qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include <server/gamelog.qh>
  24 #include "race.qh"
  25 #include <server/sv_main.qh>
  26 #include "antilag.qh"
  27 #include "campaign.qh"
  28 #include "command/common.qh"
  29 #include "scores_rules.qh"
  30 #include "weapons/common.qh"
  31
  32 #include "bot/api.qh"
  33
  34 #include "../common/ent_cs.qh"
  35 #include "../common/wepent.qh"
  36 #include <common/state.qh>
  37
  38 #include "compat/quake3.qh"
  39
  40 #include <common/effects/qc/globalsound.qh>
  41
  42 #include "../common/mapobjects/func/conveyor.qh"
  43 #include <common/mapobjects/func/ladder.qh>
  44 #include "../common/mapobjects/teleporters.qh"
  45 #include "../common/mapobjects/target/spawnpoint.qh"
  46 #include <common/mapobjects/trigger/counter.qh>
  47 #include <common/mapobjects/trigger/swamp.qh>
  48
  49 #include "../common/vehicles/all.qh"
  50
  51 #include "weapons/hitplot.qh"
  52 #include "weapons/selection.qh"
  53 #include "weapons/weaponsystem.qh"
  54
  55 #include "../common/net_notice.qh"
  56 #include "../common/net_linked.qh"
  57 #include "../common/physics/player.qh"
  58
  59 #include <common/vehicles/sv_vehicles.qh>
  60
  61 #include "../common/items/_mod.qh"
  62
  63 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  64
  65 #include "../common/mutators/mutator/waypoints/all.qh"
  66 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  67 #include <common/gamemodes/_mod.qh>
  68
  69 #include "../common/mapobjects/subs.qh"
  70 #include "../common/mapobjects/triggers.qh"
  71 #include "../common/mapobjects/trigger/secret.qh"
  72
  73 #include "../common/minigames/sv_minigames.qh"
  74
  75 #include "../common/items/inventory.qh"
  76
  77 #include "../common/monsters/sv_monsters.qh"
  78
  79 #include "../lib/warpzone/server.qh"
  80
  81 #include <common/mutators/mutator/overkill/oknex.qh>
  82
  83 #include <common/weapons/weapon/vortex.qh>
  84
  85 STATIC_METHOD(Client, Add, void(Client this, int _team))
  86 {
  87     ClientConnect(this);
  88     TRANSMUTE(Player, this);
  89     this.frame = 12; // 7
  90     this.team = _team;
  91     PutClientInServer(this);
  92 }
  93
  94 STATIC_METHOD(Client, Remove, void(Client this))
  95 {
  96     TRANSMUTE(Observer, this);
  97     PutClientInServer(this);
  98     ClientDisconnect(this);
  99 }
 100
 101 void send_CSQC_teamnagger() {
 102         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 103 }
 104
 105 int CountSpectators(entity player, entity to)
 106 {
 107         if(!player) { return 0; } // not sure how, but best to be safe
 108
 109         int spec_count = 0;
 110
 111         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 112         {
 113                 spec_count++;
 114         });
 115
 116         return spec_count;
 117 }
 118
 119 void WriteSpectators(entity player, entity to)
 120 {
 121         if(!player) { return; } // not sure how, but best to be safe
 122
 123         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 124         {
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if( substring(plyermodel,0,14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel,-4,4) != ".zym")
 207         if(substring(plyermodel,-4,4) != ".dpm")
 208         if(substring(plyermodel,-4,4) != ".iqm")
 209         if(substring(plyermodel,-4,4) != ".md3")
 210         if(substring(plyermodel,-4,4) != ".psk")
 211                 return FallbackPlayerModel;
 212         // forbid the LOD models
 213         if(substring(plyermodel, -9,5) == "_lod1")
 214                 return FallbackPlayerModel;
 215         if(substring(plyermodel, -9,5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this)
 239 {
 240     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 241         PlayerState_detach(this);
 242
 243         if (IS_PLAYER(this))
 244         {
 245                 if(GetResource(this, RES_HEALTH) >= 1)
 246                 {
 247                         // despawn effect
 248                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 249                 }
 250
 251                 // was a player, recount votes and ready status
 252                 if(IS_REAL_CLIENT(this))
 253                 {
 254                         if (vote_called) { VoteCount(false); }
 255                         ReadyCount();
 256                 }
 257     }
 258
 259     {
 260         entity spot = SelectSpawnPoint(this, true);
 261         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 262         this.angles = vec2(spot.angles);
 263         this.fixangle = true;
 264         // offset it so that the spectator spawns higher off the ground, looks better this way
 265         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 266         if (IS_REAL_CLIENT(this))
 267         {
 268             msg_entity = this;
 269             WriteByte(MSG_ONE, SVC_SETVIEW);
 270             WriteEntity(MSG_ONE, this);
 271         }
 272         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 273         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 274         if(!autocvar_g_debug_globalsounds)
 275         {
 276                 // needed for player sounds
 277                 this.model = "";
 278                 FixPlayermodel(this);
 279         }
 280         setmodel(this, MDL_Null);
 281         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 282         this.view_ofs = '0 0 0';
 283     }
 284
 285     RemoveGrapplingHooks(this);
 286         Portal_ClearAll(this);
 287         Unfreeze(this, false);
 288         SetSpectatee(this, NULL);
 289
 290         if (this.alivetime)
 291         {
 292                 if (!warmup_stage)
 293                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 294                 this.alivetime = 0;
 295         }
 296
 297         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 298
 299         WaypointSprite_PlayerDead(this);
 300
 301         if (CS(this).killcount != FRAGS_SPECTATOR)
 302         {
 303                 if(!game_stopped)
 304                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 305                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 306         }
 307
 308         accuracy_resend(this);
 309
 310         CS(this).spectatortime = time;
 311         if(this.bot_attack)
 312                 IL_REMOVE(g_bot_targets, this);
 313         this.bot_attack = false;
 314         if(this.monster_attack)
 315                 IL_REMOVE(g_monster_targets, this);
 316         this.monster_attack = false;
 317     STAT(HUD, this) = HUD_NORMAL;
 318         TRANSMUTE(Observer, this);
 319         this.iscreature = false;
 320         this.teleportable = TELEPORT_SIMPLE;
 321         if(this.damagedbycontents)
 322                 IL_REMOVE(g_damagedbycontents, this);
 323         this.damagedbycontents = false;
 324         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 325         SetSpectatee_status(this, etof(this));
 326         this.takedamage = DAMAGE_NO;
 327         this.solid = SOLID_NOT;
 328         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 329         this.flags = FL_CLIENT | FL_NOTARGET;
 330         this.effects = 0;
 331         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 332         this.pauserotarmor_finished = 0;
 333         this.pauserothealth_finished = 0;
 334         this.pauseregen_finished = 0;
 335         this.damageforcescale = 0;
 336         this.death_time = 0;
 337         this.respawn_flags = 0;
 338         this.respawn_time = 0;
 339         STAT(RESPAWN_TIME, this) = 0;
 340         this.alpha = 0;
 341         this.scale = 0;
 342         this.fade_time = 0;
 343         this.pain_finished = 0;
 344         STAT(STRENGTH_FINISHED, this) = 0;
 345         STAT(INVINCIBLE_FINISHED, this) = 0;
 346         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 347         STAT(AIR_FINISHED, this) = 0;
 348         //this.dphitcontentsmask = 0;
 349         this.dphitcontentsmask = DPCONTENTS_SOLID;
 350         if (autocvar_g_playerclip_collisions)
 351                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 352         this.pushltime = 0;
 353         this.istypefrag = 0;
 354         setthink(this, func_null);
 355         this.nextthink = 0;
 356         this.deadflag = DEAD_NO;
 357         UNSET_DUCKED(this);
 358         STAT(REVIVE_PROGRESS, this) = 0;
 359         this.revival_time = 0;
 360         this.draggable = drag_undraggable;
 361
 362         this.items = 0;
 363         STAT(WEAPONS, this) = '0 0 0';
 364         this.drawonlytoclient = this;
 365
 366         this.viewloc = NULL;
 367
 368         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 369
 370         this.weaponmodel = "";
 371         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 372         {
 373                 this.weaponentities[slot] = NULL;
 374         }
 375         this.exteriorweaponentity = NULL;
 376         CS(this).killcount = FRAGS_SPECTATOR;
 377         this.velocity = '0 0 0';
 378         this.avelocity = '0 0 0';
 379         this.punchangle = '0 0 0';
 380         this.punchvector = '0 0 0';
 381         this.oldvelocity = this.velocity;
 382         this.fire_endtime = -1;
 383         this.event_damage = func_null;
 384         this.event_heal = func_null;
 385
 386         for(int slot = 0; slot < MAX_AXH; ++slot)
 387         {
 388                 entity axh = this.(AuxiliaryXhair[slot]);
 389                 this.(AuxiliaryXhair[slot]) = NULL;
 390
 391                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 392                         delete(axh);
 393         }
 394
 395         if (mutator_returnvalue)
 396         {
 397                 // mutator prevents resetting teams+score
 398         }
 399         else
 400         {
 401                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 402                 this.frags = FRAGS_SPECTATOR;
 403         }
 404         if (CS(this).just_joined)
 405                 CS(this).just_joined = false;
 406 }
 407
 408 int player_getspecies(entity this)
 409 {
 410         get_model_parameters(this.model, this.skin);
 411         int s = get_model_parameters_species;
 412         get_model_parameters(string_null, 0);
 413         if (s < 0) return SPECIES_HUMAN;
 414         return s;
 415 }
 416
 417 .float model_randomizer;
 418 void FixPlayermodel(entity player)
 419 {
 420         string defaultmodel = "";
 421         int defaultskin = 0;
 422         if(autocvar_sv_defaultcharacter)
 423         {
 424                 if(teamplay)
 425                 {
 426                         switch(player.team)
 427                         {
 428                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 429                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 430                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 431                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 432                         }
 433                 }
 434
 435                 if(defaultmodel == "")
 436                 {
 437                         defaultmodel = autocvar_sv_defaultplayermodel;
 438                         defaultskin = autocvar_sv_defaultplayerskin;
 439                 }
 440
 441                 int n = tokenize_console(defaultmodel);
 442                 if(n > 0)
 443                 {
 444                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 445                         // However, do NOT randomize if the player-selected model is in the list.
 446                         for (int i = 0; i < n; ++i)
 447                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 448                                         defaultmodel = argv(i);
 449                 }
 450
 451                 int i = strstrofs(defaultmodel, ":", 0);
 452                 if(i >= 0)
 453                 {
 454                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 455                         defaultmodel = substring(defaultmodel, 0, i);
 456                 }
 457         }
 458         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 459         {
 460                 if(teamplay)
 461                 {
 462                         switch(player.team)
 463                         {
 464                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 465                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 466                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 467                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 468                         }
 469                 }
 470
 471                 if(!defaultskin)
 472                         defaultskin = autocvar_sv_defaultplayerskin;
 473         }
 474
 475         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 476         defaultmodel = M_ARGV(0, string);
 477         defaultskin = M_ARGV(1, int);
 478
 479         bool chmdl = false;
 480         int oldskin;
 481         if(defaultmodel != "")
 482         {
 483                 if (defaultmodel != player.model)
 484                 {
 485                         vector m1 = player.mins;
 486                         vector m2 = player.maxs;
 487                         setplayermodel (player, defaultmodel);
 488                         setsize (player, m1, m2);
 489                         chmdl = true;
 490                 }
 491
 492                 oldskin = player.skin;
 493                 player.skin = defaultskin;
 494         } else {
 495                 if (player.playermodel != player.model || player.playermodel == "")
 496                 {
 497                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 498                         vector m1 = player.mins;
 499                         vector m2 = player.maxs;
 500                         setplayermodel (player, player.playermodel);
 501                         setsize (player, m1, m2);
 502                         chmdl = true;
 503                 }
 504
 505                 if(!autocvar_sv_defaultcharacterskin)
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = stof(player.playerskin);
 509                 }
 510                 else
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = defaultskin;
 514                 }
 515         }
 516
 517         if(chmdl || oldskin != player.skin) // model or skin has changed
 518         {
 519                 player.species = player_getspecies(player); // update species
 520                 if(!autocvar_g_debug_globalsounds)
 521                         UpdatePlayerSounds(player); // update skin sounds
 522         }
 523
 524         if(!teamplay)
 525                 if(strlen(autocvar_sv_defaultplayercolors))
 526                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 527                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 528 }
 529
 530 void PutPlayerInServer(entity this)
 531 {
 532         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 533
 534         PlayerState_attach(this);
 535         accuracy_resend(this);
 536
 537         if (this.team < 0)
 538                 TeamBalance_JoinBestTeam(this);
 539
 540         entity spot = SelectSpawnPoint(this, false);
 541         if (!spot) {
 542                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 543                 return; // spawn failed
 544         }
 545
 546         TRANSMUTE(Player, this);
 547
 548         CS(this).wasplayer = true;
 549         this.iscreature = true;
 550         this.teleportable = TELEPORT_NORMAL;
 551         if(!this.damagedbycontents)
 552                 IL_PUSH(g_damagedbycontents, this);
 553         this.damagedbycontents = true;
 554         set_movetype(this, MOVETYPE_WALK);
 555         this.solid = SOLID_SLIDEBOX;
 556         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 557         if (autocvar_g_playerclip_collisions)
 558                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 559         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 560                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 561         this.frags = FRAGS_PLAYER;
 562         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 563         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 564         if (autocvar__notarget)
 565                 this.flags |= FL_NOTARGET;
 566         this.takedamage = DAMAGE_AIM;
 567         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 568
 569         if (warmup_stage) {
 570                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 571                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 572                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 573                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 574                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 575                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 576                 SetResource(this, RES_HEALTH, warmup_start_health);
 577                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 578                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 579         } else {
 580                 SetResource(this, RES_SHELLS, start_ammo_shells);
 581                 SetResource(this, RES_BULLETS, start_ammo_nails);
 582                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 583                 SetResource(this, RES_CELLS, start_ammo_cells);
 584                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 585                 SetResource(this, RES_FUEL, start_ammo_fuel);
 586                 SetResource(this, RES_HEALTH, start_health);
 587                 SetResource(this, RES_ARMOR, start_armorvalue);
 588                 STAT(WEAPONS, this) = start_weapons;
 589                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 590                 {
 591                         GiveRandomWeapons(this, random_start_weapons_count,
 592                                 autocvar_g_random_start_weapons, random_start_ammo);
 593                 }
 594         }
 595         SetSpectatee_status(this, 0);
 596
 597         PS(this).dual_weapons = '0 0 0';
 598
 599         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 600
 601         this.items = start_items;
 602
 603         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 604         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 605         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 606         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 607         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 608         if (!sv_ready_restart_after_countdown && time < game_starttime)
 609         {
 610                 float f = game_starttime - time;
 611                 this.spawnshieldtime += f;
 612                 this.pauserotarmor_finished += f;
 613                 this.pauserothealth_finished += f;
 614                 this.pauseregen_finished += f;
 615         }
 616
 617         this.damageforcescale = autocvar_g_player_damageforcescale;
 618         this.death_time = 0;
 619         this.respawn_flags = 0;
 620         this.respawn_time = 0;
 621         STAT(RESPAWN_TIME, this) = 0;
 622         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 623         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 624         this.fade_time = 0;
 625         this.pain_finished = 0;
 626         this.pushltime = 0;
 627         setthink(this, func_null); // players have no think function
 628         this.nextthink = 0;
 629         this.dmg_team = 0;
 630         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 631
 632         this.deadflag = DEAD_NO;
 633
 634         this.angles = spot.angles;
 635         this.angles_z = 0; // never spawn tilted even if the spot says to
 636         if (IS_BOT_CLIENT(this))
 637         {
 638                 this.v_angle = this.angles;
 639                 bot_aim_reset(this);
 640         }
 641         this.fixangle = true; // turn this way immediately
 642         this.oldvelocity = this.velocity = '0 0 0';
 643         this.avelocity = '0 0 0';
 644         this.punchangle = '0 0 0';
 645         this.punchvector = '0 0 0';
 646
 647         STAT(STRENGTH_FINISHED, this) = 0;
 648         STAT(INVINCIBLE_FINISHED, this) = 0;
 649         this.fire_endtime = -1;
 650         STAT(REVIVE_PROGRESS, this) = 0;
 651         this.revival_time = 0;
 652
 653         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 654         STAT(BUFFS, this) = 0;
 655         STAT(BUFF_TIME, this) = 0;
 656
 657         STAT(AIR_FINISHED, this) = 0;
 658         this.waterlevel = WATERLEVEL_NONE;
 659         this.watertype = CONTENT_EMPTY;
 660
 661         entity spawnevent = new_pure(spawnevent);
 662         spawnevent.owner = this;
 663         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 664
 665         // Cut off any still running player sounds.
 666         stopsound(this, CH_PLAYER_SINGLE);
 667
 668         this.model = "";
 669         FixPlayermodel(this);
 670         this.drawonlytoclient = NULL;
 671
 672         this.viewloc = NULL;
 673
 674         for(int slot = 0; slot < MAX_AXH; ++slot)
 675         {
 676                 entity axh = this.(AuxiliaryXhair[slot]);
 677                 this.(AuxiliaryXhair[slot]) = NULL;
 678
 679                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 680                         delete(axh);
 681         }
 682
 683         this.spawnpoint_targ = NULL;
 684
 685         UNSET_DUCKED(this);
 686         this.view_ofs = STAT(PL_VIEW_OFS, this);
 687         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 688         this.spawnorigin = spot.origin;
 689         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 690         // don't reset back to last position, even if new position is stuck in solid
 691         this.oldorigin = this.origin;
 692         if(this.conveyor)
 693                 IL_REMOVE(g_conveyed, this);
 694         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 695         if(this.swampslug)
 696                 IL_REMOVE(g_swamped, this);
 697         this.swampslug = NULL;
 698         this.swamp_interval = 0;
 699         if(this.ladder_entity)
 700                 IL_REMOVE(g_ladderents, this);
 701         this.ladder_entity = NULL;
 702         IL_EACH(g_counters, it.realowner == this,
 703         {
 704                 delete(it);
 705         });
 706         STAT(HUD, this) = HUD_NORMAL;
 707
 708         this.event_damage = PlayerDamage;
 709         this.event_heal = PlayerHeal;
 710
 711         this.draggable = func_null;
 712
 713         if(!this.bot_attack)
 714                 IL_PUSH(g_bot_targets, this);
 715         this.bot_attack = true;
 716         if(!this.monster_attack)
 717                 IL_PUSH(g_monster_targets, this);
 718         this.monster_attack = true;
 719         navigation_dynamicgoal_init(this, false);
 720
 721         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 722
 723         // player was spectator
 724         if (CS(this).killcount == FRAGS_SPECTATOR) {
 725                 PlayerScore_Clear(this);
 726                 CS(this).killcount = 0;
 727                 CS(this).startplaytime = time;
 728         }
 729
 730         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 731         {
 732                 .entity weaponentity = weaponentities[slot];
 733                 CL_SpawnWeaponentity(this, weaponentity);
 734         }
 735         this.alpha = default_player_alpha;
 736         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 737         this.exteriorweaponentity.alpha = default_weapon_alpha;
 738
 739         this.speedrunning = false;
 740
 741         this.counter_cnt = 0;
 742         this.fragsfilter_cnt = 0;
 743
 744         target_voicescript_clear(this);
 745
 746         // reset fields the weapons may use
 747         FOREACH(Weapons, true, {
 748                 it.wr_resetplayer(it, this);
 749                         // reload all reloadable weapons
 750                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 751                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 752                         {
 753                                 .entity weaponentity = weaponentities[slot];
 754                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 755                         }
 756                 }
 757         });
 758
 759         {
 760                 string s = spot.target;
 761                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 762                         spot.target = string_null;
 763                 SUB_UseTargets(spot, this, NULL);
 764                 if(g_assault || g_race)
 765                         spot.target = s;
 766         }
 767
 768         Unfreeze(this, false);
 769
 770         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 771
 772         if (autocvar_spawn_debug)
 773         {
 774                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 775                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 776         }
 777
 778         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 779         {
 780                 .entity weaponentity = weaponentities[slot];
 781                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 782                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 783                 else
 784                         this.(weaponentity).m_switchweapon = WEP_Null;
 785                 this.(weaponentity).m_weapon = WEP_Null;
 786                 this.(weaponentity).weaponname = "";
 787                 this.(weaponentity).m_switchingweapon = WEP_Null;
 788                 this.(weaponentity).cnt = -1;
 789         }
 790
 791         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 792
 793         if (CS(this).impulse) ImpulseCommands(this);
 794
 795         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 796         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 797         {
 798                 .entity weaponentity = weaponentities[slot];
 799                 W_WeaponFrame(this, weaponentity);
 800         }
 801
 802         if (!warmup_stage && !this.alivetime)
 803                 this.alivetime = time;
 804
 805         antilag_clear(this, CS(this));
 806 }
 807
 808 /** Called when a client spawns in the server */
 809 void PutClientInServer(entity this)
 810 {
 811         if (IS_BOT_CLIENT(this)) {
 812                 TRANSMUTE(Player, this);
 813         } else if (IS_REAL_CLIENT(this)) {
 814                 msg_entity = this;
 815                 WriteByte(MSG_ONE, SVC_SETVIEW);
 816                 WriteEntity(MSG_ONE, this);
 817         }
 818         if (game_stopped)
 819                 TRANSMUTE(Observer, this);
 820
 821         SetSpectatee(this, NULL);
 822
 823         // reset player keys
 824         if(PS(this))
 825                 PS(this).itemkeys = 0;
 826
 827         MUTATOR_CALLHOOK(PutClientInServer, this);
 828
 829         if (IS_OBSERVER(this)) {
 830                 PutObserverInServer(this);
 831         } else if (IS_PLAYER(this)) {
 832                 PutPlayerInServer(this);
 833         }
 834 }
 835
 836 // TODO do we need all these fields, or should we stop autodetecting runtime
 837 // changes and just have a console command to update this?
 838 bool ClientInit_SendEntity(entity this, entity to, int sf)
 839 {
 840         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 841         return = true;
 842         msg_entity = to;
 843         // MSG_INIT replacement
 844         // TODO: make easier to use
 845         Registry_send_all();
 846         W_PROP_reload(MSG_ONE, to);
 847         ClientInit_misc(this);
 848         MUTATOR_CALLHOOK(Ent_Init);
 849 }
 850 void ClientInit_misc(entity this)
 851 {
 852         int channel = MSG_ONE;
 853         WriteHeader(channel, ENT_CLIENT_INIT);
 854         WriteByte(channel, g_nexball_meter_period * 32);
 855         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 856         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 857         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 858         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 859         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 860         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 861         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 862         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 863
 864         if(sv_foginterval && world.fog != "")
 865                 WriteString(channel, world.fog);
 866         else
 867                 WriteString(channel, "");
 868         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 869         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 870         WriteByte(channel, serverflags);
 871         WriteCoord(channel, autocvar_g_trueaim_minrange);
 872 }
 873
 874 void ClientInit_CheckUpdate(entity this)
 875 {
 876         this.nextthink = time;
 877         if(this.count != autocvar_g_balance_armor_blockpercent)
 878         {
 879                 this.count = autocvar_g_balance_armor_blockpercent;
 880                 this.SendFlags |= 1;
 881         }
 882         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 883         {
 884                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 885                 this.SendFlags |= 1;
 886         }
 887 }
 888
 889 void ClientInit_Spawn()
 890 {
 891         entity e = new_pure(clientinit);
 892         setthink(e, ClientInit_CheckUpdate);
 893         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 894
 895         ClientInit_CheckUpdate(e);
 896 }
 897
 898 /*
 899 =============
 900 SetNewParms
 901 =============
 902 */
 903 void SetNewParms ()
 904 {
 905         // initialize parms for a new player
 906         parm1 = -(86400 * 366);
 907
 908         MUTATOR_CALLHOOK(SetNewParms);
 909 }
 910
 911 /*
 912 =============
 913 SetChangeParms
 914 =============
 915 */
 916 void SetChangeParms (entity this)
 917 {
 918         // save parms for level change
 919         parm1 = CS(this).parm_idlesince - time;
 920
 921         MUTATOR_CALLHOOK(SetChangeParms);
 922 }
 923
 924 /*
 925 =============
 926 DecodeLevelParms
 927 =============
 928 */
 929 void DecodeLevelParms(entity this)
 930 {
 931         // load parms
 932         CS(this).parm_idlesince = parm1;
 933         if (CS(this).parm_idlesince == -(86400 * 366))
 934                 CS(this).parm_idlesince = time;
 935
 936         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 937         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 938
 939         MUTATOR_CALLHOOK(DecodeLevelParms);
 940 }
 941
 942 void FixClientCvars(entity e)
 943 {
 944         // send prediction settings to the client
 945         stuffcmd(e, "\nin_bindmap 0 0\n");
 946         if(autocvar_g_antilag == 3) // client side hitscan
 947                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 948         if(autocvar_sv_gentle)
 949                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 950
 951         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 952         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 953
 954         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 955
 956         MUTATOR_CALLHOOK(FixClientCvars, e);
 957 }
 958
 959 bool findinlist_abbrev(string tofind, string list)
 960 {
 961         if(list == "" || tofind == "")
 962                 return false; // empty list or search, just return
 963
 964         // this function allows abbreviated strings!
 965         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 966         {
 967                 return true;
 968         });
 969
 970         return false;
 971 }
 972
 973 bool PlayerInIPList(entity p, string iplist)
 974 {
 975         // some safety checks (never allow local?)
 976         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 977                 return false;
 978
 979         return findinlist_abbrev(p.netaddress, iplist);
 980 }
 981
 982 bool PlayerInIDList(entity p, string idlist)
 983 {
 984         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 985         if(!p.crypto_idfp)
 986                 return false;
 987
 988         return findinlist_abbrev(p.crypto_idfp, idlist);
 989 }
 990
 991 bool PlayerInList(entity player, string list)
 992 {
 993         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 994 }
 995
 996 #ifdef DP_EXT_PRECONNECT
 997 /*
 998 =============
 999 ClientPreConnect
1000
1001 Called once (not at each match start) when a client begins a connection to the server
1002 =============
1003 */
1004 void ClientPreConnect(entity this)
1005 {
1006         if(autocvar_sv_eventlog)
1007         {
1008                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1009                         this.playerid,
1010                         etof(this),
1011                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1012                 ));
1013         }
1014 }
1015 #endif
1016
1017 string GetClientVersionMessage(entity this)
1018 {
1019         if (CS(this).version_mismatch) {
1020                 if(CS(this).version < autocvar_gameversion) {
1021                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1022                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1023                 } else {
1024                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1025                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1026                 }
1027         } else {
1028                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1029         }
1030 }
1031
1032 string getwelcomemessage(entity this)
1033 {
1034         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1035         string modifications = M_ARGV(0, string);
1036
1037         if(g_weaponarena)
1038         {
1039                 if(g_weaponarena_random)
1040                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1041                 else
1042                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1043         }
1044         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1045                 modifications = strcat(modifications, ", No start weapons");
1046         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1047                 modifications = strcat(modifications, ", Low gravity");
1048         if(g_weapon_stay && !g_cts)
1049                 modifications = strcat(modifications, ", Weapons stay");
1050         if(g_jetpack)
1051                 modifications = strcat(modifications, ", Jet pack");
1052         if(autocvar_g_powerups == 0)
1053                 modifications = strcat(modifications, ", No powerups");
1054         if(autocvar_g_powerups > 0)
1055                 modifications = strcat(modifications, ", Powerups");
1056         modifications = substring(modifications, 2, strlen(modifications) - 2);
1057
1058         string versionmessage = GetClientVersionMessage(this);
1059         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1060
1061         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1062
1063         if(modifications != "")
1064                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1065
1066         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1067         {
1068                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1069                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1070         }
1071
1072         if (cache_mutatormsg != "") {
1073                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1074         }
1075
1076         string mutator_msg = "";
1077         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1078         mutator_msg = M_ARGV(0, string);
1079
1080         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1081
1082         string motd = autocvar_sv_motd;
1083         if (motd != "") {
1084                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1085         }
1086         return s;
1087 }
1088
1089 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1090
1091 /**
1092 =============
1093 ClientConnect
1094
1095 Called when a client connects to the server
1096 =============
1097 */
1098 void ClientConnect(entity this)
1099 {
1100         if (Ban_MaybeEnforceBanOnce(this)) return;
1101         assert(!IS_CLIENT(this), return);
1102         this.flags |= FL_CLIENT;
1103         assert(player_count >= 0, player_count = 0);
1104
1105 #ifdef WATERMARK
1106         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1107 #endif
1108         TRANSMUTE(Client, this);
1109         CS(this).version_nagtime = time + 10 + random() * 10;
1110
1111         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1112
1113         bot_clientconnect(this);
1114
1115         Player_DetermineForcedTeam(this);
1116
1117         TRANSMUTE(Observer, this);
1118
1119         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1120
1121         // always track bots, don't ask for cl_allow_uidtracking
1122         if (IS_BOT_CLIENT(this))
1123                 PlayerStats_GameReport_AddPlayer(this);
1124         else
1125                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1126
1127         if (autocvar_sv_eventlog)
1128                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1129
1130         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1131
1132         stuffcmd(this, clientstuff, "\n");
1133         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1134
1135         FixClientCvars(this);
1136
1137         // get version info from player
1138         stuffcmd(this, "cmd clientversion $gameversion\n");
1139
1140         // notify about available teams
1141         if (teamplay)
1142         {
1143                 entity balance = TeamBalance_CheckAllowedTeams(this);
1144                 int t = TeamBalance_GetAllowedTeams(balance);
1145                 TeamBalance_Destroy(balance);
1146                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1147         }
1148         else
1149         {
1150                 stuffcmd(this, "set _teams_available 0\n");
1151         }
1152
1153         bot_relinkplayerlist();
1154
1155         CS(this).spectatortime = time;
1156         if (blockSpectators)
1157         {
1158                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1159         }
1160
1161         CS(this).jointime = time;
1162
1163         if (IS_REAL_CLIENT(this))
1164         {
1165                 if (g_weaponarena_weapons == WEPSET(TUBA))
1166                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1167         }
1168
1169         if (!sv_foginterval && world.fog != "")
1170                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1171
1172         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1173                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1174                         send_CSQC_teamnagger();
1175
1176         CSQCMODEL_AUTOINIT(this);
1177
1178         CS(this).model_randomizer = random();
1179
1180         if (IS_REAL_CLIENT(this))
1181                 sv_notice_join(this);
1182
1183         this.move_qcphysics = autocvar_sv_qcphysics;
1184
1185         // update physics stats (players can spawn before physics runs)
1186         Physics_UpdateStats(this);
1187
1188         IL_EACH(g_initforplayer, it.init_for_player, {
1189                 it.init_for_player(it, this);
1190         });
1191
1192         Handicap_Initialize(this);
1193
1194         MUTATOR_CALLHOOK(ClientConnect, this);
1195
1196         if (IS_REAL_CLIENT(this))
1197         {
1198                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1199                 {
1200                         CS(this).motd_actived_time = -1;
1201                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1202                 }
1203         }
1204 }
1205 /*
1206 =============
1207 ClientDisconnect
1208
1209 Called when a client disconnects from the server
1210 =============
1211 */
1212 .entity chatbubbleentity;
1213 void ClientDisconnect(entity this)
1214 {
1215         assert(IS_CLIENT(this), return);
1216
1217         PlayerStats_GameReport_FinalizePlayer(this);
1218         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1219         if (CS(this).active_minigame) part_minigame(this);
1220         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1221
1222         if (autocvar_sv_eventlog)
1223                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1224
1225         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1226
1227         if(IS_SPEC(this))
1228                 SetSpectatee(this, NULL);
1229
1230     MUTATOR_CALLHOOK(ClientDisconnect, this);
1231
1232         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1233         strfree(CS(this).weaponorder_byimpulse);
1234         ClientState_detach(this);
1235
1236         Portal_ClearAll(this);
1237
1238         Unfreeze(this, false);
1239
1240         RemoveGrapplingHooks(this);
1241
1242         // Here, everything has been done that requires this player to be a client.
1243
1244         this.flags &= ~FL_CLIENT;
1245
1246         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1247         if (this.killindicator) delete(this.killindicator);
1248
1249         IL_EACH(g_counters, it.realowner == this,
1250         {
1251                 delete(it);
1252         });
1253
1254         WaypointSprite_PlayerGone(this);
1255
1256         bot_relinkplayerlist();
1257
1258         strfree(this.clientstatus);
1259         if (this.personal) delete(this.personal);
1260
1261         this.playerid = 0;
1262         ReadyCount();
1263         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1264
1265         ONREMOVE(this);
1266 }
1267
1268 void ChatBubbleThink(entity this)
1269 {
1270         this.nextthink = time;
1271         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1272         {
1273                 if(this.owner) // but why can that ever be NULL?
1274                         this.owner.chatbubbleentity = NULL;
1275                 delete(this);
1276                 return;
1277         }
1278
1279         this.mdl = "";
1280
1281         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1282         {
1283                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1284                         this.mdl = "models/sprites/minigame_busy.iqm";
1285                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1286                         this.mdl = "models/misc/chatbubble.spr";
1287         }
1288
1289         if ( this.model != this.mdl )
1290                 _setmodel(this, this.mdl);
1291
1292 }
1293
1294 void UpdateChatBubble(entity this)
1295 {
1296         if (this.alpha < 0)
1297                 return;
1298         // spawn a chatbubble entity if needed
1299         if (!this.chatbubbleentity)
1300         {
1301                 this.chatbubbleentity = new(chatbubbleentity);
1302                 this.chatbubbleentity.owner = this;
1303                 this.chatbubbleentity.exteriormodeltoclient = this;
1304                 setthink(this.chatbubbleentity, ChatBubbleThink);
1305                 this.chatbubbleentity.nextthink = time;
1306                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1307                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1308                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1309                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1310                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1311                 //this.chatbubbleentity.model = "";
1312                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1313         }
1314 }
1315
1316 void calculate_player_respawn_time(entity this)
1317 {
1318         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1319                 return;
1320
1321         float gametype_setting_tmp;
1322         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1323         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1324         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1325         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1326         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1327         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1328
1329         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1330         if (teamplay)
1331         {
1332                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1333                         if(it.team == this.team)
1334                                 ++pcount;
1335                 });
1336                 if (sdelay_small_count == 0)
1337                         sdelay_small_count = 1;
1338                 if (sdelay_large_count == 0)
1339                         sdelay_large_count = 1;
1340         }
1341         else
1342         {
1343                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1344                         ++pcount;
1345                 });
1346                 if (sdelay_small_count == 0)
1347                 {
1348                         if (IS_INDEPENDENT_PLAYER(this))
1349                         {
1350                                 // Players play independently. No point in requiring enemies.
1351                                 sdelay_small_count = 1;
1352                         }
1353                         else
1354                         {
1355                                 // Players play AGAINST each other. Enemies required.
1356                                 sdelay_small_count = 2;
1357                         }
1358                 }
1359                 if (sdelay_large_count == 0)
1360                 {
1361                         if (IS_INDEPENDENT_PLAYER(this))
1362                         {
1363                                 // Players play independently. No point in requiring enemies.
1364                                 sdelay_large_count = 1;
1365                         }
1366                         else
1367                         {
1368                                 // Players play AGAINST each other. Enemies required.
1369                                 sdelay_large_count = 2;
1370                         }
1371                 }
1372         }
1373
1374         float sdelay;
1375
1376         if (pcount <= sdelay_small_count)
1377                 sdelay = sdelay_small;
1378         else if (pcount >= sdelay_large_count)
1379                 sdelay = sdelay_large;
1380         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1381                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1382
1383         if(waves)
1384                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1385         else
1386                 this.respawn_time = time + sdelay;
1387
1388         if(sdelay < sdelay_max)
1389                 this.respawn_time_max = time + sdelay_max;
1390         else
1391                 this.respawn_time_max = this.respawn_time;
1392
1393         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1394                 this.respawn_countdown = 10; // first number to count down from is 10
1395         else
1396                 this.respawn_countdown = -1; // do not count down
1397
1398         if(autocvar_g_forced_respawn)
1399                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1400 }
1401
1402 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1403 // added to the model skins
1404 /*void UpdateColorModHack()
1405 {
1406         float c;
1407         c = this.clientcolors & 15;
1408         // LordHavoc: only bothering to support white, green, red, yellow, blue
1409              if (!teamplay) this.colormod = '0 0 0';
1410         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1411         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1412         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1413         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1414         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1415         else this.colormod = '1 1 1';
1416 }*/
1417
1418 void respawn(entity this)
1419 {
1420         bool damagedbycontents_prev = this.damagedbycontents;
1421         if(this.alpha >= 0)
1422         {
1423                 if(autocvar_g_respawn_ghosts)
1424                 {
1425                         this.solid = SOLID_NOT;
1426                         this.takedamage = DAMAGE_NO;
1427                         this.damagedbycontents = false;
1428                         set_movetype(this, MOVETYPE_FLY);
1429                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1430                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1431                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1432                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1433                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1434                         if(autocvar_g_respawn_ghosts_time > 0)
1435                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1436                 }
1437                 else
1438                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1439         }
1440
1441         CopyBody(this, 1);
1442         this.damagedbycontents = damagedbycontents_prev;
1443
1444         this.effects |= EF_NODRAW; // prevent another CopyBody
1445         PutClientInServer(this);
1446 }
1447
1448 ERASEABLE
1449 void PrintToChat(entity client, string text)
1450 {
1451         text = strcat("\{1}^7", text, "\n");
1452         sprint(client, text);
1453 }
1454
1455 ERASEABLE
1456 void DebugPrintToChat(entity client, string text)
1457 {
1458         if (autocvar_developer > 0)
1459         {
1460                 PrintToChat(client, text);
1461         }
1462 }
1463
1464 ERASEABLE
1465 void PrintToChatAll(string text)
1466 {
1467         text = strcat("\{1}^7", text, "\n");
1468         bprint(text);
1469 }
1470
1471 ERASEABLE
1472 void DebugPrintToChatAll(string text)
1473 {
1474         if (autocvar_developer > 0)
1475         {
1476                 PrintToChatAll(text);
1477         }
1478 }
1479
1480 ERASEABLE
1481 void PrintToChatTeam(int team_num, string text)
1482 {
1483         text = strcat("\{1}^7", text, "\n");
1484         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1485         {
1486                 if (it.team == team_num)
1487                 {
1488                         sprint(it, text);
1489                 }
1490         });
1491 }
1492
1493 ERASEABLE
1494 void DebugPrintToChatTeam(int team_num, string text)
1495 {
1496         if (autocvar_developer > 0)
1497         {
1498                 PrintToChatTeam(team_num, text);
1499         }
1500 }
1501
1502 void play_countdown(entity this, float finished, Sound samp)
1503 {
1504         TC(Sound, samp);
1505         if(IS_REAL_CLIENT(this))
1506                 if(floor(finished - time - frametime) != floor(finished - time))
1507                         if(finished - time < 6)
1508                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1509 }
1510
1511 void player_powerups(entity this)
1512 {
1513         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1514                 this.modelflags |= MF_ROCKET;
1515         else
1516                 this.modelflags &= ~MF_ROCKET;
1517
1518         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1519
1520         if (IS_DEAD(this))
1521         {
1522                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1523                 {
1524                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1525                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1526                         this.items &= ~ITEM_Strength.m_itemid;
1527                         this.items &= ~ITEM_Shield.m_itemid;
1528                         this.items -= (this.items & IT_SUPERWEAPON);
1529                 }
1530         }
1531
1532         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1533                 return;
1534
1535         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1536         int items_prev = this.items;
1537
1538         Fire_ApplyDamage(this);
1539         Fire_ApplyEffect(this);
1540
1541         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1542         {
1543                 if (this.items & ITEM_Strength.m_itemid)
1544                 {
1545                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1546                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1547                         if (time > STAT(STRENGTH_FINISHED, this))
1548                         {
1549                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1550                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1551                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1552                         }
1553                 }
1554                 else
1555                 {
1556                         if (time < STAT(STRENGTH_FINISHED, this))
1557                         {
1558                                 this.items = this.items | ITEM_Strength.m_itemid;
1559                                 if(!g_cts)
1560                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1561                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1562                         }
1563                 }
1564                 if (this.items & ITEM_Shield.m_itemid)
1565                 {
1566                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1567                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1568                         if (time > STAT(INVINCIBLE_FINISHED, this))
1569                         {
1570                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1571                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1572                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1573                         }
1574                 }
1575                 else
1576                 {
1577                         if (time < STAT(INVINCIBLE_FINISHED, this))
1578                         {
1579                                 this.items = this.items | ITEM_Shield.m_itemid;
1580                                 if(!g_cts)
1581                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1582                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1583                         }
1584                 }
1585                 if (this.items & IT_SUPERWEAPON)
1586                 {
1587                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1588                         {
1589                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1590                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1591                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1592                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1593                         }
1594                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1595                         {
1596                                 // don't let them run out
1597                         }
1598                         else
1599                         {
1600                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1601                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1602                                 {
1603                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1604                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1605                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1606                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1607                                 }
1608                         }
1609                 }
1610                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1611                 {
1612                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1613                         {
1614                                 this.items = this.items | IT_SUPERWEAPON;
1615                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1616                                 {
1617                                         if(!g_cts)
1618                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1619                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1620                                 }
1621                         }
1622                         else
1623                         {
1624                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1625                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1626                         }
1627                 }
1628                 else
1629                 {
1630                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1631                 }
1632         }
1633
1634         if(autocvar_g_nodepthtestplayers)
1635                 this.effects = this.effects | EF_NODEPTHTEST;
1636
1637         if(autocvar_g_fullbrightplayers)
1638                 this.effects = this.effects | EF_FULLBRIGHT;
1639
1640         if (time >= game_starttime)
1641         if (time < this.spawnshieldtime)
1642                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1643
1644         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1645 }
1646
1647 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1648 {
1649         if(current > stable)
1650                 return current;
1651         else if(current > stable - 0.25) // when close enough, "snap"
1652                 return stable;
1653         else
1654                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1655 }
1656
1657 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1658 {
1659         if(current < stable)
1660                 return current;
1661         else if(current < stable + 0.25) // when close enough, "snap"
1662                 return stable;
1663         else
1664                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1665 }
1666
1667 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1668 {
1669         float old = GetResource(this, res);
1670         float current = old;
1671         if(current > rotstable)
1672         {
1673                 if(rotframetime > 0)
1674                 {
1675                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1676                         current = max(rotstable, current - rotlinear * rotframetime);
1677                 }
1678         }
1679         else if(current < regenstable)
1680         {
1681                 if(regenframetime > 0)
1682                 {
1683                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1684                         current = min(regenstable, current + regenlinear * regenframetime);
1685                 }
1686         }
1687
1688         float limit = GetResourceLimit(this, res) * limit_mod;
1689         if(current > limit)
1690                 current = limit;
1691
1692         if (current != old)
1693                 SetResource(this, res, current);
1694 }
1695
1696 void player_regen(entity this)
1697 {
1698         float max_mod, regen_mod, rot_mod, limit_mod;
1699         max_mod = regen_mod = rot_mod = limit_mod = 1;
1700
1701         float regen_health = autocvar_g_balance_health_regen;
1702         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1703         float regen_health_rot = autocvar_g_balance_health_rot;
1704         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1705         float regen_health_stable = autocvar_g_balance_health_regenstable;
1706         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1707         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1708                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1709         max_mod = M_ARGV(1, float);
1710         regen_mod = M_ARGV(2, float);
1711         rot_mod = M_ARGV(3, float);
1712         limit_mod = M_ARGV(4, float);
1713         regen_health = M_ARGV(5, float);
1714         regen_health_linear = M_ARGV(6, float);
1715         regen_health_rot = M_ARGV(7, float);
1716         regen_health_rotlinear = M_ARGV(8, float);
1717         regen_health_stable = M_ARGV(9, float);
1718         regen_health_rotstable = M_ARGV(10, float);
1719
1720         if(!mutator_returnvalue)
1721         if(!STAT(FROZEN, this))
1722         {
1723                 float maxa = autocvar_g_balance_armor_rotstable;
1724                 float mina = autocvar_g_balance_armor_regenstable;
1725
1726                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1727                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1728                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1729
1730                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1731                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1732                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1733         }
1734
1735         // if player rotted to death...  die!
1736         // check this outside above checks, as player may still be able to rot to death
1737         if(GetResource(this, RES_HEALTH) < 1)
1738         {
1739                 if(this.vehicle)
1740                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1741                 if(this.event_damage)
1742                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1743         }
1744
1745         if (!(this.items & IT_UNLIMITED_AMMO))
1746         {
1747                 float maxf = autocvar_g_balance_fuel_rotstable;
1748                 float minf = autocvar_g_balance_fuel_regenstable;
1749
1750                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1751                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1752                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1753         }
1754 }
1755
1756 bool zoomstate_set;
1757 void SetZoomState(entity this, float newzoom)
1758 {
1759         if(newzoom != CS(this).zoomstate)
1760         {
1761                 CS(this).zoomstate = newzoom;
1762                 ClientData_Touch(this);
1763         }
1764         zoomstate_set = true;
1765 }
1766
1767 void GetPressedKeys(entity this)
1768 {
1769         MUTATOR_CALLHOOK(GetPressedKeys, this);
1770         int keys = STAT(PRESSED_KEYS, this);
1771         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1772         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1773         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1774         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1775
1776         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1777         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1778         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1779         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1780         CS(this).pressedkeys = keys; // store for other users
1781
1782         STAT(PRESSED_KEYS, this) = keys;
1783 }
1784
1785 /*
1786 ======================
1787 spectate mode routines
1788 ======================
1789 */
1790
1791 void SpectateCopy(entity this, entity spectatee)
1792 {
1793         TC(Client, this); TC(Client, spectatee);
1794
1795         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1796         PS(this) = PS(spectatee);
1797         this.armortype = spectatee.armortype;
1798         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1799         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1800         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1801         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1802         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1803         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1804         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1805         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1806         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1807         CS(this).impulse = 0;
1808         this.disableclientprediction = 1; // no need to run prediction on a spectator
1809         this.items = spectatee.items;
1810         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1811         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1812         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1813         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1814         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1815         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1816         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1817         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1818         this.punchangle = spectatee.punchangle;
1819         this.view_ofs = spectatee.view_ofs;
1820         this.velocity = spectatee.velocity;
1821         this.dmg_take = spectatee.dmg_take;
1822         this.dmg_save = spectatee.dmg_save;
1823         this.dmg_inflictor = spectatee.dmg_inflictor;
1824         this.v_angle = spectatee.v_angle;
1825         this.angles = spectatee.v_angle;
1826         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1827         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1828         this.viewloc = spectatee.viewloc;
1829         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1830                 this.fixangle = true;
1831         setorigin(this, spectatee.origin);
1832         setsize(this, spectatee.mins, spectatee.maxs);
1833         SetZoomState(this, CS(spectatee).zoomstate);
1834
1835     anticheat_spectatecopy(this, spectatee);
1836         STAT(HUD, this) = STAT(HUD, spectatee);
1837         if(spectatee.vehicle)
1838     {
1839         this.angles = spectatee.v_angle;
1840
1841         //this.fixangle = false;
1842         //this.velocity = spectatee.vehicle.velocity;
1843         this.vehicle_health = spectatee.vehicle_health;
1844         this.vehicle_shield = spectatee.vehicle_shield;
1845         this.vehicle_energy = spectatee.vehicle_energy;
1846         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1847         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1848         this.vehicle_reload1 = spectatee.vehicle_reload1;
1849         this.vehicle_reload2 = spectatee.vehicle_reload2;
1850
1851         //msg_entity = this;
1852
1853        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1854             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1855            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1856            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1857
1858         //WriteByte (MSG_ONE, SVC_SETVIEW);
1859         //    WriteEntity(MSG_ONE, this);
1860         //makevectors(spectatee.v_angle);
1861         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1862     }
1863 }
1864
1865 bool SpectateUpdate(entity this)
1866 {
1867         if(!this.enemy)
1868                 return false;
1869
1870         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1871         {
1872                 SetSpectatee(this, NULL);
1873                 return false;
1874         }
1875
1876         SpectateCopy(this, this.enemy);
1877
1878         return true;
1879 }
1880
1881 bool SpectateSet(entity this)
1882 {
1883         if(!IS_PLAYER(this.enemy))
1884                 return false;
1885
1886         ClientData_Touch(this.enemy);
1887
1888         msg_entity = this;
1889         WriteByte(MSG_ONE, SVC_SETVIEW);
1890         WriteEntity(MSG_ONE, this.enemy);
1891         set_movetype(this, MOVETYPE_NONE);
1892         accuracy_resend(this);
1893
1894         if(!SpectateUpdate(this))
1895                 PutObserverInServer(this);
1896
1897         return true;
1898 }
1899
1900 void SetSpectatee_status(entity this, int spectatee_num)
1901 {
1902         int oldspectatee_status = CS(this).spectatee_status;
1903         CS(this).spectatee_status = spectatee_num;
1904
1905         if (CS(this).spectatee_status != oldspectatee_status)
1906         {
1907                 if (STAT(PRESSED_KEYS, this))
1908                 {
1909                         CS(this).pressedkeys = 0;
1910                         STAT(PRESSED_KEYS, this) = 0;
1911                 }
1912                 ClientData_Touch(this);
1913                 if (g_race || g_cts) race_InitSpectator();
1914         }
1915 }
1916
1917 void SetSpectatee(entity this, entity spectatee)
1918 {
1919         if(IS_BOT_CLIENT(this))
1920                 return; // bots abuse .enemy, this code is useless to them
1921
1922         entity old_spectatee = this.enemy;
1923
1924         this.enemy = spectatee;
1925
1926         // WEAPONTODO
1927         // these are required to fix the spectator bug with arc
1928         if(old_spectatee)
1929         {
1930                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1931                 {
1932                         .entity weaponentity = weaponentities[slot];
1933                         if(old_spectatee.(weaponentity).arc_beam)
1934                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1935                 }
1936         }
1937         if(this.enemy)
1938         {
1939                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1940                 {
1941                         .entity weaponentity = weaponentities[slot];
1942                         if(this.enemy.(weaponentity).arc_beam)
1943                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1944                 }
1945         }
1946
1947         if (this.enemy)
1948                 SetSpectatee_status(this, etof(this.enemy));
1949
1950         // needed to update spectator list
1951         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1952 }
1953
1954 bool Spectate(entity this, entity pl)
1955 {
1956         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1957                 return false;
1958         pl = M_ARGV(1, entity);
1959
1960         SetSpectatee(this, pl);
1961         return SpectateSet(this);
1962 }
1963
1964 bool SpectateNext(entity this)
1965 {
1966         entity ent = find(this.enemy, classname, STR_PLAYER);
1967
1968         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1969                 ent = M_ARGV(1, entity);
1970         else if (!ent)
1971                 ent = find(ent, classname, STR_PLAYER);
1972
1973         if(ent) { SetSpectatee(this, ent); }
1974
1975         return SpectateSet(this);
1976 }
1977
1978 bool SpectatePrev(entity this)
1979 {
1980         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1981         entity ent = findchain(classname, STR_PLAYER);
1982         if (!ent) // no player
1983                 return false;
1984
1985         entity first = ent;
1986         // skip players until current spectated player
1987         if(this.enemy)
1988         while(ent && ent != this.enemy)
1989                 ent = ent.chain;
1990
1991         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1992         {
1993                 case MUT_SPECPREV_FOUND:
1994                     ent = M_ARGV(1, entity);
1995                     break;
1996                 case MUT_SPECPREV_RETURN:
1997                     return true;
1998                 case MUT_SPECPREV_CONTINUE:
1999                 default:
2000                 {
2001                         if(ent.chain)
2002                                 ent = ent.chain;
2003                         else
2004                                 ent = first;
2005                         break;
2006                 }
2007         }
2008
2009         SetSpectatee(this, ent);
2010         return SpectateSet(this);
2011 }
2012
2013 /*
2014 =============
2015 ShowRespawnCountdown()
2016
2017 Update a respawn countdown display.
2018 =============
2019 */
2020 void ShowRespawnCountdown(entity this)
2021 {
2022         float number;
2023         if(!IS_DEAD(this)) // just respawned?
2024                 return;
2025         else
2026         {
2027                 number = ceil(this.respawn_time - time);
2028                 if(number <= 0)
2029                         return;
2030                 if(number <= this.respawn_countdown)
2031                 {
2032                         this.respawn_countdown = number - 1;
2033                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2034                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2035                 }
2036         }
2037 }
2038
2039 .bool team_selected;
2040 bool ShowTeamSelection(entity this)
2041 {
2042         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2043                 return false;
2044         stuffcmd(this, "menu_showteamselect\n");
2045         return true;
2046 }
2047 void Join(entity this)
2048 {
2049         TRANSMUTE(Player, this);
2050
2051         if(!this.team_selected)
2052         if(autocvar_g_campaign || autocvar_g_balance_teams)
2053                 TeamBalance_JoinBestTeam(this);
2054
2055         if(autocvar_g_campaign)
2056                 campaign_bots_may_start = true;
2057
2058         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2059
2060         PutClientInServer(this);
2061
2062         if(IS_PLAYER(this))
2063         if(teamplay && this.team != -1)
2064         {
2065         }
2066         else
2067                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2068         this.team_selected = false;
2069 }
2070
2071 int GetPlayerLimit()
2072 {
2073         if(g_duel)
2074                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2075         int player_limit = autocvar_g_maxplayers;
2076         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2077         player_limit = M_ARGV(0, int);
2078         return player_limit;
2079 }
2080
2081 /**
2082  * Determines whether the player is allowed to join. This depends on cvar
2083  * g_maxplayers, if it isn't used this function always return true, otherwise
2084  * it checks whether the number of currently playing players exceeds g_maxplayers.
2085  * @return int number of free slots for players, 0 if none
2086  */
2087 int nJoinAllowed(entity this, entity ignore)
2088 {
2089         if(!ignore)
2090         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2091         // so report 0 free slots if restricted
2092         {
2093                 if(autocvar_g_forced_team_otherwise == "spectate")
2094                         return 0;
2095                 if(autocvar_g_forced_team_otherwise == "spectator")
2096                         return 0;
2097         }
2098
2099         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2100                 return 0; // forced spectators can never join
2101
2102         // TODO simplify this
2103         int totalClients = 0;
2104         int currentlyPlaying = 0;
2105         FOREACH_CLIENT(true, {
2106                 if(it != ignore)
2107                         ++totalClients;
2108                 if(IS_REAL_CLIENT(it))
2109                 if(IS_PLAYER(it) || it.caplayer)
2110                         ++currentlyPlaying;
2111         });
2112
2113         int player_limit = GetPlayerLimit();
2114
2115         int free_slots = 0;
2116         if (!player_limit)
2117                 free_slots = maxclients - totalClients;
2118         else if(player_limit > 0 && currentlyPlaying < player_limit)
2119                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2120
2121         static float msg_time = 0;
2122         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2123         {
2124                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2125                 msg_time = time + 0.5;
2126         }
2127
2128         return free_slots;
2129 }
2130
2131 /**
2132  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2133  * g_maxplayers_spectator_blocktime seconds
2134  */
2135 void checkSpectatorBlock(entity this)
2136 {
2137         if(IS_SPEC(this) || IS_OBSERVER(this))
2138         if(!this.caplayer)
2139         if(IS_REAL_CLIENT(this))
2140         {
2141                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2142                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2143                         dropclient(this);
2144                 }
2145         }
2146 }
2147
2148 void PrintWelcomeMessage(entity this)
2149 {
2150         if(CS(this).motd_actived_time == 0)
2151         {
2152                 if (autocvar_g_campaign) {
2153                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2154                                 CS(this).motd_actived_time = time;
2155                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2156                         }
2157                 } else {
2158                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2159                                 CS(this).motd_actived_time = time;
2160                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2161                         }
2162                 }
2163         }
2164         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2165         {
2166                 if (autocvar_g_campaign) {
2167                         if (PHYS_INPUT_BUTTON_INFO(this))
2168                                 CS(this).motd_actived_time = time;
2169                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2170                                 CS(this).motd_actived_time = 0;
2171                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2172                         }
2173                 } else {
2174                         if (PHYS_INPUT_BUTTON_INFO(this))
2175                                 CS(this).motd_actived_time = time;
2176                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2177                                 CS(this).motd_actived_time = 0;
2178                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2179                         }
2180                 }
2181         }
2182         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2183         {
2184                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2185                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2186                 else if (CS(this).motd_actived_time == -2)
2187                 {
2188                         // instantly hide MOTD
2189                         CS(this).motd_actived_time = 0;
2190                         if (autocvar_g_campaign)
2191                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2192                         else
2193                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2194                 }
2195                 else if (IS_PLAYER(this) || IS_SPEC(this))
2196                 {
2197                         // FIXME occasionally for some reason MOTD never goes away
2198                         // delay MOTD removal a little bit in the hope it fixes this bug
2199                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2200                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2201                         else //if (CS(this).motd_actived_time < -2)
2202                                 CS(this).motd_actived_time++;
2203                 }
2204         }
2205 }
2206
2207 bool joinAllowed(entity this)
2208 {
2209         if (CS(this).version_mismatch) return false;
2210         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2211         if (!nJoinAllowed(this, this)) return false;
2212         if (teamplay && lockteams) return false;
2213         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2214         if (ShowTeamSelection(this)) return false;
2215         return true;
2216 }
2217
2218 .string shootfromfixedorigin;
2219 .bool dualwielding_prev;
2220 bool PlayerThink(entity this)
2221 {
2222         if (game_stopped || intermission_running) {
2223                 this.modelflags &= ~MF_ROCKET;
2224                 if(intermission_running)
2225                         IntermissionThink(this);
2226                 return false;
2227         }
2228
2229         if (timeout_status == TIMEOUT_ACTIVE) {
2230         // don't allow the player to turn around while game is paused
2231                 // FIXME turn this into CSQC stuff
2232                 this.v_angle = this.lastV_angle;
2233                 this.angles = this.lastV_angle;
2234                 this.fixangle = true;
2235         }
2236
2237         if (frametime) player_powerups(this);
2238
2239         if (IS_DEAD(this)) {
2240                 if (this.personal && g_race_qualifying) {
2241                         if (time > this.respawn_time) {
2242                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2243                                 respawn(this);
2244                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2245                         }
2246                 } else {
2247                         if (frametime) player_anim(this);
2248
2249                         if (this.respawn_flags & RESPAWN_DENY)
2250                         {
2251                                 STAT(RESPAWN_TIME, this) = 0;
2252                                 return false;
2253                         }
2254
2255                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2256
2257                         switch(this.deadflag)
2258                         {
2259                                 case DEAD_DYING:
2260                                 {
2261                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2262                                                 this.deadflag = DEAD_RESPAWNING;
2263                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2264                                                 this.deadflag = DEAD_DEAD;
2265                                         break;
2266                                 }
2267                                 case DEAD_DEAD:
2268                                 {
2269                                         if (button_pressed)
2270                                                 this.deadflag = DEAD_RESPAWNABLE;
2271                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2272                                                 this.deadflag = DEAD_RESPAWNING;
2273                                         break;
2274                                 }
2275                                 case DEAD_RESPAWNABLE:
2276                                 {
2277                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2278                                                 this.deadflag = DEAD_RESPAWNING;
2279                                         break;
2280                                 }
2281                                 case DEAD_RESPAWNING:
2282                                 {
2283                                         if (time > this.respawn_time)
2284                                         {
2285                                                 this.respawn_time = time + 1; // only retry once a second
2286                                                 this.respawn_time_max = this.respawn_time;
2287                                                 respawn(this);
2288                                         }
2289                                         break;
2290                                 }
2291                         }
2292
2293                         ShowRespawnCountdown(this);
2294
2295                         if (this.respawn_flags & RESPAWN_SILENT)
2296                                 STAT(RESPAWN_TIME, this) = 0;
2297                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2298                         {
2299                                 if (time < this.respawn_time)
2300                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2301                                 else if (this.deadflag != DEAD_RESPAWNING)
2302                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2303                         }
2304                         else
2305                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2306                 }
2307
2308                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2309                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2310                         STAT(RESPAWN_TIME, this) *= -1;
2311
2312                 return false;
2313         }
2314
2315         FixPlayermodel(this);
2316
2317         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2318                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2319                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2320         }
2321
2322         // reset gun alignment when dual wielding status changes
2323         // to ensure guns are always aligned right and left
2324         bool dualwielding = W_DualWielding(this);
2325         if(this.dualwielding_prev != dualwielding)
2326         {
2327                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2328                 this.dualwielding_prev = dualwielding;
2329         }
2330
2331         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2332         //if(frametime)
2333         {
2334                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2335                 {
2336                         .entity weaponentity = weaponentities[slot];
2337                         if(WEP_CVAR(vortex, charge_always))
2338                                 W_Vortex_Charge(this, weaponentity, frametime);
2339                         W_WeaponFrame(this, weaponentity);
2340                 }
2341         }
2342
2343         if (frametime)
2344         {
2345                 // WEAPONTODO: Add a weapon request for this
2346                 // rot vortex charge to the charge limit
2347                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2348                 {
2349                         .entity weaponentity = weaponentities[slot];
2350                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2351                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2352                 }
2353
2354                 player_regen(this);
2355                 player_anim(this);
2356                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2357         }
2358
2359         monsters_setstatus(this);
2360
2361         return true;
2362 }
2363
2364 .bool would_spectate;
2365 void ObserverOrSpectatorThink(entity this)
2366 {
2367         bool is_spec = IS_SPEC(this);
2368         if ( CS(this).impulse )
2369         {
2370                 int r = MinigameImpulse(this, CS(this).impulse);
2371                 if (!is_spec || r)
2372                         CS(this).impulse = 0;
2373
2374                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2375                 {
2376                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2377                         CS(this).impulse = 0;
2378                         return;
2379                 }
2380         }
2381
2382         if (this.flags & FL_JUMPRELEASED) {
2383                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2384                         this.flags &= ~FL_JUMPRELEASED;
2385                         this.flags |= FL_SPAWNING;
2386                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2387                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2388                         this.flags &= ~FL_JUMPRELEASED;
2389                         if(SpectateNext(this)) {
2390                                 TRANSMUTE(Spectator, this);
2391                         } else if (is_spec) {
2392                                 TRANSMUTE(Observer, this);
2393                                 PutClientInServer(this);
2394                         }
2395                         if (is_spec)
2396                                 CS(this).impulse = 0;
2397                 } else if (is_spec) {
2398                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2399                                 this.flags &= ~FL_JUMPRELEASED;
2400                                 if(SpectatePrev(this)) {
2401                                         TRANSMUTE(Spectator, this);
2402                                 } else {
2403                                         TRANSMUTE(Observer, this);
2404                                         PutClientInServer(this);
2405                                 }
2406                                 CS(this).impulse = 0;
2407                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2408                                 this.would_spectate = false;
2409                                 this.flags &= ~FL_JUMPRELEASED;
2410                                 TRANSMUTE(Observer, this);
2411                                 PutClientInServer(this);
2412                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2413                                 PutObserverInServer(this);
2414                                 this.would_spectate = true;
2415                         }
2416                 }
2417                 else {
2418                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2419                         set_movetype(this, preferred_movetype);
2420                 }
2421         } else {
2422                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2423                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2424                         this.flags |= FL_JUMPRELEASED;
2425                         if(this.flags & FL_SPAWNING)
2426                         {
2427                                 this.flags &= ~FL_SPAWNING;
2428                                 if(joinAllowed(this))
2429                                         Join(this);
2430                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2431                                         CS(this).autojoin_checked = -1;
2432                                 return;
2433                         }
2434                 }
2435                 if(is_spec && !SpectateUpdate(this))
2436                         PutObserverInServer(this);
2437         }
2438         if (is_spec)
2439                 this.flags |= FL_CLIENT | FL_NOTARGET;
2440 }
2441
2442 void PlayerUseKey(entity this)
2443 {
2444         if (!IS_PLAYER(this))
2445                 return;
2446
2447         if(this.vehicle)
2448         {
2449                 if(!game_stopped)
2450                 {
2451                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2452                         return;
2453                 }
2454         }
2455         else if(autocvar_g_vehicles_enter)
2456         {
2457                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2458                 {
2459                         entity head, closest_target = NULL;
2460                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2461
2462                         while(head) // find the closest acceptable target to enter
2463                         {
2464                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2465                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2466                                 {
2467                                         if(closest_target)
2468                                         {
2469                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2470                                                 { closest_target = head; }
2471                                         }
2472                                         else { closest_target = head; }
2473                                 }
2474
2475                                 head = head.chain;
2476                         }
2477
2478                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2479                 }
2480         }
2481
2482         // a use key was pressed; call handlers
2483         MUTATOR_CALLHOOK(PlayerUseKey, this);
2484 }
2485
2486
2487 /*
2488 =============
2489 PlayerPreThink
2490
2491 Called every frame for each client before the physics are run
2492 =============
2493 */
2494 .float last_vehiclecheck;
2495 void PlayerPreThink (entity this)
2496 {
2497         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2498         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2499
2500         WarpZone_PlayerPhysics_FixVAngle(this);
2501
2502         if (frametime) {
2503                 // physics frames: update anticheat stuff
2504                 anticheat_prethink(this);
2505         }
2506
2507         if (blockSpectators && frametime) {
2508                 // WORKAROUND: only use dropclient in server frames (frametime set).
2509                 // Never use it in cl_movement frames (frametime zero).
2510                 checkSpectatorBlock(this);
2511         }
2512
2513         zoomstate_set = false;
2514
2515         // Check for nameless players
2516         if (this.netname == "" || this.netname != CS(this).netname_previous)
2517         {
2518                 bool assume_unchanged = (CS(this).netname_previous == "");
2519                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2520                 {
2521                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2522                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2523                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2524                         assume_unchanged = false;
2525                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2526                 }
2527                 if (isInvisibleString(this.netname))
2528                 {
2529                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2530                         sprint(this, "Warning: invisible names are not allowed.\n");
2531                         assume_unchanged = false;
2532                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2533                 }
2534                 if (!assume_unchanged && autocvar_sv_eventlog)
2535                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2536                 strcpy(CS(this).netname_previous, this.netname);
2537         }
2538
2539         // version nagging
2540         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2541         CS(this).version_nagtime = 0;
2542         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2543             // git client
2544         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2545             // git server
2546             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2547         } else {
2548             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2549             if (r < 0) { // old client
2550                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2551             } else if (r > 0) { // old server
2552                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2553             }
2554         }
2555     }
2556
2557         // GOD MODE info
2558         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2559         {
2560                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2561                 this.max_armorvalue = 0;
2562         }
2563
2564         if (frametime && IS_PLAYER(this))
2565         {
2566                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2567                 {
2568                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2569                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2570                         if (this.iceblock)
2571                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2572
2573                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2574                                 Unfreeze(this, false);
2575                 }
2576                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2577                 {
2578                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2579                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2580
2581                         if (GetResource(this, RES_HEALTH) < 1)
2582                         {
2583                                 if (this.vehicle)
2584                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2585                                 if(this.event_damage)
2586                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2587                         }
2588                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2589                                 Unfreeze(this, false);
2590                 }
2591         }
2592
2593         MUTATOR_CALLHOOK(PlayerPreThink, this);
2594
2595         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2596         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2597         {
2598                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2599                 {
2600                         if(!it.owner)
2601                         {
2602                                 if(!it.team || SAME_TEAM(this, it))
2603                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2604                                 else if(autocvar_g_vehicles_steal)
2605                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2606                         }
2607                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2608                         {
2609                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2610                         }
2611                 });
2612
2613                 this.last_vehiclecheck = time + 1;
2614         }
2615
2616         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2617         {
2618                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2619                         PlayerUseKey(this);
2620                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2621         }
2622
2623         if (IS_REAL_CLIENT(this))
2624                 PrintWelcomeMessage(this);
2625
2626         if (IS_PLAYER(this)) {
2627                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2628                         error("Client can't be spawned as player on connection!");
2629                 if(!PlayerThink(this))
2630                         return;
2631         }
2632         else if (game_stopped || intermission_running) {
2633                 if(intermission_running)
2634                         IntermissionThink(this);
2635                 return;
2636         }
2637         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2638         {
2639                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2640                 CS(this).autojoin_checked = 1;
2641                 // don't do this in ClientConnect
2642                 // many things can go wrong if a client is spawned as player on connection
2643                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2644                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2645                                 && (!teamplay || autocvar_g_balance_teams)))
2646                 {
2647                         campaign_bots_may_start = true;
2648                         if(joinAllowed(this))
2649                                 Join(this);
2650                         return;
2651                 }
2652         }
2653         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2654                 ObserverOrSpectatorThink(this);
2655         }
2656
2657         // WEAPONTODO: Add weapon request for this
2658         if (!zoomstate_set) {
2659                 bool wep_zoomed = false;
2660                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2661                 {
2662                         .entity weaponentity = weaponentities[slot];
2663                         Weapon thiswep = this.(weaponentity).m_weapon;
2664                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2665                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2666                 }
2667                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2668         }
2669
2670         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2671         {
2672                 CS(this).teamkill_soundtime = 0;
2673
2674                 entity e = CS(this).teamkill_soundsource;
2675                 entity oldpusher = e.pusher;
2676                 e.pusher = this;
2677                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2678                 e.pusher = oldpusher;
2679         }
2680
2681         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2682                 CS(this).taunt_soundtime = 0;
2683                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2684         }
2685
2686         target_voicescript_next(this);
2687
2688         // WEAPONTODO: Move into weaponsystem somehow
2689         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2690         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2691         {
2692                 .entity weaponentity = weaponentities[slot];
2693                 if(this.(weaponentity).m_weapon == WEP_Null)
2694                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2695         }
2696 }
2697
2698 void DrownPlayer(entity this)
2699 {
2700         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2701                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2702         {
2703                 STAT(AIR_FINISHED, this) = 0;
2704                 return;
2705         }
2706
2707         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2708         {
2709                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2710                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2711                 STAT(AIR_FINISHED, this) = 0;
2712         }
2713         else
2714         {
2715                 if (!STAT(AIR_FINISHED, this))
2716                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2717                 if (STAT(AIR_FINISHED, this) < time)
2718                 {       // drown!
2719                         if (this.pain_finished < time)
2720                         {
2721                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2722                                 this.pain_finished = time + 0.5;
2723                         }
2724                 }
2725         }
2726 }
2727
2728 .bool move_qcphysics;
2729
2730 void Player_Physics(entity this)
2731 {
2732         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2733
2734         if(!this.move_qcphysics)
2735                 return;
2736
2737         if(!frametime && !CS(this).pm_frametime)
2738                 return;
2739
2740         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2741
2742         CS(this).pm_frametime = 0;
2743 }
2744
2745 /*
2746 =============
2747 PlayerPostThink
2748
2749 Called every frame for each client after the physics are run
2750 =============
2751 */
2752 void PlayerPostThink (entity this)
2753 {
2754         Player_Physics(this);
2755
2756         if (sv_maxidle > 0)
2757         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2758         if (IS_REAL_CLIENT(this))
2759         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2760         {
2761                 int totalClients = 0;
2762                 if(sv_maxidle_slots > 0)
2763                 {
2764                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2765                         {
2766                                 ++totalClients;
2767                         });
2768                 }
2769
2770                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2771                 { /* do nothing */ }
2772                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2773                 {
2774                         if (CS(this).idlekick_lasttimeleft)
2775                         {
2776                                 CS(this).idlekick_lasttimeleft = 0;
2777                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2778                         }
2779                 }
2780                 else
2781                 {
2782                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2783                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2784                                 if (!CS(this).idlekick_lasttimeleft)
2785                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2786                         }
2787                         if (timeleft <= 0) {
2788                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2789                                 dropclient(this);
2790                                 return;
2791                         }
2792                         else if (timeleft <= 10) {
2793                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2794                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2795                 }
2796                                 CS(this).idlekick_lasttimeleft = timeleft;
2797                         }
2798                 }
2799         }
2800
2801         CheatFrame(this);
2802
2803         if (game_stopped)
2804         {
2805                 this.solid = SOLID_NOT;
2806                 this.takedamage = DAMAGE_NO;
2807                 set_movetype(this, MOVETYPE_NONE);
2808                 CS(this).teamkill_complain = 0;
2809                 CS(this).teamkill_soundtime = 0;
2810                 CS(this).teamkill_soundsource = NULL;
2811         }
2812
2813         if (IS_PLAYER(this)) {
2814                 if(this.death_time == time && IS_DEAD(this))
2815                 {
2816                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2817                         // once all the damage events of this frame have been processed with normal size
2818                         this.maxs.z = 5;
2819                         setsize(this, this.mins, this.maxs);
2820                 }
2821                 DrownPlayer(this);
2822                 UpdateChatBubble(this);
2823                 if (CS(this).impulse) ImpulseCommands(this);
2824                 if (game_stopped)
2825                 {
2826                         CSQCMODEL_AUTOUPDATE(this);
2827                         return;
2828                 }
2829                 GetPressedKeys(this);
2830         }
2831         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2832         {
2833                 CS(this).pressedkeys = 0;
2834                 STAT(PRESSED_KEYS, this) = 0;
2835         }
2836
2837         if (this.waypointsprite_attachedforcarrier) {
2838                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2839                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2840         }
2841
2842         CSQCMODEL_AUTOUPDATE(this);
2843 }
2844
2845 /**
2846  * message "": do not say, just test flood control
2847  * return value:
2848  *   1 = accept
2849  *   0 = reject
2850  *  -1 = fake accept
2851  */
2852 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2853 {
2854         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2855                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2856
2857         if (source)
2858                 msgin = formatmessage(source, msgin);
2859
2860         string colorstr;
2861         if (!(IS_PLAYER(source) || source.caplayer))
2862                 colorstr = "^0"; // black for spectators
2863         else if(teamplay)
2864                 colorstr = Team_ColorCode(source.team);
2865         else
2866         {
2867                 colorstr = "";
2868                 teamsay = false;
2869         }
2870
2871         if (!source) {
2872                 colorstr = "";
2873                 teamsay = false;
2874         }
2875
2876         if(msgin != "")
2877                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2878
2879         /*
2880          * using bprint solves this... me stupid
2881         // how can we prevent the message from appearing in a listen server?
2882         // for now, just give "say" back and only handle say_team
2883         if(!teamsay)
2884         {
2885                 clientcommand(source, strcat("say ", msgin));
2886                 return;
2887         }
2888         */
2889
2890         string namestr = "";
2891         if (source)
2892                 namestr = playername(source, autocvar_g_chat_teamcolors);
2893
2894         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2895
2896         string msgstr = "", cmsgstr = "";
2897         string privatemsgprefix = string_null;
2898         int privatemsgprefixlen = 0;
2899         if (msgin != "")
2900         {
2901                 bool found_me = false;
2902                 if(strstrofs(msgin, "/me", 0) >= 0)
2903                 {
2904                         string newmsgin = "";
2905                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2906                         FOREACH_WORD(msgin, true,
2907                         {
2908                                 if(strdecolorize(it) == "/me")
2909                                 {
2910                                         found_me = true;
2911                                         newmsgin = cons(newmsgin, newnamestr);
2912                                 }
2913                                 else
2914                                         newmsgin = cons(newmsgin, it);
2915                         });
2916                         msgin = newmsgin;
2917                 }
2918
2919                 if(privatesay)
2920                 {
2921                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2922                         privatemsgprefixlen = strlen(msgstr);
2923                         msgstr = strcat(msgstr, msgin);
2924                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2925                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2926                 }
2927                 else if(teamsay)
2928                 {
2929                         if(found_me)
2930                         {
2931                                 //msgin = strreplace("/me", "", msgin);
2932                                 //msgin = substring(msgin, 3, strlen(msgin));
2933                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2934                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2935                         }
2936                         else
2937                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2938                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2939                 }
2940                 else
2941                 {
2942                         if(found_me)
2943                         {
2944                                 //msgin = strreplace("/me", "", msgin);
2945                                 //msgin = substring(msgin, 3, strlen(msgin));
2946                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2947                                 msgstr = strcat("\{1}^4* ^7", msgin);
2948                         }
2949                         else {
2950                                 msgstr = "\{1}";
2951                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2952                                 msgstr = strcat(msgstr, msgin);
2953                         }
2954                         cmsgstr = "";
2955                 }
2956                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2957         }
2958
2959         string fullmsgstr = msgstr;
2960         string fullcmsgstr = cmsgstr;
2961
2962         // FLOOD CONTROL
2963         int flood = 0;
2964         var .float flood_field = floodcontrol_chat;
2965         if(floodcontrol && source)
2966         {
2967                 float flood_spl;
2968                 float flood_burst;
2969                 float flood_lmax;
2970                 float lines;
2971                 if(privatesay)
2972                 {
2973                         flood_spl = autocvar_g_chat_flood_spl_tell;
2974                         flood_burst = autocvar_g_chat_flood_burst_tell;
2975                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2976                         flood_field = floodcontrol_chattell;
2977                 }
2978                 else if(teamsay)
2979                 {
2980                         flood_spl = autocvar_g_chat_flood_spl_team;
2981                         flood_burst = autocvar_g_chat_flood_burst_team;
2982                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2983                         flood_field = floodcontrol_chatteam;
2984                 }
2985                 else
2986                 {
2987                         flood_spl = autocvar_g_chat_flood_spl;
2988                         flood_burst = autocvar_g_chat_flood_burst;
2989                         flood_lmax = autocvar_g_chat_flood_lmax;
2990                         flood_field = floodcontrol_chat;
2991                 }
2992                 flood_burst = max(0, flood_burst - 1);
2993                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2994
2995                 // do flood control for the default line size
2996                 if(msgstr != "")
2997                 {
2998                         getWrappedLine_remaining = msgstr;
2999                         msgstr = "";
3000                         lines = 0;
3001                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
3002                         {
3003                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
3004                                 ++lines;
3005                         }
3006                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3007
3008                         if(getWrappedLine_remaining != "")
3009                         {
3010                                 msgstr = strcat(msgstr, "\n");
3011                                 flood = 2;
3012                         }
3013
3014                         if (time >= source.(flood_field))
3015                         {
3016                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3017                         }
3018                         else
3019                         {
3020                                 flood = 1;
3021                                 msgstr = fullmsgstr;
3022                         }
3023                 }
3024                 else
3025                 {
3026                         if (time >= source.(flood_field))
3027                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3028                         else
3029                                 flood = 1;
3030                 }
3031
3032                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3033                         source.(flood_field) = flood = 0;
3034         }
3035
3036         string sourcemsgstr, sourcecmsgstr;
3037         if(flood == 2) // cannot happen for empty msgstr
3038         {
3039                 if(autocvar_g_chat_flood_notify_flooder)
3040                 {
3041                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3042                         sourcecmsgstr = "";
3043                 }
3044                 else
3045                 {
3046                         sourcemsgstr = fullmsgstr;
3047                         sourcecmsgstr = fullcmsgstr;
3048                 }
3049                 cmsgstr = "";
3050         }
3051         else
3052         {
3053                 sourcemsgstr = msgstr;
3054                 sourcecmsgstr = cmsgstr;
3055         }
3056
3057         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3058         {
3059                 if (!game_stopped)
3060                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
3061                         teamsay = -1; // spectators
3062         }
3063
3064         if(flood)
3065                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3066
3067         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3068         if(privatesay)
3069                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3070
3071         int ret;
3072         if(source && CS(source).muted)
3073         {
3074                 // always fake the message
3075                 ret = -1;
3076         }
3077         else if(flood == 1)
3078         {
3079                 if (autocvar_g_chat_flood_notify_flooder)
3080                 {
3081                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3082                         ret = 0;
3083                 }
3084                 else
3085                         ret = -1;
3086         }
3087         else
3088         {
3089                 ret = 1;
3090         }
3091
3092         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3093         {
3094                 if (!game_stopped)
3095                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3096                         ret = -1; // just hide the message completely
3097         }
3098
3099         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3100         ret = M_ARGV(1, int);
3101
3102         string event_log_msg = "";
3103
3104         if(sourcemsgstr != "" && ret != 0)
3105         {
3106                 if(ret < 0) // faked message, because the player is muted
3107                 {
3108                         sprint(source, sourcemsgstr);
3109                         if(sourcecmsgstr != "" && !privatesay)
3110                                 centerprint(source, sourcecmsgstr);
3111                 }
3112                 else if(privatesay) // private message, between 2 people only
3113                 {
3114                         sprint(source, sourcemsgstr);
3115                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3116                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3117                         {
3118                                 sprint(privatesay, msgstr);
3119                                 if(cmsgstr != "")
3120                                         centerprint(privatesay, cmsgstr);
3121                         }
3122                 }
3123                 else if ( teamsay && CS(source).active_minigame )
3124                 {
3125                         sprint(source, sourcemsgstr);
3126                         dedicated_print(msgstr); // send to server console too
3127                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3128                                 sprint(it, msgstr);
3129                         });
3130                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3131
3132                 }
3133                 else if(teamsay > 0) // team message, only sent to team mates
3134                 {
3135                         sprint(source, sourcemsgstr);
3136                         dedicated_print(msgstr); // send to server console too
3137                         if(sourcecmsgstr != "")
3138                                 centerprint(source, sourcecmsgstr);
3139                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3140                                 sprint(it, msgstr);
3141                                 if(cmsgstr != "")
3142                                         centerprint(it, cmsgstr);
3143                         });
3144                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3145                 }
3146                 else if(teamsay < 0) // spectator message, only sent to spectators
3147                 {
3148                         sprint(source, sourcemsgstr);
3149                         dedicated_print(msgstr); // send to server console too
3150                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3151                                 sprint(it, msgstr);
3152                         });
3153                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3154                 }
3155                 else
3156                 {
3157                         if (source) {
3158                                 sprint(source, sourcemsgstr);
3159                                 dedicated_print(msgstr); // send to server console too
3160                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3161                         }
3162                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3163                                 sprint(it, msgstr);
3164                         });
3165                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3166                 }
3167         }
3168
3169         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3170                 GameLogEcho(event_log_msg);
3171         }
3172
3173         return ret;
3174 }
3175
3176 // hack to copy the button fields from the client entity to the Client State
3177 void PM_UpdateButtons(entity this, entity store)
3178 {
3179         if(this.impulse)
3180                 store.impulse = this.impulse;
3181         this.impulse = 0;
3182
3183         bool typing = this.buttonchat || this.button12;
3184
3185         store.button0 = (typing) ? 0 : this.button0;
3186         //button1?!
3187         store.button2 = (typing) ? 0 : this.button2;
3188         store.button3 = (typing) ? 0 : this.button3;
3189         store.button4 = this.button4;
3190         store.button5 = (typing) ? 0 : this.button5;
3191         store.button6 = this.button6;
3192         store.button7 = this.button7;
3193         store.button8 = this.button8;
3194         store.button9 = this.button9;
3195         store.button10 = this.button10;
3196         store.button11 = this.button11;
3197         store.button12 = this.button12;
3198         store.button13 = this.button13;
3199         store.button14 = this.button14;
3200         store.button15 = this.button15;
3201         store.button16 = this.button16;
3202         store.buttonuse = this.buttonuse;
3203         store.buttonchat = this.buttonchat;
3204
3205         store.cursor_active = this.cursor_active;
3206         store.cursor_screen = this.cursor_screen;
3207         store.cursor_trace_start = this.cursor_trace_start;
3208         store.cursor_trace_endpos = this.cursor_trace_endpos;
3209         store.cursor_trace_ent = this.cursor_trace_ent;
3210
3211         store.ping = this.ping;
3212         store.ping_packetloss = this.ping_packetloss;
3213         store.ping_movementloss = this.ping_movementloss;
3214
3215         store.v_angle = this.v_angle;
3216         store.movement = this.movement;
3217 }
3218
3219 NET_HANDLE(fpsreport, bool)
3220 {
3221         int fps = ReadShort();
3222         PlayerScore_Set(sender, SP_FPS, fps);
3223         return true;
3224 }