qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 STATIC_METHOD(Client, Add, void(Client this, int _team))
  66 {
  67     ClientConnect(this);
  68     TRANSMUTE(Player, this);
  69     this.frame = 12; // 7
  70     this.team = _team;
  71     PutClientInServer(this);
  72 }
  73
  74 void PutObserverInServer(entity this);
  75
  76 STATIC_METHOD(Client, Remove, void(Client this))
  77 {
  78     TRANSMUTE(Observer, this);
  79     PutClientInServer(this);
  80     ClientDisconnect(this);
  81 }
  82
  83 void send_CSQC_teamnagger() {
  84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  85 }
  86
  87 int CountSpectators(entity player, entity to)
  88 {
  89         if(!player) { return 0; } // not sure how, but best to be safe
  90
  91         int spec_count = 0;
  92
  93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  94         {
  95                 spec_count++;
  96         });
  97
  98         return spec_count;
  99 }
 100
 101 void WriteSpectators(entity player, entity to)
 102 {
 103         if(!player) { return; } // not sure how, but best to be safe
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 WriteByte(MSG_ENTITY, num_for_edict(it));
 108         });
 109 }
 110
 111 bool ClientData_Send(entity this, entity to, int sf)
 112 {
 113         assert(to == this.owner, return false);
 114
 115         entity e = to;
 116         if (IS_SPEC(e)) e = e.enemy;
 117
 118         sf = 0;
 119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 123
 124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 125         WriteByte(MSG_ENTITY, sf);
 126
 127         if (sf & BIT(1))
 128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 129
 130         if(sf & BIT(4))
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         CS(this).clientdata.drawonlytoclient = this;
 144         CS(this).clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(CS(this).clientdata);
 150         CS(this).clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         CS(e).clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 159 }
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this))
 225         {
 226                 if(this.health >= 1)
 227                 {
 228                         // despawn effect
 229                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230                 }
 231
 232                 // was a player, recount votes and ready status
 233                 if(IS_REAL_CLIENT(this))
 234                 {
 235                         if (vote_called) { VoteCount(false); }
 236                         ReadyCount();
 237                 }
 238     }
 239
 240     {
 241         entity spot = SelectSpawnPoint(this, true);
 242         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 243         this.angles = vec2(spot.angles);
 244         this.fixangle = true;
 245         // offset it so that the spectator spawns higher off the ground, looks better this way
 246         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 247         if (IS_REAL_CLIENT(this))
 248         {
 249             msg_entity = this;
 250             WriteByte(MSG_ONE, SVC_SETVIEW);
 251             WriteEntity(MSG_ONE, this);
 252         }
 253         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 254         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 255         if(!autocvar_g_debug_globalsounds)
 256         {
 257                 // needed for player sounds
 258                 this.model = "";
 259                 FixPlayermodel(this);
 260         }
 261         setmodel(this, MDL_Null);
 262         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 263         this.view_ofs = '0 0 0';
 264     }
 265
 266     RemoveGrapplingHooks(this);
 267         Portal_ClearAll(this);
 268         Unfreeze(this);
 269         SetSpectatee(this, NULL);
 270
 271         if (this.alivetime)
 272         {
 273                 if (!warmup_stage)
 274                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 275                 this.alivetime = 0;
 276         }
 277
 278         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 279
 280         WaypointSprite_PlayerDead(this);
 281
 282         if (mutator_returnvalue) {
 283             // mutator prevents resetting teams+score
 284         } else {
 285                 int old_team_index = Team_TeamToIndex(this.team);
 286                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 287                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, old_team_index, -1);
 288         this.frags = FRAGS_SPECTATOR;
 289         PlayerScore_Clear(this);  // clear scores when needed
 290     }
 291
 292         if (CS(this).killcount != FRAGS_SPECTATOR)
 293         {
 294                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298
 299                 if(!CS(this).just_joined)
 300                         LogTeamchange(this.playerid, -1, TEAM_CHANGE_SPECTATOR);
 301                 else
 302                         CS(this).just_joined = false;
 303         }
 304
 305         accuracy_resend(this);
 306
 307         CS(this).spectatortime = time;
 308         if(this.bot_attack)
 309                 IL_REMOVE(g_bot_targets, this);
 310         this.bot_attack = false;
 311         if(this.monster_attack)
 312                 IL_REMOVE(g_monster_targets, this);
 313         this.monster_attack = false;
 314     STAT(HUD, this) = HUD_NORMAL;
 315         TRANSMUTE(Observer, this);
 316         this.iscreature = false;
 317         this.teleportable = TELEPORT_SIMPLE;
 318         if(this.damagedbycontents)
 319                 IL_REMOVE(g_damagedbycontents, this);
 320         this.damagedbycontents = false;
 321         this.health = FRAGS_SPECTATOR;
 322         SetSpectatee_status(this, etof(this));
 323         this.takedamage = DAMAGE_NO;
 324         this.solid = SOLID_NOT;
 325         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 326         this.flags = FL_CLIENT | FL_NOTARGET;
 327         this.armorvalue = 666;
 328         this.effects = 0;
 329         this.armorvalue = autocvar_g_balance_armor_start;
 330         this.pauserotarmor_finished = 0;
 331         this.pauserothealth_finished = 0;
 332         this.pauseregen_finished = 0;
 333         this.damageforcescale = 0;
 334         this.death_time = 0;
 335         this.respawn_flags = 0;
 336         this.respawn_time = 0;
 337         STAT(RESPAWN_TIME, this) = 0;
 338         this.alpha = 0;
 339         this.scale = 0;
 340         this.fade_time = 0;
 341         this.pain_frame = 0;
 342         this.pain_finished = 0;
 343         this.strength_finished = 0;
 344         this.invincible_finished = 0;
 345         this.superweapons_finished = 0;
 346         this.dphitcontentsmask = 0;
 347         this.pushltime = 0;
 348         this.istypefrag = 0;
 349         setthink(this, func_null);
 350         this.nextthink = 0;
 351         this.deadflag = DEAD_NO;
 352         this.crouch = false;
 353         STAT(REVIVE_PROGRESS, this) = 0;
 354         this.revival_time = 0;
 355
 356         this.items = 0;
 357         this.weapons = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387 }
 388
 389 int player_getspecies(entity this)
 390 {
 391         get_model_parameters(this.model, this.skin);
 392         int s = get_model_parameters_species;
 393         get_model_parameters(string_null, 0);
 394         if (s < 0) return SPECIES_HUMAN;
 395         return s;
 396 }
 397
 398 .float model_randomizer;
 399 void FixPlayermodel(entity player)
 400 {
 401         string defaultmodel = "";
 402         int defaultskin = 0;
 403         if(autocvar_sv_defaultcharacter)
 404         {
 405                 if(teamplay)
 406                 {
 407                         switch(player.team)
 408                         {
 409                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 410                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 411                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 412                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 413                         }
 414                 }
 415
 416                 if(defaultmodel == "")
 417                 {
 418                         defaultmodel = autocvar_sv_defaultplayermodel;
 419                         defaultskin = autocvar_sv_defaultplayerskin;
 420                 }
 421
 422                 int n = tokenize_console(defaultmodel);
 423                 if(n > 0)
 424                 {
 425                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 426                         // However, do NOT randomize if the player-selected model is in the list.
 427                         for (int i = 0; i < n; ++i)
 428                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 429                                         defaultmodel = argv(i);
 430                 }
 431
 432                 int i = strstrofs(defaultmodel, ":", 0);
 433                 if(i >= 0)
 434                 {
 435                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 436                         defaultmodel = substring(defaultmodel, 0, i);
 437                 }
 438         }
 439         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 440         {
 441                 if(teamplay)
 442                 {
 443                         switch(player.team)
 444                         {
 445                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 446                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 447                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 448                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 449                         }
 450                 }
 451
 452                 if(!defaultskin)
 453                         defaultskin = autocvar_sv_defaultplayerskin;
 454         }
 455
 456         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 457         defaultmodel = M_ARGV(0, string);
 458         defaultskin = M_ARGV(1, int);
 459
 460         bool chmdl = false;
 461         int oldskin;
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != player.model)
 465                 {
 466                         vector m1 = player.mins;
 467                         vector m2 = player.maxs;
 468                         setplayermodel (player, defaultmodel);
 469                         setsize (player, m1, m2);
 470                         chmdl = true;
 471                 }
 472
 473                 oldskin = player.skin;
 474                 player.skin = defaultskin;
 475         } else {
 476                 if (player.playermodel != player.model || player.playermodel == "")
 477                 {
 478                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, player.playermodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 if(!autocvar_sv_defaultcharacterskin)
 487                 {
 488                         oldskin = player.skin;
 489                         player.skin = stof(player.playerskin);
 490                 }
 491                 else
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = defaultskin;
 495                 }
 496         }
 497
 498         if(chmdl || oldskin != player.skin) // model or skin has changed
 499         {
 500                 player.species = player_getspecies(player); // update species
 501                 if(!autocvar_g_debug_globalsounds)
 502                         UpdatePlayerSounds(player); // update skin sounds
 503         }
 504
 505         if(!teamplay)
 506                 if(strlen(autocvar_sv_defaultplayercolors))
 507                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 508                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 509 }
 510
 511 void PutPlayerInServer(entity this)
 512 {
 513         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 514
 515         PlayerState_attach(this);
 516         accuracy_resend(this);
 517
 518         if (this.team < 0)
 519                 TeamBalance_JoinBestTeam(this, true);
 520
 521         entity spot = SelectSpawnPoint(this, false);
 522         if (!spot) {
 523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 524                 return; // spawn failed
 525         }
 526
 527         TRANSMUTE(Player, this);
 528
 529         CS(this).wasplayer = true;
 530         this.iscreature = true;
 531         this.teleportable = TELEPORT_NORMAL;
 532         if(!this.damagedbycontents)
 533                 IL_PUSH(g_damagedbycontents, this);
 534         this.damagedbycontents = true;
 535         set_movetype(this, MOVETYPE_WALK);
 536         this.solid = SOLID_SLIDEBOX;
 537         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 538         if (autocvar_g_playerclip_collisions)
 539                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 540         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 541                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 542         this.frags = FRAGS_PLAYER;
 543         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 544         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 545         if (autocvar__notarget)
 546                 this.flags |= FL_NOTARGET;
 547         this.takedamage = DAMAGE_AIM;
 548         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 549
 550         if (warmup_stage) {
 551                 this.ammo_shells = warmup_start_ammo_shells;
 552                 this.ammo_nails = warmup_start_ammo_nails;
 553                 this.ammo_rockets = warmup_start_ammo_rockets;
 554                 this.ammo_cells = warmup_start_ammo_cells;
 555                 this.ammo_plasma = warmup_start_ammo_plasma;
 556                 this.ammo_fuel = warmup_start_ammo_fuel;
 557                 this.health = warmup_start_health;
 558                 this.armorvalue = warmup_start_armorvalue;
 559                 this.weapons = WARMUP_START_WEAPONS;
 560         } else {
 561                 this.ammo_shells = start_ammo_shells;
 562                 this.ammo_nails = start_ammo_nails;
 563                 this.ammo_rockets = start_ammo_rockets;
 564                 this.ammo_cells = start_ammo_cells;
 565                 this.ammo_plasma = start_ammo_plasma;
 566                 this.ammo_fuel = start_ammo_fuel;
 567                 this.health = start_health;
 568                 this.armorvalue = start_armorvalue;
 569                 this.weapons = start_weapons;
 570                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 571                 {
 572                         GiveRandomWeapons(this, random_start_weapons_count,
 573                                 autocvar_g_random_start_weapons, random_start_ammo);
 574                 }
 575         }
 576         SetSpectatee_status(this, 0);
 577
 578         PS(this).dual_weapons = '0 0 0';
 579
 580         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 581
 582         this.items = start_items;
 583
 584         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 585         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 586         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 587         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 588         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 589         if (!sv_ready_restart_after_countdown && time < game_starttime)
 590         {
 591                 float f = game_starttime - time;
 592                 this.spawnshieldtime += f;
 593                 this.pauserotarmor_finished += f;
 594                 this.pauserothealth_finished += f;
 595                 this.pauseregen_finished += f;
 596         }
 597
 598         this.damageforcescale = 2;
 599         this.death_time = 0;
 600         this.respawn_flags = 0;
 601         this.respawn_time = 0;
 602         STAT(RESPAWN_TIME, this) = 0;
 603         this.scale = autocvar_sv_player_scale;
 604         this.fade_time = 0;
 605         this.pain_frame = 0;
 606         this.pain_finished = 0;
 607         this.pushltime = 0;
 608         setthink(this, func_null); // players have no think function
 609         this.nextthink = 0;
 610         this.dmg_team = 0;
 611         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 612
 613         this.deadflag = DEAD_NO;
 614
 615         this.angles = spot.angles;
 616         this.angles_z = 0; // never spawn tilted even if the spot says to
 617         if (IS_BOT_CLIENT(this))
 618                 this.v_angle = this.angles;
 619         this.fixangle = true; // turn this way immediately
 620         this.oldvelocity = this.velocity = '0 0 0';
 621         this.avelocity = '0 0 0';
 622         this.punchangle = '0 0 0';
 623         this.punchvector = '0 0 0';
 624
 625         this.strength_finished = 0;
 626         this.invincible_finished = 0;
 627         this.fire_endtime = -1;
 628         STAT(REVIVE_PROGRESS, this) = 0;
 629         this.revival_time = 0;
 630
 631         this.air_finished = time + 12;
 632         this.waterlevel = WATERLEVEL_NONE;
 633         this.watertype = CONTENT_EMPTY;
 634
 635         entity spawnevent = new_pure(spawnevent);
 636         spawnevent.owner = this;
 637         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 638
 639         // Cut off any still running player sounds.
 640         stopsound(this, CH_PLAYER_SINGLE);
 641
 642         this.model = "";
 643         FixPlayermodel(this);
 644         this.drawonlytoclient = NULL;
 645
 646         this.viewloc = NULL;
 647
 648         for(int slot = 0; slot < MAX_AXH; ++slot)
 649         {
 650                 entity axh = this.(AuxiliaryXhair[slot]);
 651                 this.(AuxiliaryXhair[slot]) = NULL;
 652
 653                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 654                         delete(axh);
 655         }
 656
 657         this.spawnpoint_targ = NULL;
 658
 659         this.crouch = false;
 660         this.view_ofs = STAT(PL_VIEW_OFS, this);
 661         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 662         this.spawnorigin = spot.origin;
 663         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 664         // don't reset back to last position, even if new position is stuck in solid
 665         this.oldorigin = this.origin;
 666         if(this.conveyor)
 667                 IL_REMOVE(g_conveyed, this);
 668         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 669         STAT(HUD, this) = HUD_NORMAL;
 670
 671         this.event_damage = PlayerDamage;
 672
 673         if(!this.bot_attack)
 674                 IL_PUSH(g_bot_targets, this);
 675         this.bot_attack = true;
 676         if(!this.monster_attack)
 677                 IL_PUSH(g_monster_targets, this);
 678         this.monster_attack = true;
 679         navigation_dynamicgoal_init(this, false);
 680
 681         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 682
 683         // player was spectator
 684         if (CS(this).killcount == FRAGS_SPECTATOR) {
 685                 PlayerScore_Clear(this);
 686                 CS(this).killcount = 0;
 687                 CS(this).startplaytime = time;
 688         }
 689
 690         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691         {
 692                 .entity weaponentity = weaponentities[slot];
 693                 entity oldwep = this.(weaponentity);
 694                 CL_SpawnWeaponentity(this, weaponentity);
 695                 if(oldwep && oldwep.owner == this)
 696                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 697         }
 698         this.alpha = default_player_alpha;
 699         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 700         this.exteriorweaponentity.alpha = default_weapon_alpha;
 701
 702         this.speedrunning = false;
 703
 704         target_voicescript_clear(this);
 705
 706         // reset fields the weapons may use
 707         FOREACH(Weapons, true, {
 708                 it.wr_resetplayer(it, this);
 709                         // reload all reloadable weapons
 710                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 711                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 712                         {
 713                                 .entity weaponentity = weaponentities[slot];
 714                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 715                         }
 716                 }
 717         });
 718
 719         {
 720                 string s = spot.target;
 721                 spot.target = string_null;
 722                 SUB_UseTargets(spot, this, NULL);
 723                 spot.target = s;
 724         }
 725
 726         Unfreeze(this);
 727
 728         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 729
 730         if (autocvar_spawn_debug)
 731         {
 732                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 733                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 734         }
 735
 736         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 740                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 741                 else
 742                         this.(weaponentity).m_switchweapon = WEP_Null;
 743                 this.(weaponentity).m_weapon = WEP_Null;
 744                 this.(weaponentity).weaponname = "";
 745                 this.(weaponentity).m_switchingweapon = WEP_Null;
 746                 this.(weaponentity).cnt = -1;
 747         }
 748
 749         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 750
 751         if (!warmup_stage && !this.alivetime)
 752                 this.alivetime = time;
 753
 754         antilag_clear(this, CS(this));
 755 }
 756
 757 /** Called when a client spawns in the server */
 758 void PutClientInServer(entity this)
 759 {
 760         if (IS_BOT_CLIENT(this)) {
 761                 TRANSMUTE(Player, this);
 762         } else if (IS_REAL_CLIENT(this)) {
 763                 msg_entity = this;
 764                 WriteByte(MSG_ONE, SVC_SETVIEW);
 765                 WriteEntity(MSG_ONE, this);
 766         }
 767         if (game_stopped)
 768                 TRANSMUTE(Observer, this);
 769
 770         SetSpectatee(this, NULL);
 771
 772         // reset player keys
 773         if(PS(this))
 774                 PS(this).itemkeys = 0;
 775
 776         MUTATOR_CALLHOOK(PutClientInServer, this);
 777
 778         if (IS_OBSERVER(this)) {
 779                 PutObserverInServer(this);
 780         } else if (IS_PLAYER(this)) {
 781                 PutPlayerInServer(this);
 782         }
 783 }
 784
 785 void ClientInit_misc(entity this);
 786
 787 // TODO do we need all these fields, or should we stop autodetecting runtime
 788 // changes and just have a console command to update this?
 789 bool ClientInit_SendEntity(entity this, entity to, int sf)
 790 {
 791         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 792         return = true;
 793         msg_entity = to;
 794         // MSG_INIT replacement
 795         // TODO: make easier to use
 796         Registry_send_all();
 797         W_PROP_reload(MSG_ONE, to);
 798         ClientInit_misc(this);
 799         MUTATOR_CALLHOOK(Ent_Init);
 800 }
 801 void ClientInit_misc(entity this)
 802 {
 803         int channel = MSG_ONE;
 804         WriteHeader(channel, ENT_CLIENT_INIT);
 805         WriteByte(channel, g_nexball_meter_period * 32);
 806         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 807         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 810         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 811         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 814
 815         if(sv_foginterval && world.fog != "")
 816                 WriteString(channel, world.fog);
 817         else
 818                 WriteString(channel, "");
 819         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 820         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 821         WriteByte(channel, serverflags);
 822         WriteCoord(channel, autocvar_g_trueaim_minrange);
 823 }
 824
 825 void ClientInit_CheckUpdate(entity this)
 826 {
 827         this.nextthink = time;
 828         if(this.count != autocvar_g_balance_armor_blockpercent)
 829         {
 830                 this.count = autocvar_g_balance_armor_blockpercent;
 831                 this.SendFlags |= 1;
 832         }
 833         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 834         {
 835                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 836                 this.SendFlags |= 1;
 837         }
 838 }
 839
 840 void ClientInit_Spawn()
 841 {
 842         entity e = new_pure(clientinit);
 843         setthink(e, ClientInit_CheckUpdate);
 844         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 845
 846         ClientInit_CheckUpdate(e);
 847 }
 848
 849 /*
 850 =============
 851 SetNewParms
 852 =============
 853 */
 854 void SetNewParms ()
 855 {
 856         // initialize parms for a new player
 857         parm1 = -(86400 * 366);
 858
 859         MUTATOR_CALLHOOK(SetNewParms);
 860 }
 861
 862 /*
 863 =============
 864 SetChangeParms
 865 =============
 866 */
 867 void SetChangeParms (entity this)
 868 {
 869         // save parms for level change
 870         parm1 = CS(this).parm_idlesince - time;
 871
 872         MUTATOR_CALLHOOK(SetChangeParms);
 873 }
 874
 875 /*
 876 =============
 877 DecodeLevelParms
 878 =============
 879 */
 880 void DecodeLevelParms(entity this)
 881 {
 882         // load parms
 883         CS(this).parm_idlesince = parm1;
 884         if (CS(this).parm_idlesince == -(86400 * 366))
 885                 CS(this).parm_idlesince = time;
 886
 887         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 888         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 889
 890         MUTATOR_CALLHOOK(DecodeLevelParms);
 891 }
 892
 893 /*
 894 =============
 895 ClientKill
 896
 897 Called when a client types 'kill' in the console
 898 =============
 899 */
 900
 901 .float clientkill_nexttime;
 902 void ClientKill_Now_TeamChange(entity this)
 903 {
 904         if(this.killindicator_teamchange == -1)
 905         {
 906                 TeamBalance_JoinBestTeam(this, true);
 907         }
 908         else if(this.killindicator_teamchange == -2)
 909         {
 910                 if(blockSpectators)
 911                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 912                 PutObserverInServer(this);
 913         }
 914         else
 915                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 916         this.killindicator_teamchange = 0;
 917 }
 918
 919 void ClientKill_Now(entity this)
 920 {
 921         if(this.vehicle)
 922         {
 923             vehicles_exit(this.vehicle, VHEF_RELEASE);
 924             if(!this.killindicator_teamchange)
 925             {
 926             this.vehicle_health = -1;
 927             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 928             }
 929         }
 930
 931         if(this.killindicator && !wasfreed(this.killindicator))
 932                 delete(this.killindicator);
 933
 934         this.killindicator = NULL;
 935
 936         if(this.killindicator_teamchange)
 937                 ClientKill_Now_TeamChange(this);
 938
 939         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 940         {
 941                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 942         }
 943
 944         // now I am sure the player IS dead
 945 }
 946 void KillIndicator_Think(entity this)
 947 {
 948         if (game_stopped)
 949         {
 950                 this.owner.killindicator = NULL;
 951                 delete(this);
 952                 return;
 953         }
 954
 955         if (this.owner.alpha < 0 && !this.owner.vehicle)
 956         {
 957                 this.owner.killindicator = NULL;
 958                 delete(this);
 959                 return;
 960         }
 961
 962         if(this.cnt <= 0)
 963         {
 964                 ClientKill_Now(this.owner);
 965                 return;
 966         }
 967     else if(this.health == 1) // health == 1 means that it's silent
 968     {
 969         this.nextthink = time + 1;
 970         this.cnt -= 1;
 971     }
 972         else
 973         {
 974                 if(this.cnt <= 10)
 975                         setmodel(this, MDL_NUM(this.cnt));
 976                 if(IS_REAL_CLIENT(this.owner))
 977                 {
 978                         if(this.cnt <= 10)
 979                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 980                 }
 981                 this.nextthink = time + 1;
 982                 this.cnt -= 1;
 983         }
 984 }
 985
 986 float clientkilltime;
 987 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 988 {
 989         float killtime;
 990         float starttime;
 991
 992         if (game_stopped)
 993                 return;
 994
 995         killtime = autocvar_g_balance_kill_delay;
 996
 997     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 998         return;
 999     killtime = M_ARGV(1, float);
1000
1001         this.killindicator_teamchange = targetteam;
1002
1003     if(!this.killindicator)
1004         {
1005                 if(!IS_DEAD(this))
1006                 {
1007                         killtime = max(killtime, this.clientkill_nexttime - time);
1008                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1009                 }
1010
1011                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1012                 {
1013                         ClientKill_Now(this);
1014                 }
1015                 else
1016                 {
1017                         starttime = max(time, clientkilltime);
1018
1019                         this.killindicator = spawn();
1020                         this.killindicator.owner = this;
1021                         this.killindicator.scale = 0.5;
1022                         setattachment(this.killindicator, this, "");
1023                         setorigin(this.killindicator, '0 0 52');
1024                         setthink(this.killindicator, KillIndicator_Think);
1025                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1026                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1027                         this.killindicator.cnt = ceil(killtime);
1028                         this.killindicator.count = bound(0, ceil(killtime), 10);
1029                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1030
1031                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1032                         {
1033                                 it.killindicator = spawn();
1034                                 it.killindicator.owner = it;
1035                                 it.killindicator.scale = 0.5;
1036                                 setattachment(it.killindicator, it, "");
1037                                 setorigin(it.killindicator, '0 0 52');
1038                                 setthink(it.killindicator, KillIndicator_Think);
1039                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1040                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1041                                 it.killindicator.cnt = ceil(killtime);
1042                         });
1043                         this.lip = 0;
1044                 }
1045         }
1046         if(this.killindicator)
1047         {
1048                 if(targetteam == 0) // just die
1049                 {
1050                         this.killindicator.colormod = '0 0 0';
1051                         if(IS_REAL_CLIENT(this))
1052                         if(this.killindicator.cnt > 0)
1053                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1054                 }
1055                 else if(targetteam == -1) // auto
1056                 {
1057                         this.killindicator.colormod = '0 1 0';
1058                         if(IS_REAL_CLIENT(this))
1059                         if(this.killindicator.cnt > 0)
1060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1061                 }
1062                 else if(targetteam == -2) // spectate
1063                 {
1064                         this.killindicator.colormod = '0.5 0.5 0.5';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1068                 }
1069                 else
1070                 {
1071                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1075                 }
1076         }
1077
1078 }
1079
1080 void ClientKill (entity this)
1081 {
1082         if(game_stopped) return;
1083         if(this.player_blocked) return;
1084         if(STAT(FROZEN, this)) return;
1085
1086         ClientKill_TeamChange(this, 0);
1087 }
1088
1089 void FixClientCvars(entity e)
1090 {
1091         // send prediction settings to the client
1092         stuffcmd(e, "\nin_bindmap 0 0\n");
1093         if(autocvar_g_antilag == 3) // client side hitscan
1094                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1095         if(autocvar_sv_gentle)
1096                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1097
1098         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1099         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1100
1101         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1102
1103         MUTATOR_CALLHOOK(FixClientCvars, e);
1104 }
1105
1106 bool findinlist_abbrev(string tofind, string list)
1107 {
1108         if(list == "" || tofind == "")
1109                 return false; // empty list or search, just return
1110
1111         // this function allows abbreviated strings!
1112         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1113         {
1114                 return true;
1115         });
1116
1117         return false;
1118 }
1119
1120 bool PlayerInIPList(entity p, string iplist)
1121 {
1122         // some safety checks (never allow local?)
1123         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1124                 return false;
1125
1126         return findinlist_abbrev(p.netaddress, iplist);
1127 }
1128
1129 bool PlayerInIDList(entity p, string idlist)
1130 {
1131         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1132         if(!p.crypto_idfp)
1133                 return false;
1134
1135         return findinlist_abbrev(p.crypto_idfp, idlist);
1136 }
1137
1138 bool PlayerInList(entity player, string list)
1139 {
1140         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1141 }
1142
1143 #ifdef DP_EXT_PRECONNECT
1144 /*
1145 =============
1146 ClientPreConnect
1147
1148 Called once (not at each match start) when a client begins a connection to the server
1149 =============
1150 */
1151 void ClientPreConnect(entity this)
1152 {
1153         if(autocvar_sv_eventlog)
1154         {
1155                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1156                         this.playerid,
1157                         etof(this),
1158                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1159                 ));
1160         }
1161 }
1162 #endif
1163
1164 string GetClientVersionMessage(entity this)
1165 {
1166         if (CS(this).version_mismatch) {
1167                 if(CS(this).version < autocvar_gameversion) {
1168                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1169                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1170                 } else {
1171                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1172                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1173                 }
1174         } else {
1175                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1176         }
1177 }
1178
1179 string getwelcomemessage(entity this)
1180 {
1181         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1182         string modifications = M_ARGV(0, string);
1183
1184         if(g_weaponarena)
1185         {
1186                 if(g_weaponarena_random)
1187                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1188                 else
1189                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1190         }
1191         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1192                 modifications = strcat(modifications, ", No start weapons");
1193         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1194                 modifications = strcat(modifications, ", Low gravity");
1195         if(g_weapon_stay && !g_cts)
1196                 modifications = strcat(modifications, ", Weapons stay");
1197         if(g_jetpack)
1198                 modifications = strcat(modifications, ", Jet pack");
1199         if(autocvar_g_powerups == 0)
1200                 modifications = strcat(modifications, ", No powerups");
1201         if(autocvar_g_powerups > 0)
1202                 modifications = strcat(modifications, ", Powerups");
1203         modifications = substring(modifications, 2, strlen(modifications) - 2);
1204
1205         string versionmessage = GetClientVersionMessage(this);
1206         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1207
1208         if(modifications != "")
1209                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1210
1211         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1212         {
1213                 if(cache_lastmutatormsg)
1214                         strunzone(cache_lastmutatormsg);
1215                 if(cache_mutatormsg)
1216                         strunzone(cache_mutatormsg);
1217                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
1218                 cache_mutatormsg = strzone(cache_lastmutatormsg);
1219         }
1220
1221         if (cache_mutatormsg != "") {
1222                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1223         }
1224
1225         string mutator_msg = "";
1226         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1227         mutator_msg = M_ARGV(0, string);
1228
1229         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1230
1231         string motd = autocvar_sv_motd;
1232         if (motd != "") {
1233                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1234         }
1235         return s;
1236 }
1237
1238 /**
1239 =============
1240 ClientConnect
1241
1242 Called when a client connects to the server
1243 =============
1244 */
1245 void ClientConnect(entity this)
1246 {
1247         if (Ban_MaybeEnforceBanOnce(this)) return;
1248         assert(!IS_CLIENT(this), return);
1249         this.flags |= FL_CLIENT;
1250         assert(player_count >= 0, player_count = 0);
1251
1252 #ifdef WATERMARK
1253         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1254 #endif
1255         TRANSMUTE(Client, this);
1256         CS(this).version_nagtime = time + 10 + random() * 10;
1257
1258         // identify the right forced team
1259         if (autocvar_g_campaign)
1260         {
1261                 if (IS_REAL_CLIENT(this)) // only players, not bots
1262                 {
1263                         switch (autocvar_g_campaign_forceteam)
1264                         {
1265                                 case 1: this.team_forced = NUM_TEAM_1; break;
1266                                 case 2: this.team_forced = NUM_TEAM_2; break;
1267                                 case 3: this.team_forced = NUM_TEAM_3; break;
1268                                 case 4: this.team_forced = NUM_TEAM_4; break;
1269                                 default: this.team_forced = 0;
1270                         }
1271                 }
1272         }
1273         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1274         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1275         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1276         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1277         else switch (autocvar_g_forced_team_otherwise)
1278         {
1279                 default: this.team_forced = 0; break;
1280                 case "red": this.team_forced = NUM_TEAM_1; break;
1281                 case "blue": this.team_forced = NUM_TEAM_2; break;
1282                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1283                 case "pink": this.team_forced = NUM_TEAM_4; break;
1284                 case "spectate":
1285                 case "spectator":
1286                         this.team_forced = -1;
1287                         break;
1288         }
1289         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1290
1291         int playerid_save = this.playerid;
1292         this.playerid = 0; // silent
1293         TeamBalance_JoinBestTeam(this, false); // if the team number is valid, keep it
1294         this.playerid = playerid_save;
1295
1296         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1297                 TRANSMUTE(Observer, this);
1298         } else {
1299                 if (!teamplay || autocvar_g_balance_teams) {
1300                         TRANSMUTE(Player, this);
1301                         campaign_bots_may_start = true;
1302                 } else {
1303                         TRANSMUTE(Observer, this); // do it anyway
1304                 }
1305         }
1306
1307         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1308
1309         // always track bots, don't ask for cl_allow_uidtracking
1310         if (IS_BOT_CLIENT(this))
1311                 PlayerStats_GameReport_AddPlayer(this);
1312         else
1313                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1314
1315         if (autocvar_sv_eventlog)
1316                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1317
1318         LogTeamchange(this.playerid, this.team, TEAM_CHANGE_CONNECT);
1319
1320         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1321
1322         if(teamplay && IS_PLAYER(this))
1323                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1324         else
1325                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1326
1327         stuffcmd(this, clientstuff, "\n");
1328         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1329
1330         FixClientCvars(this);
1331
1332         // get version info from player
1333         stuffcmd(this, "cmd clientversion $gameversion\n");
1334
1335         // notify about available teams
1336         if (teamplay)
1337         {
1338                 entity balance = TeamBalance_CheckAllowedTeams(this);
1339                 int t = TeamBalance_GetAllowedTeams(balance);
1340                 TeamBalance_Destroy(balance);
1341                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1342         }
1343         else
1344         {
1345                 stuffcmd(this, "set _teams_available 0\n");
1346         }
1347
1348         bot_relinkplayerlist();
1349
1350         CS(this).spectatortime = time;
1351         if (blockSpectators)
1352         {
1353                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1354         }
1355
1356         CS(this).jointime = time;
1357
1358         if (IS_REAL_CLIENT(this))
1359         {
1360                 if (g_weaponarena_weapons == WEPSET(TUBA))
1361                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1362         }
1363
1364         if (!sv_foginterval && world.fog != "")
1365                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1366
1367         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1368                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1369                         send_CSQC_teamnagger();
1370
1371         CSQCMODEL_AUTOINIT(this);
1372
1373         CS(this).model_randomizer = random();
1374
1375         if (IS_REAL_CLIENT(this))
1376                 sv_notice_join(this);
1377
1378         // update physics stats (players can spawn before physics runs)
1379         Physics_UpdateStats(this);
1380
1381         IL_EACH(g_initforplayer, it.init_for_player, {
1382                 it.init_for_player(it, this);
1383         });
1384
1385         Handicap_Initialize(this);
1386
1387         MUTATOR_CALLHOOK(ClientConnect, this);
1388
1389         if (IS_REAL_CLIENT(this))
1390         {
1391                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1392                 {
1393                         CS(this).motd_actived_time = -1;
1394                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1395                 }
1396         }
1397 }
1398 /*
1399 =============
1400 ClientDisconnect
1401
1402 Called when a client disconnects from the server
1403 =============
1404 */
1405 .entity chatbubbleentity;
1406 void ReadyCount();
1407 void ClientDisconnect(entity this)
1408 {
1409         assert(IS_CLIENT(this), return);
1410
1411         PlayerStats_GameReport_FinalizePlayer(this);
1412         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1413         if (CS(this).active_minigame) part_minigame(this);
1414         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1415
1416         if (autocvar_sv_eventlog)
1417                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1418
1419         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1420
1421         if(IS_SPEC(this))
1422                 SetSpectatee(this, NULL);
1423
1424     MUTATOR_CALLHOOK(ClientDisconnect, this);
1425
1426         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1427         if (CS(this).weaponorder_byimpulse) strunzone(CS(this).weaponorder_byimpulse);
1428         ClientState_detach(this);
1429
1430         Portal_ClearAll(this);
1431
1432         Unfreeze(this);
1433
1434         RemoveGrapplingHooks(this);
1435
1436         // Here, everything has been done that requires this player to be a client.
1437
1438         this.flags &= ~FL_CLIENT;
1439
1440         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1441         if (this.killindicator) delete(this.killindicator);
1442
1443         WaypointSprite_PlayerGone(this);
1444
1445         bot_relinkplayerlist();
1446
1447         if (this.clientstatus) strunzone(this.clientstatus);
1448         if (this.personal) delete(this.personal);
1449
1450         this.playerid = 0;
1451         ReadyCount();
1452         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1453
1454         ONREMOVE(this);
1455 }
1456
1457 void ChatBubbleThink(entity this)
1458 {
1459         this.nextthink = time;
1460         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1461         {
1462                 if(this.owner) // but why can that ever be NULL?
1463                         this.owner.chatbubbleentity = NULL;
1464                 delete(this);
1465                 return;
1466         }
1467
1468         this.mdl = "";
1469
1470         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1471         {
1472                 if ( CS(this.owner).active_minigame )
1473                         this.mdl = "models/sprites/minigame_busy.iqm";
1474                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1475                         this.mdl = "models/misc/chatbubble.spr";
1476         }
1477
1478         if ( this.model != this.mdl )
1479                 _setmodel(this, this.mdl);
1480
1481 }
1482
1483 void UpdateChatBubble(entity this)
1484 {
1485         if (this.alpha < 0)
1486                 return;
1487         // spawn a chatbubble entity if needed
1488         if (!this.chatbubbleentity)
1489         {
1490                 this.chatbubbleentity = new(chatbubbleentity);
1491                 this.chatbubbleentity.owner = this;
1492                 this.chatbubbleentity.exteriormodeltoclient = this;
1493                 setthink(this.chatbubbleentity, ChatBubbleThink);
1494                 this.chatbubbleentity.nextthink = time;
1495                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1496                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1497                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1498                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1499                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1500                 //this.chatbubbleentity.model = "";
1501                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1502         }
1503 }
1504
1505
1506 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1507 // added to the model skins
1508 /*void UpdateColorModHack()
1509 {
1510         float c;
1511         c = this.clientcolors & 15;
1512         // LordHavoc: only bothering to support white, green, red, yellow, blue
1513              if (!teamplay) this.colormod = '0 0 0';
1514         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1515         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1516         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1517         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1518         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1519         else this.colormod = '1 1 1';
1520 }*/
1521
1522 void respawn(entity this)
1523 {
1524         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1525         {
1526                 this.solid = SOLID_NOT;
1527                 this.takedamage = DAMAGE_NO;
1528                 set_movetype(this, MOVETYPE_FLY);
1529                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1530                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1531                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1532                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1533                 if(autocvar_g_respawn_ghosts_maxtime)
1534                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1535         }
1536
1537         CopyBody(this, 1);
1538
1539         this.effects |= EF_NODRAW; // prevent another CopyBody
1540         PutClientInServer(this);
1541 }
1542
1543 void play_countdown(entity this, float finished, Sound samp)
1544 {
1545     TC(Sound, samp);
1546         if(IS_REAL_CLIENT(this))
1547                 if(floor(finished - time - frametime) != floor(finished - time))
1548                         if(finished - time < 6)
1549                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1550 }
1551
1552 void player_powerups(entity this)
1553 {
1554         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1555         int items_prev = this.items;
1556
1557         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1558                 this.modelflags |= MF_ROCKET;
1559         else
1560                 this.modelflags &= ~MF_ROCKET;
1561
1562         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1563
1564         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1565                 return;
1566
1567         Fire_ApplyDamage(this);
1568         Fire_ApplyEffect(this);
1569
1570         if (!g_instagib)
1571         {
1572                 if (this.items & ITEM_Strength.m_itemid)
1573                 {
1574                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1575                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1576                         if (time > this.strength_finished)
1577                         {
1578                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1579                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1580                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1581                         }
1582                 }
1583                 else
1584                 {
1585                         if (time < this.strength_finished)
1586                         {
1587                                 this.items = this.items | ITEM_Strength.m_itemid;
1588                                 if(!g_cts)
1589                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1590                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1591                         }
1592                 }
1593                 if (this.items & ITEM_Shield.m_itemid)
1594                 {
1595                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1596                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1597                         if (time > this.invincible_finished)
1598                         {
1599                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1600                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1601                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1602                         }
1603                 }
1604                 else
1605                 {
1606                         if (time < this.invincible_finished)
1607                         {
1608                                 this.items = this.items | ITEM_Shield.m_itemid;
1609                                 if(!g_cts)
1610                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1611                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1612                         }
1613                 }
1614                 if (this.items & IT_SUPERWEAPON)
1615                 {
1616                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1617                         {
1618                                 this.superweapons_finished = 0;
1619                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1620                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1621                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1622                         }
1623                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1624                         {
1625                                 // don't let them run out
1626                         }
1627                         else
1628                         {
1629                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1630                                 if (time > this.superweapons_finished)
1631                                 {
1632                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1633                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1634                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1635                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1636                                 }
1637                         }
1638                 }
1639                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1640                 {
1641                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1642                         {
1643                                 this.items = this.items | IT_SUPERWEAPON;
1644                                 if(!g_cts)
1645                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1646                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1647                         }
1648                         else
1649                         {
1650                                 this.superweapons_finished = 0;
1651                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1652                         }
1653                 }
1654                 else
1655                 {
1656                         this.superweapons_finished = 0;
1657                 }
1658         }
1659
1660         if(autocvar_g_nodepthtestplayers)
1661                 this.effects = this.effects | EF_NODEPTHTEST;
1662
1663         if(autocvar_g_fullbrightplayers)
1664                 this.effects = this.effects | EF_FULLBRIGHT;
1665
1666         if (time >= game_starttime)
1667         if (time < this.spawnshieldtime)
1668                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1669
1670         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1671 }
1672
1673 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1674 {
1675         if(current > stable)
1676                 return current;
1677         else if(current > stable - 0.25) // when close enough, "snap"
1678                 return stable;
1679         else
1680                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1681 }
1682
1683 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1684 {
1685         if(current < stable)
1686                 return current;
1687         else if(current < stable + 0.25) // when close enough, "snap"
1688                 return stable;
1689         else
1690                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1691 }
1692
1693 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1694 {
1695         if(current > rotstable)
1696         {
1697                 if(rotframetime > 0)
1698                 {
1699                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1700                         current = max(rotstable, current - rotlinear * rotframetime);
1701                 }
1702         }
1703         else if(current < regenstable)
1704         {
1705                 if(regenframetime > 0)
1706                 {
1707                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1708                         current = min(regenstable, current + regenlinear * regenframetime);
1709                 }
1710         }
1711
1712         if(current > limit)
1713                 current = limit;
1714
1715         return current;
1716 }
1717
1718 void player_regen(entity this)
1719 {
1720         float max_mod, regen_mod, rot_mod, limit_mod;
1721         max_mod = regen_mod = rot_mod = limit_mod = 1;
1722
1723         float regen_health = autocvar_g_balance_health_regen;
1724         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1725         float regen_health_rot = autocvar_g_balance_health_rot;
1726         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1727         float regen_health_stable = autocvar_g_balance_health_regenstable;
1728         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1729         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1730                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1731         max_mod = M_ARGV(1, float);
1732         regen_mod = M_ARGV(2, float);
1733         rot_mod = M_ARGV(3, float);
1734         limit_mod = M_ARGV(4, float);
1735         regen_health = M_ARGV(5, float);
1736         regen_health_linear = M_ARGV(6, float);
1737         regen_health_rot = M_ARGV(7, float);
1738         regen_health_rotlinear = M_ARGV(8, float);
1739         regen_health_stable = M_ARGV(9, float);
1740         regen_health_rotstable = M_ARGV(10, float);
1741
1742         if(!mutator_returnvalue)
1743         if(!STAT(FROZEN, this))
1744         {
1745                 float mina, maxa, limith, limita;
1746                 maxa = autocvar_g_balance_armor_rotstable;
1747                 mina = autocvar_g_balance_armor_regenstable;
1748                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1749                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1750
1751                 regen_health_rotstable = regen_health_rotstable * max_mod;
1752                 regen_health_stable = regen_health_stable * max_mod;
1753                 limith = limith * limit_mod;
1754                 limita = limita * limit_mod;
1755
1756                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1757                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1758         }
1759
1760         // if player rotted to death...  die!
1761         // check this outside above checks, as player may still be able to rot to death
1762         if(this.health < 1)
1763         {
1764                 if(this.vehicle)
1765                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1766                 if(this.event_damage)
1767                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1768         }
1769
1770         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1771         {
1772                 float minf, maxf, limitf;
1773
1774                 maxf = autocvar_g_balance_fuel_rotstable;
1775                 minf = autocvar_g_balance_fuel_regenstable;
1776                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1777
1778                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1779         }
1780         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1781         // TODO: Remove this hack when all code uses GivePlayerHealth and
1782         // GivePlayerArmor.
1783         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1784         {
1785                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1786         }
1787         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1788         {
1789                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1790         }
1791         // End hack.
1792 }
1793
1794 bool zoomstate_set;
1795 void SetZoomState(entity this, float newzoom)
1796 {
1797         if(newzoom != CS(this).zoomstate)
1798         {
1799                 CS(this).zoomstate = newzoom;
1800                 ClientData_Touch(this);
1801         }
1802         zoomstate_set = true;
1803 }
1804
1805 void GetPressedKeys(entity this)
1806 {
1807         MUTATOR_CALLHOOK(GetPressedKeys, this);
1808         int keys = STAT(PRESSED_KEYS, this);
1809         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1810         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1811         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1812         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1813
1814         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1815         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1816         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1817         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1818         CS(this).pressedkeys = keys; // store for other users
1819
1820         STAT(PRESSED_KEYS, this) = keys;
1821 }
1822
1823 /*
1824 ======================
1825 spectate mode routines
1826 ======================
1827 */
1828
1829 void SpectateCopy(entity this, entity spectatee)
1830 {
1831     TC(Client, this); TC(Client, spectatee);
1832
1833         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1834         PS(this) = PS(spectatee);
1835         this.armortype = spectatee.armortype;
1836         this.armorvalue = spectatee.armorvalue;
1837         this.ammo_cells = spectatee.ammo_cells;
1838         this.ammo_plasma = spectatee.ammo_plasma;
1839         this.ammo_shells = spectatee.ammo_shells;
1840         this.ammo_nails = spectatee.ammo_nails;
1841         this.ammo_rockets = spectatee.ammo_rockets;
1842         this.ammo_fuel = spectatee.ammo_fuel;
1843         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1844         this.health = spectatee.health;
1845         CS(this).impulse = 0;
1846         this.items = spectatee.items;
1847         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1848         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1849         this.strength_finished = spectatee.strength_finished;
1850         this.invincible_finished = spectatee.invincible_finished;
1851         this.superweapons_finished = spectatee.superweapons_finished;
1852         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1853         this.weapons = spectatee.weapons;
1854         this.punchangle = spectatee.punchangle;
1855         this.view_ofs = spectatee.view_ofs;
1856         this.velocity = spectatee.velocity;
1857         this.dmg_take = spectatee.dmg_take;
1858         this.dmg_save = spectatee.dmg_save;
1859         this.dmg_inflictor = spectatee.dmg_inflictor;
1860         this.v_angle = spectatee.v_angle;
1861         this.angles = spectatee.v_angle;
1862         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1863         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1864         this.viewloc = spectatee.viewloc;
1865         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1866                 this.fixangle = true;
1867         setorigin(this, spectatee.origin);
1868         setsize(this, spectatee.mins, spectatee.maxs);
1869         SetZoomState(this, CS(spectatee).zoomstate);
1870
1871     anticheat_spectatecopy(this, spectatee);
1872         STAT(HUD, this) = STAT(HUD, spectatee);
1873         if(spectatee.vehicle)
1874     {
1875         this.angles = spectatee.v_angle;
1876
1877         //this.fixangle = false;
1878         //this.velocity = spectatee.vehicle.velocity;
1879         this.vehicle_health = spectatee.vehicle_health;
1880         this.vehicle_shield = spectatee.vehicle_shield;
1881         this.vehicle_energy = spectatee.vehicle_energy;
1882         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1883         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1884         this.vehicle_reload1 = spectatee.vehicle_reload1;
1885         this.vehicle_reload2 = spectatee.vehicle_reload2;
1886
1887         //msg_entity = this;
1888
1889        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1890             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1891            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1892            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1893
1894         //WriteByte (MSG_ONE, SVC_SETVIEW);
1895         //    WriteEntity(MSG_ONE, this);
1896         //makevectors(spectatee.v_angle);
1897         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1898     }
1899 }
1900
1901 bool SpectateUpdate(entity this)
1902 {
1903         if(!this.enemy)
1904                 return false;
1905
1906         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1907         {
1908                 SetSpectatee(this, NULL);
1909                 return false;
1910         }
1911
1912         SpectateCopy(this, this.enemy);
1913
1914         return true;
1915 }
1916
1917 bool SpectateSet(entity this)
1918 {
1919         if(!IS_PLAYER(this.enemy))
1920                 return false;
1921
1922         ClientData_Touch(this.enemy);
1923
1924         msg_entity = this;
1925         WriteByte(MSG_ONE, SVC_SETVIEW);
1926         WriteEntity(MSG_ONE, this.enemy);
1927         set_movetype(this, MOVETYPE_NONE);
1928         accuracy_resend(this);
1929
1930         if(!SpectateUpdate(this))
1931                 PutObserverInServer(this);
1932
1933         return true;
1934 }
1935
1936 void SetSpectatee_status(entity this, int spectatee_num)
1937 {
1938         int oldspectatee_status = CS(this).spectatee_status;
1939         CS(this).spectatee_status = spectatee_num;
1940
1941         if (CS(this).spectatee_status != oldspectatee_status)
1942         {
1943                 ClientData_Touch(this);
1944                 if (g_race || g_cts) race_InitSpectator();
1945         }
1946 }
1947
1948 void SetSpectatee(entity this, entity spectatee)
1949 {
1950         if(IS_BOT_CLIENT(this))
1951                 return; // bots abuse .enemy, this code is useless to them
1952
1953         entity old_spectatee = this.enemy;
1954
1955         this.enemy = spectatee;
1956
1957         // WEAPONTODO
1958         // these are required to fix the spectator bug with arc
1959         if(old_spectatee)
1960         {
1961                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1962                 {
1963                         .entity weaponentity = weaponentities[slot];
1964                         if(old_spectatee.(weaponentity).arc_beam)
1965                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1966                 }
1967         }
1968         if(this.enemy)
1969         {
1970                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1971                 {
1972                         .entity weaponentity = weaponentities[slot];
1973                         if(this.enemy.(weaponentity).arc_beam)
1974                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1975                 }
1976         }
1977
1978         if (this.enemy)
1979                 SetSpectatee_status(this, etof(this.enemy));
1980
1981         // needed to update spectator list
1982         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1983 }
1984
1985 bool Spectate(entity this, entity pl)
1986 {
1987         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1988                 return false;
1989         pl = M_ARGV(1, entity);
1990
1991         SetSpectatee(this, pl);
1992         return SpectateSet(this);
1993 }
1994
1995 bool SpectateNext(entity this)
1996 {
1997         entity ent = find(this.enemy, classname, STR_PLAYER);
1998
1999         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2000                 ent = M_ARGV(1, entity);
2001         else if (!ent)
2002                 ent = find(ent, classname, STR_PLAYER);
2003
2004         if(ent) { SetSpectatee(this, ent); }
2005
2006         return SpectateSet(this);
2007 }
2008
2009 bool SpectatePrev(entity this)
2010 {
2011         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2012         entity ent = findchain(classname, STR_PLAYER);
2013         if (!ent) // no player
2014                 return false;
2015
2016         entity first = ent;
2017         // skip players until current spectated player
2018         if(this.enemy)
2019         while(ent && ent != this.enemy)
2020                 ent = ent.chain;
2021
2022         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2023         {
2024                 case MUT_SPECPREV_FOUND:
2025                     ent = M_ARGV(1, entity);
2026                     break;
2027                 case MUT_SPECPREV_RETURN:
2028                     return true;
2029                 case MUT_SPECPREV_CONTINUE:
2030                 default:
2031                 {
2032                         if(ent.chain)
2033                                 ent = ent.chain;
2034                         else
2035                                 ent = first;
2036                         break;
2037                 }
2038         }
2039
2040         SetSpectatee(this, ent);
2041         return SpectateSet(this);
2042 }
2043
2044 /*
2045 =============
2046 ShowRespawnCountdown()
2047
2048 Update a respawn countdown display.
2049 =============
2050 */
2051 void ShowRespawnCountdown(entity this)
2052 {
2053         float number;
2054         if(!IS_DEAD(this)) // just respawned?
2055                 return;
2056         else
2057         {
2058                 number = ceil(this.respawn_time - time);
2059                 if(number <= 0)
2060                         return;
2061                 if(number <= this.respawn_countdown)
2062                 {
2063                         this.respawn_countdown = number - 1;
2064                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2065                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2066                 }
2067         }
2068 }
2069
2070 .bool team_selected;
2071 bool ShowTeamSelection(entity this)
2072 {
2073         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2074                 return false;
2075         stuffcmd(this, "menu_showteamselect\n");
2076         return true;
2077 }
2078 void Join(entity this)
2079 {
2080         TRANSMUTE(Player, this);
2081
2082         if(!this.team_selected)
2083         if(autocvar_g_campaign || autocvar_g_balance_teams)
2084                 TeamBalance_JoinBestTeam(this, true);
2085
2086         if(autocvar_g_campaign)
2087                 campaign_bots_may_start = true;
2088
2089         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2090
2091         PutClientInServer(this);
2092
2093         if(IS_PLAYER(this))
2094         if(teamplay && this.team != -1)
2095                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2096         else
2097                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2098         this.team_selected = false;
2099 }
2100
2101 /**
2102  * Determines whether the player is allowed to join. This depends on cvar
2103  * g_maxplayers, if it isn't used this function always return true, otherwise
2104  * it checks whether the number of currently playing players exceeds g_maxplayers.
2105  * @return int number of free slots for players, 0 if none
2106  */
2107 int nJoinAllowed(entity this, entity ignore)
2108 {
2109         if(!ignore)
2110         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2111         // so report 0 free slots if restricted
2112         {
2113                 if(autocvar_g_forced_team_otherwise == "spectate")
2114                         return 0;
2115                 if(autocvar_g_forced_team_otherwise == "spectator")
2116                         return 0;
2117         }
2118
2119         if(this && this.team_forced < 0)
2120                 return 0; // forced spectators can never join
2121
2122         // TODO simplify this
2123         int totalClients = 0;
2124         int currentlyPlaying = 0;
2125         FOREACH_CLIENT(true, {
2126                 if(it != ignore)
2127                         ++totalClients;
2128                 if(IS_REAL_CLIENT(it))
2129                 if(IS_PLAYER(it) || it.caplayer)
2130                         ++currentlyPlaying;
2131         });
2132
2133         float free_slots = 0;
2134         if (!autocvar_g_maxplayers)
2135                 free_slots = maxclients - totalClients;
2136         else if(currentlyPlaying < autocvar_g_maxplayers)
2137                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2138
2139         static float join_prevent_msg_time = 0;
2140         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2141         {
2142                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2143                 join_prevent_msg_time = time + 3;
2144         }
2145
2146         return free_slots;
2147 }
2148
2149 /**
2150  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2151  * g_maxplayers_spectator_blocktime seconds
2152  */
2153 void checkSpectatorBlock(entity this)
2154 {
2155         if(IS_SPEC(this) || IS_OBSERVER(this))
2156         if(!this.caplayer)
2157         if(IS_REAL_CLIENT(this))
2158         {
2159                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2160                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2161                         dropclient(this);
2162                 }
2163         }
2164 }
2165
2166 void PrintWelcomeMessage(entity this)
2167 {
2168         if(CS(this).motd_actived_time == 0)
2169         {
2170                 if (autocvar_g_campaign) {
2171                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2172                                 CS(this).motd_actived_time = time;
2173                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2174                         }
2175                 } else {
2176                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2177                                 CS(this).motd_actived_time = time;
2178                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2179                         }
2180                 }
2181         }
2182         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2183         {
2184                 if (autocvar_g_campaign) {
2185                         if (PHYS_INPUT_BUTTON_INFO(this))
2186                                 CS(this).motd_actived_time = time;
2187                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2188                                 CS(this).motd_actived_time = 0;
2189                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2190                         }
2191                 } else {
2192                         if (PHYS_INPUT_BUTTON_INFO(this))
2193                                 CS(this).motd_actived_time = time;
2194                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2195                                 CS(this).motd_actived_time = 0;
2196                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2197                         }
2198                 }
2199         }
2200         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2201         {
2202                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2203                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2204                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2205                 {
2206                         // instanctly hide MOTD
2207                         CS(this).motd_actived_time = 0;
2208                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2209                 }
2210         }
2211 }
2212
2213 bool joinAllowed(entity this)
2214 {
2215         if (CS(this).version_mismatch) return false;
2216         if (!nJoinAllowed(this, this)) return false;
2217         if (teamplay && lockteams) return false;
2218         if (ShowTeamSelection(this)) return false;
2219         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2220         return true;
2221 }
2222
2223 .int items_added;
2224 .string shootfromfixedorigin;
2225 bool PlayerThink(entity this)
2226 {
2227         if (game_stopped || intermission_running) {
2228                 this.modelflags &= ~MF_ROCKET;
2229                 if(intermission_running)
2230                         IntermissionThink(this);
2231                 return false;
2232         }
2233
2234         if (timeout_status == TIMEOUT_ACTIVE) {
2235         // don't allow the player to turn around while game is paused
2236                 // FIXME turn this into CSQC stuff
2237                 this.v_angle = this.lastV_angle;
2238                 this.angles = this.lastV_angle;
2239                 this.fixangle = true;
2240         }
2241
2242         if (frametime) player_powerups(this);
2243
2244         if (IS_DEAD(this)) {
2245                 if (this.personal && g_race_qualifying) {
2246                         if (time > this.respawn_time) {
2247                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2248                                 respawn(this);
2249                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2250                         }
2251                 } else {
2252                         if (frametime) player_anim(this);
2253
2254                         if (this.respawn_flags & RESPAWN_DENY)
2255                         {
2256                                 STAT(RESPAWN_TIME, this) = 0;
2257                                 return false;
2258                         }
2259
2260                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2261
2262                         switch(this.deadflag)
2263                         {
2264                                 case DEAD_DYING:
2265                                 {
2266                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2267                                                 this.deadflag = DEAD_RESPAWNING;
2268                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2269                                                 this.deadflag = DEAD_DEAD;
2270                                         break;
2271                                 }
2272                                 case DEAD_DEAD:
2273                                 {
2274                                         if (button_pressed)
2275                                                 this.deadflag = DEAD_RESPAWNABLE;
2276                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2277                                                 this.deadflag = DEAD_RESPAWNING;
2278                                         break;
2279                                 }
2280                                 case DEAD_RESPAWNABLE:
2281                                 {
2282                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2283                                                 this.deadflag = DEAD_RESPAWNING;
2284                                         break;
2285                                 }
2286                                 case DEAD_RESPAWNING:
2287                                 {
2288                                         if (time > this.respawn_time)
2289                                         {
2290                                                 this.respawn_time = time + 1; // only retry once a second
2291                                                 this.respawn_time_max = this.respawn_time;
2292                                                 respawn(this);
2293                                         }
2294                                         break;
2295                                 }
2296                         }
2297
2298                         ShowRespawnCountdown(this);
2299
2300                         if (this.respawn_flags & RESPAWN_SILENT)
2301                                 STAT(RESPAWN_TIME, this) = 0;
2302                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2303                         {
2304                                 if (time < this.respawn_time)
2305                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2306                                 else if (this.deadflag != DEAD_RESPAWNING)
2307                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2308                         }
2309                         else
2310                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2311                 }
2312
2313                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2314                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2315                         STAT(RESPAWN_TIME, this) *= -1;
2316
2317                 return false;
2318         }
2319
2320         bool have_hook = false;
2321         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2322         {
2323                 .entity weaponentity = weaponentities[slot];
2324                 if(this.(weaponentity).hook.state)
2325                 {
2326                         have_hook = true;
2327                         break;
2328                 }
2329         }
2330         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2331         if (have_hook) {
2332                 do_crouch = false;
2333         //} else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2334                 //do_crouch = false;
2335         } else if (this.vehicle) {
2336                 do_crouch = false;
2337         } else if (STAT(FROZEN, this)) {
2338                 do_crouch = false;
2339     }
2340
2341         if (do_crouch) {
2342                 if (!this.crouch) {
2343                         this.crouch = true;
2344                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2345                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2346                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2347                 }
2348         } else if (this.crouch) {
2349         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2350         if (!trace_startsolid) {
2351             this.crouch = false;
2352             this.view_ofs = STAT(PL_VIEW_OFS, this);
2353             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2354         }
2355         }
2356
2357         FixPlayermodel(this);
2358
2359         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2360                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2361                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2362         }
2363
2364         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2365         //if(frametime)
2366         {
2367                 this.items &= ~this.items_added;
2368
2369                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2370                 {
2371                         .entity weaponentity = weaponentities[slot];
2372                         W_WeaponFrame(this, weaponentity);
2373                 }
2374
2375                 this.items_added = 0;
2376                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2377             this.items_added |= IT_FUEL;
2378
2379                 this.items |= this.items_added;
2380         }
2381
2382         player_regen(this);
2383
2384         // WEAPONTODO: Add a weapon request for this
2385         // rot vortex charge to the charge limit
2386         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2387         {
2388                 .entity weaponentity = weaponentities[slot];
2389                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2390                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2391         }
2392
2393         if (frametime) player_anim(this);
2394
2395         // secret status
2396         secrets_setstatus(this);
2397
2398         // monsters status
2399         monsters_setstatus(this);
2400
2401         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2402
2403         return true;
2404 }
2405
2406 void ObserverThink(entity this)
2407 {
2408         if ( CS(this).impulse )
2409         {
2410                 MinigameImpulse(this, CS(this).impulse);
2411                 CS(this).impulse = 0;
2412         }
2413
2414         if (this.flags & FL_JUMPRELEASED) {
2415                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2416                         this.flags &= ~FL_JUMPRELEASED;
2417                         this.flags |= FL_SPAWNING;
2418                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2419                         this.flags &= ~FL_JUMPRELEASED;
2420                         if(SpectateNext(this)) {
2421                                 TRANSMUTE(Spectator, this);
2422                         }
2423                 } else {
2424                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2425                         set_movetype(this, preferred_movetype);
2426                 }
2427         } else {
2428                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2429                         this.flags |= FL_JUMPRELEASED;
2430                         if(this.flags & FL_SPAWNING)
2431                         {
2432                                 this.flags &= ~FL_SPAWNING;
2433                                 Join(this);
2434                                 return;
2435                         }
2436                 }
2437         }
2438 }
2439
2440 void SpectatorThink(entity this)
2441 {
2442         if ( CS(this).impulse )
2443         {
2444                 if(MinigameImpulse(this, CS(this).impulse))
2445                         CS(this).impulse = 0;
2446
2447                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2448                 {
2449                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2450                         CS(this).impulse = 0;
2451                         return;
2452                 }
2453         }
2454
2455         if (this.flags & FL_JUMPRELEASED) {
2456                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2457                         this.flags &= ~FL_JUMPRELEASED;
2458                         this.flags |= FL_SPAWNING;
2459                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2460                         this.flags &= ~FL_JUMPRELEASED;
2461                         if(SpectateNext(this)) {
2462                                 TRANSMUTE(Spectator, this);
2463                         } else {
2464                                 TRANSMUTE(Observer, this);
2465                                 PutClientInServer(this);
2466                         }
2467                         CS(this).impulse = 0;
2468                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2469                         this.flags &= ~FL_JUMPRELEASED;
2470                         if(SpectatePrev(this)) {
2471                                 TRANSMUTE(Spectator, this);
2472                         } else {
2473                                 TRANSMUTE(Observer, this);
2474                                 PutClientInServer(this);
2475                         }
2476                         CS(this).impulse = 0;
2477                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2478                         this.flags &= ~FL_JUMPRELEASED;
2479                         TRANSMUTE(Observer, this);
2480                         PutClientInServer(this);
2481                 } else {
2482                         if(!SpectateUpdate(this))
2483                                 PutObserverInServer(this);
2484                 }
2485         } else {
2486                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2487                         this.flags |= FL_JUMPRELEASED;
2488                         if(this.flags & FL_SPAWNING)
2489                         {
2490                                 this.flags &= ~FL_SPAWNING;
2491                                 Join(this);
2492                                 return;
2493                         }
2494                 }
2495                 if(!SpectateUpdate(this))
2496                         PutObserverInServer(this);
2497         }
2498
2499         this.flags |= FL_CLIENT | FL_NOTARGET;
2500 }
2501
2502 void vehicles_enter (entity pl, entity veh);
2503 void PlayerUseKey(entity this)
2504 {
2505         if (!IS_PLAYER(this))
2506                 return;
2507
2508         if(this.vehicle)
2509         {
2510                 if(!game_stopped)
2511                 {
2512                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2513                         return;
2514                 }
2515         }
2516         else if(autocvar_g_vehicles_enter)
2517         {
2518                 if(!STAT(FROZEN, this))
2519                 if(!IS_DEAD(this))
2520                 if(!game_stopped)
2521                 {
2522                         entity head, closest_target = NULL;
2523                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2524
2525                         while(head) // find the closest acceptable target to enter
2526                         {
2527                                 if(IS_VEHICLE(head))
2528                                 if(!IS_DEAD(head))
2529                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2530                                 if(head.takedamage != DAMAGE_NO)
2531                                 {
2532                                         if(closest_target)
2533                                         {
2534                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2535                                                 { closest_target = head; }
2536                                         }
2537                                         else { closest_target = head; }
2538                                 }
2539
2540                                 head = head.chain;
2541                         }
2542
2543                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2544                 }
2545         }
2546
2547         // a use key was pressed; call handlers
2548         MUTATOR_CALLHOOK(PlayerUseKey, this);
2549 }
2550
2551
2552 /*
2553 =============
2554 PlayerPreThink
2555
2556 Called every frame for each client before the physics are run
2557 =============
2558 */
2559 .float last_vehiclecheck;
2560 void PlayerPreThink (entity this)
2561 {
2562         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2563         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2564
2565         WarpZone_PlayerPhysics_FixVAngle(this);
2566
2567         if (frametime) {
2568                 // physics frames: update anticheat stuff
2569                 anticheat_prethink(this);
2570         }
2571
2572         if (blockSpectators && frametime) {
2573                 // WORKAROUND: only use dropclient in server frames (frametime set).
2574                 // Never use it in cl_movement frames (frametime zero).
2575                 checkSpectatorBlock(this);
2576         }
2577
2578         zoomstate_set = false;
2579
2580         // Check for nameless players
2581         if (this.netname == "" || this.netname != CS(this).netname_previous)
2582         {
2583                 bool assume_unchanged = (CS(this).netname_previous == "");
2584                 if (isInvisibleString(this.netname))
2585                 {
2586                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2587                         assume_unchanged = false;
2588                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2589                 }
2590                 if (!assume_unchanged && autocvar_sv_eventlog)
2591                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2592                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2593                 CS(this).netname_previous = strzone(this.netname);
2594         }
2595
2596         // version nagging
2597         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2598         CS(this).version_nagtime = 0;
2599         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2600             // git client
2601         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2602             // git server
2603             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2604         } else {
2605             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2606             if (r < 0) { // old client
2607                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2608             } else if (r > 0) { // old server
2609                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2610             }
2611         }
2612     }
2613
2614         // GOD MODE info
2615         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2616         {
2617                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2618                 this.max_armorvalue = 0;
2619         }
2620
2621         if(IS_PLAYER(this))
2622         {
2623                 if (STAT(FROZEN, this) == 2)
2624                 {
2625                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2626                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2627                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2628
2629                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2630                                 Unfreeze(this);
2631                 }
2632                 else if (STAT(FROZEN, this) == 3)
2633                 {
2634                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2635                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2636
2637                         if (this.health < 1)
2638                         {
2639                                 if (this.vehicle)
2640                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2641                                 if(this.event_damage)
2642                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2643                         }
2644                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2645                                 Unfreeze(this);
2646                 }
2647         }
2648
2649         MUTATOR_CALLHOOK(PlayerPreThink, this);
2650
2651         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2652         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2653         {
2654                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2655                 {
2656                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2657                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2658                         {
2659                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2660                         }
2661                         else if(!it.owner)
2662                         {
2663                                 if(!it.team || SAME_TEAM(this, it))
2664                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2665                                 else if(autocvar_g_vehicles_steal)
2666                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2667                         }
2668                 });
2669
2670                 this.last_vehiclecheck = time + 1;
2671         }
2672
2673         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2674         {
2675                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2676                         PlayerUseKey(this);
2677                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2678         }
2679
2680         if (IS_REAL_CLIENT(this))
2681                 PrintWelcomeMessage(this);
2682
2683         if (IS_PLAYER(this)) {
2684                 if(!PlayerThink(this))
2685                         return;
2686         }
2687         else if (game_stopped || intermission_running) {
2688                 if(intermission_running)
2689                         IntermissionThink(this);
2690                 return;
2691         }
2692         else if (IS_OBSERVER(this)) {
2693                 ObserverThink(this);
2694         }
2695         else if (IS_SPEC(this)) {
2696                 SpectatorThink(this);
2697         }
2698
2699         // WEAPONTODO: Add weapon request for this
2700         if (!zoomstate_set) {
2701                 bool wep_zoomed = false;
2702                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2703                 {
2704                         .entity weaponentity = weaponentities[slot];
2705                         Weapon thiswep = this.(weaponentity).m_weapon;
2706                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2707                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2708                 }
2709                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2710     }
2711
2712         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2713         {
2714                 CS(this).teamkill_soundtime = 0;
2715
2716                 entity e = CS(this).teamkill_soundsource;
2717                 entity oldpusher = e.pusher;
2718                 e.pusher = this;
2719                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2720                 e.pusher = oldpusher;
2721         }
2722
2723         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2724                 CS(this).taunt_soundtime = 0;
2725                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2726         }
2727
2728         target_voicescript_next(this);
2729
2730         // WEAPONTODO: Move into weaponsystem somehow
2731         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2732         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2733         {
2734                 .entity weaponentity = weaponentities[slot];
2735                 if(this.(weaponentity).m_weapon == WEP_Null)
2736                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2737         }
2738 }
2739
2740 void DrownPlayer(entity this)
2741 {
2742         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2743                 return;
2744
2745         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2746         {
2747                 if(this.air_finished < time)
2748                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2749                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2750         }
2751         else if (this.air_finished < time)
2752         {       // drown!
2753                 if (this.pain_finished < time)
2754                 {
2755                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2756                         this.pain_finished = time + 0.5;
2757                 }
2758         }
2759 }
2760
2761 .bool move_qcphysics;
2762
2763 void Player_Physics(entity this)
2764 {
2765         set_movetype(this, this.move_movetype);
2766
2767         if(!this.move_qcphysics)
2768                 return;
2769
2770         if(!frametime && !CS(this).pm_frametime)
2771                 return;
2772
2773         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2774
2775         CS(this).pm_frametime = 0;
2776 }
2777
2778 /*
2779 =============
2780 PlayerPostThink
2781
2782 Called every frame for each client after the physics are run
2783 =============
2784 */
2785 void PlayerPostThink (entity this)
2786 {
2787         Player_Physics(this);
2788
2789         if (sv_maxidle > 0)
2790         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2791         if (IS_REAL_CLIENT(this))
2792         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2793         {
2794                 int totalClients = 0;
2795                 if(sv_maxidle_slots > 0)
2796                 {
2797                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2798                         {
2799                                 ++totalClients;
2800                         });
2801                 }
2802
2803                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2804                 { /* do nothing */ }
2805                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2806                 {
2807                         if (CS(this).idlekick_lasttimeleft)
2808                         {
2809                                 CS(this).idlekick_lasttimeleft = 0;
2810                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2811                         }
2812                 }
2813                 else
2814                 {
2815                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2816                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2817                                 if (!CS(this).idlekick_lasttimeleft)
2818                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2819                         }
2820                         if (timeleft <= 0) {
2821                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2822                                 dropclient(this);
2823                                 return;
2824                         }
2825                         else if (timeleft <= 10) {
2826                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2827                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2828                 }
2829                                 CS(this).idlekick_lasttimeleft = timeleft;
2830                         }
2831                 }
2832         }
2833
2834         CheatFrame(this);
2835
2836         if (game_stopped)
2837         {
2838                 this.solid = SOLID_NOT;
2839                 this.takedamage = DAMAGE_NO;
2840                 set_movetype(this, MOVETYPE_NONE);
2841         }
2842
2843         if (IS_PLAYER(this)) {
2844                 if(this.death_time == time && IS_DEAD(this))
2845                 {
2846                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2847                         // once all the damage events of this frame have been processed with normal size
2848                         this.maxs.z = 5;
2849                         setsize(this, this.mins, this.maxs);
2850                 }
2851                 DrownPlayer(this);
2852                 UpdateChatBubble(this);
2853                 if (CS(this).impulse) ImpulseCommands(this);
2854                 if (game_stopped)
2855                 {
2856                         CSQCMODEL_AUTOUPDATE(this);
2857                         return;
2858                 }
2859                 GetPressedKeys(this);
2860         }
2861
2862         if (this.waypointsprite_attachedforcarrier) {
2863             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2864                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2865     }
2866
2867         playerdemo_write(this);
2868
2869         CSQCMODEL_AUTOUPDATE(this);
2870 }
2871
2872 // hack to copy the button fields from the client entity to the Client State
2873 void PM_UpdateButtons(entity this, entity store)
2874 {
2875         if(this.impulse)
2876                 store.impulse = this.impulse;
2877         this.impulse = 0;
2878
2879         bool typing = this.buttonchat;
2880
2881         store.button0 = (typing) ? 0 : this.button0;
2882         //button1?!
2883         store.button2 = (typing) ? 0 : this.button2;
2884         store.button3 = (typing) ? 0 : this.button3;
2885         store.button4 = this.button4;
2886         store.button5 = (typing) ? 0 : this.button5;
2887         store.button6 = this.button6;
2888         store.button7 = this.button7;
2889         store.button8 = this.button8;
2890         store.button9 = this.button9;
2891         store.button10 = this.button10;
2892         store.button11 = this.button11;
2893         store.button12 = this.button12;
2894         store.button13 = this.button13;
2895         store.button14 = this.button14;
2896         store.button15 = this.button15;
2897         store.button16 = this.button16;
2898         store.buttonuse = this.buttonuse;
2899         store.buttonchat = this.buttonchat;
2900
2901         store.cursor_active = this.cursor_active;
2902         store.cursor_screen = this.cursor_screen;
2903         store.cursor_trace_start = this.cursor_trace_start;
2904         store.cursor_trace_endpos = this.cursor_trace_endpos;
2905         store.cursor_trace_ent = this.cursor_trace_ent;
2906
2907         store.ping = this.ping;
2908         store.ping_packetloss = this.ping_packetloss;
2909         store.ping_movementloss = this.ping_movementloss;
2910
2911         store.v_angle = this.v_angle;
2912         store.movement = (typing) ? '0 0 0' : this.movement;
2913 }
2914
2915 NET_HANDLE(fpsreport, bool)
2916 {
2917         int fps = ReadShort();
2918         PlayerScore_Set(sender, SP_FPS, fps);
2919         return true;
2920 }