qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include <common/effects/qc/globalsound.qh>
  36
  37 #include "../common/mapobjects/func/conveyor.qh"
  38 #include "../common/mapobjects/teleporters.qh"
  39 #include "../common/mapobjects/target/spawnpoint.qh"
  40
  41 #include "../common/vehicles/all.qh"
  42
  43 #include "weapons/hitplot.qh"
  44 #include "weapons/weaponsystem.qh"
  45
  46 #include "../common/net_notice.qh"
  47 #include "../common/net_linked.qh"
  48 #include "../common/physics/player.qh"
  49
  50 #include <common/vehicles/sv_vehicles.qh>
  51
  52 #include "../common/items/_mod.qh"
  53
  54 #include "../common/mutators/mutator/waypoints/all.qh"
  55 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  56 #include <common/gamemodes/_mod.qh>
  57
  58 #include "../common/mapobjects/subs.qh"
  59 #include "../common/mapobjects/triggers.qh"
  60 #include "../common/mapobjects/trigger/secret.qh"
  61
  62 #include "../common/minigames/sv_minigames.qh"
  63
  64 #include "../common/items/inventory.qh"
  65
  66 #include "../common/monsters/sv_monsters.qh"
  67
  68 #include "../lib/warpzone/server.qh"
  69
  70 #include <common/mutators/mutator/overkill/oknex.qh>
  71
  72 STATIC_METHOD(Client, Add, void(Client this, int _team))
  73 {
  74     ClientConnect(this);
  75     TRANSMUTE(Player, this);
  76     this.frame = 12; // 7
  77     this.team = _team;
  78     PutClientInServer(this);
  79 }
  80
  81 STATIC_METHOD(Client, Remove, void(Client this))
  82 {
  83     TRANSMUTE(Observer, this);
  84     PutClientInServer(this);
  85     ClientDisconnect(this);
  86 }
  87
  88 void send_CSQC_teamnagger() {
  89         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  90 }
  91
  92 int CountSpectators(entity player, entity to)
  93 {
  94         if(!player) { return 0; } // not sure how, but best to be safe
  95
  96         int spec_count = 0;
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 spec_count++;
 101         });
 102
 103         return spec_count;
 104 }
 105
 106 void WriteSpectators(entity player, entity to)
 107 {
 108         if(!player) { return; } // not sure how, but best to be safe
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 WriteByte(MSG_ENTITY, num_for_edict(it));
 113         });
 114 }
 115
 116 bool ClientData_Send(entity this, entity to, int sf)
 117 {
 118         assert(to == this.owner, return false);
 119
 120         entity e = to;
 121         if (IS_SPEC(e)) e = e.enemy;
 122
 123         sf = 0;
 124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 128
 129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 130         WriteByte(MSG_ENTITY, sf);
 131
 132         if (sf & BIT(1))
 133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 134
 135         if(sf & BIT(4))
 136         {
 137                 float specs = CountSpectators(e, to);
 138                 WriteByte(MSG_ENTITY, specs);
 139                 WriteSpectators(e, to);
 140         }
 141
 142         return true;
 143 }
 144
 145 void ClientData_Attach(entity this)
 146 {
 147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 148         CS(this).clientdata.drawonlytoclient = this;
 149         CS(this).clientdata.owner = this;
 150 }
 151
 152 void ClientData_Detach(entity this)
 153 {
 154         delete(CS(this).clientdata);
 155         CS(this).clientdata = NULL;
 156 }
 157
 158 void ClientData_Touch(entity e)
 159 {
 160         entity cd = CS(e).clientdata;
 161         if (cd) { cd.SendFlags = 1; }
 162
 163         // make it spectatable
 164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 165         {
 166                 entity cd = CS(it).clientdata;
 167                 if (cd) { cd.SendFlags = 1; }
 168         });
 169 }
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 /** putting a client as observer in the server */
 225 void PutObserverInServer(entity this)
 226 {
 227     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 228         PlayerState_detach(this);
 229
 230         if (IS_PLAYER(this))
 231         {
 232                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 233                 {
 234                         // despawn effect
 235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 236                 }
 237
 238                 // was a player, recount votes and ready status
 239                 if(IS_REAL_CLIENT(this))
 240                 {
 241                         if (vote_called) { VoteCount(false); }
 242                         ReadyCount();
 243                 }
 244     }
 245
 246     {
 247         entity spot = SelectSpawnPoint(this, true);
 248         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 249         this.angles = vec2(spot.angles);
 250         this.fixangle = true;
 251         // offset it so that the spectator spawns higher off the ground, looks better this way
 252         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 253         if (IS_REAL_CLIENT(this))
 254         {
 255             msg_entity = this;
 256             WriteByte(MSG_ONE, SVC_SETVIEW);
 257             WriteEntity(MSG_ONE, this);
 258         }
 259         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 260         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 261         if(!autocvar_g_debug_globalsounds)
 262         {
 263                 // needed for player sounds
 264                 this.model = "";
 265                 FixPlayermodel(this);
 266         }
 267         setmodel(this, MDL_Null);
 268         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 269         this.view_ofs = '0 0 0';
 270     }
 271
 272     RemoveGrapplingHooks(this);
 273         Portal_ClearAll(this);
 274         Unfreeze(this);
 275         SetSpectatee(this, NULL);
 276
 277         if (this.alivetime)
 278         {
 279                 if (!warmup_stage)
 280                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 281                 this.alivetime = 0;
 282         }
 283
 284         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 285
 286         WaypointSprite_PlayerDead(this);
 287
 288         if (mutator_returnvalue) {
 289             // mutator prevents resetting teams+score
 290         } else {
 291                 int oldteam = this.team;
 292                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 293                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 294         this.frags = FRAGS_SPECTATOR;
 295         PlayerScore_Clear(this);  // clear scores when needed
 296     }
 297
 298         if (CS(this).killcount != FRAGS_SPECTATOR)
 299         {
 300                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 301                 if(!game_stopped)
 302                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 303                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 304
 305                 if(!CS(this).just_joined)
 306                         LogTeamchange(this.playerid, -1, 4);
 307                 else
 308                         CS(this).just_joined = false;
 309         }
 310
 311         accuracy_resend(this);
 312
 313         CS(this).spectatortime = time;
 314         if(this.bot_attack)
 315                 IL_REMOVE(g_bot_targets, this);
 316         this.bot_attack = false;
 317         if(this.monster_attack)
 318                 IL_REMOVE(g_monster_targets, this);
 319         this.monster_attack = false;
 320     STAT(HUD, this) = HUD_NORMAL;
 321         TRANSMUTE(Observer, this);
 322         this.iscreature = false;
 323         this.teleportable = TELEPORT_SIMPLE;
 324         if(this.damagedbycontents)
 325                 IL_REMOVE(g_damagedbycontents, this);
 326         this.damagedbycontents = false;
 327         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 328         SetSpectatee_status(this, etof(this));
 329         this.takedamage = DAMAGE_NO;
 330         this.solid = SOLID_NOT;
 331         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 332         this.flags = FL_CLIENT | FL_NOTARGET;
 333         this.effects = 0;
 334         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 335         this.pauserotarmor_finished = 0;
 336         this.pauserothealth_finished = 0;
 337         this.pauseregen_finished = 0;
 338         this.damageforcescale = 0;
 339         this.death_time = 0;
 340         this.respawn_flags = 0;
 341         this.respawn_time = 0;
 342         STAT(RESPAWN_TIME, this) = 0;
 343         this.alpha = 0;
 344         this.scale = 0;
 345         this.fade_time = 0;
 346         this.pain_frame = 0;
 347         this.pain_finished = 0;
 348         this.strength_finished = 0;
 349         this.invincible_finished = 0;
 350         this.superweapons_finished = 0;
 351         this.dphitcontentsmask = 0;
 352         this.pushltime = 0;
 353         this.istypefrag = 0;
 354         setthink(this, func_null);
 355         this.nextthink = 0;
 356         this.deadflag = DEAD_NO;
 357         this.crouch = false;
 358         STAT(REVIVE_PROGRESS, this) = 0;
 359         this.revival_time = 0;
 360
 361         this.items = 0;
 362         STAT(WEAPONS, this) = '0 0 0';
 363         this.drawonlytoclient = this;
 364
 365         this.viewloc = NULL;
 366
 367         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 368
 369         this.weaponmodel = "";
 370         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 371         {
 372                 this.weaponentities[slot] = NULL;
 373         }
 374         this.exteriorweaponentity = NULL;
 375         CS(this).killcount = FRAGS_SPECTATOR;
 376         this.velocity = '0 0 0';
 377         this.avelocity = '0 0 0';
 378         this.punchangle = '0 0 0';
 379         this.punchvector = '0 0 0';
 380         this.oldvelocity = this.velocity;
 381         this.fire_endtime = -1;
 382         this.event_damage = func_null;
 383
 384         for(int slot = 0; slot < MAX_AXH; ++slot)
 385         {
 386                 entity axh = this.(AuxiliaryXhair[slot]);
 387                 this.(AuxiliaryXhair[slot]) = NULL;
 388
 389                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 390                         delete(axh);
 391         }
 392 }
 393
 394 int player_getspecies(entity this)
 395 {
 396         get_model_parameters(this.model, this.skin);
 397         int s = get_model_parameters_species;
 398         get_model_parameters(string_null, 0);
 399         if (s < 0) return SPECIES_HUMAN;
 400         return s;
 401 }
 402
 403 .float model_randomizer;
 404 void FixPlayermodel(entity player)
 405 {
 406         string defaultmodel = "";
 407         int defaultskin = 0;
 408         if(autocvar_sv_defaultcharacter)
 409         {
 410                 if(teamplay)
 411                 {
 412                         switch(player.team)
 413                         {
 414                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 415                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 416                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 417                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 418                         }
 419                 }
 420
 421                 if(defaultmodel == "")
 422                 {
 423                         defaultmodel = autocvar_sv_defaultplayermodel;
 424                         defaultskin = autocvar_sv_defaultplayerskin;
 425                 }
 426
 427                 int n = tokenize_console(defaultmodel);
 428                 if(n > 0)
 429                 {
 430                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 431                         // However, do NOT randomize if the player-selected model is in the list.
 432                         for (int i = 0; i < n; ++i)
 433                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 434                                         defaultmodel = argv(i);
 435                 }
 436
 437                 int i = strstrofs(defaultmodel, ":", 0);
 438                 if(i >= 0)
 439                 {
 440                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 441                         defaultmodel = substring(defaultmodel, 0, i);
 442                 }
 443         }
 444         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 445         {
 446                 if(teamplay)
 447                 {
 448                         switch(player.team)
 449                         {
 450                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 451                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 452                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 453                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 454                         }
 455                 }
 456
 457                 if(!defaultskin)
 458                         defaultskin = autocvar_sv_defaultplayerskin;
 459         }
 460
 461         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 462         defaultmodel = M_ARGV(0, string);
 463         defaultskin = M_ARGV(1, int);
 464
 465         bool chmdl = false;
 466         int oldskin;
 467         if(defaultmodel != "")
 468         {
 469                 if (defaultmodel != player.model)
 470                 {
 471                         vector m1 = player.mins;
 472                         vector m2 = player.maxs;
 473                         setplayermodel (player, defaultmodel);
 474                         setsize (player, m1, m2);
 475                         chmdl = true;
 476                 }
 477
 478                 oldskin = player.skin;
 479                 player.skin = defaultskin;
 480         } else {
 481                 if (player.playermodel != player.model || player.playermodel == "")
 482                 {
 483                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 484                         vector m1 = player.mins;
 485                         vector m2 = player.maxs;
 486                         setplayermodel (player, player.playermodel);
 487                         setsize (player, m1, m2);
 488                         chmdl = true;
 489                 }
 490
 491                 if(!autocvar_sv_defaultcharacterskin)
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = stof(player.playerskin);
 495                 }
 496                 else
 497                 {
 498                         oldskin = player.skin;
 499                         player.skin = defaultskin;
 500                 }
 501         }
 502
 503         if(chmdl || oldskin != player.skin) // model or skin has changed
 504         {
 505                 player.species = player_getspecies(player); // update species
 506                 if(!autocvar_g_debug_globalsounds)
 507                         UpdatePlayerSounds(player); // update skin sounds
 508         }
 509
 510         if(!teamplay)
 511                 if(strlen(autocvar_sv_defaultplayercolors))
 512                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 513                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 514 }
 515
 516 void PutPlayerInServer(entity this)
 517 {
 518         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 519
 520         PlayerState_attach(this);
 521         accuracy_resend(this);
 522
 523         if (this.team < 0)
 524                 JoinBestTeam(this, true);
 525
 526         entity spot = SelectSpawnPoint(this, false);
 527         if (!spot) {
 528                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 529                 return; // spawn failed
 530         }
 531
 532         TRANSMUTE(Player, this);
 533
 534         CS(this).wasplayer = true;
 535         this.iscreature = true;
 536         this.teleportable = TELEPORT_NORMAL;
 537         if(!this.damagedbycontents)
 538                 IL_PUSH(g_damagedbycontents, this);
 539         this.damagedbycontents = true;
 540         set_movetype(this, MOVETYPE_WALK);
 541         this.solid = SOLID_SLIDEBOX;
 542         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 543         if (autocvar_g_playerclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 545         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 546                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 547         this.frags = FRAGS_PLAYER;
 548         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 549         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 550         if (autocvar__notarget)
 551                 this.flags |= FL_NOTARGET;
 552         this.takedamage = DAMAGE_AIM;
 553         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 554
 555         if (warmup_stage) {
 556                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 557                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 558                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 559                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 560                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 561                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 562                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 563                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 564                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 565         } else {
 566                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 567                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 568                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 569                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 570                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 571                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 572                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 573                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 574                 STAT(WEAPONS, this) = start_weapons;
 575                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 576                 {
 577                         GiveRandomWeapons(this, random_start_weapons_count,
 578                                 autocvar_g_random_start_weapons, random_start_ammo);
 579                 }
 580         }
 581         SetSpectatee_status(this, 0);
 582
 583         PS(this).dual_weapons = '0 0 0';
 584
 585         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 586
 587         this.items = start_items;
 588
 589         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 590         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 591         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 592         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 593         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 594         if (!sv_ready_restart_after_countdown && time < game_starttime)
 595         {
 596                 float f = game_starttime - time;
 597                 this.spawnshieldtime += f;
 598                 this.pauserotarmor_finished += f;
 599                 this.pauserothealth_finished += f;
 600                 this.pauseregen_finished += f;
 601         }
 602
 603         this.damageforcescale = 2;
 604         this.death_time = 0;
 605         this.respawn_flags = 0;
 606         this.respawn_time = 0;
 607         STAT(RESPAWN_TIME, this) = 0;
 608         this.scale = autocvar_sv_player_scale;
 609         this.fade_time = 0;
 610         this.pain_frame = 0;
 611         this.pain_finished = 0;
 612         this.pushltime = 0;
 613         setthink(this, func_null); // players have no think function
 614         this.nextthink = 0;
 615         this.dmg_team = 0;
 616         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 617
 618         this.deadflag = DEAD_NO;
 619
 620         this.angles = spot.angles;
 621         this.angles_z = 0; // never spawn tilted even if the spot says to
 622         if (IS_BOT_CLIENT(this))
 623                 this.v_angle = this.angles;
 624         this.fixangle = true; // turn this way immediately
 625         this.oldvelocity = this.velocity = '0 0 0';
 626         this.avelocity = '0 0 0';
 627         this.punchangle = '0 0 0';
 628         this.punchvector = '0 0 0';
 629
 630         this.strength_finished = 0;
 631         this.invincible_finished = 0;
 632         this.fire_endtime = -1;
 633         STAT(REVIVE_PROGRESS, this) = 0;
 634         this.revival_time = 0;
 635
 636         this.air_finished = time + 12;
 637         this.waterlevel = WATERLEVEL_NONE;
 638         this.watertype = CONTENT_EMPTY;
 639
 640         entity spawnevent = new_pure(spawnevent);
 641         spawnevent.owner = this;
 642         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 643
 644         // Cut off any still running player sounds.
 645         stopsound(this, CH_PLAYER_SINGLE);
 646
 647         this.model = "";
 648         FixPlayermodel(this);
 649         this.drawonlytoclient = NULL;
 650
 651         this.viewloc = NULL;
 652
 653         for(int slot = 0; slot < MAX_AXH; ++slot)
 654         {
 655                 entity axh = this.(AuxiliaryXhair[slot]);
 656                 this.(AuxiliaryXhair[slot]) = NULL;
 657
 658                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 659                         delete(axh);
 660         }
 661
 662         this.spawnpoint_targ = NULL;
 663
 664         this.crouch = false;
 665         this.view_ofs = STAT(PL_VIEW_OFS, this);
 666         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 667         this.spawnorigin = spot.origin;
 668         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 669         // don't reset back to last position, even if new position is stuck in solid
 670         this.oldorigin = this.origin;
 671         if(this.conveyor)
 672                 IL_REMOVE(g_conveyed, this);
 673         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 674         STAT(HUD, this) = HUD_NORMAL;
 675
 676         this.event_damage = PlayerDamage;
 677
 678         if(!this.bot_attack)
 679                 IL_PUSH(g_bot_targets, this);
 680         this.bot_attack = true;
 681         if(!this.monster_attack)
 682                 IL_PUSH(g_monster_targets, this);
 683         this.monster_attack = true;
 684         navigation_dynamicgoal_init(this, false);
 685
 686         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 687
 688         // player was spectator
 689         if (CS(this).killcount == FRAGS_SPECTATOR) {
 690                 PlayerScore_Clear(this);
 691                 CS(this).killcount = 0;
 692                 CS(this).startplaytime = time;
 693         }
 694
 695         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 696         {
 697                 .entity weaponentity = weaponentities[slot];
 698                 entity oldwep = this.(weaponentity);
 699                 CL_SpawnWeaponentity(this, weaponentity);
 700                 if(oldwep && oldwep.owner == this)
 701                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 702         }
 703         this.alpha = default_player_alpha;
 704         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 705         this.exteriorweaponentity.alpha = default_weapon_alpha;
 706
 707         this.speedrunning = false;
 708
 709         target_voicescript_clear(this);
 710
 711         // reset fields the weapons may use
 712         FOREACH(Weapons, true, {
 713                 it.wr_resetplayer(it, this);
 714                         // reload all reloadable weapons
 715                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 716                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 717                         {
 718                                 .entity weaponentity = weaponentities[slot];
 719                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 720                         }
 721                 }
 722         });
 723
 724         {
 725                 string s = spot.target;
 726                 spot.target = string_null;
 727                 SUB_UseTargets(spot, this, NULL);
 728                 spot.target = s;
 729         }
 730
 731         Unfreeze(this);
 732
 733         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 734
 735         if (autocvar_spawn_debug)
 736         {
 737                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 738                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 739         }
 740
 741         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 742         {
 743                 .entity weaponentity = weaponentities[slot];
 744                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 745                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 746                 else
 747                         this.(weaponentity).m_switchweapon = WEP_Null;
 748                 this.(weaponentity).m_weapon = WEP_Null;
 749                 this.(weaponentity).weaponname = "";
 750                 this.(weaponentity).m_switchingweapon = WEP_Null;
 751                 this.(weaponentity).cnt = -1;
 752         }
 753
 754         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 755
 756         if (!warmup_stage && !this.alivetime)
 757                 this.alivetime = time;
 758
 759         antilag_clear(this, CS(this));
 760 }
 761
 762 /** Called when a client spawns in the server */
 763 void PutClientInServer(entity this)
 764 {
 765         if (IS_BOT_CLIENT(this)) {
 766                 TRANSMUTE(Player, this);
 767         } else if (IS_REAL_CLIENT(this)) {
 768                 msg_entity = this;
 769                 WriteByte(MSG_ONE, SVC_SETVIEW);
 770                 WriteEntity(MSG_ONE, this);
 771         }
 772         if (game_stopped)
 773                 TRANSMUTE(Observer, this);
 774
 775         SetSpectatee(this, NULL);
 776
 777         // reset player keys
 778         if(PS(this))
 779                 PS(this).itemkeys = 0;
 780
 781         MUTATOR_CALLHOOK(PutClientInServer, this);
 782
 783         if (IS_OBSERVER(this)) {
 784                 PutObserverInServer(this);
 785         } else if (IS_PLAYER(this)) {
 786                 PutPlayerInServer(this);
 787         }
 788 }
 789
 790 // TODO do we need all these fields, or should we stop autodetecting runtime
 791 // changes and just have a console command to update this?
 792 bool ClientInit_SendEntity(entity this, entity to, int sf)
 793 {
 794         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 795         return = true;
 796         msg_entity = to;
 797         // MSG_INIT replacement
 798         // TODO: make easier to use
 799         Registry_send_all();
 800         W_PROP_reload(MSG_ONE, to);
 801         ClientInit_misc(this);
 802         MUTATOR_CALLHOOK(Ent_Init);
 803 }
 804 void ClientInit_misc(entity this)
 805 {
 806         int channel = MSG_ONE;
 807         WriteHeader(channel, ENT_CLIENT_INIT);
 808         WriteByte(channel, g_nexball_meter_period * 32);
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 810         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 811         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 812         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 814         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 815         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 816         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 817
 818         if(sv_foginterval && world.fog != "")
 819                 WriteString(channel, world.fog);
 820         else
 821                 WriteString(channel, "");
 822         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 823         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 824         WriteByte(channel, serverflags);
 825         WriteCoord(channel, autocvar_g_trueaim_minrange);
 826 }
 827
 828 void ClientInit_CheckUpdate(entity this)
 829 {
 830         this.nextthink = time;
 831         if(this.count != autocvar_g_balance_armor_blockpercent)
 832         {
 833                 this.count = autocvar_g_balance_armor_blockpercent;
 834                 this.SendFlags |= 1;
 835         }
 836         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 837         {
 838                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 839                 this.SendFlags |= 1;
 840         }
 841 }
 842
 843 void ClientInit_Spawn()
 844 {
 845         entity e = new_pure(clientinit);
 846         setthink(e, ClientInit_CheckUpdate);
 847         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 848
 849         ClientInit_CheckUpdate(e);
 850 }
 851
 852 /*
 853 =============
 854 SetNewParms
 855 =============
 856 */
 857 void SetNewParms ()
 858 {
 859         // initialize parms for a new player
 860         parm1 = -(86400 * 366);
 861
 862         MUTATOR_CALLHOOK(SetNewParms);
 863 }
 864
 865 /*
 866 =============
 867 SetChangeParms
 868 =============
 869 */
 870 void SetChangeParms (entity this)
 871 {
 872         // save parms for level change
 873         parm1 = CS(this).parm_idlesince - time;
 874
 875         MUTATOR_CALLHOOK(SetChangeParms);
 876 }
 877
 878 /*
 879 =============
 880 DecodeLevelParms
 881 =============
 882 */
 883 void DecodeLevelParms(entity this)
 884 {
 885         // load parms
 886         CS(this).parm_idlesince = parm1;
 887         if (CS(this).parm_idlesince == -(86400 * 366))
 888                 CS(this).parm_idlesince = time;
 889
 890         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 891         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 892
 893         MUTATOR_CALLHOOK(DecodeLevelParms);
 894 }
 895
 896 /*
 897 =============
 898 ClientKill
 899
 900 Called when a client types 'kill' in the console
 901 =============
 902 */
 903
 904 .float clientkill_nexttime;
 905 void ClientKill_Now_TeamChange(entity this)
 906 {
 907         if(this.killindicator_teamchange == -1)
 908         {
 909                 JoinBestTeam( this, true );
 910         }
 911         else if(this.killindicator_teamchange == -2)
 912         {
 913                 if(blockSpectators)
 914                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 915                 PutObserverInServer(this);
 916         }
 917         else
 918                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 919         this.killindicator_teamchange = 0;
 920 }
 921
 922 void ClientKill_Now(entity this)
 923 {
 924         if(this.vehicle)
 925         {
 926             vehicles_exit(this.vehicle, VHEF_RELEASE);
 927             if(!this.killindicator_teamchange)
 928             {
 929             this.vehicle_health = -1;
 930             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 931             }
 932         }
 933
 934         if(this.killindicator && !wasfreed(this.killindicator))
 935                 delete(this.killindicator);
 936
 937         this.killindicator = NULL;
 938
 939         if(this.killindicator_teamchange)
 940                 ClientKill_Now_TeamChange(this);
 941
 942         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 943         {
 944                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 945         }
 946
 947         // now I am sure the player IS dead
 948 }
 949 void KillIndicator_Think(entity this)
 950 {
 951         if (game_stopped)
 952         {
 953                 this.owner.killindicator = NULL;
 954                 delete(this);
 955                 return;
 956         }
 957
 958         if (this.owner.alpha < 0 && !this.owner.vehicle)
 959         {
 960                 this.owner.killindicator = NULL;
 961                 delete(this);
 962                 return;
 963         }
 964
 965         if(this.cnt <= 0)
 966         {
 967                 ClientKill_Now(this.owner);
 968                 return;
 969         }
 970     else if(this.count == 1) // count == 1 means that it's silent
 971     {
 972         this.nextthink = time + 1;
 973         this.cnt -= 1;
 974     }
 975         else
 976         {
 977                 if(this.cnt <= 10)
 978                         setmodel(this, MDL_NUM(this.cnt));
 979                 if(IS_REAL_CLIENT(this.owner))
 980                 {
 981                         if(this.cnt <= 10)
 982                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 983                 }
 984                 this.nextthink = time + 1;
 985                 this.cnt -= 1;
 986         }
 987 }
 988
 989 float clientkilltime;
 990 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 991 {
 992         float killtime;
 993         float starttime;
 994
 995         if (game_stopped)
 996                 return;
 997
 998         killtime = autocvar_g_balance_kill_delay;
 999
1000     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1001         return;
1002     killtime = M_ARGV(1, float);
1003
1004         this.killindicator_teamchange = targetteam;
1005
1006     if(!this.killindicator)
1007         {
1008                 if(!IS_DEAD(this))
1009                 {
1010                         killtime = max(killtime, this.clientkill_nexttime - time);
1011                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1012                 }
1013
1014                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1015                 {
1016                         ClientKill_Now(this);
1017                 }
1018                 else
1019                 {
1020                         starttime = max(time, clientkilltime);
1021
1022                         this.killindicator = spawn();
1023                         this.killindicator.owner = this;
1024                         this.killindicator.scale = 0.5;
1025                         setattachment(this.killindicator, this, "");
1026                         setorigin(this.killindicator, '0 0 52');
1027                         setthink(this.killindicator, KillIndicator_Think);
1028                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1029                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1030                         this.killindicator.cnt = ceil(killtime);
1031                         this.killindicator.count = bound(0, ceil(killtime), 10);
1032                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1033
1034                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1035                         {
1036                                 it.killindicator = spawn();
1037                                 it.killindicator.owner = it;
1038                                 it.killindicator.scale = 0.5;
1039                                 setattachment(it.killindicator, it, "");
1040                                 setorigin(it.killindicator, '0 0 52');
1041                                 setthink(it.killindicator, KillIndicator_Think);
1042                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1043                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1044                                 it.killindicator.cnt = ceil(killtime);
1045                         });
1046                         this.lip = 0;
1047                 }
1048         }
1049         if(this.killindicator)
1050         {
1051                 if(targetteam == 0) // just die
1052                 {
1053                         this.killindicator.colormod = '0 0 0';
1054                         if(IS_REAL_CLIENT(this))
1055                         if(this.killindicator.cnt > 0)
1056                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1057                 }
1058                 else if(targetteam == -1) // auto
1059                 {
1060                         this.killindicator.colormod = '0 1 0';
1061                         if(IS_REAL_CLIENT(this))
1062                         if(this.killindicator.cnt > 0)
1063                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1064                 }
1065                 else if(targetteam == -2) // spectate
1066                 {
1067                         this.killindicator.colormod = '0.5 0.5 0.5';
1068                         if(IS_REAL_CLIENT(this))
1069                         if(this.killindicator.cnt > 0)
1070                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1071                 }
1072                 else
1073                 {
1074                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1075                         if(IS_REAL_CLIENT(this))
1076                         if(this.killindicator.cnt > 0)
1077                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1078                 }
1079         }
1080
1081 }
1082
1083 void ClientKill (entity this)
1084 {
1085         if(game_stopped) return;
1086         if(this.player_blocked) return;
1087         if(STAT(FROZEN, this)) return;
1088
1089         ClientKill_TeamChange(this, 0);
1090 }
1091
1092 void FixClientCvars(entity e)
1093 {
1094         // send prediction settings to the client
1095         stuffcmd(e, "\nin_bindmap 0 0\n");
1096         if(autocvar_g_antilag == 3) // client side hitscan
1097                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1098         if(autocvar_sv_gentle)
1099                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1100
1101         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1102         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1103
1104         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1105
1106         MUTATOR_CALLHOOK(FixClientCvars, e);
1107 }
1108
1109 bool findinlist_abbrev(string tofind, string list)
1110 {
1111         if(list == "" || tofind == "")
1112                 return false; // empty list or search, just return
1113
1114         // this function allows abbreviated strings!
1115         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1116         {
1117                 return true;
1118         });
1119
1120         return false;
1121 }
1122
1123 bool PlayerInIPList(entity p, string iplist)
1124 {
1125         // some safety checks (never allow local?)
1126         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1127                 return false;
1128
1129         return findinlist_abbrev(p.netaddress, iplist);
1130 }
1131
1132 bool PlayerInIDList(entity p, string idlist)
1133 {
1134         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1135         if(!p.crypto_idfp)
1136                 return false;
1137
1138         return findinlist_abbrev(p.crypto_idfp, idlist);
1139 }
1140
1141 bool PlayerInList(entity player, string list)
1142 {
1143         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1144 }
1145
1146 #ifdef DP_EXT_PRECONNECT
1147 /*
1148 =============
1149 ClientPreConnect
1150
1151 Called once (not at each match start) when a client begins a connection to the server
1152 =============
1153 */
1154 void ClientPreConnect(entity this)
1155 {
1156         if(autocvar_sv_eventlog)
1157         {
1158                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1159                         this.playerid,
1160                         etof(this),
1161                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1162                 ));
1163         }
1164 }
1165 #endif
1166
1167 /**
1168 =============
1169 ClientConnect
1170
1171 Called when a client connects to the server
1172 =============
1173 */
1174 void ClientConnect(entity this)
1175 {
1176         if (Ban_MaybeEnforceBanOnce(this)) return;
1177         assert(!IS_CLIENT(this), return);
1178         this.flags |= FL_CLIENT;
1179         assert(player_count >= 0, player_count = 0);
1180
1181 #ifdef WATERMARK
1182         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1183 #endif
1184         TRANSMUTE(Client, this);
1185         CS(this).version_nagtime = time + 10 + random() * 10;
1186
1187         // identify the right forced team
1188         if (autocvar_g_campaign)
1189         {
1190                 if (IS_REAL_CLIENT(this)) // only players, not bots
1191                 {
1192                         switch (autocvar_g_campaign_forceteam)
1193                         {
1194                                 case 1: this.team_forced = NUM_TEAM_1; break;
1195                                 case 2: this.team_forced = NUM_TEAM_2; break;
1196                                 case 3: this.team_forced = NUM_TEAM_3; break;
1197                                 case 4: this.team_forced = NUM_TEAM_4; break;
1198                                 default: this.team_forced = 0;
1199                         }
1200                 }
1201         }
1202         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1203         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1204         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1205         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1206         else switch (autocvar_g_forced_team_otherwise)
1207         {
1208                 default: this.team_forced = 0; break;
1209                 case "red": this.team_forced = NUM_TEAM_1; break;
1210                 case "blue": this.team_forced = NUM_TEAM_2; break;
1211                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1212                 case "pink": this.team_forced = NUM_TEAM_4; break;
1213                 case "spectate":
1214                 case "spectator":
1215                         this.team_forced = -1;
1216                         break;
1217         }
1218         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1219
1220         int playerid_save = this.playerid;
1221         this.playerid = 0; // silent
1222         JoinBestTeam(this, false); // if the team number is valid, keep it
1223         this.playerid = playerid_save;
1224
1225         TRANSMUTE(Observer, this);
1226
1227         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1228
1229         // always track bots, don't ask for cl_allow_uidtracking
1230         if (IS_BOT_CLIENT(this))
1231                 PlayerStats_GameReport_AddPlayer(this);
1232         else
1233                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1234
1235         if (autocvar_sv_eventlog)
1236                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1237
1238         LogTeamchange(this.playerid, this.team, 1);
1239
1240         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1241
1242         if(teamplay && IS_PLAYER(this))
1243                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1244         else
1245                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1246
1247         stuffcmd(this, clientstuff, "\n");
1248         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1249
1250         FixClientCvars(this);
1251
1252         // get version info from player
1253         stuffcmd(this, "cmd clientversion $gameversion\n");
1254
1255         // notify about available teams
1256         if (teamplay)
1257         {
1258                 CheckAllowedTeams(this);
1259                 int t = 0;
1260                 if (c1 >= 0) t |= BIT(0);
1261                 if (c2 >= 0) t |= BIT(1);
1262                 if (c3 >= 0) t |= BIT(2);
1263                 if (c4 >= 0) t |= BIT(3);
1264                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1265         }
1266         else
1267         {
1268                 stuffcmd(this, "set _teams_available 0\n");
1269         }
1270
1271         bot_relinkplayerlist();
1272
1273         CS(this).spectatortime = time;
1274         if (blockSpectators)
1275         {
1276                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1277         }
1278
1279         CS(this).jointime = time;
1280
1281         if (IS_REAL_CLIENT(this))
1282         {
1283                 if (g_weaponarena_weapons == WEPSET(TUBA))
1284                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1285         }
1286
1287         if (!sv_foginterval && world.fog != "")
1288                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1289
1290         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1291                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1292                         send_CSQC_teamnagger();
1293
1294         CSQCMODEL_AUTOINIT(this);
1295
1296         CS(this).model_randomizer = random();
1297
1298         if (IS_REAL_CLIENT(this))
1299                 sv_notice_join(this);
1300
1301         // update physics stats (players can spawn before physics runs)
1302         Physics_UpdateStats(this);
1303
1304         IL_EACH(g_initforplayer, it.init_for_player, {
1305                 it.init_for_player(it, this);
1306         });
1307
1308         Handicap_Initialize(this);
1309
1310         MUTATOR_CALLHOOK(ClientConnect, this);
1311
1312         if (IS_REAL_CLIENT(this))
1313         {
1314                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1315                 {
1316                         CS(this).motd_actived_time = -1;
1317                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1318                 }
1319         }
1320 }
1321 /*
1322 =============
1323 ClientDisconnect
1324
1325 Called when a client disconnects from the server
1326 =============
1327 */
1328 .entity chatbubbleentity;
1329 void ClientDisconnect(entity this)
1330 {
1331         assert(IS_CLIENT(this), return);
1332
1333         PlayerStats_GameReport_FinalizePlayer(this);
1334         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1335         if (CS(this).active_minigame) part_minigame(this);
1336         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1337
1338         if (autocvar_sv_eventlog)
1339                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1340
1341         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1342
1343         if(IS_SPEC(this))
1344                 SetSpectatee(this, NULL);
1345
1346     MUTATOR_CALLHOOK(ClientDisconnect, this);
1347
1348         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1349         strfree(CS(this).weaponorder_byimpulse);
1350         ClientState_detach(this);
1351
1352         Portal_ClearAll(this);
1353
1354         Unfreeze(this);
1355
1356         RemoveGrapplingHooks(this);
1357
1358         // Here, everything has been done that requires this player to be a client.
1359
1360         this.flags &= ~FL_CLIENT;
1361
1362         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1363         if (this.killindicator) delete(this.killindicator);
1364
1365         WaypointSprite_PlayerGone(this);
1366
1367         bot_relinkplayerlist();
1368
1369         strfree(this.clientstatus);
1370         if (this.personal) delete(this.personal);
1371
1372         this.playerid = 0;
1373         ReadyCount();
1374         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1375
1376         ONREMOVE(this);
1377 }
1378
1379 void ChatBubbleThink(entity this)
1380 {
1381         this.nextthink = time;
1382         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1383         {
1384                 if(this.owner) // but why can that ever be NULL?
1385                         this.owner.chatbubbleentity = NULL;
1386                 delete(this);
1387                 return;
1388         }
1389
1390         this.mdl = "";
1391
1392         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1393         {
1394                 if ( CS(this.owner).active_minigame )
1395                         this.mdl = "models/sprites/minigame_busy.iqm";
1396                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1397                         this.mdl = "models/misc/chatbubble.spr";
1398         }
1399
1400         if ( this.model != this.mdl )
1401                 _setmodel(this, this.mdl);
1402
1403 }
1404
1405 void UpdateChatBubble(entity this)
1406 {
1407         if (this.alpha < 0)
1408                 return;
1409         // spawn a chatbubble entity if needed
1410         if (!this.chatbubbleentity)
1411         {
1412                 this.chatbubbleentity = new(chatbubbleentity);
1413                 this.chatbubbleentity.owner = this;
1414                 this.chatbubbleentity.exteriormodeltoclient = this;
1415                 setthink(this.chatbubbleentity, ChatBubbleThink);
1416                 this.chatbubbleentity.nextthink = time;
1417                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1418                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1419                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1420                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1421                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1422                 //this.chatbubbleentity.model = "";
1423                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1424         }
1425 }
1426
1427
1428 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1429 // added to the model skins
1430 /*void UpdateColorModHack()
1431 {
1432         float c;
1433         c = this.clientcolors & 15;
1434         // LordHavoc: only bothering to support white, green, red, yellow, blue
1435              if (!teamplay) this.colormod = '0 0 0';
1436         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1437         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1438         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1439         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1440         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1441         else this.colormod = '1 1 1';
1442 }*/
1443
1444 void respawn(entity this)
1445 {
1446         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1447         {
1448                 this.solid = SOLID_NOT;
1449                 this.takedamage = DAMAGE_NO;
1450                 set_movetype(this, MOVETYPE_FLY);
1451                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1452                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1453                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1454                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1455                 if(autocvar_g_respawn_ghosts_maxtime)
1456                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1457         }
1458
1459         CopyBody(this, 1);
1460
1461         this.effects |= EF_NODRAW; // prevent another CopyBody
1462         PutClientInServer(this);
1463 }
1464
1465 void PrintToChat(entity client, string text)
1466 {
1467         text = strcat("\{1}^7", text, "\n");
1468         sprint(client, text);
1469 }
1470
1471 void DebugPrintToChat(entity client, string text)
1472 {
1473         if (autocvar_developer)
1474         {
1475                 PrintToChat(client, text);
1476         }
1477 }
1478
1479 void PrintToChatAll(string text)
1480 {
1481         text = strcat("\{1}^7", text, "\n");
1482         bprint(text);
1483 }
1484
1485 void DebugPrintToChatAll(string text)
1486 {
1487         if (autocvar_developer)
1488         {
1489                 PrintToChatAll(text);
1490         }
1491 }
1492
1493 void PrintToChatTeam(int team_num, string text)
1494 {
1495         text = strcat("\{1}^7", text, "\n");
1496         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1497         {
1498                 if (it.team == team_num)
1499                 {
1500                         sprint(it, text);
1501                 }
1502         });
1503 }
1504
1505 void DebugPrintToChatTeam(int team_num, string text)
1506 {
1507         if (autocvar_developer)
1508         {
1509                 PrintToChatTeam(team_num, text);
1510         }
1511 }
1512
1513 void play_countdown(entity this, float finished, Sound samp)
1514 {
1515     TC(Sound, samp);
1516         if(IS_REAL_CLIENT(this))
1517                 if(floor(finished - time - frametime) != floor(finished - time))
1518                         if(finished - time < 6)
1519                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1520 }
1521
1522 void player_powerups(entity this)
1523 {
1524         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1525         int items_prev = this.items;
1526
1527         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1528                 this.modelflags |= MF_ROCKET;
1529         else
1530                 this.modelflags &= ~MF_ROCKET;
1531
1532         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1533
1534         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1535                 return;
1536
1537         Fire_ApplyDamage(this);
1538         Fire_ApplyEffect(this);
1539
1540         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1541         {
1542                 if (this.items & ITEM_Strength.m_itemid)
1543                 {
1544                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1545                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1546                         if (time > this.strength_finished)
1547                         {
1548                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1549                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1550                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1551                         }
1552                 }
1553                 else
1554                 {
1555                         if (time < this.strength_finished)
1556                         {
1557                                 this.items = this.items | ITEM_Strength.m_itemid;
1558                                 if(!g_cts)
1559                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1560                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1561                         }
1562                 }
1563                 if (this.items & ITEM_Shield.m_itemid)
1564                 {
1565                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1566                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1567                         if (time > this.invincible_finished)
1568                         {
1569                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1570                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1571                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1572                         }
1573                 }
1574                 else
1575                 {
1576                         if (time < this.invincible_finished)
1577                         {
1578                                 this.items = this.items | ITEM_Shield.m_itemid;
1579                                 if(!g_cts)
1580                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1581                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1582                         }
1583                 }
1584                 if (this.items & IT_SUPERWEAPON)
1585                 {
1586                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1587                         {
1588                                 this.superweapons_finished = 0;
1589                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1590                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1591                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1592                         }
1593                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1594                         {
1595                                 // don't let them run out
1596                         }
1597                         else
1598                         {
1599                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1600                                 if (time > this.superweapons_finished)
1601                                 {
1602                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1603                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1604                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1605                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1606                                 }
1607                         }
1608                 }
1609                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1610                 {
1611                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1612                         {
1613                                 this.items = this.items | IT_SUPERWEAPON;
1614                                 if(!g_cts)
1615                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1616                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1617                         }
1618                         else
1619                         {
1620                                 this.superweapons_finished = 0;
1621                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1622                         }
1623                 }
1624                 else
1625                 {
1626                         this.superweapons_finished = 0;
1627                 }
1628         }
1629
1630         if(autocvar_g_nodepthtestplayers)
1631                 this.effects = this.effects | EF_NODEPTHTEST;
1632
1633         if(autocvar_g_fullbrightplayers)
1634                 this.effects = this.effects | EF_FULLBRIGHT;
1635
1636         if (time >= game_starttime)
1637         if (time < this.spawnshieldtime)
1638                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1639
1640         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1641 }
1642
1643 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1644 {
1645         if(current > stable)
1646                 return current;
1647         else if(current > stable - 0.25) // when close enough, "snap"
1648                 return stable;
1649         else
1650                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1651 }
1652
1653 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1654 {
1655         if(current < stable)
1656                 return current;
1657         else if(current < stable + 0.25) // when close enough, "snap"
1658                 return stable;
1659         else
1660                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1661 }
1662
1663 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1664 {
1665         if(current > rotstable)
1666         {
1667                 if(rotframetime > 0)
1668                 {
1669                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1670                         current = max(rotstable, current - rotlinear * rotframetime);
1671                 }
1672         }
1673         else if(current < regenstable)
1674         {
1675                 if(regenframetime > 0)
1676                 {
1677                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1678                         current = min(regenstable, current + regenlinear * regenframetime);
1679                 }
1680         }
1681
1682         if(current > limit)
1683                 current = limit;
1684
1685         return current;
1686 }
1687
1688 void player_regen(entity this)
1689 {
1690         float max_mod, regen_mod, rot_mod, limit_mod;
1691         max_mod = regen_mod = rot_mod = limit_mod = 1;
1692
1693         float regen_health = autocvar_g_balance_health_regen;
1694         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1695         float regen_health_rot = autocvar_g_balance_health_rot;
1696         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1697         float regen_health_stable = autocvar_g_balance_health_regenstable;
1698         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1699         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1700                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1701         max_mod = M_ARGV(1, float);
1702         regen_mod = M_ARGV(2, float);
1703         rot_mod = M_ARGV(3, float);
1704         limit_mod = M_ARGV(4, float);
1705         regen_health = M_ARGV(5, float);
1706         regen_health_linear = M_ARGV(6, float);
1707         regen_health_rot = M_ARGV(7, float);
1708         regen_health_rotlinear = M_ARGV(8, float);
1709         regen_health_stable = M_ARGV(9, float);
1710         regen_health_rotstable = M_ARGV(10, float);
1711
1712         if(!mutator_returnvalue)
1713         if(!STAT(FROZEN, this))
1714         {
1715                 float mina, maxa, limith, limita;
1716                 maxa = autocvar_g_balance_armor_rotstable;
1717                 mina = autocvar_g_balance_armor_regenstable;
1718                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1719                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1720
1721                 regen_health_rotstable = regen_health_rotstable * max_mod;
1722                 regen_health_stable = regen_health_stable * max_mod;
1723                 limith = limith * limit_mod;
1724                 limita = limita * limit_mod;
1725
1726                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1727                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1728                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1729                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1730                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1731                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1732         }
1733
1734         // if player rotted to death...  die!
1735         // check this outside above checks, as player may still be able to rot to death
1736         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1737         {
1738                 if(this.vehicle)
1739                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1740                 if(this.event_damage)
1741                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1742         }
1743
1744         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1745         {
1746                 float minf, maxf, limitf;
1747
1748                 maxf = autocvar_g_balance_fuel_rotstable;
1749                 minf = autocvar_g_balance_fuel_regenstable;
1750                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1751
1752                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1753                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1754                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1755         }
1756 }
1757
1758 bool zoomstate_set;
1759 void SetZoomState(entity this, float newzoom)
1760 {
1761         if(newzoom != CS(this).zoomstate)
1762         {
1763                 CS(this).zoomstate = newzoom;
1764                 ClientData_Touch(this);
1765         }
1766         zoomstate_set = true;
1767 }
1768
1769 void GetPressedKeys(entity this)
1770 {
1771         MUTATOR_CALLHOOK(GetPressedKeys, this);
1772         int keys = STAT(PRESSED_KEYS, this);
1773         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1774         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1775         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1776         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1777
1778         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1779         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1780         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1781         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1782         CS(this).pressedkeys = keys; // store for other users
1783
1784         STAT(PRESSED_KEYS, this) = keys;
1785 }
1786
1787 /*
1788 ======================
1789 spectate mode routines
1790 ======================
1791 */
1792
1793 void SpectateCopy(entity this, entity spectatee)
1794 {
1795     TC(Client, this); TC(Client, spectatee);
1796
1797         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1798         PS(this) = PS(spectatee);
1799         this.armortype = spectatee.armortype;
1800         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1801         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1802         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1803         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1804         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1805         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1806         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1807         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1808         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1809         CS(this).impulse = 0;
1810         this.items = spectatee.items;
1811         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1812         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1813         this.strength_finished = spectatee.strength_finished;
1814         this.invincible_finished = spectatee.invincible_finished;
1815         this.superweapons_finished = spectatee.superweapons_finished;
1816         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1817         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1818         this.punchangle = spectatee.punchangle;
1819         this.view_ofs = spectatee.view_ofs;
1820         this.velocity = spectatee.velocity;
1821         this.dmg_take = spectatee.dmg_take;
1822         this.dmg_save = spectatee.dmg_save;
1823         this.dmg_inflictor = spectatee.dmg_inflictor;
1824         this.v_angle = spectatee.v_angle;
1825         this.angles = spectatee.v_angle;
1826         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1827         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1828         this.viewloc = spectatee.viewloc;
1829         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1830                 this.fixangle = true;
1831         setorigin(this, spectatee.origin);
1832         setsize(this, spectatee.mins, spectatee.maxs);
1833         SetZoomState(this, CS(spectatee).zoomstate);
1834
1835     anticheat_spectatecopy(this, spectatee);
1836         STAT(HUD, this) = STAT(HUD, spectatee);
1837         if(spectatee.vehicle)
1838     {
1839         this.angles = spectatee.v_angle;
1840
1841         //this.fixangle = false;
1842         //this.velocity = spectatee.vehicle.velocity;
1843         this.vehicle_health = spectatee.vehicle_health;
1844         this.vehicle_shield = spectatee.vehicle_shield;
1845         this.vehicle_energy = spectatee.vehicle_energy;
1846         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1847         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1848         this.vehicle_reload1 = spectatee.vehicle_reload1;
1849         this.vehicle_reload2 = spectatee.vehicle_reload2;
1850
1851         //msg_entity = this;
1852
1853        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1854             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1855            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1856            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1857
1858         //WriteByte (MSG_ONE, SVC_SETVIEW);
1859         //    WriteEntity(MSG_ONE, this);
1860         //makevectors(spectatee.v_angle);
1861         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1862     }
1863 }
1864
1865 bool SpectateUpdate(entity this)
1866 {
1867         if(!this.enemy)
1868                 return false;
1869
1870         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1871         {
1872                 SetSpectatee(this, NULL);
1873                 return false;
1874         }
1875
1876         SpectateCopy(this, this.enemy);
1877
1878         return true;
1879 }
1880
1881 bool SpectateSet(entity this)
1882 {
1883         if(!IS_PLAYER(this.enemy))
1884                 return false;
1885
1886         ClientData_Touch(this.enemy);
1887
1888         msg_entity = this;
1889         WriteByte(MSG_ONE, SVC_SETVIEW);
1890         WriteEntity(MSG_ONE, this.enemy);
1891         set_movetype(this, MOVETYPE_NONE);
1892         accuracy_resend(this);
1893
1894         if(!SpectateUpdate(this))
1895                 PutObserverInServer(this);
1896
1897         return true;
1898 }
1899
1900 void SetSpectatee_status(entity this, int spectatee_num)
1901 {
1902         int oldspectatee_status = CS(this).spectatee_status;
1903         CS(this).spectatee_status = spectatee_num;
1904
1905         if (CS(this).spectatee_status != oldspectatee_status)
1906         {
1907                 ClientData_Touch(this);
1908                 if (g_race || g_cts) race_InitSpectator();
1909         }
1910 }
1911
1912 void SetSpectatee(entity this, entity spectatee)
1913 {
1914         if(IS_BOT_CLIENT(this))
1915                 return; // bots abuse .enemy, this code is useless to them
1916
1917         entity old_spectatee = this.enemy;
1918
1919         this.enemy = spectatee;
1920
1921         // WEAPONTODO
1922         // these are required to fix the spectator bug with arc
1923         if(old_spectatee)
1924         {
1925                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1926                 {
1927                         .entity weaponentity = weaponentities[slot];
1928                         if(old_spectatee.(weaponentity).arc_beam)
1929                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1930                 }
1931         }
1932         if(this.enemy)
1933         {
1934                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1935                 {
1936                         .entity weaponentity = weaponentities[slot];
1937                         if(this.enemy.(weaponentity).arc_beam)
1938                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1939                 }
1940         }
1941
1942         if (this.enemy)
1943                 SetSpectatee_status(this, etof(this.enemy));
1944
1945         // needed to update spectator list
1946         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1947 }
1948
1949 bool Spectate(entity this, entity pl)
1950 {
1951         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1952                 return false;
1953         pl = M_ARGV(1, entity);
1954
1955         SetSpectatee(this, pl);
1956         return SpectateSet(this);
1957 }
1958
1959 bool SpectateNext(entity this)
1960 {
1961         entity ent = find(this.enemy, classname, STR_PLAYER);
1962
1963         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1964                 ent = M_ARGV(1, entity);
1965         else if (!ent)
1966                 ent = find(ent, classname, STR_PLAYER);
1967
1968         if(ent) { SetSpectatee(this, ent); }
1969
1970         return SpectateSet(this);
1971 }
1972
1973 bool SpectatePrev(entity this)
1974 {
1975         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1976         entity ent = findchain(classname, STR_PLAYER);
1977         if (!ent) // no player
1978                 return false;
1979
1980         entity first = ent;
1981         // skip players until current spectated player
1982         if(this.enemy)
1983         while(ent && ent != this.enemy)
1984                 ent = ent.chain;
1985
1986         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1987         {
1988                 case MUT_SPECPREV_FOUND:
1989                     ent = M_ARGV(1, entity);
1990                     break;
1991                 case MUT_SPECPREV_RETURN:
1992                     return true;
1993                 case MUT_SPECPREV_CONTINUE:
1994                 default:
1995                 {
1996                         if(ent.chain)
1997                                 ent = ent.chain;
1998                         else
1999                                 ent = first;
2000                         break;
2001                 }
2002         }
2003
2004         SetSpectatee(this, ent);
2005         return SpectateSet(this);
2006 }
2007
2008 /*
2009 =============
2010 ShowRespawnCountdown()
2011
2012 Update a respawn countdown display.
2013 =============
2014 */
2015 void ShowRespawnCountdown(entity this)
2016 {
2017         float number;
2018         if(!IS_DEAD(this)) // just respawned?
2019                 return;
2020         else
2021         {
2022                 number = ceil(this.respawn_time - time);
2023                 if(number <= 0)
2024                         return;
2025                 if(number <= this.respawn_countdown)
2026                 {
2027                         this.respawn_countdown = number - 1;
2028                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2029                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2030                 }
2031         }
2032 }
2033
2034 .bool team_selected;
2035 bool ShowTeamSelection(entity this)
2036 {
2037         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2038                 return false;
2039         stuffcmd(this, "menu_showteamselect\n");
2040         return true;
2041 }
2042 void Join(entity this)
2043 {
2044         TRANSMUTE(Player, this);
2045
2046         if(!this.team_selected)
2047         if(autocvar_g_campaign || autocvar_g_balance_teams)
2048                 JoinBestTeam(this, true);
2049
2050         if(autocvar_g_campaign)
2051                 campaign_bots_may_start = true;
2052
2053         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2054
2055         PutClientInServer(this);
2056
2057         if(IS_PLAYER(this))
2058         if(teamplay && this.team != -1)
2059                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2060         else
2061                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2062         this.team_selected = false;
2063 }
2064
2065 /**
2066  * Determines whether the player is allowed to join. This depends on cvar
2067  * g_maxplayers, if it isn't used this function always return true, otherwise
2068  * it checks whether the number of currently playing players exceeds g_maxplayers.
2069  * @return int number of free slots for players, 0 if none
2070  */
2071 int nJoinAllowed(entity this, entity ignore)
2072 {
2073         if(!ignore)
2074         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2075         // so report 0 free slots if restricted
2076         {
2077                 if(autocvar_g_forced_team_otherwise == "spectate")
2078                         return 0;
2079                 if(autocvar_g_forced_team_otherwise == "spectator")
2080                         return 0;
2081         }
2082
2083         if(this && this.team_forced < 0)
2084                 return 0; // forced spectators can never join
2085
2086         // TODO simplify this
2087         int totalClients = 0;
2088         int currentlyPlaying = 0;
2089         FOREACH_CLIENT(true, {
2090                 if(it != ignore)
2091                         ++totalClients;
2092                 if(IS_REAL_CLIENT(it))
2093                 if(IS_PLAYER(it) || it.caplayer)
2094                         ++currentlyPlaying;
2095         });
2096
2097         float free_slots = 0;
2098         if (!autocvar_g_maxplayers)
2099                 free_slots = maxclients - totalClients;
2100         else if(currentlyPlaying < autocvar_g_maxplayers)
2101                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2102
2103         static float join_prevent_msg_time = 0;
2104         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2105         {
2106                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2107                 join_prevent_msg_time = time + 3;
2108         }
2109
2110         return free_slots;
2111 }
2112
2113 /**
2114  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2115  * g_maxplayers_spectator_blocktime seconds
2116  */
2117 void checkSpectatorBlock(entity this)
2118 {
2119         if(IS_SPEC(this) || IS_OBSERVER(this))
2120         if(!this.caplayer)
2121         if(IS_REAL_CLIENT(this))
2122         {
2123                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2124                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2125                         dropclient(this);
2126                 }
2127         }
2128 }
2129
2130 void PrintWelcomeMessage(entity this)
2131 {
2132         if(CS(this).motd_actived_time == 0)
2133         {
2134                 if (autocvar_g_campaign) {
2135                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2136                                 CS(this).motd_actived_time = time;
2137                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2138                         }
2139                 } else {
2140                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2141                                 CS(this).motd_actived_time = time;
2142                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2143                         }
2144                 }
2145         }
2146         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2147         {
2148                 if (autocvar_g_campaign) {
2149                         if (PHYS_INPUT_BUTTON_INFO(this))
2150                                 CS(this).motd_actived_time = time;
2151                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2152                                 CS(this).motd_actived_time = 0;
2153                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2154                         }
2155                 } else {
2156                         if (PHYS_INPUT_BUTTON_INFO(this))
2157                                 CS(this).motd_actived_time = time;
2158                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2159                                 CS(this).motd_actived_time = 0;
2160                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2161                         }
2162                 }
2163         }
2164         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2165         {
2166                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2167                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2168                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2169                 {
2170                         // instanctly hide MOTD
2171                         CS(this).motd_actived_time = 0;
2172                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2173                 }
2174         }
2175 }
2176
2177 const int MIN_SPEC_TIME = 1;
2178 bool joinAllowed(entity this)
2179 {
2180         if (CS(this).version_mismatch) return false;
2181         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2182         if (!nJoinAllowed(this, this)) return false;
2183         if (teamplay && lockteams) return false;
2184         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2185         if (ShowTeamSelection(this)) return false;
2186         return true;
2187 }
2188
2189 .int items_added;
2190 .string shootfromfixedorigin;
2191 bool PlayerThink(entity this)
2192 {
2193         if (game_stopped || intermission_running) {
2194                 this.modelflags &= ~MF_ROCKET;
2195                 if(intermission_running)
2196                         IntermissionThink(this);
2197                 return false;
2198         }
2199
2200         if (timeout_status == TIMEOUT_ACTIVE) {
2201         // don't allow the player to turn around while game is paused
2202                 // FIXME turn this into CSQC stuff
2203                 this.v_angle = this.lastV_angle;
2204                 this.angles = this.lastV_angle;
2205                 this.fixangle = true;
2206         }
2207
2208         if (frametime) player_powerups(this);
2209
2210         if (IS_DEAD(this)) {
2211                 if (this.personal && g_race_qualifying) {
2212                         if (time > this.respawn_time) {
2213                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2214                                 respawn(this);
2215                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2216                         }
2217                 } else {
2218                         if (frametime) player_anim(this);
2219
2220                         if (this.respawn_flags & RESPAWN_DENY)
2221                         {
2222                                 STAT(RESPAWN_TIME, this) = 0;
2223                                 return false;
2224                         }
2225
2226                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2227
2228                         switch(this.deadflag)
2229                         {
2230                                 case DEAD_DYING:
2231                                 {
2232                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2233                                                 this.deadflag = DEAD_RESPAWNING;
2234                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2235                                                 this.deadflag = DEAD_DEAD;
2236                                         break;
2237                                 }
2238                                 case DEAD_DEAD:
2239                                 {
2240                                         if (button_pressed)
2241                                                 this.deadflag = DEAD_RESPAWNABLE;
2242                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2243                                                 this.deadflag = DEAD_RESPAWNING;
2244                                         break;
2245                                 }
2246                                 case DEAD_RESPAWNABLE:
2247                                 {
2248                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2249                                                 this.deadflag = DEAD_RESPAWNING;
2250                                         break;
2251                                 }
2252                                 case DEAD_RESPAWNING:
2253                                 {
2254                                         if (time > this.respawn_time)
2255                                         {
2256                                                 this.respawn_time = time + 1; // only retry once a second
2257                                                 this.respawn_time_max = this.respawn_time;
2258                                                 respawn(this);
2259                                         }
2260                                         break;
2261                                 }
2262                         }
2263
2264                         ShowRespawnCountdown(this);
2265
2266                         if (this.respawn_flags & RESPAWN_SILENT)
2267                                 STAT(RESPAWN_TIME, this) = 0;
2268                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2269                         {
2270                                 if (time < this.respawn_time)
2271                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2272                                 else if (this.deadflag != DEAD_RESPAWNING)
2273                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2274                         }
2275                         else
2276                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2277                 }
2278
2279                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2280                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2281                         STAT(RESPAWN_TIME, this) *= -1;
2282
2283                 return false;
2284         }
2285
2286         FixPlayermodel(this);
2287
2288         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2289                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2290                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2291         }
2292
2293         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2294         //if(frametime)
2295         {
2296                 this.items &= ~this.items_added;
2297
2298                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2299                 {
2300                         .entity weaponentity = weaponentities[slot];
2301                         W_WeaponFrame(this, weaponentity);
2302                 }
2303
2304                 this.items_added = 0;
2305                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2306             this.items_added |= IT_FUEL;
2307
2308                 this.items |= this.items_added;
2309         }
2310
2311         player_regen(this);
2312
2313         // WEAPONTODO: Add a weapon request for this
2314         // rot vortex charge to the charge limit
2315         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2316         {
2317                 .entity weaponentity = weaponentities[slot];
2318                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2319                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2320         }
2321
2322         if (frametime) player_anim(this);
2323
2324         // secret status
2325         secrets_setstatus(this);
2326
2327         // monsters status
2328         monsters_setstatus(this);
2329
2330         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2331
2332         return true;
2333 }
2334
2335 .bool would_spectate;
2336 void ObserverThink(entity this)
2337 {
2338         if ( CS(this).impulse )
2339         {
2340                 MinigameImpulse(this, CS(this).impulse);
2341                 CS(this).impulse = 0;
2342         }
2343
2344         if (this.flags & FL_JUMPRELEASED) {
2345                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2346                         this.flags &= ~FL_JUMPRELEASED;
2347                         this.flags |= FL_SPAWNING;
2348                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2349                         this.flags &= ~FL_JUMPRELEASED;
2350                         if(SpectateNext(this)) {
2351                                 TRANSMUTE(Spectator, this);
2352                         }
2353                 } else {
2354                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2355                         set_movetype(this, preferred_movetype);
2356                 }
2357         } else {
2358                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2359                         this.flags |= FL_JUMPRELEASED;
2360                         if(this.flags & FL_SPAWNING)
2361                         {
2362                                 this.flags &= ~FL_SPAWNING;
2363                                 Join(this);
2364                                 return;
2365                         }
2366                 }
2367         }
2368 }
2369
2370 void SpectatorThink(entity this)
2371 {
2372         if ( CS(this).impulse )
2373         {
2374                 if(MinigameImpulse(this, CS(this).impulse))
2375                         CS(this).impulse = 0;
2376
2377                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2378                 {
2379                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2380                         CS(this).impulse = 0;
2381                         return;
2382                 }
2383         }
2384
2385         if (this.flags & FL_JUMPRELEASED) {
2386                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2387                         this.flags &= ~FL_JUMPRELEASED;
2388                         this.flags |= FL_SPAWNING;
2389                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2390                         this.flags &= ~FL_JUMPRELEASED;
2391                         if(SpectateNext(this)) {
2392                                 TRANSMUTE(Spectator, this);
2393                         } else {
2394                                 TRANSMUTE(Observer, this);
2395                                 PutClientInServer(this);
2396                         }
2397                         CS(this).impulse = 0;
2398                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2399                         this.flags &= ~FL_JUMPRELEASED;
2400                         if(SpectatePrev(this)) {
2401                                 TRANSMUTE(Spectator, this);
2402                         } else {
2403                                 TRANSMUTE(Observer, this);
2404                                 PutClientInServer(this);
2405                         }
2406                         CS(this).impulse = 0;
2407                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2408                         this.would_spectate = false;
2409                         this.flags &= ~FL_JUMPRELEASED;
2410                         TRANSMUTE(Observer, this);
2411                         PutClientInServer(this);
2412                 } else {
2413                         if(!SpectateUpdate(this))
2414                         {
2415                                 if(!SpectateNext(this))
2416                                 {
2417                                         PutObserverInServer(this);
2418                                         this.would_spectate = true;
2419                                 }
2420                         }
2421                 }
2422         } else {
2423                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2424                         this.flags |= FL_JUMPRELEASED;
2425                         if(this.flags & FL_SPAWNING)
2426                         {
2427                                 this.flags &= ~FL_SPAWNING;
2428                                 Join(this);
2429                                 return;
2430                         }
2431                 }
2432                 if(!SpectateUpdate(this))
2433                         PutObserverInServer(this);
2434         }
2435
2436         this.flags |= FL_CLIENT | FL_NOTARGET;
2437 }
2438
2439 void PlayerUseKey(entity this)
2440 {
2441         if (!IS_PLAYER(this))
2442                 return;
2443
2444         if(this.vehicle)
2445         {
2446                 if(!game_stopped)
2447                 {
2448                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2449                         return;
2450                 }
2451         }
2452         else if(autocvar_g_vehicles_enter)
2453         {
2454                 if(!STAT(FROZEN, this))
2455                 if(!IS_DEAD(this))
2456                 if(!game_stopped)
2457                 {
2458                         entity head, closest_target = NULL;
2459                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2460
2461                         while(head) // find the closest acceptable target to enter
2462                         {
2463                                 if(IS_VEHICLE(head))
2464                                 if(!IS_DEAD(head))
2465                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2466                                 if(head.takedamage != DAMAGE_NO)
2467                                 {
2468                                         if(closest_target)
2469                                         {
2470                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2471                                                 { closest_target = head; }
2472                                         }
2473                                         else { closest_target = head; }
2474                                 }
2475
2476                                 head = head.chain;
2477                         }
2478
2479                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2480                 }
2481         }
2482
2483         // a use key was pressed; call handlers
2484         MUTATOR_CALLHOOK(PlayerUseKey, this);
2485 }
2486
2487
2488 /*
2489 =============
2490 PlayerPreThink
2491
2492 Called every frame for each client before the physics are run
2493 =============
2494 */
2495 .float last_vehiclecheck;
2496 void PlayerPreThink (entity this)
2497 {
2498         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2499         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2500
2501         WarpZone_PlayerPhysics_FixVAngle(this);
2502
2503         if (frametime) {
2504                 // physics frames: update anticheat stuff
2505                 anticheat_prethink(this);
2506         }
2507
2508         if (blockSpectators && frametime) {
2509                 // WORKAROUND: only use dropclient in server frames (frametime set).
2510                 // Never use it in cl_movement frames (frametime zero).
2511                 checkSpectatorBlock(this);
2512         }
2513
2514         zoomstate_set = false;
2515
2516         // Check for nameless players
2517         if (this.netname == "" || this.netname != CS(this).netname_previous)
2518         {
2519                 bool assume_unchanged = (CS(this).netname_previous == "");
2520                 if (isInvisibleString(this.netname))
2521                 {
2522                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2523                         assume_unchanged = false;
2524                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2525                 }
2526                 if (!assume_unchanged && autocvar_sv_eventlog)
2527                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2528                 strcpy(CS(this).netname_previous, this.netname);
2529         }
2530
2531         // version nagging
2532         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2533         CS(this).version_nagtime = 0;
2534         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2535             // git client
2536         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2537             // git server
2538             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2539         } else {
2540             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2541             if (r < 0) { // old client
2542                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2543             } else if (r > 0) { // old server
2544                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2545             }
2546         }
2547     }
2548
2549         // GOD MODE info
2550         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2551         {
2552                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2553                 this.max_armorvalue = 0;
2554         }
2555
2556         if(IS_PLAYER(this))
2557         {
2558                 if (STAT(FROZEN, this) == 2)
2559                 {
2560                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2561                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2562                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2563
2564                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2565                                 Unfreeze(this);
2566                 }
2567                 else if (STAT(FROZEN, this) == 3)
2568                 {
2569                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2570                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2571
2572                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2573                         {
2574                                 if (this.vehicle)
2575                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2576                                 if(this.event_damage)
2577                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2578                         }
2579                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2580                                 Unfreeze(this);
2581                 }
2582         }
2583
2584         MUTATOR_CALLHOOK(PlayerPreThink, this);
2585
2586         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2587         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2588         {
2589                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2590                 {
2591                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2592                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2593                         {
2594                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2595                         }
2596                         else if(!it.owner)
2597                         {
2598                                 if(!it.team || SAME_TEAM(this, it))
2599                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2600                                 else if(autocvar_g_vehicles_steal)
2601                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2602                         }
2603                 });
2604
2605                 this.last_vehiclecheck = time + 1;
2606         }
2607
2608         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2609         {
2610                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2611                         PlayerUseKey(this);
2612                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2613         }
2614
2615         if (IS_REAL_CLIENT(this))
2616                 PrintWelcomeMessage(this);
2617
2618         if (IS_PLAYER(this)) {
2619                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2620                         error("Client can't be spawned as player on connection!");
2621                 if(!PlayerThink(this))
2622                         return;
2623         }
2624         else if (game_stopped || intermission_running) {
2625                 if(intermission_running)
2626                         IntermissionThink(this);
2627                 return;
2628         }
2629         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2630         {
2631                 CS(this).autojoin_checked = true;
2632                 // don't do this in ClientConnect
2633                 // many things can go wrong if a client is spawned as player on connection
2634                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2635                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2636                                 && (!teamplay || autocvar_g_balance_teams)))
2637                 {
2638                         campaign_bots_may_start = true;
2639                         Join(this);
2640                         return;
2641                 }
2642         }
2643         else if (IS_OBSERVER(this)) {
2644                 ObserverThink(this);
2645         }
2646         else if (IS_SPEC(this)) {
2647                 SpectatorThink(this);
2648         }
2649
2650         // WEAPONTODO: Add weapon request for this
2651         if (!zoomstate_set) {
2652                 bool wep_zoomed = false;
2653                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2654                 {
2655                         .entity weaponentity = weaponentities[slot];
2656                         Weapon thiswep = this.(weaponentity).m_weapon;
2657                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2658                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2659                 }
2660                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2661     }
2662
2663         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2664         {
2665                 CS(this).teamkill_soundtime = 0;
2666
2667                 entity e = CS(this).teamkill_soundsource;
2668                 entity oldpusher = e.pusher;
2669                 e.pusher = this;
2670                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2671                 e.pusher = oldpusher;
2672         }
2673
2674         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2675                 CS(this).taunt_soundtime = 0;
2676                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2677         }
2678
2679         target_voicescript_next(this);
2680
2681         // WEAPONTODO: Move into weaponsystem somehow
2682         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2683         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2684         {
2685                 .entity weaponentity = weaponentities[slot];
2686                 if(this.(weaponentity).m_weapon == WEP_Null)
2687                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2688         }
2689 }
2690
2691 void DrownPlayer(entity this)
2692 {
2693         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2694                 return;
2695
2696         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2697         {
2698                 if(this.air_finished < time)
2699                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2700                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2701         }
2702         else if (this.air_finished < time)
2703         {       // drown!
2704                 if (this.pain_finished < time)
2705                 {
2706                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2707                         this.pain_finished = time + 0.5;
2708                 }
2709         }
2710 }
2711
2712 .bool move_qcphysics;
2713
2714 void Player_Physics(entity this)
2715 {
2716         set_movetype(this, this.move_movetype);
2717
2718         if(!this.move_qcphysics)
2719                 return;
2720
2721         if(!frametime && !CS(this).pm_frametime)
2722                 return;
2723
2724         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2725
2726         CS(this).pm_frametime = 0;
2727 }
2728
2729 /*
2730 =============
2731 PlayerPostThink
2732
2733 Called every frame for each client after the physics are run
2734 =============
2735 */
2736 void PlayerPostThink (entity this)
2737 {
2738         Player_Physics(this);
2739
2740         if (sv_maxidle > 0)
2741         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2742         if (IS_REAL_CLIENT(this))
2743         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2744         {
2745                 int totalClients = 0;
2746                 if(sv_maxidle_slots > 0)
2747                 {
2748                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2749                         {
2750                                 ++totalClients;
2751                         });
2752                 }
2753
2754                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2755                 { /* do nothing */ }
2756                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2757                 {
2758                         if (CS(this).idlekick_lasttimeleft)
2759                         {
2760                                 CS(this).idlekick_lasttimeleft = 0;
2761                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2762                         }
2763                 }
2764                 else
2765                 {
2766                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2767                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2768                                 if (!CS(this).idlekick_lasttimeleft)
2769                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2770                         }
2771                         if (timeleft <= 0) {
2772                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2773                                 dropclient(this);
2774                                 return;
2775                         }
2776                         else if (timeleft <= 10) {
2777                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2778                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2779                 }
2780                                 CS(this).idlekick_lasttimeleft = timeleft;
2781                         }
2782                 }
2783         }
2784
2785         CheatFrame(this);
2786
2787         if (game_stopped)
2788         {
2789                 this.solid = SOLID_NOT;
2790                 this.takedamage = DAMAGE_NO;
2791                 set_movetype(this, MOVETYPE_NONE);
2792         }
2793
2794         if (IS_PLAYER(this)) {
2795                 if(this.death_time == time && IS_DEAD(this))
2796                 {
2797                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2798                         // once all the damage events of this frame have been processed with normal size
2799                         this.maxs.z = 5;
2800                         setsize(this, this.mins, this.maxs);
2801                 }
2802                 DrownPlayer(this);
2803                 UpdateChatBubble(this);
2804                 if (CS(this).impulse) ImpulseCommands(this);
2805                 if (game_stopped)
2806                 {
2807                         CSQCMODEL_AUTOUPDATE(this);
2808                         return;
2809                 }
2810                 GetPressedKeys(this);
2811         }
2812
2813         if (this.waypointsprite_attachedforcarrier) {
2814             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2815                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2816     }
2817
2818         playerdemo_write(this);
2819
2820         CSQCMODEL_AUTOUPDATE(this);
2821 }
2822
2823 // hack to copy the button fields from the client entity to the Client State
2824 void PM_UpdateButtons(entity this, entity store)
2825 {
2826         if(this.impulse)
2827                 store.impulse = this.impulse;
2828         this.impulse = 0;
2829
2830         bool typing = this.buttonchat;
2831
2832         store.button0 = (typing) ? 0 : this.button0;
2833         //button1?!
2834         store.button2 = (typing) ? 0 : this.button2;
2835         store.button3 = (typing) ? 0 : this.button3;
2836         store.button4 = this.button4;
2837         store.button5 = (typing) ? 0 : this.button5;
2838         store.button6 = this.button6;
2839         store.button7 = this.button7;
2840         store.button8 = this.button8;
2841         store.button9 = this.button9;
2842         store.button10 = this.button10;
2843         store.button11 = this.button11;
2844         store.button12 = this.button12;
2845         store.button13 = this.button13;
2846         store.button14 = this.button14;
2847         store.button15 = this.button15;
2848         store.button16 = this.button16;
2849         store.buttonuse = this.buttonuse;
2850         store.buttonchat = this.buttonchat;
2851
2852         store.cursor_active = this.cursor_active;
2853         store.cursor_screen = this.cursor_screen;
2854         store.cursor_trace_start = this.cursor_trace_start;
2855         store.cursor_trace_endpos = this.cursor_trace_endpos;
2856         store.cursor_trace_ent = this.cursor_trace_ent;
2857
2858         store.ping = this.ping;
2859         store.ping_packetloss = this.ping_packetloss;
2860         store.ping_movementloss = this.ping_movementloss;
2861
2862         store.v_angle = this.v_angle;
2863         store.movement = (typing) ? '0 0 0' : this.movement;
2864 }
2865
2866 NET_HANDLE(fpsreport, bool)
2867 {
2868         int fps = ReadShort();
2869         PlayerScore_Set(sender, SP_FPS, fps);
2870         return true;
2871 }