qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 STATIC_METHOD(Client, Add, void(Client this, int _team))
  66 {
  67     ClientConnect(this);
  68     TRANSMUTE(Player, this);
  69     this.frame = 12; // 7
  70     this.team = _team;
  71     PutClientInServer(this);
  72 }
  73
  74 void PutObserverInServer(entity this);
  75
  76 STATIC_METHOD(Client, Remove, void(Client this))
  77 {
  78     TRANSMUTE(Observer, this);
  79     PutClientInServer(this);
  80     ClientDisconnect(this);
  81 }
  82
  83 void send_CSQC_teamnagger() {
  84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  85 }
  86
  87 int CountSpectators(entity player, entity to)
  88 {
  89         if(!player) { return 0; } // not sure how, but best to be safe
  90
  91         int spec_count = 0;
  92
  93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  94         {
  95                 spec_count++;
  96         });
  97
  98         return spec_count;
  99 }
 100
 101 void WriteSpectators(entity player, entity to)
 102 {
 103         if(!player) { return; } // not sure how, but best to be safe
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 WriteByte(MSG_ENTITY, num_for_edict(it));
 108         });
 109 }
 110
 111 bool ClientData_Send(entity this, entity to, int sf)
 112 {
 113         assert(to == this.owner, return false);
 114
 115         entity e = to;
 116         if (IS_SPEC(e)) e = e.enemy;
 117
 118         sf = 0;
 119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 123
 124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 125         WriteByte(MSG_ENTITY, sf);
 126
 127         if (sf & BIT(1))
 128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 129
 130         if(sf & BIT(4))
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         CS(this).clientdata.drawonlytoclient = this;
 144         CS(this).clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(CS(this).clientdata);
 150         CS(this).clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         CS(e).clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 159 }
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this))
 225         {
 226                 if(this.health >= 1)
 227                 {
 228                         // despawn effect
 229                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230                 }
 231
 232                 // was a player, recount votes and ready status
 233                 if(IS_REAL_CLIENT(this))
 234                 {
 235                         if (vote_called) { VoteCount(false); }
 236                         ReadyCount();
 237                 }
 238     }
 239
 240     {
 241         entity spot = SelectSpawnPoint(this, true);
 242         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 243         this.angles = vec2(spot.angles);
 244         this.fixangle = true;
 245         // offset it so that the spectator spawns higher off the ground, looks better this way
 246         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 247         if (IS_REAL_CLIENT(this))
 248         {
 249             msg_entity = this;
 250             WriteByte(MSG_ONE, SVC_SETVIEW);
 251             WriteEntity(MSG_ONE, this);
 252         }
 253         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 254         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 255         if(!autocvar_g_debug_globalsounds)
 256         {
 257                 // needed for player sounds
 258                 this.model = "";
 259                 FixPlayermodel(this);
 260         }
 261         setmodel(this, MDL_Null);
 262         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 263         this.view_ofs = '0 0 0';
 264     }
 265
 266     RemoveGrapplingHooks(this);
 267         Portal_ClearAll(this);
 268         Unfreeze(this);
 269         SetSpectatee(this, NULL);
 270
 271         if (this.alivetime)
 272         {
 273                 if (!warmup_stage)
 274                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 275                 this.alivetime = 0;
 276         }
 277
 278         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 279
 280         WaypointSprite_PlayerDead(this);
 281
 282         if (mutator_returnvalue) {
 283             // mutator prevents resetting teams+score
 284         } else {
 285                 Player_SetTeamIndex(this, -1);
 286                 this.frags = FRAGS_SPECTATOR;
 287         PlayerScore_Clear(this);  // clear scores when needed
 288     }
 289
 290         if (CS(this).killcount != FRAGS_SPECTATOR)
 291         {
 292                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 293                 if(!game_stopped)
 294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 296
 297                 if(!CS(this).just_joined)
 298                         LogTeamchange(this.playerid, -1, TEAM_CHANGE_SPECTATOR);
 299                 else
 300                         CS(this).just_joined = false;
 301         }
 302
 303         accuracy_resend(this);
 304
 305         CS(this).spectatortime = time;
 306         if(this.bot_attack)
 307                 IL_REMOVE(g_bot_targets, this);
 308         this.bot_attack = false;
 309         if(this.monster_attack)
 310                 IL_REMOVE(g_monster_targets, this);
 311         this.monster_attack = false;
 312     STAT(HUD, this) = HUD_NORMAL;
 313         TRANSMUTE(Observer, this);
 314         this.iscreature = false;
 315         this.teleportable = TELEPORT_SIMPLE;
 316         if(this.damagedbycontents)
 317                 IL_REMOVE(g_damagedbycontents, this);
 318         this.damagedbycontents = false;
 319         this.health = FRAGS_SPECTATOR;
 320         SetSpectatee_status(this, etof(this));
 321         this.takedamage = DAMAGE_NO;
 322         this.solid = SOLID_NOT;
 323         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 324         this.flags = FL_CLIENT | FL_NOTARGET;
 325         this.armorvalue = 666;
 326         this.effects = 0;
 327         this.armorvalue = autocvar_g_balance_armor_start;
 328         this.pauserotarmor_finished = 0;
 329         this.pauserothealth_finished = 0;
 330         this.pauseregen_finished = 0;
 331         this.damageforcescale = 0;
 332         this.death_time = 0;
 333         this.respawn_flags = 0;
 334         this.respawn_time = 0;
 335         STAT(RESPAWN_TIME, this) = 0;
 336         this.alpha = 0;
 337         this.scale = 0;
 338         this.fade_time = 0;
 339         this.pain_frame = 0;
 340         this.pain_finished = 0;
 341         this.strength_finished = 0;
 342         this.invincible_finished = 0;
 343         this.superweapons_finished = 0;
 344         this.dphitcontentsmask = 0;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         this.crouch = false;
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353
 354         this.items = 0;
 355         this.weapons = '0 0 0';
 356         this.drawonlytoclient = this;
 357
 358         this.viewloc = NULL;
 359
 360         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 361
 362         this.weaponmodel = "";
 363         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 364         {
 365                 this.weaponentities[slot] = NULL;
 366         }
 367         this.exteriorweaponentity = NULL;
 368         CS(this).killcount = FRAGS_SPECTATOR;
 369         this.velocity = '0 0 0';
 370         this.avelocity = '0 0 0';
 371         this.punchangle = '0 0 0';
 372         this.punchvector = '0 0 0';
 373         this.oldvelocity = this.velocity;
 374         this.fire_endtime = -1;
 375         this.event_damage = func_null;
 376
 377         for(int slot = 0; slot < MAX_AXH; ++slot)
 378         {
 379                 entity axh = this.(AuxiliaryXhair[slot]);
 380                 this.(AuxiliaryXhair[slot]) = NULL;
 381
 382                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 383                         delete(axh);
 384         }
 385 }
 386
 387 int player_getspecies(entity this)
 388 {
 389         get_model_parameters(this.model, this.skin);
 390         int s = get_model_parameters_species;
 391         get_model_parameters(string_null, 0);
 392         if (s < 0) return SPECIES_HUMAN;
 393         return s;
 394 }
 395
 396 .float model_randomizer;
 397 void FixPlayermodel(entity player)
 398 {
 399         string defaultmodel = "";
 400         int defaultskin = 0;
 401         if(autocvar_sv_defaultcharacter)
 402         {
 403                 if(teamplay)
 404                 {
 405                         switch(player.team)
 406                         {
 407                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 408                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 409                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 410                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 411                         }
 412                 }
 413
 414                 if(defaultmodel == "")
 415                 {
 416                         defaultmodel = autocvar_sv_defaultplayermodel;
 417                         defaultskin = autocvar_sv_defaultplayerskin;
 418                 }
 419
 420                 int n = tokenize_console(defaultmodel);
 421                 if(n > 0)
 422                 {
 423                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 424                         // However, do NOT randomize if the player-selected model is in the list.
 425                         for (int i = 0; i < n; ++i)
 426                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 427                                         defaultmodel = argv(i);
 428                 }
 429
 430                 int i = strstrofs(defaultmodel, ":", 0);
 431                 if(i >= 0)
 432                 {
 433                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 434                         defaultmodel = substring(defaultmodel, 0, i);
 435                 }
 436         }
 437         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 438         {
 439                 if(teamplay)
 440                 {
 441                         switch(player.team)
 442                         {
 443                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 444                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 445                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 446                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 447                         }
 448                 }
 449
 450                 if(!defaultskin)
 451                         defaultskin = autocvar_sv_defaultplayerskin;
 452         }
 453
 454         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 455         defaultmodel = M_ARGV(0, string);
 456         defaultskin = M_ARGV(1, int);
 457
 458         bool chmdl = false;
 459         int oldskin;
 460         if(defaultmodel != "")
 461         {
 462                 if (defaultmodel != player.model)
 463                 {
 464                         vector m1 = player.mins;
 465                         vector m2 = player.maxs;
 466                         setplayermodel (player, defaultmodel);
 467                         setsize (player, m1, m2);
 468                         chmdl = true;
 469                 }
 470
 471                 oldskin = player.skin;
 472                 player.skin = defaultskin;
 473         } else {
 474                 if (player.playermodel != player.model || player.playermodel == "")
 475                 {
 476                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 477                         vector m1 = player.mins;
 478                         vector m2 = player.maxs;
 479                         setplayermodel (player, player.playermodel);
 480                         setsize (player, m1, m2);
 481                         chmdl = true;
 482                 }
 483
 484                 if(!autocvar_sv_defaultcharacterskin)
 485                 {
 486                         oldskin = player.skin;
 487                         player.skin = stof(player.playerskin);
 488                 }
 489                 else
 490                 {
 491                         oldskin = player.skin;
 492                         player.skin = defaultskin;
 493                 }
 494         }
 495
 496         if(chmdl || oldskin != player.skin) // model or skin has changed
 497         {
 498                 player.species = player_getspecies(player); // update species
 499                 if(!autocvar_g_debug_globalsounds)
 500                         UpdatePlayerSounds(player); // update skin sounds
 501         }
 502
 503         if(!teamplay)
 504                 if(strlen(autocvar_sv_defaultplayercolors))
 505                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 506                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 507 }
 508
 509 void PutPlayerInServer(entity this)
 510 {
 511         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 512
 513         PlayerState_attach(this);
 514         accuracy_resend(this);
 515
 516         if (this.team < 0)
 517                 TeamBalance_JoinBestTeam(this, true);
 518
 519         entity spot = SelectSpawnPoint(this, false);
 520         if (!spot) {
 521                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 522                 return; // spawn failed
 523         }
 524
 525         TRANSMUTE(Player, this);
 526
 527         CS(this).wasplayer = true;
 528         this.iscreature = true;
 529         this.teleportable = TELEPORT_NORMAL;
 530         if(!this.damagedbycontents)
 531                 IL_PUSH(g_damagedbycontents, this);
 532         this.damagedbycontents = true;
 533         set_movetype(this, MOVETYPE_WALK);
 534         this.solid = SOLID_SLIDEBOX;
 535         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 536         if (autocvar_g_playerclip_collisions)
 537                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 538         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 539                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 540         this.frags = FRAGS_PLAYER;
 541         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 542         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 543         if (autocvar__notarget)
 544                 this.flags |= FL_NOTARGET;
 545         this.takedamage = DAMAGE_AIM;
 546         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 547
 548         if (warmup_stage) {
 549                 this.ammo_shells = warmup_start_ammo_shells;
 550                 this.ammo_nails = warmup_start_ammo_nails;
 551                 this.ammo_rockets = warmup_start_ammo_rockets;
 552                 this.ammo_cells = warmup_start_ammo_cells;
 553                 this.ammo_plasma = warmup_start_ammo_plasma;
 554                 this.ammo_fuel = warmup_start_ammo_fuel;
 555                 this.health = warmup_start_health;
 556                 this.armorvalue = warmup_start_armorvalue;
 557                 this.weapons = WARMUP_START_WEAPONS;
 558         } else {
 559                 this.ammo_shells = start_ammo_shells;
 560                 this.ammo_nails = start_ammo_nails;
 561                 this.ammo_rockets = start_ammo_rockets;
 562                 this.ammo_cells = start_ammo_cells;
 563                 this.ammo_plasma = start_ammo_plasma;
 564                 this.ammo_fuel = start_ammo_fuel;
 565                 this.health = start_health;
 566                 this.armorvalue = start_armorvalue;
 567                 this.weapons = start_weapons;
 568                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 569                 {
 570                         GiveRandomWeapons(this, random_start_weapons_count,
 571                                 autocvar_g_random_start_weapons, random_start_ammo);
 572                 }
 573         }
 574         SetSpectatee_status(this, 0);
 575
 576         PS(this).dual_weapons = '0 0 0';
 577
 578         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 579
 580         this.items = start_items;
 581
 582         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 583         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 584         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 585         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 586         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 587         if (!sv_ready_restart_after_countdown && time < game_starttime)
 588         {
 589                 float f = game_starttime - time;
 590                 this.spawnshieldtime += f;
 591                 this.pauserotarmor_finished += f;
 592                 this.pauserothealth_finished += f;
 593                 this.pauseregen_finished += f;
 594         }
 595
 596         this.damageforcescale = 2;
 597         this.death_time = 0;
 598         this.respawn_flags = 0;
 599         this.respawn_time = 0;
 600         STAT(RESPAWN_TIME, this) = 0;
 601         this.scale = autocvar_sv_player_scale;
 602         this.fade_time = 0;
 603         this.pain_frame = 0;
 604         this.pain_finished = 0;
 605         this.pushltime = 0;
 606         setthink(this, func_null); // players have no think function
 607         this.nextthink = 0;
 608         this.dmg_team = 0;
 609         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 610
 611         this.deadflag = DEAD_NO;
 612
 613         this.angles = spot.angles;
 614         this.angles_z = 0; // never spawn tilted even if the spot says to
 615         if (IS_BOT_CLIENT(this))
 616                 this.v_angle = this.angles;
 617         this.fixangle = true; // turn this way immediately
 618         this.oldvelocity = this.velocity = '0 0 0';
 619         this.avelocity = '0 0 0';
 620         this.punchangle = '0 0 0';
 621         this.punchvector = '0 0 0';
 622
 623         this.strength_finished = 0;
 624         this.invincible_finished = 0;
 625         this.fire_endtime = -1;
 626         STAT(REVIVE_PROGRESS, this) = 0;
 627         this.revival_time = 0;
 628
 629         this.air_finished = time + 12;
 630         this.waterlevel = WATERLEVEL_NONE;
 631         this.watertype = CONTENT_EMPTY;
 632
 633         entity spawnevent = new_pure(spawnevent);
 634         spawnevent.owner = this;
 635         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 636
 637         // Cut off any still running player sounds.
 638         stopsound(this, CH_PLAYER_SINGLE);
 639
 640         this.model = "";
 641         FixPlayermodel(this);
 642         this.drawonlytoclient = NULL;
 643
 644         this.viewloc = NULL;
 645
 646         for(int slot = 0; slot < MAX_AXH; ++slot)
 647         {
 648                 entity axh = this.(AuxiliaryXhair[slot]);
 649                 this.(AuxiliaryXhair[slot]) = NULL;
 650
 651                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 652                         delete(axh);
 653         }
 654
 655         this.spawnpoint_targ = NULL;
 656
 657         this.crouch = false;
 658         this.view_ofs = STAT(PL_VIEW_OFS, this);
 659         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 660         this.spawnorigin = spot.origin;
 661         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 662         // don't reset back to last position, even if new position is stuck in solid
 663         this.oldorigin = this.origin;
 664         if(this.conveyor)
 665                 IL_REMOVE(g_conveyed, this);
 666         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 667         STAT(HUD, this) = HUD_NORMAL;
 668
 669         this.event_damage = PlayerDamage;
 670
 671         if(!this.bot_attack)
 672                 IL_PUSH(g_bot_targets, this);
 673         this.bot_attack = true;
 674         if(!this.monster_attack)
 675                 IL_PUSH(g_monster_targets, this);
 676         this.monster_attack = true;
 677         navigation_dynamicgoal_init(this, false);
 678
 679         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 680
 681         // player was spectator
 682         if (CS(this).killcount == FRAGS_SPECTATOR) {
 683                 PlayerScore_Clear(this);
 684                 CS(this).killcount = 0;
 685                 CS(this).startplaytime = time;
 686         }
 687
 688         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 689         {
 690                 .entity weaponentity = weaponentities[slot];
 691                 entity oldwep = this.(weaponentity);
 692                 CL_SpawnWeaponentity(this, weaponentity);
 693                 if(oldwep && oldwep.owner == this)
 694                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 695         }
 696         this.alpha = default_player_alpha;
 697         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 698         this.exteriorweaponentity.alpha = default_weapon_alpha;
 699
 700         this.speedrunning = false;
 701
 702         target_voicescript_clear(this);
 703
 704         // reset fields the weapons may use
 705         FOREACH(Weapons, true, {
 706                 it.wr_resetplayer(it, this);
 707                         // reload all reloadable weapons
 708                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 709                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 710                         {
 711                                 .entity weaponentity = weaponentities[slot];
 712                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 713                         }
 714                 }
 715         });
 716
 717         {
 718                 string s = spot.target;
 719                 spot.target = string_null;
 720                 SUB_UseTargets(spot, this, NULL);
 721                 spot.target = s;
 722         }
 723
 724         Unfreeze(this);
 725
 726         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 727
 728         if (autocvar_spawn_debug)
 729         {
 730                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 731                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 732         }
 733
 734         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 735         {
 736                 .entity weaponentity = weaponentities[slot];
 737                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 738                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 739                 else
 740                         this.(weaponentity).m_switchweapon = WEP_Null;
 741                 this.(weaponentity).m_weapon = WEP_Null;
 742                 this.(weaponentity).weaponname = "";
 743                 this.(weaponentity).m_switchingweapon = WEP_Null;
 744                 this.(weaponentity).cnt = -1;
 745         }
 746
 747         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 748
 749         if (!warmup_stage && !this.alivetime)
 750                 this.alivetime = time;
 751
 752         antilag_clear(this, CS(this));
 753 }
 754
 755 /** Called when a client spawns in the server */
 756 void PutClientInServer(entity this)
 757 {
 758         if (IS_BOT_CLIENT(this)) {
 759                 TRANSMUTE(Player, this);
 760         } else if (IS_REAL_CLIENT(this)) {
 761                 msg_entity = this;
 762                 WriteByte(MSG_ONE, SVC_SETVIEW);
 763                 WriteEntity(MSG_ONE, this);
 764         }
 765         if (game_stopped)
 766                 TRANSMUTE(Observer, this);
 767
 768         SetSpectatee(this, NULL);
 769
 770         // reset player keys
 771         if(PS(this))
 772                 PS(this).itemkeys = 0;
 773
 774         MUTATOR_CALLHOOK(PutClientInServer, this);
 775
 776         if (IS_OBSERVER(this)) {
 777                 PutObserverInServer(this);
 778         } else if (IS_PLAYER(this)) {
 779                 PutPlayerInServer(this);
 780         }
 781 }
 782
 783 void ClientInit_misc(entity this);
 784
 785 // TODO do we need all these fields, or should we stop autodetecting runtime
 786 // changes and just have a console command to update this?
 787 bool ClientInit_SendEntity(entity this, entity to, int sf)
 788 {
 789         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 790         return = true;
 791         msg_entity = to;
 792         // MSG_INIT replacement
 793         // TODO: make easier to use
 794         Registry_send_all();
 795         W_PROP_reload(MSG_ONE, to);
 796         ClientInit_misc(this);
 797         MUTATOR_CALLHOOK(Ent_Init);
 798 }
 799 void ClientInit_misc(entity this)
 800 {
 801         int channel = MSG_ONE;
 802         WriteHeader(channel, ENT_CLIENT_INIT);
 803         WriteByte(channel, g_nexball_meter_period * 32);
 804         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 805         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 806         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 807         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 808         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 809         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 810         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 811         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 812
 813         if(sv_foginterval && world.fog != "")
 814                 WriteString(channel, world.fog);
 815         else
 816                 WriteString(channel, "");
 817         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 818         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 819         WriteByte(channel, serverflags);
 820         WriteCoord(channel, autocvar_g_trueaim_minrange);
 821 }
 822
 823 void ClientInit_CheckUpdate(entity this)
 824 {
 825         this.nextthink = time;
 826         if(this.count != autocvar_g_balance_armor_blockpercent)
 827         {
 828                 this.count = autocvar_g_balance_armor_blockpercent;
 829                 this.SendFlags |= 1;
 830         }
 831         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 832         {
 833                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 834                 this.SendFlags |= 1;
 835         }
 836 }
 837
 838 void ClientInit_Spawn()
 839 {
 840         entity e = new_pure(clientinit);
 841         setthink(e, ClientInit_CheckUpdate);
 842         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 843
 844         ClientInit_CheckUpdate(e);
 845 }
 846
 847 /*
 848 =============
 849 SetNewParms
 850 =============
 851 */
 852 void SetNewParms ()
 853 {
 854         // initialize parms for a new player
 855         parm1 = -(86400 * 366);
 856
 857         MUTATOR_CALLHOOK(SetNewParms);
 858 }
 859
 860 /*
 861 =============
 862 SetChangeParms
 863 =============
 864 */
 865 void SetChangeParms (entity this)
 866 {
 867         // save parms for level change
 868         parm1 = CS(this).parm_idlesince - time;
 869
 870         MUTATOR_CALLHOOK(SetChangeParms);
 871 }
 872
 873 /*
 874 =============
 875 DecodeLevelParms
 876 =============
 877 */
 878 void DecodeLevelParms(entity this)
 879 {
 880         // load parms
 881         CS(this).parm_idlesince = parm1;
 882         if (CS(this).parm_idlesince == -(86400 * 366))
 883                 CS(this).parm_idlesince = time;
 884
 885         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 886         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 887
 888         MUTATOR_CALLHOOK(DecodeLevelParms);
 889 }
 890
 891 /*
 892 =============
 893 ClientKill
 894
 895 Called when a client types 'kill' in the console
 896 =============
 897 */
 898
 899 .float clientkill_nexttime;
 900 void ClientKill_Now_TeamChange(entity this)
 901 {
 902         if(this.killindicator_teamchange == -1)
 903         {
 904                 TeamBalance_JoinBestTeam(this, true);
 905         }
 906         else if(this.killindicator_teamchange == -2)
 907         {
 908                 if(blockSpectators)
 909                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 910                 PutObserverInServer(this);
 911         }
 912         else
 913                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 914         this.killindicator_teamchange = 0;
 915 }
 916
 917 void ClientKill_Now(entity this)
 918 {
 919         if(this.vehicle)
 920         {
 921             vehicles_exit(this.vehicle, VHEF_RELEASE);
 922             if(!this.killindicator_teamchange)
 923             {
 924             this.vehicle_health = -1;
 925             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 926             }
 927         }
 928
 929         if(this.killindicator && !wasfreed(this.killindicator))
 930                 delete(this.killindicator);
 931
 932         this.killindicator = NULL;
 933
 934         if(this.killindicator_teamchange)
 935                 ClientKill_Now_TeamChange(this);
 936
 937         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 938         {
 939                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 940         }
 941
 942         // now I am sure the player IS dead
 943 }
 944 void KillIndicator_Think(entity this)
 945 {
 946         if (game_stopped)
 947         {
 948                 this.owner.killindicator = NULL;
 949                 delete(this);
 950                 return;
 951         }
 952
 953         if (this.owner.alpha < 0 && !this.owner.vehicle)
 954         {
 955                 this.owner.killindicator = NULL;
 956                 delete(this);
 957                 return;
 958         }
 959
 960         if(this.cnt <= 0)
 961         {
 962                 ClientKill_Now(this.owner);
 963                 return;
 964         }
 965     else if(this.health == 1) // health == 1 means that it's silent
 966     {
 967         this.nextthink = time + 1;
 968         this.cnt -= 1;
 969     }
 970         else
 971         {
 972                 if(this.cnt <= 10)
 973                         setmodel(this, MDL_NUM(this.cnt));
 974                 if(IS_REAL_CLIENT(this.owner))
 975                 {
 976                         if(this.cnt <= 10)
 977                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 978                 }
 979                 this.nextthink = time + 1;
 980                 this.cnt -= 1;
 981         }
 982 }
 983
 984 float clientkilltime;
 985 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 986 {
 987         float killtime;
 988         float starttime;
 989
 990         if (game_stopped)
 991                 return;
 992
 993         killtime = autocvar_g_balance_kill_delay;
 994
 995     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 996         return;
 997     killtime = M_ARGV(1, float);
 998
 999         this.killindicator_teamchange = targetteam;
1000
1001     if(!this.killindicator)
1002         {
1003                 if(!IS_DEAD(this))
1004                 {
1005                         killtime = max(killtime, this.clientkill_nexttime - time);
1006                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1007                 }
1008
1009                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1010                 {
1011                         ClientKill_Now(this);
1012                 }
1013                 else
1014                 {
1015                         starttime = max(time, clientkilltime);
1016
1017                         this.killindicator = spawn();
1018                         this.killindicator.owner = this;
1019                         this.killindicator.scale = 0.5;
1020                         setattachment(this.killindicator, this, "");
1021                         setorigin(this.killindicator, '0 0 52');
1022                         setthink(this.killindicator, KillIndicator_Think);
1023                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1024                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1025                         this.killindicator.cnt = ceil(killtime);
1026                         this.killindicator.count = bound(0, ceil(killtime), 10);
1027                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1028
1029                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1030                         {
1031                                 it.killindicator = spawn();
1032                                 it.killindicator.owner = it;
1033                                 it.killindicator.scale = 0.5;
1034                                 setattachment(it.killindicator, it, "");
1035                                 setorigin(it.killindicator, '0 0 52');
1036                                 setthink(it.killindicator, KillIndicator_Think);
1037                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1038                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1039                                 it.killindicator.cnt = ceil(killtime);
1040                         });
1041                         this.lip = 0;
1042                 }
1043         }
1044         if(this.killindicator)
1045         {
1046                 if(targetteam == 0) // just die
1047                 {
1048                         this.killindicator.colormod = '0 0 0';
1049                         if(IS_REAL_CLIENT(this))
1050                         if(this.killindicator.cnt > 0)
1051                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1052                 }
1053                 else if(targetteam == -1) // auto
1054                 {
1055                         this.killindicator.colormod = '0 1 0';
1056                         if(IS_REAL_CLIENT(this))
1057                         if(this.killindicator.cnt > 0)
1058                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1059                 }
1060                 else if(targetteam == -2) // spectate
1061                 {
1062                         this.killindicator.colormod = '0.5 0.5 0.5';
1063                         if(IS_REAL_CLIENT(this))
1064                         if(this.killindicator.cnt > 0)
1065                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1066                 }
1067                 else
1068                 {
1069                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1070                         if(IS_REAL_CLIENT(this))
1071                         if(this.killindicator.cnt > 0)
1072                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1073                 }
1074         }
1075
1076 }
1077
1078 void ClientKill (entity this)
1079 {
1080         if(game_stopped) return;
1081         if(this.player_blocked) return;
1082         if(STAT(FROZEN, this)) return;
1083
1084         ClientKill_TeamChange(this, 0);
1085 }
1086
1087 void FixClientCvars(entity e)
1088 {
1089         // send prediction settings to the client
1090         stuffcmd(e, "\nin_bindmap 0 0\n");
1091         if(autocvar_g_antilag == 3) // client side hitscan
1092                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1093         if(autocvar_sv_gentle)
1094                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1095
1096         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1097         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1098
1099         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1100
1101         MUTATOR_CALLHOOK(FixClientCvars, e);
1102 }
1103
1104 bool findinlist_abbrev(string tofind, string list)
1105 {
1106         if(list == "" || tofind == "")
1107                 return false; // empty list or search, just return
1108
1109         // this function allows abbreviated strings!
1110         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1111         {
1112                 return true;
1113         });
1114
1115         return false;
1116 }
1117
1118 bool PlayerInIPList(entity p, string iplist)
1119 {
1120         // some safety checks (never allow local?)
1121         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1122                 return false;
1123
1124         return findinlist_abbrev(p.netaddress, iplist);
1125 }
1126
1127 bool PlayerInIDList(entity p, string idlist)
1128 {
1129         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1130         if(!p.crypto_idfp)
1131                 return false;
1132
1133         return findinlist_abbrev(p.crypto_idfp, idlist);
1134 }
1135
1136 bool PlayerInList(entity player, string list)
1137 {
1138         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1139 }
1140
1141 #ifdef DP_EXT_PRECONNECT
1142 /*
1143 =============
1144 ClientPreConnect
1145
1146 Called once (not at each match start) when a client begins a connection to the server
1147 =============
1148 */
1149 void ClientPreConnect(entity this)
1150 {
1151         if(autocvar_sv_eventlog)
1152         {
1153                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1154                         this.playerid,
1155                         etof(this),
1156                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1157                 ));
1158         }
1159 }
1160 #endif
1161
1162 string GetClientVersionMessage(entity this)
1163 {
1164         if (CS(this).version_mismatch) {
1165                 if(CS(this).version < autocvar_gameversion) {
1166                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1167                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1168                 } else {
1169                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1170                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1171                 }
1172         } else {
1173                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1174         }
1175 }
1176
1177 string getwelcomemessage(entity this)
1178 {
1179         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1180         string modifications = M_ARGV(0, string);
1181
1182         if(g_weaponarena)
1183         {
1184                 if(g_weaponarena_random)
1185                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1186                 else
1187                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1188         }
1189         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1190                 modifications = strcat(modifications, ", No start weapons");
1191         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1192                 modifications = strcat(modifications, ", Low gravity");
1193         if(g_weapon_stay && !g_cts)
1194                 modifications = strcat(modifications, ", Weapons stay");
1195         if(g_jetpack)
1196                 modifications = strcat(modifications, ", Jet pack");
1197         if(autocvar_g_powerups == 0)
1198                 modifications = strcat(modifications, ", No powerups");
1199         if(autocvar_g_powerups > 0)
1200                 modifications = strcat(modifications, ", Powerups");
1201         modifications = substring(modifications, 2, strlen(modifications) - 2);
1202
1203         string versionmessage = GetClientVersionMessage(this);
1204         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1205
1206         if(modifications != "")
1207                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1208
1209         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1210         {
1211                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1212                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1213         }
1214
1215         if (cache_mutatormsg != "") {
1216                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1217         }
1218
1219         string mutator_msg = "";
1220         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1221         mutator_msg = M_ARGV(0, string);
1222
1223         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1224
1225         string motd = autocvar_sv_motd;
1226         if (motd != "") {
1227                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1228         }
1229         return s;
1230 }
1231
1232 /**
1233 =============
1234 ClientConnect
1235
1236 Called when a client connects to the server
1237 =============
1238 */
1239 void ClientConnect(entity this)
1240 {
1241         if (Ban_MaybeEnforceBanOnce(this)) return;
1242         assert(!IS_CLIENT(this), return);
1243         this.flags |= FL_CLIENT;
1244         assert(player_count >= 0, player_count = 0);
1245
1246 #ifdef WATERMARK
1247         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1248 #endif
1249         TRANSMUTE(Client, this);
1250         CS(this).version_nagtime = time + 10 + random() * 10;
1251
1252         // identify the right forced team
1253         if (autocvar_g_campaign)
1254         {
1255                 if (IS_REAL_CLIENT(this)) // only players, not bots
1256                 {
1257                         switch (autocvar_g_campaign_forceteam)
1258                         {
1259                                 case 1: this.team_forced = NUM_TEAM_1; break;
1260                                 case 2: this.team_forced = NUM_TEAM_2; break;
1261                                 case 3: this.team_forced = NUM_TEAM_3; break;
1262                                 case 4: this.team_forced = NUM_TEAM_4; break;
1263                                 default: this.team_forced = 0;
1264                         }
1265                 }
1266         }
1267         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1268         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1269         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1270         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1271         else switch (autocvar_g_forced_team_otherwise)
1272         {
1273                 default: this.team_forced = 0; break;
1274                 case "red": this.team_forced = NUM_TEAM_1; break;
1275                 case "blue": this.team_forced = NUM_TEAM_2; break;
1276                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1277                 case "pink": this.team_forced = NUM_TEAM_4; break;
1278                 case "spectate":
1279                 case "spectator":
1280                         this.team_forced = -1;
1281                         break;
1282         }
1283         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1284
1285         int playerid_save = this.playerid;
1286         this.playerid = 0; // silent
1287         TeamBalance_JoinBestTeam(this, false); // if the team number is valid, keep it
1288         this.playerid = playerid_save;
1289
1290         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1291                 TRANSMUTE(Observer, this);
1292         } else {
1293                 if (!teamplay || autocvar_g_balance_teams) {
1294                         TRANSMUTE(Player, this);
1295                         campaign_bots_may_start = true;
1296                 } else {
1297                         TRANSMUTE(Observer, this); // do it anyway
1298                 }
1299         }
1300
1301         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1302
1303         // always track bots, don't ask for cl_allow_uidtracking
1304         if (IS_BOT_CLIENT(this))
1305                 PlayerStats_GameReport_AddPlayer(this);
1306         else
1307                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1308
1309         if (autocvar_sv_eventlog)
1310                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1311
1312         LogTeamchange(this.playerid, this.team, TEAM_CHANGE_CONNECT);
1313
1314         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1315
1316         if(teamplay && IS_PLAYER(this))
1317                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1318         else
1319                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1320
1321         stuffcmd(this, clientstuff, "\n");
1322         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1323
1324         FixClientCvars(this);
1325
1326         // get version info from player
1327         stuffcmd(this, "cmd clientversion $gameversion\n");
1328
1329         // notify about available teams
1330         if (teamplay)
1331         {
1332                 entity balance = TeamBalance_CheckAllowedTeams(this);
1333                 int t = TeamBalance_GetAllowedTeams(balance);
1334                 TeamBalance_Destroy(balance);
1335                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1336         }
1337         else
1338         {
1339                 stuffcmd(this, "set _teams_available 0\n");
1340         }
1341
1342         bot_relinkplayerlist();
1343
1344         CS(this).spectatortime = time;
1345         if (blockSpectators)
1346         {
1347                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1348         }
1349
1350         CS(this).jointime = time;
1351
1352         if (IS_REAL_CLIENT(this))
1353         {
1354                 if (g_weaponarena_weapons == WEPSET(TUBA))
1355                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1356         }
1357
1358         if (!sv_foginterval && world.fog != "")
1359                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1360
1361         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1362                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1363                         send_CSQC_teamnagger();
1364
1365         CSQCMODEL_AUTOINIT(this);
1366
1367         CS(this).model_randomizer = random();
1368
1369         if (IS_REAL_CLIENT(this))
1370                 sv_notice_join(this);
1371
1372         // update physics stats (players can spawn before physics runs)
1373         Physics_UpdateStats(this);
1374
1375         IL_EACH(g_initforplayer, it.init_for_player, {
1376                 it.init_for_player(it, this);
1377         });
1378
1379         Handicap_Initialize(this);
1380
1381         MUTATOR_CALLHOOK(ClientConnect, this);
1382
1383         if (IS_REAL_CLIENT(this))
1384         {
1385                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1386                 {
1387                         CS(this).motd_actived_time = -1;
1388                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1389                 }
1390         }
1391 }
1392 /*
1393 =============
1394 ClientDisconnect
1395
1396 Called when a client disconnects from the server
1397 =============
1398 */
1399 .entity chatbubbleentity;
1400 void ReadyCount();
1401 void ClientDisconnect(entity this)
1402 {
1403         assert(IS_CLIENT(this), return);
1404
1405         PlayerStats_GameReport_FinalizePlayer(this);
1406         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1407         if (CS(this).active_minigame) part_minigame(this);
1408         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1409
1410         if (autocvar_sv_eventlog)
1411                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1412
1413         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1414
1415         if(IS_SPEC(this))
1416                 SetSpectatee(this, NULL);
1417
1418     MUTATOR_CALLHOOK(ClientDisconnect, this);
1419
1420         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1421         strfree(CS(this).weaponorder_byimpulse);
1422         ClientState_detach(this);
1423
1424         Portal_ClearAll(this);
1425
1426         Unfreeze(this);
1427
1428         RemoveGrapplingHooks(this);
1429
1430         // Here, everything has been done that requires this player to be a client.
1431
1432         this.flags &= ~FL_CLIENT;
1433
1434         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1435         if (this.killindicator) delete(this.killindicator);
1436
1437         WaypointSprite_PlayerGone(this);
1438
1439         bot_relinkplayerlist();
1440
1441         strfree(this.clientstatus);
1442         if (this.personal) delete(this.personal);
1443
1444         this.playerid = 0;
1445         ReadyCount();
1446         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1447
1448         ONREMOVE(this);
1449 }
1450
1451 void ChatBubbleThink(entity this)
1452 {
1453         this.nextthink = time;
1454         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1455         {
1456                 if(this.owner) // but why can that ever be NULL?
1457                         this.owner.chatbubbleentity = NULL;
1458                 delete(this);
1459                 return;
1460         }
1461
1462         this.mdl = "";
1463
1464         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1465         {
1466                 if ( CS(this.owner).active_minigame )
1467                         this.mdl = "models/sprites/minigame_busy.iqm";
1468                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1469                         this.mdl = "models/misc/chatbubble.spr";
1470         }
1471
1472         if ( this.model != this.mdl )
1473                 _setmodel(this, this.mdl);
1474
1475 }
1476
1477 void UpdateChatBubble(entity this)
1478 {
1479         if (this.alpha < 0)
1480                 return;
1481         // spawn a chatbubble entity if needed
1482         if (!this.chatbubbleentity)
1483         {
1484                 this.chatbubbleentity = new(chatbubbleentity);
1485                 this.chatbubbleentity.owner = this;
1486                 this.chatbubbleentity.exteriormodeltoclient = this;
1487                 setthink(this.chatbubbleentity, ChatBubbleThink);
1488                 this.chatbubbleentity.nextthink = time;
1489                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1490                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1491                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1492                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1493                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1494                 //this.chatbubbleentity.model = "";
1495                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1496         }
1497 }
1498
1499
1500 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1501 // added to the model skins
1502 /*void UpdateColorModHack()
1503 {
1504         float c;
1505         c = this.clientcolors & 15;
1506         // LordHavoc: only bothering to support white, green, red, yellow, blue
1507              if (!teamplay) this.colormod = '0 0 0';
1508         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1509         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1510         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1511         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1512         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1513         else this.colormod = '1 1 1';
1514 }*/
1515
1516 void respawn(entity this)
1517 {
1518         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1519         {
1520                 this.solid = SOLID_NOT;
1521                 this.takedamage = DAMAGE_NO;
1522                 set_movetype(this, MOVETYPE_FLY);
1523                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1524                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1525                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1526                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1527                 if(autocvar_g_respawn_ghosts_maxtime)
1528                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1529         }
1530
1531         CopyBody(this, 1);
1532
1533         this.effects |= EF_NODRAW; // prevent another CopyBody
1534         PutClientInServer(this);
1535 }
1536
1537 void play_countdown(entity this, float finished, Sound samp)
1538 {
1539     TC(Sound, samp);
1540         if(IS_REAL_CLIENT(this))
1541                 if(floor(finished - time - frametime) != floor(finished - time))
1542                         if(finished - time < 6)
1543                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1544 }
1545
1546 void player_powerups(entity this)
1547 {
1548         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1549         int items_prev = this.items;
1550
1551         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1552                 this.modelflags |= MF_ROCKET;
1553         else
1554                 this.modelflags &= ~MF_ROCKET;
1555
1556         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1557
1558         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1559                 return;
1560
1561         Fire_ApplyDamage(this);
1562         Fire_ApplyEffect(this);
1563
1564         if (!autocvar_g_instagib)
1565         {
1566                 if (this.items & ITEM_Strength.m_itemid)
1567                 {
1568                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1569                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1570                         if (time > this.strength_finished)
1571                         {
1572                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1573                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1574                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1575                         }
1576                 }
1577                 else
1578                 {
1579                         if (time < this.strength_finished)
1580                         {
1581                                 this.items = this.items | ITEM_Strength.m_itemid;
1582                                 if(!g_cts)
1583                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1584                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1585                         }
1586                 }
1587                 if (this.items & ITEM_Shield.m_itemid)
1588                 {
1589                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1590                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1591                         if (time > this.invincible_finished)
1592                         {
1593                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1594                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1595                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1596                         }
1597                 }
1598                 else
1599                 {
1600                         if (time < this.invincible_finished)
1601                         {
1602                                 this.items = this.items | ITEM_Shield.m_itemid;
1603                                 if(!g_cts)
1604                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1605                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1606                         }
1607                 }
1608                 if (this.items & IT_SUPERWEAPON)
1609                 {
1610                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1611                         {
1612                                 this.superweapons_finished = 0;
1613                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1614                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1615                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1616                         }
1617                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1618                         {
1619                                 // don't let them run out
1620                         }
1621                         else
1622                         {
1623                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1624                                 if (time > this.superweapons_finished)
1625                                 {
1626                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1627                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1628                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1629                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1630                                 }
1631                         }
1632                 }
1633                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1634                 {
1635                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1636                         {
1637                                 this.items = this.items | IT_SUPERWEAPON;
1638                                 if(!g_cts)
1639                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1640                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1641                         }
1642                         else
1643                         {
1644                                 this.superweapons_finished = 0;
1645                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1646                         }
1647                 }
1648                 else
1649                 {
1650                         this.superweapons_finished = 0;
1651                 }
1652         }
1653
1654         if(autocvar_g_nodepthtestplayers)
1655                 this.effects = this.effects | EF_NODEPTHTEST;
1656
1657         if(autocvar_g_fullbrightplayers)
1658                 this.effects = this.effects | EF_FULLBRIGHT;
1659
1660         if (time >= game_starttime)
1661         if (time < this.spawnshieldtime)
1662                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1663
1664         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1665 }
1666
1667 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1668 {
1669         if(current > stable)
1670                 return current;
1671         else if(current > stable - 0.25) // when close enough, "snap"
1672                 return stable;
1673         else
1674                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1675 }
1676
1677 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1678 {
1679         if(current < stable)
1680                 return current;
1681         else if(current < stable + 0.25) // when close enough, "snap"
1682                 return stable;
1683         else
1684                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1685 }
1686
1687 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1688 {
1689         if(current > rotstable)
1690         {
1691                 if(rotframetime > 0)
1692                 {
1693                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1694                         current = max(rotstable, current - rotlinear * rotframetime);
1695                 }
1696         }
1697         else if(current < regenstable)
1698         {
1699                 if(regenframetime > 0)
1700                 {
1701                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1702                         current = min(regenstable, current + regenlinear * regenframetime);
1703                 }
1704         }
1705
1706         if(current > limit)
1707                 current = limit;
1708
1709         return current;
1710 }
1711
1712 void player_regen(entity this)
1713 {
1714         float max_mod, regen_mod, rot_mod, limit_mod;
1715         max_mod = regen_mod = rot_mod = limit_mod = 1;
1716
1717         float regen_health = autocvar_g_balance_health_regen;
1718         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1719         float regen_health_rot = autocvar_g_balance_health_rot;
1720         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1721         float regen_health_stable = autocvar_g_balance_health_regenstable;
1722         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1723         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1724                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1725         max_mod = M_ARGV(1, float);
1726         regen_mod = M_ARGV(2, float);
1727         rot_mod = M_ARGV(3, float);
1728         limit_mod = M_ARGV(4, float);
1729         regen_health = M_ARGV(5, float);
1730         regen_health_linear = M_ARGV(6, float);
1731         regen_health_rot = M_ARGV(7, float);
1732         regen_health_rotlinear = M_ARGV(8, float);
1733         regen_health_stable = M_ARGV(9, float);
1734         regen_health_rotstable = M_ARGV(10, float);
1735
1736         if(!mutator_returnvalue)
1737         if(!STAT(FROZEN, this))
1738         {
1739                 float mina, maxa, limith, limita;
1740                 maxa = autocvar_g_balance_armor_rotstable;
1741                 mina = autocvar_g_balance_armor_regenstable;
1742                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1743                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1744
1745                 regen_health_rotstable = regen_health_rotstable * max_mod;
1746                 regen_health_stable = regen_health_stable * max_mod;
1747                 limith = limith * limit_mod;
1748                 limita = limita * limit_mod;
1749
1750                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1751                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1752         }
1753
1754         // if player rotted to death...  die!
1755         // check this outside above checks, as player may still be able to rot to death
1756         if(this.health < 1)
1757         {
1758                 if(this.vehicle)
1759                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1760                 if(this.event_damage)
1761                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1762         }
1763
1764         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1765         {
1766                 float minf, maxf, limitf;
1767
1768                 maxf = autocvar_g_balance_fuel_rotstable;
1769                 minf = autocvar_g_balance_fuel_regenstable;
1770                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1771
1772                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1773         }
1774         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1775         // TODO: Remove this hack when all code uses GivePlayerHealth and
1776         // GivePlayerArmor.
1777         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1778         {
1779                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1780         }
1781         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1782         {
1783                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1784         }
1785         // End hack.
1786 }
1787
1788 bool zoomstate_set;
1789 void SetZoomState(entity this, float newzoom)
1790 {
1791         if(newzoom != CS(this).zoomstate)
1792         {
1793                 CS(this).zoomstate = newzoom;
1794                 ClientData_Touch(this);
1795         }
1796         zoomstate_set = true;
1797 }
1798
1799 void GetPressedKeys(entity this)
1800 {
1801         MUTATOR_CALLHOOK(GetPressedKeys, this);
1802         int keys = STAT(PRESSED_KEYS, this);
1803         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1804         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1805         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1806         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1807
1808         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1809         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1810         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1811         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1812         CS(this).pressedkeys = keys; // store for other users
1813
1814         STAT(PRESSED_KEYS, this) = keys;
1815 }
1816
1817 /*
1818 ======================
1819 spectate mode routines
1820 ======================
1821 */
1822
1823 void SpectateCopy(entity this, entity spectatee)
1824 {
1825     TC(Client, this); TC(Client, spectatee);
1826
1827         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1828         PS(this) = PS(spectatee);
1829         this.armortype = spectatee.armortype;
1830         this.armorvalue = spectatee.armorvalue;
1831         this.ammo_cells = spectatee.ammo_cells;
1832         this.ammo_plasma = spectatee.ammo_plasma;
1833         this.ammo_shells = spectatee.ammo_shells;
1834         this.ammo_nails = spectatee.ammo_nails;
1835         this.ammo_rockets = spectatee.ammo_rockets;
1836         this.ammo_fuel = spectatee.ammo_fuel;
1837         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1838         this.health = spectatee.health;
1839         CS(this).impulse = 0;
1840         this.items = spectatee.items;
1841         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1842         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1843         this.strength_finished = spectatee.strength_finished;
1844         this.invincible_finished = spectatee.invincible_finished;
1845         this.superweapons_finished = spectatee.superweapons_finished;
1846         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1847         this.weapons = spectatee.weapons;
1848         this.punchangle = spectatee.punchangle;
1849         this.view_ofs = spectatee.view_ofs;
1850         this.velocity = spectatee.velocity;
1851         this.dmg_take = spectatee.dmg_take;
1852         this.dmg_save = spectatee.dmg_save;
1853         this.dmg_inflictor = spectatee.dmg_inflictor;
1854         this.v_angle = spectatee.v_angle;
1855         this.angles = spectatee.v_angle;
1856         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1857         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1858         this.viewloc = spectatee.viewloc;
1859         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1860                 this.fixangle = true;
1861         setorigin(this, spectatee.origin);
1862         setsize(this, spectatee.mins, spectatee.maxs);
1863         SetZoomState(this, CS(spectatee).zoomstate);
1864
1865     anticheat_spectatecopy(this, spectatee);
1866         STAT(HUD, this) = STAT(HUD, spectatee);
1867         if(spectatee.vehicle)
1868     {
1869         this.angles = spectatee.v_angle;
1870
1871         //this.fixangle = false;
1872         //this.velocity = spectatee.vehicle.velocity;
1873         this.vehicle_health = spectatee.vehicle_health;
1874         this.vehicle_shield = spectatee.vehicle_shield;
1875         this.vehicle_energy = spectatee.vehicle_energy;
1876         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1877         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1878         this.vehicle_reload1 = spectatee.vehicle_reload1;
1879         this.vehicle_reload2 = spectatee.vehicle_reload2;
1880
1881         //msg_entity = this;
1882
1883        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1884             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1885            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1886            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1887
1888         //WriteByte (MSG_ONE, SVC_SETVIEW);
1889         //    WriteEntity(MSG_ONE, this);
1890         //makevectors(spectatee.v_angle);
1891         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1892     }
1893 }
1894
1895 bool SpectateUpdate(entity this)
1896 {
1897         if(!this.enemy)
1898                 return false;
1899
1900         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1901         {
1902                 SetSpectatee(this, NULL);
1903                 return false;
1904         }
1905
1906         SpectateCopy(this, this.enemy);
1907
1908         return true;
1909 }
1910
1911 bool SpectateSet(entity this)
1912 {
1913         if(!IS_PLAYER(this.enemy))
1914                 return false;
1915
1916         ClientData_Touch(this.enemy);
1917
1918         msg_entity = this;
1919         WriteByte(MSG_ONE, SVC_SETVIEW);
1920         WriteEntity(MSG_ONE, this.enemy);
1921         set_movetype(this, MOVETYPE_NONE);
1922         accuracy_resend(this);
1923
1924         if(!SpectateUpdate(this))
1925                 PutObserverInServer(this);
1926
1927         return true;
1928 }
1929
1930 void SetSpectatee_status(entity this, int spectatee_num)
1931 {
1932         int oldspectatee_status = CS(this).spectatee_status;
1933         CS(this).spectatee_status = spectatee_num;
1934
1935         if (CS(this).spectatee_status != oldspectatee_status)
1936         {
1937                 ClientData_Touch(this);
1938                 if (g_race || g_cts) race_InitSpectator();
1939         }
1940 }
1941
1942 void SetSpectatee(entity this, entity spectatee)
1943 {
1944         if(IS_BOT_CLIENT(this))
1945                 return; // bots abuse .enemy, this code is useless to them
1946
1947         entity old_spectatee = this.enemy;
1948
1949         this.enemy = spectatee;
1950
1951         // WEAPONTODO
1952         // these are required to fix the spectator bug with arc
1953         if(old_spectatee)
1954         {
1955                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1956                 {
1957                         .entity weaponentity = weaponentities[slot];
1958                         if(old_spectatee.(weaponentity).arc_beam)
1959                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1960                 }
1961         }
1962         if(this.enemy)
1963         {
1964                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1965                 {
1966                         .entity weaponentity = weaponentities[slot];
1967                         if(this.enemy.(weaponentity).arc_beam)
1968                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1969                 }
1970         }
1971
1972         if (this.enemy)
1973                 SetSpectatee_status(this, etof(this.enemy));
1974
1975         // needed to update spectator list
1976         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1977 }
1978
1979 bool Spectate(entity this, entity pl)
1980 {
1981         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1982                 return false;
1983         pl = M_ARGV(1, entity);
1984
1985         SetSpectatee(this, pl);
1986         return SpectateSet(this);
1987 }
1988
1989 bool SpectateNext(entity this)
1990 {
1991         entity ent = find(this.enemy, classname, STR_PLAYER);
1992
1993         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1994                 ent = M_ARGV(1, entity);
1995         else if (!ent)
1996                 ent = find(ent, classname, STR_PLAYER);
1997
1998         if(ent) { SetSpectatee(this, ent); }
1999
2000         return SpectateSet(this);
2001 }
2002
2003 bool SpectatePrev(entity this)
2004 {
2005         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2006         entity ent = findchain(classname, STR_PLAYER);
2007         if (!ent) // no player
2008                 return false;
2009
2010         entity first = ent;
2011         // skip players until current spectated player
2012         if(this.enemy)
2013         while(ent && ent != this.enemy)
2014                 ent = ent.chain;
2015
2016         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2017         {
2018                 case MUT_SPECPREV_FOUND:
2019                     ent = M_ARGV(1, entity);
2020                     break;
2021                 case MUT_SPECPREV_RETURN:
2022                     return true;
2023                 case MUT_SPECPREV_CONTINUE:
2024                 default:
2025                 {
2026                         if(ent.chain)
2027                                 ent = ent.chain;
2028                         else
2029                                 ent = first;
2030                         break;
2031                 }
2032         }
2033
2034         SetSpectatee(this, ent);
2035         return SpectateSet(this);
2036 }
2037
2038 /*
2039 =============
2040 ShowRespawnCountdown()
2041
2042 Update a respawn countdown display.
2043 =============
2044 */
2045 void ShowRespawnCountdown(entity this)
2046 {
2047         float number;
2048         if(!IS_DEAD(this)) // just respawned?
2049                 return;
2050         else
2051         {
2052                 number = ceil(this.respawn_time - time);
2053                 if(number <= 0)
2054                         return;
2055                 if(number <= this.respawn_countdown)
2056                 {
2057                         this.respawn_countdown = number - 1;
2058                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2059                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2060                 }
2061         }
2062 }
2063
2064 .bool team_selected;
2065 bool ShowTeamSelection(entity this)
2066 {
2067         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2068                 return false;
2069         stuffcmd(this, "menu_showteamselect\n");
2070         return true;
2071 }
2072 void Join(entity this)
2073 {
2074         TRANSMUTE(Player, this);
2075
2076         if(!this.team_selected)
2077         if(autocvar_g_campaign || autocvar_g_balance_teams)
2078                 TeamBalance_JoinBestTeam(this, true);
2079
2080         if(autocvar_g_campaign)
2081                 campaign_bots_may_start = true;
2082
2083         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2084
2085         PutClientInServer(this);
2086
2087         if(IS_PLAYER(this))
2088         if(teamplay && this.team != -1)
2089         {
2090                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2091         }
2092         else
2093                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2094         this.team_selected = false;
2095 }
2096
2097 /**
2098  * Determines whether the player is allowed to join. This depends on cvar
2099  * g_maxplayers, if it isn't used this function always return true, otherwise
2100  * it checks whether the number of currently playing players exceeds g_maxplayers.
2101  * @return int number of free slots for players, 0 if none
2102  */
2103 int nJoinAllowed(entity this, entity ignore)
2104 {
2105         if(!ignore)
2106         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2107         // so report 0 free slots if restricted
2108         {
2109                 if(autocvar_g_forced_team_otherwise == "spectate")
2110                         return 0;
2111                 if(autocvar_g_forced_team_otherwise == "spectator")
2112                         return 0;
2113         }
2114
2115         if(this && this.team_forced < 0)
2116                 return 0; // forced spectators can never join
2117
2118         // TODO simplify this
2119         int totalClients = 0;
2120         int currentlyPlaying = 0;
2121         FOREACH_CLIENT(true, {
2122                 if(it != ignore)
2123                         ++totalClients;
2124                 if(IS_REAL_CLIENT(it))
2125                 if(IS_PLAYER(it) || it.caplayer)
2126                         ++currentlyPlaying;
2127         });
2128
2129         float free_slots = 0;
2130         if (!autocvar_g_maxplayers)
2131                 free_slots = maxclients - totalClients;
2132         else if(currentlyPlaying < autocvar_g_maxplayers)
2133                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2134
2135         static float join_prevent_msg_time = 0;
2136         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2137         {
2138                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2139                 join_prevent_msg_time = time + 3;
2140         }
2141
2142         return free_slots;
2143 }
2144
2145 /**
2146  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2147  * g_maxplayers_spectator_blocktime seconds
2148  */
2149 void checkSpectatorBlock(entity this)
2150 {
2151         if(IS_SPEC(this) || IS_OBSERVER(this))
2152         if(!this.caplayer)
2153         if(IS_REAL_CLIENT(this))
2154         {
2155                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2156                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2157                         dropclient(this);
2158                 }
2159         }
2160 }
2161
2162 void PrintWelcomeMessage(entity this)
2163 {
2164         if(CS(this).motd_actived_time == 0)
2165         {
2166                 if (autocvar_g_campaign) {
2167                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2168                                 CS(this).motd_actived_time = time;
2169                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2170                         }
2171                 } else {
2172                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2173                                 CS(this).motd_actived_time = time;
2174                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2175                         }
2176                 }
2177         }
2178         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2179         {
2180                 if (autocvar_g_campaign) {
2181                         if (PHYS_INPUT_BUTTON_INFO(this))
2182                                 CS(this).motd_actived_time = time;
2183                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2184                                 CS(this).motd_actived_time = 0;
2185                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2186                         }
2187                 } else {
2188                         if (PHYS_INPUT_BUTTON_INFO(this))
2189                                 CS(this).motd_actived_time = time;
2190                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2191                                 CS(this).motd_actived_time = 0;
2192                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2193                         }
2194                 }
2195         }
2196         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2197         {
2198                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2199                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2200                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2201                 {
2202                         // instanctly hide MOTD
2203                         CS(this).motd_actived_time = 0;
2204                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2205                 }
2206         }
2207 }
2208
2209 bool joinAllowed(entity this)
2210 {
2211         if (CS(this).version_mismatch) return false;
2212         if (!nJoinAllowed(this, this)) return false;
2213         if (teamplay && lockteams) return false;
2214         if (ShowTeamSelection(this)) return false;
2215         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2216         return true;
2217 }
2218
2219 .int items_added;
2220 .string shootfromfixedorigin;
2221 bool PlayerThink(entity this)
2222 {
2223         if (game_stopped || intermission_running) {
2224                 this.modelflags &= ~MF_ROCKET;
2225                 if(intermission_running)
2226                         IntermissionThink(this);
2227                 return false;
2228         }
2229
2230         if (timeout_status == TIMEOUT_ACTIVE) {
2231         // don't allow the player to turn around while game is paused
2232                 // FIXME turn this into CSQC stuff
2233                 this.v_angle = this.lastV_angle;
2234                 this.angles = this.lastV_angle;
2235                 this.fixangle = true;
2236         }
2237
2238         if (frametime) player_powerups(this);
2239
2240         if (IS_DEAD(this)) {
2241                 if (this.personal && g_race_qualifying) {
2242                         if (time > this.respawn_time) {
2243                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2244                                 respawn(this);
2245                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2246                         }
2247                 } else {
2248                         if (frametime) player_anim(this);
2249
2250                         if (this.respawn_flags & RESPAWN_DENY)
2251                         {
2252                                 STAT(RESPAWN_TIME, this) = 0;
2253                                 return false;
2254                         }
2255
2256                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2257
2258                         switch(this.deadflag)
2259                         {
2260                                 case DEAD_DYING:
2261                                 {
2262                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2263                                                 this.deadflag = DEAD_RESPAWNING;
2264                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2265                                                 this.deadflag = DEAD_DEAD;
2266                                         break;
2267                                 }
2268                                 case DEAD_DEAD:
2269                                 {
2270                                         if (button_pressed)
2271                                                 this.deadflag = DEAD_RESPAWNABLE;
2272                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2273                                                 this.deadflag = DEAD_RESPAWNING;
2274                                         break;
2275                                 }
2276                                 case DEAD_RESPAWNABLE:
2277                                 {
2278                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2279                                                 this.deadflag = DEAD_RESPAWNING;
2280                                         break;
2281                                 }
2282                                 case DEAD_RESPAWNING:
2283                                 {
2284                                         if (time > this.respawn_time)
2285                                         {
2286                                                 this.respawn_time = time + 1; // only retry once a second
2287                                                 this.respawn_time_max = this.respawn_time;
2288                                                 respawn(this);
2289                                         }
2290                                         break;
2291                                 }
2292                         }
2293
2294                         ShowRespawnCountdown(this);
2295
2296                         if (this.respawn_flags & RESPAWN_SILENT)
2297                                 STAT(RESPAWN_TIME, this) = 0;
2298                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2299                         {
2300                                 if (time < this.respawn_time)
2301                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2302                                 else if (this.deadflag != DEAD_RESPAWNING)
2303                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2304                         }
2305                         else
2306                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2307                 }
2308
2309                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2310                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2311                         STAT(RESPAWN_TIME, this) *= -1;
2312
2313                 return false;
2314         }
2315
2316         FixPlayermodel(this);
2317
2318         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2319                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2320                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2321         }
2322
2323         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2324         //if(frametime)
2325         {
2326                 this.items &= ~this.items_added;
2327
2328                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2329                 {
2330                         .entity weaponentity = weaponentities[slot];
2331                         W_WeaponFrame(this, weaponentity);
2332                 }
2333
2334                 this.items_added = 0;
2335                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2336             this.items_added |= IT_FUEL;
2337
2338                 this.items |= this.items_added;
2339         }
2340
2341         player_regen(this);
2342
2343         // WEAPONTODO: Add a weapon request for this
2344         // rot vortex charge to the charge limit
2345         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2346         {
2347                 .entity weaponentity = weaponentities[slot];
2348                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2349                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2350         }
2351
2352         if (frametime) player_anim(this);
2353
2354         // secret status
2355         secrets_setstatus(this);
2356
2357         // monsters status
2358         monsters_setstatus(this);
2359
2360         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2361
2362         return true;
2363 }
2364
2365 void ObserverThink(entity this)
2366 {
2367         if ( CS(this).impulse )
2368         {
2369                 MinigameImpulse(this, CS(this).impulse);
2370                 CS(this).impulse = 0;
2371         }
2372
2373         if (this.flags & FL_JUMPRELEASED) {
2374                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2375                         this.flags &= ~FL_JUMPRELEASED;
2376                         this.flags |= FL_SPAWNING;
2377                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2378                         this.flags &= ~FL_JUMPRELEASED;
2379                         if(SpectateNext(this)) {
2380                                 TRANSMUTE(Spectator, this);
2381                         }
2382                 } else {
2383                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2384                         set_movetype(this, preferred_movetype);
2385                 }
2386         } else {
2387                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2388                         this.flags |= FL_JUMPRELEASED;
2389                         if(this.flags & FL_SPAWNING)
2390                         {
2391                                 this.flags &= ~FL_SPAWNING;
2392                                 Join(this);
2393                                 return;
2394                         }
2395                 }
2396         }
2397 }
2398
2399 void SpectatorThink(entity this)
2400 {
2401         if ( CS(this).impulse )
2402         {
2403                 if(MinigameImpulse(this, CS(this).impulse))
2404                         CS(this).impulse = 0;
2405
2406                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2407                 {
2408                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2409                         CS(this).impulse = 0;
2410                         return;
2411                 }
2412         }
2413
2414         if (this.flags & FL_JUMPRELEASED) {
2415                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2416                         this.flags &= ~FL_JUMPRELEASED;
2417                         this.flags |= FL_SPAWNING;
2418                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2419                         this.flags &= ~FL_JUMPRELEASED;
2420                         if(SpectateNext(this)) {
2421                                 TRANSMUTE(Spectator, this);
2422                         } else {
2423                                 TRANSMUTE(Observer, this);
2424                                 PutClientInServer(this);
2425                         }
2426                         CS(this).impulse = 0;
2427                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2428                         this.flags &= ~FL_JUMPRELEASED;
2429                         if(SpectatePrev(this)) {
2430                                 TRANSMUTE(Spectator, this);
2431                         } else {
2432                                 TRANSMUTE(Observer, this);
2433                                 PutClientInServer(this);
2434                         }
2435                         CS(this).impulse = 0;
2436                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2437                         this.flags &= ~FL_JUMPRELEASED;
2438                         TRANSMUTE(Observer, this);
2439                         PutClientInServer(this);
2440                 } else {
2441                         if(!SpectateUpdate(this))
2442                                 PutObserverInServer(this);
2443                 }
2444         } else {
2445                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2446                         this.flags |= FL_JUMPRELEASED;
2447                         if(this.flags & FL_SPAWNING)
2448                         {
2449                                 this.flags &= ~FL_SPAWNING;
2450                                 Join(this);
2451                                 return;
2452                         }
2453                 }
2454                 if(!SpectateUpdate(this))
2455                         PutObserverInServer(this);
2456         }
2457
2458         this.flags |= FL_CLIENT | FL_NOTARGET;
2459 }
2460
2461 void vehicles_enter (entity pl, entity veh);
2462 void PlayerUseKey(entity this)
2463 {
2464         if (!IS_PLAYER(this))
2465                 return;
2466
2467         if(this.vehicle)
2468         {
2469                 if(!game_stopped)
2470                 {
2471                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2472                         return;
2473                 }
2474         }
2475         else if(autocvar_g_vehicles_enter)
2476         {
2477                 if(!STAT(FROZEN, this))
2478                 if(!IS_DEAD(this))
2479                 if(!game_stopped)
2480                 {
2481                         entity head, closest_target = NULL;
2482                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2483
2484                         while(head) // find the closest acceptable target to enter
2485                         {
2486                                 if(IS_VEHICLE(head))
2487                                 if(!IS_DEAD(head))
2488                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2489                                 if(head.takedamage != DAMAGE_NO)
2490                                 {
2491                                         if(closest_target)
2492                                         {
2493                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2494                                                 { closest_target = head; }
2495                                         }
2496                                         else { closest_target = head; }
2497                                 }
2498
2499                                 head = head.chain;
2500                         }
2501
2502                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2503                 }
2504         }
2505
2506         // a use key was pressed; call handlers
2507         MUTATOR_CALLHOOK(PlayerUseKey, this);
2508 }
2509
2510
2511 /*
2512 =============
2513 PlayerPreThink
2514
2515 Called every frame for each client before the physics are run
2516 =============
2517 */
2518 .float last_vehiclecheck;
2519 void PlayerPreThink (entity this)
2520 {
2521         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2522         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2523
2524         WarpZone_PlayerPhysics_FixVAngle(this);
2525
2526         if (frametime) {
2527                 // physics frames: update anticheat stuff
2528                 anticheat_prethink(this);
2529         }
2530
2531         if (blockSpectators && frametime) {
2532                 // WORKAROUND: only use dropclient in server frames (frametime set).
2533                 // Never use it in cl_movement frames (frametime zero).
2534                 checkSpectatorBlock(this);
2535         }
2536
2537         zoomstate_set = false;
2538
2539         // Check for nameless players
2540         if (this.netname == "" || this.netname != CS(this).netname_previous)
2541         {
2542                 bool assume_unchanged = (CS(this).netname_previous == "");
2543                 if (isInvisibleString(this.netname))
2544                 {
2545                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2546                         assume_unchanged = false;
2547                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2548                 }
2549                 if (!assume_unchanged && autocvar_sv_eventlog)
2550                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2551                 strcpy(CS(this).netname_previous, this.netname);
2552         }
2553
2554         // version nagging
2555         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2556         CS(this).version_nagtime = 0;
2557         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2558             // git client
2559         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2560             // git server
2561             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2562         } else {
2563             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2564             if (r < 0) { // old client
2565                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2566             } else if (r > 0) { // old server
2567                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2568             }
2569         }
2570     }
2571
2572         // GOD MODE info
2573         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2574         {
2575                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2576                 this.max_armorvalue = 0;
2577         }
2578
2579         if(IS_PLAYER(this))
2580         {
2581                 if (STAT(FROZEN, this) == 2)
2582                 {
2583                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2584                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2585                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2586
2587                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2588                                 Unfreeze(this);
2589                 }
2590                 else if (STAT(FROZEN, this) == 3)
2591                 {
2592                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2593                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2594
2595                         if (this.health < 1)
2596                         {
2597                                 if (this.vehicle)
2598                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2599                                 if(this.event_damage)
2600                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2601                         }
2602                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2603                                 Unfreeze(this);
2604                 }
2605         }
2606
2607         MUTATOR_CALLHOOK(PlayerPreThink, this);
2608
2609         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2610         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2611         {
2612                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2613                 {
2614                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2615                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2616                         {
2617                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2618                         }
2619                         else if(!it.owner)
2620                         {
2621                                 if(!it.team || SAME_TEAM(this, it))
2622                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2623                                 else if(autocvar_g_vehicles_steal)
2624                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2625                         }
2626                 });
2627
2628                 this.last_vehiclecheck = time + 1;
2629         }
2630
2631         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2632         {
2633                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2634                         PlayerUseKey(this);
2635                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2636         }
2637
2638         if (IS_REAL_CLIENT(this))
2639                 PrintWelcomeMessage(this);
2640
2641         if (IS_PLAYER(this)) {
2642                 if(!PlayerThink(this))
2643                         return;
2644         }
2645         else if (game_stopped || intermission_running) {
2646                 if(intermission_running)
2647                         IntermissionThink(this);
2648                 return;
2649         }
2650         else if (IS_OBSERVER(this)) {
2651                 ObserverThink(this);
2652         }
2653         else if (IS_SPEC(this)) {
2654                 SpectatorThink(this);
2655         }
2656
2657         // WEAPONTODO: Add weapon request for this
2658         if (!zoomstate_set) {
2659                 bool wep_zoomed = false;
2660                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2661                 {
2662                         .entity weaponentity = weaponentities[slot];
2663                         Weapon thiswep = this.(weaponentity).m_weapon;
2664                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2665                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2666                 }
2667                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2668     }
2669
2670         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2671         {
2672                 CS(this).teamkill_soundtime = 0;
2673
2674                 entity e = CS(this).teamkill_soundsource;
2675                 entity oldpusher = e.pusher;
2676                 e.pusher = this;
2677                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2678                 e.pusher = oldpusher;
2679         }
2680
2681         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2682                 CS(this).taunt_soundtime = 0;
2683                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2684         }
2685
2686         target_voicescript_next(this);
2687
2688         // WEAPONTODO: Move into weaponsystem somehow
2689         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2690         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2691         {
2692                 .entity weaponentity = weaponentities[slot];
2693                 if(this.(weaponentity).m_weapon == WEP_Null)
2694                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2695         }
2696 }
2697
2698 void DrownPlayer(entity this)
2699 {
2700         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2701                 return;
2702
2703         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2704         {
2705                 if(this.air_finished < time)
2706                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2707                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2708         }
2709         else if (this.air_finished < time)
2710         {       // drown!
2711                 if (this.pain_finished < time)
2712                 {
2713                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2714                         this.pain_finished = time + 0.5;
2715                 }
2716         }
2717 }
2718
2719 .bool move_qcphysics;
2720
2721 void Player_Physics(entity this)
2722 {
2723         set_movetype(this, this.move_movetype);
2724
2725         if(!this.move_qcphysics)
2726                 return;
2727
2728         if(!frametime && !CS(this).pm_frametime)
2729                 return;
2730
2731         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2732
2733         CS(this).pm_frametime = 0;
2734 }
2735
2736 /*
2737 =============
2738 PlayerPostThink
2739
2740 Called every frame for each client after the physics are run
2741 =============
2742 */
2743 void PlayerPostThink (entity this)
2744 {
2745         Player_Physics(this);
2746
2747         if (sv_maxidle > 0)
2748         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2749         if (IS_REAL_CLIENT(this))
2750         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2751         {
2752                 int totalClients = 0;
2753                 if(sv_maxidle_slots > 0)
2754                 {
2755                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2756                         {
2757                                 ++totalClients;
2758                         });
2759                 }
2760
2761                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2762                 { /* do nothing */ }
2763                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2764                 {
2765                         if (CS(this).idlekick_lasttimeleft)
2766                         {
2767                                 CS(this).idlekick_lasttimeleft = 0;
2768                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2769                         }
2770                 }
2771                 else
2772                 {
2773                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2774                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2775                                 if (!CS(this).idlekick_lasttimeleft)
2776                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2777                         }
2778                         if (timeleft <= 0) {
2779                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2780                                 dropclient(this);
2781                                 return;
2782                         }
2783                         else if (timeleft <= 10) {
2784                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2785                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2786                 }
2787                                 CS(this).idlekick_lasttimeleft = timeleft;
2788                         }
2789                 }
2790         }
2791
2792         CheatFrame(this);
2793
2794         if (game_stopped)
2795         {
2796                 this.solid = SOLID_NOT;
2797                 this.takedamage = DAMAGE_NO;
2798                 set_movetype(this, MOVETYPE_NONE);
2799         }
2800
2801         if (IS_PLAYER(this)) {
2802                 if(this.death_time == time && IS_DEAD(this))
2803                 {
2804                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2805                         // once all the damage events of this frame have been processed with normal size
2806                         this.maxs.z = 5;
2807                         setsize(this, this.mins, this.maxs);
2808                 }
2809                 DrownPlayer(this);
2810                 UpdateChatBubble(this);
2811                 if (CS(this).impulse) ImpulseCommands(this);
2812                 if (game_stopped)
2813                 {
2814                         CSQCMODEL_AUTOUPDATE(this);
2815                         return;
2816                 }
2817                 GetPressedKeys(this);
2818         }
2819
2820         if (this.waypointsprite_attachedforcarrier) {
2821             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2822                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2823     }
2824
2825         playerdemo_write(this);
2826
2827         CSQCMODEL_AUTOUPDATE(this);
2828 }
2829
2830 // hack to copy the button fields from the client entity to the Client State
2831 void PM_UpdateButtons(entity this, entity store)
2832 {
2833         if(this.impulse)
2834                 store.impulse = this.impulse;
2835         this.impulse = 0;
2836
2837         bool typing = this.buttonchat;
2838
2839         store.button0 = (typing) ? 0 : this.button0;
2840         //button1?!
2841         store.button2 = (typing) ? 0 : this.button2;
2842         store.button3 = (typing) ? 0 : this.button3;
2843         store.button4 = this.button4;
2844         store.button5 = (typing) ? 0 : this.button5;
2845         store.button6 = this.button6;
2846         store.button7 = this.button7;
2847         store.button8 = this.button8;
2848         store.button9 = this.button9;
2849         store.button10 = this.button10;
2850         store.button11 = this.button11;
2851         store.button12 = this.button12;
2852         store.button13 = this.button13;
2853         store.button14 = this.button14;
2854         store.button15 = this.button15;
2855         store.button16 = this.button16;
2856         store.buttonuse = this.buttonuse;
2857         store.buttonchat = this.buttonchat;
2858
2859         store.cursor_active = this.cursor_active;
2860         store.cursor_screen = this.cursor_screen;
2861         store.cursor_trace_start = this.cursor_trace_start;
2862         store.cursor_trace_endpos = this.cursor_trace_endpos;
2863         store.cursor_trace_ent = this.cursor_trace_ent;
2864
2865         store.ping = this.ping;
2866         store.ping_packetloss = this.ping_packetloss;
2867         store.ping_movementloss = this.ping_movementloss;
2868
2869         store.v_angle = this.v_angle;
2870         store.movement = (typing) ? '0 0 0' : this.movement;
2871 }
2872
2873 NET_HANDLE(fpsreport, bool)
2874 {
2875         int fps = ReadShort();
2876         PlayerScore_Set(sender, SP_FPS, fps);
2877         return true;
2878 }