qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/mapobjects/func/conveyor.qh"
  37 #include "../common/mapobjects/teleporters.qh"
  38 #include "../common/mapobjects/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include <common/vehicles/sv_vehicles.qh>
  50
  51 #include "../common/items/_mod.qh"
  52
  53 #include "../common/mutators/mutator/waypoints/all.qh"
  54 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  55 #include <common/gamemodes/_mod.qh>
  56
  57 #include "../common/mapobjects/subs.qh"
  58 #include "../common/mapobjects/triggers.qh"
  59 #include "../common/mapobjects/trigger/secret.qh"
  60
  61 #include "../common/minigames/sv_minigames.qh"
  62
  63 #include "../common/items/inventory.qh"
  64
  65 #include "../common/monsters/sv_monsters.qh"
  66
  67 #include "../lib/warpzone/server.qh"
  68
  69 #include <common/mutators/mutator/overkill/oknex.qh>
  70
  71 STATIC_METHOD(Client, Add, void(Client this, int _team))
  72 {
  73     ClientConnect(this);
  74     TRANSMUTE(Player, this);
  75     this.frame = 12; // 7
  76     this.team = _team;
  77     PutClientInServer(this);
  78 }
  79
  80 STATIC_METHOD(Client, Remove, void(Client this))
  81 {
  82     TRANSMUTE(Observer, this);
  83     PutClientInServer(this);
  84     ClientDisconnect(this);
  85 }
  86
  87 void send_CSQC_teamnagger() {
  88         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  89 }
  90
  91 int CountSpectators(entity player, entity to)
  92 {
  93         if(!player) { return 0; } // not sure how, but best to be safe
  94
  95         int spec_count = 0;
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 spec_count++;
 100         });
 101
 102         return spec_count;
 103 }
 104
 105 void WriteSpectators(entity player, entity to)
 106 {
 107         if(!player) { return; } // not sure how, but best to be safe
 108
 109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 110         {
 111                 WriteByte(MSG_ENTITY, num_for_edict(it));
 112         });
 113 }
 114
 115 bool ClientData_Send(entity this, entity to, int sf)
 116 {
 117         assert(to == this.owner, return false);
 118
 119         entity e = to;
 120         if (IS_SPEC(e)) e = e.enemy;
 121
 122         sf = 0;
 123         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 124         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 125         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 126         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 127
 128         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 129         WriteByte(MSG_ENTITY, sf);
 130
 131         if (sf & BIT(1))
 132                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 133
 134         if(sf & BIT(4))
 135         {
 136                 float specs = CountSpectators(e, to);
 137                 WriteByte(MSG_ENTITY, specs);
 138                 WriteSpectators(e, to);
 139         }
 140
 141         return true;
 142 }
 143
 144 void ClientData_Attach(entity this)
 145 {
 146         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 147         CS(this).clientdata.drawonlytoclient = this;
 148         CS(this).clientdata.owner = this;
 149 }
 150
 151 void ClientData_Detach(entity this)
 152 {
 153         delete(CS(this).clientdata);
 154         CS(this).clientdata = NULL;
 155 }
 156
 157 void ClientData_Touch(entity e)
 158 {
 159         entity cd = CS(e).clientdata;
 160         if (cd) { cd.SendFlags = 1; }
 161
 162         // make it spectatable
 163         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 164         {
 165                 entity cd = CS(it).clientdata;
 166                 if (cd) { cd.SendFlags = 1; }
 167         });
 168 }
 169
 170
 171 /*
 172 =============
 173 CheckPlayerModel
 174
 175 Checks if the argument string can be a valid playermodel.
 176 Returns a valid one in doubt.
 177 =============
 178 */
 179 string FallbackPlayerModel;
 180 string CheckPlayerModel(string plyermodel) {
 181         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 182         {
 183                 // note: we cannot summon Don Strunzone here, some player may
 184                 // still have the model string set. In case anyone manages how
 185                 // to change a cvar default, we'll have a small leak here.
 186                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 187         }
 188         // only in right path
 189         if( substring(plyermodel,0,14) != "models/player/")
 190                 return FallbackPlayerModel;
 191         // only good file extensions
 192         if(substring(plyermodel,-4,4) != ".zym")
 193         if(substring(plyermodel,-4,4) != ".dpm")
 194         if(substring(plyermodel,-4,4) != ".iqm")
 195         if(substring(plyermodel,-4,4) != ".md3")
 196         if(substring(plyermodel,-4,4) != ".psk")
 197                 return FallbackPlayerModel;
 198         // forbid the LOD models
 199         if(substring(plyermodel, -9,5) == "_lod1")
 200                 return FallbackPlayerModel;
 201         if(substring(plyermodel, -9,5) == "_lod2")
 202                 return FallbackPlayerModel;
 203         if(plyermodel != strtolower(plyermodel))
 204                 return FallbackPlayerModel;
 205         // also, restrict to server models
 206         if(autocvar_sv_servermodelsonly)
 207         {
 208                 if(!fexists(plyermodel))
 209                         return FallbackPlayerModel;
 210         }
 211         return plyermodel;
 212 }
 213
 214 void setplayermodel(entity e, string modelname)
 215 {
 216         precache_model(modelname);
 217         _setmodel(e, modelname);
 218         player_setupanimsformodel(e);
 219         if(!autocvar_g_debug_globalsounds)
 220                 UpdatePlayerSounds(e);
 221 }
 222
 223 /** putting a client as observer in the server */
 224 void PutObserverInServer(entity this)
 225 {
 226     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 227         PlayerState_detach(this);
 228
 229         if (IS_PLAYER(this))
 230         {
 231                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 232                 {
 233                         // despawn effect
 234                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 235                 }
 236
 237                 // was a player, recount votes and ready status
 238                 if(IS_REAL_CLIENT(this))
 239                 {
 240                         if (vote_called) { VoteCount(false); }
 241                         ReadyCount();
 242                 }
 243     }
 244
 245     {
 246         entity spot = SelectSpawnPoint(this, true);
 247         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 248         this.angles = vec2(spot.angles);
 249         this.fixangle = true;
 250         // offset it so that the spectator spawns higher off the ground, looks better this way
 251         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 252         if (IS_REAL_CLIENT(this))
 253         {
 254             msg_entity = this;
 255             WriteByte(MSG_ONE, SVC_SETVIEW);
 256             WriteEntity(MSG_ONE, this);
 257         }
 258         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 259         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 260         if(!autocvar_g_debug_globalsounds)
 261         {
 262                 // needed for player sounds
 263                 this.model = "";
 264                 FixPlayermodel(this);
 265         }
 266         setmodel(this, MDL_Null);
 267         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 268         this.view_ofs = '0 0 0';
 269     }
 270
 271     RemoveGrapplingHooks(this);
 272         Portal_ClearAll(this);
 273         Unfreeze(this);
 274         SetSpectatee(this, NULL);
 275
 276         if (this.alivetime)
 277         {
 278                 if (!warmup_stage)
 279                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 280                 this.alivetime = 0;
 281         }
 282
 283         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 284
 285         WaypointSprite_PlayerDead(this);
 286
 287         if (CS(this).killcount != FRAGS_SPECTATOR)
 288         {
 289                 if(!game_stopped)
 290                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 291                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 292
 293                 if(CS(this).just_joined)
 294                 {
 295                         CS(this).just_joined = false;
 296                 }
 297         }
 298
 299         accuracy_resend(this);
 300
 301         CS(this).spectatortime = time;
 302         if(this.bot_attack)
 303                 IL_REMOVE(g_bot_targets, this);
 304         this.bot_attack = false;
 305         if(this.monster_attack)
 306                 IL_REMOVE(g_monster_targets, this);
 307         this.monster_attack = false;
 308     STAT(HUD, this) = HUD_NORMAL;
 309         TRANSMUTE(Observer, this);
 310         this.iscreature = false;
 311         this.teleportable = TELEPORT_SIMPLE;
 312         if(this.damagedbycontents)
 313                 IL_REMOVE(g_damagedbycontents, this);
 314         this.damagedbycontents = false;
 315         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 316         SetSpectatee_status(this, etof(this));
 317         this.takedamage = DAMAGE_NO;
 318         this.solid = SOLID_NOT;
 319         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 320         this.flags = FL_CLIENT | FL_NOTARGET;
 321         this.effects = 0;
 322         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 323         this.pauserotarmor_finished = 0;
 324         this.pauserothealth_finished = 0;
 325         this.pauseregen_finished = 0;
 326         this.damageforcescale = 0;
 327         this.death_time = 0;
 328         this.respawn_flags = 0;
 329         this.respawn_time = 0;
 330         STAT(RESPAWN_TIME, this) = 0;
 331         this.alpha = 0;
 332         this.scale = 0;
 333         this.fade_time = 0;
 334         this.pain_frame = 0;
 335         this.pain_finished = 0;
 336         this.strength_finished = 0;
 337         this.invincible_finished = 0;
 338         this.superweapons_finished = 0;
 339         this.dphitcontentsmask = 0;
 340         this.pushltime = 0;
 341         this.istypefrag = 0;
 342         setthink(this, func_null);
 343         this.nextthink = 0;
 344         this.deadflag = DEAD_NO;
 345         this.crouch = false;
 346         STAT(REVIVE_PROGRESS, this) = 0;
 347         this.revival_time = 0;
 348
 349         this.items = 0;
 350         STAT(WEAPONS, this) = '0 0 0';
 351         this.drawonlytoclient = this;
 352
 353         this.viewloc = NULL;
 354
 355         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 356
 357         this.weaponmodel = "";
 358         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 359         {
 360                 this.weaponentities[slot] = NULL;
 361         }
 362         this.exteriorweaponentity = NULL;
 363         CS(this).killcount = FRAGS_SPECTATOR;
 364         this.velocity = '0 0 0';
 365         this.avelocity = '0 0 0';
 366         this.punchangle = '0 0 0';
 367         this.punchvector = '0 0 0';
 368         this.oldvelocity = this.velocity;
 369         this.fire_endtime = -1;
 370         this.event_damage = func_null;
 371         this.event_heal = func_null;
 372
 373         for(int slot = 0; slot < MAX_AXH; ++slot)
 374         {
 375                 entity axh = this.(AuxiliaryXhair[slot]);
 376                 this.(AuxiliaryXhair[slot]) = NULL;
 377
 378                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 379                         delete(axh);
 380         }
 381
 382         if (mutator_returnvalue)
 383         {
 384                 // mutator prevents resetting teams+score
 385         }
 386         else
 387         {
 388                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 389                 this.frags = FRAGS_SPECTATOR;
 390                 PlayerScore_Clear(this);  // clear scores when needed
 391     }
 392 }
 393
 394 int player_getspecies(entity this)
 395 {
 396         get_model_parameters(this.model, this.skin);
 397         int s = get_model_parameters_species;
 398         get_model_parameters(string_null, 0);
 399         if (s < 0) return SPECIES_HUMAN;
 400         return s;
 401 }
 402
 403 .float model_randomizer;
 404 void FixPlayermodel(entity player)
 405 {
 406         string defaultmodel = "";
 407         int defaultskin = 0;
 408         if(autocvar_sv_defaultcharacter)
 409         {
 410                 if(teamplay)
 411                 {
 412                         switch(player.team)
 413                         {
 414                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 415                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 416                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 417                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 418                         }
 419                 }
 420
 421                 if(defaultmodel == "")
 422                 {
 423                         defaultmodel = autocvar_sv_defaultplayermodel;
 424                         defaultskin = autocvar_sv_defaultplayerskin;
 425                 }
 426
 427                 int n = tokenize_console(defaultmodel);
 428                 if(n > 0)
 429                 {
 430                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 431                         // However, do NOT randomize if the player-selected model is in the list.
 432                         for (int i = 0; i < n; ++i)
 433                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 434                                         defaultmodel = argv(i);
 435                 }
 436
 437                 int i = strstrofs(defaultmodel, ":", 0);
 438                 if(i >= 0)
 439                 {
 440                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 441                         defaultmodel = substring(defaultmodel, 0, i);
 442                 }
 443         }
 444         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 445         {
 446                 if(teamplay)
 447                 {
 448                         switch(player.team)
 449                         {
 450                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 451                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 452                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 453                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 454                         }
 455                 }
 456
 457                 if(!defaultskin)
 458                         defaultskin = autocvar_sv_defaultplayerskin;
 459         }
 460
 461         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 462         defaultmodel = M_ARGV(0, string);
 463         defaultskin = M_ARGV(1, int);
 464
 465         bool chmdl = false;
 466         int oldskin;
 467         if(defaultmodel != "")
 468         {
 469                 if (defaultmodel != player.model)
 470                 {
 471                         vector m1 = player.mins;
 472                         vector m2 = player.maxs;
 473                         setplayermodel (player, defaultmodel);
 474                         setsize (player, m1, m2);
 475                         chmdl = true;
 476                 }
 477
 478                 oldskin = player.skin;
 479                 player.skin = defaultskin;
 480         } else {
 481                 if (player.playermodel != player.model || player.playermodel == "")
 482                 {
 483                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 484                         vector m1 = player.mins;
 485                         vector m2 = player.maxs;
 486                         setplayermodel (player, player.playermodel);
 487                         setsize (player, m1, m2);
 488                         chmdl = true;
 489                 }
 490
 491                 if(!autocvar_sv_defaultcharacterskin)
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = stof(player.playerskin);
 495                 }
 496                 else
 497                 {
 498                         oldskin = player.skin;
 499                         player.skin = defaultskin;
 500                 }
 501         }
 502
 503         if(chmdl || oldskin != player.skin) // model or skin has changed
 504         {
 505                 player.species = player_getspecies(player); // update species
 506                 if(!autocvar_g_debug_globalsounds)
 507                         UpdatePlayerSounds(player); // update skin sounds
 508         }
 509
 510         if(!teamplay)
 511                 if(strlen(autocvar_sv_defaultplayercolors))
 512                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 513                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 514 }
 515
 516 void PutPlayerInServer(entity this)
 517 {
 518         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 519
 520         PlayerState_attach(this);
 521         accuracy_resend(this);
 522
 523         if (this.team < 0)
 524                 TeamBalance_JoinBestTeam(this);
 525
 526         entity spot = SelectSpawnPoint(this, false);
 527         if (!spot) {
 528                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 529                 return; // spawn failed
 530         }
 531
 532         TRANSMUTE(Player, this);
 533
 534         CS(this).wasplayer = true;
 535         this.iscreature = true;
 536         this.teleportable = TELEPORT_NORMAL;
 537         if(!this.damagedbycontents)
 538                 IL_PUSH(g_damagedbycontents, this);
 539         this.damagedbycontents = true;
 540         set_movetype(this, MOVETYPE_WALK);
 541         this.solid = SOLID_SLIDEBOX;
 542         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 543         if (autocvar_g_playerclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 545         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 546                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 547         this.frags = FRAGS_PLAYER;
 548         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 549         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 550         if (autocvar__notarget)
 551                 this.flags |= FL_NOTARGET;
 552         this.takedamage = DAMAGE_AIM;
 553         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 554
 555         if (warmup_stage) {
 556                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 557                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 558                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 559                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 560                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 561                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 562                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 563                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 564                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 565         } else {
 566                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 567                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 568                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 569                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 570                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 571                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 572                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 573                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 574                 STAT(WEAPONS, this) = start_weapons;
 575                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 576                 {
 577                         GiveRandomWeapons(this, random_start_weapons_count,
 578                                 autocvar_g_random_start_weapons, random_start_ammo);
 579                 }
 580         }
 581         SetSpectatee_status(this, 0);
 582
 583         PS(this).dual_weapons = '0 0 0';
 584
 585         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 586
 587         this.items = start_items;
 588
 589         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 590         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 591         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 592         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 593         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 594         if (!sv_ready_restart_after_countdown && time < game_starttime)
 595         {
 596                 float f = game_starttime - time;
 597                 this.spawnshieldtime += f;
 598                 this.pauserotarmor_finished += f;
 599                 this.pauserothealth_finished += f;
 600                 this.pauseregen_finished += f;
 601         }
 602
 603         this.damageforcescale = 2;
 604         this.death_time = 0;
 605         this.respawn_flags = 0;
 606         this.respawn_time = 0;
 607         STAT(RESPAWN_TIME, this) = 0;
 608         this.scale = autocvar_sv_player_scale;
 609         this.fade_time = 0;
 610         this.pain_frame = 0;
 611         this.pain_finished = 0;
 612         this.pushltime = 0;
 613         setthink(this, func_null); // players have no think function
 614         this.nextthink = 0;
 615         this.dmg_team = 0;
 616         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 617
 618         this.deadflag = DEAD_NO;
 619
 620         this.angles = spot.angles;
 621         this.angles_z = 0; // never spawn tilted even if the spot says to
 622         if (IS_BOT_CLIENT(this))
 623                 this.v_angle = this.angles;
 624         this.fixangle = true; // turn this way immediately
 625         this.oldvelocity = this.velocity = '0 0 0';
 626         this.avelocity = '0 0 0';
 627         this.punchangle = '0 0 0';
 628         this.punchvector = '0 0 0';
 629
 630         this.strength_finished = 0;
 631         this.invincible_finished = 0;
 632         this.fire_endtime = -1;
 633         STAT(REVIVE_PROGRESS, this) = 0;
 634         this.revival_time = 0;
 635
 636         this.air_finished = time + 12;
 637         this.waterlevel = WATERLEVEL_NONE;
 638         this.watertype = CONTENT_EMPTY;
 639
 640         entity spawnevent = new_pure(spawnevent);
 641         spawnevent.owner = this;
 642         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 643
 644         // Cut off any still running player sounds.
 645         stopsound(this, CH_PLAYER_SINGLE);
 646
 647         this.model = "";
 648         FixPlayermodel(this);
 649         this.drawonlytoclient = NULL;
 650
 651         this.viewloc = NULL;
 652
 653         for(int slot = 0; slot < MAX_AXH; ++slot)
 654         {
 655                 entity axh = this.(AuxiliaryXhair[slot]);
 656                 this.(AuxiliaryXhair[slot]) = NULL;
 657
 658                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 659                         delete(axh);
 660         }
 661
 662         this.spawnpoint_targ = NULL;
 663
 664         this.crouch = false;
 665         this.view_ofs = STAT(PL_VIEW_OFS, this);
 666         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 667         this.spawnorigin = spot.origin;
 668         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 669         // don't reset back to last position, even if new position is stuck in solid
 670         this.oldorigin = this.origin;
 671         if(this.conveyor)
 672                 IL_REMOVE(g_conveyed, this);
 673         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 674         STAT(HUD, this) = HUD_NORMAL;
 675
 676         this.event_damage = PlayerDamage;
 677         this.event_heal = PlayerHeal;
 678
 679         if(!this.bot_attack)
 680                 IL_PUSH(g_bot_targets, this);
 681         this.bot_attack = true;
 682         if(!this.monster_attack)
 683                 IL_PUSH(g_monster_targets, this);
 684         this.monster_attack = true;
 685         navigation_dynamicgoal_init(this, false);
 686
 687         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 688
 689         // player was spectator
 690         if (CS(this).killcount == FRAGS_SPECTATOR) {
 691                 PlayerScore_Clear(this);
 692                 CS(this).killcount = 0;
 693                 CS(this).startplaytime = time;
 694         }
 695
 696         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 697         {
 698                 .entity weaponentity = weaponentities[slot];
 699                 entity oldwep = this.(weaponentity);
 700                 CL_SpawnWeaponentity(this, weaponentity);
 701                 if(oldwep && oldwep.owner == this)
 702                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 703         }
 704         this.alpha = default_player_alpha;
 705         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 706         this.exteriorweaponentity.alpha = default_weapon_alpha;
 707
 708         this.speedrunning = false;
 709
 710         target_voicescript_clear(this);
 711
 712         // reset fields the weapons may use
 713         FOREACH(Weapons, true, {
 714                 it.wr_resetplayer(it, this);
 715                         // reload all reloadable weapons
 716                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 717                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 718                         {
 719                                 .entity weaponentity = weaponentities[slot];
 720                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 721                         }
 722                 }
 723         });
 724
 725         {
 726                 string s = spot.target;
 727                 spot.target = string_null;
 728                 SUB_UseTargets(spot, this, NULL);
 729                 spot.target = s;
 730         }
 731
 732         Unfreeze(this);
 733
 734         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 735
 736         if (autocvar_spawn_debug)
 737         {
 738                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 739                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 740         }
 741
 742         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 743         {
 744                 .entity weaponentity = weaponentities[slot];
 745                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 746                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 747                 else
 748                         this.(weaponentity).m_switchweapon = WEP_Null;
 749                 this.(weaponentity).m_weapon = WEP_Null;
 750                 this.(weaponentity).weaponname = "";
 751                 this.(weaponentity).m_switchingweapon = WEP_Null;
 752                 this.(weaponentity).cnt = -1;
 753         }
 754
 755         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 756
 757         if (CS(this).impulse) ImpulseCommands(this);
 758
 759         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 760         {
 761                 .entity weaponentity = weaponentities[slot];
 762                 W_WeaponFrame(this, weaponentity);
 763         }
 764
 765         if (!warmup_stage && !this.alivetime)
 766                 this.alivetime = time;
 767
 768         antilag_clear(this, CS(this));
 769 }
 770
 771 /** Called when a client spawns in the server */
 772 void PutClientInServer(entity this)
 773 {
 774         if (IS_BOT_CLIENT(this)) {
 775                 TRANSMUTE(Player, this);
 776         } else if (IS_REAL_CLIENT(this)) {
 777                 msg_entity = this;
 778                 WriteByte(MSG_ONE, SVC_SETVIEW);
 779                 WriteEntity(MSG_ONE, this);
 780         }
 781         if (game_stopped)
 782                 TRANSMUTE(Observer, this);
 783
 784         SetSpectatee(this, NULL);
 785
 786         // reset player keys
 787         if(PS(this))
 788                 PS(this).itemkeys = 0;
 789
 790         MUTATOR_CALLHOOK(PutClientInServer, this);
 791
 792         if (IS_OBSERVER(this)) {
 793                 PutObserverInServer(this);
 794         } else if (IS_PLAYER(this)) {
 795                 PutPlayerInServer(this);
 796         }
 797 }
 798
 799 // TODO do we need all these fields, or should we stop autodetecting runtime
 800 // changes and just have a console command to update this?
 801 bool ClientInit_SendEntity(entity this, entity to, int sf)
 802 {
 803         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 804         return = true;
 805         msg_entity = to;
 806         // MSG_INIT replacement
 807         // TODO: make easier to use
 808         Registry_send_all();
 809         W_PROP_reload(MSG_ONE, to);
 810         ClientInit_misc(this);
 811         MUTATOR_CALLHOOK(Ent_Init);
 812 }
 813 void ClientInit_misc(entity this)
 814 {
 815         int channel = MSG_ONE;
 816         WriteHeader(channel, ENT_CLIENT_INIT);
 817         WriteByte(channel, g_nexball_meter_period * 32);
 818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 819         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 820         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 821         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 823         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 824         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 825         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 826
 827         if(sv_foginterval && world.fog != "")
 828                 WriteString(channel, world.fog);
 829         else
 830                 WriteString(channel, "");
 831         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 832         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 833         WriteByte(channel, serverflags);
 834         WriteCoord(channel, autocvar_g_trueaim_minrange);
 835 }
 836
 837 void ClientInit_CheckUpdate(entity this)
 838 {
 839         this.nextthink = time;
 840         if(this.count != autocvar_g_balance_armor_blockpercent)
 841         {
 842                 this.count = autocvar_g_balance_armor_blockpercent;
 843                 this.SendFlags |= 1;
 844         }
 845         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 846         {
 847                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 848                 this.SendFlags |= 1;
 849         }
 850 }
 851
 852 void ClientInit_Spawn()
 853 {
 854         entity e = new_pure(clientinit);
 855         setthink(e, ClientInit_CheckUpdate);
 856         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 857
 858         ClientInit_CheckUpdate(e);
 859 }
 860
 861 /*
 862 =============
 863 SetNewParms
 864 =============
 865 */
 866 void SetNewParms ()
 867 {
 868         // initialize parms for a new player
 869         parm1 = -(86400 * 366);
 870
 871         MUTATOR_CALLHOOK(SetNewParms);
 872 }
 873
 874 /*
 875 =============
 876 SetChangeParms
 877 =============
 878 */
 879 void SetChangeParms (entity this)
 880 {
 881         // save parms for level change
 882         parm1 = CS(this).parm_idlesince - time;
 883
 884         MUTATOR_CALLHOOK(SetChangeParms);
 885 }
 886
 887 /*
 888 =============
 889 DecodeLevelParms
 890 =============
 891 */
 892 void DecodeLevelParms(entity this)
 893 {
 894         // load parms
 895         CS(this).parm_idlesince = parm1;
 896         if (CS(this).parm_idlesince == -(86400 * 366))
 897                 CS(this).parm_idlesince = time;
 898
 899         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 900         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 901
 902         MUTATOR_CALLHOOK(DecodeLevelParms);
 903 }
 904
 905 /*
 906 =============
 907 ClientKill
 908
 909 Called when a client types 'kill' in the console
 910 =============
 911 */
 912
 913 .float clientkill_nexttime;
 914 void ClientKill_Now_TeamChange(entity this)
 915 {
 916         if(this.killindicator_teamchange == -1)
 917         {
 918                 TeamBalance_JoinBestTeam(this);
 919         }
 920         else if(this.killindicator_teamchange == -2)
 921         {
 922                 if(blockSpectators)
 923                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 924                 PutObserverInServer(this);
 925         }
 926         else
 927                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 928         this.killindicator_teamchange = 0;
 929 }
 930
 931 void ClientKill_Now(entity this)
 932 {
 933         if(this.vehicle)
 934         {
 935             vehicles_exit(this.vehicle, VHEF_RELEASE);
 936             if(!this.killindicator_teamchange)
 937             {
 938             this.vehicle_health = -1;
 939             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 940             }
 941         }
 942
 943         if(this.killindicator && !wasfreed(this.killindicator))
 944                 delete(this.killindicator);
 945
 946         this.killindicator = NULL;
 947
 948         if(this.killindicator_teamchange)
 949                 ClientKill_Now_TeamChange(this);
 950
 951         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 952         {
 953                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 954         }
 955
 956         // now I am sure the player IS dead
 957 }
 958 void KillIndicator_Think(entity this)
 959 {
 960         if (game_stopped)
 961         {
 962                 this.owner.killindicator = NULL;
 963                 delete(this);
 964                 return;
 965         }
 966
 967         if (this.owner.alpha < 0 && !this.owner.vehicle)
 968         {
 969                 this.owner.killindicator = NULL;
 970                 delete(this);
 971                 return;
 972         }
 973
 974         if(this.cnt <= 0)
 975         {
 976                 ClientKill_Now(this.owner);
 977                 return;
 978         }
 979     else if(this.count == 1) // count == 1 means that it's silent
 980     {
 981         this.nextthink = time + 1;
 982         this.cnt -= 1;
 983     }
 984         else
 985         {
 986                 if(this.cnt <= 10)
 987                         setmodel(this, MDL_NUM(this.cnt));
 988                 if(IS_REAL_CLIENT(this.owner))
 989                 {
 990                         if(this.cnt <= 10)
 991                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 992                 }
 993                 this.nextthink = time + 1;
 994                 this.cnt -= 1;
 995         }
 996 }
 997
 998 float clientkilltime;
 999 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1000 {
1001         float killtime;
1002         float starttime;
1003
1004         if (game_stopped)
1005                 return;
1006
1007         killtime = autocvar_g_balance_kill_delay;
1008
1009     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1010         return;
1011     killtime = M_ARGV(1, float);
1012
1013         this.killindicator_teamchange = targetteam;
1014
1015     if(!this.killindicator)
1016         {
1017                 if(!IS_DEAD(this))
1018                 {
1019                         killtime = max(killtime, this.clientkill_nexttime - time);
1020                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1021                 }
1022
1023                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1024                 {
1025                         ClientKill_Now(this);
1026                 }
1027                 else
1028                 {
1029                         starttime = max(time, clientkilltime);
1030
1031                         this.killindicator = spawn();
1032                         this.killindicator.owner = this;
1033                         this.killindicator.scale = 0.5;
1034                         setattachment(this.killindicator, this, "");
1035                         setorigin(this.killindicator, '0 0 52');
1036                         setthink(this.killindicator, KillIndicator_Think);
1037                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1038                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1039                         this.killindicator.cnt = ceil(killtime);
1040                         this.killindicator.count = bound(0, ceil(killtime), 10);
1041                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1042
1043                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1044                         {
1045                                 it.killindicator = spawn();
1046                                 it.killindicator.owner = it;
1047                                 it.killindicator.scale = 0.5;
1048                                 setattachment(it.killindicator, it, "");
1049                                 setorigin(it.killindicator, '0 0 52');
1050                                 setthink(it.killindicator, KillIndicator_Think);
1051                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1052                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1053                                 it.killindicator.cnt = ceil(killtime);
1054                         });
1055                         this.lip = 0;
1056                 }
1057         }
1058         if(this.killindicator)
1059         {
1060                 if(targetteam == 0) // just die
1061                 {
1062                         this.killindicator.colormod = '0 0 0';
1063                         if(IS_REAL_CLIENT(this))
1064                         if(this.killindicator.cnt > 0)
1065                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1066                 }
1067                 else if(targetteam == -1) // auto
1068                 {
1069                         this.killindicator.colormod = '0 1 0';
1070                         if(IS_REAL_CLIENT(this))
1071                         if(this.killindicator.cnt > 0)
1072                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1073                 }
1074                 else if(targetteam == -2) // spectate
1075                 {
1076                         this.killindicator.colormod = '0.5 0.5 0.5';
1077                         if(IS_REAL_CLIENT(this))
1078                         if(this.killindicator.cnt > 0)
1079                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1080                 }
1081                 else
1082                 {
1083                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1084                         if(IS_REAL_CLIENT(this))
1085                         if(this.killindicator.cnt > 0)
1086                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1087                 }
1088         }
1089
1090 }
1091
1092 void ClientKill (entity this)
1093 {
1094         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1095
1096         if(game_stopped) return;
1097         if(this.player_blocked) return;
1098         if(STAT(FROZEN, this)) return;
1099
1100         ClientKill_TeamChange(this, 0);
1101 }
1102
1103 void FixClientCvars(entity e)
1104 {
1105         // send prediction settings to the client
1106         stuffcmd(e, "\nin_bindmap 0 0\n");
1107         if(autocvar_g_antilag == 3) // client side hitscan
1108                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1109         if(autocvar_sv_gentle)
1110                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1111
1112         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1113         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1114
1115         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1116
1117         MUTATOR_CALLHOOK(FixClientCvars, e);
1118 }
1119
1120 bool findinlist_abbrev(string tofind, string list)
1121 {
1122         if(list == "" || tofind == "")
1123                 return false; // empty list or search, just return
1124
1125         // this function allows abbreviated strings!
1126         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1127         {
1128                 return true;
1129         });
1130
1131         return false;
1132 }
1133
1134 bool PlayerInIPList(entity p, string iplist)
1135 {
1136         // some safety checks (never allow local?)
1137         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1138                 return false;
1139
1140         return findinlist_abbrev(p.netaddress, iplist);
1141 }
1142
1143 bool PlayerInIDList(entity p, string idlist)
1144 {
1145         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1146         if(!p.crypto_idfp)
1147                 return false;
1148
1149         return findinlist_abbrev(p.crypto_idfp, idlist);
1150 }
1151
1152 bool PlayerInList(entity player, string list)
1153 {
1154         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1155 }
1156
1157 #ifdef DP_EXT_PRECONNECT
1158 /*
1159 =============
1160 ClientPreConnect
1161
1162 Called once (not at each match start) when a client begins a connection to the server
1163 =============
1164 */
1165 void ClientPreConnect(entity this)
1166 {
1167         if(autocvar_sv_eventlog)
1168         {
1169                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1170                         this.playerid,
1171                         etof(this),
1172                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1173                 ));
1174         }
1175 }
1176 #endif
1177
1178 string GetClientVersionMessage(entity this)
1179 {
1180         if (CS(this).version_mismatch) {
1181                 if(CS(this).version < autocvar_gameversion) {
1182                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1183                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1184                 } else {
1185                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1186                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1187                 }
1188         } else {
1189                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1190         }
1191 }
1192
1193 string getwelcomemessage(entity this)
1194 {
1195         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1196         string modifications = M_ARGV(0, string);
1197
1198         if(g_weaponarena)
1199         {
1200                 if(g_weaponarena_random)
1201                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1202                 else
1203                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1204         }
1205         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1206                 modifications = strcat(modifications, ", No start weapons");
1207         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1208                 modifications = strcat(modifications, ", Low gravity");
1209         if(g_weapon_stay && !g_cts)
1210                 modifications = strcat(modifications, ", Weapons stay");
1211         if(g_jetpack)
1212                 modifications = strcat(modifications, ", Jet pack");
1213         if(autocvar_g_powerups == 0)
1214                 modifications = strcat(modifications, ", No powerups");
1215         if(autocvar_g_powerups > 0)
1216                 modifications = strcat(modifications, ", Powerups");
1217         modifications = substring(modifications, 2, strlen(modifications) - 2);
1218
1219         string versionmessage = GetClientVersionMessage(this);
1220         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1221
1222         if(modifications != "")
1223                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1224
1225         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1226         {
1227                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1228                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1229         }
1230
1231         if (cache_mutatormsg != "") {
1232                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1233         }
1234
1235         string mutator_msg = "";
1236         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1237         mutator_msg = M_ARGV(0, string);
1238
1239         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1240
1241         string motd = autocvar_sv_motd;
1242         if (motd != "") {
1243                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1244         }
1245         return s;
1246 }
1247
1248 /**
1249 =============
1250 ClientConnect
1251
1252 Called when a client connects to the server
1253 =============
1254 */
1255 void ClientConnect(entity this)
1256 {
1257         if (Ban_MaybeEnforceBanOnce(this)) return;
1258         assert(!IS_CLIENT(this), return);
1259         this.flags |= FL_CLIENT;
1260         assert(player_count >= 0, player_count = 0);
1261
1262 #ifdef WATERMARK
1263         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1264 #endif
1265         TRANSMUTE(Client, this);
1266         CS(this).version_nagtime = time + 10 + random() * 10;
1267
1268         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1269
1270         bot_clientconnect(this);
1271
1272         Player_DetermineForcedTeam(this);
1273
1274         TRANSMUTE(Observer, this);
1275
1276         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1277
1278         // always track bots, don't ask for cl_allow_uidtracking
1279         if (IS_BOT_CLIENT(this))
1280                 PlayerStats_GameReport_AddPlayer(this);
1281         else
1282                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1283
1284         if (autocvar_sv_eventlog)
1285                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1286
1287         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1288
1289         stuffcmd(this, clientstuff, "\n");
1290         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1291
1292         FixClientCvars(this);
1293
1294         // get version info from player
1295         stuffcmd(this, "cmd clientversion $gameversion\n");
1296
1297         // notify about available teams
1298         if (teamplay)
1299         {
1300                 entity balance = TeamBalance_CheckAllowedTeams(this);
1301                 int t = TeamBalance_GetAllowedTeams(balance);
1302                 TeamBalance_Destroy(balance);
1303                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1304         }
1305         else
1306         {
1307                 stuffcmd(this, "set _teams_available 0\n");
1308         }
1309
1310         bot_relinkplayerlist();
1311
1312         CS(this).spectatortime = time;
1313         if (blockSpectators)
1314         {
1315                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1316         }
1317
1318         CS(this).jointime = time;
1319
1320         if (IS_REAL_CLIENT(this))
1321         {
1322                 if (g_weaponarena_weapons == WEPSET(TUBA))
1323                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1324         }
1325
1326         if (!sv_foginterval && world.fog != "")
1327                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1328
1329         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1330                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1331                         send_CSQC_teamnagger();
1332
1333         CSQCMODEL_AUTOINIT(this);
1334
1335         CS(this).model_randomizer = random();
1336
1337         if (IS_REAL_CLIENT(this))
1338                 sv_notice_join(this);
1339
1340         // update physics stats (players can spawn before physics runs)
1341         Physics_UpdateStats(this);
1342
1343         IL_EACH(g_initforplayer, it.init_for_player, {
1344                 it.init_for_player(it, this);
1345         });
1346
1347         Handicap_Initialize(this);
1348
1349         MUTATOR_CALLHOOK(ClientConnect, this);
1350
1351         if (IS_REAL_CLIENT(this))
1352         {
1353                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1354                 {
1355                         CS(this).motd_actived_time = -1;
1356                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1357                 }
1358         }
1359 }
1360 /*
1361 =============
1362 ClientDisconnect
1363
1364 Called when a client disconnects from the server
1365 =============
1366 */
1367 .entity chatbubbleentity;
1368 void ClientDisconnect(entity this)
1369 {
1370         assert(IS_CLIENT(this), return);
1371
1372         PlayerStats_GameReport_FinalizePlayer(this);
1373         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1374         if (CS(this).active_minigame) part_minigame(this);
1375         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1376
1377         if (autocvar_sv_eventlog)
1378                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1379
1380         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1381
1382         if(IS_SPEC(this))
1383                 SetSpectatee(this, NULL);
1384
1385     MUTATOR_CALLHOOK(ClientDisconnect, this);
1386
1387         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1388         strfree(CS(this).weaponorder_byimpulse);
1389         ClientState_detach(this);
1390
1391         Portal_ClearAll(this);
1392
1393         Unfreeze(this);
1394
1395         RemoveGrapplingHooks(this);
1396
1397         // Here, everything has been done that requires this player to be a client.
1398
1399         this.flags &= ~FL_CLIENT;
1400
1401         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1402         if (this.killindicator) delete(this.killindicator);
1403
1404         WaypointSprite_PlayerGone(this);
1405
1406         bot_relinkplayerlist();
1407
1408         strfree(this.clientstatus);
1409         if (this.personal) delete(this.personal);
1410
1411         this.playerid = 0;
1412         ReadyCount();
1413         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1414
1415         ONREMOVE(this);
1416 }
1417
1418 void ChatBubbleThink(entity this)
1419 {
1420         this.nextthink = time;
1421         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1422         {
1423                 if(this.owner) // but why can that ever be NULL?
1424                         this.owner.chatbubbleentity = NULL;
1425                 delete(this);
1426                 return;
1427         }
1428
1429         this.mdl = "";
1430
1431         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1432         {
1433                 if ( CS(this.owner).active_minigame )
1434                         this.mdl = "models/sprites/minigame_busy.iqm";
1435                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1436                         this.mdl = "models/misc/chatbubble.spr";
1437         }
1438
1439         if ( this.model != this.mdl )
1440                 _setmodel(this, this.mdl);
1441
1442 }
1443
1444 void UpdateChatBubble(entity this)
1445 {
1446         if (this.alpha < 0)
1447                 return;
1448         // spawn a chatbubble entity if needed
1449         if (!this.chatbubbleentity)
1450         {
1451                 this.chatbubbleentity = new(chatbubbleentity);
1452                 this.chatbubbleentity.owner = this;
1453                 this.chatbubbleentity.exteriormodeltoclient = this;
1454                 setthink(this.chatbubbleentity, ChatBubbleThink);
1455                 this.chatbubbleentity.nextthink = time;
1456                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1457                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1458                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1459                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1460                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1461                 //this.chatbubbleentity.model = "";
1462                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1463         }
1464 }
1465
1466
1467 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1468 // added to the model skins
1469 /*void UpdateColorModHack()
1470 {
1471         float c;
1472         c = this.clientcolors & 15;
1473         // LordHavoc: only bothering to support white, green, red, yellow, blue
1474              if (!teamplay) this.colormod = '0 0 0';
1475         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1476         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1477         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1478         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1479         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1480         else this.colormod = '1 1 1';
1481 }*/
1482
1483 void respawn(entity this)
1484 {
1485         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1486         {
1487                 this.solid = SOLID_NOT;
1488                 this.takedamage = DAMAGE_NO;
1489                 set_movetype(this, MOVETYPE_FLY);
1490                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1491                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1492                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1493                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1494                 if(autocvar_g_respawn_ghosts_maxtime)
1495                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1496         }
1497
1498         CopyBody(this, 1);
1499
1500         this.effects |= EF_NODRAW; // prevent another CopyBody
1501         PutClientInServer(this);
1502 }
1503
1504 void PrintToChat(entity client, string text)
1505 {
1506         text = strcat("\{1}^7", text, "\n");
1507         sprint(client, text);
1508 }
1509
1510 void DebugPrintToChat(entity client, string text)
1511 {
1512         if (autocvar_developer)
1513         {
1514                 PrintToChat(client, text);
1515         }
1516 }
1517
1518 void PrintToChatAll(string text)
1519 {
1520         text = strcat("\{1}^7", text, "\n");
1521         bprint(text);
1522 }
1523
1524 void DebugPrintToChatAll(string text)
1525 {
1526         if (autocvar_developer)
1527         {
1528                 PrintToChatAll(text);
1529         }
1530 }
1531
1532 void PrintToChatTeam(int team_num, string text)
1533 {
1534         text = strcat("\{1}^7", text, "\n");
1535         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1536         {
1537                 if (it.team == team_num)
1538                 {
1539                         sprint(it, text);
1540                 }
1541         });
1542 }
1543
1544 void DebugPrintToChatTeam(int team_num, string text)
1545 {
1546         if (autocvar_developer)
1547         {
1548                 PrintToChatTeam(team_num, text);
1549         }
1550 }
1551
1552 void play_countdown(entity this, float finished, Sound samp)
1553 {
1554         TC(Sound, samp);
1555         if(IS_REAL_CLIENT(this))
1556                 if(floor(finished - time - frametime) != floor(finished - time))
1557                         if(finished - time < 6)
1558                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1559 }
1560
1561 void player_powerups(entity this)
1562 {
1563         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1564         int items_prev = this.items;
1565
1566         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1567                 this.modelflags |= MF_ROCKET;
1568         else
1569                 this.modelflags &= ~MF_ROCKET;
1570
1571         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1572
1573         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1574                 return;
1575
1576         Fire_ApplyDamage(this);
1577         Fire_ApplyEffect(this);
1578
1579         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1580         {
1581                 if (this.items & ITEM_Strength.m_itemid)
1582                 {
1583                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1584                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1585                         if (time > this.strength_finished)
1586                         {
1587                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1588                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1589                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1590                         }
1591                 }
1592                 else
1593                 {
1594                         if (time < this.strength_finished)
1595                         {
1596                                 this.items = this.items | ITEM_Strength.m_itemid;
1597                                 if(!g_cts)
1598                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1599                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1600                         }
1601                 }
1602                 if (this.items & ITEM_Shield.m_itemid)
1603                 {
1604                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1605                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1606                         if (time > this.invincible_finished)
1607                         {
1608                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1609                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1610                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1611                         }
1612                 }
1613                 else
1614                 {
1615                         if (time < this.invincible_finished)
1616                         {
1617                                 this.items = this.items | ITEM_Shield.m_itemid;
1618                                 if(!g_cts)
1619                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1620                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1621                         }
1622                 }
1623                 if (this.items & IT_SUPERWEAPON)
1624                 {
1625                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1626                         {
1627                                 this.superweapons_finished = 0;
1628                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1629                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1630                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1631                         }
1632                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1633                         {
1634                                 // don't let them run out
1635                         }
1636                         else
1637                         {
1638                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1639                                 if (time > this.superweapons_finished)
1640                                 {
1641                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1642                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1643                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1644                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1645                                 }
1646                         }
1647                 }
1648                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1649                 {
1650                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1651                         {
1652                                 this.items = this.items | IT_SUPERWEAPON;
1653                                 if(!g_cts)
1654                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1655                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1656                         }
1657                         else
1658                         {
1659                                 this.superweapons_finished = 0;
1660                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1661                         }
1662                 }
1663                 else
1664                 {
1665                         this.superweapons_finished = 0;
1666                 }
1667         }
1668
1669         if(autocvar_g_nodepthtestplayers)
1670                 this.effects = this.effects | EF_NODEPTHTEST;
1671
1672         if(autocvar_g_fullbrightplayers)
1673                 this.effects = this.effects | EF_FULLBRIGHT;
1674
1675         if (time >= game_starttime)
1676         if (time < this.spawnshieldtime)
1677                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1678
1679         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1680 }
1681
1682 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1683 {
1684         if(current > stable)
1685                 return current;
1686         else if(current > stable - 0.25) // when close enough, "snap"
1687                 return stable;
1688         else
1689                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1690 }
1691
1692 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1693 {
1694         if(current < stable)
1695                 return current;
1696         else if(current < stable + 0.25) // when close enough, "snap"
1697                 return stable;
1698         else
1699                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1700 }
1701
1702 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1703 {
1704         if(current > rotstable)
1705         {
1706                 if(rotframetime > 0)
1707                 {
1708                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1709                         current = max(rotstable, current - rotlinear * rotframetime);
1710                 }
1711         }
1712         else if(current < regenstable)
1713         {
1714                 if(regenframetime > 0)
1715                 {
1716                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1717                         current = min(regenstable, current + regenlinear * regenframetime);
1718                 }
1719         }
1720
1721         if(current > limit)
1722                 current = limit;
1723
1724         return current;
1725 }
1726
1727 void player_regen(entity this)
1728 {
1729         float max_mod, regen_mod, rot_mod, limit_mod;
1730         max_mod = regen_mod = rot_mod = limit_mod = 1;
1731
1732         float regen_health = autocvar_g_balance_health_regen;
1733         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1734         float regen_health_rot = autocvar_g_balance_health_rot;
1735         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1736         float regen_health_stable = autocvar_g_balance_health_regenstable;
1737         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1738         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1739                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1740         max_mod = M_ARGV(1, float);
1741         regen_mod = M_ARGV(2, float);
1742         rot_mod = M_ARGV(3, float);
1743         limit_mod = M_ARGV(4, float);
1744         regen_health = M_ARGV(5, float);
1745         regen_health_linear = M_ARGV(6, float);
1746         regen_health_rot = M_ARGV(7, float);
1747         regen_health_rotlinear = M_ARGV(8, float);
1748         regen_health_stable = M_ARGV(9, float);
1749         regen_health_rotstable = M_ARGV(10, float);
1750
1751         if(!mutator_returnvalue)
1752         if(!STAT(FROZEN, this))
1753         {
1754                 float mina, maxa, limith, limita;
1755                 maxa = autocvar_g_balance_armor_rotstable;
1756                 mina = autocvar_g_balance_armor_regenstable;
1757                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1758                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1759
1760                 regen_health_rotstable = regen_health_rotstable * max_mod;
1761                 regen_health_stable = regen_health_stable * max_mod;
1762                 limith = limith * limit_mod;
1763                 limita = limita * limit_mod;
1764
1765                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1766                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1767                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1768                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1769                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1770                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1771         }
1772
1773         // if player rotted to death...  die!
1774         // check this outside above checks, as player may still be able to rot to death
1775         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1776         {
1777                 if(this.vehicle)
1778                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1779                 if(this.event_damage)
1780                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1781         }
1782
1783         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1784         {
1785                 float minf, maxf, limitf;
1786
1787                 maxf = autocvar_g_balance_fuel_rotstable;
1788                 minf = autocvar_g_balance_fuel_regenstable;
1789                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1790
1791                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1792                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1793                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1794         }
1795 }
1796
1797 bool zoomstate_set;
1798 void SetZoomState(entity this, float newzoom)
1799 {
1800         if(newzoom != CS(this).zoomstate)
1801         {
1802                 CS(this).zoomstate = newzoom;
1803                 ClientData_Touch(this);
1804         }
1805         zoomstate_set = true;
1806 }
1807
1808 void GetPressedKeys(entity this)
1809 {
1810         MUTATOR_CALLHOOK(GetPressedKeys, this);
1811         int keys = STAT(PRESSED_KEYS, this);
1812         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1813         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1814         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1815         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1816
1817         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1818         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1819         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1820         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1821         CS(this).pressedkeys = keys; // store for other users
1822
1823         STAT(PRESSED_KEYS, this) = keys;
1824 }
1825
1826 /*
1827 ======================
1828 spectate mode routines
1829 ======================
1830 */
1831
1832 void SpectateCopy(entity this, entity spectatee)
1833 {
1834         TC(Client, this); TC(Client, spectatee);
1835
1836         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1837         PS(this) = PS(spectatee);
1838         this.armortype = spectatee.armortype;
1839         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1840         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1841         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1842         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1843         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1844         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1845         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1846         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1847         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1848         CS(this).impulse = 0;
1849         this.items = spectatee.items;
1850         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1851         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1852         this.strength_finished = spectatee.strength_finished;
1853         this.invincible_finished = spectatee.invincible_finished;
1854         this.superweapons_finished = spectatee.superweapons_finished;
1855         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1856         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1857         this.punchangle = spectatee.punchangle;
1858         this.view_ofs = spectatee.view_ofs;
1859         this.velocity = spectatee.velocity;
1860         this.dmg_take = spectatee.dmg_take;
1861         this.dmg_save = spectatee.dmg_save;
1862         this.dmg_inflictor = spectatee.dmg_inflictor;
1863         this.v_angle = spectatee.v_angle;
1864         this.angles = spectatee.v_angle;
1865         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1866         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1867         this.viewloc = spectatee.viewloc;
1868         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1869                 this.fixangle = true;
1870         setorigin(this, spectatee.origin);
1871         setsize(this, spectatee.mins, spectatee.maxs);
1872         SetZoomState(this, CS(spectatee).zoomstate);
1873
1874     anticheat_spectatecopy(this, spectatee);
1875         STAT(HUD, this) = STAT(HUD, spectatee);
1876         if(spectatee.vehicle)
1877     {
1878         this.angles = spectatee.v_angle;
1879
1880         //this.fixangle = false;
1881         //this.velocity = spectatee.vehicle.velocity;
1882         this.vehicle_health = spectatee.vehicle_health;
1883         this.vehicle_shield = spectatee.vehicle_shield;
1884         this.vehicle_energy = spectatee.vehicle_energy;
1885         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1886         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1887         this.vehicle_reload1 = spectatee.vehicle_reload1;
1888         this.vehicle_reload2 = spectatee.vehicle_reload2;
1889
1890         //msg_entity = this;
1891
1892        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1893             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1894            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1895            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1896
1897         //WriteByte (MSG_ONE, SVC_SETVIEW);
1898         //    WriteEntity(MSG_ONE, this);
1899         //makevectors(spectatee.v_angle);
1900         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1901     }
1902 }
1903
1904 bool SpectateUpdate(entity this)
1905 {
1906         if(!this.enemy)
1907                 return false;
1908
1909         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1910         {
1911                 SetSpectatee(this, NULL);
1912                 return false;
1913         }
1914
1915         SpectateCopy(this, this.enemy);
1916
1917         return true;
1918 }
1919
1920 bool SpectateSet(entity this)
1921 {
1922         if(!IS_PLAYER(this.enemy))
1923                 return false;
1924
1925         ClientData_Touch(this.enemy);
1926
1927         msg_entity = this;
1928         WriteByte(MSG_ONE, SVC_SETVIEW);
1929         WriteEntity(MSG_ONE, this.enemy);
1930         set_movetype(this, MOVETYPE_NONE);
1931         accuracy_resend(this);
1932
1933         if(!SpectateUpdate(this))
1934                 PutObserverInServer(this);
1935
1936         return true;
1937 }
1938
1939 void SetSpectatee_status(entity this, int spectatee_num)
1940 {
1941         int oldspectatee_status = CS(this).spectatee_status;
1942         CS(this).spectatee_status = spectatee_num;
1943
1944         if (CS(this).spectatee_status != oldspectatee_status)
1945         {
1946                 ClientData_Touch(this);
1947                 if (g_race || g_cts) race_InitSpectator();
1948         }
1949 }
1950
1951 void SetSpectatee(entity this, entity spectatee)
1952 {
1953         if(IS_BOT_CLIENT(this))
1954                 return; // bots abuse .enemy, this code is useless to them
1955
1956         entity old_spectatee = this.enemy;
1957
1958         this.enemy = spectatee;
1959
1960         // WEAPONTODO
1961         // these are required to fix the spectator bug with arc
1962         if(old_spectatee)
1963         {
1964                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1965                 {
1966                         .entity weaponentity = weaponentities[slot];
1967                         if(old_spectatee.(weaponentity).arc_beam)
1968                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1969                 }
1970         }
1971         if(this.enemy)
1972         {
1973                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1974                 {
1975                         .entity weaponentity = weaponentities[slot];
1976                         if(this.enemy.(weaponentity).arc_beam)
1977                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1978                 }
1979         }
1980
1981         if (this.enemy)
1982                 SetSpectatee_status(this, etof(this.enemy));
1983
1984         // needed to update spectator list
1985         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1986 }
1987
1988 bool Spectate(entity this, entity pl)
1989 {
1990         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1991                 return false;
1992         pl = M_ARGV(1, entity);
1993
1994         SetSpectatee(this, pl);
1995         return SpectateSet(this);
1996 }
1997
1998 bool SpectateNext(entity this)
1999 {
2000         entity ent = find(this.enemy, classname, STR_PLAYER);
2001
2002         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2003                 ent = M_ARGV(1, entity);
2004         else if (!ent)
2005                 ent = find(ent, classname, STR_PLAYER);
2006
2007         if(ent) { SetSpectatee(this, ent); }
2008
2009         return SpectateSet(this);
2010 }
2011
2012 bool SpectatePrev(entity this)
2013 {
2014         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2015         entity ent = findchain(classname, STR_PLAYER);
2016         if (!ent) // no player
2017                 return false;
2018
2019         entity first = ent;
2020         // skip players until current spectated player
2021         if(this.enemy)
2022         while(ent && ent != this.enemy)
2023                 ent = ent.chain;
2024
2025         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2026         {
2027                 case MUT_SPECPREV_FOUND:
2028                     ent = M_ARGV(1, entity);
2029                     break;
2030                 case MUT_SPECPREV_RETURN:
2031                     return true;
2032                 case MUT_SPECPREV_CONTINUE:
2033                 default:
2034                 {
2035                         if(ent.chain)
2036                                 ent = ent.chain;
2037                         else
2038                                 ent = first;
2039                         break;
2040                 }
2041         }
2042
2043         SetSpectatee(this, ent);
2044         return SpectateSet(this);
2045 }
2046
2047 /*
2048 =============
2049 ShowRespawnCountdown()
2050
2051 Update a respawn countdown display.
2052 =============
2053 */
2054 void ShowRespawnCountdown(entity this)
2055 {
2056         float number;
2057         if(!IS_DEAD(this)) // just respawned?
2058                 return;
2059         else
2060         {
2061                 number = ceil(this.respawn_time - time);
2062                 if(number <= 0)
2063                         return;
2064                 if(number <= this.respawn_countdown)
2065                 {
2066                         this.respawn_countdown = number - 1;
2067                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2068                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2069                 }
2070         }
2071 }
2072
2073 .bool team_selected;
2074 bool ShowTeamSelection(entity this)
2075 {
2076         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2077                 return false;
2078         stuffcmd(this, "menu_showteamselect\n");
2079         return true;
2080 }
2081 void Join(entity this)
2082 {
2083         TRANSMUTE(Player, this);
2084
2085         if(!this.team_selected)
2086         if(autocvar_g_campaign || autocvar_g_balance_teams)
2087                 TeamBalance_JoinBestTeam(this);
2088
2089         if(autocvar_g_campaign)
2090                 campaign_bots_may_start = true;
2091
2092         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2093
2094         PutClientInServer(this);
2095
2096         if(IS_PLAYER(this))
2097         if(teamplay && this.team != -1)
2098         {
2099                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2100         }
2101         else
2102                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2103         this.team_selected = false;
2104 }
2105
2106 /**
2107  * Determines whether the player is allowed to join. This depends on cvar
2108  * g_maxplayers, if it isn't used this function always return true, otherwise
2109  * it checks whether the number of currently playing players exceeds g_maxplayers.
2110  * @return int number of free slots for players, 0 if none
2111  */
2112 int nJoinAllowed(entity this, entity ignore)
2113 {
2114         if(!ignore)
2115         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2116         // so report 0 free slots if restricted
2117         {
2118                 if(autocvar_g_forced_team_otherwise == "spectate")
2119                         return 0;
2120                 if(autocvar_g_forced_team_otherwise == "spectator")
2121                         return 0;
2122         }
2123
2124         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2125                 return 0; // forced spectators can never join
2126
2127         // TODO simplify this
2128         int totalClients = 0;
2129         int currentlyPlaying = 0;
2130         FOREACH_CLIENT(true, {
2131                 if(it != ignore)
2132                         ++totalClients;
2133                 if(IS_REAL_CLIENT(it))
2134                 if(IS_PLAYER(it) || it.caplayer)
2135                         ++currentlyPlaying;
2136         });
2137
2138         float free_slots = 0;
2139         if (!autocvar_g_maxplayers)
2140                 free_slots = maxclients - totalClients;
2141         else if(currentlyPlaying < autocvar_g_maxplayers)
2142                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2143
2144         static float join_prevent_msg_time = 0;
2145         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2146         {
2147                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2148                 join_prevent_msg_time = time + 3;
2149         }
2150
2151         return free_slots;
2152 }
2153
2154 /**
2155  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2156  * g_maxplayers_spectator_blocktime seconds
2157  */
2158 void checkSpectatorBlock(entity this)
2159 {
2160         if(IS_SPEC(this) || IS_OBSERVER(this))
2161         if(!this.caplayer)
2162         if(IS_REAL_CLIENT(this))
2163         {
2164                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2165                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2166                         dropclient(this);
2167                 }
2168         }
2169 }
2170
2171 void PrintWelcomeMessage(entity this)
2172 {
2173         if(CS(this).motd_actived_time == 0)
2174         {
2175                 if (autocvar_g_campaign) {
2176                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2177                                 CS(this).motd_actived_time = time;
2178                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2179                         }
2180                 } else {
2181                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2182                                 CS(this).motd_actived_time = time;
2183                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2184                         }
2185                 }
2186         }
2187         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2188         {
2189                 if (autocvar_g_campaign) {
2190                         if (PHYS_INPUT_BUTTON_INFO(this))
2191                                 CS(this).motd_actived_time = time;
2192                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2193                                 CS(this).motd_actived_time = 0;
2194                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2195                         }
2196                 } else {
2197                         if (PHYS_INPUT_BUTTON_INFO(this))
2198                                 CS(this).motd_actived_time = time;
2199                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2200                                 CS(this).motd_actived_time = 0;
2201                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2202                         }
2203                 }
2204         }
2205         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2206         {
2207                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2208                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2209                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2210                 {
2211                         // instanctly hide MOTD
2212                         CS(this).motd_actived_time = 0;
2213                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2214                 }
2215         }
2216 }
2217
2218 const int MIN_SPEC_TIME = 1;
2219 bool joinAllowed(entity this)
2220 {
2221         if (CS(this).version_mismatch) return false;
2222         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2223         if (!nJoinAllowed(this, this)) return false;
2224         if (teamplay && lockteams) return false;
2225         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2226         if (ShowTeamSelection(this)) return false;
2227         return true;
2228 }
2229
2230 .int items_added;
2231 .string shootfromfixedorigin;
2232 bool PlayerThink(entity this)
2233 {
2234         if (game_stopped || intermission_running) {
2235                 this.modelflags &= ~MF_ROCKET;
2236                 if(intermission_running)
2237                         IntermissionThink(this);
2238                 return false;
2239         }
2240
2241         if (timeout_status == TIMEOUT_ACTIVE) {
2242         // don't allow the player to turn around while game is paused
2243                 // FIXME turn this into CSQC stuff
2244                 this.v_angle = this.lastV_angle;
2245                 this.angles = this.lastV_angle;
2246                 this.fixangle = true;
2247         }
2248
2249         if (frametime) player_powerups(this);
2250
2251         if (IS_DEAD(this)) {
2252                 if (this.personal && g_race_qualifying) {
2253                         if (time > this.respawn_time) {
2254                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2255                                 respawn(this);
2256                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2257                         }
2258                 } else {
2259                         if (frametime) player_anim(this);
2260
2261                         if (this.respawn_flags & RESPAWN_DENY)
2262                         {
2263                                 STAT(RESPAWN_TIME, this) = 0;
2264                                 return false;
2265                         }
2266
2267                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2268
2269                         switch(this.deadflag)
2270                         {
2271                                 case DEAD_DYING:
2272                                 {
2273                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2274                                                 this.deadflag = DEAD_RESPAWNING;
2275                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2276                                                 this.deadflag = DEAD_DEAD;
2277                                         break;
2278                                 }
2279                                 case DEAD_DEAD:
2280                                 {
2281                                         if (button_pressed)
2282                                                 this.deadflag = DEAD_RESPAWNABLE;
2283                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2284                                                 this.deadflag = DEAD_RESPAWNING;
2285                                         break;
2286                                 }
2287                                 case DEAD_RESPAWNABLE:
2288                                 {
2289                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2290                                                 this.deadflag = DEAD_RESPAWNING;
2291                                         break;
2292                                 }
2293                                 case DEAD_RESPAWNING:
2294                                 {
2295                                         if (time > this.respawn_time)
2296                                         {
2297                                                 this.respawn_time = time + 1; // only retry once a second
2298                                                 this.respawn_time_max = this.respawn_time;
2299                                                 respawn(this);
2300                                         }
2301                                         break;
2302                                 }
2303                         }
2304
2305                         ShowRespawnCountdown(this);
2306
2307                         if (this.respawn_flags & RESPAWN_SILENT)
2308                                 STAT(RESPAWN_TIME, this) = 0;
2309                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2310                         {
2311                                 if (time < this.respawn_time)
2312                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2313                                 else if (this.deadflag != DEAD_RESPAWNING)
2314                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2315                         }
2316                         else
2317                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2318                 }
2319
2320                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2321                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2322                         STAT(RESPAWN_TIME, this) *= -1;
2323
2324                 return false;
2325         }
2326
2327         FixPlayermodel(this);
2328
2329         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2330                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2331                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2332         }
2333
2334         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2335         //if(frametime)
2336         {
2337                 this.items &= ~this.items_added;
2338
2339                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2340                 {
2341                         .entity weaponentity = weaponentities[slot];
2342                         W_WeaponFrame(this, weaponentity);
2343                 }
2344
2345                 this.items_added = 0;
2346                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2347             this.items_added |= IT_FUEL;
2348
2349                 this.items |= this.items_added;
2350         }
2351
2352         player_regen(this);
2353
2354         // WEAPONTODO: Add a weapon request for this
2355         // rot vortex charge to the charge limit
2356         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2357         {
2358                 .entity weaponentity = weaponentities[slot];
2359                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2360                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2361         }
2362
2363         if (frametime) player_anim(this);
2364
2365         // secret status
2366         secrets_setstatus(this);
2367
2368         // monsters status
2369         monsters_setstatus(this);
2370
2371         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2372
2373         return true;
2374 }
2375
2376 .bool would_spectate;
2377 void ObserverThink(entity this)
2378 {
2379         if ( CS(this).impulse )
2380         {
2381                 MinigameImpulse(this, CS(this).impulse);
2382                 CS(this).impulse = 0;
2383         }
2384
2385         if (this.flags & FL_JUMPRELEASED) {
2386                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2387                         this.flags &= ~FL_JUMPRELEASED;
2388                         this.flags |= FL_SPAWNING;
2389                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2390                         this.flags &= ~FL_JUMPRELEASED;
2391                         if(SpectateNext(this)) {
2392                                 TRANSMUTE(Spectator, this);
2393                         }
2394                 } else {
2395                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2396                         set_movetype(this, preferred_movetype);
2397                 }
2398         } else {
2399                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2400                         this.flags |= FL_JUMPRELEASED;
2401                         if(this.flags & FL_SPAWNING)
2402                         {
2403                                 this.flags &= ~FL_SPAWNING;
2404                                 Join(this);
2405                                 return;
2406                         }
2407                 }
2408         }
2409 }
2410
2411 void SpectatorThink(entity this)
2412 {
2413         if ( CS(this).impulse )
2414         {
2415                 if(MinigameImpulse(this, CS(this).impulse))
2416                         CS(this).impulse = 0;
2417
2418                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2419                 {
2420                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2421                         CS(this).impulse = 0;
2422                         return;
2423                 }
2424         }
2425
2426         if (this.flags & FL_JUMPRELEASED) {
2427                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2428                         this.flags &= ~FL_JUMPRELEASED;
2429                         this.flags |= FL_SPAWNING;
2430                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2431                         this.flags &= ~FL_JUMPRELEASED;
2432                         if(SpectateNext(this)) {
2433                                 TRANSMUTE(Spectator, this);
2434                         } else {
2435                                 TRANSMUTE(Observer, this);
2436                                 PutClientInServer(this);
2437                         }
2438                         CS(this).impulse = 0;
2439                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2440                         this.flags &= ~FL_JUMPRELEASED;
2441                         if(SpectatePrev(this)) {
2442                                 TRANSMUTE(Spectator, this);
2443                         } else {
2444                                 TRANSMUTE(Observer, this);
2445                                 PutClientInServer(this);
2446                         }
2447                         CS(this).impulse = 0;
2448                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2449                         this.would_spectate = false;
2450                         this.flags &= ~FL_JUMPRELEASED;
2451                         TRANSMUTE(Observer, this);
2452                         PutClientInServer(this);
2453                 } else {
2454                         if(!SpectateUpdate(this))
2455                         {
2456                                 if(!SpectateNext(this))
2457                                 {
2458                                         PutObserverInServer(this);
2459                                         this.would_spectate = true;
2460                                 }
2461                         }
2462                 }
2463         } else {
2464                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2465                         this.flags |= FL_JUMPRELEASED;
2466                         if(this.flags & FL_SPAWNING)
2467                         {
2468                                 this.flags &= ~FL_SPAWNING;
2469                                 Join(this);
2470                                 return;
2471                         }
2472                 }
2473                 if(!SpectateUpdate(this))
2474                         PutObserverInServer(this);
2475         }
2476
2477         this.flags |= FL_CLIENT | FL_NOTARGET;
2478 }
2479
2480 void PlayerUseKey(entity this)
2481 {
2482         if (!IS_PLAYER(this))
2483                 return;
2484
2485         if(this.vehicle)
2486         {
2487                 if(!game_stopped)
2488                 {
2489                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2490                         return;
2491                 }
2492         }
2493         else if(autocvar_g_vehicles_enter)
2494         {
2495                 if(!STAT(FROZEN, this))
2496                 if(!IS_DEAD(this))
2497                 if(!game_stopped)
2498                 {
2499                         entity head, closest_target = NULL;
2500                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2501
2502                         while(head) // find the closest acceptable target to enter
2503                         {
2504                                 if(IS_VEHICLE(head))
2505                                 if(!IS_DEAD(head))
2506                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2507                                 if(head.takedamage != DAMAGE_NO)
2508                                 {
2509                                         if(closest_target)
2510                                         {
2511                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2512                                                 { closest_target = head; }
2513                                         }
2514                                         else { closest_target = head; }
2515                                 }
2516
2517                                 head = head.chain;
2518                         }
2519
2520                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2521                 }
2522         }
2523
2524         // a use key was pressed; call handlers
2525         MUTATOR_CALLHOOK(PlayerUseKey, this);
2526 }
2527
2528
2529 /*
2530 =============
2531 PlayerPreThink
2532
2533 Called every frame for each client before the physics are run
2534 =============
2535 */
2536 .float last_vehiclecheck;
2537 void PlayerPreThink (entity this)
2538 {
2539         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2540         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2541
2542         WarpZone_PlayerPhysics_FixVAngle(this);
2543
2544         if (frametime) {
2545                 // physics frames: update anticheat stuff
2546                 anticheat_prethink(this);
2547         }
2548
2549         if (blockSpectators && frametime) {
2550                 // WORKAROUND: only use dropclient in server frames (frametime set).
2551                 // Never use it in cl_movement frames (frametime zero).
2552                 checkSpectatorBlock(this);
2553         }
2554
2555         zoomstate_set = false;
2556
2557         // Check for nameless players
2558         if (this.netname == "" || this.netname != CS(this).netname_previous)
2559         {
2560                 bool assume_unchanged = (CS(this).netname_previous == "");
2561                 if (isInvisibleString(this.netname))
2562                 {
2563                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2564                         assume_unchanged = false;
2565                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2566                 }
2567                 if (!assume_unchanged && autocvar_sv_eventlog)
2568                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2569                 strcpy(CS(this).netname_previous, this.netname);
2570         }
2571
2572         // version nagging
2573         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2574         CS(this).version_nagtime = 0;
2575         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2576             // git client
2577         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2578             // git server
2579             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2580         } else {
2581             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2582             if (r < 0) { // old client
2583                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2584             } else if (r > 0) { // old server
2585                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2586             }
2587         }
2588     }
2589
2590         // GOD MODE info
2591         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2592         {
2593                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2594                 this.max_armorvalue = 0;
2595         }
2596
2597         if(IS_PLAYER(this))
2598         {
2599                 if (STAT(FROZEN, this) == 2)
2600                 {
2601                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2602                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2603                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2604
2605                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2606                                 Unfreeze(this);
2607                 }
2608                 else if (STAT(FROZEN, this) == 3)
2609                 {
2610                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2611                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2612
2613                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2614                         {
2615                                 if (this.vehicle)
2616                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2617                                 if(this.event_damage)
2618                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2619                         }
2620                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2621                                 Unfreeze(this);
2622                 }
2623         }
2624
2625         MUTATOR_CALLHOOK(PlayerPreThink, this);
2626
2627         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2628         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2629         {
2630                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2631                 {
2632                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2633                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2634                         {
2635                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2636                         }
2637                         else if(!it.owner)
2638                         {
2639                                 if(!it.team || SAME_TEAM(this, it))
2640                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2641                                 else if(autocvar_g_vehicles_steal)
2642                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2643                         }
2644                 });
2645
2646                 this.last_vehiclecheck = time + 1;
2647         }
2648
2649         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2650         {
2651                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2652                         PlayerUseKey(this);
2653                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2654         }
2655
2656         if (IS_REAL_CLIENT(this))
2657                 PrintWelcomeMessage(this);
2658
2659         if (IS_PLAYER(this)) {
2660                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2661                         error("Client can't be spawned as player on connection!");
2662                 if(!PlayerThink(this))
2663                         return;
2664         }
2665         else if (game_stopped || intermission_running) {
2666                 if(intermission_running)
2667                         IntermissionThink(this);
2668                 return;
2669         }
2670         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2671         {
2672                 CS(this).autojoin_checked = true;
2673                 // don't do this in ClientConnect
2674                 // many things can go wrong if a client is spawned as player on connection
2675                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2676                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2677                                 && (!teamplay || autocvar_g_balance_teams)))
2678                 {
2679                         campaign_bots_may_start = true;
2680                         Join(this);
2681                         return;
2682                 }
2683         }
2684         else if (IS_OBSERVER(this)) {
2685                 ObserverThink(this);
2686         }
2687         else if (IS_SPEC(this)) {
2688                 SpectatorThink(this);
2689         }
2690
2691         // WEAPONTODO: Add weapon request for this
2692         if (!zoomstate_set) {
2693                 bool wep_zoomed = false;
2694                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2695                 {
2696                         .entity weaponentity = weaponentities[slot];
2697                         Weapon thiswep = this.(weaponentity).m_weapon;
2698                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2699                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2700                 }
2701                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2702     }
2703
2704         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2705         {
2706                 CS(this).teamkill_soundtime = 0;
2707
2708                 entity e = CS(this).teamkill_soundsource;
2709                 entity oldpusher = e.pusher;
2710                 e.pusher = this;
2711                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2712                 e.pusher = oldpusher;
2713         }
2714
2715         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2716                 CS(this).taunt_soundtime = 0;
2717                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2718         }
2719
2720         target_voicescript_next(this);
2721
2722         // WEAPONTODO: Move into weaponsystem somehow
2723         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2724         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2725         {
2726                 .entity weaponentity = weaponentities[slot];
2727                 if(this.(weaponentity).m_weapon == WEP_Null)
2728                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2729         }
2730 }
2731
2732 void DrownPlayer(entity this)
2733 {
2734         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2735                 return;
2736
2737         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2738         {
2739                 if(this.air_finished < time)
2740                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2741                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2742         }
2743         else if (this.air_finished < time)
2744         {       // drown!
2745                 if (this.pain_finished < time)
2746                 {
2747                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2748                         this.pain_finished = time + 0.5;
2749                 }
2750         }
2751 }
2752
2753 .bool move_qcphysics;
2754
2755 void Player_Physics(entity this)
2756 {
2757         set_movetype(this, this.move_movetype);
2758
2759         if(!this.move_qcphysics)
2760                 return;
2761
2762         if(!frametime && !CS(this).pm_frametime)
2763                 return;
2764
2765         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2766
2767         CS(this).pm_frametime = 0;
2768 }
2769
2770 /*
2771 =============
2772 PlayerPostThink
2773
2774 Called every frame for each client after the physics are run
2775 =============
2776 */
2777 void PlayerPostThink (entity this)
2778 {
2779         Player_Physics(this);
2780
2781         if (sv_maxidle > 0)
2782         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2783         if (IS_REAL_CLIENT(this))
2784         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2785         {
2786                 int totalClients = 0;
2787                 if(sv_maxidle_slots > 0)
2788                 {
2789                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2790                         {
2791                                 ++totalClients;
2792                         });
2793                 }
2794
2795                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2796                 { /* do nothing */ }
2797                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2798                 {
2799                         if (CS(this).idlekick_lasttimeleft)
2800                         {
2801                                 CS(this).idlekick_lasttimeleft = 0;
2802                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2803                         }
2804                 }
2805                 else
2806                 {
2807                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2808                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2809                                 if (!CS(this).idlekick_lasttimeleft)
2810                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2811                         }
2812                         if (timeleft <= 0) {
2813                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2814                                 dropclient(this);
2815                                 return;
2816                         }
2817                         else if (timeleft <= 10) {
2818                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2819                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2820                 }
2821                                 CS(this).idlekick_lasttimeleft = timeleft;
2822                         }
2823                 }
2824         }
2825
2826         CheatFrame(this);
2827
2828         if (game_stopped)
2829         {
2830                 this.solid = SOLID_NOT;
2831                 this.takedamage = DAMAGE_NO;
2832                 set_movetype(this, MOVETYPE_NONE);
2833         }
2834
2835         if (IS_PLAYER(this)) {
2836                 if(this.death_time == time && IS_DEAD(this))
2837                 {
2838                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2839                         // once all the damage events of this frame have been processed with normal size
2840                         this.maxs.z = 5;
2841                         setsize(this, this.mins, this.maxs);
2842                 }
2843                 DrownPlayer(this);
2844                 UpdateChatBubble(this);
2845                 if (CS(this).impulse) ImpulseCommands(this);
2846                 if (game_stopped)
2847                 {
2848                         CSQCMODEL_AUTOUPDATE(this);
2849                         return;
2850                 }
2851                 GetPressedKeys(this);
2852         }
2853
2854         if (this.waypointsprite_attachedforcarrier) {
2855             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2856                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2857     }
2858
2859         CSQCMODEL_AUTOUPDATE(this);
2860 }
2861
2862 // hack to copy the button fields from the client entity to the Client State
2863 void PM_UpdateButtons(entity this, entity store)
2864 {
2865         if(this.impulse)
2866                 store.impulse = this.impulse;
2867         this.impulse = 0;
2868
2869         bool typing = this.buttonchat;
2870
2871         store.button0 = (typing) ? 0 : this.button0;
2872         //button1?!
2873         store.button2 = (typing) ? 0 : this.button2;
2874         store.button3 = (typing) ? 0 : this.button3;
2875         store.button4 = this.button4;
2876         store.button5 = (typing) ? 0 : this.button5;
2877         store.button6 = this.button6;
2878         store.button7 = this.button7;
2879         store.button8 = this.button8;
2880         store.button9 = this.button9;
2881         store.button10 = this.button10;
2882         store.button11 = this.button11;
2883         store.button12 = this.button12;
2884         store.button13 = this.button13;
2885         store.button14 = this.button14;
2886         store.button15 = this.button15;
2887         store.button16 = this.button16;
2888         store.buttonuse = this.buttonuse;
2889         store.buttonchat = this.buttonchat;
2890
2891         store.cursor_active = this.cursor_active;
2892         store.cursor_screen = this.cursor_screen;
2893         store.cursor_trace_start = this.cursor_trace_start;
2894         store.cursor_trace_endpos = this.cursor_trace_endpos;
2895         store.cursor_trace_ent = this.cursor_trace_ent;
2896
2897         store.ping = this.ping;
2898         store.ping_packetloss = this.ping_packetloss;
2899         store.ping_movementloss = this.ping_movementloss;
2900
2901         store.v_angle = this.v_angle;
2902         store.movement = (typing) ? '0 0 0' : this.movement;
2903 }
2904
2905 NET_HANDLE(fpsreport, bool)
2906 {
2907         int fps = ReadShort();
2908         PlayerScore_Set(sender, SP_FPS, fps);
2909         return true;
2910 }